qcsrc/client/hud/panel/vote.qc

   1 /** Vote window (#9) */
   2 void HUD_Vote()
   3 {
   4         if(autocvar_cl_allow_uid2name == -1 && (gametype == MAPINFO_TYPE_CTS || gametype == MAPINFO_TYPE_RACE || (serverflags & SERVERFLAG_PLAYERSTATS)))
   5         {
   6                 vote_active = 1;
   7                 if (autocvar__hud_configure)
   8                 {
   9                         vote_yescount = 0;
  10                         vote_nocount = 0;
  11                         LOG_INFO(_("^1You must answer before entering hud configure mode\n"));
  12                         cvar_set("_hud_configure", "0");
  13                 }
  14                 if(vote_called_vote)
  15                         strunzone(vote_called_vote);
  16                 vote_called_vote = strzone(_("^2Name ^7instead of \"^1Anonymous player^7\" in stats"));
  17                 uid2name_dialog = 1;
  18         }
  19
  20         if(!autocvar__hud_configure)
  21         {
  22                 if(!autocvar_hud_panel_vote) return;
  23
  24                 panel_fg_alpha = autocvar_hud_panel_fg_alpha;
  25                 panel_bg_alpha_str = autocvar_hud_panel_vote_bg_alpha;
  26
  27                 if(panel_bg_alpha_str == "") {
  28                         panel_bg_alpha_str = ftos(autocvar_hud_panel_bg_alpha);
  29                 }
  30                 panel_bg_alpha = stof(panel_bg_alpha_str);
  31         }
  32         else
  33         {
  34                 vote_yescount = 3;
  35                 vote_nocount = 2;
  36                 vote_needed = 4;
  37         }
  38
  39         string s;
  40         float a;
  41         if(vote_active != vote_prev) {
  42                 vote_change = time;
  43                 vote_prev = vote_active;
  44         }
  45
  46         if(vote_active || autocvar__hud_configure)
  47                 vote_alpha = bound(0, (time - vote_change) * 2, 1);
  48         else
  49                 vote_alpha = bound(0, 1 - (time - vote_change) * 2, 1);
  50
  51         if(!vote_alpha)
  52                 return;
  53
  54         HUD_Panel_UpdateCvars();
  55
  56         if(uid2name_dialog)
  57         {
  58                 panel_pos = eX * 0.3 * vid_conwidth + eY * 0.1 * vid_conheight;
  59                 panel_size = eX * 0.4 * vid_conwidth + eY * 0.3 * vid_conheight;
  60         }
  61
  62     // these must be below above block
  63         vector pos, mySize;
  64         pos = panel_pos;
  65         mySize = panel_size;
  66
  67         a = vote_alpha * (vote_highlighted ? autocvar_hud_panel_vote_alreadyvoted_alpha : 1);
  68         HUD_Panel_DrawBg(a);
  69         a = panel_fg_alpha * a;
  70
  71         if(panel_bg_padding)
  72         {
  73                 pos += '1 1 0' * panel_bg_padding;
  74                 mySize -= '2 2 0' * panel_bg_padding;
  75         }
  76
  77         // always force 3:1 aspect
  78         vector newSize = '0 0 0';
  79         if(mySize.x/mySize.y > 3)
  80         {
  81                 newSize.x = 3 * mySize.y;
  82                 newSize.y = mySize.y;
  83
  84                 pos.x = pos.x + (mySize.x - newSize.x) / 2;
  85         }
  86         else
  87         {
  88                 newSize.y = 1/3 * mySize.x;
  89                 newSize.x = mySize.x;
  90
  91                 pos.y = pos.y + (mySize.y - newSize.y) / 2;
  92         }
  93         mySize = newSize;
  94
  95         s = _("A vote has been called for:");
  96         if(uid2name_dialog)
  97                 s = _("Allow servers to store and display your name?");
  98         drawstring_aspect(pos, s, eX * mySize.x + eY * (2/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
  99         s = textShortenToWidth(vote_called_vote, mySize.x, '1 1 0' * mySize.y * (1/8), stringwidth_colors);
 100         if(autocvar__hud_configure)
 101                 s = _("^1Configure the HUD");
 102         drawcolorcodedstring_aspect(pos + eY * (2/8) * mySize.y, s, eX * mySize.x + eY * (1.75/8) * mySize.y, a, DRAWFLAG_NORMAL);
 103
 104         // print the yes/no counts
 105     s = sprintf(_("Yes (%s): %d"), getcommandkey("vyes", "vyes"), vote_yescount);
 106         drawstring_aspect(pos + eY * (4/8) * mySize.y, s, eX * 0.5 * mySize.x + eY * (1.5/8) * mySize.y, '0 1 0', a, DRAWFLAG_NORMAL);
 107     s = sprintf(_("No (%s): %d"), getcommandkey("vno", "vno"), vote_nocount);
 108         drawstring_aspect(pos + eX * 0.5 * mySize.x + eY * (4/8) * mySize.y, s, eX * 0.5 * mySize.x + eY * (1.5/8) * mySize.y, '1 0 0', a, DRAWFLAG_NORMAL);
 109
 110         // draw the progress bar backgrounds
 111         drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_back", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
 112
 113         // draw the highlights
 114         if(vote_highlighted == 1) {
 115                 drawsetcliparea(pos.x, pos.y, mySize.x * 0.5, mySize.y);
 116                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_voted", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
 117         }
 118         else if(vote_highlighted == -1) {
 119                 drawsetcliparea(pos.x + 0.5 * mySize.x, pos.y, mySize.x * 0.5, mySize.y);
 120                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_voted", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
 121         }
 122
 123         // draw the progress bars
 124         if(vote_yescount && vote_needed)
 125         {
 126                 drawsetcliparea(pos.x, pos.y, mySize.x * 0.5 * (vote_yescount/vote_needed), mySize.y);
 127                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_prog", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
 128         }
 129
 130         if(vote_nocount && vote_needed)
 131         {
 132                 drawsetcliparea(pos.x + mySize.x - mySize.x * 0.5 * (vote_nocount/vote_needed), pos.y, mySize.x * 0.5, mySize.y);
 133                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_prog", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
 134         }
 135
 136         drawresetcliparea();
 137 }