qcsrc/client/hud/panel/vote.qc

   1 #include "vote.qh"
   2
   3 #include <client/autocvars.qh>
   4 #include <client/defs.qh>
   5 #include <client/miscfunctions.qh>
   6 #include <common/mapinfo.qh>
   7
   8 // Vote (#9)
   9
  10 void HUD_Vote()
  11 {
  12         if(autocvar_cl_allow_uid2name == -1 && (gametype == MAPINFO_TYPE_CTS || gametype == MAPINFO_TYPE_RACE || (serverflags & SERVERFLAG_PLAYERSTATS)))
  13         {
  14                 // this dialog gets overriden by the uid2name menu dialog, if it exists
  15                 // TODO remove this client side uid2name dialog in the next release
  16                 if(!autocvar__menu_alpha)
  17                         uid2name_dialog = 0;
  18
  19                 if (!uid2name_dialog)
  20                         localcmd("menu_cmd directmenu Uid2Name\n");
  21
  22                 vote_active = 1;
  23                 if (autocvar__hud_configure)
  24                 {
  25                         vote_yescount = 0;
  26                         vote_nocount = 0;
  27                         LOG_INFO(_("^1You must answer before entering hud configure mode\n"));
  28                         cvar_set("_hud_configure", "0");
  29                 }
  30                 if(vote_called_vote)
  31                         strunzone(vote_called_vote);
  32                 vote_called_vote = strzone(_("^2Name ^7instead of \"^1Anonymous player^7\" in stats"));
  33                 uid2name_dialog = 1;
  34         }
  35
  36         if(!autocvar__hud_configure)
  37         {
  38                 if(!autocvar_hud_panel_vote) return;
  39                 /*
  40                 if(cvar("hud_panel_vote_test")) {
  41                         if(vote_called_vote) strunzone(vote_called_vote); vote_called_vote = strzone("^1test the vote panel");
  42                         vote_active = true; vote_yescount = 3; vote_nocount = 2; vote_needed = 4;
  43                 } else vote_active = false;
  44                 */
  45         }
  46         else
  47         {
  48                 vote_yescount = 3;
  49                 vote_nocount = 2;
  50                 vote_needed = 4;
  51         }
  52
  53         string s;
  54         float a;
  55         if(vote_active != vote_prev) {
  56                 vote_change = time;
  57                 vote_prev = vote_active;
  58         }
  59
  60         if(vote_active || autocvar__hud_configure)
  61                 vote_alpha = bound(0, (time - vote_change) * 2, 1);
  62         else
  63                 vote_alpha = bound(0, 1 - (time - vote_change) * 2, 1);
  64
  65         a = vote_alpha * (vote_highlighted ? autocvar_hud_panel_vote_alreadyvoted_alpha : 1);
  66         if(a <= 0)
  67                 return;
  68         //panel_fade_alpha *= a;
  69         // nothing can hide this panel, not even the menu
  70         float hud_fade_alpha_save = hud_fade_alpha;
  71         if(uid2name_dialog && autocvar__menu_alpha)
  72                 hud_fade_alpha = 0;
  73         else
  74                 hud_fade_alpha = a;
  75         HUD_Panel_LoadCvars();
  76         hud_fade_alpha = hud_fade_alpha_save;
  77
  78         if(uid2name_dialog)
  79         {
  80                 panel_pos = vec2(0.3 * vid_conwidth, 0.1 * vid_conheight);
  81                 panel_size = vec2(0.4 * vid_conwidth, 0.3 * vid_conheight);
  82         }
  83
  84         vector pos, mySize;
  85         pos = panel_pos;
  86         mySize = panel_size;
  87
  88         if (autocvar_hud_panel_vote_dynamichud)
  89                 HUD_Scale_Enable();
  90         else
  91                 HUD_Scale_Disable();
  92         HUD_Panel_DrawBg();
  93
  94         if(panel_bg_padding)
  95         {
  96                 pos += '1 1 0' * panel_bg_padding;
  97                 mySize -= '2 2 0' * panel_bg_padding;
  98         }
  99
 100         // always force 3:1 aspect
 101         vector newSize = '0 0 0';
 102         if(mySize.x/mySize.y > 3)
 103         {
 104                 newSize.x = 3 * mySize.y;
 105                 newSize.y = mySize.y;
 106
 107                 pos.x = pos.x + (mySize.x - newSize.x) / 2;
 108         }
 109         else
 110         {
 111                 newSize.y = 1/3 * mySize.x;
 112                 newSize.x = mySize.x;
 113
 114                 pos.y = pos.y + (mySize.y - newSize.y) / 2;
 115         }
 116         mySize = newSize;
 117
 118         s = _("A vote has been called for:");
 119         if(uid2name_dialog)
 120                 s = _("Allow servers to store and display your name?");
 121         drawstring_aspect(pos, s, vec2(mySize.x, (2/8) * mySize.y), '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 122         s = textShortenToWidth(ColorTranslateRGB(vote_called_vote), mySize.x, '1 1 0' * mySize.y * (1/8), stringwidth_colors);
 123         if(autocvar__hud_configure)
 124                 s = _("^1Configure the HUD");
 125         drawcolorcodedstring_aspect(pos + eY * (2/8) * mySize.y, s, vec2(mySize.x, (1.75/8) * mySize.y), panel_fg_alpha, DRAWFLAG_NORMAL);
 126
 127         // print the yes/no counts
 128         s = sprintf("^2%s ^7(%d)", getcommandkey_forcename(_("Yes"), "vyes"), vote_yescount);
 129         drawcolorcodedstring_aspect(pos + eY * (4/8) * mySize.y, s, vec2(0.5 * mySize.x, (1.5/8) * mySize.y), panel_fg_alpha, DRAWFLAG_NORMAL);
 130         s = sprintf("^1%s ^7(%d)", getcommandkey_forcename(_("No"), "vno"), vote_nocount);
 131         drawcolorcodedstring_aspect(pos + vec2(0.5 * mySize.x, (4/8) * mySize.y), s, vec2(0.5 * mySize.x, (1.5/8) * mySize.y), panel_fg_alpha, DRAWFLAG_NORMAL);
 132
 133         pos.y += (5/8) * mySize.y;
 134         vector tmp_size = vec2(mySize.x, (3/8) * mySize.y);
 135         // draw the progress bar backgrounds
 136         drawpic_skin(pos, "voteprogress_back", tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 137
 138         // draw the highlights
 139         if(vote_highlighted == 1) {
 140                 drawsetcliparea(pos.x, pos.y, mySize.x * 0.5, mySize.y);
 141                 drawpic_skin(pos, "voteprogress_voted", tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 142         }
 143         else if(vote_highlighted == -1) {
 144                 drawsetcliparea(pos.x + 0.5 * mySize.x, pos.y, mySize.x * 0.5, mySize.y);
 145                 drawpic_skin(pos, "voteprogress_voted", tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 146         }
 147
 148         // draw the progress bars
 149         if(vote_yescount && vote_needed)
 150         {
 151                 drawsetcliparea(pos.x, pos.y, mySize.x * 0.5 * (vote_yescount/vote_needed), mySize.y);
 152                 drawpic_skin(pos, "voteprogress_prog", tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 153         }
 154
 155         if(vote_nocount && vote_needed)
 156         {
 157                 drawsetcliparea(pos.x + mySize.x - mySize.x * 0.5 * (vote_nocount/vote_needed), pos.y, mySize.x * 0.5, mySize.y);
 158                 drawpic_skin(pos, "voteprogress_prog", tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 159         }
 160
 161         drawresetcliparea();
 162 }