qcsrc/client/hud/panel/vote.qc

   1 #include "vote.qh"
   2
   3 #include <client/autocvars.qh>
   4 #include <client/defs.qh>
   5 #include <client/miscfunctions.qh>
   6 #include <common/mapinfo.qh>
   7
   8 // Vote (#9)
   9
  10 void HUD_Vote()
  11 {
  12         if(autocvar_cl_allow_uid2name == -1 && (gametype == MAPINFO_TYPE_CTS || gametype == MAPINFO_TYPE_RACE || (serverflags & SERVERFLAG_PLAYERSTATS)))
  13         {
  14                 // this dialog gets overriden by the uid2name menu dialog, if it exists
  15                 // TODO remove this client side uid2name dialog in the next release
  16                 if(!autocvar__menu_alpha)
  17                         uid2name_dialog = 0;
  18
  19                 if (!uid2name_dialog)
  20                         localcmd("menu_cmd directmenu Uid2Name\n");
  21
  22                 vote_active = 1;
  23                 if (autocvar__hud_configure)
  24                 {
  25                         vote_yescount = 0;
  26                         vote_nocount = 0;
  27                         LOG_INFO(_("^1You must answer before entering hud configure mode"));
  28                         cvar_set("_hud_configure", "0");
  29                 }
  30                 strcpy(vote_called_vote, _("^2Name ^7instead of \"^1Anonymous player^7\" in stats"));
  31                 uid2name_dialog = 1;
  32         }
  33
  34         if(!autocvar__hud_configure)
  35         {
  36                 if(!autocvar_hud_panel_vote) return;
  37                 /*
  38                 if(cvar("hud_panel_vote_test")) {
  39                         if(vote_called_vote) strunzone(vote_called_vote); vote_called_vote = strzone("^1test the vote panel");
  40                         vote_active = true; vote_yescount = 3; vote_nocount = 2; vote_needed = 4;
  41                 } else vote_active = false;
  42                 */
  43         }
  44         else
  45         {
  46                 vote_yescount = 3;
  47                 vote_nocount = 2;
  48                 vote_needed = 4;
  49         }
  50
  51         string s;
  52         float a;
  53         if(vote_active != vote_prev) {
  54                 vote_change = time;
  55                 vote_prev = vote_active;
  56         }
  57
  58         if(vote_active || autocvar__hud_configure)
  59                 vote_alpha = bound(0, (time - vote_change) * 2, 1);
  60         else
  61                 vote_alpha = bound(0, 1 - (time - vote_change) * 2, 1);
  62
  63         a = vote_alpha * (vote_highlighted ? autocvar_hud_panel_vote_alreadyvoted_alpha : 1);
  64         if(a <= 0)
  65                 return;
  66         //panel_fade_alpha *= a;
  67         // nothing can hide this panel, not even the menu
  68         float hud_fade_alpha_save = hud_fade_alpha;
  69         if(uid2name_dialog && autocvar__menu_alpha)
  70                 hud_fade_alpha = 0;
  71         else
  72                 hud_fade_alpha = a;
  73         HUD_Panel_LoadCvars();
  74         hud_fade_alpha = hud_fade_alpha_save;
  75
  76         if(uid2name_dialog)
  77         {
  78                 panel_pos = vec2(0.3 * vid_conwidth, 0.1 * vid_conheight);
  79                 panel_size = vec2(0.4 * vid_conwidth, 0.3 * vid_conheight);
  80         }
  81
  82         vector pos, mySize;
  83         pos = panel_pos;
  84         mySize = panel_size;
  85
  86         if (autocvar_hud_panel_vote_dynamichud)
  87                 HUD_Scale_Enable();
  88         else
  89                 HUD_Scale_Disable();
  90         HUD_Panel_DrawBg();
  91
  92         if(panel_bg_padding)
  93         {
  94                 pos += '1 1 0' * panel_bg_padding;
  95                 mySize -= '2 2 0' * panel_bg_padding;
  96         }
  97
  98         // always force 3:1 aspect
  99         vector newSize = '0 0 0';
 100         if(mySize.x/mySize.y > 3)
 101         {
 102                 newSize.x = 3 * mySize.y;
 103                 newSize.y = mySize.y;
 104
 105                 pos.x = pos.x + (mySize.x - newSize.x) / 2;
 106         }
 107         else
 108         {
 109                 newSize.y = 1/3 * mySize.x;
 110                 newSize.x = mySize.x;
 111
 112                 pos.y = pos.y + (mySize.y - newSize.y) / 2;
 113         }
 114         mySize = newSize;
 115
 116         s = _("A vote has been called for:");
 117         if(uid2name_dialog)
 118                 s = _("Allow servers to store and display your name?");
 119         drawstring_aspect(pos, s, vec2(mySize.x, (2/8) * mySize.y), '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 120         s = textShortenToWidth(ColorTranslateRGB(vote_called_vote), mySize.x, '1 1 0' * mySize.y * (1/8), stringwidth_colors);
 121         if(autocvar__hud_configure)
 122                 s = _("^1Configure the HUD");
 123         drawcolorcodedstring_aspect(pos + eY * (2/8) * mySize.y, s, vec2(mySize.x, (1.75/8) * mySize.y), panel_fg_alpha, DRAWFLAG_NORMAL);
 124
 125         // print the yes/no counts
 126         s = sprintf("^2%s ^7(%d)", getcommandkey_forcename(_("Yes"), "vyes"), vote_yescount);
 127         drawcolorcodedstring_aspect(pos + eY * (4/8) * mySize.y, s, vec2(0.5 * mySize.x, (1.5/8) * mySize.y), panel_fg_alpha, DRAWFLAG_NORMAL);
 128         s = sprintf("^1%s ^7(%d)", getcommandkey_forcename(_("No"), "vno"), vote_nocount);
 129         drawcolorcodedstring_aspect(pos + vec2(0.5 * mySize.x, (4/8) * mySize.y), s, vec2(0.5 * mySize.x, (1.5/8) * mySize.y), panel_fg_alpha, DRAWFLAG_NORMAL);
 130
 131         pos.y += (5/8) * mySize.y;
 132         vector tmp_size = vec2(mySize.x, (3/8) * mySize.y);
 133         // draw the progress bar backgrounds
 134         drawpic_skin(pos, "voteprogress_back", tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 135
 136         // draw the highlights
 137         if(vote_highlighted == 1) {
 138                 drawsetcliparea(pos.x, pos.y, mySize.x * 0.5, mySize.y);
 139                 drawpic_skin(pos, "voteprogress_voted", tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 140         }
 141         else if(vote_highlighted == -1) {
 142                 drawsetcliparea(pos.x + 0.5 * mySize.x, pos.y, mySize.x * 0.5, mySize.y);
 143                 drawpic_skin(pos, "voteprogress_voted", tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 144         }
 145
 146         // draw the progress bars
 147         if(vote_yescount && vote_needed)
 148         {
 149                 drawsetcliparea(pos.x, pos.y, mySize.x * 0.5 * (vote_yescount/vote_needed), mySize.y);
 150                 drawpic_skin(pos, "voteprogress_prog", tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 151         }
 152
 153         if(vote_nocount && vote_needed)
 154         {
 155                 drawsetcliparea(pos.x + mySize.x - mySize.x * 0.5 * (vote_nocount/vote_needed), pos.y, mySize.x * 0.5, mySize.y);
 156                 drawpic_skin(pos, "voteprogress_prog", tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 157         }
 158
 159         drawresetcliparea();
 160 }