qcsrc/client/hud/panel/quickmenu.qc

   1 #include "quickmenu.qh"
   2
   3 #include <client/autocvars.qh>
   4 #include <client/defs.qh>
   5 #include <client/miscfunctions.qh>
   6 #include <common/ent_cs.qh>
   7 #include <client/hud/_mod.qh>
   8 #include <client/mapvoting.qh>
   9
  10 // QuickMenu (#23)
  11
  12 // QUICKMENU_MAXLINES must be <= 10
  13 const int QUICKMENU_MAXLINES = 10;
  14 // visible entries are loaded from QuickMenu_Buffer into QuickMenu_Page_* arrays
  15 string QuickMenu_Page_Command[QUICKMENU_MAXLINES];
  16 string QuickMenu_Page_Description[QUICKMENU_MAXLINES];
  17 int QuickMenu_Page_Command_Type[QUICKMENU_MAXLINES];
  18 int QuickMenu_Page_Entries;
  19 int QuickMenu_Page;
  20 int QuickMenu_Page_ActivatedEntry = -1;
  21 bool QuickMenu_Page_ActivatedEntry_Close;
  22 float QuickMenu_Page_ActivatedEntry_Time;
  23 bool QuickMenu_IsLastPage;
  24 // all the entries are loaded into QuickMenu_Buffer
  25 // each entry (submenu or command) is composed of 2 entries
  26 const int QUICKMENU_MAXENTRIES = 256;
  27 const int QUICKMENU_BUFFER_MAXENTRIES = 2 * QUICKMENU_MAXENTRIES;
  28 int QuickMenu_Buffer = -1;
  29 int QuickMenu_Buffer_Size;
  30 int QuickMenu_Buffer_Index;
  31 string QuickMenu_CurrentSubMenu;
  32 float QuickMenu_TimeOut;
  33
  34 // QuickMenu_Buffer are labeled with these tags
  35 #define QM_TAG_TITLE "T"
  36 #define QM_TAG_SUBMENU "S"
  37 #define QM_TAG_COMMAND "C"
  38 #define QM_TAG_PLCOMMAND "P"
  39
  40 #define QuickMenu_Buffer_Set(tag, string) bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat(tag, string))
  41 #define QuickMenu_Buffer_Get() bufstr_get(QuickMenu_Buffer, QuickMenu_Buffer_Index)
  42
  43 // if s1 is not empty s will be displayed as command otherwise as submenu
  44 void QuickMenu_Page_LoadEntry(int i, string s, string s1)
  45 {
  46     TC(int, i);
  47         //printf("^xc80 entry %d: %s, %s\n", i, s, s1);
  48         if (QuickMenu_Page_Description[i])
  49                 strunzone(QuickMenu_Page_Description[i]);
  50         QuickMenu_Page_Description[i] = strzone(s);
  51         if (QuickMenu_Page_Command[i])
  52                 strunzone(QuickMenu_Page_Command[i]);
  53         QuickMenu_Page_Command[i] = strzone(s1);
  54 }
  55
  56 void QuickMenu_Page_ClearEntry(int i)
  57 {
  58     TC(int, i);
  59         if (QuickMenu_Page_Description[i])
  60                 strunzone(QuickMenu_Page_Description[i]);
  61         QuickMenu_Page_Description[i] = string_null;
  62         if (QuickMenu_Page_Command[i])
  63                 strunzone(QuickMenu_Page_Command[i]);
  64         QuickMenu_Page_Command[i] = string_null;
  65         QuickMenu_Page_Command_Type[i] = 0;
  66 }
  67
  68 float QuickMenu_Page_Load(string target_submenu, float new_page);
  69 void QuickMenu_Default(string submenu);
  70 bool QuickMenu_Open(string mode, string submenu, string file)
  71 {
  72         int fh = -1;
  73         string s;
  74
  75         if(mode == "")
  76         {
  77                 if(file == "" || file == "0")
  78                         mode = "default";
  79                 else
  80                         mode = "file";
  81         }
  82
  83         if(mode == "file")
  84         {
  85                 if(file == "" || file == "0")
  86                         LOG_INFO("No file name is set in hud_panel_quickmenu_file, loading default quickmenu");
  87                 else
  88                 {
  89                         fh = fopen(file, FILE_READ);
  90                         if(fh < 0)
  91                                 LOG_INFOF("Couldn't open file \"%s\", loading default quickmenu", file);
  92                 }
  93                 if(fh < 0)
  94                         mode = "default";
  95         }
  96
  97         if(mode == "default")
  98         {
  99                 QuickMenu_Buffer = buf_create();
 100                 if(QuickMenu_Buffer < 0)
 101                         return false;
 102
 103                 QuickMenu_Default(submenu);
 104         }
 105         else if(mode == "file")
 106         {
 107                 QuickMenu_Buffer = buf_create();
 108                 if(QuickMenu_Buffer < 0)
 109                 {
 110                         fclose(fh);
 111                         return false;
 112                 }
 113
 114                 QuickMenu_Buffer_Size = 0;
 115                 while((s = fgets(fh)) && QuickMenu_Buffer_Size < QUICKMENU_BUFFER_MAXENTRIES)
 116                 {
 117                         // first skip invalid entries, so we don't check them anymore
 118                         float argc;
 119                         argc = tokenize_console(s);
 120                         if(argc == 0 || argv(0) == "")
 121                                 continue;
 122                         if(argc == 1)
 123                                 QuickMenu_Buffer_Set(QM_TAG_SUBMENU, argv(0));
 124                         else if(argc == 2)
 125                         {
 126                                 if(argv(1) == "")
 127                                         continue;
 128                                 QuickMenu_Buffer_Set(QM_TAG_TITLE, argv(0));
 129                                 ++QuickMenu_Buffer_Size;
 130                                 QuickMenu_Buffer_Set(QM_TAG_COMMAND, argv(1));
 131                         }
 132                         else if(argc == 3)
 133                         {
 134                                 // check for special keywords
 135                                 float teamplayers = 0, without_me = 0;
 136                                 switch(argv(2))
 137                                 {
 138                                         case "ALLPLAYERS_BUT_ME":               without_me = 1; // fall through
 139                                         case "ALLPLAYERS":                              teamplayers = 0; break;
 140                                         case "OWNTEAMPLAYERS_BUT_ME":   without_me = 1; // fall through
 141                                         case "OWNTEAMPLAYERS":                  teamplayers = 1; break;
 142                                         case "ENEMYTEAMPLAYERS":                teamplayers = 2; break;
 143                                         default: continue;
 144                                 }
 145
 146                                 if(QuickMenu_Buffer_Size + 3 < QUICKMENU_BUFFER_MAXENTRIES)
 147                                 {
 148                                         QuickMenu_Buffer_Set(QM_TAG_SUBMENU, argv(0));
 149                                         ++QuickMenu_Buffer_Size;
 150                                         QuickMenu_Buffer_Set(QM_TAG_TITLE, strcat(ftos(teamplayers), ftos(without_me))); // put PLCOMMAND arguments in the title string
 151                                         ++QuickMenu_Buffer_Size;
 152                                         QuickMenu_Buffer_Set(QM_TAG_PLCOMMAND, argv(1));
 153                                         ++QuickMenu_Buffer_Size;
 154                                         QuickMenu_Buffer_Set(QM_TAG_SUBMENU, argv(0));
 155                                 }
 156                         }
 157                         ++QuickMenu_Buffer_Size;
 158                 }
 159                 fclose(fh);
 160         }
 161         else
 162         {
 163                 LOG_WARNF("Unrecognized mode %s", mode);
 164                 return false;
 165         }
 166
 167         if (QuickMenu_Buffer_Size <= 0)
 168         {
 169                 buf_del(QuickMenu_Buffer);
 170                 QuickMenu_Buffer = -1;
 171                 return false;
 172         }
 173
 174         if(mode == "file")
 175                 QuickMenu_Page_Load(submenu, 0);
 176         else
 177                 QuickMenu_Page_Load("", 0);
 178
 179         hud_panel_quickmenu = 1;
 180         if(autocvar_hud_cursormode)
 181                 setcursormode(1);
 182         hudShiftState = 0;
 183
 184         QuickMenu_TimeOut = ((autocvar_hud_panel_quickmenu_time > 0) ? time + autocvar_hud_panel_quickmenu_time : 0);
 185         return true;
 186 }
 187
 188 void QuickMenu_Buffer_Close()
 189 {
 190         if (QuickMenu_Buffer >= 0)
 191         {
 192                 buf_del(QuickMenu_Buffer);
 193                 QuickMenu_Buffer = -1;
 194                 QuickMenu_Buffer_Size = 0;
 195         }
 196 }
 197
 198 void QuickMenu_Close()
 199 {
 200         if (QuickMenu_CurrentSubMenu)
 201                 strunzone(QuickMenu_CurrentSubMenu);
 202         QuickMenu_CurrentSubMenu = string_null;
 203         int i;
 204         for (i = 0; i < QUICKMENU_MAXLINES; ++i)
 205                 QuickMenu_Page_ClearEntry(i);
 206         QuickMenu_Page_Entries = 0;
 207         hud_panel_quickmenu = 0;
 208         mouseClicked = 0;
 209         prevMouseClicked = 0;
 210         QuickMenu_Buffer_Close();
 211
 212         if(autocvar_hud_cursormode)
 213         if(!mv_active)
 214                 setcursormode(0);
 215 }
 216
 217 // It assumes submenu open tag is already detected
 218 void QuickMenu_skip_submenu(string submenu)
 219 {
 220         string s, z_submenu;
 221         z_submenu = strzone(submenu);
 222         for(++QuickMenu_Buffer_Index ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 223         {
 224                 s = QuickMenu_Buffer_Get();
 225                 if(substring(s, 0, 1) != QM_TAG_SUBMENU)
 226                         continue;
 227                 if(substring(s, 1, -1) == z_submenu) // submenu end
 228                         break;
 229                 QuickMenu_skip_submenu(substring(s, 1, -1));
 230         }
 231         strunzone(z_submenu);
 232 }
 233
 234 bool QuickMenu_IsOpened()
 235 {
 236         return (QuickMenu_Page_Entries > 0);
 237 }
 238
 239 void HUD_Quickmenu_PlayerListEntries(string cmd, int teamplayers, bool without_me);
 240 bool HUD_Quickmenu_PlayerListEntries_Create(string cmd, int teamplayers, bool without_me)
 241 {
 242     TC(int, teamplayers); TC(bool, without_me);
 243         int i;
 244         for(i = 0; i < QUICKMENU_MAXLINES; ++i)
 245                 QuickMenu_Page_ClearEntry(i);
 246         QuickMenu_Buffer_Close();
 247
 248         QuickMenu_Buffer = buf_create();
 249         if(QuickMenu_Buffer < 0)
 250                 return false;
 251
 252         HUD_Quickmenu_PlayerListEntries(cmd, teamplayers, without_me);
 253
 254         if(QuickMenu_Buffer_Size <= 0)
 255         {
 256                 buf_del(QuickMenu_Buffer);
 257                 QuickMenu_Buffer = -1;
 258                 return false;
 259         }
 260         return true;
 261 }
 262
 263 // new_page 0 means page 0, new_page != 0 means next page
 264 int QuickMenu_Buffer_Index_Prev;
 265 bool QuickMenu_Page_Load(string target_submenu, bool new_page)
 266 {
 267     TC(bool, new_page);
 268         string s = string_null, cmd = string_null, z_submenu;
 269
 270         if (new_page == 0)
 271                 QuickMenu_Page = 0;
 272         else
 273                 ++QuickMenu_Page;
 274
 275         z_submenu = strzone(target_submenu);
 276         if (QuickMenu_CurrentSubMenu)
 277                 strunzone(QuickMenu_CurrentSubMenu);
 278         QuickMenu_CurrentSubMenu = strzone(z_submenu);
 279
 280         QuickMenu_IsLastPage = true;
 281         QuickMenu_Page_Entries = 0;
 282
 283         QuickMenu_Buffer_Index = 0;
 284         if (z_submenu != "")
 285         {
 286                 // skip everything until the submenu open tag is found
 287                 for( ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 288                 {
 289                         s = QuickMenu_Buffer_Get();
 290                         if(substring(s, 0, 1) == QM_TAG_SUBMENU && substring(s, 1, -1) == z_submenu)
 291                         {
 292                                 // printf("^3 beginning of %s\n", z_submenu);
 293                                 ++QuickMenu_Buffer_Index;
 294                                 break; // target_submenu found!
 295                         }
 296                         // printf("^1 skipping %s\n", s);
 297                 }
 298                 if(QuickMenu_Buffer_Index == QuickMenu_Buffer_Size)
 299                         LOG_WARNF("Couldn't find submenu \"%s\"", z_submenu);
 300         }
 301
 302         // only the last page can contain up to QUICKMENU_MAXLINES entries
 303         // the other ones contain only (QUICKMENU_MAXLINES - 2) entries
 304         // so that the panel can show an empty row and "Continue..."
 305         float first_entry = QuickMenu_Page * (QUICKMENU_MAXLINES - 2);
 306         int entry_num = 0; // counts entries in target_submenu
 307         for( ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 308         {
 309                 s = QuickMenu_Buffer_Get();
 310
 311                 if(z_submenu != "" && substring(s, 1, -1) == z_submenu)
 312                 {
 313                         // printf("^3 end of %s\n", z_submenu);
 314                         break;
 315                 }
 316
 317                 if(entry_num >= first_entry)
 318                 {
 319                         ++QuickMenu_Page_Entries;
 320                         if(QuickMenu_Page_Entries == QUICKMENU_MAXLINES - 2)
 321                                 QuickMenu_Buffer_Index_Prev = QuickMenu_Buffer_Index;
 322                         else if(QuickMenu_Page_Entries == QUICKMENU_MAXLINES)
 323                         {
 324                                 QuickMenu_Page_ClearEntry(QUICKMENU_MAXLINES - 1);
 325                                 QuickMenu_Buffer_Index = QuickMenu_Buffer_Index_Prev;
 326                                 QuickMenu_IsLastPage = false;
 327                                 break;
 328                         }
 329                 }
 330
 331                 // NOTE: entries are loaded starting from 1, not from 0
 332                 if(substring(s, 0, 1) == QM_TAG_SUBMENU)
 333                 {
 334                         if(entry_num >= first_entry)
 335                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, substring(s, 1, -1), "");
 336                         QuickMenu_skip_submenu(substring(s, 1, -1));
 337                 }
 338                 else if(substring(s, 0, 1) == QM_TAG_TITLE)
 339                 {
 340                         ++QuickMenu_Buffer_Index;
 341                         if(entry_num >= first_entry)
 342                         {
 343                                 cmd = QuickMenu_Buffer_Get();
 344                                 string command_code = substring(cmd, 0, 1);
 345                                 if(command_code == QM_TAG_COMMAND)
 346                                         cmd = substring(cmd, 1, -1);
 347                                 else if(command_code == QM_TAG_PLCOMMAND)
 348                                 {
 349                                         // throw away the current quickmenu buffer and load a new one
 350                                         cmd = substring(cmd, 1, -1);
 351                                         strunzone(z_submenu);
 352                                         if(HUD_Quickmenu_PlayerListEntries_Create(cmd, stof(substring(s, 1, 1)), stof(substring(s, 2, 1))))
 353                                                 return QuickMenu_Page_Load("", 0);
 354                                         QuickMenu_Close();
 355                                         return false;
 356                                 }
 357
 358                                 tokenize_console(cmd);
 359                                 QuickMenu_Page_Command_Type[QuickMenu_Page_Entries] = (argv(1) && argv(0) == "toggle");
 360
 361                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, substring(s, 1, -1), cmd);
 362                         }
 363
 364                 }
 365
 366                 ++entry_num;
 367         }
 368         strunzone(z_submenu);
 369         if (QuickMenu_Page_Entries == 0)
 370         {
 371                 QuickMenu_Close();
 372                 return false;
 373         }
 374         QuickMenu_TimeOut = ((autocvar_hud_panel_quickmenu_time > 0) ? time + autocvar_hud_panel_quickmenu_time : 0);
 375         return true;
 376 }
 377
 378 bool QuickMenu_ActionForNumber(int num)
 379 {
 380     TC(int, num);
 381         if (!QuickMenu_IsLastPage)
 382         {
 383                 if (num < 0 || num >= QUICKMENU_MAXLINES)
 384                         return false;
 385                 if (num == QUICKMENU_MAXLINES - 1)
 386                         return false;
 387                 if (num == 0)
 388                 {
 389                         QuickMenu_Page_Load(QuickMenu_CurrentSubMenu, +1);
 390                         return false;
 391                 }
 392         } else if (num <= 0 || num > QuickMenu_Page_Entries)
 393                 return false;
 394
 395         if (QuickMenu_Page_Command[num] != "")
 396         {
 397                 localcmd(strcat("\n", QuickMenu_Page_Command[num], "\n"));
 398                 QuickMenu_TimeOut = ((autocvar_hud_panel_quickmenu_time > 0) ? time + autocvar_hud_panel_quickmenu_time : 0);
 399                 return true;
 400         }
 401         if (QuickMenu_Page_Description[num] != "")
 402                 QuickMenu_Page_Load(QuickMenu_Page_Description[num], 0);
 403         return false;
 404 }
 405
 406 void QuickMenu_Page_ActiveEntry(int entry_num)
 407 {
 408     TC(int, entry_num);
 409         QuickMenu_Page_ActivatedEntry = entry_num;
 410         QuickMenu_Page_ActivatedEntry_Time = time + 0.1;
 411         if(QuickMenu_Page_Command[QuickMenu_Page_ActivatedEntry])
 412         {
 413                 bool f = QuickMenu_ActionForNumber(QuickMenu_Page_ActivatedEntry);
 414                 // toggle commands don't close the quickmenu
 415                 if(QuickMenu_Page_Command_Type[QuickMenu_Page_ActivatedEntry] == 1)
 416                         QuickMenu_Page_ActivatedEntry_Close = false;
 417                 else
 418                         QuickMenu_Page_ActivatedEntry_Close = (f && !(hudShiftState & S_CTRL));
 419         }
 420         else
 421                 QuickMenu_Page_ActivatedEntry_Close = (!(hudShiftState & S_CTRL));
 422 }
 423
 424 bool QuickMenu_InputEvent(int bInputType, float nPrimary, float nSecondary)
 425 {
 426     TC(int, bInputType);
 427         // we only care for keyboard events
 428         if(bInputType == 2)
 429                 return false;
 430
 431         if(!QuickMenu_IsOpened() || autocvar__hud_configure || mv_active)
 432                 return false;
 433
 434         if(bInputType == 3)
 435         {
 436                 mousepos.x = nPrimary;
 437                 mousepos.y = nSecondary;
 438                 return true;
 439         }
 440
 441         // allow console bind to work
 442         string con_keys = findkeysforcommand("toggleconsole", 0);
 443         int keys = tokenize(con_keys); // findkeysforcommand returns data for this
 444         bool hit_con_bind = false;
 445         int i;
 446         for (i = 0; i < keys; ++i)
 447         {
 448                 if(nPrimary == stof(argv(i)))
 449                         hit_con_bind = true;
 450         }
 451
 452         if(bInputType == 0) {
 453                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 454                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 455                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 456         }
 457         else if(bInputType == 1) {
 458                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 459                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 460                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 461         }
 462
 463         if(nPrimary == K_ESCAPE)
 464         {
 465                 if (bInputType == 1)
 466                         return true;
 467                 QuickMenu_Close();
 468         }
 469         else if(nPrimary >= '0' && nPrimary <= '9')
 470         {
 471                 if (bInputType == 1)
 472                         return true;
 473                 QuickMenu_Page_ActiveEntry(stof(chr2str(nPrimary)));
 474         }
 475         if(nPrimary == K_MOUSE1)
 476         {
 477                 if(bInputType == 0) // key pressed
 478                         mouseClicked |= S_MOUSE1;
 479                 else if(bInputType == 1) // key released
 480                         mouseClicked -= (mouseClicked & S_MOUSE1);
 481         }
 482         else if(nPrimary == K_MOUSE2)
 483         {
 484                 if(bInputType == 0) // key pressed
 485                         mouseClicked |= S_MOUSE2;
 486                 else if(bInputType == 1) // key released
 487                         mouseClicked -= (mouseClicked & S_MOUSE2);
 488         }
 489         else if(hit_con_bind)
 490                 return false;
 491
 492         return true;
 493 }
 494
 495 void QuickMenu_Mouse()
 496 {
 497         if(mv_active) return;
 498
 499         if(!mouseClicked)
 500         if(prevMouseClicked & S_MOUSE2)
 501         {
 502                 QuickMenu_Close();
 503                 return;
 504         }
 505
 506         if (!autocvar_hud_cursormode)
 507                 update_mousepos();
 508
 509         panel = HUD_PANEL(QUICKMENU);
 510         HUD_Panel_LoadCvars();
 511
 512         if(panel_bg_padding)
 513         {
 514                 panel_pos += '1 1 0' * panel_bg_padding;
 515                 panel_size -= '2 2 0' * panel_bg_padding;
 516         }
 517
 518         float first_entry_pos, entries_height;
 519         vector fontsize;
 520         fontsize = '1 1 0' * (panel_size.y / QUICKMENU_MAXLINES);
 521         first_entry_pos = panel_pos.y + ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y) / 2;
 522         entries_height = panel_size.y - ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y);
 523
 524         if (mousepos.x >= panel_pos.x && mousepos.y >= first_entry_pos && mousepos.x <= panel_pos.x + panel_size.x && mousepos.y <= first_entry_pos + entries_height)
 525         {
 526                 int entry_num = min(QuickMenu_Page_Entries - 1, floor((mousepos.y - first_entry_pos) / fontsize.y));
 527                 if (QuickMenu_IsLastPage || entry_num != QUICKMENU_MAXLINES - 2)
 528                 {
 529                         // recycling panel_pos as entry_pos
 530                         panel_pos.y = first_entry_pos + entry_num * fontsize.y;
 531                         vector color;
 532                         if(mouseClicked & S_MOUSE1)
 533                                 color = '0.5 1 0.5';
 534                         else if(hudShiftState & S_CTRL)
 535                                 color = '1 1 0.3';
 536                         else
 537                                 color = '1 1 1';
 538                         drawfill(panel_pos, vec2(panel_size.x, fontsize.y), color, .2, DRAWFLAG_NORMAL);
 539
 540                         if(!mouseClicked && (prevMouseClicked & S_MOUSE1))
 541                                 QuickMenu_Page_ActiveEntry((entry_num < QUICKMENU_MAXLINES - 1) ? entry_num + 1 : 0);
 542                 }
 543         }
 544
 545         draw_cursor_normal(mousepos, '1 1 1', 0.8);
 546
 547         prevMouseClicked = mouseClicked;
 548 }
 549
 550 void HUD_Quickmenu_DrawEntry(vector pos, string desc, string option, vector fontsize)
 551 {
 552         string entry;
 553         float offset;
 554         float desc_width = panel_size.x;
 555         if(option)
 556         {
 557                 string pic = strcat(hud_skin_path, "/", option);
 558                 if(precache_pic(pic) == "")
 559                         pic = strcat("gfx/hud/default/", option);
 560                 vector option_size = '1 1 0' * fontsize.y * 0.8;
 561                 desc_width -= option_size.x;
 562                 drawpic(pos + vec2(desc_width, (fontsize.y - option_size.y) / 2), pic, option_size, '1 1 1', panel_fg_alpha, DRAWFLAG_ADDITIVE);
 563                 desc_width -= fontsize.x / 4;
 564         }
 565         entry = textShortenToWidth(desc, desc_width, fontsize, stringwidth_colors);
 566         if (autocvar_hud_panel_quickmenu_align > 0)
 567         {
 568                 float real_desc_width = stringwidth_colors(entry, fontsize);
 569                 offset = (desc_width - real_desc_width) * min(autocvar_hud_panel_quickmenu_align, 1);
 570
 571                 if(option)
 572                 {
 573                         // when there's enough room align description regardless the checkbox
 574                         float extra_offset = (panel_size.x - desc_width) * min(autocvar_hud_panel_quickmenu_align, 1);
 575                         if(offset + real_desc_width + extra_offset < desc_width)
 576                                 offset += extra_offset;
 577                         else
 578                                 offset = max(0, desc_width - real_desc_width);
 579                 }
 580                 drawcolorcodedstring(pos + eX * offset, entry, fontsize, panel_fg_alpha, DRAWFLAG_ADDITIVE);
 581         }
 582         else
 583                 drawcolorcodedstring(pos, entry, fontsize, panel_fg_alpha, DRAWFLAG_ADDITIVE);
 584 }
 585
 586 void HUD_QuickMenu()
 587 {
 588         if(!autocvar__hud_configure)
 589         {
 590                 if (hud_configure_prev && hud_configure_prev != -1)
 591                         QuickMenu_Close();
 592
 593                 if(!hud_draw_maximized) return;
 594                 if(mv_active) return;
 595                 //if(!autocvar_hud_panel_quickmenu) return;
 596                 if(!hud_panel_quickmenu) return;
 597
 598                 if(QuickMenu_TimeOut)
 599                 if(time > QuickMenu_TimeOut)
 600                 {
 601                         QuickMenu_Close();
 602                         return;
 603                 }
 604         }
 605         else
 606         {
 607                 if(!QuickMenu_IsOpened())
 608                 {
 609                         QuickMenu_Page_Entries = 1;
 610                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Submenu%d"), QuickMenu_Page_Entries), "");
 611                         ++QuickMenu_Page_Entries;
 612                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Submenu%d"), QuickMenu_Page_Entries), "");
 613                         ++QuickMenu_Page_Entries;
 614                         // although real command doesn't matter here, it must not be empty
 615                         // otherwise the entry is displayed like a submenu
 616                         for (; QuickMenu_Page_Entries < QUICKMENU_MAXLINES - 1; ++QuickMenu_Page_Entries)
 617                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Command%d"), QuickMenu_Page_Entries), "-");
 618                         ++QuickMenu_Page_Entries;
 619                         QuickMenu_Page_ClearEntry(QuickMenu_Page_Entries);
 620                         QuickMenu_IsLastPage = false;
 621                 }
 622         }
 623
 624         HUD_Panel_LoadCvars();
 625
 626         HUD_Scale_Disable();
 627         HUD_Panel_DrawBg();
 628
 629         if(panel_bg_padding)
 630         {
 631                 panel_pos += '1 1 0' * panel_bg_padding;
 632                 panel_size -= '2 2 0' * panel_bg_padding;
 633         }
 634
 635         int i;
 636         vector fontsize;
 637         string color;
 638         fontsize = '1 1 0' * (panel_size.y / QUICKMENU_MAXLINES);
 639
 640         if (!QuickMenu_IsLastPage)
 641         {
 642                 color = "^5";
 643                 HUD_Quickmenu_DrawEntry(panel_pos + eY * (panel_size.y - fontsize.y), sprintf("%d: %s%s", 0, color, _("Continue...")), string_null, fontsize);
 644         }
 645         else
 646                 panel_pos.y += ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y) / 2;
 647
 648         for (i = 1; i <= QuickMenu_Page_Entries; ++i) {
 649                 if (QuickMenu_Page_Description[i] == "")
 650                         break;
 651                 string option = string_null;
 652                 if (QuickMenu_Page_Command[i] == "")
 653                         color = "^4";
 654                 else
 655                 {
 656                         color = "^3";
 657                         if(QuickMenu_Page_Command_Type[i] == 1) // toggle command
 658                         {
 659                                 int end = strstrofs(QuickMenu_Page_Command[i], ";", 0);
 660                                 if(end < 0)
 661                                         tokenize_console(QuickMenu_Page_Command[i]);
 662                                 else
 663                                         tokenize_console(substring(QuickMenu_Page_Command[i], 0, end));
 664
 665                                 if(argv(1) && argv(0) == "toggle")
 666                                 {
 667                                         // "enable feature xxx" "toggle xxx" (or "toggle xxx 1 0")
 668                                         // "disable feature xxx" "toggle xxx 0 1"
 669                                         float ON_value = 1, OFF_value = 0;
 670                                         if(argv(2))
 671                                                 ON_value = stof(argv(2));
 672
 673                                         if(argv(3))
 674                                                 OFF_value = stof(argv(3));
 675                                         else
 676                                                 OFF_value = !ON_value;
 677
 678                                         float value = cvar(argv(1));
 679                                         if(value == ON_value)
 680                                                 option = "checkbox_checked";
 681                                         else if(value == OFF_value)
 682                                                 option = "checkbox_empty";
 683                                         else
 684                                                 option = "checkbox_undefined";
 685                                 }
 686                         }
 687                 }
 688                 HUD_Quickmenu_DrawEntry(panel_pos, sprintf("%d: %s%s", i, color, QuickMenu_Page_Description[i]), option, fontsize);
 689
 690                 if(QuickMenu_Page_ActivatedEntry_Time && time < QuickMenu_Page_ActivatedEntry_Time
 691                         && QuickMenu_Page_ActivatedEntry == i)
 692                         drawfill(panel_pos, vec2(panel_size.x, fontsize.y), '0.5 1 0.5', .2, DRAWFLAG_NORMAL);
 693
 694                 panel_pos.y += fontsize.y;
 695         }
 696
 697         if(QuickMenu_Page_ActivatedEntry >= 0 && time >= QuickMenu_Page_ActivatedEntry_Time)
 698         {
 699                 if(!QuickMenu_Page_Command[QuickMenu_Page_ActivatedEntry])
 700                 {
 701                         bool f = QuickMenu_ActionForNumber(QuickMenu_Page_ActivatedEntry);
 702                         if(f && QuickMenu_Page_ActivatedEntry_Close)
 703                                 QuickMenu_Close();
 704                 }
 705                 else if(QuickMenu_Page_ActivatedEntry_Close)
 706                         QuickMenu_Close();
 707                 QuickMenu_Page_ActivatedEntry = -1;
 708                 QuickMenu_Page_ActivatedEntry_Time = 0;
 709         }
 710 }
 711
 712
 713 #define QUICKMENU_SMENU(submenu,eng_submenu) { \
 714         if(target_submenu == eng_submenu && target_submenu_found) \
 715                 return; /* target_submenu entries are now loaded, exit */ \
 716         if(QuickMenu_Buffer_Size < QUICKMENU_BUFFER_MAXENTRIES) \
 717                 QuickMenu_Buffer_Set(QM_TAG_SUBMENU, submenu); \
 718         ++QuickMenu_Buffer_Size; \
 719         if(target_submenu == eng_submenu && !target_submenu_found) { \
 720                 QuickMenu_Buffer_Size = 0; /* enable load of next entries */ \
 721                 target_submenu_found = true; \
 722         } \
 723 }
 724
 725 #define QUICKMENU_ENTRY(title,command) { \
 726         if(QuickMenu_Buffer_Size + 1 < QUICKMENU_BUFFER_MAXENTRIES) \
 727         { \
 728                 QuickMenu_Buffer_Set(QM_TAG_TITLE, title); \
 729                 ++QuickMenu_Buffer_Size; \
 730                 QuickMenu_Buffer_Set(QM_TAG_COMMAND, command); \
 731         } \
 732         ++QuickMenu_Buffer_Size; \
 733 }
 734
 735 #define QUICKMENU_SMENU_PL(submenu,eng_submenu,command,teamplayers,without_me) { \
 736         if(QuickMenu_Buffer_Size + 3 < QUICKMENU_BUFFER_MAXENTRIES) {\
 737                 QUICKMENU_SMENU(submenu,eng_submenu) \
 738                 QuickMenu_Buffer_Set(QM_TAG_TITLE, strcat(ftos(teamplayers), ftos(without_me))); \
 739                 ++QuickMenu_Buffer_Size; \
 740                 QuickMenu_Buffer_Set(QM_TAG_PLCOMMAND, command); \
 741                 ++QuickMenu_Buffer_Size; \
 742                 QUICKMENU_SMENU(submenu,eng_submenu) \
 743         } \
 744 }
 745
 746
 747
 748 // useful to Translate a string inside the Command
 749 #define QUICKMENU_ENTRY_TC(title,command,text,translated_text) {\
 750         if(prvm_language == "en") { \
 751                 tc_title = title; \
 752                 tc_cmd = sprintf(command, text); \
 753         } \
 754         else if(!autocvar_hud_panel_quickmenu_translatecommands || translated_text == text) { \
 755                 tc_title = strcat("(en)", title); \
 756                 tc_cmd = sprintf(command, text); \
 757         } \
 758         else { \
 759                 tc_title = strcat("(", prvm_language, ")", title); \
 760                 tc_cmd = sprintf(command, translated_text); \
 761         } \
 762         QUICKMENU_ENTRY(tc_title, tc_cmd) \
 763 }
 764
 765 void HUD_Quickmenu_PlayerListEntries(string cmd, int teamplayers, bool without_me)
 766 {
 767     TC(int, teamplayers); TC(bool, without_me);
 768         entity pl;
 769         if(teamplayers && !team_count)
 770                 return;
 771
 772         for(pl = players.sort_next; pl; pl = pl.sort_next)
 773         {
 774                 if(teamplayers == 1 && (pl.team != myteam || pl.team == NUM_SPECTATOR)) // only own team players
 775                         continue;
 776                 if(teamplayers == 2 && (pl.team == myteam || pl.team == NUM_SPECTATOR)) // only enemy team players
 777                         continue;
 778                 if(without_me && pl.sv_entnum == player_localnum)
 779                         continue;
 780                 QUICKMENU_ENTRY(entcs_GetName(pl.sv_entnum), sprintf(cmd, entcs_GetName(pl.sv_entnum)))
 781         }
 782
 783         return;
 784 }
 785
 786
 787 // Specifying target_submenu, this function only loads entries inside target_submenu
 788 // NOTE: alternatively we could have loaded the whole default quickmenu and
 789 // then called QuickMenu_Page_Load(target_submenu, 0);
 790 // but this sytem is more reliable since we can always refer to target_submenu
 791 // with the English title even if a translation is active
 792 void QuickMenu_Default(string target_submenu)
 793 {
 794         bool target_submenu_found = false;
 795         if(target_submenu != "")
 796                 QuickMenu_Buffer_Size = QUICKMENU_BUFFER_MAXENTRIES; // forbids load of next entries until target_submenu
 797
 798         string tc_title;
 799         string tc_cmd;
 800
 801         QUICKMENU_SMENU(_("Chat"), "Chat")
 802                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^nice one")), "say %s", ":-) / nice one", CTX(_("QMCMD^:-) / nice one")))
 803                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^good game")), "say %s", "good game", CTX(_("QMCMD^good game")))
 804                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^hi / good luck")), "say %s", "hi / good luck and have fun", CTX(_("QMCMD^hi / good luck and have fun")))
 805         QUICKMENU_SMENU(_("Chat"), "Chat")
 806
 807         if(teamplay)
 808         {
 809         QUICKMENU_SMENU(CTX(_("QMCMD^Team chat")), "Team chat")
 810                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^quad soon")), "say_team %s", "quad soon", CTX(_("QMCMD^quad soon")))
 811                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^free item, icon")), "say_team %s; g_waypointsprite_team_here_p", "free item %x^7 (l:%y^7)", CTX(_("QMCMD^free item %x^7 (l:%y^7)")))
 812                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^took item, icon")), "say_team %s; g_waypointsprite_team_here", "took item (l:%l^7)", CTX(_("QMCMD^took item (l:%l^7)")))
 813                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^negative")), "say_team %s", "negative", CTX(_("QMCMD^negative")))
 814                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^positive")), "say_team %s", "positive", CTX(_("QMCMD^positive")))
 815                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^need help, icon")), "say_team %s; g_waypointsprite_team_helpme; cmd voice needhelp", "need help (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^need help (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 816                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^enemy seen, icon")), "say_team %s; g_waypointsprite_team_danger_p; cmd voice incoming", "enemy seen (l:%y^7)", CTX(_("QMCMD^enemy seen (l:%y^7)")))
 817                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^flag seen, icon")), "say_team %s; g_waypointsprite_team_here_p; cmd voice seenflag", "flag seen (l:%y^7)", CTX(_("QMCMD^flag seen (l:%y^7)")))
 818                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^defending, icon")), "say_team %s; g_waypointsprite_team_here", "defending (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^defending (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 819                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^roaming, icon")), "say_team %s; g_waypointsprite_team_here", "roaming (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^roaming (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 820                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^attacking, icon")), "say_team %s; g_waypointsprite_team_here", "attacking (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^attacking (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 821                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^killed flagcarrier, icon")), "say_team %s; g_waypointsprite_team_here_p", "killed flagcarrier (l:%y^7)", CTX(_("QMCMD^killed flagcarrier (l:%y^7)")))
 822                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^dropped flag, icon")), "say_team %s; g_waypointsprite_team_here_d", "dropped flag (l:%d^7)", CTX(_("QMCMD^dropped flag (l:%d^7)")))
 823                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^drop weapon, icon")), "say_team %s; g_waypointsprite_team_here; wait; dropweapon", "dropped gun %w^7 (l:%l^7)", CTX(_("QMCMD^dropped weapon %w^7 (l:%l^7)")))
 824                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^drop flag/key, icon")), "say_team %s; g_waypointsprite_team_here; wait; use", "dropped flag/key %w^7 (l:%l^7)", CTX(_("QMCMD^dropped flag/key %w^7 (l:%l^7)")))
 825         QUICKMENU_SMENU(CTX(_("QMCMD^Team chat")), "Team chat")
 826         }
 827
 828         QUICKMENU_SMENU_PL(CTX(_("QMCMD^Send private message to")), "Send private message to", "commandmode tell \"%s^7\"", 0, 1)
 829
 830         QUICKMENU_SMENU(CTX(_("QMCMD^Settings")), "Settings")
 831                 QUICKMENU_SMENU(CTX(_("QMCMD^View/HUD settings")), "View/HUD settings")
 832                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person view")), "toggle chase_active")
 833                         QUICKMENU_ENTRY(CTX(_("QMCMD^Player models like mine")), "toggle cl_forceplayermodels")
 834                         QUICKMENU_ENTRY(CTX(_("QMCMD^Names above players")), "toggle hud_shownames")
 835                         QUICKMENU_ENTRY(CTX(_("QMCMD^Crosshair per weapon")), "toggle crosshair_per_weapon")
 836                         QUICKMENU_ENTRY(CTX(_("QMCMD^FPS")), "toggle hud_panel_engineinfo")
 837                         QUICKMENU_ENTRY(CTX(_("QMCMD^Net graph")), "toggle shownetgraph")
 838                 QUICKMENU_SMENU(CTX(_("QMCMD^View/HUD settings")), "View/HUD settings")
 839
 840                 QUICKMENU_SMENU(CTX(_("QMCMD^Sound settings")), "Sound settings")
 841                         QUICKMENU_ENTRY(CTX(_("QMCMD^Hit sound")), "toggle cl_hitsound")
 842                         QUICKMENU_ENTRY(CTX(_("QMCMD^Chat sound")), "toggle con_chatsound")
 843                 QUICKMENU_SMENU(CTX(_("QMCMD^Sound settings")), "Sound settings")
 844
 845                 if(spectatee_status > 0)
 846                 {
 847                 QUICKMENU_SMENU(CTX(_("QMCMD^Spectator camera")), "Spectator camera")
 848                         QUICKMENU_ENTRY(CTX(_("QMCMD^1st person")), "chase_active 0; -use")
 849                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person around player")), "chase_active 1; +use")
 850                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person behind")), "chase_active 1; -use")
 851                 QUICKMENU_SMENU(CTX(_("QMCMD^Spectator camera")), "Spectator camera")
 852                 }
 853
 854                 if(spectatee_status == -1)
 855                 {
 856                 QUICKMENU_SMENU(CTX(_("QMCMD^Observer camera")), "Observer camera")
 857                         QUICKMENU_ENTRY(CTX(_("QMCMD^Increase speed")), "weapnext")
 858                         QUICKMENU_ENTRY(CTX(_("QMCMD^Decrease speed")), "weapprev")
 859                         QUICKMENU_ENTRY(CTX(_("QMCMD^Wall collision off")), "+use")
 860                         QUICKMENU_ENTRY(CTX(_("QMCMD^Wall collision on")), "-use")
 861                 QUICKMENU_SMENU(CTX(_("QMCMD^Observer camera")), "Observer camera")
 862                 }
 863
 864                 QUICKMENU_ENTRY(CTX(_("QMCMD^Fullscreen")), "toggle vid_fullscreen; vid_restart")
 865                 if(prvm_language != "en")
 866                 QUICKMENU_ENTRY(CTX(_("QMCMD^Translate chat messages")), "toggle hud_panel_quickmenu_translatecommands")
 867         QUICKMENU_SMENU(CTX(_("QMCMD^Settings")), "Settings")
 868
 869         QUICKMENU_SMENU(CTX(_("QMCMD^Call a vote")), "Call a vote")
 870                 QUICKMENU_ENTRY(CTX(_("QMCMD^Restart the map")), "vcall restart")
 871                 QUICKMENU_ENTRY(CTX(_("QMCMD^End match")), "vcall endmatch")
 872                 if(STAT(TIMELIMIT) > 0)
 873                 {
 874                 QUICKMENU_ENTRY(CTX(_("QMCMD^Reduce match time")), "vcall reducematchtime")
 875                 QUICKMENU_ENTRY(CTX(_("QMCMD^Extend match time")), "vcall extendmatchtime")
 876                 }
 877                 if(teamplay)
 878                 QUICKMENU_ENTRY(CTX(_("QMCMD^Shuffle teams")), "vcall shuffleteams")
 879         QUICKMENU_SMENU(CTX(_("QMCMD^Call a vote")), "Call a vote")
 880
 881         if(target_submenu != "" && !target_submenu_found)
 882         {
 883                 LOG_WARNF("Couldn't find submenu \"%s\"", target_submenu);
 884                 if(prvm_language != "en")
 885                         LOG_WARNF("^3Warning: submenu must be in English", target_submenu);
 886                 QuickMenu_Buffer_Size = 0;
 887         }
 888 }
 889 #undef QUICKMENU_SMENU
 890 #undef QUICKMENU_ENTRY
 891 #undef QUICKMENU_ENTRY_TC