qcsrc/client/hud/panel/infomessages.qc

   1 // Info messages panel (#14)
   2
   3 #define drawInfoMessage(s) do {                                                                                                                                                                         \
   4         if(autocvar_hud_panel_infomessages_flip)                                                                                                                                                \
   5                 o.x = pos.x + mySize.x - stringwidth(s, true, fontsize);                                                                                                        \
   6         drawcolorcodedstring(o, s, fontsize, a, DRAWFLAG_NORMAL);                                                                                                               \
   7         o.y += fontsize.y;                                                                                                                                                                                              \
   8 } while(0)
   9 void HUD_InfoMessages()
  10 {
  11         if(!autocvar__hud_configure)
  12         {
  13                 if(!autocvar_hud_panel_infomessages) return;
  14         }
  15
  16         HUD_Panel_UpdateCvars();
  17         vector pos, mySize;
  18         pos = panel_pos;
  19         mySize = panel_size;
  20
  21         HUD_Panel_DrawBg(1);
  22         if(panel_bg_padding)
  23         {
  24                 pos += '1 1 0' * panel_bg_padding;
  25                 mySize -= '2 2 0' * panel_bg_padding;
  26         }
  27
  28         // always force 5:1 aspect
  29         vector newSize = '0 0 0';
  30         if(mySize.x/mySize.y > 5)
  31         {
  32                 newSize.x = 5 * mySize.y;
  33                 newSize.y = mySize.y;
  34
  35                 pos.x = pos.x + (mySize.x - newSize.x) / 2;
  36         }
  37         else
  38         {
  39                 newSize.y = 1/5 * mySize.x;
  40                 newSize.x = mySize.x;
  41
  42                 pos.y = pos.y + (mySize.y - newSize.y) / 2;
  43         }
  44
  45         mySize = newSize;
  46         entity tm;
  47         vector o;
  48         o = pos;
  49
  50         vector fontsize;
  51         fontsize = '0.20 0.20 0' * mySize.y;
  52
  53         float a;
  54         a = panel_fg_alpha;
  55
  56         string s;
  57         if(!autocvar__hud_configure)
  58         {
  59                 if(spectatee_status && !intermission)
  60                 {
  61                         a = 1;
  62                         if(spectatee_status == -1)
  63                                 s = _("^1Observing");
  64                         else
  65                                 s = sprintf(_("^1Spectating: ^7%s"), entcs_GetName(current_player));
  66                         drawInfoMessage(s);
  67
  68                         if(spectatee_status == -1)
  69                                 s = sprintf(_("^1Press ^3%s^1 to spectate"), getcommandkey("primary fire", "+fire"));
  70                         else
  71                                 s = sprintf(_("^1Press ^3%s^1 or ^3%s^1 for next or previous player"), getcommandkey("next weapon", "weapnext"), getcommandkey("previous weapon", "weapprev"));
  72                         drawInfoMessage(s);
  73
  74                         if(spectatee_status == -1)
  75                                 s = sprintf(_("^1Use ^3%s^1 or ^3%s^1 to change the speed"), getcommandkey("next weapon", "weapnext"), getcommandkey("previous weapon", "weapprev"));
  76                         else
  77                                 s = sprintf(_("^1Press ^3%s^1 to observe"), getcommandkey("secondary fire", "+fire2"));
  78                         drawInfoMessage(s);
  79
  80                         s = sprintf(_("^1Press ^3%s^1 for gamemode info"), getcommandkey("server info", "+show_info"));
  81                         drawInfoMessage(s);
  82
  83                         if(gametype == MAPINFO_TYPE_LMS)
  84                         {
  85                                 entity sk;
  86                                 sk = playerslots[player_localnum];
  87                                 if(sk.(scores[ps_primary]) >= 666)
  88                                         s = _("^1Match has already begun");
  89                                 else if(sk.(scores[ps_primary]) > 0)
  90                                         s = _("^1You have no more lives left");
  91                                 else
  92                                         s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey("jump", "+jump"));
  93                         }
  94                         else
  95                                 s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey("jump", "+jump"));
  96                         drawInfoMessage(s);
  97
  98                         //show restart countdown:
  99                         if (time < STAT(GAMESTARTTIME)) {
 100                                 float countdown;
 101                                 //we need to ceil, otherwise the countdown would be off by .5 when using round()
 102                                 countdown = ceil(STAT(GAMESTARTTIME) - time);
 103                                 s = sprintf(_("^1Game starts in ^3%d^1 seconds"), countdown);
 104                                 drawcolorcodedstring(o, s, fontsize, a, DRAWFLAG_NORMAL);
 105                                 o.y += fontsize.y;
 106                         }
 107                 }
 108                 if(warmup_stage && !intermission)
 109                 {
 110                         s = _("^2Currently in ^1warmup^2 stage!");
 111                         drawInfoMessage(s);
 112                 }
 113
 114                 string blinkcolor;
 115                 if(time % 1 >= 0.5)
 116                         blinkcolor = "^1";
 117                 else
 118                         blinkcolor = "^3";
 119
 120                 if(ready_waiting && !intermission && !spectatee_status)
 121                 {
 122                         if(ready_waiting_for_me)
 123                         {
 124                                 if(warmup_stage)
 125                                         s = sprintf(_("%sPress ^3%s%s to end warmup"), blinkcolor, getcommandkey("ready", "ready"), blinkcolor);
 126                                 else
 127                                         s = sprintf(_("%sPress ^3%s%s once you are ready"), blinkcolor, getcommandkey("ready", "ready"), blinkcolor);
 128                         }
 129                         else
 130                         {
 131                                 if(warmup_stage)
 132                                         s = _("^2Waiting for others to ready up to end warmup...");
 133                                 else
 134                                         s = _("^2Waiting for others to ready up...");
 135                         }
 136                         drawInfoMessage(s);
 137                 }
 138                 else if(warmup_stage && !intermission && !spectatee_status)
 139                 {
 140                         s = sprintf(_("^2Press ^3%s^2 to end warmup"), getcommandkey("ready", "ready"));
 141                         drawInfoMessage(s);
 142                 }
 143
 144                 if(teamplay && !intermission && !spectatee_status && gametype != MAPINFO_TYPE_CA && teamnagger)
 145                 {
 146                         float ts_min = 0, ts_max = 0;
 147                         tm = teams.sort_next;
 148                         if (tm)
 149                         {
 150                                 for (; tm.sort_next; tm = tm.sort_next)
 151                                 {
 152                                         if(!tm.team_size || tm.team == NUM_SPECTATOR)
 153                                                 continue;
 154                                         if(!ts_min) ts_min = tm.team_size;
 155                                         else ts_min = min(ts_min, tm.team_size);
 156                                         if(!ts_max) ts_max = tm.team_size;
 157                                         else ts_max = max(ts_max, tm.team_size);
 158                                 }
 159                                 if ((ts_max - ts_min) > 1)
 160                                 {
 161                                         s = strcat(blinkcolor, _("Teamnumbers are unbalanced!"));
 162                                         tm = GetTeam(myteam, false);
 163                                         if (tm)
 164                                         if (tm.team != NUM_SPECTATOR)
 165                                         if (tm.team_size == ts_max)
 166                                                 s = strcat(s, sprintf(_(" Press ^3%s%s to adjust"), getcommandkey("team menu", "menu_showteamselect"), blinkcolor));
 167                                         drawInfoMessage(s);
 168                                 }
 169                         }
 170                 }
 171         }
 172         else
 173         {
 174                 s = _("^7Press ^3ESC ^7to show HUD options.");
 175                 drawInfoMessage(s);
 176                 s = _("^3Doubleclick ^7a panel for panel-specific options.");
 177                 drawInfoMessage(s);
 178                 s = _("^3CTRL ^7to disable collision testing, ^3SHIFT ^7and");
 179                 drawInfoMessage(s);
 180                 s = _("^3ALT ^7+ ^3ARROW KEYS ^7for fine adjustments.");
 181                 drawInfoMessage(s);
 182         }
 183 }