qcsrc/client/hud/panel/healtharmor.qc

   1 #include "healtharmor.qh"
   2
   3 #include <common/deathtypes/all.qh>
   4
   5 /** Health/armor (#3) */
   6 void HUD_HealthArmor()
   7 {
   8         int armor, health, fuel;
   9         if(!autocvar__hud_configure)
  10         {
  11                 if(!autocvar_hud_panel_healtharmor) return;
  12                 if(hud != HUD_NORMAL) return;
  13                 if(spectatee_status == -1) return;
  14
  15                 health = STAT(HEALTH);
  16                 if(health <= 0)
  17                 {
  18                         prev_health = -1;
  19                         return;
  20                 }
  21                 armor = STAT(ARMOR);
  22
  23                 // code to check for spectatee_status changes is in Ent_ClientData()
  24                 // prev_p_health and prev_health can be set to -1 there
  25
  26                 if (prev_p_health == -1)
  27                 {
  28                         // no effect
  29                         health_beforedamage = 0;
  30                         armor_beforedamage = 0;
  31                         health_damagetime = 0;
  32                         armor_damagetime = 0;
  33                         prev_health = health;
  34                         prev_armor = armor;
  35                         old_p_health = health;
  36                         old_p_armor = armor;
  37                         prev_p_health = health;
  38                         prev_p_armor = armor;
  39                 }
  40                 else if (prev_health == -1)
  41                 {
  42                         //start the load effect
  43                         health_damagetime = 0;
  44                         armor_damagetime = 0;
  45                         prev_health = 0;
  46                         prev_armor = 0;
  47                 }
  48                 fuel = STAT(FUEL);
  49         }
  50         else
  51         {
  52                 health = 150;
  53                 armor = 75;
  54                 fuel = 20;
  55         }
  56
  57         HUD_Panel_UpdateCvars();
  58
  59         draw_beginBoldFont();
  60
  61         vector pos, mySize;
  62         pos = panel_pos;
  63         mySize = panel_size;
  64
  65         HUD_Panel_DrawBg(1);
  66         if(panel_bg_padding)
  67         {
  68                 pos += '1 1 0' * panel_bg_padding;
  69                 mySize -= '2 2 0' * panel_bg_padding;
  70         }
  71
  72         int baralign = autocvar_hud_panel_healtharmor_baralign;
  73         int iconalign = autocvar_hud_panel_healtharmor_iconalign;
  74
  75     int maxhealth = autocvar_hud_panel_healtharmor_maxhealth;
  76     int maxarmor = autocvar_hud_panel_healtharmor_maxarmor;
  77         if(autocvar_hud_panel_healtharmor_combined) // combined health and armor display
  78         {
  79                 vector v;
  80                 v = healtharmor_maxdamage(health, armor, armorblockpercent, DEATH_WEAPON.m_id);
  81
  82                 float x;
  83                 x = floor(v.x + 1);
  84
  85         float maxtotal = maxhealth + maxarmor;
  86                 string biggercount;
  87                 if(v.z) // NOT fully armored
  88                 {
  89                         biggercount = "health";
  90                         if(autocvar_hud_panel_healtharmor_progressbar)
  91                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_health, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
  92                         if(armor)
  93             if(autocvar_hud_panel_healtharmor_text)
  94                                 drawpic_aspect_skin(pos + eX * mySize.x - eX * 0.5 * mySize.y, "armor", '0.5 0.5 0' * mySize.y, '1 1 1', panel_fg_alpha * armor / health, DRAWFLAG_NORMAL);
  95                 }
  96                 else
  97                 {
  98                         biggercount = "armor";
  99                         if(autocvar_hud_panel_healtharmor_progressbar)
 100                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 101                         if(health)
 102             if(autocvar_hud_panel_healtharmor_text)
 103                                 drawpic_aspect_skin(pos + eX * mySize.x - eX * 0.5 * mySize.y, "health", '0.5 0.5 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 104                 }
 105         if(autocvar_hud_panel_healtharmor_text)
 106                         DrawNumIcon(pos, mySize, x, biggercount, 0, iconalign, HUD_Get_Num_Color(x, maxtotal), 1);
 107
 108                 if(fuel)
 109                         HUD_Panel_DrawProgressBar(pos, eX * mySize.x + eY * 0.2 * mySize.y, "progressbar", fuel/100, 0, (baralign == 1 || baralign == 3), autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
 110         }
 111         else
 112         {
 113                 float panel_ar = mySize.x/mySize.y;
 114                 bool is_vertical = (panel_ar < 1);
 115                 vector health_offset = '0 0 0', armor_offset = '0 0 0';
 116                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
 117                 {
 118                         mySize.x *= 0.5;
 119                         if (autocvar_hud_panel_healtharmor_flip)
 120                                 health_offset.x = mySize.x;
 121                         else
 122                                 armor_offset.x = mySize.x;
 123                 }
 124                 else
 125                 {
 126                         mySize.y *= 0.5;
 127                         if (autocvar_hud_panel_healtharmor_flip)
 128                                 health_offset.y = mySize.y;
 129                         else
 130                                 armor_offset.y = mySize.y;
 131                 }
 132
 133                 bool health_baralign, armor_baralign, fuel_baralign;
 134                 bool health_iconalign, armor_iconalign;
 135                 if (autocvar_hud_panel_healtharmor_flip)
 136                 {
 137                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
 138                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
 139                         fuel_baralign = health_baralign;
 140                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
 141                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
 142                 }
 143                 else
 144                 {
 145                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
 146                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
 147                         fuel_baralign = armor_baralign;
 148                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
 149                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
 150                 }
 151
 152                 //if(health)
 153                 {
 154                         if(autocvar_hud_panel_healtharmor_progressbar)
 155                         {
 156                                 float p_health, pain_health_alpha;
 157                                 p_health = health;
 158                                 pain_health_alpha = 1;
 159                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 160                                 {
 161                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
 162                                         {
 163                                                 if (fabs(prev_health - health) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
 164                                                 {
 165                                                         if (time - old_p_healthtime < 1)
 166                                                                 old_p_health = prev_p_health;
 167                                                         else
 168                                                                 old_p_health = prev_health;
 169                                                         old_p_healthtime = time;
 170                                                 }
 171                                                 if (time - old_p_healthtime < 1)
 172                                                 {
 173                                                         p_health += (old_p_health - health) * (1 - (time - old_p_healthtime));
 174                                                         prev_p_health = p_health;
 175                                                 }
 176                                         }
 177                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
 178                                         {
 179                                                 if (prev_health - health >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
 180                                                 {
 181                                                         if (time - health_damagetime >= 1)
 182                                                                 health_beforedamage = prev_health;
 183                                                         health_damagetime = time;
 184                                                 }
 185                                                 if (time - health_damagetime < 1)
 186                                                 {
 187                                                         float health_damagealpha = 1 - (time - health_damagetime)*(time - health_damagetime);
 188                                                         HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, health_beforedamage/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * health_damagealpha, DRAWFLAG_NORMAL);
 189                                                 }
 190                                         }
 191                                         prev_health = health;
 192
 193                                         if (health <= autocvar_hud_panel_healtharmor_progressbar_gfx_lowhealth)
 194                                         {
 195                                                 float BLINK_FACTOR = 0.15;
 196                                                 float BLINK_BASE = 0.85;
 197                                                 float BLINK_FREQ = 9;
 198                                                 pain_health_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
 199                                         }
 200                                 }
 201                                 HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, p_health/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * pain_health_alpha, DRAWFLAG_NORMAL);
 202                         }
 203                         if(autocvar_hud_panel_healtharmor_text)
 204                                 DrawNumIcon(pos + health_offset, mySize, health, "health", is_vertical, health_iconalign, HUD_Get_Num_Color(health, maxhealth), 1);
 205                 }
 206
 207                 if(armor)
 208                 {
 209                         if(autocvar_hud_panel_healtharmor_progressbar)
 210                         {
 211                                 float p_armor;
 212                                 p_armor = armor;
 213                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 214                                 {
 215                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
 216                                         {
 217                                                 if (fabs(prev_armor - armor) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
 218                                                 {
 219                                                         if (time - old_p_armortime < 1)
 220                                                                 old_p_armor = prev_p_armor;
 221                                                         else
 222                                                                 old_p_armor = prev_armor;
 223                                                         old_p_armortime = time;
 224                                                 }
 225                                                 if (time - old_p_armortime < 1)
 226                                                 {
 227                                                         p_armor += (old_p_armor - armor) * (1 - (time - old_p_armortime));
 228                                                         prev_p_armor = p_armor;
 229                                                 }
 230                                         }
 231                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
 232                                         {
 233                                                 if (prev_armor - armor >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
 234                                                 {
 235                                                         if (time - armor_damagetime >= 1)
 236                                                                 armor_beforedamage = prev_armor;
 237                                                         armor_damagetime = time;
 238                                                 }
 239                                                 if (time - armor_damagetime < 1)
 240                                                 {
 241                                                         float armor_damagealpha = 1 - (time - armor_damagetime)*(time - armor_damagetime);
 242                                                         HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, armor_beforedamage/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * armor_damagealpha, DRAWFLAG_NORMAL);
 243                                                 }
 244                                         }
 245                                         prev_armor = armor;
 246                                 }
 247                                 HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, p_armor/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 248                         }
 249                         if(autocvar_hud_panel_healtharmor_text)
 250                                 DrawNumIcon(pos + armor_offset, mySize, armor, "armor", is_vertical, armor_iconalign, HUD_Get_Num_Color(armor, maxarmor), 1);
 251                 }
 252
 253                 if(fuel)
 254                 {
 255                         if (is_vertical)
 256                                 mySize.x *= 0.2 / 2; //if vertical always halve x to not cover too much numbers with 3 digits
 257                         else
 258                                 mySize.y *= 0.2;
 259                         if (panel_ar >= 4)
 260                                 mySize.x *= 2; //restore full panel size
 261                         else if (panel_ar < 1/4)
 262                                 mySize.y *= 2; //restore full panel size
 263                         HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", fuel/100, is_vertical, fuel_baralign, autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
 264                 }
 265         }
 266
 267         draw_endBoldFont();
 268 }