qcsrc/client/hud/panel/infomessages.qc

   1 #include "infomessages.qh"
   2
   3 #include <client/autocvars.qh>
   4 #include <client/miscfunctions.qh>
   5
   6 #include <common/ent_cs.qh>
   7
   8 // Info messages (#14)
   9
  10 void HUD_InfoMessages_Export(int fh)
  11 {
  12         // allow saving cvars that aesthetically change the panel into hud skin files
  13         HUD_Write_Cvar("hud_panel_infomessages_flip");
  14 }
  15
  16 float autocvar_hud_panel_infomessages_group0 = 1;
  17 float autocvar_hud_panel_infomessages_group_fadetime = 0.4;
  18 float autocvar_hud_panel_infomessages_group_time = 6;
  19 const int IMG_COUNT = 1; // number of InfoMessage Groups
  20 float img_fade[IMG_COUNT];
  21 int img_cur_msg[IMG_COUNT];
  22 float img_time[IMG_COUNT];
  23
  24 int img_select(int group_id)
  25 {
  26         float fadetime = max(0.001, autocvar_hud_panel_infomessages_group_fadetime);
  27         if(time > img_time[group_id])
  28         {
  29                 img_fade[group_id] = max(0, img_fade[group_id] - frametime / fadetime);
  30                 if(!img_fade[group_id])
  31                 {
  32                         ++img_cur_msg[group_id];
  33                         img_time[group_id] = floor(time) + autocvar_hud_panel_infomessages_group_time;
  34                 }
  35         }
  36         else
  37                 img_fade[group_id] = min(1, img_fade[group_id] + frametime / fadetime);
  38         return img_cur_msg[group_id];
  39 }
  40
  41 vector InfoMessages_drawstring(string s, vector pos, vector sz, float a, vector fontsize)
  42 {
  43         getWrappedLine_remaining = s;
  44         float offset = 0;
  45         while(getWrappedLine_remaining)
  46         {
  47                 s = getWrappedLine(sz.x - offset, fontsize, stringwidth_colors);
  48                 if(autocvar_hud_panel_infomessages_flip)
  49                         offset = sz.x - stringwidth_colors(s, fontsize) - offset;
  50                 drawcolorcodedstring(pos + eX * offset, s, fontsize, a, DRAWFLAG_NORMAL);
  51                 pos.y += fontsize.y;
  52                 offset = fontsize.x;
  53         }
  54         pos.y += fontsize.y * 0.25;
  55         return pos;
  56 }
  57
  58 #define InfoMessage(s) MACRO_BEGIN \
  59         pos = InfoMessages_drawstring(s, pos, mySize, ((img_curr_group >= 0) ? panel_fg_alpha * img_fade[img_curr_group] : panel_fg_alpha), fontsize); \
  60         img_curr_group = -1; \
  61 MACRO_END
  62
  63 void HUD_InfoMessages()
  64 {
  65         if(!autocvar__hud_configure)
  66         {
  67                 if(!autocvar_hud_panel_infomessages) return;
  68         }
  69
  70         HUD_Panel_LoadCvars();
  71         vector pos, mySize;
  72         pos = panel_pos;
  73         mySize = panel_size;
  74
  75         if (autocvar_hud_panel_infomessages_dynamichud)
  76                 HUD_Scale_Enable();
  77         else
  78                 HUD_Scale_Disable();
  79         HUD_Panel_DrawBg();
  80         if(panel_bg_padding)
  81         {
  82                 pos += '1 1 0' * panel_bg_padding;
  83                 mySize -= '2 2 0' * panel_bg_padding;
  84         }
  85
  86         vector fontsize = '0.2 0.2 0' * mySize.y;
  87         string s;
  88         int img_curr_group = -1;
  89         if(!autocvar__hud_configure)
  90         {
  91                 if(spectatee_status)
  92                 {
  93                         if(spectatee_status == -1)
  94                                 s = _("^1Observing");
  95                         else
  96                                 s = sprintf(_("^1Spectating: ^7%s"), entcs_GetName(current_player));
  97                         InfoMessage(s);
  98
  99                         if(autocvar_hud_panel_infomessages_group0)
 100                         {
 101                                 img_curr_group = 0;
 102                                 switch(img_select(img_curr_group) % 3)
 103                                 {
 104                                         default:
 105                                         case 0:
 106                                                 if(spectatee_status == -1)
 107                                                         s = sprintf(_("^1Press ^3%s^1 to spectate"), getcommandkey(_("primary fire"), "+fire"));
 108                                                 else
 109                                                         s = sprintf(_("^1Press ^3%s^1 or ^3%s^1 for next or previous player"), getcommandkey(_("next weapon"), "weapnext"), getcommandkey(_("previous weapon"), "weapprev"));
 110                                                 break;
 111                                         case 1:
 112                                                 if(spectatee_status == -1)
 113                                                         s = sprintf(_("^1Use ^3%s^1 or ^3%s^1 to change the speed"), getcommandkey(_("next weapon"), "weapnext"), getcommandkey(_("previous weapon"), "weapprev"));
 114                                                 else
 115                                                         s = sprintf(_("^1Press ^3%s^1 to observe, ^3%s^1 to change camera mode"), getcommandkey(_("secondary fire"), "+fire2"), getcommandkey(_("drop weapon"), "dropweapon"));
 116                                                 break;
 117                                         case 2:
 118                                                 s = sprintf(_("^1Press ^3%s^1 for gamemode info"), getcommandkey(_("server info"), "+show_info"));
 119                                                 break;
 120                                 }
 121                                 InfoMessage(s);
 122                         }
 123
 124                         bool mutator_returnvalue = MUTATOR_CALLHOOK(DrawInfoMessages, pos, mySize, img_curr_group);
 125                         pos = M_ARGV(0, vector);
 126                         img_curr_group = M_ARGV(2, int);
 127
 128                         if(!mutator_returnvalue)
 129                         {
 130                                 s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey(_("jump"), "+jump"));
 131                                 InfoMessage(s);
 132                         }
 133                 }
 134
 135                 if (time < STAT(GAMESTARTTIME))
 136                 {
 137                         //we need to ceil, otherwise the countdown would be off by .5 when using round()
 138                         float countdown = ceil(STAT(GAMESTARTTIME) - time);
 139                         s = sprintf(_("^1Game starts in ^3%d^1 seconds"), countdown);
 140                         InfoMessage(s);
 141                 }
 142
 143                 if(warmup_stage)
 144                 {
 145                         s = _("^2Currently in ^1warmup^2 stage!");
 146                         InfoMessage(s);
 147                 }
 148
 149                 string blinkcolor;
 150                 if(time % 1 >= 0.5)
 151                         blinkcolor = "^1";
 152                 else
 153                         blinkcolor = "^3";
 154
 155                 if(ready_waiting && !spectatee_status)
 156                 {
 157                         if(ready_waiting_for_me)
 158                         {
 159                                 if(warmup_stage)
 160                                         s = sprintf(_("%sPress ^3%s%s to end warmup"), blinkcolor, getcommandkey(_("ready"), "ready"), blinkcolor);
 161                                 else
 162                                         s = sprintf(_("%sPress ^3%s%s once you are ready"), blinkcolor, getcommandkey(_("ready"), "ready"), blinkcolor);
 163                         }
 164                         else
 165                         {
 166                                 if(warmup_stage)
 167                                         s = _("^2Waiting for others to ready up to end warmup...");
 168                                 else
 169                                         s = _("^2Waiting for others to ready up...");
 170                         }
 171                         InfoMessage(s);
 172                 }
 173                 else if(warmup_stage && !spectatee_status)
 174                 {
 175                         s = sprintf(_("^2Press ^3%s^2 to end warmup"), getcommandkey(_("ready"), "ready"));
 176                         InfoMessage(s);
 177                 }
 178
 179                 if(teamplay && !spectatee_status && teamnagger)
 180                 {
 181                         float ts_min = 0, ts_max = 0;
 182                         entity tm = teams.sort_next;
 183                         if (tm)
 184                         {
 185                                 for (; tm.sort_next; tm = tm.sort_next)
 186                                 {
 187                                         if(!tm.team_size || tm.team == NUM_SPECTATOR)
 188                                                 continue;
 189                                         if(!ts_min) ts_min = tm.team_size;
 190                                         else ts_min = min(ts_min, tm.team_size);
 191                                         if(!ts_max) ts_max = tm.team_size;
 192                                         else ts_max = max(ts_max, tm.team_size);
 193                                 }
 194                                 if ((ts_max - ts_min) > 1)
 195                                 {
 196                                         s = strcat(blinkcolor, _("Teamnumbers are unbalanced!"));
 197                                         tm = GetTeam(myteam, false);
 198                                         if (tm && tm.team != NUM_SPECTATOR && tm.team_size == ts_max)
 199                                                 s = strcat(s, sprintf(_(" Press ^3%s%s to adjust"), getcommandkey(_("team menu"), "menu_showteamselect"), blinkcolor));
 200                                         InfoMessage(s);
 201                                 }
 202                         }
 203                 }
 204
 205                 if(autocvar_cl_showspectators)
 206                 if(num_spectators)
 207                 //if(spectatee_status != -1)
 208                 {
 209                         s = ((spectatee_status) ? _("^1Spectating this player:") : _("^1Spectating you:"));
 210                         // InfoMessage(s)
 211                         int limit = min(num_spectators, MAX_SPECTATORS);
 212                         for(int i = 0; i < limit; ++i)
 213                         {
 214                                 float slot = spectatorlist[i];
 215                                 if(i == 0)
 216                                         s = strcat(s, " ^7", entcs_GetName(slot));
 217                                 else
 218                                         s = strcat("^7", entcs_GetName(slot));
 219                                 InfoMessage(s);
 220                         }
 221                 }
 222         }
 223         else
 224         {
 225                 InfoMessage(_("^7Press ^3ESC ^7to show HUD options."));
 226                 InfoMessage(_("^3Doubleclick ^7a panel for panel-specific options."));
 227                 InfoMessage(_("^3CTRL ^7to disable collision testing, ^3SHIFT ^7and"));
 228                 InfoMessage(_("^3ALT ^7+ ^3ARROW KEYS ^7for fine adjustments."));
 229         }
 230 }