qcsrc/client/hud/panel/quickmenu.qc

   1 #include "quickmenu.qh"
   2 // QuickMenu (#23)
   3
   4 #include <common/ent_cs.qh>
   5 #include <client/hud/all.qh>
   6 #include <client/mapvoting.qh>
   7
   8 // QUICKMENU_MAXLINES must be <= 10
   9 const int QUICKMENU_MAXLINES = 10;
  10 // visible entries are loaded from QuickMenu_Buffer into QuickMenu_Page_* arrays
  11 string QuickMenu_Page_Command[QUICKMENU_MAXLINES];
  12 string QuickMenu_Page_Description[QUICKMENU_MAXLINES];
  13 int QuickMenu_Page_Command_Type[QUICKMENU_MAXLINES];
  14 int QuickMenu_Page_Entries;
  15 int QuickMenu_Page;
  16 int QuickMenu_Page_ActivatedEntry = -1;
  17 bool QuickMenu_Page_ActivatedEntry_Close;
  18 float QuickMenu_Page_ActivatedEntry_Time;
  19 bool QuickMenu_IsLastPage;
  20 // all the entries are loaded into QuickMenu_Buffer
  21 // each entry (submenu or command) is composed of 2 entries
  22 const int QUICKMENU_MAXENTRIES = 256;
  23 const int QUICKMENU_BUFFER_MAXENTRIES = 2 * QUICKMENU_MAXENTRIES;
  24 int QuickMenu_Buffer = -1;
  25 int QuickMenu_Buffer_Size;
  26 int QuickMenu_Buffer_Index;
  27 string QuickMenu_CurrentSubMenu;
  28 float QuickMenu_TimeOut;
  29
  30 // QuickMenu_Buffer are labeled with these tags
  31 #define QM_TAG_TITLE "T"
  32 #define QM_TAG_SUBMENU "S"
  33 #define QM_TAG_COMMAND "C"
  34 #define QM_TAG_PLCOMMAND "P"
  35
  36 #define QuickMenu_Buffer_Set(tag, string) bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat(tag, string))
  37 #define QuickMenu_Buffer_Get() bufstr_get(QuickMenu_Buffer, QuickMenu_Buffer_Index)
  38
  39 // if s1 is not empty s will be displayed as command otherwise as submenu
  40 void QuickMenu_Page_LoadEntry(int i, string s, string s1)
  41 {
  42     TC(int, i);
  43         //printf("^xc80 entry %d: %s, %s\n", i, s, s1);
  44         if (QuickMenu_Page_Description[i])
  45                 strunzone(QuickMenu_Page_Description[i]);
  46         QuickMenu_Page_Description[i] = strzone(s);
  47         if (QuickMenu_Page_Command[i])
  48                 strunzone(QuickMenu_Page_Command[i]);
  49         QuickMenu_Page_Command[i] = strzone(s1);
  50 }
  51
  52 void QuickMenu_Page_ClearEntry(int i)
  53 {
  54     TC(int, i);
  55         if (QuickMenu_Page_Description[i])
  56                 strunzone(QuickMenu_Page_Description[i]);
  57         QuickMenu_Page_Description[i] = string_null;
  58         if (QuickMenu_Page_Command[i])
  59                 strunzone(QuickMenu_Page_Command[i]);
  60         QuickMenu_Page_Command[i] = string_null;
  61 }
  62
  63 float QuickMenu_Page_Load(string target_submenu, float new_page);
  64 void QuickMenu_Default(string submenu);
  65 bool QuickMenu_Open(string mode, string submenu)
  66 {
  67         int fh = -1;
  68         string s;
  69
  70         if(mode == "")
  71         {
  72                 if(autocvar_hud_panel_quickmenu_file == "" || autocvar_hud_panel_quickmenu_file == "0")
  73                         mode = "default";
  74                 else
  75                         mode = "file";
  76         }
  77
  78         if(mode == "file")
  79         {
  80                 if(autocvar_hud_panel_quickmenu_file == "" || autocvar_hud_panel_quickmenu_file == "0")
  81                         LOG_INFO("No file name is set in hud_panel_quickmenu_file, loading default quickmenu\n");
  82                 else
  83                 {
  84                         fh = fopen(autocvar_hud_panel_quickmenu_file, FILE_READ);
  85                         if(fh < 0)
  86                                 LOG_INFOF("Couldn't open file \"%s\", loading default quickmenu\n", autocvar_hud_panel_quickmenu_file);
  87                 }
  88                 if(fh < 0)
  89                         mode = "default";
  90         }
  91
  92         if(mode == "default")
  93         {
  94                 QuickMenu_Buffer = buf_create();
  95                 if(QuickMenu_Buffer < 0)
  96                         return false;
  97
  98                 QuickMenu_Default(submenu);
  99         }
 100         else if(mode == "file")
 101         {
 102                 QuickMenu_Buffer = buf_create();
 103                 if(QuickMenu_Buffer < 0)
 104                 {
 105                         fclose(fh);
 106                         return false;
 107                 }
 108
 109                 QuickMenu_Buffer_Size = 0;
 110                 while((s = fgets(fh)) && QuickMenu_Buffer_Size < QUICKMENU_BUFFER_MAXENTRIES)
 111                 {
 112                         // first skip invalid entries, so we don't check them anymore
 113                         float argc;
 114                         argc = tokenize_console(s);
 115                         if(argc == 0 || argv(0) == "")
 116                                 continue;
 117                         if(argc == 1)
 118                                 QuickMenu_Buffer_Set(QM_TAG_SUBMENU, argv(0));
 119                         else if(argc == 2)
 120                         {
 121                                 if(argv(1) == "")
 122                                         continue;
 123                                 QuickMenu_Buffer_Set(QM_TAG_TITLE, argv(0));
 124                                 ++QuickMenu_Buffer_Size;
 125                                 QuickMenu_Buffer_Set(QM_TAG_COMMAND, argv(1));
 126                         }
 127                         else if(argc == 3)
 128                         {
 129                                 // check for special keywords
 130                                 float teamplayers = 0, without_me = 0;
 131                                 switch(argv(2))
 132                                 {
 133                                         case "ALLPLAYERS_BUT_ME":               without_me = 1; // fall through
 134                                         case "ALLPLAYERS":                              teamplayers = 0; break;
 135                                         case "OWNTEAMPLAYERS_BUT_ME":   without_me = 1; // fall through
 136                                         case "OWNTEAMPLAYERS":                  teamplayers = 1; break;
 137                                         case "ENEMYTEAMPLAYERS":                teamplayers = 2; break;
 138                                         default: continue;
 139                                 }
 140
 141                                 if(QuickMenu_Buffer_Size + 3 < QUICKMENU_BUFFER_MAXENTRIES)
 142                                 {
 143                                         QuickMenu_Buffer_Set(QM_TAG_SUBMENU, argv(0));
 144                                         ++QuickMenu_Buffer_Size;
 145                                         QuickMenu_Buffer_Set(QM_TAG_TITLE, strcat(ftos(teamplayers), ftos(without_me))); // put PLCOMMAND arguments in the title string
 146                                         ++QuickMenu_Buffer_Size;
 147                                         QuickMenu_Buffer_Set(QM_TAG_PLCOMMAND, argv(1));
 148                                         ++QuickMenu_Buffer_Size;
 149                                         QuickMenu_Buffer_Set(QM_TAG_SUBMENU, argv(0));
 150                                 }
 151                         }
 152                         ++QuickMenu_Buffer_Size;
 153                 }
 154                 fclose(fh);
 155         }
 156         else
 157         {
 158                 LOG_WARNINGF("Unrecognized mode %s\n", mode);
 159                 return false;
 160         }
 161
 162         if (QuickMenu_Buffer_Size <= 0)
 163         {
 164                 buf_del(QuickMenu_Buffer);
 165                 QuickMenu_Buffer = -1;
 166                 return false;
 167         }
 168
 169         if(mode == "file")
 170                 QuickMenu_Page_Load(submenu, 0);
 171         else
 172                 QuickMenu_Page_Load("", 0);
 173
 174         hud_panel_quickmenu = 1;
 175         if(autocvar_hud_cursormode)
 176                 setcursormode(1);
 177         hudShiftState = 0;
 178
 179         QuickMenu_TimeOut = ((autocvar_hud_panel_quickmenu_time > 0) ? time + autocvar_hud_panel_quickmenu_time : 0);
 180         return true;
 181 }
 182
 183 void QuickMenu_Buffer_Close()
 184 {
 185         if (QuickMenu_Buffer >= 0)
 186         {
 187                 buf_del(QuickMenu_Buffer);
 188                 QuickMenu_Buffer = -1;
 189                 QuickMenu_Buffer_Size = 0;
 190         }
 191 }
 192
 193 void QuickMenu_Close()
 194 {
 195         if (QuickMenu_CurrentSubMenu)
 196                 strunzone(QuickMenu_CurrentSubMenu);
 197         QuickMenu_CurrentSubMenu = string_null;
 198         int i;
 199         for (i = 0; i < QUICKMENU_MAXLINES; ++i)
 200                 QuickMenu_Page_ClearEntry(i);
 201         QuickMenu_Page_Entries = 0;
 202         hud_panel_quickmenu = 0;
 203         mouseClicked = 0;
 204         prevMouseClicked = 0;
 205         QuickMenu_Buffer_Close();
 206
 207         if(autocvar_hud_cursormode)
 208         if(!mv_active)
 209                 setcursormode(0);
 210 }
 211
 212 // It assumes submenu open tag is already detected
 213 void QuickMenu_skip_submenu(string submenu)
 214 {
 215         string s, z_submenu;
 216         z_submenu = strzone(submenu);
 217         for(++QuickMenu_Buffer_Index ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 218         {
 219                 s = QuickMenu_Buffer_Get();
 220                 if(substring(s, 0, 1) != QM_TAG_SUBMENU)
 221                         continue;
 222                 if(substring(s, 1, -1) == z_submenu) // submenu end
 223                         break;
 224                 QuickMenu_skip_submenu(substring(s, 1, -1));
 225         }
 226         strunzone(z_submenu);
 227 }
 228
 229 bool QuickMenu_IsOpened()
 230 {
 231         return (QuickMenu_Page_Entries > 0);
 232 }
 233
 234 void HUD_Quickmenu_PlayerListEntries(string cmd, int teamplayers, bool without_me);
 235 bool HUD_Quickmenu_PlayerListEntries_Create(string cmd, int teamplayers, bool without_me)
 236 {
 237     TC(int, teamplayers); TC(bool, without_me);
 238         int i;
 239         for(i = 0; i < QUICKMENU_MAXLINES; ++i)
 240                 QuickMenu_Page_ClearEntry(i);
 241         QuickMenu_Buffer_Close();
 242
 243         QuickMenu_Buffer = buf_create();
 244         if(QuickMenu_Buffer < 0)
 245                 return false;
 246
 247         HUD_Quickmenu_PlayerListEntries(cmd, teamplayers, without_me);
 248
 249         if(QuickMenu_Buffer_Size <= 0)
 250         {
 251                 buf_del(QuickMenu_Buffer);
 252                 QuickMenu_Buffer = -1;
 253                 return false;
 254         }
 255         return true;
 256 }
 257
 258 // new_page 0 means page 0, new_page != 0 means next page
 259 int QuickMenu_Buffer_Index_Prev;
 260 bool QuickMenu_Page_Load(string target_submenu, bool new_page)
 261 {
 262     TC(bool, new_page);
 263         string s = string_null, cmd = string_null, z_submenu;
 264
 265         if (new_page == 0)
 266                 QuickMenu_Page = 0;
 267         else
 268                 ++QuickMenu_Page;
 269
 270         z_submenu = strzone(target_submenu);
 271         if (QuickMenu_CurrentSubMenu)
 272                 strunzone(QuickMenu_CurrentSubMenu);
 273         QuickMenu_CurrentSubMenu = strzone(z_submenu);
 274
 275         QuickMenu_IsLastPage = true;
 276         QuickMenu_Page_Entries = 0;
 277
 278         QuickMenu_Buffer_Index = 0;
 279         if (z_submenu != "")
 280         {
 281                 // skip everything until the submenu open tag is found
 282                 for( ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 283                 {
 284                         s = QuickMenu_Buffer_Get();
 285                         if(substring(s, 0, 1) == QM_TAG_SUBMENU && substring(s, 1, -1) == z_submenu)
 286                         {
 287                                 // printf("^3 beginning of %s\n", z_submenu);
 288                                 ++QuickMenu_Buffer_Index;
 289                                 break; // target_submenu found!
 290                         }
 291                         // printf("^1 skipping %s\n", s);
 292                 }
 293                 if(QuickMenu_Buffer_Index == QuickMenu_Buffer_Size)
 294                         LOG_WARNINGF("Couldn't find submenu \"%s\"\n", z_submenu);
 295         }
 296
 297         // only the last page can contain up to QUICKMENU_MAXLINES entries
 298         // the other ones contain only (QUICKMENU_MAXLINES - 2) entries
 299         // so that the panel can show an empty row and "Continue..."
 300         float first_entry = QuickMenu_Page * (QUICKMENU_MAXLINES - 2);
 301         int entry_num = 0; // counts entries in target_submenu
 302         for( ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 303         {
 304                 s = QuickMenu_Buffer_Get();
 305
 306                 if(z_submenu != "" && substring(s, 1, -1) == z_submenu)
 307                 {
 308                         // printf("^3 end of %s\n", z_submenu);
 309                         break;
 310                 }
 311
 312                 if(entry_num >= first_entry)
 313                 {
 314                         ++QuickMenu_Page_Entries;
 315                         if(QuickMenu_Page_Entries == QUICKMENU_MAXLINES - 2)
 316                                 QuickMenu_Buffer_Index_Prev = QuickMenu_Buffer_Index;
 317                         else if(QuickMenu_Page_Entries == QUICKMENU_MAXLINES)
 318                         {
 319                                 QuickMenu_Page_ClearEntry(QUICKMENU_MAXLINES - 1);
 320                                 QuickMenu_Buffer_Index = QuickMenu_Buffer_Index_Prev;
 321                                 QuickMenu_IsLastPage = false;
 322                                 break;
 323                         }
 324                 }
 325
 326                 // NOTE: entries are loaded starting from 1, not from 0
 327                 if(substring(s, 0, 1) == QM_TAG_SUBMENU)
 328                 {
 329                         if(entry_num >= first_entry)
 330                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, substring(s, 1, -1), "");
 331                         QuickMenu_skip_submenu(substring(s, 1, -1));
 332                 }
 333                 else if(entry_num >= first_entry && substring(s, 0, 1) == QM_TAG_TITLE)
 334                 {
 335                         ++QuickMenu_Buffer_Index;
 336                         cmd = QuickMenu_Buffer_Get();
 337                         string command_code = substring(cmd, 0, 1);
 338                         if(command_code == QM_TAG_COMMAND)
 339                                 cmd = substring(cmd, 1, -1);
 340                         else if(command_code == QM_TAG_PLCOMMAND)
 341                         {
 342                                 // throw away the current quickmenu buffer and load a new one
 343                                 cmd = substring(cmd, 1, -1);
 344                                 strunzone(z_submenu);
 345                                 if(HUD_Quickmenu_PlayerListEntries_Create(cmd, stof(substring(s, 1, 1)), stof(substring(s, 2, 1))))
 346                                         return QuickMenu_Page_Load("", 0);
 347                                 QuickMenu_Close();
 348                                 return false;
 349                         }
 350
 351                         tokenize_console(cmd);
 352                         QuickMenu_Page_Command_Type[QuickMenu_Page_Entries] = (argv(1) && argv(0) == "toggle");
 353
 354                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, substring(s, 1, -1), cmd);
 355                 }
 356
 357                 ++entry_num;
 358         }
 359         strunzone(z_submenu);
 360         if (QuickMenu_Page_Entries == 0)
 361         {
 362                 QuickMenu_Close();
 363                 return false;
 364         }
 365         QuickMenu_TimeOut = ((autocvar_hud_panel_quickmenu_time > 0) ? time + autocvar_hud_panel_quickmenu_time : 0);
 366         return true;
 367 }
 368
 369 bool QuickMenu_ActionForNumber(int num)
 370 {
 371     TC(int, num);
 372         if (!QuickMenu_IsLastPage)
 373         {
 374                 if (num < 0 || num >= QUICKMENU_MAXLINES)
 375                         return false;
 376                 if (num == QUICKMENU_MAXLINES - 1)
 377                         return false;
 378                 if (num == 0)
 379                 {
 380                         QuickMenu_Page_Load(QuickMenu_CurrentSubMenu, +1);
 381                         return false;
 382                 }
 383         } else if (num <= 0 || num > QuickMenu_Page_Entries)
 384                 return false;
 385
 386         if (QuickMenu_Page_Command[num] != "")
 387         {
 388                 localcmd(strcat("\n", QuickMenu_Page_Command[num], "\n"));
 389                 QuickMenu_TimeOut = ((autocvar_hud_panel_quickmenu_time > 0) ? time + autocvar_hud_panel_quickmenu_time : 0);
 390                 return true;
 391         }
 392         if (QuickMenu_Page_Description[num] != "")
 393                 QuickMenu_Page_Load(QuickMenu_Page_Description[num], 0);
 394         return false;
 395 }
 396
 397 void QuickMenu_Page_ActiveEntry(int entry_num)
 398 {
 399     TC(int, entry_num);
 400         QuickMenu_Page_ActivatedEntry = entry_num;
 401         QuickMenu_Page_ActivatedEntry_Time = time + 0.1;
 402         if(QuickMenu_Page_Command[QuickMenu_Page_ActivatedEntry])
 403         {
 404                 bool f = QuickMenu_ActionForNumber(QuickMenu_Page_ActivatedEntry);
 405                 // toggle commands don't close the quickmenu
 406                 if(QuickMenu_Page_Command_Type[QuickMenu_Page_ActivatedEntry] == 1)
 407                         QuickMenu_Page_ActivatedEntry_Close = false;
 408                 else
 409                         QuickMenu_Page_ActivatedEntry_Close = (f && !(hudShiftState & S_CTRL));
 410         }
 411         else
 412                 QuickMenu_Page_ActivatedEntry_Close = (!(hudShiftState & S_CTRL));
 413 }
 414
 415 bool QuickMenu_InputEvent(int bInputType, float nPrimary, float nSecondary)
 416 {
 417     TC(int, bInputType);
 418         // we only care for keyboard events
 419         if(bInputType == 2)
 420                 return false;
 421
 422         if(!QuickMenu_IsOpened() || autocvar__hud_configure || mv_active)
 423                 return false;
 424
 425         if(bInputType == 3)
 426         {
 427                 mousepos.x = nPrimary;
 428                 mousepos.y = nSecondary;
 429                 return true;
 430         }
 431
 432         // allow console bind to work
 433         string con_keys;
 434         float keys;
 435         con_keys = findkeysforcommand("toggleconsole", 0);
 436         keys = tokenize(con_keys); // findkeysforcommand returns data for this
 437
 438         bool hit_con_bind = false;
 439         int i;
 440         for (i = 0; i < keys; ++i)
 441         {
 442                 if(nPrimary == stof(argv(i)))
 443                         hit_con_bind = true;
 444         }
 445
 446         if(bInputType == 0) {
 447                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 448                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 449                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 450         }
 451         else if(bInputType == 1) {
 452                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 453                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 454                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 455         }
 456
 457         if(nPrimary == K_ESCAPE)
 458         {
 459                 if (bInputType == 1)
 460                         return true;
 461                 QuickMenu_Close();
 462         }
 463         else if(nPrimary >= '0' && nPrimary <= '9')
 464         {
 465                 if (bInputType == 1)
 466                         return true;
 467                 QuickMenu_Page_ActiveEntry(stof(chr2str(nPrimary)));
 468         }
 469         if(nPrimary == K_MOUSE1)
 470         {
 471                 if(bInputType == 0) // key pressed
 472                         mouseClicked |= S_MOUSE1;
 473                 else if(bInputType == 1) // key released
 474                         mouseClicked -= (mouseClicked & S_MOUSE1);
 475         }
 476         else if(nPrimary == K_MOUSE2)
 477         {
 478                 if(bInputType == 0) // key pressed
 479                         mouseClicked |= S_MOUSE2;
 480                 else if(bInputType == 1) // key released
 481                         mouseClicked -= (mouseClicked & S_MOUSE2);
 482         }
 483         else if(hit_con_bind)
 484                 return false;
 485
 486         return true;
 487 }
 488
 489 void QuickMenu_Mouse()
 490 {
 491         if(mv_active) return;
 492
 493         if(!mouseClicked)
 494         if(prevMouseClicked & S_MOUSE2)
 495         {
 496                 QuickMenu_Close();
 497                 return;
 498         }
 499
 500         if(!autocvar_hud_cursormode)
 501         {
 502                 mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
 503
 504                 mousepos.x = bound(0, mousepos.x, vid_conwidth);
 505                 mousepos.y = bound(0, mousepos.y, vid_conheight);
 506         }
 507
 508         HUD_Panel_UpdateCvars();
 509
 510         if(panel_bg_padding)
 511         {
 512                 panel_pos += '1 1 0' * panel_bg_padding;
 513                 panel_size -= '2 2 0' * panel_bg_padding;
 514         }
 515
 516         float first_entry_pos, entries_height;
 517         vector fontsize;
 518         fontsize = '1 1 0' * (panel_size.y / QUICKMENU_MAXLINES);
 519         first_entry_pos = panel_pos.y + ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y) / 2;
 520         entries_height = panel_size.y - ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y);
 521
 522         if (mousepos.x >= panel_pos.x && mousepos.y >= first_entry_pos && mousepos.x <= panel_pos.x + panel_size.x && mousepos.y <= first_entry_pos + entries_height)
 523         {
 524                 float entry_num;
 525                 entry_num = floor((mousepos.y - first_entry_pos) / fontsize.y);
 526                 if (QuickMenu_IsLastPage || entry_num != QUICKMENU_MAXLINES - 2)
 527                 {
 528                         panel_pos.y = first_entry_pos + entry_num * fontsize.y;
 529                         vector color;
 530                         if(mouseClicked & S_MOUSE1)
 531                                 color = '0.5 1 0.5';
 532                         else if(hudShiftState & S_CTRL)
 533                                 color = '1 1 0.3';
 534                         else
 535                                 color = '1 1 1';
 536                         drawfill(panel_pos, eX * panel_size.x + eY * fontsize.y, color, .2, DRAWFLAG_NORMAL);
 537
 538                         if(!mouseClicked && (prevMouseClicked & S_MOUSE1))
 539                                 QuickMenu_Page_ActiveEntry((entry_num < QUICKMENU_MAXLINES - 1) ? entry_num + 1 : 0);
 540                 }
 541         }
 542
 543         draw_cursor_normal(mousepos, '1 1 1', 0.8);
 544
 545         prevMouseClicked = mouseClicked;
 546 }
 547
 548 void HUD_Quickmenu_DrawEntry(vector pos, string desc, string option, vector fontsize)
 549 {
 550         string entry;
 551         float offset;
 552         float desc_width = panel_size.x;
 553         if(option)
 554         {
 555                 string pic = strcat(hud_skin_path, "/", option);
 556                 if(precache_pic(pic) == "")
 557                         pic = strcat("gfx/hud/default/", option);
 558                 vector option_size = '1 1 0' * fontsize.y * 0.8;
 559                 desc_width -= option_size.x;
 560                 drawpic(pos + eX * desc_width + eY * (fontsize.y - option_size.y) / 2, pic, option_size, '1 1 1', panel_fg_alpha, DRAWFLAG_ADDITIVE);
 561                 desc_width -= fontsize.x / 4;
 562         }
 563         entry = textShortenToWidth(desc, desc_width, fontsize, stringwidth_colors);
 564         if (autocvar_hud_panel_quickmenu_align > 0)
 565         {
 566                 float real_desc_width = stringwidth_colors(entry, fontsize);
 567                 offset = (desc_width - real_desc_width) * min(autocvar_hud_panel_quickmenu_align, 1);
 568
 569                 if(option)
 570                 {
 571                         // when there's enough room align description regardless the checkbox
 572                         float extra_offset = (panel_size.x - desc_width) * min(autocvar_hud_panel_quickmenu_align, 1);
 573                         if(offset + real_desc_width + extra_offset < desc_width)
 574                                 offset += extra_offset;
 575                         else
 576                                 offset = max(0, desc_width - real_desc_width);
 577                 }
 578                 drawcolorcodedstring(pos + eX * offset, entry, fontsize, panel_fg_alpha, DRAWFLAG_ADDITIVE);
 579         }
 580         else
 581                 drawcolorcodedstring(pos, entry, fontsize, panel_fg_alpha, DRAWFLAG_ADDITIVE);
 582 }
 583
 584 void HUD_QuickMenu()
 585 {
 586         if(!autocvar__hud_configure)
 587         {
 588                 if (hud_configure_prev && hud_configure_prev != -1)
 589                         QuickMenu_Close();
 590
 591                 if(!hud_draw_maximized) return;
 592                 if(mv_active) return;
 593                 //if(!autocvar_hud_panel_quickmenu) return;
 594                 if(!hud_panel_quickmenu) return;
 595
 596                 if(QuickMenu_TimeOut)
 597                 if(time > QuickMenu_TimeOut)
 598                 {
 599                         QuickMenu_Close();
 600                         return;
 601                 }
 602         }
 603         else
 604         {
 605                 if(!QuickMenu_IsOpened())
 606                 {
 607                         QuickMenu_Page_Entries = 1;
 608                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Submenu%d"), QuickMenu_Page_Entries), "");
 609                         ++QuickMenu_Page_Entries;
 610                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Submenu%d"), QuickMenu_Page_Entries), "");
 611                         ++QuickMenu_Page_Entries;
 612                         // although real command doesn't matter here, it must not be empty
 613                         // otherwise the entry is displayed like a submenu
 614                         for (; QuickMenu_Page_Entries < QUICKMENU_MAXLINES - 1; ++QuickMenu_Page_Entries)
 615                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Command%d"), QuickMenu_Page_Entries), "-");
 616                         ++QuickMenu_Page_Entries;
 617                         QuickMenu_Page_ClearEntry(QuickMenu_Page_Entries);
 618                         QuickMenu_IsLastPage = false;
 619                 }
 620         }
 621
 622         HUD_Panel_UpdateCvars();
 623
 624         HUD_Scale_Enable();
 625         HUD_Panel_DrawBg(1);
 626
 627         if(panel_bg_padding)
 628         {
 629                 panel_pos += '1 1 0' * panel_bg_padding;
 630                 panel_size -= '2 2 0' * panel_bg_padding;
 631         }
 632
 633         int i;
 634         vector fontsize;
 635         string color;
 636         fontsize = '1 1 0' * (panel_size.y / QUICKMENU_MAXLINES);
 637
 638         if (!QuickMenu_IsLastPage)
 639         {
 640                 color = "^5";
 641                 HUD_Quickmenu_DrawEntry(panel_pos + eY * (panel_size.y - fontsize.y), sprintf("%d: %s%s", 0, color, _("Continue...")), string_null, fontsize);
 642         }
 643         else
 644                 panel_pos.y += ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y) / 2;
 645
 646         for (i = 1; i <= QuickMenu_Page_Entries; ++i) {
 647                 if (QuickMenu_Page_Description[i] == "")
 648                         break;
 649                 string option = string_null;
 650                 if (QuickMenu_Page_Command[i] == "")
 651                         color = "^4";
 652                 else
 653                 {
 654                         color = "^3";
 655                         if(QuickMenu_Page_Command_Type[i] == 1) // toggle command
 656                         {
 657                                 int end = strstrofs(QuickMenu_Page_Command[i], ";", 0);
 658                                 if(end < 0)
 659                                         tokenize_console(QuickMenu_Page_Command[i]);
 660                                 else
 661                                         tokenize_console(substring(QuickMenu_Page_Command[i], 0, end));
 662
 663                                 //if(argv(1) && argv(0) == "toggle") // already checked
 664                                 {
 665                                         // "enable feature xxx" "toggle xxx" (or "toggle xxx 1 0")
 666                                         // "disable feature xxx" "toggle xxx 0 1"
 667                                         float ON_value = 1, OFF_value = 0;
 668                                         if(argv(2))
 669                                                 ON_value = stof(argv(2));
 670
 671                                         if(argv(3))
 672                                                 OFF_value = stof(argv(3));
 673                                         else
 674                                                 OFF_value = !ON_value;
 675
 676                                         float value = cvar(argv(1));
 677                                         if(value == ON_value)
 678                                                 option = "checkbox_checked";
 679                                         else if(value == OFF_value)
 680                                                 option = "checkbox_empty";
 681                                         else
 682                                                 option = "checkbox_undefined";
 683                                 }
 684                         }
 685                 }
 686                 HUD_Quickmenu_DrawEntry(panel_pos, sprintf("%d: %s%s", i, color, QuickMenu_Page_Description[i]), option, fontsize);
 687
 688                 if(QuickMenu_Page_ActivatedEntry_Time && time < QuickMenu_Page_ActivatedEntry_Time
 689                         && QuickMenu_Page_ActivatedEntry == i)
 690                         drawfill(panel_pos, eX * panel_size.x + eY * fontsize.y, '0.5 1 0.5', .2, DRAWFLAG_NORMAL);
 691
 692                 panel_pos.y += fontsize.y;
 693         }
 694
 695         if(QuickMenu_Page_ActivatedEntry >= 0 && time >= QuickMenu_Page_ActivatedEntry_Time)
 696         {
 697                 if(!QuickMenu_Page_Command[QuickMenu_Page_ActivatedEntry])
 698                 {
 699                         bool f = QuickMenu_ActionForNumber(QuickMenu_Page_ActivatedEntry);
 700                         if(f && QuickMenu_Page_ActivatedEntry_Close)
 701                                 QuickMenu_Close();
 702                 }
 703                 else if(QuickMenu_Page_ActivatedEntry_Close)
 704                         QuickMenu_Close();
 705                 QuickMenu_Page_ActivatedEntry = -1;
 706                 QuickMenu_Page_ActivatedEntry_Time = 0;
 707         }
 708 }
 709
 710
 711 #define QUICKMENU_SMENU(submenu,eng_submenu) { \
 712         if(target_submenu == eng_submenu && target_submenu_found) \
 713                 return; /* target_submenu entries are now loaded, exit */ \
 714         if(QuickMenu_Buffer_Size < QUICKMENU_BUFFER_MAXENTRIES) \
 715                 QuickMenu_Buffer_Set(QM_TAG_SUBMENU, submenu); \
 716         ++QuickMenu_Buffer_Size; \
 717         if(target_submenu == eng_submenu && !target_submenu_found) { \
 718                 QuickMenu_Buffer_Size = 0; /* enable load of next entries */ \
 719                 target_submenu_found = true; \
 720         } \
 721 }
 722
 723 #define QUICKMENU_ENTRY(title,command) { \
 724         if(QuickMenu_Buffer_Size + 1 < QUICKMENU_BUFFER_MAXENTRIES) \
 725         { \
 726                 QuickMenu_Buffer_Set(QM_TAG_TITLE, title); \
 727                 ++QuickMenu_Buffer_Size; \
 728                 QuickMenu_Buffer_Set(QM_TAG_COMMAND, command); \
 729         } \
 730         ++QuickMenu_Buffer_Size; \
 731 }
 732
 733 #define QUICKMENU_SMENU_PL(submenu,eng_submenu,command,teamplayers,without_me) { \
 734         if(QuickMenu_Buffer_Size + 3 < QUICKMENU_BUFFER_MAXENTRIES) {\
 735                 QUICKMENU_SMENU(submenu,eng_submenu) \
 736                 QuickMenu_Buffer_Set(QM_TAG_TITLE, strcat(ftos(teamplayers), ftos(without_me))); \
 737                 ++QuickMenu_Buffer_Size; \
 738                 QuickMenu_Buffer_Set(QM_TAG_PLCOMMAND, command); \
 739                 ++QuickMenu_Buffer_Size; \
 740                 QUICKMENU_SMENU(submenu,eng_submenu) \
 741         } \
 742 }
 743
 744
 745
 746 // useful to Translate a string inside the Command
 747 #define QUICKMENU_ENTRY_TC(title,command,text,translated_text) {\
 748         if(prvm_language == "en") \
 749                 QUICKMENU_ENTRY(title, sprintf(command, text)) \
 750         else if(!autocvar_hud_panel_quickmenu_translatecommands || translated_text == text) \
 751                 QUICKMENU_ENTRY(strcat("(en)", title), sprintf(command, text)) \
 752         else \
 753                 QUICKMENU_ENTRY(strcat("(", prvm_language, ")", title), sprintf(command, translated_text)) \
 754 }
 755
 756 void HUD_Quickmenu_PlayerListEntries(string cmd, int teamplayers, bool without_me)
 757 {
 758     TC(int, teamplayers); TC(bool, without_me);
 759         entity pl;
 760         if(teamplayers && !team_count)
 761                 return;
 762
 763         for(pl = players.sort_next; pl; pl = pl.sort_next)
 764         {
 765                 if(teamplayers == 1 && (pl.team != myteam || pl.team == NUM_SPECTATOR)) // only own team players
 766                         continue;
 767                 if(teamplayers == 2 && (pl.team == myteam || pl.team == NUM_SPECTATOR)) // only enemy team players
 768                         continue;
 769                 if(without_me && pl.sv_entnum == player_localnum)
 770                         continue;
 771                 QUICKMENU_ENTRY(entcs_GetName(pl.sv_entnum), sprintf(cmd, entcs_GetName(pl.sv_entnum)))
 772         }
 773
 774         return;
 775 }
 776
 777
 778 // Specifying target_submenu, this function only loads entries inside target_submenu
 779 // NOTE: alternatively we could have loaded the whole default quickmenu and
 780 // then called QuickMenu_Page_Load(target_submenu, 0);
 781 // but this sytem is more reliable since we can always refer to target_submenu
 782 // with the English title even if a translation is active
 783 void QuickMenu_Default(string target_submenu)
 784 {
 785         bool target_submenu_found = false;
 786         if(target_submenu != "")
 787                 QuickMenu_Buffer_Size = QUICKMENU_BUFFER_MAXENTRIES; // forbids load of next entries until target_submenu
 788
 789         QUICKMENU_SMENU(CTX(_("QMCMD^Chat")), "Chat")
 790                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^nice one")), "say %s", ":-) / nice one", CTX(_("QMCMD^:-) / nice one")))
 791                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^good game")), "say %s", "good game", CTX(_("QMCMD^good game")))
 792                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^hi / good luck")), "say %s", "hi / good luck and have fun", CTX(_("QMCMD^hi / good luck and have fun")))
 793         QUICKMENU_SMENU(CTX(_("QMCMD^Chat")), "Chat")
 794
 795         if(teamplay)
 796         {
 797         QUICKMENU_SMENU(CTX(_("QMCMD^Team chat")), "Team chat")
 798                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^quad soon")), "say_team %s", "quad soon", CTX(_("QMCMD^quad soon")))
 799                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^free item, icon")), "say_team %s; g_waypointsprite_team_here_p", "free item %x^7 (l:%y^7)", CTX(_("QMCMD^free item %x^7 (l:%y^7)")))
 800                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^took item, icon")), "say_team %s; g_waypointsprite_team_here", "took item (l:%l^7)", CTX(_("QMCMD^took item (l:%l^7)")))
 801                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^negative")), "say_team %s", "negative", CTX(_("QMCMD^negative")))
 802                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^positive")), "say_team %s", "positive", CTX(_("QMCMD^positive")))
 803                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^need help, icon")), "say_team %s; g_waypointsprite_team_helpme; cmd voice needhelp", "need help (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^need help (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 804                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^enemy seen, icon")), "say_team %s; g_waypointsprite_team_danger_p; cmd voice incoming", "enemy seen (l:%y^7)", CTX(_("QMCMD^enemy seen (l:%y^7)")))
 805                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^flag seen, icon")), "say_team %s; g_waypointsprite_team_here_p; cmd voice seenflag", "flag seen (l:%y^7)", CTX(_("QMCMD^flag seen (l:%y^7)")))
 806                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^defending, icon")), "say_team %s; g_waypointsprite_team_here", "defending (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^defending (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 807                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^roaming, icon")), "say_team %s; g_waypointsprite_team_here", "roaming (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^roaming (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 808                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^attacking, icon")), "say_team %s; g_waypointsprite_team_here", "attacking (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^attacking (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 809                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^killed flag, icon")), "say_team %s; g_waypointsprite_team_here_p", "killed flagcarrier (l:%y^7)", CTX(_("QMCMD^killed flagcarrier (l:%y^7)")))
 810                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^dropped flag, icon")), "say_team %s; g_waypointsprite_team_here_d", "dropped flag (l:%d^7)", CTX(_("QMCMD^dropped flag (l:%d^7)")))
 811                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^drop gun, icon")), "say_team %s; g_waypointsprite_team_here; wait; dropweapon", "dropped gun %w^7 (l:%l^7)", CTX(_("QMCMD^dropped gun %w^7 (l:%l^7)")))
 812                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^drop flag/key, icon")), "say_team %s; g_waypointsprite_team_here; wait; use", "dropped flag/key %w^7 (l:%l^7)", CTX(_("QMCMD^dropped flag/key %w^7 (l:%l^7)")))
 813         QUICKMENU_SMENU(CTX(_("QMCMD^Team chat")), "Team chat")
 814         }
 815
 816         QUICKMENU_SMENU_PL(CTX(_("QMCMD^Send private message to")), "Send private message to", "commandmode tell \"%s^7\"", 0, 1)
 817
 818         QUICKMENU_SMENU(CTX(_("QMCMD^Settings")), "Settings")
 819                 QUICKMENU_SMENU(CTX(_("QMCMD^View/HUD settings")), "View/HUD settings")
 820                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person view")), "toggle chase_active")
 821                         QUICKMENU_ENTRY(CTX(_("QMCMD^Player models like mine")), "toggle cl_forceplayermodels")
 822                         QUICKMENU_ENTRY(CTX(_("QMCMD^Names above players")), "toggle hud_shownames")
 823                         QUICKMENU_ENTRY(CTX(_("QMCMD^Crosshair per weapon")), "toggle crosshair_per_weapon")
 824                         QUICKMENU_ENTRY(CTX(_("QMCMD^FPS")), "toggle hud_panel_engineinfo")
 825                         QUICKMENU_ENTRY(CTX(_("QMCMD^Net graph")), "toggle shownetgraph")
 826                 QUICKMENU_SMENU(CTX(_("QMCMD^View/HUD settings")), "View/HUD settings")
 827
 828                 QUICKMENU_SMENU(CTX(_("QMCMD^Sound settings")), "Sound settings")
 829                         QUICKMENU_ENTRY(CTX(_("QMCMD^Hit sound")), "toggle cl_hitsound")
 830                         QUICKMENU_ENTRY(CTX(_("QMCMD^Chat sound")), "toggle con_chatsound")
 831                 QUICKMENU_SMENU(CTX(_("QMCMD^Sound settings")), "Sound settings")
 832
 833                 if(spectatee_status > 0)
 834                 {
 835                 QUICKMENU_SMENU(CTX(_("QMCMD^Spectator camera")), "Spectator camera")
 836                         QUICKMENU_ENTRY(CTX(_("QMCMD^1st person")), "chase_active 0; -use")
 837                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person around player")), "chase_active 1; +use")
 838                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person behind")), "chase_active 1; -use")
 839                 QUICKMENU_SMENU(CTX(_("QMCMD^Spectator camera")), "Spectator camera")
 840                 }
 841
 842                 if(spectatee_status == -1)
 843                 {
 844                 QUICKMENU_SMENU(CTX(_("QMCMD^Observer camera")), "Observer camera")
 845                         QUICKMENU_ENTRY(CTX(_("QMCMD^Increase speed")), "weapnext")
 846                         QUICKMENU_ENTRY(CTX(_("QMCMD^Decrease speed")), "weapprev")
 847                         QUICKMENU_ENTRY(CTX(_("QMCMD^Wall collision off")), "+use")
 848                         QUICKMENU_ENTRY(CTX(_("QMCMD^Wall collision on")), "-use")
 849                 QUICKMENU_SMENU(CTX(_("QMCMD^Observer camera")), "Observer camera")
 850                 }
 851
 852                 QUICKMENU_ENTRY(CTX(_("QMCMD^Fullscreen")), "toggle vid_fullscreen; vid_restart")
 853                 if(prvm_language != "en")
 854                 QUICKMENU_ENTRY(CTX(_("QMCMD^Translate chat messages")), "toggle hud_panel_quickmenu_translatecommands")
 855         QUICKMENU_SMENU(CTX(_("QMCMD^Settings")), "Settings")
 856
 857         QUICKMENU_SMENU(CTX(_("QMCMD^Call a vote")), "Call a vote")
 858                 QUICKMENU_ENTRY(CTX(_("QMCMD^Restart the map")), "vcall restart")
 859                 QUICKMENU_ENTRY(CTX(_("QMCMD^End match")), "vcall endmatch")
 860                 if(STAT(TIMELIMIT) > 0)
 861                 {
 862                 QUICKMENU_ENTRY(CTX(_("QMCMD^Reduce match time")), "vcall reducematchtime")
 863                 QUICKMENU_ENTRY(CTX(_("QMCMD^Extend match time")), "vcall extendmatchtime")
 864                 }
 865                 if(teamplay)
 866                 QUICKMENU_ENTRY(CTX(_("QMCMD^Shuffle teams")), "vcall shuffleteams")
 867         QUICKMENU_SMENU(CTX(_("QMCMD^Call a vote")), "Call a vote")
 868
 869         if(target_submenu != "" && !target_submenu_found)
 870         {
 871                 LOG_WARNINGF("Couldn't find submenu \"%s\"\n", target_submenu);
 872                 if(prvm_language != "en")
 873                         LOG_WARNINGF("^3Warning: submenu must be in English\n", target_submenu);
 874                 QuickMenu_Buffer_Size = 0;
 875         }
 876 }
 877 #undef QUICKMENU_SMENU
 878 #undef QUICKMENU_ENTRY
 879 #undef QUICKMENU_ENTRY_TC