qcsrc/client/hud_config.qc

   1 #define HUD_Write(s) fputs(fh, s)
   2 // q: quoted, n: not quoted
   3 #define HUD_Write_Cvar_n(cvar) HUD_Write(strcat("seta ", cvar, " ", cvar_string(cvar), "\n"))
   4 #define HUD_Write_Cvar_q(cvar) HUD_Write(strcat("seta ", cvar, " \"", cvar_string(cvar), "\"\n"))
   5 #define HUD_Write_PanelCvar_n(cvar_suf) HUD_Write_Cvar_n(strcat("hud_panel_", panel_name, cvar_suf))
   6 #define HUD_Write_PanelCvar_q(cvar_suf) HUD_Write_Cvar_q(strcat("hud_panel_", panel_name, cvar_suf))
   7 // Save the config
   8 void HUD_Panel_ExportCfg(string cfgname)
   9 {
  10         float fh;
  11         string filename = strcat("hud_", autocvar_hud_skin, "_", cfgname, ".cfg");
  12         fh = fopen(filename, FILE_WRITE);
  13         if(fh >= 0)
  14         {
  15                 HUD_Write_Cvar_q("hud_skin");
  16                 HUD_Write_Cvar_q("hud_panel_bg");
  17                 HUD_Write_Cvar_q("hud_panel_bg_color");
  18                 HUD_Write_Cvar_q("hud_panel_bg_color_team");
  19                 HUD_Write_Cvar_q("hud_panel_bg_alpha");
  20                 HUD_Write_Cvar_q("hud_panel_bg_border");
  21                 HUD_Write_Cvar_q("hud_panel_bg_padding");
  22                 HUD_Write_Cvar_q("hud_panel_fg_alpha");
  23                 HUD_Write("\n");
  24
  25                 HUD_Write_Cvar_q("hud_dock");
  26                 HUD_Write_Cvar_q("hud_dock_color");
  27                 HUD_Write_Cvar_q("hud_dock_color_team");
  28                 HUD_Write_Cvar_q("hud_dock_alpha");
  29                 HUD_Write("\n");
  30
  31                 HUD_Write_Cvar_q("hud_progressbar_alpha");
  32                 HUD_Write_Cvar_q("hud_progressbar_strength_color");
  33                 HUD_Write_Cvar_q("hud_progressbar_shield_color");
  34                 HUD_Write_Cvar_q("hud_progressbar_health_color");
  35                 HUD_Write_Cvar_q("hud_progressbar_armor_color");
  36                 HUD_Write_Cvar_q("hud_progressbar_fuel_color");
  37                 HUD_Write_Cvar_q("hud_progressbar_nexball_color");
  38                 HUD_Write_Cvar_q("hud_progressbar_speed_color");
  39                 HUD_Write_Cvar_q("hud_progressbar_acceleration_color");
  40                 HUD_Write_Cvar_q("hud_progressbar_acceleration_neg_color");
  41                 HUD_Write("\n");
  42
  43                 HUD_Write_Cvar_q("_hud_panelorder");
  44                 HUD_Write("\n");
  45
  46                 HUD_Write_Cvar_q("hud_configure_grid");
  47                 HUD_Write_Cvar_q("hud_configure_grid_xsize");
  48                 HUD_Write_Cvar_q("hud_configure_grid_ysize");
  49                 HUD_Write("\n");
  50
  51                 // common cvars for all panels
  52                 float i;
  53                 for (i = 0; i < HUD_PANEL_NUM; ++i)
  54                 {
  55                         HUD_Panel_GetName(i);
  56
  57                         HUD_Write_PanelCvar_n("");
  58                         HUD_Write_PanelCvar_q("_pos");
  59                         HUD_Write_PanelCvar_q("_size");
  60                         HUD_Write_PanelCvar_q("_bg");
  61                         HUD_Write_PanelCvar_q("_bg_color");
  62                         HUD_Write_PanelCvar_q("_bg_color_team");
  63                         HUD_Write_PanelCvar_q("_bg_alpha");
  64                         HUD_Write_PanelCvar_q("_bg_border");
  65                         HUD_Write_PanelCvar_q("_bg_padding");
  66                         switch(i) {
  67                                 case HUD_PANEL_WEAPONS:
  68                                         HUD_Write_PanelCvar_q("_accuracy");
  69                                         HUD_Write_PanelCvar_q("_label");
  70                                         HUD_Write_PanelCvar_q("_complainbubble");
  71                                         HUD_Write_PanelCvar_q("_complainbubble_padding");
  72                                         HUD_Write_PanelCvar_q("_complainbubble_time");
  73                                         HUD_Write_PanelCvar_q("_complainbubble_fadetime");
  74                                         HUD_Write_PanelCvar_q("_complainbubble_color_outofammo");
  75                                         HUD_Write_PanelCvar_q("_complainbubble_color_donthave");
  76                                         HUD_Write_PanelCvar_q("_complainbubble_color_unavailable");
  77                                         HUD_Write_PanelCvar_q("_ammo");
  78                                         HUD_Write_PanelCvar_q("_ammo_color");
  79                                         HUD_Write_PanelCvar_q("_ammo_alpha");
  80                                         HUD_Write_PanelCvar_q("_aspect");
  81                                         HUD_Write_PanelCvar_q("_timeout");
  82                                         HUD_Write_PanelCvar_q("_timeout_effect");
  83                                         HUD_Write_PanelCvar_q("_onlyowned");
  84                                         break;
  85                                 case HUD_PANEL_AMMO:
  86                                         HUD_Write_PanelCvar_q("_onlycurrent");
  87                                         HUD_Write_PanelCvar_q("_iconalign");
  88                                         HUD_Write_PanelCvar_q("_progressbar");
  89                                         HUD_Write_PanelCvar_q("_progressbar_name");
  90                                         HUD_Write_PanelCvar_q("_progressbar_xoffset");
  91                                         HUD_Write_PanelCvar_q("_text");
  92                                         break;
  93                                 case HUD_PANEL_POWERUPS:
  94                                         HUD_Write_PanelCvar_q("_flip");
  95                                         HUD_Write_PanelCvar_q("_iconalign");
  96                                         HUD_Write_PanelCvar_q("_baralign");
  97                                         HUD_Write_PanelCvar_q("_progressbar");
  98                                         HUD_Write_PanelCvar_q("_progressbar_strength");
  99                                         HUD_Write_PanelCvar_q("_progressbar_shield");
 100                                         HUD_Write_PanelCvar_q("_text");
 101                                         break;
 102                                 case HUD_PANEL_HEALTHARMOR:
 103                                         HUD_Write_PanelCvar_q("_flip");
 104                                         HUD_Write_PanelCvar_q("_iconalign");
 105                                         HUD_Write_PanelCvar_q("_baralign");
 106                                         HUD_Write_PanelCvar_q("_progressbar");
 107                                         HUD_Write_PanelCvar_q("_progressbar_health");
 108                                         HUD_Write_PanelCvar_q("_progressbar_armor");
 109                                         HUD_Write_PanelCvar_q("_progressbar_gfx");
 110                                         HUD_Write_PanelCvar_q("_progressbar_gfx_smooth");
 111                                         HUD_Write_PanelCvar_q("_text");
 112                                         break;
 113                                 case HUD_PANEL_NOTIFY:
 114                                         HUD_Write_PanelCvar_q("_flip");
 115                                         HUD_Write_PanelCvar_q("_fontsize");
 116                                         HUD_Write_PanelCvar_q("_print");
 117                                         HUD_Write_PanelCvar_q("_time");
 118                                         HUD_Write_PanelCvar_q("_fadetime");
 119                                         break;
 120                                 case HUD_PANEL_TIMER:
 121                                         HUD_Write_PanelCvar_q("_increment");
 122                                         break;
 123                                 case HUD_PANEL_RADAR:
 124                                         HUD_Write_PanelCvar_q("_foreground_alpha");
 125                                         HUD_Write_PanelCvar_q("_rotation");
 126                                         HUD_Write_PanelCvar_q("_zoommode");
 127                                         HUD_Write_PanelCvar_q("_scale");
 128                                         HUD_Write_PanelCvar_q("_maximized_scale");
 129                                         HUD_Write_PanelCvar_q("_maximized_size");
 130                                         break;
 131                                 case HUD_PANEL_SCORE:
 132                                         HUD_Write_PanelCvar_q("_rankings");
 133                                         break;
 134                                 case HUD_PANEL_VOTE:
 135                                         HUD_Write_PanelCvar_q("_alreadyvoted_alpha");
 136                                         break;
 137                                 case HUD_PANEL_MODICONS:
 138                                         HUD_Write_PanelCvar_q("_dom_layout");
 139                                         break;
 140                                 case HUD_PANEL_PRESSEDKEYS:
 141                                         HUD_Write_PanelCvar_q("_aspect");
 142                                         break;
 143                                 case HUD_PANEL_ENGINEINFO:
 144                                         HUD_Write_PanelCvar_q("_framecounter_time");
 145                                         HUD_Write_PanelCvar_q("_framecounter_decimals");
 146                                         break;
 147                                 case HUD_PANEL_INFOMESSAGES:
 148                                         HUD_Write_PanelCvar_q("_flip");
 149                                         break;
 150                                 case HUD_PANEL_PHYSICS:
 151                                         HUD_Write_PanelCvar_q("_speed_unit");
 152                                         HUD_Write_PanelCvar_q("_speed_unit_show");
 153                                         HUD_Write_PanelCvar_q("_speed_max");
 154                                         HUD_Write_PanelCvar_q("_speed_vertical");
 155                                         HUD_Write_PanelCvar_q("_topspeed");
 156                                         HUD_Write_PanelCvar_q("_topspeed_time");
 157                                         HUD_Write_PanelCvar_q("_acceleration_max");
 158                                         HUD_Write_PanelCvar_q("_acceleration_vertical");
 159                                         HUD_Write_PanelCvar_q("_flip");
 160                                         HUD_Write_PanelCvar_q("_baralign");
 161                                         HUD_Write_PanelCvar_q("_progressbar");
 162                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_mode");
 163                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_scale");
 164                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_nonlinear");
 165                                         HUD_Write_PanelCvar_q("_text");
 166                                         HUD_Write_PanelCvar_q("_text_scale");
 167                                         break;
 168                                 case HUD_PANEL_CENTERPRINT:
 169                                         HUD_Write_PanelCvar_q("_align");
 170                                         HUD_Write_PanelCvar_q("_flip");
 171                                         HUD_Write_PanelCvar_q("_fontscale");
 172                                         HUD_Write_PanelCvar_q("_time");
 173                                         HUD_Write_PanelCvar_q("_fade_in");
 174                                         HUD_Write_PanelCvar_q("_fade_out");
 175                                         HUD_Write_PanelCvar_q("_fade_subsequent");
 176                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone");
 177                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone_minalpha");
 178                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo");
 179                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo_minalpha");
 180                                         HUD_Write_PanelCvar_q("_fade_subsequent_minfontsize");
 181                                         HUD_Write_PanelCvar_q("_fade_minfontsize");
 182                                         break;
 183                         }
 184                         HUD_Write("\n");
 185                 }
 186                 HUD_Write("menu_sync\n"); // force the menu to reread the cvars, so that the dialogs are updated
 187
 188                 print(sprintf(_("^2Successfully exported to %s! (Note: It's saved in data/data/)\n"), filename));
 189                 fclose(fh);
 190         }
 191         else
 192                 print(sprintf(_("^1Couldn't write to %s\n"), filename));
 193 }
 194
 195 void HUD_Configure_Exit_Force()
 196 {
 197         if (menu_enabled)
 198         {
 199                 menu_enabled = 0;
 200                 localcmd("togglemenu\n");
 201         }
 202         cvar_set("_hud_configure", "0");
 203 }
 204
 205 // check if move will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 206 vector HUD_Panel_CheckMove(vector myPos, vector mySize)
 207 {
 208         float i;
 209         float myCenter_x, myCenter_y, targCenter_x, targCenter_y;
 210         vector myTarget;
 211         myTarget = myPos;
 212
 213         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 214                 if(i == highlightedPanel || !panel_enabled)
 215                         continue;
 216
 217                 HUD_Panel_UpdatePosSizeForId(i);
 218
 219                 panel_pos -= '1 1 0' * panel_bg_border;
 220                 panel_size += '2 2 0' * panel_bg_border;
 221
 222                 if(myPos_y + mySize_y < panel_pos_y)
 223                         continue;
 224                 if(myPos_y > panel_pos_y + panel_size_y)
 225                         continue;
 226
 227                 if(myPos_x + mySize_x < panel_pos_x)
 228                         continue;
 229                 if(myPos_x > panel_pos_x + panel_size_x)
 230                         continue;
 231
 232                 // OK, there IS a collision.
 233
 234                 myCenter_x = myPos_x + 0.5 * mySize_x;
 235                 myCenter_y = myPos_y + 0.5 * mySize_y;
 236
 237                 targCenter_x = panel_pos_x + 0.5 * panel_size_x;
 238                 targCenter_y = panel_pos_y + 0.5 * panel_size_y;
 239
 240                 if(myCenter_x < targCenter_x && myCenter_y < targCenter_y) // top left (of the target panel)
 241                 {
 242                         if(myPos_x + mySize_x - panel_pos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 243                                 myTarget_x = panel_pos_x - mySize_x;
 244                         else // push it upwards
 245                                 myTarget_y = panel_pos_y - mySize_y;
 246                 }
 247                 else if(myCenter_x > targCenter_x && myCenter_y < targCenter_y) // top right
 248                 {
 249                         if(panel_pos_x + panel_size_x - myPos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 250                                 myTarget_x = panel_pos_x + panel_size_x;
 251                         else // push it upwards
 252                                 myTarget_y = panel_pos_y - mySize_y;
 253                 }
 254                 else if(myCenter_x < targCenter_x && myCenter_y > targCenter_y) // bottom left
 255                 {
 256                         if(myPos_x + mySize_x - panel_pos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 257                                 myTarget_x = panel_pos_x - mySize_x;
 258                         else // push it downwards
 259                                 myTarget_y = panel_pos_y + panel_size_y;
 260                 }
 261                 else if(myCenter_x > targCenter_x && myCenter_y > targCenter_y) // bottom right
 262                 {
 263                         if(panel_pos_x + panel_size_x - myPos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 264                                 myTarget_x = panel_pos_x + panel_size_x;
 265                         else // push it downwards
 266                                 myTarget_y = panel_pos_y + panel_size_y;
 267                 }
 268                 //if(cvar("hud_configure_checkcollisions_debug"))
 269                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 270         }
 271
 272         return myTarget;
 273 }
 274
 275 void HUD_Panel_SetPos(vector pos)
 276 {
 277         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 278         vector mySize;
 279         mySize = panel_size;
 280
 281         //if(cvar("hud_configure_checkcollisions_debug"))
 282                 //drawfill(pos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 283
 284         if(autocvar_hud_configure_grid)
 285         {
 286                 pos_x = floor((pos_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 287                 pos_y = floor((pos_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 288         }
 289
 290         if(hud_configure_checkcollisions)
 291                 pos = HUD_Panel_CheckMove(pos, mySize);
 292
 293         pos_x = bound(0, pos_x, vid_conwidth - mySize_x);
 294         pos_y = bound(0, pos_y, vid_conheight - mySize_y);
 295
 296         string s;
 297         s = strcat(ftos(pos_x/vid_conwidth), " ", ftos(pos_y/vid_conheight));
 298
 299         HUD_Panel_GetName(highlightedPanel);
 300         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 301 }
 302
 303 // check if resize will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 304 vector HUD_Panel_CheckResize(vector mySize, vector resizeorigin) {
 305         float i;
 306
 307         vector targEndPos;
 308
 309         float dist_x, dist_y;
 310         float ratio;
 311         ratio = mySize_x/mySize_y;
 312
 313         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 314                 if(i == highlightedPanel || !panel_enabled)
 315                         continue;
 316
 317                 HUD_Panel_UpdatePosSizeForId(i);
 318
 319                 panel_pos -= '1 1 0' * panel_bg_border;
 320                 panel_size += '2 2 0' * panel_bg_border;
 321
 322                 targEndPos = panel_pos + panel_size;
 323
 324                 // resizeorigin is WITHIN target panel, just abort any collision testing against that particular panel to produce expected behaviour!
 325                 if(resizeorigin_x > panel_pos_x && resizeorigin_x < targEndPos_x && resizeorigin_y > panel_pos_y && resizeorigin_y < targEndPos_y)
 326                         continue;
 327
 328                 if (resizeCorner == 1)
 329                 {
 330                         // check if this panel is on our way
 331                         if (resizeorigin_x <= panel_pos_x)
 332                                 continue;
 333                         if (resizeorigin_y <= panel_pos_y)
 334                                 continue;
 335                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 336                                 continue;
 337                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 338                                 continue;
 339
 340                         // there is a collision:
 341                         // detect which side of the panel we are facing is actually limiting the resizing
 342                         // (which side the resize direction finds for first) and reduce the size up to there
 343                         //
 344                         // dist is the distance between resizeorigin and the "analogous" point of the panel
 345                         // in this case between resizeorigin (bottom-right point) and the bottom-right point of the panel
 346                         dist_x = resizeorigin_x - targEndPos_x;
 347                         dist_y = resizeorigin_y - targEndPos_y;
 348                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 349                                 mySize_x = min(mySize_x, dist_x);
 350                         else
 351                                 mySize_y = min(mySize_y, dist_y);
 352                 }
 353                 else if (resizeCorner == 2)
 354                 {
 355                         if (resizeorigin_x >= targEndPos_x)
 356                                 continue;
 357                         if (resizeorigin_y <= panel_pos_y)
 358                                 continue;
 359                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 360                                 continue;
 361                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 362                                 continue;
 363
 364                         dist_x = panel_pos_x - resizeorigin_x;
 365                         dist_y = resizeorigin_y - targEndPos_y;
 366                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 367                                 mySize_x = min(mySize_x, dist_x);
 368                         else
 369                                 mySize_y = min(mySize_y, dist_y);
 370                 }
 371                 else if (resizeCorner == 3)
 372                 {
 373                         if (resizeorigin_x <= panel_pos_x)
 374                                 continue;
 375                         if (resizeorigin_y >= targEndPos_y)
 376                                 continue;
 377                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 378                                 continue;
 379                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 380                                 continue;
 381
 382                         dist_x = resizeorigin_x - targEndPos_x;
 383                         dist_y = panel_pos_y - resizeorigin_y;
 384                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 385                                 mySize_x = min(mySize_x, dist_x);
 386                         else
 387                                 mySize_y = min(mySize_y, dist_y);
 388                 }
 389                 else if (resizeCorner == 4)
 390                 {
 391                         if (resizeorigin_x >= targEndPos_x)
 392                                 continue;
 393                         if (resizeorigin_y >= targEndPos_y)
 394                                 continue;
 395                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 396                                 continue;
 397                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 398                                 continue;
 399
 400                         dist_x = panel_pos_x - resizeorigin_x;
 401                         dist_y = panel_pos_y - resizeorigin_y;
 402                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 403                                 mySize_x = min(mySize_x, dist_x);
 404                         else
 405                                 mySize_y = min(mySize_y, dist_y);
 406                 }
 407                 //if(cvar("hud_configure_checkcollisions_debug"))
 408                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 409         }
 410
 411         return mySize;
 412 }
 413
 414 void HUD_Panel_SetPosSize(vector mySize)
 415 {
 416         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 417         vector resizeorigin;
 418         resizeorigin = panel_click_resizeorigin;
 419         local noref vector myPos; // fteqcc sucks
 420
 421         // minimum panel size cap
 422         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 423         mySize_y = max(0.025 * vid_conheight, mySize_y);
 424
 425         if(highlightedPanel == HUD_PANEL_CHAT) // some panels have their own restrictions, like the chat panel (which actually only moves the engine chat print around). Looks bad if it's too small.
 426         {
 427                 mySize_x = max(17 * autocvar_con_chatsize, mySize_x);
 428                 mySize_y = max(2 * autocvar_con_chatsize + 2 * panel_bg_padding, mySize_y);
 429         }
 430
 431         // collision testing|
 432         // -----------------+
 433
 434         // we need to know pos at this stage, but it might still change later if we hit a screen edge/other panel (?)
 435         if(resizeCorner == 1) {
 436                 myPos_x = resizeorigin_x - mySize_x;
 437                 myPos_y = resizeorigin_y - mySize_y;
 438         } else if(resizeCorner == 2) {
 439                 myPos_x = resizeorigin_x;
 440                 myPos_y = resizeorigin_y - mySize_y;
 441         } else if(resizeCorner == 3) {
 442                 myPos_x = resizeorigin_x - mySize_x;
 443                 myPos_y = resizeorigin_y;
 444         } else { // resizeCorner == 4
 445                 myPos_x = resizeorigin_x;
 446                 myPos_y = resizeorigin_y;
 447         }
 448
 449         // left/top screen edges
 450         if(myPos_x < 0)
 451                 mySize_x = mySize_x + myPos_x;
 452         if(myPos_y < 0)
 453                 mySize_y = mySize_y + myPos_y;
 454
 455         // bottom/right screen edges
 456         if(myPos_x + mySize_x > vid_conwidth)
 457                 mySize_x = vid_conwidth - myPos_x;
 458         if(myPos_y + mySize_y > vid_conheight)
 459                 mySize_y = vid_conheight - myPos_y;
 460
 461         //if(cvar("hud_configure_checkcollisions_debug"))
 462                 //drawfill(myPos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 463
 464         // before checkresize, otherwise panel can be snapped partially inside another panel or panel aspect ratio can be broken
 465         if(autocvar_hud_configure_grid)
 466         {
 467                 mySize_x = floor((mySize_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 468                 mySize_y = floor((mySize_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 469         }
 470
 471         if(hud_configure_checkcollisions)
 472                 mySize = HUD_Panel_CheckResize(mySize, resizeorigin);
 473
 474         // minimum panel size cap, do this once more so we NEVER EVER EVER have a panel smaller than this, JUST IN CASE above code still makes the panel eg negative (impossible to resize back without changing cvars manually then)
 475         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 476         mySize_y = max(0.025 * vid_conheight, mySize_y);
 477
 478         // do another pos check, as size might have changed by now
 479         if(resizeCorner == 1) {
 480                 myPos_x = resizeorigin_x - mySize_x;
 481                 myPos_y = resizeorigin_y - mySize_y;
 482         } else if(resizeCorner == 2) {
 483                 myPos_x = resizeorigin_x;
 484                 myPos_y = resizeorigin_y - mySize_y;
 485         } else if(resizeCorner == 3) {
 486                 myPos_x = resizeorigin_x - mySize_x;
 487                 myPos_y = resizeorigin_y;
 488         } else { // resizeCorner == 4
 489                 myPos_x = resizeorigin_x;
 490                 myPos_y = resizeorigin_y;
 491         }
 492
 493         //if(cvar("hud_configure_checkcollisions_debug"))
 494                 //drawfill(myPos, mySize, '0 1 0', .3, DRAWFLAG_NORMAL);
 495
 496         HUD_Panel_GetName(highlightedPanel);
 497         string s;
 498         s = strcat(ftos(mySize_x/vid_conwidth), " ", ftos(mySize_y/vid_conheight));
 499         cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 500
 501         s = strcat(ftos(myPos_x/vid_conwidth), " ", ftos(myPos_y/vid_conheight));
 502         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 503 }
 504
 505 float pressed_key_time;
 506 vector highlightedPanel_initial_pos, highlightedPanel_initial_size;
 507 void HUD_Panel_Arrow_Action(float nPrimary)
 508 {
 509         if (highlightedPanel == -1)
 510                 return;
 511
 512         hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
 513
 514         float step;
 515         if(autocvar_hud_configure_grid)
 516         {
 517                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 518                 {
 519                         if (hudShiftState & S_SHIFT)
 520                                 step = hud_configure_realGridSize_y;
 521                         else
 522                                 step = 2 * hud_configure_realGridSize_y;
 523                 }
 524                 else
 525                 {
 526                         if (hudShiftState & S_SHIFT)
 527                                 step = hud_configure_realGridSize_x;
 528                         else
 529                                 step = 2 * hud_configure_realGridSize_x;
 530                 }
 531         }
 532         else
 533         {
 534                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 535                         step = vid_conheight;
 536                 else
 537                         step = vid_conwidth;
 538                 if (hudShiftState & S_SHIFT)
 539                         step = (step / 256); // more precision
 540                 else
 541                         step = (step / 64) * (1 + 2 * (time - pressed_key_time));
 542         }
 543
 544         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 545
 546         highlightedPanel_initial_pos = panel_pos;
 547         highlightedPanel_initial_size = panel_size;
 548
 549         if (hudShiftState & S_ALT) // resize
 550         {
 551                 highlightedAction = 1;
 552                 if(nPrimary == K_UPARROW)
 553                         resizeCorner = 1;
 554                 else if(nPrimary == K_RIGHTARROW)
 555                         resizeCorner = 2;
 556                 else if(nPrimary == K_LEFTARROW)
 557                         resizeCorner = 3;
 558                 else // if(nPrimary == K_DOWNARROW)
 559                         resizeCorner = 4;
 560
 561                 // ctrl+arrow reduces the size, instead of increasing it
 562                 // Note that ctrl disables collisions check too, but it's fine
 563                 // since we don't collide with anything reducing the size
 564                 if (hudShiftState & S_CTRL) {
 565                         step = -step;
 566                         resizeCorner = 5 - resizeCorner;
 567                 }
 568
 569                 vector mySize;
 570                 mySize = panel_size;
 571                 panel_click_resizeorigin = panel_pos;
 572                 if(resizeCorner == 1) {
 573                         panel_click_resizeorigin += mySize;
 574                         mySize_y += step;
 575                 } else if(resizeCorner == 2) {
 576                         panel_click_resizeorigin_y += mySize_y;
 577                         mySize_x += step;
 578                 } else if(resizeCorner == 3) {
 579                         panel_click_resizeorigin_x += mySize_x;
 580                         mySize_x += step;
 581                 } else { // resizeCorner == 4
 582                         mySize_y += step;
 583                 }
 584                 HUD_Panel_SetPosSize(mySize);
 585         }
 586         else // move
 587         {
 588                 highlightedAction = 2;
 589                 vector pos;
 590                 pos = panel_pos;
 591                 if(nPrimary == K_UPARROW)
 592                         pos_y -= step;
 593                 else if(nPrimary == K_DOWNARROW)
 594                         pos_y += step;
 595                 else if(nPrimary == K_LEFTARROW)
 596                         pos_x -= step;
 597                 else // if(nPrimary == K_RIGHTARROW)
 598                         pos_x += step;
 599
 600                 HUD_Panel_SetPos(pos);
 601         }
 602
 603         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 604
 605         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
 606         {
 607                 // backup!
 608                 panel_pos_backup = highlightedPanel_initial_pos;
 609                 panel_size_backup = highlightedPanel_initial_size;
 610                 highlightedPanel_backup = highlightedPanel;
 611         }
 612 }
 613
 614 const float S_MOUSE1 = 1;
 615 const float S_MOUSE2 = 2;
 616 const float S_MOUSE3 = 4;
 617 float mouseClicked;
 618 float prevMouseClicked; // previous state
 619 float prevMouseClickedTime; // time during previous left mouse click, to check for doubleclicks
 620 vector prevMouseClickedPos; // pos during previous left mouse click, to check for doubleclicks
 621
 622 void HUD_Panel_EnableMenu();
 623 float tab_panels[HUD_PANEL_NUM];
 624 float tab_panel, tab_backward;
 625 vector tab_panel_pos;
 626 void HUD_Panel_FirstInDrawQ(float id);
 627 void reset_tab_panels()
 628 {
 629         int i;
 630         for(i = 0; i < HUD_PANEL_NUM; ++i)
 631                 tab_panels[i] = -1;
 632 }
 633 float HUD_Panel_InputEvent(float bInputType, float nPrimary, float nSecondary)
 634 {
 635         string s;
 636
 637         if(bInputType == 2)
 638                 return false;
 639
 640         if(!autocvar__hud_configure)
 641                 return false;
 642
 643         // block any input while a menu dialog is fading
 644         if(autocvar__menu_alpha)
 645                 return true;
 646
 647         if(bInputType == 3)
 648         {
 649                 mousepos_x = nPrimary;
 650                 mousepos_y = nSecondary;
 651                 return true;
 652         }
 653
 654         // allow console bind to work
 655         string con_keys;
 656         float keys;
 657         con_keys = findkeysforcommand("toggleconsole", 0);
 658         keys = tokenize(con_keys); // findkeysforcommand returns data for this
 659
 660         float hit_con_bind, i;
 661         for (i = 0; i < keys; ++i)
 662         {
 663                 if(nPrimary == stof(argv(i)))
 664                         hit_con_bind = 1;
 665         }
 666
 667         if(bInputType == 0) {
 668                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 669                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 670                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 671         }
 672         else if(bInputType == 1) {
 673                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 674                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 675                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 676         }
 677
 678         if(nPrimary == K_CTRL)
 679         {
 680                 if (bInputType == 1) //ctrl has been released
 681                 {
 682                         if (tab_panel != -1)
 683                         {
 684                                 //switch to selected panel
 685                                 highlightedPanel = tab_panel;
 686                                 highlightedAction = 0;
 687                                 HUD_Panel_FirstInDrawQ(highlightedPanel);
 688                         }
 689                         tab_panel = -1;
 690                         reset_tab_panels();
 691                 }
 692         }
 693
 694         if(nPrimary == K_MOUSE1)
 695         {
 696                 if(bInputType == 0) // key pressed
 697                         mouseClicked |= S_MOUSE1;
 698                 else if(bInputType == 1) // key released
 699                         mouseClicked -= (mouseClicked & S_MOUSE1);
 700         }
 701         else if(nPrimary == K_MOUSE2)
 702         {
 703                 if(bInputType == 0) // key pressed
 704                         mouseClicked |= S_MOUSE2;
 705                 else if(bInputType == 1) // key released
 706                         mouseClicked -= (mouseClicked & S_MOUSE2);
 707         }
 708         else if(nPrimary == K_ESCAPE)
 709         {
 710                 if (bInputType == 1)
 711                         return true;
 712                 menu_enabled = 1;
 713                 menu_enabled_time = time;
 714                 localcmd("menu_showhudexit\n");
 715         }
 716         else if(nPrimary == K_BACKSPACE && hudShiftState & S_CTRL)
 717         {
 718                 if (bInputType == 1)
 719                         return true;
 720                 if (!menu_enabled)
 721                         cvar_set("_hud_configure", "0");
 722         }
 723         else if(nPrimary == K_TAB && hudShiftState & S_CTRL) // select and highlight another panel
 724         {
 725                 if (bInputType == 1 || mouseClicked)
 726                         return true;
 727
 728                 //FIXME: if a panel is highlighted, has the same pos_x and lays in the same level
 729                 //of other panels then next consecutive ctrl-tab will select the highlighted panel too
 730                 //(it should only after every other panel of the hud)
 731                 //It's a minor bug anyway, we can live with it
 732
 733                 float starting_panel;
 734                 float old_tab_panel = tab_panel;
 735                 if (tab_panel == -1) //first press of TAB
 736                 {
 737                         if (highlightedPanel != -1)
 738                                 HUD_Panel_UpdatePosSizeForId(highlightedPanel)
 739                         else
 740                                 panel_pos = '0 0 0';
 741                         starting_panel = highlightedPanel; //can be -1, it means no starting panel
 742                         tab_panel_pos = panel_pos; //to compute level
 743                 }
 744                 else
 745                 {
 746                         if ( ((!tab_backward) && (hudShiftState & S_SHIFT)) || (tab_backward && !(hudShiftState & S_SHIFT)) ) //tab direction changed?
 747                                 reset_tab_panels();
 748                         starting_panel = tab_panel;
 749                 }
 750                 tab_backward = (hudShiftState & S_SHIFT);
 751
 752                 float k, level, start_pos_x;
 753                 vector candidate_pos;
 754                 const float LEVELS_NUM = 4;
 755                 float level_height = vid_conheight / LEVELS_NUM;
 756 :find_tab_panel
 757                 level = floor(tab_panel_pos_y / level_height) * level_height; //starting level
 758                 candidate_pos_x = (!tab_backward) ? vid_conwidth : 0;
 759                 start_pos_x = tab_panel_pos_x;
 760                 tab_panel = -1;
 761                 k=0;
 762                 while(++k)
 763                 {
 764                         for(i = 0; i < HUD_PANEL_NUM; ++i)
 765                         {
 766                                 if (i == tab_panels[i] || i == starting_panel)
 767                                         continue;
 768                                 HUD_Panel_UpdatePosSizeForId(i)
 769                                 if (panel_pos_y >= level && (panel_pos_y - level) < level_height)
 770                                 if (  ( !tab_backward && panel_pos_x >= start_pos_x && (panel_pos_x < candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y <= candidate_pos_y)) )
 771                                         || ( tab_backward && panel_pos_x <= start_pos_x && (panel_pos_x > candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y >= candidate_pos_y)) )  )
 772                                 {
 773                                         tab_panel = i;
 774                                         tab_panel_pos = candidate_pos = panel_pos;
 775                                 }
 776                         }
 777                         if (tab_panel != -1)
 778                                 break;
 779                         if (k == LEVELS_NUM) //tab_panel not found
 780                         {
 781                                 reset_tab_panels();
 782                                 if (old_tab_panel == -2) //this prevents an infinite loop (should not happen normally)
 783                                 {
 784                                         tab_panel = -1;
 785                                         return true;
 786                                 }
 787                                 starting_panel = old_tab_panel;
 788                                 old_tab_panel = -2;
 789                                 goto find_tab_panel; //u must find tab_panel!
 790                         }
 791                         if (!tab_backward)
 792                         {
 793                                 level = mod(level + level_height, vid_conheight);
 794                                 start_pos_x = 0;
 795                                 candidate_pos_x = vid_conwidth;
 796                         }
 797                         else
 798                         {
 799                                 level = mod(level - level_height, vid_conheight);
 800                                 start_pos_x = vid_conwidth;
 801                                 candidate_pos_x = 0;
 802                         }
 803                 }
 804
 805                 tab_panels[tab_panel] = tab_panel;
 806         }
 807         else if(nPrimary == K_SPACE && hudShiftState & S_CTRL) // enable/disable highlighted panel or dock
 808         {
 809                 if (bInputType == 1 || mouseClicked)
 810                         return true;
 811
 812                 if (highlightedPanel != -1)
 813                 {
 814                         HUD_Panel_GetName(highlightedPanel);
 815                         cvar_set(strcat("hud_panel_", panel_name), ftos(!(panel_enabled)));
 816                 }
 817                 else
 818                         cvar_set(strcat("hud_dock"), (autocvar_hud_dock == "") ? "dock" : "");
 819         }
 820         else if(nPrimary == 'c' && hudShiftState & S_CTRL) // copy highlighted panel size
 821         {
 822                 if (bInputType == 1 || mouseClicked)
 823                         return true;
 824
 825                 if (highlightedPanel != -1)
 826                 {
 827                         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 828                         panel_size_copied = panel_size;
 829                         highlightedPanel_copied = highlightedPanel;
 830                 }
 831         }
 832         else if(nPrimary == 'v' && hudShiftState & S_CTRL) // past copied size on the highlighted panel
 833         {
 834                 if (bInputType == 1 || mouseClicked)
 835                         return true;
 836
 837                 if (highlightedPanel_copied == -1 || highlightedPanel == -1)
 838                         return true;
 839
 840                 HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 841
 842                 // reduce size if it'd go beyond screen boundaries
 843                 vector tmp_size = panel_size_copied;
 844                 if (panel_pos_x + panel_size_copied_x > vid_conwidth)
 845                         tmp_size_x = vid_conwidth - panel_pos_x;
 846                 if (panel_pos_y + panel_size_copied_y > vid_conheight)
 847                         tmp_size_y = vid_conheight - panel_pos_y;
 848
 849                 if (panel_size == tmp_size)
 850                         return true;
 851
 852                 // backup first!
 853                 panel_pos_backup = panel_pos;
 854                 panel_size_backup = panel_size;
 855                 highlightedPanel_backup = highlightedPanel;
 856
 857                 s = strcat(ftos(tmp_size_x/vid_conwidth), " ", ftos(tmp_size_y/vid_conheight));
 858                 HUD_Panel_GetName(highlightedPanel);
 859                 cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 860         }
 861         else if(nPrimary == 'z' && hudShiftState & S_CTRL) // undo last action
 862         {
 863                 if (bInputType == 1 || mouseClicked)
 864                         return true;
 865                 //restore previous values
 866                 if (highlightedPanel_backup != -1)
 867                 {
 868                         HUD_Panel_GetName(highlightedPanel_backup);
 869                         s = strcat(ftos(panel_pos_backup_x/vid_conwidth), " ", ftos(panel_pos_backup_y/vid_conheight));
 870                         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 871                         s = strcat(ftos(panel_size_backup_x/vid_conwidth), " ", ftos(panel_size_backup_y/vid_conheight));
 872                         cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 873                         highlightedPanel_backup = -1;
 874                 }
 875         }
 876         else if(nPrimary == K_UPARROW || nPrimary == K_DOWNARROW || nPrimary == K_LEFTARROW || nPrimary == K_RIGHTARROW)
 877         {
 878                 if (bInputType == 1)
 879                 {
 880                         pressed_key_time = 0;
 881                         return true;
 882                 }
 883                 else if (pressed_key_time == 0)
 884                         pressed_key_time = time;
 885
 886                 if (!mouseClicked)
 887                         HUD_Panel_Arrow_Action(nPrimary); //move or resize panel
 888         }
 889         else if(nPrimary == K_ENTER || nPrimary == K_SPACE || nPrimary == K_KP_ENTER)
 890         {
 891                 if (bInputType == 1)
 892                         return true;
 893                 if (highlightedPanel != -1)
 894                         HUD_Panel_EnableMenu();
 895         }
 896         else if(hit_con_bind)
 897                 return false;
 898
 899         return true;
 900 }
 901
 902 float HUD_Panel_Check_Mouse_Pos(float allow_move)
 903 {
 904         float i, j, border;
 905
 906         while(j < HUD_PANEL_NUM)
 907         {
 908                 i = panel_order[j];
 909                 j += 1;
 910
 911                 HUD_Panel_UpdatePosSizeForId(i);
 912
 913                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 914
 915                 // move
 916                 if(allow_move && mousepos_x >= panel_pos_x && mousepos_y >= panel_pos_y && mousepos_x <= panel_pos_x + panel_size_x && mousepos_y <= panel_pos_y + panel_size_y)
 917                 {
 918                         return 1;
 919                 }
 920                 // resize from topleft border
 921                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 922                 {
 923                         return 2;
 924                 }
 925                 // resize from topright border
 926                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 927                 {
 928                         return 3;
 929                 }
 930                 // resize from bottomleft border
 931                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
 932                 {
 933                         return 3;
 934                 }
 935                 // resize from bottomright border
 936                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
 937                 {
 938                         return 2;
 939                 }
 940         }
 941         return 0;
 942 }
 943
 944 // move a panel to the beginning of the panel order array (which means it gets drawn last, on top of everything else)
 945 void HUD_Panel_FirstInDrawQ(float id)
 946 {
 947         float i;
 948         var float place = -1;
 949         // find out where in the array our current id is, save into place
 950         for(i = 0; i < HUD_PANEL_NUM; ++i)
 951         {
 952                 if(panel_order[i] == id)
 953                 {
 954                         place = i;
 955                         break;
 956                 }
 957         }
 958         // place last if we didn't find a place for it yet (probably new panel, or screwed up cvar)
 959         if(place == -1)
 960                 place = HUD_PANEL_NUM - 1;
 961
 962         // move all ids up by one step in the array until "place"
 963         for(i = place; i > 0; --i)
 964         {
 965                 panel_order[i] = panel_order[i-1];
 966         }
 967         // now save the new top id
 968         panel_order[0] = id;
 969
 970         // let's save them into the cvar by some strcat trickery
 971         string s;
 972         for(i = 0; i < HUD_PANEL_NUM; ++i)
 973         {
 974                 s = strcat(s, ftos(panel_order[i]), " ");
 975         }
 976         cvar_set("_hud_panelorder", s);
 977         if(hud_panelorder_prev)
 978                 strunzone(hud_panelorder_prev);
 979         hud_panelorder_prev = strzone(autocvar__hud_panelorder); // prevent HUD_Main from doing useless update, we already updated here
 980 }
 981
 982 void HUD_Panel_Highlight(float allow_move)
 983 {
 984         float i, j, border;
 985
 986         while(j < HUD_PANEL_NUM)
 987         {
 988                 i = panel_order[j];
 989                 j += 1;
 990
 991                 HUD_Panel_UpdatePosSizeForId(i);
 992
 993                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 994
 995                 // move
 996                 if(allow_move && mousepos_x >= panel_pos_x && mousepos_y >= panel_pos_y && mousepos_x <= panel_pos_x + panel_size_x && mousepos_y <= panel_pos_y + panel_size_y)
 997                 {
 998                         highlightedPanel = i;
 999                         HUD_Panel_FirstInDrawQ(i);
1000                         highlightedAction = 1;
1001                         panel_click_distance = mousepos - panel_pos;
1002                         return;
1003                 }
1004                 // resize from topleft border
1005                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
1006                 {
1007                         highlightedPanel = i;
1008                         HUD_Panel_FirstInDrawQ(i);
1009                         highlightedAction = 2;
1010                         resizeCorner = 1;
1011                         panel_click_distance = mousepos - panel_pos;
1012                         panel_click_resizeorigin = panel_pos + panel_size;
1013                         return;
1014                 }
1015                 // resize from topright border
1016                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
1017                 {
1018                         highlightedPanel = i;
1019                         HUD_Panel_FirstInDrawQ(i);
1020                         highlightedAction = 2;
1021                         resizeCorner = 2;
1022                         panel_click_distance_x = panel_size_x - mousepos_x + panel_pos_x;
1023                         panel_click_distance_y = mousepos_y - panel_pos_y;
1024                         panel_click_resizeorigin = panel_pos + eY * panel_size_y;
1025                         return;
1026                 }
1027                 // resize from bottomleft border
1028                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
1029                 {
1030                         highlightedPanel = i;
1031                         HUD_Panel_FirstInDrawQ(i);
1032                         highlightedAction = 2;
1033                         resizeCorner = 3;
1034                         panel_click_distance_x = mousepos_x - panel_pos_x;
1035                         panel_click_distance_y = panel_size_y - mousepos_y + panel_pos_y;
1036                         panel_click_resizeorigin = panel_pos + eX * panel_size_x;
1037                         return;
1038                 }
1039                 // resize from bottomright border
1040                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
1041                 {
1042                         highlightedPanel = i;
1043                         HUD_Panel_FirstInDrawQ(i);
1044                         highlightedAction = 2;
1045                         resizeCorner = 4;
1046                         panel_click_distance = panel_size - mousepos + panel_pos;
1047                         panel_click_resizeorigin = panel_pos;
1048                         return;
1049                 }
1050         }
1051         highlightedPanel = -1;
1052         highlightedAction = 0;
1053 }
1054
1055 void HUD_Panel_EnableMenu()
1056 {
1057         menu_enabled = 2;
1058         menu_enabled_time = time;
1059         HUD_Panel_GetName(highlightedPanel);
1060         localcmd("menu_showhudoptions ", panel_name, "\n");
1061 }
1062 float mouse_over_panel;
1063 void HUD_Panel_Mouse()
1064 {
1065         // TODO: needs better check... is there any float that contains the current state of the menu? _menu_alpha isn't apparently updated the frame the menu gets enabled
1066         if (autocvar__menu_alpha == 0 && time - menu_enabled_time > 0.5)
1067                 menu_enabled = 0;
1068
1069         /*
1070         print("menu_enabled: ", ftos(menu_enabled), "\n");
1071         print("Highlighted: ", ftos(highlightedPanel), "\n");
1072         print("Menu theAlpha: ", ftos(autocvar__menu_alpha), "\n");
1073         */
1074
1075         if(autocvar__menu_alpha == 1)
1076                 return;
1077
1078         if(mouseClicked)
1079         {
1080                 if(prevMouseClicked == 0)
1081                 {
1082                         if (tab_panel != -1)
1083                         {
1084                                 //stop ctrl-tab selection
1085                                 tab_panel = -1;
1086                                 reset_tab_panels();
1087                         }
1088                         HUD_Panel_Highlight(mouseClicked & S_MOUSE1); // sets highlightedPanel, highlightedAction, panel_click_distance, panel_click_resizeorigin
1089                                                                         // and calls HUD_Panel_UpdatePosSizeForId() for the highlighted panel
1090                         if (highlightedPanel != -1)
1091                         {
1092                                 highlightedPanel_initial_pos = panel_pos;
1093                                 highlightedPanel_initial_size = panel_size;
1094                         }
1095                         // doubleclick check
1096                         if ((mouseClicked & S_MOUSE1) && time - prevMouseClickedTime < 0.4 && highlightedPanel != -1 && prevMouseClickedPos == mousepos)
1097                         {
1098                                 mouseClicked = 0; // to prevent spam, I guess.
1099                                 HUD_Panel_EnableMenu();
1100                         }
1101                         else
1102                         {
1103                                 if (mouseClicked & S_MOUSE1)
1104                                 {
1105                                         prevMouseClickedTime = time;
1106                                         prevMouseClickedPos = mousepos;
1107                                 }
1108                                 mouse_over_panel = HUD_Panel_Check_Mouse_Pos(mouseClicked & S_MOUSE1);
1109                         }
1110                 }
1111                 else
1112                         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
1113
1114                 if (highlightedPanel != -1)
1115                 {
1116                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1117                         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
1118                         {
1119                                 hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
1120                                 // backup!
1121                                 panel_pos_backup = highlightedPanel_initial_pos;
1122                                 panel_size_backup = highlightedPanel_initial_size;
1123                                 highlightedPanel_backup = highlightedPanel;
1124                         }
1125                         else
1126                                 // in case the clicked panel is inside another panel and we aren't
1127                                 // moving it, avoid the immediate "fix" of its position/size
1128                                 // (often unwanted and hateful) by disabling collisions check
1129                                 hud_configure_checkcollisions = false;
1130                 }
1131
1132                 if(highlightedAction == 1)
1133                         HUD_Panel_SetPos(mousepos - panel_click_distance);
1134                 else if(highlightedAction == 2)
1135                 {
1136                         vector mySize;
1137                         if(resizeCorner == 1) {
1138                                 mySize_x = panel_click_resizeorigin_x - (mousepos_x - panel_click_distance_x);
1139                                 mySize_y = panel_click_resizeorigin_y - (mousepos_y - panel_click_distance_y);
1140                         } else if(resizeCorner == 2) {
1141                                 mySize_x = mousepos_x + panel_click_distance_x - panel_click_resizeorigin_x;
1142                                 mySize_y = panel_click_distance_y + panel_click_resizeorigin_y - mousepos_y;
1143                         } else if(resizeCorner == 3) {
1144                                 mySize_x = panel_click_resizeorigin_x + panel_click_distance_x - mousepos_x;
1145                                 mySize_y = mousepos_y + panel_click_distance_y - panel_click_resizeorigin_y;
1146                         } else { // resizeCorner == 4
1147                                 mySize_x = mousepos_x - (panel_click_resizeorigin_x - panel_click_distance_x);
1148                                 mySize_y = mousepos_y - (panel_click_resizeorigin_y - panel_click_distance_y);
1149                         }
1150                         HUD_Panel_SetPosSize(mySize);
1151                 }
1152         }
1153         else
1154         {
1155                 if(menu_enabled == 2)
1156                         mouse_over_panel = 0;
1157                 else
1158                         mouse_over_panel = HUD_Panel_Check_Mouse_Pos(TRUE);
1159                 if (mouse_over_panel && tab_panel == -1)
1160                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1161         }
1162         // draw cursor after performing move/resize to have the panel pos/size updated before mouse_over_panel
1163         const vector cursorsize = '32 32 0';
1164         float cursor_alpha = 1 - autocvar__menu_alpha;
1165
1166         if(!mouse_over_panel)
1167                 drawpic(mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1168         else if(mouse_over_panel == 1)
1169                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_move.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1170         else if(mouse_over_panel == 2)
1171                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1172         else
1173                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize2.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1174
1175         prevMouseClicked = mouseClicked;
1176 }
1177
1178 const float hlBorderSize = 4;
1179 const string hlBorder = "gfx/hud/default/border_highlighted";
1180 const string hlBorder2 = "gfx/hud/default/border_highlighted2";
1181 void HUD_Panel_HlBorder(float myBorder, vector color, float theAlpha)
1182 {
1183         drawfill(panel_pos - '1 1 0' * myBorder, panel_size + '2 2 0' * myBorder, '0 0.5 1', .5 * theAlpha, DRAWFLAG_NORMAL);
1184         drawpic_tiled(panel_pos - '1 1 0' * myBorder, hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1185         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * (panel_size_y + 2 * myBorder - hlBorderSize), hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1186         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize, hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1187         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize + eX * (panel_size_x + 2 * myBorder - hlBorderSize), hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1188 }