qcsrc/client/hud/panel/weapons.qc

   1 #include "weapons.qh"
   2 // Weapon icons (#0)
   3
   4 entity weaponorder[Weapons_MAX];
   5 void weaponorder_swap(int i, int j, entity pass)
   6 {
   7     TC(int, i); TC(int, j);
   8         entity h = weaponorder[i];
   9         weaponorder[i] = weaponorder[j];
  10         weaponorder[j] = h;
  11 }
  12
  13 string weaponorder_cmp_str;
  14 int weaponorder_cmp(int i, int j, entity pass)
  15 {
  16     TC(int, i); TC(int, j);
  17         int ai = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[i].m_id), 0);
  18         int aj = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[j].m_id), 0);
  19         return aj - ai; // the string is in REVERSE order (higher prio at the right is what we want, but higher prio first is the string)
  20 }
  21
  22 #define HUD_WEAPONS_GET_FULL_LAYOUT() MACRO_BEGIN { \
  23         int nHidden = 0; \
  24         FOREACH(Weapons, it != WEP_Null, { \
  25                 if (weapons_stat & WepSet_FromWeapon(it)) continue; \
  26                 if (it.spawnflags & WEP_FLAG_MUTATORBLOCKED) nHidden += 1; \
  27         }); \
  28         vector table_size = HUD_GetTableSize_BestItemAR((Weapons_COUNT - 1) - nHidden, panel_size, aspect); \
  29         columns = table_size.x; \
  30         rows = table_size.y; \
  31         weapon_size.x = panel_size.x / columns; \
  32         weapon_size.y = panel_size.y / rows; \
  33 } MACRO_END
  34
  35 void HUD_Weapons()
  36 {
  37         // declarations
  38         WepSet weapons_stat = WepSet_GetFromStat();
  39         int i;
  40         float f, a;
  41         float screen_ar;
  42         vector center = '0 0 0';
  43         int weapon_count, weapon_id;
  44         int row, column, rows = 0, columns = 0;
  45         bool vertical_order = true;
  46         float aspect = autocvar_hud_panel_weapons_aspect;
  47
  48         float timeout = autocvar_hud_panel_weapons_timeout;
  49         float timein_effect_length = autocvar_hud_panel_weapons_timeout_speed_in; //? 0.375 : 0);
  50         float timeout_effect_length = autocvar_hud_panel_weapons_timeout_speed_out; //? 0.75 : 0);
  51
  52         vector barsize = '0 0 0', baroffset = '0 0 0';
  53         vector ammo_color = '1 0 1';
  54         float ammo_alpha = 1;
  55
  56         float when = max(1, autocvar_hud_panel_weapons_complainbubble_time);
  57         float fadetime = max(0, autocvar_hud_panel_weapons_complainbubble_fadetime);
  58
  59         vector weapon_pos, weapon_size = '0 0 0';
  60         vector color;
  61
  62         // check to see if we want to continue
  63         if(hud != HUD_NORMAL) return;
  64
  65         if(!autocvar__hud_configure)
  66         {
  67                 if((!autocvar_hud_panel_weapons) || (spectatee_status == -1))
  68                         return;
  69                 if(timeout && time >= weapontime + timeout + timeout_effect_length)
  70                 if(autocvar_hud_panel_weapons_timeout_effect == 3 || (autocvar_hud_panel_weapons_timeout_effect == 1 && !(autocvar_hud_panel_weapons_timeout_fadebgmin + autocvar_hud_panel_weapons_timeout_fadefgmin)))
  71                 {
  72                         weaponprevtime = time;
  73                         return;
  74                 }
  75         }
  76
  77         // update generic hud functions
  78         HUD_Panel_UpdateCvars();
  79
  80         // figure out weapon order (how the weapons are sorted) // TODO make this configurable
  81         if(weaponorder_bypriority != autocvar_cl_weaponpriority || !weaponorder[0])
  82         {
  83                 int weapon_cnt;
  84                 if(weaponorder_bypriority)
  85                         strunzone(weaponorder_bypriority);
  86                 if(weaponorder_byimpulse)
  87                         strunzone(weaponorder_byimpulse);
  88
  89                 weaponorder_bypriority = strzone(autocvar_cl_weaponpriority);
  90                 weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(W_FixWeaponOrder_ForceComplete(W_NumberWeaponOrder(weaponorder_bypriority))));
  91                 weaponorder_cmp_str = strcat(" ", weaponorder_byimpulse, " ");
  92
  93                 weapon_cnt = 0;
  94                 FOREACH(Weapons, it != WEP_Null && it.impulse >= 0, weaponorder[weapon_cnt++] = it);
  95                 for(i = weapon_cnt; i < Weapons_MAX; ++i)
  96                         weaponorder[i] = NULL;
  97                 heapsort(weapon_cnt, weaponorder_swap, weaponorder_cmp, NULL);
  98
  99                 weaponorder_cmp_str = string_null;
 100         }
 101
 102         if(!autocvar_hud_panel_weapons_complainbubble || autocvar__hud_configure || time - complain_weapon_time >= when + fadetime)
 103                 complain_weapon = 0;
 104
 105         if(autocvar__hud_configure)
 106         {
 107                 if(!weapons_stat)
 108                 {
 109                         int j = 0;
 110                         FOREACH(Weapons, it != WEP_Null && it.impulse >= 0 && (it.impulse % 3 != 0) && j < 6, {
 111                                 if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 112                                 {
 113                                         weapons_stat |= it.m_wepset;
 114                                         ++j;
 115                                 }
 116                         });
 117                 }
 118
 119                 #if 0
 120                 /// debug code
 121                 if(cvar("wep_add"))
 122                 {
 123                         int j;
 124                         int nHidden = 0;
 125                         FOREACH(Weapons, it != WEP_Null, {
 126                                 if (it.spawnflags & WEP_FLAG_MUTATORBLOCKED) nHidden += 1;
 127                         });
 128                         weapons_stat = '0 0 0';
 129                         float countw = 1 + floor((floor(time * cvar("wep_add"))) % ((Weapons_COUNT - 1) - nHidden));
 130                         for(i = 0, j = 0; i <= (Weapons_COUNT - 1) && j < countw; ++i)
 131                         {
 132                                 if(weaponorder[i].spawnflags & WEP_FLAG_MUTATORBLOCKED)
 133                                         continue;
 134                                 weapons_stat |= weaponorder[i].m_wepset;
 135                                 ++j;
 136                         }
 137                 }
 138                 #endif
 139         }
 140
 141         // determine which weapons are going to be shown
 142         if (autocvar_hud_panel_weapons_onlyowned)
 143         {
 144                 if(autocvar__hud_configure)
 145                 {
 146                         if(menu_enabled != 2)
 147                                 HUD_Panel_DrawBg(1); // also draw the bg of the entire panel
 148                 }
 149
 150                 // do we own this weapon?
 151                 weapon_count = 0;
 152                 for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 153                         if((weapons_stat & WepSet_FromWeapon(weaponorder[i])) || (weaponorder[i].m_id == complain_weapon))
 154                                 ++weapon_count;
 155
 156
 157                 // might as well commit suicide now, no reason to live ;)
 158                 if (weapon_count == 0)
 159                         return;
 160
 161                 vector old_panel_size = panel_size;
 162                 panel_size -= '2 2 0' * panel_bg_padding;
 163
 164                 HUD_WEAPONS_GET_FULL_LAYOUT();
 165
 166                 // NOTE: although weapons should aways look the same even if onlyowned is enabled,
 167                 // we enlarge them a bit when possible to better match the desired aspect ratio
 168                 if(panel_size.x / panel_size.y < aspect)
 169                 {
 170                         // maximum number of rows that allows to display items with the desired aspect ratio
 171                         int max_rows = floor(panel_size.y / (weapon_size.x / aspect));
 172                         columns = min(columns, ceil(weapon_count / max_rows));
 173                         rows = ceil(weapon_count / columns);
 174                         weapon_size.y = min(panel_size.y / rows, weapon_size.x / aspect);
 175                         weapon_size.x = min(panel_size.x / columns, aspect * weapon_size.y);
 176                         vertical_order = false;
 177                 }
 178                 else
 179                 {
 180                         int max_columns = floor(panel_size.x / (weapon_size.y * aspect));
 181                         rows = min(rows, ceil(weapon_count / max_columns));
 182                         columns = ceil(weapon_count / rows);
 183                         weapon_size.x = min(panel_size.x / columns, aspect * weapon_size.y);
 184                         weapon_size.y = min(panel_size.y / rows, weapon_size.x / aspect);
 185                         vertical_order = true;
 186                 }
 187
 188                 // reduce size of the panel
 189                 panel_size.x = columns * weapon_size.x;
 190                 panel_size.y = rows * weapon_size.y;
 191                 panel_size += '2 2 0' * panel_bg_padding;
 192
 193                 // center the resized panel, or snap it to the screen edge when close enough
 194                 if(panel_pos.x > vid_conwidth * 0.001)
 195                 {
 196                         if(panel_pos.x + old_panel_size.x > vid_conwidth * 0.999)
 197                                 panel_pos.x += old_panel_size.x - panel_size.x;
 198                         else
 199                                 panel_pos.x += (old_panel_size.x - panel_size.x) / 2;
 200                 }
 201                 else if(old_panel_size.x > vid_conwidth * 0.999)
 202                         panel_pos.x += (old_panel_size.x - panel_size.x) / 2;
 203
 204                 if(panel_pos.y > vid_conheight * 0.001)
 205                 {
 206                         if(panel_pos.y + old_panel_size.y > vid_conheight * 0.999)
 207                                 panel_pos.y += old_panel_size.y - panel_size.y;
 208                         else
 209                                 panel_pos.y += (old_panel_size.y - panel_size.y) / 2;
 210                 }
 211                 else if(old_panel_size.y > vid_conheight * 0.999)
 212                         panel_pos.y += (old_panel_size.y - panel_size.y) / 2;
 213         }
 214         else
 215                 weapon_count = (Weapons_COUNT - 1);
 216
 217         // animation for fading in/out the panel respectively when not in use
 218         if(!autocvar__hud_configure)
 219         {
 220                 if (timeout && time >= weapontime + timeout) // apply timeout effect if needed
 221                 {
 222                         f = bound(0, (time - (weapontime + timeout)) / timeout_effect_length, 1);
 223
 224                         // fade the panel alpha
 225                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 226                         {
 227                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * f + (1 - f));
 228                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * f + (1 - f));
 229                         }
 230                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 231                         {
 232                                 panel_bg_alpha *= (1 - f);
 233                                 panel_fg_alpha *= (1 - f);
 234                         }
 235
 236                         // move the panel off the screen
 237                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 238                         {
 239                                 f *= f; // for a cooler movement
 240                                 center.x = panel_pos.x + panel_size.x/2;
 241                                 center.y = panel_pos.y + panel_size.y/2;
 242                                 screen_ar = vid_conwidth/vid_conheight;
 243                                 if (center.x/center.y < screen_ar) //bottom left
 244                                 {
 245                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //bottom
 246                                                 panel_pos.y += f * (vid_conheight - panel_pos.y);
 247                                         else //left
 248                                                 panel_pos.x -= f * (panel_pos.x + panel_size.x);
 249                                 }
 250                                 else //top right
 251                                 {
 252                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //right
 253                                                 panel_pos.x += f * (vid_conwidth - panel_pos.x);
 254                                         else //top
 255                                                 panel_pos.y -= f * (panel_pos.y + panel_size.y);
 256                                 }
 257                                 if(f == 1)
 258                                         center.x = -1; // mark the panel as off screen
 259                         }
 260                         weaponprevtime = time - (1 - f) * timein_effect_length;
 261                 }
 262                 else if (timeout && time < weaponprevtime + timein_effect_length) // apply timein effect if needed
 263                 {
 264                         f = bound(0, (time - weaponprevtime) / timein_effect_length, 1);
 265
 266                         // fade the panel alpha
 267                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 268                         {
 269                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * (1 - f) + f);
 270                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * (1 - f) + f);
 271                         }
 272                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 273                         {
 274                                 panel_bg_alpha *= (f);
 275                                 panel_fg_alpha *= (f);
 276                         }
 277
 278                         // move the panel back on screen
 279                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 280                         {
 281                                 f *= f; // for a cooler movement
 282                                 f = 1 - f;
 283                                 center.x = panel_pos.x + panel_size.x/2;
 284                                 center.y = panel_pos.y + panel_size.y/2;
 285                                 screen_ar = vid_conwidth/vid_conheight;
 286                                 if (center.x/center.y < screen_ar) //bottom left
 287                                 {
 288                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //bottom
 289                                                 panel_pos.y += f * (vid_conheight - panel_pos.y);
 290                                         else //left
 291                                                 panel_pos.x -= f * (panel_pos.x + panel_size.x);
 292                                 }
 293                                 else //top right
 294                                 {
 295                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //right
 296                                                 panel_pos.x += f * (vid_conwidth - panel_pos.x);
 297                                         else //top
 298                                                 panel_pos.y -= f * (panel_pos.y + panel_size.y);
 299                                 }
 300                         }
 301                 }
 302         }
 303
 304         // draw the background, then change the virtual size of it to better fit other items inside
 305         if (autocvar_hud_panel_weapons_dynamichud)
 306                 HUD_Scale_Enable();
 307         else
 308                 HUD_Scale_Disable();
 309         HUD_Panel_DrawBg(1);
 310
 311         if(center.x == -1)
 312                 return; // panel has gone off screen
 313
 314         if(panel_bg_padding)
 315         {
 316                 panel_pos += '1 1 0' * panel_bg_padding;
 317                 panel_size -= '2 2 0' * panel_bg_padding;
 318         }
 319
 320         // after the sizing and animations are done, update the other values
 321
 322         if(!rows) // if rows is > 0 onlyowned code has already updated these vars
 323         {
 324                 HUD_WEAPONS_GET_FULL_LAYOUT();
 325                 vertical_order = (panel_size.x / panel_size.y >= aspect);
 326         }
 327
 328         // calculate position/size for visual bar displaying ammount of ammo status
 329         if (autocvar_hud_panel_weapons_ammo)
 330         {
 331                 ammo_color = stov(autocvar_hud_panel_weapons_ammo_color);
 332                 ammo_alpha = panel_fg_alpha * autocvar_hud_panel_weapons_ammo_alpha;
 333
 334                 if(weapon_size.x/weapon_size.y > aspect)
 335                 {
 336                         barsize.x = aspect * weapon_size.y;
 337                         barsize.y = weapon_size.y;
 338                         baroffset.x = (weapon_size.x - barsize.x) / 2;
 339                 }
 340                 else
 341                 {
 342                         barsize.y = 1/aspect * weapon_size.x;
 343                         barsize.x = weapon_size.x;
 344                         baroffset.y = (weapon_size.y - barsize.y) / 2;
 345                 }
 346         }
 347         if(autocvar_hud_panel_weapons_accuracy)
 348                 Accuracy_LoadColors();
 349
 350         // draw items
 351         row = column = 0;
 352         vector label_size = '1 1 0' * min(weapon_size.x, weapon_size.y) * bound(0, autocvar_hud_panel_weapons_label_scale, 1);
 353         vector noncurrent_pos = '0 0 0';
 354         vector noncurrent_size = weapon_size * bound(0, autocvar_hud_panel_weapons_noncurrent_scale, 1);
 355         float noncurrent_alpha = panel_fg_alpha * bound(0, autocvar_hud_panel_weapons_noncurrent_alpha, 1);
 356         bool isCurrent;
 357
 358         for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 359         {
 360                 // retrieve information about the current weapon to be drawn
 361                 entity it = weaponorder[i];
 362                 weapon_id = it.impulse;
 363
 364                 // skip if this weapon doesn't exist
 365                 if(!it || weapon_id < 0) { continue; }
 366
 367                 // skip this weapon if we don't own it (and onlyowned is enabled)-- or if weapons_complainbubble is showing for this weapon
 368                 if(autocvar_hud_panel_weapons_onlyowned)
 369                 {
 370                         if (!((weapons_stat & WepSet_FromWeapon(it)) || (it.m_id == complain_weapon)))
 371                                 continue;
 372                 }
 373                 else
 374                 {
 375                         if (it.spawnflags & WEP_FLAG_MUTATORBLOCKED && !(weapons_stat & WepSet_FromWeapon(it)))
 376                                 continue;
 377                 }
 378
 379                 // figure out the drawing position of weapon
 380                 weapon_pos = (panel_pos + eX * column * weapon_size.x + eY * row * weapon_size.y);
 381                 noncurrent_pos.x = weapon_pos.x + (weapon_size.x - noncurrent_size.x) / 2;
 382                 noncurrent_pos.y = weapon_pos.y + (weapon_size.y - noncurrent_size.y) / 2;
 383
 384                 // draw background behind currently selected weapon
 385                 isCurrent = (it == switchweapon);
 386                 if(isCurrent)
 387                         drawpic_aspect_skin(weapon_pos, "weapon_current_bg", weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 388
 389                 // draw the weapon accuracy
 390                 if(autocvar_hud_panel_weapons_accuracy)
 391                 {
 392                         float panel_weapon_accuracy = weapon_accuracy[it.m_id-WEP_FIRST];
 393                         if(panel_weapon_accuracy >= 0)
 394                         {
 395                                 color = Accuracy_GetColor(panel_weapon_accuracy);
 396                                 drawpic_aspect_skin(weapon_pos, "weapon_accuracy", weapon_size, color, panel_fg_alpha, DRAWFLAG_NORMAL);
 397                         }
 398                 }
 399
 400                 // drawing all the weapon items
 401                 if(weapons_stat & WepSet_FromWeapon(it))
 402                 {
 403                         // draw the weapon image
 404                         if(isCurrent)
 405                                 drawpic_aspect_skin(weapon_pos, it.model2, weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 406                         else
 407                                 drawpic_aspect_skin(noncurrent_pos, it.model2, noncurrent_size, '1 1 1', noncurrent_alpha, DRAWFLAG_NORMAL);
 408
 409                         // draw weapon label string
 410                         switch(autocvar_hud_panel_weapons_label)
 411                         {
 412                                 case 1: // weapon number
 413                                         drawstring(weapon_pos, ftos(weapon_id), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 414                                         break;
 415
 416                                 case 2: // bind
 417                                         drawstring(weapon_pos, getcommandkey(ftos(weapon_id), strcat("weapon_group_", ftos(weapon_id))), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 418                                         break;
 419
 420                                 case 3: // weapon name
 421                                         drawstring(weapon_pos, strtolower(it.m_name), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 422                                         break;
 423
 424                                 default: // nothing
 425                                         break;
 426                         }
 427
 428                         // draw ammo status bar
 429                         if(autocvar_hud_panel_weapons_ammo && (it.ammo_field != ammo_none))
 430                         {
 431                                 float ammo_full;
 432                                 a = getstati(GetAmmoStat(it.ammo_field)); // how much ammo do we have?
 433
 434                                 if(a > 0)
 435                                 {
 436                                         switch(it.ammo_field)
 437                                         {
 438                                                 case ammo_shells:  ammo_full = autocvar_hud_panel_weapons_ammo_full_shells;  break;
 439                                                 case ammo_nails:   ammo_full = autocvar_hud_panel_weapons_ammo_full_nails;   break;
 440                                                 case ammo_rockets: ammo_full = autocvar_hud_panel_weapons_ammo_full_rockets; break;
 441                                                 case ammo_cells:   ammo_full = autocvar_hud_panel_weapons_ammo_full_cells;   break;
 442                                                 case ammo_plasma:  ammo_full = autocvar_hud_panel_weapons_ammo_full_plasma;  break;
 443                                                 case ammo_fuel:    ammo_full = autocvar_hud_panel_weapons_ammo_full_fuel;    break;
 444                                                 default: ammo_full = 60;
 445                                         }
 446
 447                                         drawsetcliparea(
 448                                                 weapon_pos.x + baroffset.x,
 449                                                 weapon_pos.y + baroffset.y,
 450                                                 barsize.x * bound(0, a/ammo_full, 1),
 451                                                 barsize.y
 452                                         );
 453
 454                                         drawpic_aspect_skin(
 455                                                 weapon_pos,
 456                                                 "weapon_ammo",
 457                                                 weapon_size,
 458                                                 ammo_color,
 459                                                 ammo_alpha,
 460                                                 DRAWFLAG_NORMAL
 461                                         );
 462
 463                                         drawresetcliparea();
 464                                 }
 465                         }
 466                 }
 467                 else // draw a "ghost weapon icon" if you don't have the weapon
 468                 {
 469                         drawpic_aspect_skin(noncurrent_pos, it.model2, noncurrent_size, '0.2 0.2 0.2', panel_fg_alpha * 0.5, DRAWFLAG_NORMAL);
 470                 }
 471
 472                 // draw the complain message
 473                 if(it.m_id == complain_weapon)
 474                 {
 475                         if(fadetime)
 476                                 a = ((complain_weapon_time + when > time) ? 1 : bound(0, (complain_weapon_time + when + fadetime - time) / fadetime, 1));
 477                         else
 478                                 a = ((complain_weapon_time + when > time) ? 1 : 0);
 479
 480                         string s;
 481                         if(complain_weapon_type == 0) {
 482                                 s = _("Out of ammo");
 483                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_outofammo);
 484                         }
 485                         else if(complain_weapon_type == 1) {
 486                                 s = _("Don't have");
 487                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_donthave);
 488                         }
 489                         else {
 490                                 s = _("Unavailable");
 491                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_unavailable);
 492                         }
 493                         float padding = autocvar_hud_panel_weapons_complainbubble_padding;
 494                         drawpic_aspect_skin(weapon_pos + '1 1 0' * padding, "weapon_complainbubble", weapon_size - '2 2 0' * padding, color, a * panel_fg_alpha, DRAWFLAG_NORMAL);
 495                         drawstring_aspect(weapon_pos + '1 1 0' * padding, s, weapon_size - '2 2 0' * padding, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
 496                 }
 497
 498                 #if 0
 499                 /// debug code
 500                 if(!autocvar_hud_panel_weapons_onlyowned)
 501                 {
 502                         drawfill(weapon_pos + '1 1 0', weapon_size - '2 2 0', '1 1 1', panel_fg_alpha * 0.2, DRAWFLAG_NORMAL);
 503                         drawstring(weapon_pos, ftos(i + 1), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 504                 }
 505                 #endif
 506
 507                 // continue with new position for the next weapon
 508                 if(vertical_order)
 509                 {
 510                         ++column;
 511                         if(column >= columns)
 512                         {
 513                                 column = 0;
 514                                 ++row;
 515                         }
 516                 }
 517                 else
 518                 {
 519                         ++row;
 520                         if(row >= rows)
 521                         {
 522                                 row = 0;
 523                                 ++column;
 524                         }
 525                 }
 526         }
 527 }