qcsrc/client/hud/panel/quickmenu.qc

   1 #include "quickmenu.qh"
   2
   3 #include <client/autocvars.qh>
   4 #include <client/defs.qh>
   5 #include <client/miscfunctions.qh>
   6 #include <common/ent_cs.qh>
   7 #include <common/minigames/cl_minigames.qh>
   8 #include <client/hud/_mod.qh>
   9 #include <client/mapvoting.qh>
  10
  11 // QuickMenu (#23)
  12
  13 // QUICKMENU_MAXLINES must be <= 10
  14 const int QUICKMENU_MAXLINES = 10;
  15 // visible entries are loaded from QuickMenu_Buffer into QuickMenu_Page_* arrays
  16 string QuickMenu_Page_Command[QUICKMENU_MAXLINES];
  17 string QuickMenu_Page_Description[QUICKMENU_MAXLINES];
  18 int QuickMenu_Page_Command_Type[QUICKMENU_MAXLINES];
  19 int QuickMenu_Page_Entries;
  20 int QuickMenu_Page;
  21 int QuickMenu_Page_ActivatedEntry = -1;
  22 bool QuickMenu_Page_ActivatedEntry_Close;
  23 float QuickMenu_Page_ActivatedEntry_Time;
  24 bool QuickMenu_IsLastPage;
  25 // all the entries are loaded into QuickMenu_Buffer
  26 // each entry (submenu or command) is composed of 2 entries
  27 const int QUICKMENU_MAXENTRIES = 256;
  28 const int QUICKMENU_BUFFER_MAXENTRIES = 2 * QUICKMENU_MAXENTRIES;
  29 int QuickMenu_Buffer = -1;
  30 int QuickMenu_Buffer_Size;
  31 int QuickMenu_Buffer_Index;
  32 string QuickMenu_CurrentSubMenu;
  33 float QuickMenu_TimeOut;
  34
  35 // QuickMenu_Buffer are labeled with these tags
  36 #define QM_TAG_TITLE "T"
  37 #define QM_TAG_SUBMENU "S"
  38 #define QM_TAG_COMMAND "C"
  39 #define QM_TAG_PLCOMMAND "P"
  40
  41 #define QuickMenu_Buffer_Set(tag, string) bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat(tag, string))
  42 #define QuickMenu_Buffer_Get() bufstr_get(QuickMenu_Buffer, QuickMenu_Buffer_Index)
  43
  44 // if s1 is not empty s will be displayed as command otherwise as submenu
  45 void QuickMenu_Page_LoadEntry(int i, string s, string s1)
  46 {
  47         TC(int, i);
  48         //LOG_INFOF("^xc80 entry %d: %s, %s\n", i, s, s1);
  49         strcpy(QuickMenu_Page_Description[i], s);
  50         strcpy(QuickMenu_Page_Command[i], s1);
  51 }
  52
  53 void QuickMenu_Page_ClearEntry(int i)
  54 {
  55         TC(int, i);
  56         strfree(QuickMenu_Page_Description[i]);
  57         strfree(QuickMenu_Page_Command[i]);
  58         QuickMenu_Page_Command_Type[i] = 0;
  59 }
  60
  61 bool HUD_QuickMenu_Forbidden()
  62 {
  63         return (mv_active
  64                 || (hud_configure_prev && hud_configure_prev != -1)
  65                 || HUD_MinigameMenu_IsOpened()
  66                 || (QuickMenu_TimeOut && time > QuickMenu_TimeOut));
  67 }
  68
  69 // returns true if succeded, false otherwise
  70 bool QuickMenu_Open(string mode, string submenu, string file)
  71 {
  72         QuickMenu_TimeOut = 0;
  73         if (HUD_QuickMenu_Forbidden())
  74                 return false;
  75
  76         int fh = -1;
  77         string s;
  78
  79         if(mode == "")
  80         {
  81                 if(file == "" || file == "0")
  82                         mode = "default";
  83                 else
  84                         mode = "file";
  85         }
  86
  87         if(mode == "file")
  88         {
  89                 if(file == "" || file == "0")
  90                         LOG_INFO("No file name is set in hud_panel_quickmenu_file, loading default quickmenu");
  91                 else
  92                 {
  93                         fh = fopen(file, FILE_READ);
  94                         if(fh < 0)
  95                                 LOG_INFOF("Couldn't open file \"%s\", loading default quickmenu", file);
  96                 }
  97                 if(fh < 0)
  98                         mode = "default";
  99         }
 100
 101         if(mode == "default")
 102         {
 103                 QuickMenu_Buffer = buf_create();
 104                 if(QuickMenu_Buffer < 0)
 105                         return false;
 106
 107                 QuickMenu_Default(submenu);
 108         }
 109         else if(mode == "file")
 110         {
 111                 QuickMenu_Buffer = buf_create();
 112                 if(QuickMenu_Buffer < 0)
 113                 {
 114                         fclose(fh);
 115                         return false;
 116                 }
 117
 118                 QuickMenu_Buffer_Size = 0;
 119                 while((s = fgets(fh)) && QuickMenu_Buffer_Size < QUICKMENU_BUFFER_MAXENTRIES)
 120                 {
 121                         // first skip invalid entries, so we don't check them anymore
 122                         int argc;
 123                         argc = tokenize_console(s);
 124                         if(argc == 0 || argv(0) == "")
 125                                 continue;
 126                         if(argc == 1)
 127                                 QuickMenu_Buffer_Set(QM_TAG_SUBMENU, argv(0));
 128                         else if(argc == 2)
 129                         {
 130                                 if(argv(1) == "")
 131                                         continue;
 132                                 QuickMenu_Buffer_Set(QM_TAG_TITLE, argv(0));
 133                                 ++QuickMenu_Buffer_Size;
 134                                 QuickMenu_Buffer_Set(QM_TAG_COMMAND, argv(1));
 135                         }
 136                         else if(argc == 3)
 137                         {
 138                                 // check for special keywords
 139                                 float teamplayers = 0, without_me = 0;
 140                                 switch(argv(2))
 141                                 {
 142                                         case "ALLPLAYERS_BUT_ME":               without_me = 1; // fall through
 143                                         case "ALLPLAYERS":                              teamplayers = 0; break;
 144                                         case "OWNTEAMPLAYERS_BUT_ME":   without_me = 1; // fall through
 145                                         case "OWNTEAMPLAYERS":                  teamplayers = 1; break;
 146                                         case "ENEMYTEAMPLAYERS":                teamplayers = 2; break;
 147                                         default: continue;
 148                                 }
 149
 150                                 if(QuickMenu_Buffer_Size + 3 < QUICKMENU_BUFFER_MAXENTRIES)
 151                                 {
 152                                         QuickMenu_Buffer_Set(QM_TAG_SUBMENU, argv(0));
 153                                         ++QuickMenu_Buffer_Size;
 154                                         QuickMenu_Buffer_Set(QM_TAG_TITLE, strcat(ftos(teamplayers), ftos(without_me))); // put PLCOMMAND arguments in the title string
 155                                         ++QuickMenu_Buffer_Size;
 156                                         QuickMenu_Buffer_Set(QM_TAG_PLCOMMAND, argv(1));
 157                                         ++QuickMenu_Buffer_Size;
 158                                         QuickMenu_Buffer_Set(QM_TAG_SUBMENU, argv(0));
 159                                 }
 160                         }
 161                         ++QuickMenu_Buffer_Size;
 162                 }
 163                 fclose(fh);
 164         }
 165         else
 166         {
 167                 LOG_WARNF("Unrecognized mode %s", mode);
 168                 return false;
 169         }
 170
 171         if (QuickMenu_Buffer_Size <= 0)
 172         {
 173                 buf_del(QuickMenu_Buffer);
 174                 QuickMenu_Buffer = -1;
 175                 return false;
 176         }
 177
 178         if(mode == "file")
 179                 QuickMenu_Page_Load(submenu, 0);
 180         else
 181                 QuickMenu_Page_Load("", 0);
 182
 183         hudShiftState = 0;
 184
 185         QuickMenu_TimeOut = ((autocvar_hud_panel_quickmenu_time > 0) ? time + autocvar_hud_panel_quickmenu_time : 0);
 186         return true;
 187 }
 188
 189 void QuickMenu_Buffer_Close()
 190 {
 191         if (QuickMenu_Buffer >= 0)
 192         {
 193                 buf_del(QuickMenu_Buffer);
 194                 QuickMenu_Buffer = -1;
 195                 QuickMenu_Buffer_Size = 0;
 196         }
 197 }
 198
 199 void QuickMenu_Close()
 200 {
 201         strfree(QuickMenu_CurrentSubMenu);
 202         int i;
 203         for (i = 0; i < QUICKMENU_MAXLINES; ++i)
 204                 QuickMenu_Page_ClearEntry(i);
 205         QuickMenu_Page_Entries = 0;
 206         mouseClicked = 0;
 207         prevMouseClicked = 0;
 208         QuickMenu_Buffer_Close();
 209 }
 210
 211 // It assumes submenu open tag is already detected
 212 void QuickMenu_skip_submenu(string submenu)
 213 {
 214         string z_submenu = string_null; strcpy(z_submenu, submenu);
 215         for(++QuickMenu_Buffer_Index ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 216         {
 217                 string s = QuickMenu_Buffer_Get();
 218                 if(substring(s, 0, 1) != QM_TAG_SUBMENU)
 219                         continue;
 220                 if(substring(s, 1, -1) == z_submenu) // submenu end
 221                         break;
 222                 QuickMenu_skip_submenu(substring(s, 1, -1));
 223         }
 224         strfree(z_submenu);
 225 }
 226
 227 bool QuickMenu_IsOpened()
 228 {
 229         return (QuickMenu_Page_Entries > 0);
 230 }
 231
 232 bool HUD_Quickmenu_PlayerListEntries_Create(string cmd, int teamplayers, bool without_me)
 233 {
 234         TC(int, teamplayers); TC(bool, without_me);
 235         int i;
 236         for(i = 0; i < QUICKMENU_MAXLINES; ++i)
 237                 QuickMenu_Page_ClearEntry(i);
 238         QuickMenu_Buffer_Close();
 239
 240         QuickMenu_Buffer = buf_create();
 241         if(QuickMenu_Buffer < 0)
 242                 return false;
 243
 244         HUD_Quickmenu_PlayerListEntries(cmd, teamplayers, without_me);
 245
 246         if(QuickMenu_Buffer_Size <= 0)
 247         {
 248                 buf_del(QuickMenu_Buffer);
 249                 QuickMenu_Buffer = -1;
 250                 return false;
 251         }
 252         return true;
 253 }
 254
 255 // new_page 0 means page 0, new_page != 0 means next page
 256 int QuickMenu_Buffer_Index_Prev;
 257 bool QuickMenu_Page_Load(string target_submenu, bool new_page)
 258 {
 259         TC(bool, new_page);
 260         string s = string_null, cmd = string_null, z_submenu;
 261
 262         if (new_page == 0)
 263                 QuickMenu_Page = 0;
 264         else
 265                 ++QuickMenu_Page;
 266
 267         z_submenu = strzone(target_submenu);
 268         strcpy(QuickMenu_CurrentSubMenu, z_submenu);
 269
 270         QuickMenu_IsLastPage = true;
 271         QuickMenu_Page_Entries = 0;
 272
 273         QuickMenu_Buffer_Index = 0;
 274         if (z_submenu != "")
 275         {
 276                 // skip everything until the submenu open tag is found
 277                 for( ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 278                 {
 279                         s = QuickMenu_Buffer_Get();
 280                         if(substring(s, 0, 1) == QM_TAG_SUBMENU && substring(s, 1, -1) == z_submenu)
 281                         {
 282                                 //LOG_INFOF("^3 beginning of %s\n", z_submenu);
 283                                 ++QuickMenu_Buffer_Index;
 284                                 break; // target_submenu found!
 285                         }
 286                         //LOG_INFOF("^1 skipping %s\n", s);
 287                 }
 288                 if(QuickMenu_Buffer_Index == QuickMenu_Buffer_Size)
 289                         LOG_WARNF("Couldn't find submenu \"%s\"", z_submenu);
 290         }
 291
 292         // only the last page can contain up to QUICKMENU_MAXLINES entries
 293         // the other ones contain only (QUICKMENU_MAXLINES - 2) entries
 294         // so that the panel can show an empty row and "Continue..."
 295         float first_entry = QuickMenu_Page * (QUICKMENU_MAXLINES - 2);
 296         int entry_num = 0; // counts entries in target_submenu
 297         for( ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 298         {
 299                 s = QuickMenu_Buffer_Get();
 300
 301                 if(z_submenu != "" && substring(s, 1, -1) == z_submenu)
 302                 {
 303                         //LOG_INFOF("^3 end of %s\n", z_submenu);
 304                         break;
 305                 }
 306
 307                 if(entry_num >= first_entry)
 308                 {
 309                         ++QuickMenu_Page_Entries;
 310                         if(QuickMenu_Page_Entries == QUICKMENU_MAXLINES - 2)
 311                                 QuickMenu_Buffer_Index_Prev = QuickMenu_Buffer_Index;
 312                         else if(QuickMenu_Page_Entries == QUICKMENU_MAXLINES)
 313                         {
 314                                 QuickMenu_Page_ClearEntry(QUICKMENU_MAXLINES - 1);
 315                                 QuickMenu_Buffer_Index = QuickMenu_Buffer_Index_Prev;
 316                                 QuickMenu_IsLastPage = false;
 317                                 break;
 318                         }
 319                 }
 320
 321                 // NOTE: entries are loaded starting from 1, not from 0
 322                 if(substring(s, 0, 1) == QM_TAG_SUBMENU)
 323                 {
 324                         if(entry_num >= first_entry)
 325                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, substring(s, 1, -1), "");
 326                         QuickMenu_skip_submenu(substring(s, 1, -1));
 327                 }
 328                 else if(substring(s, 0, 1) == QM_TAG_TITLE)
 329                 {
 330                         ++QuickMenu_Buffer_Index;
 331                         if(entry_num >= first_entry)
 332                         {
 333                                 cmd = QuickMenu_Buffer_Get();
 334                                 string command_code = substring(cmd, 0, 1);
 335                                 if(command_code == QM_TAG_COMMAND)
 336                                         cmd = substring(cmd, 1, -1);
 337                                 else if(command_code == QM_TAG_PLCOMMAND)
 338                                 {
 339                                         // throw away the current quickmenu buffer and load a new one
 340                                         cmd = substring(cmd, 1, -1);
 341                                         strunzone(z_submenu);
 342                                         if(HUD_Quickmenu_PlayerListEntries_Create(cmd, stof(substring(s, 1, 1)), stof(substring(s, 2, 1))))
 343                                                 return QuickMenu_Page_Load("", 0);
 344                                         QuickMenu_Close();
 345                                         return false;
 346                                 }
 347
 348                                 tokenize_console(cmd);
 349                                 QuickMenu_Page_Command_Type[QuickMenu_Page_Entries] = (argv(1) && argv(0) == "toggle");
 350
 351                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, substring(s, 1, -1), cmd);
 352                         }
 353
 354                 }
 355
 356                 ++entry_num;
 357         }
 358         strunzone(z_submenu);
 359         if (QuickMenu_Page_Entries == 0)
 360         {
 361                 QuickMenu_Close();
 362                 return false;
 363         }
 364         QuickMenu_TimeOut = ((autocvar_hud_panel_quickmenu_time > 0) ? time + autocvar_hud_panel_quickmenu_time : 0);
 365         return true;
 366 }
 367
 368 bool QuickMenu_ActionForNumber(int num)
 369 {
 370         TC(int, num);
 371         if (!QuickMenu_IsLastPage)
 372         {
 373                 if (num < 0 || num >= QUICKMENU_MAXLINES)
 374                         return false;
 375                 if (num == QUICKMENU_MAXLINES - 1)
 376                         return false;
 377                 if (num == 0)
 378                 {
 379                         QuickMenu_Page_Load(QuickMenu_CurrentSubMenu, +1);
 380                         return false;
 381                 }
 382         } else if (num <= 0 || num > QuickMenu_Page_Entries)
 383                 return false;
 384
 385         if (QuickMenu_Page_Command[num] != "")
 386         {
 387                 localcmd(strcat("\n", QuickMenu_Page_Command[num], "\n"));
 388                 QuickMenu_TimeOut = ((autocvar_hud_panel_quickmenu_time > 0) ? time + autocvar_hud_panel_quickmenu_time : 0);
 389                 return true;
 390         }
 391         if (QuickMenu_Page_Description[num] != "")
 392                 QuickMenu_Page_Load(QuickMenu_Page_Description[num], 0);
 393         return false;
 394 }
 395
 396 void QuickMenu_Page_ActiveEntry(int entry_num)
 397 {
 398         TC(int, entry_num);
 399         QuickMenu_Page_ActivatedEntry = entry_num;
 400         QuickMenu_Page_ActivatedEntry_Time = time + 0.1;
 401         if(QuickMenu_Page_Command[QuickMenu_Page_ActivatedEntry])
 402         {
 403                 bool f = QuickMenu_ActionForNumber(QuickMenu_Page_ActivatedEntry);
 404                 // toggle commands don't close the quickmenu
 405                 if(QuickMenu_Page_Command_Type[QuickMenu_Page_ActivatedEntry] == 1)
 406                         QuickMenu_Page_ActivatedEntry_Close = false;
 407                 else
 408                         QuickMenu_Page_ActivatedEntry_Close = (f && !(hudShiftState & S_CTRL));
 409         }
 410         else
 411                 QuickMenu_Page_ActivatedEntry_Close = (!(hudShiftState & S_CTRL));
 412 }
 413
 414 bool QuickMenu_InputEvent(int bInputType, float nPrimary, float nSecondary)
 415 {
 416         TC(int, bInputType);
 417         // we only care for keyboard events
 418         if(bInputType == 2)
 419                 return false;
 420
 421         if(!QuickMenu_IsOpened() || autocvar__hud_configure || mv_active)
 422                 return false;
 423
 424         if(bInputType == 3)
 425         {
 426                 mousepos.x = nPrimary;
 427                 mousepos.y = nSecondary;
 428                 return true;
 429         }
 430
 431         // allow console bind to work
 432         string con_keys = findkeysforcommand("toggleconsole", 0);
 433         int keys = tokenize(con_keys); // findkeysforcommand returns data for this
 434         bool hit_con_bind = false;
 435         int i;
 436         for (i = 0; i < keys; ++i)
 437         {
 438                 if(nPrimary == stof(argv(i)))
 439                         hit_con_bind = true;
 440         }
 441
 442         if(bInputType == 0) {
 443                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 444                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 445                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 446         }
 447         else if(bInputType == 1) {
 448                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 449                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 450                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 451         }
 452
 453         if(nPrimary == K_ESCAPE)
 454         {
 455                 if (bInputType == 1)
 456                         return true;
 457                 QuickMenu_Close();
 458         }
 459         else if(nPrimary >= '0' && nPrimary <= '9')
 460         {
 461                 if (bInputType == 1)
 462                         return true;
 463                 QuickMenu_Page_ActiveEntry(stof(chr2str(nPrimary)));
 464         }
 465         if(nPrimary == K_MOUSE1)
 466         {
 467                 if(bInputType == 0) // key pressed
 468                         mouseClicked |= S_MOUSE1;
 469                 else if(bInputType == 1) // key released
 470                         mouseClicked -= (mouseClicked & S_MOUSE1);
 471         }
 472         else if(nPrimary == K_MOUSE2)
 473         {
 474                 if(bInputType == 0) // key pressed
 475                         mouseClicked |= S_MOUSE2;
 476                 else if(bInputType == 1) // key released
 477                         mouseClicked -= (mouseClicked & S_MOUSE2);
 478         }
 479         else if(hit_con_bind)
 480                 return false;
 481
 482         return true;
 483 }
 484
 485 void QuickMenu_Mouse()
 486 {
 487         if(mv_active) return;
 488
 489         if(!mouseClicked)
 490         if(prevMouseClicked & S_MOUSE2)
 491         {
 492                 QuickMenu_Close();
 493                 return;
 494         }
 495
 496         panel = HUD_PANEL(QUICKMENU);
 497         HUD_Panel_LoadCvars();
 498
 499         if(panel_bg_padding)
 500         {
 501                 panel_pos += '1 1 0' * panel_bg_padding;
 502                 panel_size -= '2 2 0' * panel_bg_padding;
 503         }
 504
 505         float first_entry_pos, entries_height;
 506         vector fontsize;
 507         fontsize = '1 1 0' * (panel_size.y / QUICKMENU_MAXLINES);
 508         first_entry_pos = panel_pos.y + ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y) / 2;
 509         entries_height = panel_size.y - ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y);
 510
 511         if (mousepos.x >= panel_pos.x && mousepos.y >= first_entry_pos && mousepos.x <= panel_pos.x + panel_size.x && mousepos.y <= first_entry_pos + entries_height)
 512         {
 513                 int entry_num = min(QuickMenu_Page_Entries - 1, floor((mousepos.y - first_entry_pos) / fontsize.y));
 514                 if (QuickMenu_IsLastPage || entry_num != QUICKMENU_MAXLINES - 2)
 515                 {
 516                         // recycling panel_pos as entry_pos
 517                         panel_pos.y = first_entry_pos + entry_num * fontsize.y;
 518                         vector color;
 519                         if(mouseClicked & S_MOUSE1)
 520                                 color = '0.5 1 0.5';
 521                         else if(hudShiftState & S_CTRL)
 522                                 color = '1 1 0.3';
 523                         else
 524                                 color = '1 1 1';
 525                         drawfill(panel_pos, vec2(panel_size.x, fontsize.y), color, .2, DRAWFLAG_NORMAL);
 526
 527                         if(!mouseClicked && (prevMouseClicked & S_MOUSE1))
 528                                 QuickMenu_Page_ActiveEntry((entry_num < QUICKMENU_MAXLINES - 1) ? entry_num + 1 : 0);
 529                 }
 530         }
 531 }
 532
 533 void HUD_Quickmenu_DrawEntry(vector pos, string desc, string option, vector fontsize)
 534 {
 535         string entry;
 536         float offset;
 537         float desc_width = panel_size.x;
 538         if(option)
 539         {
 540                 string pic = strcat(hud_skin_path, "/", option);
 541                 if(precache_pic(pic) == "")
 542                         pic = strcat("gfx/hud/default/", option);
 543                 vector option_size = '1 1 0' * fontsize.y * 0.8;
 544                 desc_width -= option_size.x;
 545                 drawpic(pos + vec2(desc_width, (fontsize.y - option_size.y) / 2), pic, option_size, '1 1 1', panel_fg_alpha, DRAWFLAG_ADDITIVE);
 546                 desc_width -= fontsize.x / 4;
 547         }
 548         entry = textShortenToWidth(desc, desc_width, fontsize, stringwidth_colors);
 549         if (autocvar_hud_panel_quickmenu_align > 0)
 550         {
 551                 float real_desc_width = stringwidth_colors(entry, fontsize);
 552                 offset = (desc_width - real_desc_width) * min(autocvar_hud_panel_quickmenu_align, 1);
 553
 554                 if(option)
 555                 {
 556                         // when there's enough room align description regardless the checkbox
 557                         float extra_offset = (panel_size.x - desc_width) * min(autocvar_hud_panel_quickmenu_align, 1);
 558                         if(offset + real_desc_width + extra_offset < desc_width)
 559                                 offset += extra_offset;
 560                         else
 561                                 offset = max(0, desc_width - real_desc_width);
 562                 }
 563                 drawcolorcodedstring(pos + eX * offset, entry, fontsize, panel_fg_alpha, DRAWFLAG_ADDITIVE);
 564         }
 565         else
 566                 drawcolorcodedstring(pos, entry, fontsize, panel_fg_alpha, DRAWFLAG_ADDITIVE);
 567 }
 568
 569 void HUD_QuickMenu()
 570 {
 571         if(!autocvar__hud_configure)
 572         {
 573                 if (!hud_draw_maximized || !QuickMenu_IsOpened())
 574                         return;
 575
 576                 if (HUD_QuickMenu_Forbidden())
 577                 {
 578                         QuickMenu_Close();
 579                         return;
 580                 }
 581         }
 582         else
 583         {
 584                 if(!QuickMenu_IsOpened())
 585                 {
 586                         QuickMenu_Page_Entries = 1;
 587                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Submenu%d"), QuickMenu_Page_Entries), "");
 588                         ++QuickMenu_Page_Entries;
 589                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Submenu%d"), QuickMenu_Page_Entries), "");
 590                         ++QuickMenu_Page_Entries;
 591                         // although real command doesn't matter here, it must not be empty
 592                         // otherwise the entry is displayed like a submenu
 593                         for (; QuickMenu_Page_Entries < QUICKMENU_MAXLINES - 1; ++QuickMenu_Page_Entries)
 594                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Command%d"), QuickMenu_Page_Entries), "-");
 595                         ++QuickMenu_Page_Entries;
 596                         QuickMenu_Page_ClearEntry(QuickMenu_Page_Entries);
 597                         QuickMenu_IsLastPage = false;
 598                 }
 599         }
 600
 601         HUD_Panel_LoadCvars();
 602
 603         HUD_Scale_Disable();
 604         HUD_Panel_DrawBg();
 605
 606         if(panel_bg_padding)
 607         {
 608                 panel_pos += '1 1 0' * panel_bg_padding;
 609                 panel_size -= '2 2 0' * panel_bg_padding;
 610         }
 611
 612         int i;
 613         vector fontsize;
 614         string color;
 615         fontsize = '1 1 0' * (panel_size.y / QUICKMENU_MAXLINES);
 616
 617         if (!QuickMenu_IsLastPage)
 618         {
 619                 color = "^5";
 620                 HUD_Quickmenu_DrawEntry(panel_pos + eY * (panel_size.y - fontsize.y), sprintf("%d: %s%s", 0, color, _("Continue...")), string_null, fontsize);
 621         }
 622         else
 623                 panel_pos.y += ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y) / 2;
 624
 625         for (i = 1; i <= QuickMenu_Page_Entries; ++i) {
 626                 if (QuickMenu_Page_Description[i] == "")
 627                         break;
 628                 string option = string_null;
 629                 if (QuickMenu_Page_Command[i] == "")
 630                         color = "^4";
 631                 else
 632                 {
 633                         color = "^3";
 634                         if(QuickMenu_Page_Command_Type[i] == 1) // toggle command
 635                         {
 636                                 int end = strstrofs(QuickMenu_Page_Command[i], ";", 0);
 637                                 if(end < 0)
 638                                         tokenize_console(QuickMenu_Page_Command[i]);
 639                                 else
 640                                         tokenize_console(substring(QuickMenu_Page_Command[i], 0, end));
 641
 642                                 if(argv(1) && argv(0) == "toggle")
 643                                 {
 644                                         // "enable feature xxx" "toggle xxx" (or "toggle xxx 1 0")
 645                                         // "disable feature xxx" "toggle xxx 0 1"
 646                                         float ON_value = 1, OFF_value = 0;
 647                                         if(argv(2))
 648                                                 ON_value = stof(argv(2));
 649
 650                                         if(argv(3))
 651                                                 OFF_value = stof(argv(3));
 652                                         else
 653                                                 OFF_value = !ON_value;
 654
 655                                         float value = cvar(argv(1));
 656                                         if(value == ON_value)
 657                                                 option = "checkbox_checked";
 658                                         else if(value == OFF_value)
 659                                                 option = "checkbox_empty";
 660                                         else
 661                                                 option = "checkbox_undefined";
 662                                 }
 663                         }
 664                 }
 665                 HUD_Quickmenu_DrawEntry(panel_pos, sprintf("%d: %s%s", i, color, QuickMenu_Page_Description[i]), option, fontsize);
 666
 667                 if(QuickMenu_Page_ActivatedEntry_Time && time < QuickMenu_Page_ActivatedEntry_Time
 668                         && QuickMenu_Page_ActivatedEntry == i)
 669                         drawfill(panel_pos, vec2(panel_size.x, fontsize.y), '0.5 1 0.5', .2, DRAWFLAG_NORMAL);
 670
 671                 panel_pos.y += fontsize.y;
 672         }
 673
 674         if(QuickMenu_Page_ActivatedEntry >= 0 && time >= QuickMenu_Page_ActivatedEntry_Time)
 675         {
 676                 if(!QuickMenu_Page_Command[QuickMenu_Page_ActivatedEntry])
 677                 {
 678                         bool f = QuickMenu_ActionForNumber(QuickMenu_Page_ActivatedEntry);
 679                         if(f && QuickMenu_Page_ActivatedEntry_Close)
 680                                 QuickMenu_Close();
 681                 }
 682                 else if(QuickMenu_Page_ActivatedEntry_Close)
 683                         QuickMenu_Close();
 684                 QuickMenu_Page_ActivatedEntry = -1;
 685                 QuickMenu_Page_ActivatedEntry_Time = 0;
 686         }
 687 }
 688
 689
 690 #define QUICKMENU_SMENU(submenu,eng_submenu) { \
 691         if(target_submenu == eng_submenu && target_submenu_found) \
 692                 return; /* target_submenu entries are now loaded, exit */ \
 693         if(QuickMenu_Buffer_Size < QUICKMENU_BUFFER_MAXENTRIES) \
 694                 QuickMenu_Buffer_Set(QM_TAG_SUBMENU, submenu); \
 695         ++QuickMenu_Buffer_Size; \
 696         if(target_submenu == eng_submenu && !target_submenu_found) { \
 697                 QuickMenu_Buffer_Size = 0; /* enable load of next entries */ \
 698                 target_submenu_found = true; \
 699         } \
 700 }
 701
 702 #define QUICKMENU_ENTRY(title,command) { \
 703         if(QuickMenu_Buffer_Size + 1 < QUICKMENU_BUFFER_MAXENTRIES) \
 704         { \
 705                 QuickMenu_Buffer_Set(QM_TAG_TITLE, title); \
 706                 ++QuickMenu_Buffer_Size; \
 707                 QuickMenu_Buffer_Set(QM_TAG_COMMAND, command); \
 708         } \
 709         ++QuickMenu_Buffer_Size; \
 710 }
 711
 712 #define QUICKMENU_SMENU_PL(submenu,eng_submenu,command,teamplayers,without_me) { \
 713         if(QuickMenu_Buffer_Size + 3 < QUICKMENU_BUFFER_MAXENTRIES) {\
 714                 QUICKMENU_SMENU(submenu,eng_submenu) \
 715                 QuickMenu_Buffer_Set(QM_TAG_TITLE, strcat(ftos(teamplayers), ftos(without_me))); \
 716                 ++QuickMenu_Buffer_Size; \
 717                 QuickMenu_Buffer_Set(QM_TAG_PLCOMMAND, command); \
 718                 ++QuickMenu_Buffer_Size; \
 719                 QUICKMENU_SMENU(submenu,eng_submenu) \
 720         } \
 721 }
 722
 723
 724
 725 // useful to Translate a string inside the Command
 726 #define QUICKMENU_ENTRY_TC(title,command,text,translated_text) {\
 727         if(prvm_language == "en") { \
 728                 tc_title = title; \
 729                 tc_cmd = sprintf(command, text); \
 730         } \
 731         else if(!autocvar_hud_panel_quickmenu_translatecommands || translated_text == text) { \
 732                 tc_title = strcat("(en)", title); \
 733                 tc_cmd = sprintf(command, text); \
 734         } \
 735         else { \
 736                 tc_title = strcat("(", prvm_language, ")", title); \
 737                 tc_cmd = sprintf(command, translated_text); \
 738         } \
 739         QUICKMENU_ENTRY(tc_title, tc_cmd) \
 740 }
 741
 742 void HUD_Quickmenu_PlayerListEntries(string cmd, int teamplayers, bool without_me)
 743 {
 744         TC(int, teamplayers); TC(bool, without_me);
 745         entity pl;
 746         if(teamplayers && !team_count)
 747                 return;
 748
 749         for(pl = players.sort_next; pl; pl = pl.sort_next)
 750         {
 751                 if(teamplayers == 1 && (pl.team != myteam || pl.team == NUM_SPECTATOR)) // only own team players
 752                         continue;
 753                 if(teamplayers == 2 && (pl.team == myteam || pl.team == NUM_SPECTATOR)) // only enemy team players
 754                         continue;
 755                 if(without_me && pl.sv_entnum == player_localnum)
 756                         continue;
 757                 QUICKMENU_ENTRY(entcs_GetName(pl.sv_entnum), sprintf(cmd, entcs_GetName(pl.sv_entnum)))
 758         }
 759
 760         return;
 761 }
 762
 763
 764 // Specifying target_submenu, this function only loads entries inside target_submenu
 765 // NOTE: alternatively we could have loaded the whole default quickmenu and
 766 // then called QuickMenu_Page_Load(target_submenu, 0);
 767 // but this sytem is more reliable since we can always refer to target_submenu
 768 // with the English title even if a translation is active
 769 void QuickMenu_Default(string target_submenu)
 770 {
 771         bool target_submenu_found = false;
 772         if(target_submenu != "")
 773                 QuickMenu_Buffer_Size = QUICKMENU_BUFFER_MAXENTRIES; // forbids load of next entries until target_submenu
 774
 775         string tc_title;
 776         string tc_cmd;
 777
 778         QUICKMENU_SMENU(_("Chat"), "Chat")
 779                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^nice one")), "say %s", ":-) / nice one", CTX(_("QMCMD^:-) / nice one")))
 780                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^good game")), "say %s", "good game", CTX(_("QMCMD^good game")))
 781                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^hi / good luck")), "say %s", "hi / good luck and have fun", CTX(_("QMCMD^hi / good luck and have fun")))
 782                 if(prvm_language != "en")
 783                 QUICKMENU_ENTRY(CTX(_("QMCMD^Send in English")), "toggle hud_panel_quickmenu_translatecommands 0 1; quickmenu; wait; quickmenu default Chat")
 784         QUICKMENU_SMENU(_("Chat"), "Chat")
 785
 786         if(teamplay)
 787         {
 788         QUICKMENU_SMENU(CTX(_("QMCMD^Team chat")), "Team chat")
 789                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^quad soon")), "say_team %s", "quad soon", CTX(_("QMCMD^quad soon")))
 790                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^free item, icon")), "say_team %s; g_waypointsprite_team_here_p", "free item %x^7 (l:%y^7)", CTX(_("QMCMD^free item %x^7 (l:%y^7)")))
 791                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^took item, icon")), "say_team %s; g_waypointsprite_team_here", "took item (l:%l^7)", CTX(_("QMCMD^took item (l:%l^7)")))
 792                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^negative")), "say_team %s", "negative", CTX(_("QMCMD^negative")))
 793                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^positive")), "say_team %s", "positive", CTX(_("QMCMD^positive")))
 794                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^need help, icon")), "say_team %s; g_waypointsprite_team_helpme; cmd voice needhelp", "need help (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^need help (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 795                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^enemy seen, icon")), "say_team %s; g_waypointsprite_team_danger_p; cmd voice incoming", "enemy seen (l:%y^7)", CTX(_("QMCMD^enemy seen (l:%y^7)")))
 796                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^flag seen, icon")), "say_team %s; g_waypointsprite_team_here_p; cmd voice seenflag", "flag seen (l:%y^7)", CTX(_("QMCMD^flag seen (l:%y^7)")))
 797                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^defending, icon")), "say_team %s; g_waypointsprite_team_here", "defending (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^defending (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 798                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^roaming, icon")), "say_team %s; g_waypointsprite_team_here", "roaming (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^roaming (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 799                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^attacking, icon")), "say_team %s; g_waypointsprite_team_here", "attacking (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^attacking (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 800                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^killed flagcarrier, icon")), "say_team %s; g_waypointsprite_team_here_p", "killed flagcarrier (l:%y^7)", CTX(_("QMCMD^killed flagcarrier (l:%y^7)")))
 801                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^dropped flag, icon")), "say_team %s; g_waypointsprite_team_here_d", "dropped flag (l:%d^7)", CTX(_("QMCMD^dropped flag (l:%d^7)")))
 802                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^drop weapon, icon")), "say_team %s; g_waypointsprite_team_here; wait; dropweapon", "dropped gun %w^7 (l:%l^7)", CTX(_("QMCMD^dropped weapon %w^7 (l:%l^7)")))
 803                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^drop flag/key, icon")), "say_team %s; g_waypointsprite_team_here; wait; use", "dropped flag/key %w^7 (l:%l^7)", CTX(_("QMCMD^dropped flag/key %w^7 (l:%l^7)")))
 804         QUICKMENU_SMENU(CTX(_("QMCMD^Team chat")), "Team chat")
 805         }
 806
 807         QUICKMENU_SMENU_PL(CTX(_("QMCMD^Send private message to")), "Send private message to", "commandmode tell \"%s^7\"", 0, 1)
 808
 809         QUICKMENU_SMENU(CTX(_("QMCMD^Settings")), "Settings")
 810                 QUICKMENU_SMENU(CTX(_("QMCMD^View/HUD settings")), "View/HUD settings")
 811                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person view")), "toggle chase_active")
 812                         QUICKMENU_ENTRY(CTX(_("QMCMD^Player models like mine")), "toggle cl_forceplayermodels")
 813                         QUICKMENU_ENTRY(CTX(_("QMCMD^Names above players")), "toggle hud_shownames")
 814                         QUICKMENU_ENTRY(CTX(_("QMCMD^Crosshair per weapon")), "toggle crosshair_per_weapon")
 815                         QUICKMENU_ENTRY(CTX(_("QMCMD^FPS")), "toggle hud_panel_engineinfo")
 816                         QUICKMENU_ENTRY(CTX(_("QMCMD^Net graph")), "toggle shownetgraph")
 817                 QUICKMENU_SMENU(CTX(_("QMCMD^View/HUD settings")), "View/HUD settings")
 818
 819                 QUICKMENU_SMENU(CTX(_("QMCMD^Sound settings")), "Sound settings")
 820                         QUICKMENU_ENTRY(CTX(_("QMCMD^Hit sound")), "toggle cl_hitsound")
 821                         QUICKMENU_ENTRY(CTX(_("QMCMD^Chat sound")), "toggle con_chatsound")
 822                 QUICKMENU_SMENU(CTX(_("QMCMD^Sound settings")), "Sound settings")
 823
 824                 if(spectatee_status > 0)
 825                 {
 826                 QUICKMENU_SMENU(CTX(_("QMCMD^Spectator camera")), "Spectator camera")
 827                         QUICKMENU_ENTRY(CTX(_("QMCMD^1st person")), "chase_active 0; -use")
 828                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person around player")), "chase_active 1; +use")
 829                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person behind")), "chase_active 1; -use")
 830                 QUICKMENU_SMENU(CTX(_("QMCMD^Spectator camera")), "Spectator camera")
 831                 }
 832
 833                 if(spectatee_status == -1)
 834                 {
 835                 QUICKMENU_SMENU(CTX(_("QMCMD^Observer camera")), "Observer camera")
 836                         QUICKMENU_ENTRY(CTX(_("QMCMD^Increase speed")), "weapnext")
 837                         QUICKMENU_ENTRY(CTX(_("QMCMD^Decrease speed")), "weapprev")
 838                         QUICKMENU_ENTRY(CTX(_("QMCMD^Wall collision off")), "+use")
 839                         QUICKMENU_ENTRY(CTX(_("QMCMD^Wall collision on")), "-use")
 840                 QUICKMENU_SMENU(CTX(_("QMCMD^Observer camera")), "Observer camera")
 841                 }
 842
 843                 QUICKMENU_ENTRY(CTX(_("QMCMD^Fullscreen")), "toggle vid_fullscreen; vid_restart")
 844         QUICKMENU_SMENU(CTX(_("QMCMD^Settings")), "Settings")
 845
 846         QUICKMENU_SMENU(CTX(_("QMCMD^Call a vote")), "Call a vote")
 847                 QUICKMENU_ENTRY(CTX(_("QMCMD^Restart the map")), "vcall restart")
 848                 QUICKMENU_ENTRY(CTX(_("QMCMD^End match")), "vcall endmatch")
 849                 if(STAT(TIMELIMIT) > 0)
 850                 {
 851                 QUICKMENU_ENTRY(CTX(_("QMCMD^Reduce match time")), "vcall reducematchtime")
 852                 QUICKMENU_ENTRY(CTX(_("QMCMD^Extend match time")), "vcall extendmatchtime")
 853                 }
 854                 if(teamplay)
 855                 QUICKMENU_ENTRY(CTX(_("QMCMD^Shuffle teams")), "vcall shuffleteams")
 856         QUICKMENU_SMENU(CTX(_("QMCMD^Call a vote")), "Call a vote")
 857
 858         if(target_submenu != "" && !target_submenu_found)
 859         {
 860                 LOG_INFOF("Couldn't find submenu \"%s\"", target_submenu);
 861                 if(prvm_language != "en")
 862                         LOG_INFOF("^3Warning: submenu title must be in English", target_submenu);
 863                 QuickMenu_Buffer_Size = 0;
 864         }
 865 }
 866 #undef QUICKMENU_SMENU
 867 #undef QUICKMENU_ENTRY
 868 #undef QUICKMENU_ENTRY_TC