qcsrc/client/hud_config.qc

   1 #define HUD_Write(s) fputs(fh, s)
   2 // q: quoted, n: not quoted
   3 #define HUD_Write_Cvar_n(cvar) HUD_Write(strcat("seta ", cvar, " ", cvar_string(cvar), "\n"))
   4 #define HUD_Write_Cvar_q(cvar) HUD_Write(strcat("seta ", cvar, " \"", cvar_string(cvar), "\"\n"))
   5 #define HUD_Write_PanelCvar_n(cvar_suf) HUD_Write_Cvar_n(strcat("hud_panel_", panel.panel_name, cvar_suf))
   6 #define HUD_Write_PanelCvar_q(cvar_suf) HUD_Write_Cvar_q(strcat("hud_panel_", panel.panel_name, cvar_suf))
   7 // Save the config
   8 void HUD_Panel_ExportCfg(string cfgname)
   9 {
  10         float fh;
  11         string filename = strcat("hud_", autocvar_hud_skin, "_", cfgname, ".cfg");
  12         fh = fopen(filename, FILE_WRITE);
  13         if(fh >= 0)
  14         {
  15                 HUD_Write_Cvar_q("hud_skin");
  16                 HUD_Write_Cvar_q("hud_panel_bg");
  17                 HUD_Write_Cvar_q("hud_panel_bg_color");
  18                 HUD_Write_Cvar_q("hud_panel_bg_color_team");
  19                 HUD_Write_Cvar_q("hud_panel_bg_alpha");
  20                 HUD_Write_Cvar_q("hud_panel_bg_border");
  21                 HUD_Write_Cvar_q("hud_panel_bg_padding");
  22                 HUD_Write_Cvar_q("hud_panel_fg_alpha");
  23                 HUD_Write("\n");
  24
  25                 HUD_Write_Cvar_q("hud_dock");
  26                 HUD_Write_Cvar_q("hud_dock_color");
  27                 HUD_Write_Cvar_q("hud_dock_color_team");
  28                 HUD_Write_Cvar_q("hud_dock_alpha");
  29                 HUD_Write("\n");
  30
  31                 HUD_Write_Cvar_q("hud_progressbar_alpha");
  32                 HUD_Write_Cvar_q("hud_progressbar_strength_color");
  33                 HUD_Write_Cvar_q("hud_progressbar_shield_color");
  34                 HUD_Write_Cvar_q("hud_progressbar_health_color");
  35                 HUD_Write_Cvar_q("hud_progressbar_armor_color");
  36                 HUD_Write_Cvar_q("hud_progressbar_fuel_color");
  37                 HUD_Write_Cvar_q("hud_progressbar_nexball_color");
  38                 HUD_Write_Cvar_q("hud_progressbar_speed_color");
  39                 HUD_Write_Cvar_q("hud_progressbar_acceleration_color");
  40                 HUD_Write_Cvar_q("hud_progressbar_acceleration_neg_color");
  41                 HUD_Write("\n");
  42
  43                 HUD_Write_Cvar_q("_hud_panelorder");
  44                 HUD_Write("\n");
  45
  46                 HUD_Write_Cvar_q("hud_configure_grid");
  47                 HUD_Write_Cvar_q("hud_configure_grid_xsize");
  48                 HUD_Write_Cvar_q("hud_configure_grid_ysize");
  49                 HUD_Write("\n");
  50
  51                 // common cvars for all panels
  52                 float i;
  53                 for (i = 0; i < HUD_PANEL_NUM; ++i)
  54                 {
  55                         panel = hud_panel[i];
  56
  57                         HUD_Write_PanelCvar_n("");
  58                         HUD_Write_PanelCvar_q("_pos");
  59                         HUD_Write_PanelCvar_q("_size");
  60                         HUD_Write_PanelCvar_q("_bg");
  61                         HUD_Write_PanelCvar_q("_bg_color");
  62                         HUD_Write_PanelCvar_q("_bg_color_team");
  63                         HUD_Write_PanelCvar_q("_bg_alpha");
  64                         HUD_Write_PanelCvar_q("_bg_border");
  65                         HUD_Write_PanelCvar_q("_bg_padding");
  66                         switch(i) {
  67                                 case HUD_PANEL_WEAPONS:
  68                                         HUD_Write_PanelCvar_q("_accuracy");
  69                                         HUD_Write_PanelCvar_q("_label");
  70                                         HUD_Write_PanelCvar_q("_complainbubble");
  71                                         HUD_Write_PanelCvar_q("_complainbubble_padding");
  72                                         HUD_Write_PanelCvar_q("_complainbubble_time");
  73                                         HUD_Write_PanelCvar_q("_complainbubble_fadetime");
  74                                         HUD_Write_PanelCvar_q("_complainbubble_color_outofammo");
  75                                         HUD_Write_PanelCvar_q("_complainbubble_color_donthave");
  76                                         HUD_Write_PanelCvar_q("_complainbubble_color_unavailable");
  77                                         HUD_Write_PanelCvar_q("_ammo");
  78                                         HUD_Write_PanelCvar_q("_ammo_color");
  79                                         HUD_Write_PanelCvar_q("_ammo_alpha");
  80                                         HUD_Write_PanelCvar_q("_aspect");
  81                                         HUD_Write_PanelCvar_q("_timeout");
  82                                         HUD_Write_PanelCvar_q("_timeout_effect");
  83                                         HUD_Write_PanelCvar_q("_timeout_fadebgmin");
  84                                         HUD_Write_PanelCvar_q("_timeout_fadefgmin");
  85                                         HUD_Write_PanelCvar_q("_timeout_speed_in");
  86                                         HUD_Write_PanelCvar_q("_timeout_speed_out");
  87                                         HUD_Write_PanelCvar_q("_onlyowned");
  88                                         break;
  89                                 case HUD_PANEL_AMMO:
  90                                         HUD_Write_PanelCvar_q("_onlycurrent");
  91                                         HUD_Write_PanelCvar_q("_iconalign");
  92                                         HUD_Write_PanelCvar_q("_progressbar");
  93                                         HUD_Write_PanelCvar_q("_progressbar_name");
  94                                         HUD_Write_PanelCvar_q("_progressbar_xoffset");
  95                                         HUD_Write_PanelCvar_q("_text");
  96                                         break;
  97                                 case HUD_PANEL_POWERUPS:
  98                                         HUD_Write_PanelCvar_q("_flip");
  99                                         HUD_Write_PanelCvar_q("_iconalign");
 100                                         HUD_Write_PanelCvar_q("_baralign");
 101                                         HUD_Write_PanelCvar_q("_progressbar");
 102                                         HUD_Write_PanelCvar_q("_progressbar_strength");
 103                                         HUD_Write_PanelCvar_q("_progressbar_shield");
 104                                         HUD_Write_PanelCvar_q("_text");
 105                                         break;
 106                                 case HUD_PANEL_HEALTHARMOR:
 107                                         HUD_Write_PanelCvar_q("_flip");
 108                                         HUD_Write_PanelCvar_q("_iconalign");
 109                                         HUD_Write_PanelCvar_q("_baralign");
 110                                         HUD_Write_PanelCvar_q("_progressbar");
 111                                         HUD_Write_PanelCvar_q("_progressbar_health");
 112                                         HUD_Write_PanelCvar_q("_progressbar_armor");
 113                                         HUD_Write_PanelCvar_q("_progressbar_gfx");
 114                                         HUD_Write_PanelCvar_q("_progressbar_gfx_smooth");
 115                                         HUD_Write_PanelCvar_q("_text");
 116                                         break;
 117                                 case HUD_PANEL_NOTIFY:
 118                                         HUD_Write_PanelCvar_q("_flip");
 119                                         HUD_Write_PanelCvar_q("_fontsize");
 120                                         HUD_Write_PanelCvar_q("_time");
 121                                         HUD_Write_PanelCvar_q("_fadetime");
 122                                         HUD_Write_PanelCvar_q("_icon_aspect");
 123                                         break;
 124                                 case HUD_PANEL_TIMER:
 125                                         HUD_Write_PanelCvar_q("_increment");
 126                                         break;
 127                                 case HUD_PANEL_RADAR:
 128                                         HUD_Write_PanelCvar_q("_foreground_alpha");
 129                                         HUD_Write_PanelCvar_q("_rotation");
 130                                         HUD_Write_PanelCvar_q("_zoommode");
 131                                         HUD_Write_PanelCvar_q("_scale");
 132                                         HUD_Write_PanelCvar_q("_maximized_scale");
 133                                         HUD_Write_PanelCvar_q("_maximized_size");
 134                                         HUD_Write_PanelCvar_q("_maximized_rotation");
 135                                         HUD_Write_PanelCvar_q("_maximized_zoommode");
 136                                         break;
 137                                 case HUD_PANEL_SCORE:
 138                                         HUD_Write_PanelCvar_q("_rankings");
 139                                         break;
 140                                 case HUD_PANEL_VOTE:
 141                                         HUD_Write_PanelCvar_q("_alreadyvoted_alpha");
 142                                         break;
 143                                 case HUD_PANEL_MODICONS:
 144                                         HUD_Write_PanelCvar_q("_ca_layout");
 145                                         HUD_Write_PanelCvar_q("_dom_layout");
 146                                         HUD_Write_PanelCvar_q("_freezetag_layout");
 147                                         break;
 148                                 case HUD_PANEL_PRESSEDKEYS:
 149                                         HUD_Write_PanelCvar_q("_aspect");
 150                                         HUD_Write_PanelCvar_q("_attack");
 151                                         break;
 152                                 case HUD_PANEL_ENGINEINFO:
 153                                         HUD_Write_PanelCvar_q("_framecounter_time");
 154                                         HUD_Write_PanelCvar_q("_framecounter_decimals");
 155                                         break;
 156                                 case HUD_PANEL_INFOMESSAGES:
 157                                         HUD_Write_PanelCvar_q("_flip");
 158                                         break;
 159                                 case HUD_PANEL_PHYSICS:
 160                                         HUD_Write_PanelCvar_q("_speed_unit");
 161                                         HUD_Write_PanelCvar_q("_speed_unit_show");
 162                                         HUD_Write_PanelCvar_q("_speed_max");
 163                                         HUD_Write_PanelCvar_q("_speed_vertical");
 164                                         HUD_Write_PanelCvar_q("_topspeed");
 165                                         HUD_Write_PanelCvar_q("_topspeed_time");
 166                                         HUD_Write_PanelCvar_q("_acceleration_max");
 167                                         HUD_Write_PanelCvar_q("_acceleration_vertical");
 168                                         HUD_Write_PanelCvar_q("_flip");
 169                                         HUD_Write_PanelCvar_q("_baralign");
 170                                         HUD_Write_PanelCvar_q("_progressbar");
 171                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_mode");
 172                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_scale");
 173                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_nonlinear");
 174                                         HUD_Write_PanelCvar_q("_text");
 175                                         HUD_Write_PanelCvar_q("_text_scale");
 176                                         break;
 177                                 case HUD_PANEL_CENTERPRINT:
 178                                         HUD_Write_PanelCvar_q("_align");
 179                                         HUD_Write_PanelCvar_q("_flip");
 180                                         HUD_Write_PanelCvar_q("_fontscale");
 181                                         HUD_Write_PanelCvar_q("_time");
 182                                         HUD_Write_PanelCvar_q("_fade_in");
 183                                         HUD_Write_PanelCvar_q("_fade_out");
 184                                         HUD_Write_PanelCvar_q("_fade_subsequent");
 185                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone");
 186                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone_minalpha");
 187                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo");
 188                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo_minalpha");
 189                                         HUD_Write_PanelCvar_q("_fade_subsequent_minfontsize");
 190                                         HUD_Write_PanelCvar_q("_fade_minfontsize");
 191                                         break;
 192                         }
 193                         HUD_Write("\n");
 194                 }
 195                 HUD_Write("menu_sync\n"); // force the menu to reread the cvars, so that the dialogs are updated
 196
 197                 printf(_("^2Successfully exported to %s! (Note: It's saved in data/data/)\n"), filename);
 198                 fclose(fh);
 199         }
 200         else
 201                 printf(_("^1Couldn't write to %s\n"), filename);
 202 }
 203
 204 void HUD_Configure_Exit_Force()
 205 {
 206         if (menu_enabled)
 207         {
 208                 menu_enabled = 0;
 209                 localcmd("togglemenu\n");
 210         }
 211         cvar_set("_hud_configure", "0");
 212 }
 213
 214 // check if move will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 215 vector HUD_Panel_CheckMove(vector myPos, vector mySize)
 216 {
 217         float i;
 218         float myCenter_x, myCenter_y, targCenter_x, targCenter_y;
 219         vector myTarget;
 220         myTarget = myPos;
 221
 222         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 223                 panel = hud_panel[i];
 224                 if(panel == highlightedPanel) continue;
 225                 HUD_Panel_UpdatePosSize()
 226                 if(!panel_enabled) continue;
 227
 228                 panel_pos -= '1 1 0' * panel_bg_border;
 229                 panel_size += '2 2 0' * panel_bg_border;
 230
 231                 if(myPos_y + mySize_y < panel_pos_y)
 232                         continue;
 233                 if(myPos_y > panel_pos_y + panel_size_y)
 234                         continue;
 235
 236                 if(myPos_x + mySize_x < panel_pos_x)
 237                         continue;
 238                 if(myPos_x > panel_pos_x + panel_size_x)
 239                         continue;
 240
 241                 // OK, there IS a collision.
 242
 243                 myCenter_x = myPos_x + 0.5 * mySize_x;
 244                 myCenter_y = myPos_y + 0.5 * mySize_y;
 245
 246                 targCenter_x = panel_pos_x + 0.5 * panel_size_x;
 247                 targCenter_y = panel_pos_y + 0.5 * panel_size_y;
 248
 249                 if(myCenter_x < targCenter_x && myCenter_y < targCenter_y) // top left (of the target panel)
 250                 {
 251                         if(myPos_x + mySize_x - panel_pos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 252                                 myTarget_x = panel_pos_x - mySize_x;
 253                         else // push it upwards
 254                                 myTarget_y = panel_pos_y - mySize_y;
 255                 }
 256                 else if(myCenter_x > targCenter_x && myCenter_y < targCenter_y) // top right
 257                 {
 258                         if(panel_pos_x + panel_size_x - myPos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 259                                 myTarget_x = panel_pos_x + panel_size_x;
 260                         else // push it upwards
 261                                 myTarget_y = panel_pos_y - mySize_y;
 262                 }
 263                 else if(myCenter_x < targCenter_x && myCenter_y > targCenter_y) // bottom left
 264                 {
 265                         if(myPos_x + mySize_x - panel_pos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 266                                 myTarget_x = panel_pos_x - mySize_x;
 267                         else // push it downwards
 268                                 myTarget_y = panel_pos_y + panel_size_y;
 269                 }
 270                 else if(myCenter_x > targCenter_x && myCenter_y > targCenter_y) // bottom right
 271                 {
 272                         if(panel_pos_x + panel_size_x - myPos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 273                                 myTarget_x = panel_pos_x + panel_size_x;
 274                         else // push it downwards
 275                                 myTarget_y = panel_pos_y + panel_size_y;
 276                 }
 277                 //if(cvar("hud_configure_checkcollisions_debug"))
 278                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 279         }
 280
 281         return myTarget;
 282 }
 283
 284 void HUD_Panel_SetPos(vector pos)
 285 {
 286         panel = highlightedPanel;
 287         HUD_Panel_UpdatePosSize()
 288         vector mySize;
 289         mySize = panel_size;
 290
 291         //if(cvar("hud_configure_checkcollisions_debug"))
 292                 //drawfill(pos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 293
 294         if(autocvar_hud_configure_grid)
 295         {
 296                 pos_x = floor((pos_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 297                 pos_y = floor((pos_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 298         }
 299
 300         if(hud_configure_checkcollisions)
 301                 pos = HUD_Panel_CheckMove(pos, mySize);
 302
 303         pos_x = bound(0, pos_x, vid_conwidth - mySize_x);
 304         pos_y = bound(0, pos_y, vid_conheight - mySize_y);
 305
 306         string s;
 307         s = strcat(ftos(pos_x/vid_conwidth), " ", ftos(pos_y/vid_conheight));
 308
 309         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_pos"), s);
 310 }
 311
 312 // check if resize will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 313 vector HUD_Panel_CheckResize(vector mySize, vector resizeorigin) {
 314         float i;
 315
 316         vector targEndPos;
 317
 318         float dist_x, dist_y;
 319         float ratio;
 320         ratio = mySize_x/mySize_y;
 321
 322         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 323                 panel = hud_panel[i];
 324                 if(panel == highlightedPanel) continue;
 325                 HUD_Panel_UpdatePosSize()
 326                 if(!panel_enabled) continue;
 327
 328                 panel_pos -= '1 1 0' * panel_bg_border;
 329                 panel_size += '2 2 0' * panel_bg_border;
 330
 331                 targEndPos = panel_pos + panel_size;
 332
 333                 // resizeorigin is WITHIN target panel, just abort any collision testing against that particular panel to produce expected behaviour!
 334                 if(resizeorigin_x > panel_pos_x && resizeorigin_x < targEndPos_x && resizeorigin_y > panel_pos_y && resizeorigin_y < targEndPos_y)
 335                         continue;
 336
 337                 if (resizeCorner == 1)
 338                 {
 339                         // check if this panel is on our way
 340                         if (resizeorigin_x <= panel_pos_x)
 341                                 continue;
 342                         if (resizeorigin_y <= panel_pos_y)
 343                                 continue;
 344                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 345                                 continue;
 346                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 347                                 continue;
 348
 349                         // there is a collision:
 350                         // detect which side of the panel we are facing is actually limiting the resizing
 351                         // (which side the resize direction finds for first) and reduce the size up to there
 352                         //
 353                         // dist is the distance between resizeorigin and the "analogous" point of the panel
 354                         // in this case between resizeorigin (bottom-right point) and the bottom-right point of the panel
 355                         dist_x = resizeorigin_x - targEndPos_x;
 356                         dist_y = resizeorigin_y - targEndPos_y;
 357                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 358                                 mySize_x = min(mySize_x, dist_x);
 359                         else
 360                                 mySize_y = min(mySize_y, dist_y);
 361                 }
 362                 else if (resizeCorner == 2)
 363                 {
 364                         if (resizeorigin_x >= targEndPos_x)
 365                                 continue;
 366                         if (resizeorigin_y <= panel_pos_y)
 367                                 continue;
 368                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 369                                 continue;
 370                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 371                                 continue;
 372
 373                         dist_x = panel_pos_x - resizeorigin_x;
 374                         dist_y = resizeorigin_y - targEndPos_y;
 375                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 376                                 mySize_x = min(mySize_x, dist_x);
 377                         else
 378                                 mySize_y = min(mySize_y, dist_y);
 379                 }
 380                 else if (resizeCorner == 3)
 381                 {
 382                         if (resizeorigin_x <= panel_pos_x)
 383                                 continue;
 384                         if (resizeorigin_y >= targEndPos_y)
 385                                 continue;
 386                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 387                                 continue;
 388                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 389                                 continue;
 390
 391                         dist_x = resizeorigin_x - targEndPos_x;
 392                         dist_y = panel_pos_y - resizeorigin_y;
 393                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 394                                 mySize_x = min(mySize_x, dist_x);
 395                         else
 396                                 mySize_y = min(mySize_y, dist_y);
 397                 }
 398                 else if (resizeCorner == 4)
 399                 {
 400                         if (resizeorigin_x >= targEndPos_x)
 401                                 continue;
 402                         if (resizeorigin_y >= targEndPos_y)
 403                                 continue;
 404                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 405                                 continue;
 406                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 407                                 continue;
 408
 409                         dist_x = panel_pos_x - resizeorigin_x;
 410                         dist_y = panel_pos_y - resizeorigin_y;
 411                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 412                                 mySize_x = min(mySize_x, dist_x);
 413                         else
 414                                 mySize_y = min(mySize_y, dist_y);
 415                 }
 416                 //if(cvar("hud_configure_checkcollisions_debug"))
 417                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 418         }
 419
 420         return mySize;
 421 }
 422
 423 void HUD_Panel_SetPosSize(vector mySize)
 424 {
 425         panel = highlightedPanel;
 426         HUD_Panel_UpdatePosSize()
 427         vector resizeorigin;
 428         resizeorigin = panel_click_resizeorigin;
 429         local noref vector myPos; // fteqcc sucks
 430
 431         // minimum panel size cap
 432         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 433         mySize_y = max(0.025 * vid_conheight, mySize_y);
 434
 435         if(highlightedPanel == HUD_PANEL(CHAT)) // some panels have their own restrictions, like the chat panel (which actually only moves the engine chat print around). Looks bad if it's too small.
 436         {
 437                 mySize_x = max(17 * autocvar_con_chatsize, mySize_x);
 438                 mySize_y = max(2 * autocvar_con_chatsize + 2 * panel_bg_padding, mySize_y);
 439         }
 440
 441         // collision testing|
 442         // -----------------+
 443
 444         // we need to know pos at this stage, but it might still change later if we hit a screen edge/other panel (?)
 445         if(resizeCorner == 1) {
 446                 myPos_x = resizeorigin_x - mySize_x;
 447                 myPos_y = resizeorigin_y - mySize_y;
 448         } else if(resizeCorner == 2) {
 449                 myPos_x = resizeorigin_x;
 450                 myPos_y = resizeorigin_y - mySize_y;
 451         } else if(resizeCorner == 3) {
 452                 myPos_x = resizeorigin_x - mySize_x;
 453                 myPos_y = resizeorigin_y;
 454         } else { // resizeCorner == 4
 455                 myPos_x = resizeorigin_x;
 456                 myPos_y = resizeorigin_y;
 457         }
 458
 459         // left/top screen edges
 460         if(myPos_x < 0)
 461                 mySize_x = mySize_x + myPos_x;
 462         if(myPos_y < 0)
 463                 mySize_y = mySize_y + myPos_y;
 464
 465         // bottom/right screen edges
 466         if(myPos_x + mySize_x > vid_conwidth)
 467                 mySize_x = vid_conwidth - myPos_x;
 468         if(myPos_y + mySize_y > vid_conheight)
 469                 mySize_y = vid_conheight - myPos_y;
 470
 471         //if(cvar("hud_configure_checkcollisions_debug"))
 472                 //drawfill(myPos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 473
 474         // before checkresize, otherwise panel can be snapped partially inside another panel or panel aspect ratio can be broken
 475         if(autocvar_hud_configure_grid)
 476         {
 477                 mySize_x = floor((mySize_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 478                 mySize_y = floor((mySize_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 479         }
 480
 481         if(hud_configure_checkcollisions)
 482                 mySize = HUD_Panel_CheckResize(mySize, resizeorigin);
 483
 484         // minimum panel size cap, do this once more so we NEVER EVER EVER have a panel smaller than this, JUST IN CASE above code still makes the panel eg negative (impossible to resize back without changing cvars manually then)
 485         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 486         mySize_y = max(0.025 * vid_conheight, mySize_y);
 487
 488         // do another pos check, as size might have changed by now
 489         if(resizeCorner == 1) {
 490                 myPos_x = resizeorigin_x - mySize_x;
 491                 myPos_y = resizeorigin_y - mySize_y;
 492         } else if(resizeCorner == 2) {
 493                 myPos_x = resizeorigin_x;
 494                 myPos_y = resizeorigin_y - mySize_y;
 495         } else if(resizeCorner == 3) {
 496                 myPos_x = resizeorigin_x - mySize_x;
 497                 myPos_y = resizeorigin_y;
 498         } else { // resizeCorner == 4
 499                 myPos_x = resizeorigin_x;
 500                 myPos_y = resizeorigin_y;
 501         }
 502
 503         //if(cvar("hud_configure_checkcollisions_debug"))
 504                 //drawfill(myPos, mySize, '0 1 0', .3, DRAWFLAG_NORMAL);
 505
 506         string s;
 507         s = strcat(ftos(mySize_x/vid_conwidth), " ", ftos(mySize_y/vid_conheight));
 508         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_size"), s);
 509
 510         s = strcat(ftos(myPos_x/vid_conwidth), " ", ftos(myPos_y/vid_conheight));
 511         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_pos"), s);
 512 }
 513
 514 float pressed_key_time;
 515 vector highlightedPanel_initial_pos, highlightedPanel_initial_size;
 516 void HUD_Panel_Arrow_Action(float nPrimary)
 517 {
 518         if(!highlightedPanel)
 519                 return;
 520
 521         hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
 522
 523         float step;
 524         if(autocvar_hud_configure_grid)
 525         {
 526                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 527                 {
 528                         if (hudShiftState & S_SHIFT)
 529                                 step = hud_configure_realGridSize_y;
 530                         else
 531                                 step = 2 * hud_configure_realGridSize_y;
 532                 }
 533                 else
 534                 {
 535                         if (hudShiftState & S_SHIFT)
 536                                 step = hud_configure_realGridSize_x;
 537                         else
 538                                 step = 2 * hud_configure_realGridSize_x;
 539                 }
 540         }
 541         else
 542         {
 543                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 544                         step = vid_conheight;
 545                 else
 546                         step = vid_conwidth;
 547                 if (hudShiftState & S_SHIFT)
 548                         step = (step / 256); // more precision
 549                 else
 550                         step = (step / 64) * (1 + 2 * (time - pressed_key_time));
 551         }
 552
 553         panel = highlightedPanel;
 554         HUD_Panel_UpdatePosSize()
 555
 556         highlightedPanel_initial_pos = panel_pos;
 557         highlightedPanel_initial_size = panel_size;
 558
 559         if (hudShiftState & S_ALT) // resize
 560         {
 561                 highlightedAction = 1;
 562                 if(nPrimary == K_UPARROW)
 563                         resizeCorner = 1;
 564                 else if(nPrimary == K_RIGHTARROW)
 565                         resizeCorner = 2;
 566                 else if(nPrimary == K_LEFTARROW)
 567                         resizeCorner = 3;
 568                 else // if(nPrimary == K_DOWNARROW)
 569                         resizeCorner = 4;
 570
 571                 // ctrl+arrow reduces the size, instead of increasing it
 572                 // Note that ctrl disables collisions check too, but it's fine
 573                 // since we don't collide with anything reducing the size
 574                 if (hudShiftState & S_CTRL) {
 575                         step = -step;
 576                         resizeCorner = 5 - resizeCorner;
 577                 }
 578
 579                 vector mySize;
 580                 mySize = panel_size;
 581                 panel_click_resizeorigin = panel_pos;
 582                 if(resizeCorner == 1) {
 583                         panel_click_resizeorigin += mySize;
 584                         mySize_y += step;
 585                 } else if(resizeCorner == 2) {
 586                         panel_click_resizeorigin_y += mySize_y;
 587                         mySize_x += step;
 588                 } else if(resizeCorner == 3) {
 589                         panel_click_resizeorigin_x += mySize_x;
 590                         mySize_x += step;
 591                 } else { // resizeCorner == 4
 592                         mySize_y += step;
 593                 }
 594                 HUD_Panel_SetPosSize(mySize);
 595         }
 596         else // move
 597         {
 598                 highlightedAction = 2;
 599                 vector pos;
 600                 pos = panel_pos;
 601                 if(nPrimary == K_UPARROW)
 602                         pos_y -= step;
 603                 else if(nPrimary == K_DOWNARROW)
 604                         pos_y += step;
 605                 else if(nPrimary == K_LEFTARROW)
 606                         pos_x -= step;
 607                 else // if(nPrimary == K_RIGHTARROW)
 608                         pos_x += step;
 609
 610                 HUD_Panel_SetPos(pos);
 611         }
 612
 613         panel = highlightedPanel;
 614         HUD_Panel_UpdatePosSize()
 615
 616         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
 617         {
 618                 // backup!
 619                 panel_pos_backup = highlightedPanel_initial_pos;
 620                 panel_size_backup = highlightedPanel_initial_size;
 621                 highlightedPanel_backup = highlightedPanel;
 622         }
 623 }
 624
 625 const float S_MOUSE1 = 1;
 626 const float S_MOUSE2 = 2;
 627 const float S_MOUSE3 = 4;
 628 float mouseClicked;
 629 float prevMouseClicked; // previous state
 630 float prevMouseClickedTime; // time during previous left mouse click, to check for doubleclicks
 631 vector prevMouseClickedPos; // pos during previous left mouse click, to check for doubleclicks
 632
 633 void HUD_Panel_EnableMenu();
 634 entity tab_panels[HUD_PANEL_MAX];
 635 entity tab_panel;
 636 vector tab_panel_pos;
 637 float tab_backward;
 638 void HUD_Panel_FirstInDrawQ(float id);
 639 void reset_tab_panels()
 640 {
 641         int i;
 642         for(i = 0; i < HUD_PANEL_NUM; ++i)
 643                 tab_panels[i] = world;
 644 }
 645 float HUD_Panel_InputEvent(float bInputType, float nPrimary, float nSecondary)
 646 {
 647         string s;
 648
 649         if(bInputType == 2)
 650                 return false;
 651
 652         if(!autocvar__hud_configure)
 653                 return false;
 654
 655         if(bInputType == 3)
 656         {
 657                 mousepos_x = nPrimary;
 658                 mousepos_y = nSecondary;
 659                 return true;
 660         }
 661
 662         // block any input while a menu dialog is fading
 663         // don't block mousepos read as it leads to cursor jumps in the interaction with the menu
 664         if(autocvar__menu_alpha)
 665         {
 666                 hudShiftState = 0;
 667                 mouseClicked = 0;
 668                 return true;
 669         }
 670
 671         // allow console bind to work
 672         string con_keys;
 673         float keys;
 674         con_keys = findkeysforcommand("toggleconsole", 0);
 675         keys = tokenize(con_keys); // findkeysforcommand returns data for this
 676
 677         float hit_con_bind = 0, i;
 678         for (i = 0; i < keys; ++i)
 679         {
 680                 if(nPrimary == stof(argv(i)))
 681                         hit_con_bind = 1;
 682         }
 683
 684         if(bInputType == 0) {
 685                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 686                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 687                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 688         }
 689         else if(bInputType == 1) {
 690                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 691                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 692                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 693         }
 694
 695         if(nPrimary == K_CTRL)
 696         {
 697                 if (bInputType == 1) //ctrl has been released
 698                 {
 699                         if (tab_panel)
 700                         {
 701                                 //switch to selected panel
 702                                 highlightedPanel = tab_panel;
 703                                 highlightedAction = 0;
 704                                 HUD_Panel_FirstInDrawQ(highlightedPanel.panel_id);
 705                         }
 706                         tab_panel = world;
 707                         reset_tab_panels();
 708                 }
 709         }
 710
 711         if(nPrimary == K_MOUSE1)
 712         {
 713                 if(bInputType == 0) // key pressed
 714                         mouseClicked |= S_MOUSE1;
 715                 else if(bInputType == 1) // key released
 716                         mouseClicked -= (mouseClicked & S_MOUSE1);
 717         }
 718         else if(nPrimary == K_MOUSE2)
 719         {
 720                 if(bInputType == 0) // key pressed
 721                         mouseClicked |= S_MOUSE2;
 722                 else if(bInputType == 1) // key released
 723                         mouseClicked -= (mouseClicked & S_MOUSE2);
 724         }
 725         else if(nPrimary == K_ESCAPE)
 726         {
 727                 if (bInputType == 1)
 728                         return true;
 729                 menu_enabled = 1;
 730                 localcmd("menu_showhudexit\n");
 731         }
 732         else if(nPrimary == K_BACKSPACE && hudShiftState & S_CTRL)
 733         {
 734                 if (bInputType == 1)
 735                         return true;
 736                 if (!menu_enabled)
 737                         cvar_set("_hud_configure", "0");
 738         }
 739         else if(nPrimary == K_TAB && hudShiftState & S_CTRL) // select and highlight another panel
 740         {
 741                 if (bInputType == 1 || mouseClicked)
 742                         return true;
 743
 744                 //FIXME: if a panel is highlighted, has the same pos_x and lays in the same level
 745                 //of other panels then next consecutive ctrl-tab will select the highlighted panel too
 746                 //(it should only after every other panel of the hud)
 747                 //It's a minor bug anyway, we can live with it
 748
 749                 entity starting_panel;
 750                 entity old_tab_panel = tab_panel;
 751                 if (!tab_panel) //first press of TAB
 752                 {
 753                         if (highlightedPanel)
 754                         {
 755                                 panel = highlightedPanel;
 756                                 HUD_Panel_UpdatePosSize()
 757                         }
 758                         else
 759                                 panel_pos = '0 0 0';
 760                         starting_panel = highlightedPanel;
 761                         tab_panel_pos = panel_pos; //to compute level
 762                 }
 763                 else
 764                 {
 765                         if ( ((!tab_backward) && (hudShiftState & S_SHIFT)) || (tab_backward && !(hudShiftState & S_SHIFT)) ) //tab direction changed?
 766                                 reset_tab_panels();
 767                         starting_panel = tab_panel;
 768                 }
 769                 tab_backward = (hudShiftState & S_SHIFT);
 770
 771                 float k, level = 0, start_pos_x;
 772                 vector candidate_pos = '0 0 0';
 773                 const float LEVELS_NUM = 4;
 774                 float level_height = vid_conheight / LEVELS_NUM;
 775 :find_tab_panel
 776                 level = floor(tab_panel_pos_y / level_height) * level_height; //starting level
 777                 candidate_pos_x = (!tab_backward) ? vid_conwidth : 0;
 778                 start_pos_x = tab_panel_pos_x;
 779                 tab_panel = world;
 780                 k=0;
 781                 while(++k)
 782                 {
 783                         for(i = 0; i < HUD_PANEL_NUM; ++i)
 784                         {
 785                                 panel = hud_panel[i];
 786                                 if (panel == tab_panels[i] || panel == starting_panel)
 787                                         continue;
 788                                 HUD_Panel_UpdatePosSize()
 789                                 if (panel_pos_y >= level && (panel_pos_y - level) < level_height)
 790                                 if (  ( !tab_backward && panel_pos_x >= start_pos_x && (panel_pos_x < candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y <= candidate_pos_y)) )
 791                                         || ( tab_backward && panel_pos_x <= start_pos_x && (panel_pos_x > candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y >= candidate_pos_y)) )  )
 792                                 {
 793                                         tab_panel = panel;
 794                                         tab_panel_pos = candidate_pos = panel_pos;
 795                                 }
 796                         }
 797                         if (tab_panel)
 798                                 break;
 799                         if (k == LEVELS_NUM) //tab_panel not found
 800                         {
 801                                 reset_tab_panels();
 802                                 if (!old_tab_panel)
 803                                 {
 804                                         tab_panel = world;
 805                                         return true;
 806                                 }
 807                                 starting_panel = old_tab_panel;
 808                                 old_tab_panel = world;
 809                                 goto find_tab_panel; //u must find tab_panel!
 810                         }
 811                         if (!tab_backward)
 812                         {
 813                                 level = (level + level_height) % vid_conheight;
 814                                 start_pos_x = 0;
 815                                 candidate_pos_x = vid_conwidth;
 816                         }
 817                         else
 818                         {
 819                                 level = (level - level_height) % vid_conheight;
 820                                 start_pos_x = vid_conwidth;
 821                                 candidate_pos_x = 0;
 822                         }
 823                 }
 824
 825                 tab_panels[tab_panel.panel_id] = tab_panel;
 826         }
 827         else if(nPrimary == K_SPACE && hudShiftState & S_CTRL) // enable/disable highlighted panel or dock
 828         {
 829                 if (bInputType == 1 || mouseClicked)
 830                         return true;
 831
 832                 if (highlightedPanel)
 833                         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name), ftos(!cvar(strcat("hud_panel_", highlightedPanel.panel_name))));
 834                 else
 835                         cvar_set(strcat("hud_dock"), (autocvar_hud_dock == "") ? "dock" : "");
 836         }
 837         else if(nPrimary == 'c' && hudShiftState & S_CTRL) // copy highlighted panel size
 838         {
 839                 if (bInputType == 1 || mouseClicked)
 840                         return true;
 841
 842                 if (highlightedPanel)
 843                 {
 844                         panel = highlightedPanel;
 845                         HUD_Panel_UpdatePosSize()
 846                         panel_size_copied = panel_size;
 847                 }
 848         }
 849         else if(nPrimary == 'v' && hudShiftState & S_CTRL) // past copied size on the highlighted panel
 850         {
 851                 if (bInputType == 1 || mouseClicked)
 852                         return true;
 853
 854                 if (panel_size_copied == '0 0 0' || !highlightedPanel)
 855                         return true;
 856
 857                 panel = highlightedPanel;
 858                 HUD_Panel_UpdatePosSize()
 859
 860                 // reduce size if it'd go beyond screen boundaries
 861                 vector tmp_size = panel_size_copied;
 862                 if (panel_pos_x + panel_size_copied_x > vid_conwidth)
 863                         tmp_size_x = vid_conwidth - panel_pos_x;
 864                 if (panel_pos_y + panel_size_copied_y > vid_conheight)
 865                         tmp_size_y = vid_conheight - panel_pos_y;
 866
 867                 if (panel_size == tmp_size)
 868                         return true;
 869
 870                 // backup first!
 871                 panel_pos_backup = panel_pos;
 872                 panel_size_backup = panel_size;
 873                 highlightedPanel_backup = highlightedPanel;
 874
 875                 s = strcat(ftos(tmp_size_x/vid_conwidth), " ", ftos(tmp_size_y/vid_conheight));
 876                 cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_size"), s);
 877         }
 878         else if(nPrimary == 'z' && hudShiftState & S_CTRL) // undo last action
 879         {
 880                 if (bInputType == 1 || mouseClicked)
 881                         return true;
 882                 //restore previous values
 883                 if (highlightedPanel_backup)
 884                 {
 885                         s = strcat(ftos(panel_pos_backup_x/vid_conwidth), " ", ftos(panel_pos_backup_y/vid_conheight));
 886                         cvar_set(strcat("hud_panel_", highlightedPanel_backup.panel_name, "_pos"), s);
 887                         s = strcat(ftos(panel_size_backup_x/vid_conwidth), " ", ftos(panel_size_backup_y/vid_conheight));
 888                         cvar_set(strcat("hud_panel_", highlightedPanel_backup.panel_name, "_size"), s);
 889                         highlightedPanel_backup = world;
 890                 }
 891         }
 892         else if(nPrimary == K_UPARROW || nPrimary == K_DOWNARROW || nPrimary == K_LEFTARROW || nPrimary == K_RIGHTARROW)
 893         {
 894                 if (bInputType == 1)
 895                 {
 896                         pressed_key_time = 0;
 897                         return true;
 898                 }
 899                 else if (pressed_key_time == 0)
 900                         pressed_key_time = time;
 901
 902                 if (!mouseClicked)
 903                         HUD_Panel_Arrow_Action(nPrimary); //move or resize panel
 904         }
 905         else if(nPrimary == K_ENTER || nPrimary == K_SPACE || nPrimary == K_KP_ENTER)
 906         {
 907                 if (bInputType == 1)
 908                         return true;
 909                 if (highlightedPanel)
 910                         HUD_Panel_EnableMenu();
 911         }
 912         else if(hit_con_bind)
 913                 return false;
 914
 915         return true;
 916 }
 917
 918 float HUD_Panel_Check_Mouse_Pos(float allow_move)
 919 {
 920         float i, j = 0, border;
 921
 922         while(j < HUD_PANEL_NUM)
 923         {
 924                 i = panel_order[j];
 925                 j += 1;
 926
 927                 panel = hud_panel[i];
 928                 HUD_Panel_UpdatePosSize()
 929
 930                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 931
 932                 // move
 933                 if(allow_move && mousepos_x > panel_pos_x && mousepos_y > panel_pos_y && mousepos_x < panel_pos_x + panel_size_x && mousepos_y < panel_pos_y + panel_size_y)
 934                 {
 935                         return 1;
 936                 }
 937                 // resize from topleft border
 938                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 939                 {
 940                         return 2;
 941                 }
 942                 // resize from topright border
 943                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 944                 {
 945                         return 3;
 946                 }
 947                 // resize from bottomleft border
 948                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
 949                 {
 950                         return 3;
 951                 }
 952                 // resize from bottomright border
 953                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
 954                 {
 955                         return 2;
 956                 }
 957         }
 958         return 0;
 959 }
 960
 961 // move a panel to the beginning of the panel order array (which means it gets drawn last, on top of everything else)
 962 void HUD_Panel_FirstInDrawQ(float id)
 963 {
 964         float i;
 965         var float place = -1;
 966         // find out where in the array our current id is, save into place
 967         for(i = 0; i < HUD_PANEL_NUM; ++i)
 968         {
 969                 if(panel_order[i] == id)
 970                 {
 971                         place = i;
 972                         break;
 973                 }
 974         }
 975         // place last if we didn't find a place for it yet (probably new panel, or screwed up cvar)
 976         if(place == -1)
 977                 place = HUD_PANEL_NUM - 1;
 978
 979         // move all ids up by one step in the array until "place"
 980         for(i = place; i > 0; --i)
 981         {
 982                 panel_order[i] = panel_order[i-1];
 983         }
 984         // now save the new top id
 985         panel_order[0] = id;
 986
 987         // let's save them into the cvar by some strcat trickery
 988         string s = "";
 989         for(i = 0; i < HUD_PANEL_NUM; ++i)
 990         {
 991                 s = strcat(s, ftos(panel_order[i]), " ");
 992         }
 993         cvar_set("_hud_panelorder", s);
 994         if(hud_panelorder_prev)
 995                 strunzone(hud_panelorder_prev);
 996         hud_panelorder_prev = strzone(autocvar__hud_panelorder); // prevent HUD_Main from doing useless update, we already updated here
 997 }
 998
 999 void HUD_Panel_Highlight(float allow_move)
1000 {
1001         float i, j = 0, border;
1002
1003         while(j < HUD_PANEL_NUM)
1004         {
1005                 i = panel_order[j];
1006                 j += 1;
1007
1008                 panel = hud_panel[i];
1009                 HUD_Panel_UpdatePosSize()
1010
1011                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
1012
1013                 // move
1014                 if(allow_move && mousepos_x > panel_pos_x && mousepos_y > panel_pos_y && mousepos_x < panel_pos_x + panel_size_x && mousepos_y < panel_pos_y + panel_size_y)
1015                 {
1016                         highlightedPanel = hud_panel[i];
1017                         HUD_Panel_FirstInDrawQ(i);
1018                         highlightedAction = 1;
1019                         panel_click_distance = mousepos - panel_pos;
1020                         return;
1021                 }
1022                 // resize from topleft border
1023                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
1024                 {
1025                         highlightedPanel = hud_panel[i];
1026                         HUD_Panel_FirstInDrawQ(i);
1027                         highlightedAction = 2;
1028                         resizeCorner = 1;
1029                         panel_click_distance = mousepos - panel_pos;
1030                         panel_click_resizeorigin = panel_pos + panel_size;
1031                         return;
1032                 }
1033                 // resize from topright border
1034                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
1035                 {
1036                         highlightedPanel = hud_panel[i];
1037                         HUD_Panel_FirstInDrawQ(i);
1038                         highlightedAction = 2;
1039                         resizeCorner = 2;
1040                         panel_click_distance_x = panel_size_x - mousepos_x + panel_pos_x;
1041                         panel_click_distance_y = mousepos_y - panel_pos_y;
1042                         panel_click_resizeorigin = panel_pos + eY * panel_size_y;
1043                         return;
1044                 }
1045                 // resize from bottomleft border
1046                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
1047                 {
1048                         highlightedPanel = hud_panel[i];
1049                         HUD_Panel_FirstInDrawQ(i);
1050                         highlightedAction = 2;
1051                         resizeCorner = 3;
1052                         panel_click_distance_x = mousepos_x - panel_pos_x;
1053                         panel_click_distance_y = panel_size_y - mousepos_y + panel_pos_y;
1054                         panel_click_resizeorigin = panel_pos + eX * panel_size_x;
1055                         return;
1056                 }
1057                 // resize from bottomright border
1058                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
1059                 {
1060                         highlightedPanel = hud_panel[i];
1061                         HUD_Panel_FirstInDrawQ(i);
1062                         highlightedAction = 2;
1063                         resizeCorner = 4;
1064                         panel_click_distance = panel_size - mousepos + panel_pos;
1065                         panel_click_resizeorigin = panel_pos;
1066                         return;
1067                 }
1068         }
1069         highlightedPanel = world;
1070         highlightedAction = 0;
1071 }
1072
1073 void HUD_Panel_EnableMenu()
1074 {
1075         menu_enabled = 2;
1076         localcmd("menu_showhudoptions ", highlightedPanel.panel_name, "\n");
1077 }
1078 float mouse_over_panel;
1079 void HUD_Panel_Mouse()
1080 {
1081         if(autocvar__menu_alpha == 1)
1082                 return;
1083
1084         if (!autocvar_hud_cursormode)
1085         {
1086                 mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
1087
1088                 mousepos_x = bound(0, mousepos_x, vid_conwidth);
1089                 mousepos_y = bound(0, mousepos_y, vid_conheight);
1090         }
1091
1092         if(mouseClicked)
1093         {
1094                 if(prevMouseClicked == 0)
1095                 {
1096                         if (tab_panel)
1097                         {
1098                                 //stop ctrl-tab selection
1099                                 tab_panel = world;
1100                                 reset_tab_panels();
1101                         }
1102                         HUD_Panel_Highlight(mouseClicked & S_MOUSE1); // sets highlightedPanel, highlightedAction, panel_click_distance, panel_click_resizeorigin
1103                                                                         // and calls HUD_Panel_UpdatePosSize() for the highlighted panel
1104                         if (highlightedPanel)
1105                         {
1106                                 highlightedPanel_initial_pos = panel_pos;
1107                                 highlightedPanel_initial_size = panel_size;
1108                         }
1109                         // doubleclick check
1110                         if ((mouseClicked & S_MOUSE1) && time - prevMouseClickedTime < 0.4 && highlightedPanel && prevMouseClickedPos == mousepos)
1111                         {
1112                                 mouseClicked = 0; // to prevent spam, I guess.
1113                                 HUD_Panel_EnableMenu();
1114                         }
1115                         else
1116                         {
1117                                 if (mouseClicked & S_MOUSE1)
1118                                 {
1119                                         prevMouseClickedTime = time;
1120                                         prevMouseClickedPos = mousepos;
1121                                 }
1122                                 mouse_over_panel = HUD_Panel_Check_Mouse_Pos(mouseClicked & S_MOUSE1);
1123                         }
1124                 }
1125                 else
1126                 {
1127                         panel = highlightedPanel;
1128                         HUD_Panel_UpdatePosSize()
1129                 }
1130
1131                 if (highlightedPanel)
1132                 {
1133                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1134                         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
1135                         {
1136                                 hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
1137                                 // backup!
1138                                 panel_pos_backup = highlightedPanel_initial_pos;
1139                                 panel_size_backup = highlightedPanel_initial_size;
1140                                 highlightedPanel_backup = highlightedPanel;
1141                         }
1142                         else
1143                                 // in case the clicked panel is inside another panel and we aren't
1144                                 // moving it, avoid the immediate "fix" of its position/size
1145                                 // (often unwanted and hateful) by disabling collisions check
1146                                 hud_configure_checkcollisions = false;
1147                 }
1148
1149                 if(highlightedAction == 1)
1150                         HUD_Panel_SetPos(mousepos - panel_click_distance);
1151                 else if(highlightedAction == 2)
1152                 {
1153                         vector mySize = '0 0 0';
1154                         if(resizeCorner == 1) {
1155                                 mySize_x = panel_click_resizeorigin_x - (mousepos_x - panel_click_distance_x);
1156                                 mySize_y = panel_click_resizeorigin_y - (mousepos_y - panel_click_distance_y);
1157                         } else if(resizeCorner == 2) {
1158                                 mySize_x = mousepos_x + panel_click_distance_x - panel_click_resizeorigin_x;
1159                                 mySize_y = panel_click_distance_y + panel_click_resizeorigin_y - mousepos_y;
1160                         } else if(resizeCorner == 3) {
1161                                 mySize_x = panel_click_resizeorigin_x + panel_click_distance_x - mousepos_x;
1162                                 mySize_y = mousepos_y + panel_click_distance_y - panel_click_resizeorigin_y;
1163                         } else { // resizeCorner == 4
1164                                 mySize_x = mousepos_x - (panel_click_resizeorigin_x - panel_click_distance_x);
1165                                 mySize_y = mousepos_y - (panel_click_resizeorigin_y - panel_click_distance_y);
1166                         }
1167                         HUD_Panel_SetPosSize(mySize);
1168                 }
1169         }
1170         else
1171         {
1172                 if(menu_enabled == 2)
1173                         mouse_over_panel = 0;
1174                 else
1175                         mouse_over_panel = HUD_Panel_Check_Mouse_Pos(TRUE);
1176                 if (mouse_over_panel && !tab_panel)
1177                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1178         }
1179         // draw cursor after performing move/resize to have the panel pos/size updated before mouse_over_panel
1180         const vector cursorsize = '32 32 0';
1181         float cursor_alpha = 1 - autocvar__menu_alpha;
1182
1183         if(!mouse_over_panel)
1184                 drawpic(mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1185         else if(mouse_over_panel == 1)
1186                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_move.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1187         else if(mouse_over_panel == 2)
1188                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1189         else
1190                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize2.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1191
1192         prevMouseClicked = mouseClicked;
1193 }
1194 void HUD_Configure_DrawGrid()
1195 {
1196         float i;
1197         if(autocvar_hud_configure_grid && autocvar_hud_configure_grid_alpha)
1198         {
1199                 hud_configure_gridSize_x = bound(0.005, cvar("hud_configure_grid_xsize"), 0.2);
1200                 hud_configure_gridSize_y = bound(0.005, cvar("hud_configure_grid_ysize"), 0.2);
1201                 hud_configure_realGridSize_x = hud_configure_gridSize_x * vid_conwidth;
1202                 hud_configure_realGridSize_y = hud_configure_gridSize_y * vid_conheight;
1203                 vector s;
1204                 // x-axis
1205                 s = eX + eY * vid_conheight;
1206                 for(i = 1; i < 1/hud_configure_gridSize_x; ++i)
1207                         drawfill(eX * i * hud_configure_realGridSize_x, s, '0.5 0.5 0.5', autocvar_hud_configure_grid_alpha, DRAWFLAG_NORMAL);
1208                 // y-axis
1209                 s = eY + eX * vid_conwidth;
1210                 for(i = 1; i < 1/hud_configure_gridSize_y; ++i)
1211                         drawfill(eY * i * hud_configure_realGridSize_y, s, '0.5 0.5 0.5', autocvar_hud_configure_grid_alpha, DRAWFLAG_NORMAL);
1212         }
1213 }
1214
1215 float _menu_alpha_prev;
1216 void HUD_Configure_Frame()
1217 {
1218         float i;
1219         if(autocvar__hud_configure)
1220         {
1221                 if(isdemo() || intermission == 2)
1222                 {
1223                         HUD_Configure_Exit_Force();
1224                         return;
1225                 }
1226
1227                 if(!hud_configure_prev || hud_configure_prev == -1)
1228                 {
1229                         if(autocvar_hud_cursormode)
1230                                 setcursormode(1);
1231                         hudShiftState = 0;
1232                         for(i = HUD_PANEL_NUM - 1; i >= 0; --i)
1233                                 hud_panel[panel_order[i]].update_time = time;
1234                 }
1235
1236                 // NOTE this check is necessary because _menu_alpha isn't updated the frame the menu gets enabled
1237                 if(autocvar__menu_alpha != _menu_alpha_prev)
1238                 {
1239                         if(autocvar__menu_alpha == 0)
1240                                 menu_enabled = 0;
1241                         _menu_alpha_prev = autocvar__menu_alpha;
1242                 }
1243
1244                 HUD_Configure_DrawGrid();
1245         }
1246         else if(hud_configure_prev)
1247         {
1248                 if(menu_enabled)
1249                         menu_enabled = 0;
1250                 if(autocvar_hud_cursormode)
1251                         setcursormode(0);
1252         }
1253 }
1254
1255 const float hlBorderSize = 4;
1256 const string hlBorder = "gfx/hud/default/border_highlighted";
1257 const string hlBorder2 = "gfx/hud/default/border_highlighted2";
1258 void HUD_Panel_HlBorder(float myBorder, vector color, float theAlpha)
1259 {
1260         drawfill(panel_pos - '1 1 0' * myBorder, panel_size + '2 2 0' * myBorder, '0 0.5 1', .5 * theAlpha, DRAWFLAG_NORMAL);
1261         drawpic_tiled(panel_pos - '1 1 0' * myBorder, hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1262         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * (panel_size_y + 2 * myBorder - hlBorderSize), hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1263         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize, hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1264         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize + eX * (panel_size_x + 2 * myBorder - hlBorderSize), hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1265 }
1266
1267 void HUD_Configure_PostDraw()
1268 {
1269         if(autocvar__hud_configure)
1270         {
1271                 if(tab_panel)
1272                 {
1273                         panel = tab_panel;
1274                         HUD_Panel_UpdatePosSize()
1275                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .2, DRAWFLAG_NORMAL);
1276                 }
1277                 if(highlightedPanel)
1278                 {
1279                         panel = highlightedPanel;
1280                         HUD_Panel_UpdatePosSize()
1281                         HUD_Panel_HlBorder(panel_bg_border + 1.5 * hlBorderSize, '0 0.5 1', 0.25 * (1 - autocvar__menu_alpha));
1282                 }
1283         }
1284 }