qcsrc/client/hud/panel/healtharmor.qc

   1 #include "healtharmor.qh"
   2
   3 #include <client/defs.qh>
   4 #include <client/miscfunctions.qh>
   5
   6 #include <common/deathtypes/all.qh>
   7
   8 // Health/armor (#3)
   9
  10 void HUD_HealthArmor()
  11 {
  12         int armor, health, fuel;
  13         if(!autocvar__hud_configure)
  14         {
  15                 if((!autocvar_hud_panel_healtharmor) || (spectatee_status == -1))
  16                         return;
  17                 if(hud != HUD_NORMAL) return;
  18
  19                 health = STAT(HEALTH);
  20                 if(health <= 0)
  21                 {
  22                         health = 0;
  23                         prev_health = -1;
  24                         if(autocvar_hud_panel_healtharmor_hide_ondeath)
  25                                 return;
  26                 }
  27                 armor = STAT(ARMOR);
  28
  29                 // code to check for spectatee_status changes is in ENT_CLIENT_CLIENTDATA
  30                 // prev_p_health and prev_health can be set to -1 there
  31
  32                 if (prev_p_health == -1)
  33                 {
  34                         // no effect
  35                         health_beforedamage = 0;
  36                         armor_beforedamage = 0;
  37                         health_damagetime = 0;
  38                         armor_damagetime = 0;
  39                         prev_health = health;
  40                         prev_armor = armor;
  41                         old_p_health = health;
  42                         old_p_armor = armor;
  43                         prev_p_health = health;
  44                         prev_p_armor = armor;
  45                 }
  46                 else if (prev_health == -1)
  47                 {
  48                         //start the load effect
  49                         health_damagetime = 0;
  50                         armor_damagetime = 0;
  51                         prev_health = 0;
  52                         prev_armor = 0;
  53                 }
  54                 fuel = STAT(FUEL);
  55         }
  56         else
  57         {
  58                 health = 150;
  59                 armor = 75;
  60                 fuel = 20;
  61         }
  62
  63         HUD_Panel_LoadCvars();
  64
  65         draw_beginBoldFont();
  66
  67         vector pos, mySize;
  68         pos = panel_pos;
  69         mySize = panel_size;
  70
  71         if (autocvar_hud_panel_healtharmor_dynamichud)
  72                 HUD_Scale_Enable();
  73         else
  74                 HUD_Scale_Disable();
  75         HUD_Panel_DrawBg();
  76         if(panel_bg_padding)
  77         {
  78                 pos += '1 1 0' * panel_bg_padding;
  79                 mySize -= '2 2 0' * panel_bg_padding;
  80         }
  81
  82         int baralign = autocvar_hud_panel_healtharmor_baralign;
  83         int iconalign = autocvar_hud_panel_healtharmor_iconalign;
  84
  85         int maxhealth = autocvar_hud_panel_healtharmor_maxhealth;
  86         int maxarmor = autocvar_hud_panel_healtharmor_maxarmor;
  87         if(autocvar_hud_panel_healtharmor_combined) // combined health and armor display
  88         {
  89                 vector v;
  90                 v = healtharmor_maxdamage(health, armor, armorblockpercent, DEATH_WEAPON.m_id);
  91
  92                 float hp = floor(v.x + 1);
  93
  94                 float maxtotal = maxhealth + maxarmor;
  95                 string biggercount;
  96                 if(v.z) // NOT fully armored
  97                 {
  98                         biggercount = "health";
  99                         if(autocvar_hud_panel_healtharmor_progressbar)
 100                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_health, hp/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 101                         if(armor && autocvar_hud_panel_healtharmor_text)
 102                                 drawpic_aspect_skin(pos + eX * mySize.x - eX * 0.5 * mySize.y, "armor", '0.5 0.5 0' * mySize.y, '1 1 1', panel_fg_alpha * armor / health, DRAWFLAG_NORMAL);
 103                 }
 104                 else
 105                 {
 106                         biggercount = "armor";
 107                         if(autocvar_hud_panel_healtharmor_progressbar)
 108                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, hp/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 109                         if(health && autocvar_hud_panel_healtharmor_text)
 110                                 drawpic_aspect_skin(pos + eX * mySize.x - eX * 0.5 * mySize.y, "health", '0.5 0.5 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 111                 }
 112                 if(autocvar_hud_panel_healtharmor_text)
 113                         DrawNumIcon(pos, mySize, hp, biggercount, 0, iconalign, HUD_Get_Num_Color(hp, maxtotal), 1);
 114
 115                 if(fuel)
 116                         HUD_Panel_DrawProgressBar(pos, vec2(mySize.x, 0.2 * mySize.y), "progressbar", fuel/100, 0, (baralign == 1 || baralign == 3), autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
 117         }
 118         else
 119         {
 120                 float panel_ar = mySize.x/mySize.y;
 121                 bool is_vertical = (panel_ar < 1);
 122                 vector health_offset = '0 0 0', armor_offset = '0 0 0';
 123                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
 124                 {
 125                         mySize.x *= 0.5;
 126                         if (autocvar_hud_panel_healtharmor_flip)
 127                                 health_offset.x = mySize.x;
 128                         else
 129                                 armor_offset.x = mySize.x;
 130                 }
 131                 else
 132                 {
 133                         mySize.y *= 0.5;
 134                         if (autocvar_hud_panel_healtharmor_flip)
 135                                 health_offset.y = mySize.y;
 136                         else
 137                                 armor_offset.y = mySize.y;
 138                 }
 139
 140                 bool health_baralign, armor_baralign, fuel_baralign;
 141                 bool health_iconalign, armor_iconalign;
 142                 if (autocvar_hud_panel_healtharmor_flip)
 143                 {
 144                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
 145                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
 146                         fuel_baralign = health_baralign;
 147                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
 148                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
 149                 }
 150                 else
 151                 {
 152                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
 153                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
 154                         fuel_baralign = armor_baralign;
 155                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
 156                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
 157                 }
 158
 159                 //if(health)
 160                 {
 161                         if(autocvar_hud_panel_healtharmor_progressbar)
 162                         {
 163                                 float p_health, pain_health_alpha;
 164                                 p_health = health;
 165                                 pain_health_alpha = 1;
 166                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 167                                 {
 168                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
 169                                         {
 170                                                 if (fabs(prev_health - health) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
 171                                                 {
 172                                                         if (time - old_p_healthtime < 1)
 173                                                                 old_p_health = prev_p_health;
 174                                                         else
 175                                                                 old_p_health = prev_health;
 176                                                         old_p_healthtime = time;
 177                                                 }
 178                                                 if (time - old_p_healthtime < 1)
 179                                                 {
 180                                                         p_health += (old_p_health - health) * (1 - (time - old_p_healthtime));
 181                                                         prev_p_health = p_health;
 182                                                 }
 183                                         }
 184                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
 185                                         {
 186                                                 if (prev_health - health >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
 187                                                 {
 188                                                         if (time - health_damagetime >= 1)
 189                                                                 health_beforedamage = prev_health;
 190                                                         health_damagetime = time;
 191                                                 }
 192                                                 if (time - health_damagetime < 1)
 193                                                 {
 194                                                         float health_damagealpha = 1 - (time - health_damagetime)*(time - health_damagetime);
 195                                                         HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, health_beforedamage/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * health_damagealpha, DRAWFLAG_NORMAL);
 196                                                 }
 197                                         }
 198                                         prev_health = health;
 199
 200                                         if (health <= autocvar_hud_panel_healtharmor_progressbar_gfx_lowhealth)
 201                                         {
 202                                                 float BLINK_FACTOR = 0.15;
 203                                                 float BLINK_BASE = 0.85;
 204                                                 float BLINK_FREQ = 9;
 205                                                 pain_health_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
 206                                         }
 207                                 }
 208                                 HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, p_health/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * pain_health_alpha, DRAWFLAG_NORMAL);
 209                         }
 210                         if(autocvar_hud_panel_healtharmor_text)
 211                                 DrawNumIcon(pos + health_offset, mySize, health, "health", is_vertical, health_iconalign, HUD_Get_Num_Color(health, maxhealth), 1);
 212                 }
 213
 214                 //if(armor)
 215                 {
 216                         float p_armor = armor;
 217                         if(autocvar_hud_panel_healtharmor_progressbar)
 218                         {
 219                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 220                                 {
 221                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
 222                                         {
 223                                                 if (fabs(prev_armor - armor) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
 224                                                 {
 225                                                         if (time - old_p_armortime < 1)
 226                                                                 old_p_armor = prev_p_armor;
 227                                                         else
 228                                                                 old_p_armor = prev_armor;
 229                                                         old_p_armortime = time;
 230                                                 }
 231                                                 if (time - old_p_armortime < 1)
 232                                                 {
 233                                                         p_armor += (old_p_armor - armor) * (1 - (time - old_p_armortime));
 234                                                         prev_p_armor = p_armor;
 235                                                 }
 236                                         }
 237                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
 238                                         {
 239                                                 if (prev_armor - armor >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
 240                                                 {
 241                                                         if (time - armor_damagetime >= 1)
 242                                                                 armor_beforedamage = prev_armor;
 243                                                         armor_damagetime = time;
 244                                                 }
 245                                                 if (time - armor_damagetime < 1)
 246                                                 {
 247                                                         float armor_damagealpha = 1 - (time - armor_damagetime)*(time - armor_damagetime);
 248                                                         HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, armor_beforedamage/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * armor_damagealpha, DRAWFLAG_NORMAL);
 249                                                 }
 250                                         }
 251                                         prev_armor = armor;
 252                                 }
 253                                 if(p_armor)
 254                                         HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, p_armor/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 255                         }
 256                         if(!autocvar_hud_panel_healtharmor_progressbar || p_armor)
 257                         if(autocvar_hud_panel_healtharmor_text)
 258                                 DrawNumIcon(pos + armor_offset, mySize, armor, "armor", is_vertical, armor_iconalign, HUD_Get_Num_Color(armor, maxarmor), 1);
 259                 }
 260
 261                 if(fuel)
 262                 {
 263                         if (is_vertical)
 264                                 mySize.x *= 0.2 / 2; //if vertical always halve x to not cover too much numbers with 3 digits
 265                         else
 266                                 mySize.y *= 0.2;
 267                         if (panel_ar >= 4)
 268                                 mySize.x *= 2; //restore full panel size
 269                         else if (panel_ar < 1/4)
 270                                 mySize.y *= 2; //restore full panel size
 271                         HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", fuel/100, is_vertical, fuel_baralign, autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
 272                 }
 273         }
 274
 275         draw_endBoldFont();
 276 }