qcsrc/client/hud/panel/pressedkeys.qc

   1 #include "pressedkeys.qh"
   2
   3 #include <client/autocvars.qh>
   4 #include <client/defs.qh>
   5 #include <client/miscfunctions.qh>
   6
   7 // Pressed keys (#11)
   8
   9 void HUD_PressedKeys_Export(int fh)
  10 {
  11         // allow saving cvars that aesthetically change the panel into hud skin files
  12         HUD_Write_Cvar("hud_panel_pressedkeys_aspect");
  13         HUD_Write_Cvar("hud_panel_pressedkeys_attack");
  14 }
  15
  16 void HUD_PressedKeys()
  17 {
  18         if(!autocvar__hud_configure)
  19         {
  20                 if(!autocvar_hud_panel_pressedkeys || spectatee_status < 0) return;
  21                 if(spectatee_status <= 0 && autocvar_hud_panel_pressedkeys < 2) return;
  22         }
  23
  24         HUD_Panel_LoadCvars();
  25         vector pos, mySize;
  26         pos = panel_pos;
  27         mySize = panel_size;
  28
  29         if (autocvar_hud_panel_pressedkeys_dynamichud)
  30                 HUD_Scale_Enable();
  31         else
  32                 HUD_Scale_Disable();
  33         HUD_Panel_DrawBg();
  34         if(panel_bg_padding)
  35         {
  36                 pos += '1 1 0' * panel_bg_padding;
  37                 mySize -= '2 2 0' * panel_bg_padding;
  38         }
  39
  40         // force custom aspect
  41         float aspect = autocvar_hud_panel_pressedkeys_aspect;
  42         if(aspect)
  43         {
  44                 vector newSize = '0 0 0';
  45                 if(mySize.x/mySize.y > aspect)
  46                 {
  47                         newSize.x = aspect * mySize.y;
  48                         newSize.y = mySize.y;
  49
  50                         pos.x = pos.x + (mySize.x - newSize.x) / 2;
  51                 }
  52                 else
  53                 {
  54                         newSize.y = 1/aspect * mySize.x;
  55                         newSize.x = mySize.x;
  56
  57                         pos.y = pos.y + (mySize.y - newSize.y) / 2;
  58                 }
  59                 mySize = newSize;
  60         }
  61
  62         vector keysize = vec2(mySize.x / (14/4), mySize.y / (3 - !autocvar_hud_panel_pressedkeys_attack));
  63         int pressedkeys = STAT(PRESSED_KEYS);
  64
  65         if(autocvar_hud_panel_pressedkeys_attack)
  66         {
  67                 drawpic_aspect_skin(pos + eX * (3/4 * keysize.x), ((pressedkeys & KEY_ATCK) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
  68                 drawpic_aspect_skin(pos + eX * (7/4 * keysize.x), ((pressedkeys & KEY_ATCK2) ? "key_atck2_inv.tga" : "key_atck2.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
  69                 pos.y += keysize.y;
  70         }
  71
  72         drawpic_aspect_skin(pos, ((pressedkeys & KEY_CROUCH) ? "key_crouch_inv.tga" : "key_crouch.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
  73         drawpic_aspect_skin(pos + eX * (5/4 * keysize.x), ((pressedkeys & KEY_FORWARD) ? "key_forward_inv.tga" : "key_forward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
  74         drawpic_aspect_skin(pos + eX * (10/4 * keysize.x), ((pressedkeys & KEY_JUMP) ? "key_jump_inv.tga" : "key_jump.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
  75         pos.y += keysize.y;
  76         drawpic_aspect_skin(pos + eX * (1/4 * keysize.x), ((pressedkeys & KEY_LEFT) ? "key_left_inv.tga" : "key_left.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
  77         drawpic_aspect_skin(pos + eX * (5/4 * keysize.x), ((pressedkeys & KEY_BACKWARD) ? "key_backward_inv.tga" : "key_backward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
  78         drawpic_aspect_skin(pos + eX * (9/4 * keysize.x), ((pressedkeys & KEY_RIGHT) ? "key_right_inv.tga" : "key_right.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
  79 }