qcsrc/client/hud/panel/quickmenu.qc

   1 #include "quickmenu.qh"
   2
   3 #include <client/autocvars.qh>
   4 #include <client/defs.qh>
   5 #include <client/miscfunctions.qh>
   6 #include <common/ent_cs.qh>
   7 #include <client/hud/_mod.qh>
   8 #include <client/mapvoting.qh>
   9
  10 // QuickMenu (#23)
  11
  12 // QUICKMENU_MAXLINES must be <= 10
  13 const int QUICKMENU_MAXLINES = 10;
  14 // visible entries are loaded from QuickMenu_Buffer into QuickMenu_Page_* arrays
  15 string QuickMenu_Page_Command[QUICKMENU_MAXLINES];
  16 string QuickMenu_Page_Description[QUICKMENU_MAXLINES];
  17 int QuickMenu_Page_Command_Type[QUICKMENU_MAXLINES];
  18 int QuickMenu_Page_Entries;
  19 int QuickMenu_Page;
  20 int QuickMenu_Page_ActivatedEntry = -1;
  21 bool QuickMenu_Page_ActivatedEntry_Close;
  22 float QuickMenu_Page_ActivatedEntry_Time;
  23 bool QuickMenu_IsLastPage;
  24 // all the entries are loaded into QuickMenu_Buffer
  25 // each entry (submenu or command) is composed of 2 entries
  26 const int QUICKMENU_MAXENTRIES = 256;
  27 const int QUICKMENU_BUFFER_MAXENTRIES = 2 * QUICKMENU_MAXENTRIES;
  28 int QuickMenu_Buffer = -1;
  29 int QuickMenu_Buffer_Size;
  30 int QuickMenu_Buffer_Index;
  31 string QuickMenu_CurrentSubMenu;
  32 float QuickMenu_TimeOut;
  33
  34 // QuickMenu_Buffer are labeled with these tags
  35 #define QM_TAG_TITLE "T"
  36 #define QM_TAG_SUBMENU "S"
  37 #define QM_TAG_COMMAND "C"
  38 #define QM_TAG_PLCOMMAND "P"
  39
  40 #define QuickMenu_Buffer_Set(tag, string) bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat(tag, string))
  41 #define QuickMenu_Buffer_Get() bufstr_get(QuickMenu_Buffer, QuickMenu_Buffer_Index)
  42
  43 // if s1 is not empty s will be displayed as command otherwise as submenu
  44 void QuickMenu_Page_LoadEntry(int i, string s, string s1)
  45 {
  46     TC(int, i);
  47         //LOG_INFOF("^xc80 entry %d: %s, %s\n", i, s, s1);
  48         strcpy(QuickMenu_Page_Description[i], s);
  49         strcpy(QuickMenu_Page_Command[i], s1);
  50 }
  51
  52 void QuickMenu_Page_ClearEntry(int i)
  53 {
  54     TC(int, i);
  55         strfree(QuickMenu_Page_Description[i]);
  56         strfree(QuickMenu_Page_Command[i]);
  57         QuickMenu_Page_Command_Type[i] = 0;
  58 }
  59
  60 bool QuickMenu_Open(string mode, string submenu, string file)
  61 {
  62         int fh = -1;
  63         string s;
  64
  65         if(mode == "")
  66         {
  67                 if(file == "" || file == "0")
  68                         mode = "default";
  69                 else
  70                         mode = "file";
  71         }
  72
  73         if(mode == "file")
  74         {
  75                 if(file == "" || file == "0")
  76                         LOG_INFO("No file name is set in hud_panel_quickmenu_file, loading default quickmenu");
  77                 else
  78                 {
  79                         fh = fopen(file, FILE_READ);
  80                         if(fh < 0)
  81                                 LOG_INFOF("Couldn't open file \"%s\", loading default quickmenu", file);
  82                 }
  83                 if(fh < 0)
  84                         mode = "default";
  85         }
  86
  87         if(mode == "default")
  88         {
  89                 QuickMenu_Buffer = buf_create();
  90                 if(QuickMenu_Buffer < 0)
  91                         return false;
  92
  93                 QuickMenu_Default(submenu);
  94         }
  95         else if(mode == "file")
  96         {
  97                 QuickMenu_Buffer = buf_create();
  98                 if(QuickMenu_Buffer < 0)
  99                 {
 100                         fclose(fh);
 101                         return false;
 102                 }
 103
 104                 QuickMenu_Buffer_Size = 0;
 105                 while((s = fgets(fh)) && QuickMenu_Buffer_Size < QUICKMENU_BUFFER_MAXENTRIES)
 106                 {
 107                         // first skip invalid entries, so we don't check them anymore
 108                         float argc;
 109                         argc = tokenize_console(s);
 110                         if(argc == 0 || argv(0) == "")
 111                                 continue;
 112                         if(argc == 1)
 113                                 QuickMenu_Buffer_Set(QM_TAG_SUBMENU, argv(0));
 114                         else if(argc == 2)
 115                         {
 116                                 if(argv(1) == "")
 117                                         continue;
 118                                 QuickMenu_Buffer_Set(QM_TAG_TITLE, argv(0));
 119                                 ++QuickMenu_Buffer_Size;
 120                                 QuickMenu_Buffer_Set(QM_TAG_COMMAND, argv(1));
 121                         }
 122                         else if(argc == 3)
 123                         {
 124                                 // check for special keywords
 125                                 float teamplayers = 0, without_me = 0;
 126                                 switch(argv(2))
 127                                 {
 128                                         case "ALLPLAYERS_BUT_ME":               without_me = 1; // fall through
 129                                         case "ALLPLAYERS":                              teamplayers = 0; break;
 130                                         case "OWNTEAMPLAYERS_BUT_ME":   without_me = 1; // fall through
 131                                         case "OWNTEAMPLAYERS":                  teamplayers = 1; break;
 132                                         case "ENEMYTEAMPLAYERS":                teamplayers = 2; break;
 133                                         default: continue;
 134                                 }
 135
 136                                 if(QuickMenu_Buffer_Size + 3 < QUICKMENU_BUFFER_MAXENTRIES)
 137                                 {
 138                                         QuickMenu_Buffer_Set(QM_TAG_SUBMENU, argv(0));
 139                                         ++QuickMenu_Buffer_Size;
 140                                         QuickMenu_Buffer_Set(QM_TAG_TITLE, strcat(ftos(teamplayers), ftos(without_me))); // put PLCOMMAND arguments in the title string
 141                                         ++QuickMenu_Buffer_Size;
 142                                         QuickMenu_Buffer_Set(QM_TAG_PLCOMMAND, argv(1));
 143                                         ++QuickMenu_Buffer_Size;
 144                                         QuickMenu_Buffer_Set(QM_TAG_SUBMENU, argv(0));
 145                                 }
 146                         }
 147                         ++QuickMenu_Buffer_Size;
 148                 }
 149                 fclose(fh);
 150         }
 151         else
 152         {
 153                 LOG_WARNF("Unrecognized mode %s", mode);
 154                 return false;
 155         }
 156
 157         if (QuickMenu_Buffer_Size <= 0)
 158         {
 159                 buf_del(QuickMenu_Buffer);
 160                 QuickMenu_Buffer = -1;
 161                 return false;
 162         }
 163
 164         if(mode == "file")
 165                 QuickMenu_Page_Load(submenu, 0);
 166         else
 167                 QuickMenu_Page_Load("", 0);
 168
 169         hud_panel_quickmenu = 1;
 170         hudShiftState = 0;
 171
 172         QuickMenu_TimeOut = ((autocvar_hud_panel_quickmenu_time > 0) ? time + autocvar_hud_panel_quickmenu_time : 0);
 173         return true;
 174 }
 175
 176 void QuickMenu_Buffer_Close()
 177 {
 178         if (QuickMenu_Buffer >= 0)
 179         {
 180                 buf_del(QuickMenu_Buffer);
 181                 QuickMenu_Buffer = -1;
 182                 QuickMenu_Buffer_Size = 0;
 183         }
 184 }
 185
 186 void QuickMenu_Close()
 187 {
 188         strfree(QuickMenu_CurrentSubMenu);
 189         int i;
 190         for (i = 0; i < QUICKMENU_MAXLINES; ++i)
 191                 QuickMenu_Page_ClearEntry(i);
 192         QuickMenu_Page_Entries = 0;
 193         hud_panel_quickmenu = 0;
 194         mouseClicked = 0;
 195         prevMouseClicked = 0;
 196         QuickMenu_Buffer_Close();
 197 }
 198
 199 // It assumes submenu open tag is already detected
 200 void QuickMenu_skip_submenu(string submenu)
 201 {
 202         string z_submenu = string_null; strcpy(z_submenu, submenu);
 203         for(++QuickMenu_Buffer_Index ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 204         {
 205                 string s = QuickMenu_Buffer_Get();
 206                 if(substring(s, 0, 1) != QM_TAG_SUBMENU)
 207                         continue;
 208                 if(substring(s, 1, -1) == z_submenu) // submenu end
 209                         break;
 210                 QuickMenu_skip_submenu(substring(s, 1, -1));
 211         }
 212         strfree(z_submenu);
 213 }
 214
 215 bool QuickMenu_IsOpened()
 216 {
 217         return (QuickMenu_Page_Entries > 0);
 218 }
 219
 220 bool HUD_Quickmenu_PlayerListEntries_Create(string cmd, int teamplayers, bool without_me)
 221 {
 222     TC(int, teamplayers); TC(bool, without_me);
 223         int i;
 224         for(i = 0; i < QUICKMENU_MAXLINES; ++i)
 225                 QuickMenu_Page_ClearEntry(i);
 226         QuickMenu_Buffer_Close();
 227
 228         QuickMenu_Buffer = buf_create();
 229         if(QuickMenu_Buffer < 0)
 230                 return false;
 231
 232         HUD_Quickmenu_PlayerListEntries(cmd, teamplayers, without_me);
 233
 234         if(QuickMenu_Buffer_Size <= 0)
 235         {
 236                 buf_del(QuickMenu_Buffer);
 237                 QuickMenu_Buffer = -1;
 238                 return false;
 239         }
 240         return true;
 241 }
 242
 243 // new_page 0 means page 0, new_page != 0 means next page
 244 int QuickMenu_Buffer_Index_Prev;
 245 bool QuickMenu_Page_Load(string target_submenu, bool new_page)
 246 {
 247     TC(bool, new_page);
 248         string s = string_null, cmd = string_null, z_submenu;
 249
 250         if (new_page == 0)
 251                 QuickMenu_Page = 0;
 252         else
 253                 ++QuickMenu_Page;
 254
 255         z_submenu = strzone(target_submenu);
 256         strcpy(QuickMenu_CurrentSubMenu, z_submenu);
 257
 258         QuickMenu_IsLastPage = true;
 259         QuickMenu_Page_Entries = 0;
 260
 261         QuickMenu_Buffer_Index = 0;
 262         if (z_submenu != "")
 263         {
 264                 // skip everything until the submenu open tag is found
 265                 for( ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 266                 {
 267                         s = QuickMenu_Buffer_Get();
 268                         if(substring(s, 0, 1) == QM_TAG_SUBMENU && substring(s, 1, -1) == z_submenu)
 269                         {
 270                                 //LOG_INFOF("^3 beginning of %s\n", z_submenu);
 271                                 ++QuickMenu_Buffer_Index;
 272                                 break; // target_submenu found!
 273                         }
 274                         //LOG_INFOF("^1 skipping %s\n", s);
 275                 }
 276                 if(QuickMenu_Buffer_Index == QuickMenu_Buffer_Size)
 277                         LOG_WARNF("Couldn't find submenu \"%s\"", z_submenu);
 278         }
 279
 280         // only the last page can contain up to QUICKMENU_MAXLINES entries
 281         // the other ones contain only (QUICKMENU_MAXLINES - 2) entries
 282         // so that the panel can show an empty row and "Continue..."
 283         float first_entry = QuickMenu_Page * (QUICKMENU_MAXLINES - 2);
 284         int entry_num = 0; // counts entries in target_submenu
 285         for( ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 286         {
 287                 s = QuickMenu_Buffer_Get();
 288
 289                 if(z_submenu != "" && substring(s, 1, -1) == z_submenu)
 290                 {
 291                         //LOG_INFOF("^3 end of %s\n", z_submenu);
 292                         break;
 293                 }
 294
 295                 if(entry_num >= first_entry)
 296                 {
 297                         ++QuickMenu_Page_Entries;
 298                         if(QuickMenu_Page_Entries == QUICKMENU_MAXLINES - 2)
 299                                 QuickMenu_Buffer_Index_Prev = QuickMenu_Buffer_Index;
 300                         else if(QuickMenu_Page_Entries == QUICKMENU_MAXLINES)
 301                         {
 302                                 QuickMenu_Page_ClearEntry(QUICKMENU_MAXLINES - 1);
 303                                 QuickMenu_Buffer_Index = QuickMenu_Buffer_Index_Prev;
 304                                 QuickMenu_IsLastPage = false;
 305                                 break;
 306                         }
 307                 }
 308
 309                 // NOTE: entries are loaded starting from 1, not from 0
 310                 if(substring(s, 0, 1) == QM_TAG_SUBMENU)
 311                 {
 312                         if(entry_num >= first_entry)
 313                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, substring(s, 1, -1), "");
 314                         QuickMenu_skip_submenu(substring(s, 1, -1));
 315                 }
 316                 else if(substring(s, 0, 1) == QM_TAG_TITLE)
 317                 {
 318                         ++QuickMenu_Buffer_Index;
 319                         if(entry_num >= first_entry)
 320                         {
 321                                 cmd = QuickMenu_Buffer_Get();
 322                                 string command_code = substring(cmd, 0, 1);
 323                                 if(command_code == QM_TAG_COMMAND)
 324                                         cmd = substring(cmd, 1, -1);
 325                                 else if(command_code == QM_TAG_PLCOMMAND)
 326                                 {
 327                                         // throw away the current quickmenu buffer and load a new one
 328                                         cmd = substring(cmd, 1, -1);
 329                                         strunzone(z_submenu);
 330                                         if(HUD_Quickmenu_PlayerListEntries_Create(cmd, stof(substring(s, 1, 1)), stof(substring(s, 2, 1))))
 331                                                 return QuickMenu_Page_Load("", 0);
 332                                         QuickMenu_Close();
 333                                         return false;
 334                                 }
 335
 336                                 tokenize_console(cmd);
 337                                 QuickMenu_Page_Command_Type[QuickMenu_Page_Entries] = (argv(1) && argv(0) == "toggle");
 338
 339                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, substring(s, 1, -1), cmd);
 340                         }
 341
 342                 }
 343
 344                 ++entry_num;
 345         }
 346         strunzone(z_submenu);
 347         if (QuickMenu_Page_Entries == 0)
 348         {
 349                 QuickMenu_Close();
 350                 return false;
 351         }
 352         QuickMenu_TimeOut = ((autocvar_hud_panel_quickmenu_time > 0) ? time + autocvar_hud_panel_quickmenu_time : 0);
 353         return true;
 354 }
 355
 356 bool QuickMenu_ActionForNumber(int num)
 357 {
 358     TC(int, num);
 359         if (!QuickMenu_IsLastPage)
 360         {
 361                 if (num < 0 || num >= QUICKMENU_MAXLINES)
 362                         return false;
 363                 if (num == QUICKMENU_MAXLINES - 1)
 364                         return false;
 365                 if (num == 0)
 366                 {
 367                         QuickMenu_Page_Load(QuickMenu_CurrentSubMenu, +1);
 368                         return false;
 369                 }
 370         } else if (num <= 0 || num > QuickMenu_Page_Entries)
 371                 return false;
 372
 373         if (QuickMenu_Page_Command[num] != "")
 374         {
 375                 localcmd(strcat("\n", QuickMenu_Page_Command[num], "\n"));
 376                 QuickMenu_TimeOut = ((autocvar_hud_panel_quickmenu_time > 0) ? time + autocvar_hud_panel_quickmenu_time : 0);
 377                 return true;
 378         }
 379         if (QuickMenu_Page_Description[num] != "")
 380                 QuickMenu_Page_Load(QuickMenu_Page_Description[num], 0);
 381         return false;
 382 }
 383
 384 void QuickMenu_Page_ActiveEntry(int entry_num)
 385 {
 386     TC(int, entry_num);
 387         QuickMenu_Page_ActivatedEntry = entry_num;
 388         QuickMenu_Page_ActivatedEntry_Time = time + 0.1;
 389         if(QuickMenu_Page_Command[QuickMenu_Page_ActivatedEntry])
 390         {
 391                 bool f = QuickMenu_ActionForNumber(QuickMenu_Page_ActivatedEntry);
 392                 // toggle commands don't close the quickmenu
 393                 if(QuickMenu_Page_Command_Type[QuickMenu_Page_ActivatedEntry] == 1)
 394                         QuickMenu_Page_ActivatedEntry_Close = false;
 395                 else
 396                         QuickMenu_Page_ActivatedEntry_Close = (f && !(hudShiftState & S_CTRL));
 397         }
 398         else
 399                 QuickMenu_Page_ActivatedEntry_Close = (!(hudShiftState & S_CTRL));
 400 }
 401
 402 bool QuickMenu_InputEvent(int bInputType, float nPrimary, float nSecondary)
 403 {
 404     TC(int, bInputType);
 405         // we only care for keyboard events
 406         if(bInputType == 2)
 407                 return false;
 408
 409         if(!QuickMenu_IsOpened() || autocvar__hud_configure || mv_active)
 410                 return false;
 411
 412         if(bInputType == 3)
 413         {
 414                 mousepos.x = nPrimary;
 415                 mousepos.y = nSecondary;
 416                 return true;
 417         }
 418
 419         // allow console bind to work
 420         string con_keys = findkeysforcommand("toggleconsole", 0);
 421         int keys = tokenize(con_keys); // findkeysforcommand returns data for this
 422         bool hit_con_bind = false;
 423         int i;
 424         for (i = 0; i < keys; ++i)
 425         {
 426                 if(nPrimary == stof(argv(i)))
 427                         hit_con_bind = true;
 428         }
 429
 430         if(bInputType == 0) {
 431                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 432                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 433                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 434         }
 435         else if(bInputType == 1) {
 436                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 437                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 438                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 439         }
 440
 441         if(nPrimary == K_ESCAPE)
 442         {
 443                 if (bInputType == 1)
 444                         return true;
 445                 QuickMenu_Close();
 446         }
 447         else if(nPrimary >= '0' && nPrimary <= '9')
 448         {
 449                 if (bInputType == 1)
 450                         return true;
 451                 QuickMenu_Page_ActiveEntry(stof(chr2str(nPrimary)));
 452         }
 453         if(nPrimary == K_MOUSE1)
 454         {
 455                 if(bInputType == 0) // key pressed
 456                         mouseClicked |= S_MOUSE1;
 457                 else if(bInputType == 1) // key released
 458                         mouseClicked -= (mouseClicked & S_MOUSE1);
 459         }
 460         else if(nPrimary == K_MOUSE2)
 461         {
 462                 if(bInputType == 0) // key pressed
 463                         mouseClicked |= S_MOUSE2;
 464                 else if(bInputType == 1) // key released
 465                         mouseClicked -= (mouseClicked & S_MOUSE2);
 466         }
 467         else if(hit_con_bind)
 468                 return false;
 469
 470         return true;
 471 }
 472
 473 void QuickMenu_Mouse()
 474 {
 475         if(mv_active) return;
 476
 477         if(!mouseClicked)
 478         if(prevMouseClicked & S_MOUSE2)
 479         {
 480                 QuickMenu_Close();
 481                 return;
 482         }
 483
 484         panel = HUD_PANEL(QUICKMENU);
 485         HUD_Panel_LoadCvars();
 486
 487         if(panel_bg_padding)
 488         {
 489                 panel_pos += '1 1 0' * panel_bg_padding;
 490                 panel_size -= '2 2 0' * panel_bg_padding;
 491         }
 492
 493         float first_entry_pos, entries_height;
 494         vector fontsize;
 495         fontsize = '1 1 0' * (panel_size.y / QUICKMENU_MAXLINES);
 496         first_entry_pos = panel_pos.y + ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y) / 2;
 497         entries_height = panel_size.y - ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y);
 498
 499         if (mousepos.x >= panel_pos.x && mousepos.y >= first_entry_pos && mousepos.x <= panel_pos.x + panel_size.x && mousepos.y <= first_entry_pos + entries_height)
 500         {
 501                 int entry_num = min(QuickMenu_Page_Entries - 1, floor((mousepos.y - first_entry_pos) / fontsize.y));
 502                 if (QuickMenu_IsLastPage || entry_num != QUICKMENU_MAXLINES - 2)
 503                 {
 504                         // recycling panel_pos as entry_pos
 505                         panel_pos.y = first_entry_pos + entry_num * fontsize.y;
 506                         vector color;
 507                         if(mouseClicked & S_MOUSE1)
 508                                 color = '0.5 1 0.5';
 509                         else if(hudShiftState & S_CTRL)
 510                                 color = '1 1 0.3';
 511                         else
 512                                 color = '1 1 1';
 513                         drawfill(panel_pos, vec2(panel_size.x, fontsize.y), color, .2, DRAWFLAG_NORMAL);
 514
 515                         if(!mouseClicked && (prevMouseClicked & S_MOUSE1))
 516                                 QuickMenu_Page_ActiveEntry((entry_num < QUICKMENU_MAXLINES - 1) ? entry_num + 1 : 0);
 517                 }
 518         }
 519 }
 520
 521 void HUD_Quickmenu_DrawEntry(vector pos, string desc, string option, vector fontsize)
 522 {
 523         string entry;
 524         float offset;
 525         float desc_width = panel_size.x;
 526         if(option)
 527         {
 528                 string pic = strcat(hud_skin_path, "/", option);
 529                 if(precache_pic(pic) == "")
 530                         pic = strcat("gfx/hud/default/", option);
 531                 vector option_size = '1 1 0' * fontsize.y * 0.8;
 532                 desc_width -= option_size.x;
 533                 drawpic(pos + vec2(desc_width, (fontsize.y - option_size.y) / 2), pic, option_size, '1 1 1', panel_fg_alpha, DRAWFLAG_ADDITIVE);
 534                 desc_width -= fontsize.x / 4;
 535         }
 536         entry = textShortenToWidth(desc, desc_width, fontsize, stringwidth_colors);
 537         if (autocvar_hud_panel_quickmenu_align > 0)
 538         {
 539                 float real_desc_width = stringwidth_colors(entry, fontsize);
 540                 offset = (desc_width - real_desc_width) * min(autocvar_hud_panel_quickmenu_align, 1);
 541
 542                 if(option)
 543                 {
 544                         // when there's enough room align description regardless the checkbox
 545                         float extra_offset = (panel_size.x - desc_width) * min(autocvar_hud_panel_quickmenu_align, 1);
 546                         if(offset + real_desc_width + extra_offset < desc_width)
 547                                 offset += extra_offset;
 548                         else
 549                                 offset = max(0, desc_width - real_desc_width);
 550                 }
 551                 drawcolorcodedstring(pos + eX * offset, entry, fontsize, panel_fg_alpha, DRAWFLAG_ADDITIVE);
 552         }
 553         else
 554                 drawcolorcodedstring(pos, entry, fontsize, panel_fg_alpha, DRAWFLAG_ADDITIVE);
 555 }
 556
 557 void HUD_QuickMenu()
 558 {
 559         if(!autocvar__hud_configure)
 560         {
 561                 if (hud_configure_prev && hud_configure_prev != -1)
 562                         QuickMenu_Close();
 563
 564                 if(!hud_draw_maximized) return;
 565                 if(mv_active) return;
 566                 //if(!autocvar_hud_panel_quickmenu) return;
 567                 if(!hud_panel_quickmenu) return;
 568
 569                 if(QuickMenu_TimeOut)
 570                 if(time > QuickMenu_TimeOut)
 571                 {
 572                         QuickMenu_Close();
 573                         return;
 574                 }
 575         }
 576         else
 577         {
 578                 if(!QuickMenu_IsOpened())
 579                 {
 580                         QuickMenu_Page_Entries = 1;
 581                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Submenu%d"), QuickMenu_Page_Entries), "");
 582                         ++QuickMenu_Page_Entries;
 583                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Submenu%d"), QuickMenu_Page_Entries), "");
 584                         ++QuickMenu_Page_Entries;
 585                         // although real command doesn't matter here, it must not be empty
 586                         // otherwise the entry is displayed like a submenu
 587                         for (; QuickMenu_Page_Entries < QUICKMENU_MAXLINES - 1; ++QuickMenu_Page_Entries)
 588                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Command%d"), QuickMenu_Page_Entries), "-");
 589                         ++QuickMenu_Page_Entries;
 590                         QuickMenu_Page_ClearEntry(QuickMenu_Page_Entries);
 591                         QuickMenu_IsLastPage = false;
 592                 }
 593         }
 594
 595         HUD_Panel_LoadCvars();
 596
 597         HUD_Scale_Disable();
 598         HUD_Panel_DrawBg();
 599
 600         if(panel_bg_padding)
 601         {
 602                 panel_pos += '1 1 0' * panel_bg_padding;
 603                 panel_size -= '2 2 0' * panel_bg_padding;
 604         }
 605
 606         int i;
 607         vector fontsize;
 608         string color;
 609         fontsize = '1 1 0' * (panel_size.y / QUICKMENU_MAXLINES);
 610
 611         if (!QuickMenu_IsLastPage)
 612         {
 613                 color = "^5";
 614                 HUD_Quickmenu_DrawEntry(panel_pos + eY * (panel_size.y - fontsize.y), sprintf("%d: %s%s", 0, color, _("Continue...")), string_null, fontsize);
 615         }
 616         else
 617                 panel_pos.y += ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y) / 2;
 618
 619         for (i = 1; i <= QuickMenu_Page_Entries; ++i) {
 620                 if (QuickMenu_Page_Description[i] == "")
 621                         break;
 622                 string option = string_null;
 623                 if (QuickMenu_Page_Command[i] == "")
 624                         color = "^4";
 625                 else
 626                 {
 627                         color = "^3";
 628                         if(QuickMenu_Page_Command_Type[i] == 1) // toggle command
 629                         {
 630                                 int end = strstrofs(QuickMenu_Page_Command[i], ";", 0);
 631                                 if(end < 0)
 632                                         tokenize_console(QuickMenu_Page_Command[i]);
 633                                 else
 634                                         tokenize_console(substring(QuickMenu_Page_Command[i], 0, end));
 635
 636                                 if(argv(1) && argv(0) == "toggle")
 637                                 {
 638                                         // "enable feature xxx" "toggle xxx" (or "toggle xxx 1 0")
 639                                         // "disable feature xxx" "toggle xxx 0 1"
 640                                         float ON_value = 1, OFF_value = 0;
 641                                         if(argv(2))
 642                                                 ON_value = stof(argv(2));
 643
 644                                         if(argv(3))
 645                                                 OFF_value = stof(argv(3));
 646                                         else
 647                                                 OFF_value = !ON_value;
 648
 649                                         float value = cvar(argv(1));
 650                                         if(value == ON_value)
 651                                                 option = "checkbox_checked";
 652                                         else if(value == OFF_value)
 653                                                 option = "checkbox_empty";
 654                                         else
 655                                                 option = "checkbox_undefined";
 656                                 }
 657                         }
 658                 }
 659                 HUD_Quickmenu_DrawEntry(panel_pos, sprintf("%d: %s%s", i, color, QuickMenu_Page_Description[i]), option, fontsize);
 660
 661                 if(QuickMenu_Page_ActivatedEntry_Time && time < QuickMenu_Page_ActivatedEntry_Time
 662                         && QuickMenu_Page_ActivatedEntry == i)
 663                         drawfill(panel_pos, vec2(panel_size.x, fontsize.y), '0.5 1 0.5', .2, DRAWFLAG_NORMAL);
 664
 665                 panel_pos.y += fontsize.y;
 666         }
 667
 668         if(QuickMenu_Page_ActivatedEntry >= 0 && time >= QuickMenu_Page_ActivatedEntry_Time)
 669         {
 670                 if(!QuickMenu_Page_Command[QuickMenu_Page_ActivatedEntry])
 671                 {
 672                         bool f = QuickMenu_ActionForNumber(QuickMenu_Page_ActivatedEntry);
 673                         if(f && QuickMenu_Page_ActivatedEntry_Close)
 674                                 QuickMenu_Close();
 675                 }
 676                 else if(QuickMenu_Page_ActivatedEntry_Close)
 677                         QuickMenu_Close();
 678                 QuickMenu_Page_ActivatedEntry = -1;
 679                 QuickMenu_Page_ActivatedEntry_Time = 0;
 680         }
 681 }
 682
 683
 684 #define QUICKMENU_SMENU(submenu,eng_submenu) { \
 685         if(target_submenu == eng_submenu && target_submenu_found) \
 686                 return; /* target_submenu entries are now loaded, exit */ \
 687         if(QuickMenu_Buffer_Size < QUICKMENU_BUFFER_MAXENTRIES) \
 688                 QuickMenu_Buffer_Set(QM_TAG_SUBMENU, submenu); \
 689         ++QuickMenu_Buffer_Size; \
 690         if(target_submenu == eng_submenu && !target_submenu_found) { \
 691                 QuickMenu_Buffer_Size = 0; /* enable load of next entries */ \
 692                 target_submenu_found = true; \
 693         } \
 694 }
 695
 696 #define QUICKMENU_ENTRY(title,command) { \
 697         if(QuickMenu_Buffer_Size + 1 < QUICKMENU_BUFFER_MAXENTRIES) \
 698         { \
 699                 QuickMenu_Buffer_Set(QM_TAG_TITLE, title); \
 700                 ++QuickMenu_Buffer_Size; \
 701                 QuickMenu_Buffer_Set(QM_TAG_COMMAND, command); \
 702         } \
 703         ++QuickMenu_Buffer_Size; \
 704 }
 705
 706 #define QUICKMENU_SMENU_PL(submenu,eng_submenu,command,teamplayers,without_me) { \
 707         if(QuickMenu_Buffer_Size + 3 < QUICKMENU_BUFFER_MAXENTRIES) {\
 708                 QUICKMENU_SMENU(submenu,eng_submenu) \
 709                 QuickMenu_Buffer_Set(QM_TAG_TITLE, strcat(ftos(teamplayers), ftos(without_me))); \
 710                 ++QuickMenu_Buffer_Size; \
 711                 QuickMenu_Buffer_Set(QM_TAG_PLCOMMAND, command); \
 712                 ++QuickMenu_Buffer_Size; \
 713                 QUICKMENU_SMENU(submenu,eng_submenu) \
 714         } \
 715 }
 716
 717
 718
 719 // useful to Translate a string inside the Command
 720 #define QUICKMENU_ENTRY_TC(title,command,text,translated_text) {\
 721         if(prvm_language == "en") { \
 722                 tc_title = title; \
 723                 tc_cmd = sprintf(command, text); \
 724         } \
 725         else if(!autocvar_hud_panel_quickmenu_translatecommands || translated_text == text) { \
 726                 tc_title = strcat("(en)", title); \
 727                 tc_cmd = sprintf(command, text); \
 728         } \
 729         else { \
 730                 tc_title = strcat("(", prvm_language, ")", title); \
 731                 tc_cmd = sprintf(command, translated_text); \
 732         } \
 733         QUICKMENU_ENTRY(tc_title, tc_cmd) \
 734 }
 735
 736 void HUD_Quickmenu_PlayerListEntries(string cmd, int teamplayers, bool without_me)
 737 {
 738     TC(int, teamplayers); TC(bool, without_me);
 739         entity pl;
 740         if(teamplayers && !team_count)
 741                 return;
 742
 743         for(pl = players.sort_next; pl; pl = pl.sort_next)
 744         {
 745                 if(teamplayers == 1 && (pl.team != myteam || pl.team == NUM_SPECTATOR)) // only own team players
 746                         continue;
 747                 if(teamplayers == 2 && (pl.team == myteam || pl.team == NUM_SPECTATOR)) // only enemy team players
 748                         continue;
 749                 if(without_me && pl.sv_entnum == player_localnum)
 750                         continue;
 751                 QUICKMENU_ENTRY(entcs_GetName(pl.sv_entnum), sprintf(cmd, entcs_GetName(pl.sv_entnum)))
 752         }
 753
 754         return;
 755 }
 756
 757
 758 // Specifying target_submenu, this function only loads entries inside target_submenu
 759 // NOTE: alternatively we could have loaded the whole default quickmenu and
 760 // then called QuickMenu_Page_Load(target_submenu, 0);
 761 // but this sytem is more reliable since we can always refer to target_submenu
 762 // with the English title even if a translation is active
 763 void QuickMenu_Default(string target_submenu)
 764 {
 765         bool target_submenu_found = false;
 766         if(target_submenu != "")
 767                 QuickMenu_Buffer_Size = QUICKMENU_BUFFER_MAXENTRIES; // forbids load of next entries until target_submenu
 768
 769         string tc_title;
 770         string tc_cmd;
 771
 772         QUICKMENU_SMENU(_("Chat"), "Chat")
 773                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^nice one")), "say %s", ":-) / nice one", CTX(_("QMCMD^:-) / nice one")))
 774                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^good game")), "say %s", "good game", CTX(_("QMCMD^good game")))
 775                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^hi / good luck")), "say %s", "hi / good luck and have fun", CTX(_("QMCMD^hi / good luck and have fun")))
 776                 if(prvm_language != "en")
 777                 QUICKMENU_ENTRY(CTX(_("QMCMD^Send in English")), "toggle hud_panel_quickmenu_translatecommands 0 1; quickmenu; wait; quickmenu default Chat")
 778         QUICKMENU_SMENU(_("Chat"), "Chat")
 779
 780         if(teamplay)
 781         {
 782         QUICKMENU_SMENU(CTX(_("QMCMD^Team chat")), "Team chat")
 783                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^quad soon")), "say_team %s", "quad soon", CTX(_("QMCMD^quad soon")))
 784                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^free item, icon")), "say_team %s; g_waypointsprite_team_here_p", "free item %x^7 (l:%y^7)", CTX(_("QMCMD^free item %x^7 (l:%y^7)")))
 785                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^took item, icon")), "say_team %s; g_waypointsprite_team_here", "took item (l:%l^7)", CTX(_("QMCMD^took item (l:%l^7)")))
 786                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^negative")), "say_team %s", "negative", CTX(_("QMCMD^negative")))
 787                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^positive")), "say_team %s", "positive", CTX(_("QMCMD^positive")))
 788                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^need help, icon")), "say_team %s; g_waypointsprite_team_helpme; cmd voice needhelp", "need help (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^need help (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 789                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^enemy seen, icon")), "say_team %s; g_waypointsprite_team_danger_p; cmd voice incoming", "enemy seen (l:%y^7)", CTX(_("QMCMD^enemy seen (l:%y^7)")))
 790                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^flag seen, icon")), "say_team %s; g_waypointsprite_team_here_p; cmd voice seenflag", "flag seen (l:%y^7)", CTX(_("QMCMD^flag seen (l:%y^7)")))
 791                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^defending, icon")), "say_team %s; g_waypointsprite_team_here", "defending (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^defending (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 792                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^roaming, icon")), "say_team %s; g_waypointsprite_team_here", "roaming (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^roaming (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 793                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^attacking, icon")), "say_team %s; g_waypointsprite_team_here", "attacking (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^attacking (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 794                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^killed flagcarrier, icon")), "say_team %s; g_waypointsprite_team_here_p", "killed flagcarrier (l:%y^7)", CTX(_("QMCMD^killed flagcarrier (l:%y^7)")))
 795                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^dropped flag, icon")), "say_team %s; g_waypointsprite_team_here_d", "dropped flag (l:%d^7)", CTX(_("QMCMD^dropped flag (l:%d^7)")))
 796                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^drop weapon, icon")), "say_team %s; g_waypointsprite_team_here; wait; dropweapon", "dropped gun %w^7 (l:%l^7)", CTX(_("QMCMD^dropped weapon %w^7 (l:%l^7)")))
 797                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^drop flag/key, icon")), "say_team %s; g_waypointsprite_team_here; wait; use", "dropped flag/key %w^7 (l:%l^7)", CTX(_("QMCMD^dropped flag/key %w^7 (l:%l^7)")))
 798         QUICKMENU_SMENU(CTX(_("QMCMD^Team chat")), "Team chat")
 799         }
 800
 801         QUICKMENU_SMENU_PL(CTX(_("QMCMD^Send private message to")), "Send private message to", "commandmode tell \"%s^7\"", 0, 1)
 802
 803         QUICKMENU_SMENU(CTX(_("QMCMD^Settings")), "Settings")
 804                 QUICKMENU_SMENU(CTX(_("QMCMD^View/HUD settings")), "View/HUD settings")
 805                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person view")), "toggle chase_active")
 806                         QUICKMENU_ENTRY(CTX(_("QMCMD^Player models like mine")), "toggle cl_forceplayermodels")
 807                         QUICKMENU_ENTRY(CTX(_("QMCMD^Names above players")), "toggle hud_shownames")
 808                         QUICKMENU_ENTRY(CTX(_("QMCMD^Crosshair per weapon")), "toggle crosshair_per_weapon")
 809                         QUICKMENU_ENTRY(CTX(_("QMCMD^FPS")), "toggle hud_panel_engineinfo")
 810                         QUICKMENU_ENTRY(CTX(_("QMCMD^Net graph")), "toggle shownetgraph")
 811                 QUICKMENU_SMENU(CTX(_("QMCMD^View/HUD settings")), "View/HUD settings")
 812
 813                 QUICKMENU_SMENU(CTX(_("QMCMD^Sound settings")), "Sound settings")
 814                         QUICKMENU_ENTRY(CTX(_("QMCMD^Hit sound")), "toggle cl_hitsound")
 815                         QUICKMENU_ENTRY(CTX(_("QMCMD^Chat sound")), "toggle con_chatsound")
 816                 QUICKMENU_SMENU(CTX(_("QMCMD^Sound settings")), "Sound settings")
 817
 818                 if(spectatee_status > 0)
 819                 {
 820                 QUICKMENU_SMENU(CTX(_("QMCMD^Spectator camera")), "Spectator camera")
 821                         QUICKMENU_ENTRY(CTX(_("QMCMD^1st person")), "chase_active 0; -use")
 822                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person around player")), "chase_active 1; +use")
 823                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person behind")), "chase_active 1; -use")
 824                 QUICKMENU_SMENU(CTX(_("QMCMD^Spectator camera")), "Spectator camera")
 825                 }
 826
 827                 if(spectatee_status == -1)
 828                 {
 829                 QUICKMENU_SMENU(CTX(_("QMCMD^Observer camera")), "Observer camera")
 830                         QUICKMENU_ENTRY(CTX(_("QMCMD^Increase speed")), "weapnext")
 831                         QUICKMENU_ENTRY(CTX(_("QMCMD^Decrease speed")), "weapprev")
 832                         QUICKMENU_ENTRY(CTX(_("QMCMD^Wall collision off")), "+use")
 833                         QUICKMENU_ENTRY(CTX(_("QMCMD^Wall collision on")), "-use")
 834                 QUICKMENU_SMENU(CTX(_("QMCMD^Observer camera")), "Observer camera")
 835                 }
 836
 837                 QUICKMENU_ENTRY(CTX(_("QMCMD^Fullscreen")), "toggle vid_fullscreen; vid_restart")
 838         QUICKMENU_SMENU(CTX(_("QMCMD^Settings")), "Settings")
 839
 840         QUICKMENU_SMENU(CTX(_("QMCMD^Call a vote")), "Call a vote")
 841                 QUICKMENU_ENTRY(CTX(_("QMCMD^Restart the map")), "vcall restart")
 842                 QUICKMENU_ENTRY(CTX(_("QMCMD^End match")), "vcall endmatch")
 843                 if(STAT(TIMELIMIT) > 0)
 844                 {
 845                 QUICKMENU_ENTRY(CTX(_("QMCMD^Reduce match time")), "vcall reducematchtime")
 846                 QUICKMENU_ENTRY(CTX(_("QMCMD^Extend match time")), "vcall extendmatchtime")
 847                 }
 848                 if(teamplay)
 849                 QUICKMENU_ENTRY(CTX(_("QMCMD^Shuffle teams")), "vcall shuffleteams")
 850         QUICKMENU_SMENU(CTX(_("QMCMD^Call a vote")), "Call a vote")
 851
 852         if(target_submenu != "" && !target_submenu_found)
 853         {
 854                 LOG_INFOF("Couldn't find submenu \"%s\"", target_submenu);
 855                 if(prvm_language != "en")
 856                         LOG_INFOF("^3Warning: submenu title must be in English", target_submenu);
 857                 QuickMenu_Buffer_Size = 0;
 858         }
 859 }
 860 #undef QUICKMENU_SMENU
 861 #undef QUICKMENU_ENTRY
 862 #undef QUICKMENU_ENTRY_TC