qcsrc/client/hud/panel/radar.qc

   1 // Radar (#6)
   2
   3 float HUD_Radar_Clickable()
   4 {
   5         return hud_panel_radar_mouse && !hud_panel_radar_temp_hidden;
   6 }
   7
   8 void HUD_Radar_Show_Maximized(bool doshow,float clickable)
   9 {
  10         hud_panel_radar_maximized = doshow;
  11         hud_panel_radar_temp_hidden = 0;
  12
  13         if ( doshow )
  14         {
  15                 if (clickable)
  16                 {
  17                         if(autocvar_hud_cursormode)
  18                                 setcursormode(1);
  19                         hud_panel_radar_mouse = 1;
  20                 }
  21         }
  22         else if ( hud_panel_radar_mouse )
  23         {
  24                 hud_panel_radar_mouse = 0;
  25                 mouseClicked = 0;
  26                 if(autocvar_hud_cursormode)
  27                 if(!mv_active)
  28                         setcursormode(0);
  29         }
  30 }
  31 void HUD_Radar_Hide_Maximized()
  32 {
  33         HUD_Radar_Show_Maximized(false,false);
  34 }
  35
  36
  37 float HUD_Radar_InputEvent(float bInputType, float nPrimary, float nSecondary)
  38 {
  39         if(!hud_panel_radar_maximized || !hud_panel_radar_mouse ||
  40                 autocvar__hud_configure || mv_active)
  41                 return false;
  42
  43         if(bInputType == 3)
  44         {
  45                 mousepos_x = nPrimary;
  46                 mousepos_y = nSecondary;
  47                 return true;
  48         }
  49
  50         if(nPrimary == K_MOUSE1)
  51         {
  52                 if(bInputType == 0) // key pressed
  53                         mouseClicked |= S_MOUSE1;
  54                 else if(bInputType == 1) // key released
  55                         mouseClicked -= (mouseClicked & S_MOUSE1);
  56         }
  57         else if(nPrimary == K_MOUSE2)
  58         {
  59                 if(bInputType == 0) // key pressed
  60                         mouseClicked |= S_MOUSE2;
  61                 else if(bInputType == 1) // key released
  62                         mouseClicked -= (mouseClicked & S_MOUSE2);
  63         }
  64         else if ( nPrimary == K_ESCAPE && bInputType == 0 )
  65         {
  66                 HUD_Radar_Hide_Maximized();
  67         }
  68         else
  69         {
  70                 // allow console/use binds to work without hiding the map
  71                 string con_keys;
  72                 float keys;
  73                 float i;
  74                 con_keys = strcat(findkeysforcommand("toggleconsole", 0)," ",findkeysforcommand("+use", 0)) ;
  75                 keys = tokenize(con_keys); // findkeysforcommand returns data for this
  76                 for (i = 0; i < keys; ++i)
  77                 {
  78                         if(nPrimary == stof(argv(i)))
  79                                 return false;
  80                 }
  81
  82                 if ( getstati(STAT_HEALTH) <= 0 )
  83                 {
  84                         // Show scoreboard
  85                         if ( bInputType < 2 )
  86                         {
  87                                 con_keys = findkeysforcommand("+showscores", 0);
  88                                 keys = tokenize(con_keys);
  89                                 for (i = 0; i < keys; ++i)
  90                                 {
  91                                         if ( nPrimary == stof(argv(i)) )
  92                                         {
  93                                                 hud_panel_radar_temp_hidden = bInputType == 0;
  94                                                 return false;
  95                                         }
  96                                 }
  97                         }
  98                 }
  99                 else if ( bInputType == 0 )
 100                         HUD_Radar_Hide_Maximized();
 101
 102                 return false;
 103         }
 104
 105         return true;
 106 }
 107
 108 void HUD_Radar_Mouse()
 109 {
 110         if ( !hud_panel_radar_mouse ) return;
 111         if(mv_active) return;
 112
 113         if ( intermission )
 114         {
 115                 HUD_Radar_Hide_Maximized();
 116                 return;
 117         }
 118
 119         if(mouseClicked & S_MOUSE2)
 120         {
 121                 HUD_Radar_Hide_Maximized();
 122                 return;
 123         }
 124
 125         if(!autocvar_hud_cursormode)
 126         {
 127                 mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
 128
 129                 mousepos_x = bound(0, mousepos_x, vid_conwidth);
 130                 mousepos_y = bound(0, mousepos_y, vid_conheight);
 131         }
 132
 133         HUD_Panel_UpdateCvars();
 134
 135
 136         panel_size = autocvar_hud_panel_radar_maximized_size;
 137         panel_size_x = bound(0.2, panel_size_x, 1) * vid_conwidth;
 138         panel_size_y = bound(0.2, panel_size_y, 1) * vid_conheight;
 139         panel_pos_x = (vid_conwidth - panel_size_x) / 2;
 140         panel_pos_y = (vid_conheight - panel_size_y) / 2;
 141
 142         if(mouseClicked & S_MOUSE1)
 143         {
 144                 // click outside
 145                 if ( mousepos_x < panel_pos_x || mousepos_x > panel_pos_x + panel_size_x ||
 146                          mousepos_y < panel_pos_y || mousepos_y > panel_pos_y + panel_size_y )
 147                 {
 148                         HUD_Radar_Hide_Maximized();
 149                         return;
 150                 }
 151                 vector pos = teamradar_texcoord_to_3dcoord(teamradar_2dcoord_to_texcoord(mousepos),view_origin_z);
 152                 localcmd(sprintf("cmd ons_spawn %f %f %f",pos_x,pos_y,pos_z));
 153
 154                 HUD_Radar_Hide_Maximized();
 155                 return;
 156         }
 157
 158
 159         const vector cursor_size = '32 32 0';
 160         drawpic(mousepos-'8 4 0', strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), cursor_size, '1 1 1', 0.8, DRAWFLAG_NORMAL);
 161 }
 162
 163 void HUD_Radar()
 164 {
 165         if (!autocvar__hud_configure)
 166         {
 167                 if (hud_panel_radar_maximized)
 168                 {
 169                         if (!hud_draw_maximized) return;
 170                 }
 171                 else
 172                 {
 173                         if (autocvar_hud_panel_radar == 0) return;
 174                         if (autocvar_hud_panel_radar != 2 && !teamplay) return;
 175                         if(radar_panel_modified)
 176                         {
 177                                 panel.update_time = time; // forces reload of panel attributes
 178                                 radar_panel_modified = false;
 179                         }
 180                 }
 181         }
 182
 183         if ( hud_panel_radar_temp_hidden )
 184                 return;
 185
 186         HUD_Panel_UpdateCvars();
 187
 188         float f = 0;
 189
 190         if (hud_panel_radar_maximized && !autocvar__hud_configure)
 191         {
 192                 panel_size = autocvar_hud_panel_radar_maximized_size;
 193                 panel_size.x = bound(0.2, panel_size.x, 1) * vid_conwidth;
 194                 panel_size.y = bound(0.2, panel_size.y, 1) * vid_conheight;
 195                 panel_pos.x = (vid_conwidth - panel_size.x) / 2;
 196                 panel_pos.y = (vid_conheight - panel_size.y) / 2;
 197
 198                 string panel_bg;
 199                 panel_bg = strcat(hud_skin_path, "/border_default"); // always use the default border when maximized
 200                 if(precache_pic(panel_bg) == "")
 201                         panel_bg = "gfx/hud/default/border_default"; // fallback
 202                 if(!radar_panel_modified && panel_bg != panel.current_panel_bg)
 203                         radar_panel_modified = true;
 204                 if(panel.current_panel_bg)
 205                         strunzone(panel.current_panel_bg);
 206                 panel.current_panel_bg = strzone(panel_bg);
 207
 208                 switch(hud_panel_radar_maximized_zoommode)
 209                 {
 210                         default:
 211                         case 0:
 212                                 f = current_zoomfraction;
 213                                 break;
 214                         case 1:
 215                                 f = 1 - current_zoomfraction;
 216                                 break;
 217                         case 2:
 218                                 f = 0;
 219                                 break;
 220                         case 3:
 221                                 f = 1;
 222                                 break;
 223                 }
 224
 225                 switch(hud_panel_radar_maximized_rotation)
 226                 {
 227                         case 0:
 228                                 teamradar_angle = view_angles.y - 90;
 229                                 break;
 230                         default:
 231                                 teamradar_angle = 90 * hud_panel_radar_maximized_rotation;
 232                                 break;
 233                 }
 234         }
 235         if (!hud_panel_radar_maximized && !autocvar__hud_configure)
 236         {
 237                 switch(hud_panel_radar_zoommode)
 238                 {
 239                         default:
 240                         case 0:
 241                                 f = current_zoomfraction;
 242                                 break;
 243                         case 1:
 244                                 f = 1 - current_zoomfraction;
 245                                 break;
 246                         case 2:
 247                                 f = 0;
 248                                 break;
 249                         case 3:
 250                                 f = 1;
 251                                 break;
 252                 }
 253
 254                 switch(hud_panel_radar_rotation)
 255                 {
 256                         case 0:
 257                                 teamradar_angle = view_angles.y - 90;
 258                                 break;
 259                         default:
 260                                 teamradar_angle = 90 * hud_panel_radar_rotation;
 261                                 break;
 262                 }
 263         }
 264
 265         vector pos, mySize;
 266         pos = panel_pos;
 267         mySize = panel_size;
 268
 269         HUD_Panel_DrawBg(1);
 270         if(panel_bg_padding)
 271         {
 272                 pos += '1 1 0' * panel_bg_padding;
 273                 mySize -= '2 2 0' * panel_bg_padding;
 274         }
 275
 276         int color2;
 277         float scale2d, normalsize, bigsize;
 278
 279         teamradar_origin2d = pos + 0.5 * mySize;
 280         teamradar_size2d = mySize;
 281
 282         if(minimapname == "")
 283                 return;
 284
 285         teamradar_loadcvars();
 286
 287         scale2d = vlen_maxnorm2d(mi_picmax - mi_picmin);
 288         teamradar_size2d = mySize;
 289
 290         teamradar_extraclip_mins = teamradar_extraclip_maxs = '0 0 0'; // we always center
 291
 292         // pixels per world qu to match the teamradar_size2d_x range in the longest dimension
 293         if((hud_panel_radar_rotation == 0 && !hud_panel_radar_maximized) || (hud_panel_radar_maximized_rotation == 0 && hud_panel_radar_maximized))
 294         {
 295                 // max-min distance must fit the radar in any rotation
 296                 bigsize = vlen_minnorm2d(teamradar_size2d) * scale2d / (1.05 * vlen(vec2(mi_scale)));
 297         }
 298         else
 299         {
 300                 vector c0, c1, c2, c3, span;
 301                 c0 = rotate(mi_min, teamradar_angle * DEG2RAD);
 302                 c1 = rotate(mi_max, teamradar_angle * DEG2RAD);
 303                 c2 = rotate('1 0 0' * mi_min.x + '0 1 0' * mi_max.y, teamradar_angle * DEG2RAD);
 304                 c3 = rotate('1 0 0' * mi_max.x + '0 1 0' * mi_min.y, teamradar_angle * DEG2RAD);
 305                 span = '0 0 0';
 306                 span.x = max(c0_x, c1_x, c2_x, c3_x) - min(c0_x, c1_x, c2_x, c3_x);
 307                 span.y = max(c0_y, c1_y, c2_y, c3_y) - min(c0_y, c1_y, c2_y, c3_y);
 308
 309                 // max-min distance must fit the radar in x=x, y=y
 310                 bigsize = min(
 311                         teamradar_size2d.x * scale2d / (1.05 * span.x),
 312                         teamradar_size2d.y * scale2d / (1.05 * span.y)
 313                 );
 314         }
 315
 316         normalsize = vlen_maxnorm2d(teamradar_size2d) * scale2d / hud_panel_radar_scale;
 317         if(bigsize > normalsize)
 318                 normalsize = bigsize;
 319
 320         teamradar_size =
 321                   f * bigsize
 322                 + (1 - f) * normalsize;
 323         teamradar_origin3d_in_texcoord = teamradar_3dcoord_to_texcoord(
 324                   f * mi_center
 325                 + (1 - f) * view_origin);
 326
 327         drawsetcliparea(
 328                 pos.x,
 329                 pos.y,
 330                 mySize.x,
 331                 mySize.y
 332         );
 333
 334         draw_teamradar_background(hud_panel_radar_foreground_alpha);
 335
 336         FOREACH_ENTITY_CLASS("radarlink", true, LAMBDA(
 337                 draw_teamradar_link(it.origin, it.velocity, it.team);
 338         ));
 339
 340         FOREACH_ENTITY_FLAGS(teamradar_icon, 0xFFFFFF, LAMBDA(
 341                 if ( hud_panel_radar_mouse )
 342                 if ( it.health > 0 )
 343                 if ( it.team == myteam+1 )
 344                 {
 345                         vector coord = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(it.origin));
 346                         if ( vlen(mousepos-coord) < 8 )
 347                         {
 348                                 vector brightcolor;
 349                                 brightcolor_x = min(1,it.teamradar_color_x*1.5);
 350                                 brightcolor_y = min(1,it.teamradar_color_y*1.5);
 351                                 brightcolor_z = min(1,it.teamradar_color_z*1.5);
 352                                 drawpic(coord - '8 8 0', "gfx/teamradar_icon_glow", '16 16 0', brightcolor, panel_fg_alpha, 0);
 353                         }
 354                 }
 355                 entity icon = RadarIcons_from(it.teamradar_icon);
 356                 draw_teamradar_icon(it.origin, icon, it, spritelookupcolor(it, icon.netname, it.teamradar_color), panel_fg_alpha);
 357         ));
 358         AL_EACH(_entcs, e, it != NULL, LAMBDA(
 359                 if (!it.m_entcs_private) continue;
 360                 if (entcs_is_self(it)) continue;
 361                 color2 = entcs_GetTeam(it.sv_entnum);
 362                 draw_teamradar_player(it.origin, it.angles, Team_ColorRGB(color2));
 363         ));
 364         draw_teamradar_player(view_origin, view_angles, '1 1 1');
 365
 366         drawresetcliparea();
 367
 368         if ( hud_panel_radar_mouse )
 369         {
 370                 string message = "Click to select teleport destination";
 371
 372                 if ( getstati(STAT_HEALTH) <= 0 )
 373                 {
 374                         message = "Click to select spawn location";
 375                 }
 376
 377                 drawcolorcodedstring(pos + '0.5 0 0' * (mySize_x - stringwidth(message, true, hud_fontsize)) - '0 1 0' * hud_fontsize_y * 2,
 378                                                          message, hud_fontsize, hud_panel_radar_foreground_alpha, DRAWFLAG_NORMAL);
 379
 380                 hud_panel_radar_bottom = pos_y + mySize_y + hud_fontsize_y;
 381         }
 382 }