qcsrc/client/hud_config.qc

   1 #define HUD_Write(s) fputs(fh, s)
   2 // q: quoted, n: not quoted
   3 #define HUD_Write_Cvar_n(cvar) HUD_Write(strcat("seta ", cvar, " ", cvar_string(cvar), "\n"))
   4 #define HUD_Write_Cvar_q(cvar) HUD_Write(strcat("seta ", cvar, " \"", cvar_string(cvar), "\"\n"))
   5 #define HUD_Write_PanelCvar_n(cvar_suf) HUD_Write_Cvar_n(strcat("hud_panel_", panel.panel_name, cvar_suf))
   6 #define HUD_Write_PanelCvar_q(cvar_suf) HUD_Write_Cvar_q(strcat("hud_panel_", panel.panel_name, cvar_suf))
   7 // Save the config
   8 void HUD_Panel_ExportCfg(string cfgname)
   9 {
  10         float fh;
  11         string filename = strcat("hud_", autocvar_hud_skin, "_", cfgname, ".cfg");
  12         fh = fopen(filename, FILE_WRITE);
  13         if(fh >= 0)
  14         {
  15                 HUD_Write_Cvar_q("hud_skin");
  16                 HUD_Write_Cvar_q("hud_panel_bg");
  17                 HUD_Write_Cvar_q("hud_panel_bg_color");
  18                 HUD_Write_Cvar_q("hud_panel_bg_color_team");
  19                 HUD_Write_Cvar_q("hud_panel_bg_alpha");
  20                 HUD_Write_Cvar_q("hud_panel_bg_border");
  21                 HUD_Write_Cvar_q("hud_panel_bg_padding");
  22                 HUD_Write_Cvar_q("hud_panel_fg_alpha");
  23                 HUD_Write("\n");
  24
  25                 HUD_Write_Cvar_q("hud_dock");
  26                 HUD_Write_Cvar_q("hud_dock_color");
  27                 HUD_Write_Cvar_q("hud_dock_color_team");
  28                 HUD_Write_Cvar_q("hud_dock_alpha");
  29                 HUD_Write("\n");
  30
  31                 HUD_Write_Cvar_q("hud_progressbar_alpha");
  32                 HUD_Write_Cvar_q("hud_progressbar_strength_color");
  33                 HUD_Write_Cvar_q("hud_progressbar_shield_color");
  34                 HUD_Write_Cvar_q("hud_progressbar_health_color");
  35                 HUD_Write_Cvar_q("hud_progressbar_armor_color");
  36                 HUD_Write_Cvar_q("hud_progressbar_fuel_color");
  37                 HUD_Write_Cvar_q("hud_progressbar_nexball_color");
  38                 HUD_Write_Cvar_q("hud_progressbar_speed_color");
  39                 HUD_Write_Cvar_q("hud_progressbar_acceleration_color");
  40                 HUD_Write_Cvar_q("hud_progressbar_acceleration_neg_color");
  41                 HUD_Write("\n");
  42
  43                 HUD_Write_Cvar_q("_hud_panelorder");
  44                 HUD_Write("\n");
  45
  46                 HUD_Write_Cvar_q("hud_configure_grid");
  47                 HUD_Write_Cvar_q("hud_configure_grid_xsize");
  48                 HUD_Write_Cvar_q("hud_configure_grid_ysize");
  49                 HUD_Write("\n");
  50
  51                 // common cvars for all panels
  52                 float i;
  53                 for (i = 0; i < HUD_PANEL_NUM; ++i)
  54                 {
  55                         panel = hud_panel[i];
  56
  57                         HUD_Write_PanelCvar_n("");
  58                         HUD_Write_PanelCvar_q("_pos");
  59                         HUD_Write_PanelCvar_q("_size");
  60                         HUD_Write_PanelCvar_q("_bg");
  61                         HUD_Write_PanelCvar_q("_bg_color");
  62                         HUD_Write_PanelCvar_q("_bg_color_team");
  63                         HUD_Write_PanelCvar_q("_bg_alpha");
  64                         HUD_Write_PanelCvar_q("_bg_border");
  65                         HUD_Write_PanelCvar_q("_bg_padding");
  66                         switch(i) {
  67                                 case HUD_PANEL_WEAPONS:
  68                                         HUD_Write_PanelCvar_q("_accuracy");
  69                                         HUD_Write_PanelCvar_q("_label");
  70                                         HUD_Write_PanelCvar_q("_complainbubble");
  71                                         HUD_Write_PanelCvar_q("_complainbubble_padding");
  72                                         HUD_Write_PanelCvar_q("_complainbubble_time");
  73                                         HUD_Write_PanelCvar_q("_complainbubble_fadetime");
  74                                         HUD_Write_PanelCvar_q("_complainbubble_color_outofammo");
  75                                         HUD_Write_PanelCvar_q("_complainbubble_color_donthave");
  76                                         HUD_Write_PanelCvar_q("_complainbubble_color_unavailable");
  77                                         HUD_Write_PanelCvar_q("_ammo");
  78                                         HUD_Write_PanelCvar_q("_ammo_color");
  79                                         HUD_Write_PanelCvar_q("_ammo_alpha");
  80                                         HUD_Write_PanelCvar_q("_aspect");
  81                                         HUD_Write_PanelCvar_q("_timeout");
  82                                         HUD_Write_PanelCvar_q("_timeout_effect");
  83                                         HUD_Write_PanelCvar_q("_timeout_fadebgmin");
  84                                         HUD_Write_PanelCvar_q("_timeout_fadefgmin");
  85                                         HUD_Write_PanelCvar_q("_timeout_speed_in");
  86                                         HUD_Write_PanelCvar_q("_timeout_speed_out");
  87                                         HUD_Write_PanelCvar_q("_onlyowned");
  88                                         break;
  89                                 case HUD_PANEL_AMMO:
  90                                         HUD_Write_PanelCvar_q("_onlycurrent");
  91                                         HUD_Write_PanelCvar_q("_iconalign");
  92                                         HUD_Write_PanelCvar_q("_progressbar");
  93                                         HUD_Write_PanelCvar_q("_progressbar_name");
  94                                         HUD_Write_PanelCvar_q("_progressbar_xoffset");
  95                                         HUD_Write_PanelCvar_q("_text");
  96                                         break;
  97                                 case HUD_PANEL_POWERUPS:
  98                                         HUD_Write_PanelCvar_q("_flip");
  99                                         HUD_Write_PanelCvar_q("_iconalign");
 100                                         HUD_Write_PanelCvar_q("_baralign");
 101                                         HUD_Write_PanelCvar_q("_progressbar");
 102                                         HUD_Write_PanelCvar_q("_progressbar_strength");
 103                                         HUD_Write_PanelCvar_q("_progressbar_shield");
 104                                         HUD_Write_PanelCvar_q("_text");
 105                                         break;
 106                                 case HUD_PANEL_HEALTHARMOR:
 107                                         HUD_Write_PanelCvar_q("_flip");
 108                                         HUD_Write_PanelCvar_q("_iconalign");
 109                                         HUD_Write_PanelCvar_q("_baralign");
 110                                         HUD_Write_PanelCvar_q("_progressbar");
 111                                         HUD_Write_PanelCvar_q("_progressbar_health");
 112                                         HUD_Write_PanelCvar_q("_progressbar_armor");
 113                                         HUD_Write_PanelCvar_q("_progressbar_gfx");
 114                                         HUD_Write_PanelCvar_q("_progressbar_gfx_smooth");
 115                                         HUD_Write_PanelCvar_q("_text");
 116                                         break;
 117                                 case HUD_PANEL_NOTIFY:
 118                                         HUD_Write_PanelCvar_q("_flip");
 119                                         HUD_Write_PanelCvar_q("_fontsize");
 120                                         HUD_Write_PanelCvar_q("_time");
 121                                         HUD_Write_PanelCvar_q("_fadetime");
 122                                         break;
 123                                 case HUD_PANEL_TIMER:
 124                                         HUD_Write_PanelCvar_q("_increment");
 125                                         break;
 126                                 case HUD_PANEL_RADAR:
 127                                         HUD_Write_PanelCvar_q("_foreground_alpha");
 128                                         HUD_Write_PanelCvar_q("_rotation");
 129                                         HUD_Write_PanelCvar_q("_zoommode");
 130                                         HUD_Write_PanelCvar_q("_scale");
 131                                         HUD_Write_PanelCvar_q("_maximized_scale");
 132                                         HUD_Write_PanelCvar_q("_maximized_size");
 133                                         HUD_Write_PanelCvar_q("_maximized_rotation");
 134                                         HUD_Write_PanelCvar_q("_maximized_zoommode");
 135                                         break;
 136                                 case HUD_PANEL_SCORE:
 137                                         HUD_Write_PanelCvar_q("_rankings");
 138                                         break;
 139                                 case HUD_PANEL_VOTE:
 140                                         HUD_Write_PanelCvar_q("_alreadyvoted_alpha");
 141                                         break;
 142                                 case HUD_PANEL_MODICONS:
 143                                         HUD_Write_PanelCvar_q("_ca_layout");
 144                                         HUD_Write_PanelCvar_q("_dom_layout");
 145                                         HUD_Write_PanelCvar_q("_freezetag_layout");
 146                                         break;
 147                                 case HUD_PANEL_PRESSEDKEYS:
 148                                         HUD_Write_PanelCvar_q("_aspect");
 149                                         HUD_Write_PanelCvar_q("_attack");
 150                                         break;
 151                                 case HUD_PANEL_ENGINEINFO:
 152                                         HUD_Write_PanelCvar_q("_framecounter_time");
 153                                         HUD_Write_PanelCvar_q("_framecounter_decimals");
 154                                         break;
 155                                 case HUD_PANEL_INFOMESSAGES:
 156                                         HUD_Write_PanelCvar_q("_flip");
 157                                         break;
 158                                 case HUD_PANEL_PHYSICS:
 159                                         HUD_Write_PanelCvar_q("_speed_unit");
 160                                         HUD_Write_PanelCvar_q("_speed_unit_show");
 161                                         HUD_Write_PanelCvar_q("_speed_max");
 162                                         HUD_Write_PanelCvar_q("_speed_vertical");
 163                                         HUD_Write_PanelCvar_q("_topspeed");
 164                                         HUD_Write_PanelCvar_q("_topspeed_time");
 165                                         HUD_Write_PanelCvar_q("_acceleration_max");
 166                                         HUD_Write_PanelCvar_q("_acceleration_vertical");
 167                                         HUD_Write_PanelCvar_q("_flip");
 168                                         HUD_Write_PanelCvar_q("_baralign");
 169                                         HUD_Write_PanelCvar_q("_progressbar");
 170                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_mode");
 171                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_scale");
 172                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_nonlinear");
 173                                         HUD_Write_PanelCvar_q("_text");
 174                                         HUD_Write_PanelCvar_q("_text_scale");
 175                                         break;
 176                                 case HUD_PANEL_CENTERPRINT:
 177                                         HUD_Write_PanelCvar_q("_align");
 178                                         HUD_Write_PanelCvar_q("_flip");
 179                                         HUD_Write_PanelCvar_q("_fontscale");
 180                                         HUD_Write_PanelCvar_q("_time");
 181                                         HUD_Write_PanelCvar_q("_fade_in");
 182                                         HUD_Write_PanelCvar_q("_fade_out");
 183                                         HUD_Write_PanelCvar_q("_fade_subsequent");
 184                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone");
 185                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone_minalpha");
 186                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo");
 187                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo_minalpha");
 188                                         HUD_Write_PanelCvar_q("_fade_subsequent_minfontsize");
 189                                         HUD_Write_PanelCvar_q("_fade_minfontsize");
 190                                         break;
 191                         }
 192                         HUD_Write("\n");
 193                 }
 194                 HUD_Write("menu_sync\n"); // force the menu to reread the cvars, so that the dialogs are updated
 195
 196                 print(sprintf(_("^2Successfully exported to %s! (Note: It's saved in data/data/)\n"), filename));
 197                 fclose(fh);
 198         }
 199         else
 200                 print(sprintf(_("^1Couldn't write to %s\n"), filename));
 201 }
 202
 203 void HUD_Configure_Exit_Force()
 204 {
 205         if (menu_enabled)
 206         {
 207                 menu_enabled = 0;
 208                 localcmd("togglemenu\n");
 209         }
 210         cvar_set("_hud_configure", "0");
 211 }
 212
 213 // check if move will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 214 vector HUD_Panel_CheckMove(vector myPos, vector mySize)
 215 {
 216         float i;
 217         float myCenter_x, myCenter_y, targCenter_x, targCenter_y;
 218         vector myTarget;
 219         myTarget = myPos;
 220
 221         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 222                 panel = hud_panel[i];
 223                 if(panel == highlightedPanel) continue;
 224                 HUD_Panel_UpdatePosSize()
 225                 if(!panel_enabled) continue;
 226
 227                 panel_pos -= '1 1 0' * panel_bg_border;
 228                 panel_size += '2 2 0' * panel_bg_border;
 229
 230                 if(myPos_y + mySize_y < panel_pos_y)
 231                         continue;
 232                 if(myPos_y > panel_pos_y + panel_size_y)
 233                         continue;
 234
 235                 if(myPos_x + mySize_x < panel_pos_x)
 236                         continue;
 237                 if(myPos_x > panel_pos_x + panel_size_x)
 238                         continue;
 239
 240                 // OK, there IS a collision.
 241
 242                 myCenter_x = myPos_x + 0.5 * mySize_x;
 243                 myCenter_y = myPos_y + 0.5 * mySize_y;
 244
 245                 targCenter_x = panel_pos_x + 0.5 * panel_size_x;
 246                 targCenter_y = panel_pos_y + 0.5 * panel_size_y;
 247
 248                 if(myCenter_x < targCenter_x && myCenter_y < targCenter_y) // top left (of the target panel)
 249                 {
 250                         if(myPos_x + mySize_x - panel_pos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 251                                 myTarget_x = panel_pos_x - mySize_x;
 252                         else // push it upwards
 253                                 myTarget_y = panel_pos_y - mySize_y;
 254                 }
 255                 else if(myCenter_x > targCenter_x && myCenter_y < targCenter_y) // top right
 256                 {
 257                         if(panel_pos_x + panel_size_x - myPos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 258                                 myTarget_x = panel_pos_x + panel_size_x;
 259                         else // push it upwards
 260                                 myTarget_y = panel_pos_y - mySize_y;
 261                 }
 262                 else if(myCenter_x < targCenter_x && myCenter_y > targCenter_y) // bottom left
 263                 {
 264                         if(myPos_x + mySize_x - panel_pos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 265                                 myTarget_x = panel_pos_x - mySize_x;
 266                         else // push it downwards
 267                                 myTarget_y = panel_pos_y + panel_size_y;
 268                 }
 269                 else if(myCenter_x > targCenter_x && myCenter_y > targCenter_y) // bottom right
 270                 {
 271                         if(panel_pos_x + panel_size_x - myPos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 272                                 myTarget_x = panel_pos_x + panel_size_x;
 273                         else // push it downwards
 274                                 myTarget_y = panel_pos_y + panel_size_y;
 275                 }
 276                 //if(cvar("hud_configure_checkcollisions_debug"))
 277                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 278         }
 279
 280         return myTarget;
 281 }
 282
 283 void HUD_Panel_SetPos(vector pos)
 284 {
 285         panel = highlightedPanel;
 286         HUD_Panel_UpdatePosSize()
 287         vector mySize;
 288         mySize = panel_size;
 289
 290         //if(cvar("hud_configure_checkcollisions_debug"))
 291                 //drawfill(pos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 292
 293         if(autocvar_hud_configure_grid)
 294         {
 295                 pos_x = floor((pos_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 296                 pos_y = floor((pos_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 297         }
 298
 299         if(hud_configure_checkcollisions)
 300                 pos = HUD_Panel_CheckMove(pos, mySize);
 301
 302         pos_x = bound(0, pos_x, vid_conwidth - mySize_x);
 303         pos_y = bound(0, pos_y, vid_conheight - mySize_y);
 304
 305         string s;
 306         s = strcat(ftos(pos_x/vid_conwidth), " ", ftos(pos_y/vid_conheight));
 307
 308         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_pos"), s);
 309 }
 310
 311 // check if resize will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 312 vector HUD_Panel_CheckResize(vector mySize, vector resizeorigin) {
 313         float i;
 314
 315         vector targEndPos;
 316
 317         float dist_x, dist_y;
 318         float ratio;
 319         ratio = mySize_x/mySize_y;
 320
 321         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 322                 panel = hud_panel[i];
 323                 if(panel == highlightedPanel) continue;
 324                 HUD_Panel_UpdatePosSize()
 325                 if(!panel_enabled) continue;
 326
 327                 panel_pos -= '1 1 0' * panel_bg_border;
 328                 panel_size += '2 2 0' * panel_bg_border;
 329
 330                 targEndPos = panel_pos + panel_size;
 331
 332                 // resizeorigin is WITHIN target panel, just abort any collision testing against that particular panel to produce expected behaviour!
 333                 if(resizeorigin_x > panel_pos_x && resizeorigin_x < targEndPos_x && resizeorigin_y > panel_pos_y && resizeorigin_y < targEndPos_y)
 334                         continue;
 335
 336                 if (resizeCorner == 1)
 337                 {
 338                         // check if this panel is on our way
 339                         if (resizeorigin_x <= panel_pos_x)
 340                                 continue;
 341                         if (resizeorigin_y <= panel_pos_y)
 342                                 continue;
 343                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 344                                 continue;
 345                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 346                                 continue;
 347
 348                         // there is a collision:
 349                         // detect which side of the panel we are facing is actually limiting the resizing
 350                         // (which side the resize direction finds for first) and reduce the size up to there
 351                         //
 352                         // dist is the distance between resizeorigin and the "analogous" point of the panel
 353                         // in this case between resizeorigin (bottom-right point) and the bottom-right point of the panel
 354                         dist_x = resizeorigin_x - targEndPos_x;
 355                         dist_y = resizeorigin_y - targEndPos_y;
 356                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 357                                 mySize_x = min(mySize_x, dist_x);
 358                         else
 359                                 mySize_y = min(mySize_y, dist_y);
 360                 }
 361                 else if (resizeCorner == 2)
 362                 {
 363                         if (resizeorigin_x >= targEndPos_x)
 364                                 continue;
 365                         if (resizeorigin_y <= panel_pos_y)
 366                                 continue;
 367                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 368                                 continue;
 369                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 370                                 continue;
 371
 372                         dist_x = panel_pos_x - resizeorigin_x;
 373                         dist_y = resizeorigin_y - targEndPos_y;
 374                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 375                                 mySize_x = min(mySize_x, dist_x);
 376                         else
 377                                 mySize_y = min(mySize_y, dist_y);
 378                 }
 379                 else if (resizeCorner == 3)
 380                 {
 381                         if (resizeorigin_x <= panel_pos_x)
 382                                 continue;
 383                         if (resizeorigin_y >= targEndPos_y)
 384                                 continue;
 385                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 386                                 continue;
 387                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 388                                 continue;
 389
 390                         dist_x = resizeorigin_x - targEndPos_x;
 391                         dist_y = panel_pos_y - resizeorigin_y;
 392                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 393                                 mySize_x = min(mySize_x, dist_x);
 394                         else
 395                                 mySize_y = min(mySize_y, dist_y);
 396                 }
 397                 else if (resizeCorner == 4)
 398                 {
 399                         if (resizeorigin_x >= targEndPos_x)
 400                                 continue;
 401                         if (resizeorigin_y >= targEndPos_y)
 402                                 continue;
 403                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 404                                 continue;
 405                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 406                                 continue;
 407
 408                         dist_x = panel_pos_x - resizeorigin_x;
 409                         dist_y = panel_pos_y - resizeorigin_y;
 410                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 411                                 mySize_x = min(mySize_x, dist_x);
 412                         else
 413                                 mySize_y = min(mySize_y, dist_y);
 414                 }
 415                 //if(cvar("hud_configure_checkcollisions_debug"))
 416                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 417         }
 418
 419         return mySize;
 420 }
 421
 422 void HUD_Panel_SetPosSize(vector mySize)
 423 {
 424         panel = highlightedPanel;
 425         HUD_Panel_UpdatePosSize()
 426         vector resizeorigin;
 427         resizeorigin = panel_click_resizeorigin;
 428         local noref vector myPos; // fteqcc sucks
 429
 430         // minimum panel size cap
 431         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 432         mySize_y = max(0.025 * vid_conheight, mySize_y);
 433
 434         if(highlightedPanel == HUD_PANEL(CHAT)) // some panels have their own restrictions, like the chat panel (which actually only moves the engine chat print around). Looks bad if it's too small.
 435         {
 436                 mySize_x = max(17 * autocvar_con_chatsize, mySize_x);
 437                 mySize_y = max(2 * autocvar_con_chatsize + 2 * panel_bg_padding, mySize_y);
 438         }
 439
 440         // collision testing|
 441         // -----------------+
 442
 443         // we need to know pos at this stage, but it might still change later if we hit a screen edge/other panel (?)
 444         if(resizeCorner == 1) {
 445                 myPos_x = resizeorigin_x - mySize_x;
 446                 myPos_y = resizeorigin_y - mySize_y;
 447         } else if(resizeCorner == 2) {
 448                 myPos_x = resizeorigin_x;
 449                 myPos_y = resizeorigin_y - mySize_y;
 450         } else if(resizeCorner == 3) {
 451                 myPos_x = resizeorigin_x - mySize_x;
 452                 myPos_y = resizeorigin_y;
 453         } else { // resizeCorner == 4
 454                 myPos_x = resizeorigin_x;
 455                 myPos_y = resizeorigin_y;
 456         }
 457
 458         // left/top screen edges
 459         if(myPos_x < 0)
 460                 mySize_x = mySize_x + myPos_x;
 461         if(myPos_y < 0)
 462                 mySize_y = mySize_y + myPos_y;
 463
 464         // bottom/right screen edges
 465         if(myPos_x + mySize_x > vid_conwidth)
 466                 mySize_x = vid_conwidth - myPos_x;
 467         if(myPos_y + mySize_y > vid_conheight)
 468                 mySize_y = vid_conheight - myPos_y;
 469
 470         //if(cvar("hud_configure_checkcollisions_debug"))
 471                 //drawfill(myPos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 472
 473         // before checkresize, otherwise panel can be snapped partially inside another panel or panel aspect ratio can be broken
 474         if(autocvar_hud_configure_grid)
 475         {
 476                 mySize_x = floor((mySize_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 477                 mySize_y = floor((mySize_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 478         }
 479
 480         if(hud_configure_checkcollisions)
 481                 mySize = HUD_Panel_CheckResize(mySize, resizeorigin);
 482
 483         // minimum panel size cap, do this once more so we NEVER EVER EVER have a panel smaller than this, JUST IN CASE above code still makes the panel eg negative (impossible to resize back without changing cvars manually then)
 484         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 485         mySize_y = max(0.025 * vid_conheight, mySize_y);
 486
 487         // do another pos check, as size might have changed by now
 488         if(resizeCorner == 1) {
 489                 myPos_x = resizeorigin_x - mySize_x;
 490                 myPos_y = resizeorigin_y - mySize_y;
 491         } else if(resizeCorner == 2) {
 492                 myPos_x = resizeorigin_x;
 493                 myPos_y = resizeorigin_y - mySize_y;
 494         } else if(resizeCorner == 3) {
 495                 myPos_x = resizeorigin_x - mySize_x;
 496                 myPos_y = resizeorigin_y;
 497         } else { // resizeCorner == 4
 498                 myPos_x = resizeorigin_x;
 499                 myPos_y = resizeorigin_y;
 500         }
 501
 502         //if(cvar("hud_configure_checkcollisions_debug"))
 503                 //drawfill(myPos, mySize, '0 1 0', .3, DRAWFLAG_NORMAL);
 504
 505         string s;
 506         s = strcat(ftos(mySize_x/vid_conwidth), " ", ftos(mySize_y/vid_conheight));
 507         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_size"), s);
 508
 509         s = strcat(ftos(myPos_x/vid_conwidth), " ", ftos(myPos_y/vid_conheight));
 510         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_pos"), s);
 511 }
 512
 513 float pressed_key_time;
 514 vector highlightedPanel_initial_pos, highlightedPanel_initial_size;
 515 void HUD_Panel_Arrow_Action(float nPrimary)
 516 {
 517         if(!highlightedPanel)
 518                 return;
 519
 520         hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
 521
 522         float step;
 523         if(autocvar_hud_configure_grid)
 524         {
 525                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 526                 {
 527                         if (hudShiftState & S_SHIFT)
 528                                 step = hud_configure_realGridSize_y;
 529                         else
 530                                 step = 2 * hud_configure_realGridSize_y;
 531                 }
 532                 else
 533                 {
 534                         if (hudShiftState & S_SHIFT)
 535                                 step = hud_configure_realGridSize_x;
 536                         else
 537                                 step = 2 * hud_configure_realGridSize_x;
 538                 }
 539         }
 540         else
 541         {
 542                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 543                         step = vid_conheight;
 544                 else
 545                         step = vid_conwidth;
 546                 if (hudShiftState & S_SHIFT)
 547                         step = (step / 256); // more precision
 548                 else
 549                         step = (step / 64) * (1 + 2 * (time - pressed_key_time));
 550         }
 551
 552         panel = highlightedPanel;
 553         HUD_Panel_UpdatePosSize()
 554
 555         highlightedPanel_initial_pos = panel_pos;
 556         highlightedPanel_initial_size = panel_size;
 557
 558         if (hudShiftState & S_ALT) // resize
 559         {
 560                 highlightedAction = 1;
 561                 if(nPrimary == K_UPARROW)
 562                         resizeCorner = 1;
 563                 else if(nPrimary == K_RIGHTARROW)
 564                         resizeCorner = 2;
 565                 else if(nPrimary == K_LEFTARROW)
 566                         resizeCorner = 3;
 567                 else // if(nPrimary == K_DOWNARROW)
 568                         resizeCorner = 4;
 569
 570                 // ctrl+arrow reduces the size, instead of increasing it
 571                 // Note that ctrl disables collisions check too, but it's fine
 572                 // since we don't collide with anything reducing the size
 573                 if (hudShiftState & S_CTRL) {
 574                         step = -step;
 575                         resizeCorner = 5 - resizeCorner;
 576                 }
 577
 578                 vector mySize;
 579                 mySize = panel_size;
 580                 panel_click_resizeorigin = panel_pos;
 581                 if(resizeCorner == 1) {
 582                         panel_click_resizeorigin += mySize;
 583                         mySize_y += step;
 584                 } else if(resizeCorner == 2) {
 585                         panel_click_resizeorigin_y += mySize_y;
 586                         mySize_x += step;
 587                 } else if(resizeCorner == 3) {
 588                         panel_click_resizeorigin_x += mySize_x;
 589                         mySize_x += step;
 590                 } else { // resizeCorner == 4
 591                         mySize_y += step;
 592                 }
 593                 HUD_Panel_SetPosSize(mySize);
 594         }
 595         else // move
 596         {
 597                 highlightedAction = 2;
 598                 vector pos;
 599                 pos = panel_pos;
 600                 if(nPrimary == K_UPARROW)
 601                         pos_y -= step;
 602                 else if(nPrimary == K_DOWNARROW)
 603                         pos_y += step;
 604                 else if(nPrimary == K_LEFTARROW)
 605                         pos_x -= step;
 606                 else // if(nPrimary == K_RIGHTARROW)
 607                         pos_x += step;
 608
 609                 HUD_Panel_SetPos(pos);
 610         }
 611
 612         panel = highlightedPanel;
 613         HUD_Panel_UpdatePosSize()
 614
 615         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
 616         {
 617                 // backup!
 618                 panel_pos_backup = highlightedPanel_initial_pos;
 619                 panel_size_backup = highlightedPanel_initial_size;
 620                 highlightedPanel_backup = highlightedPanel;
 621         }
 622 }
 623
 624 const float S_MOUSE1 = 1;
 625 const float S_MOUSE2 = 2;
 626 const float S_MOUSE3 = 4;
 627 float mouseClicked;
 628 float prevMouseClicked; // previous state
 629 float prevMouseClickedTime; // time during previous left mouse click, to check for doubleclicks
 630 vector prevMouseClickedPos; // pos during previous left mouse click, to check for doubleclicks
 631
 632 void HUD_Panel_EnableMenu();
 633 entity tab_panels[HUD_PANEL_MAX];
 634 entity tab_panel;
 635 vector tab_panel_pos;
 636 float tab_backward;
 637 void HUD_Panel_FirstInDrawQ(float id);
 638 void reset_tab_panels()
 639 {
 640         int i;
 641         for(i = 0; i < HUD_PANEL_NUM; ++i)
 642                 tab_panels[i] = world;
 643 }
 644 float HUD_Panel_InputEvent(float bInputType, float nPrimary, float nSecondary)
 645 {
 646         string s;
 647
 648         if(bInputType == 2)
 649                 return false;
 650
 651         if(!autocvar__hud_configure)
 652                 return false;
 653
 654         // block any input while a menu dialog is fading
 655         if(autocvar__menu_alpha)
 656                 return true;
 657
 658         if(bInputType == 3)
 659         {
 660                 mousepos_x = nPrimary;
 661                 mousepos_y = nSecondary;
 662                 return true;
 663         }
 664
 665         // allow console bind to work
 666         string con_keys;
 667         float keys;
 668         con_keys = findkeysforcommand("toggleconsole", 0);
 669         keys = tokenize(con_keys); // findkeysforcommand returns data for this
 670
 671         float hit_con_bind = 0, i;
 672         for (i = 0; i < keys; ++i)
 673         {
 674                 if(nPrimary == stof(argv(i)))
 675                         hit_con_bind = 1;
 676         }
 677
 678         if(bInputType == 0) {
 679                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 680                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 681                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 682         }
 683         else if(bInputType == 1) {
 684                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 685                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 686                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 687         }
 688
 689         if(nPrimary == K_CTRL)
 690         {
 691                 if (bInputType == 1) //ctrl has been released
 692                 {
 693                         if (tab_panel)
 694                         {
 695                                 //switch to selected panel
 696                                 highlightedPanel = tab_panel;
 697                                 highlightedAction = 0;
 698                                 HUD_Panel_FirstInDrawQ(highlightedPanel.panel_id);
 699                         }
 700                         tab_panel = world;
 701                         reset_tab_panels();
 702                 }
 703         }
 704
 705         if(nPrimary == K_MOUSE1)
 706         {
 707                 if(bInputType == 0) // key pressed
 708                         mouseClicked |= S_MOUSE1;
 709                 else if(bInputType == 1) // key released
 710                         mouseClicked -= (mouseClicked & S_MOUSE1);
 711         }
 712         else if(nPrimary == K_MOUSE2)
 713         {
 714                 if(bInputType == 0) // key pressed
 715                         mouseClicked |= S_MOUSE2;
 716                 else if(bInputType == 1) // key released
 717                         mouseClicked -= (mouseClicked & S_MOUSE2);
 718         }
 719         else if(nPrimary == K_ESCAPE)
 720         {
 721                 if (bInputType == 1)
 722                         return true;
 723                 menu_enabled = 1;
 724                 menu_enabled_time = time;
 725                 localcmd("menu_showhudexit\n");
 726         }
 727         else if(nPrimary == K_BACKSPACE && hudShiftState & S_CTRL)
 728         {
 729                 if (bInputType == 1)
 730                         return true;
 731                 if (!menu_enabled)
 732                         cvar_set("_hud_configure", "0");
 733         }
 734         else if(nPrimary == K_TAB && hudShiftState & S_CTRL) // select and highlight another panel
 735         {
 736                 if (bInputType == 1 || mouseClicked)
 737                         return true;
 738
 739                 //FIXME: if a panel is highlighted, has the same pos_x and lays in the same level
 740                 //of other panels then next consecutive ctrl-tab will select the highlighted panel too
 741                 //(it should only after every other panel of the hud)
 742                 //It's a minor bug anyway, we can live with it
 743
 744                 entity starting_panel;
 745                 entity old_tab_panel = tab_panel;
 746                 if (!tab_panel) //first press of TAB
 747                 {
 748                         if (highlightedPanel)
 749                         {
 750                                 panel = highlightedPanel;
 751                                 HUD_Panel_UpdatePosSize()
 752                         }
 753                         else
 754                                 panel_pos = '0 0 0';
 755                         starting_panel = highlightedPanel;
 756                         tab_panel_pos = panel_pos; //to compute level
 757                 }
 758                 else
 759                 {
 760                         if ( ((!tab_backward) && (hudShiftState & S_SHIFT)) || (tab_backward && !(hudShiftState & S_SHIFT)) ) //tab direction changed?
 761                                 reset_tab_panels();
 762                         starting_panel = tab_panel;
 763                 }
 764                 tab_backward = (hudShiftState & S_SHIFT);
 765
 766                 float k, level = 0, start_pos_x;
 767                 vector candidate_pos = '0 0 0';
 768                 const float LEVELS_NUM = 4;
 769                 float level_height = vid_conheight / LEVELS_NUM;
 770 :find_tab_panel
 771                 level = floor(tab_panel_pos_y / level_height) * level_height; //starting level
 772                 candidate_pos_x = (!tab_backward) ? vid_conwidth : 0;
 773                 start_pos_x = tab_panel_pos_x;
 774                 tab_panel = world;
 775                 k=0;
 776                 while(++k)
 777                 {
 778                         for(i = 0; i < HUD_PANEL_NUM; ++i)
 779                         {
 780                                 panel = hud_panel[i];
 781                                 if (panel == tab_panels[i] || panel == starting_panel)
 782                                         continue;
 783                                 HUD_Panel_UpdatePosSize()
 784                                 if (panel_pos_y >= level && (panel_pos_y - level) < level_height)
 785                                 if (  ( !tab_backward && panel_pos_x >= start_pos_x && (panel_pos_x < candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y <= candidate_pos_y)) )
 786                                         || ( tab_backward && panel_pos_x <= start_pos_x && (panel_pos_x > candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y >= candidate_pos_y)) )  )
 787                                 {
 788                                         tab_panel = panel;
 789                                         tab_panel_pos = candidate_pos = panel_pos;
 790                                 }
 791                         }
 792                         if (tab_panel)
 793                                 break;
 794                         if (k == LEVELS_NUM) //tab_panel not found
 795                         {
 796                                 reset_tab_panels();
 797                                 if (!old_tab_panel)
 798                                 {
 799                                         tab_panel = world;
 800                                         return true;
 801                                 }
 802                                 starting_panel = old_tab_panel;
 803                                 old_tab_panel = world;
 804                                 goto find_tab_panel; //u must find tab_panel!
 805                         }
 806                         if (!tab_backward)
 807                         {
 808                                 level = mod(level + level_height, vid_conheight);
 809                                 start_pos_x = 0;
 810                                 candidate_pos_x = vid_conwidth;
 811                         }
 812                         else
 813                         {
 814                                 level = mod(level - level_height, vid_conheight);
 815                                 start_pos_x = vid_conwidth;
 816                                 candidate_pos_x = 0;
 817                         }
 818                 }
 819
 820                 tab_panels[tab_panel.panel_id] = tab_panel;
 821         }
 822         else if(nPrimary == K_SPACE && hudShiftState & S_CTRL) // enable/disable highlighted panel or dock
 823         {
 824                 if (bInputType == 1 || mouseClicked)
 825                         return true;
 826
 827                 if (highlightedPanel)
 828                         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name), ftos(!cvar(strcat("hud_panel_", highlightedPanel.panel_name))));
 829                 else
 830                         cvar_set(strcat("hud_dock"), (autocvar_hud_dock == "") ? "dock" : "");
 831         }
 832         else if(nPrimary == 'c' && hudShiftState & S_CTRL) // copy highlighted panel size
 833         {
 834                 if (bInputType == 1 || mouseClicked)
 835                         return true;
 836
 837                 if (highlightedPanel)
 838                 {
 839                         panel = highlightedPanel;
 840                         HUD_Panel_UpdatePosSize()
 841                         panel_size_copied = panel_size;
 842                 }
 843         }
 844         else if(nPrimary == 'v' && hudShiftState & S_CTRL) // past copied size on the highlighted panel
 845         {
 846                 if (bInputType == 1 || mouseClicked)
 847                         return true;
 848
 849                 if (panel_size_copied == '0 0 0' || !highlightedPanel)
 850                         return true;
 851
 852                 panel = highlightedPanel;
 853                 HUD_Panel_UpdatePosSize()
 854
 855                 // reduce size if it'd go beyond screen boundaries
 856                 vector tmp_size = panel_size_copied;
 857                 if (panel_pos_x + panel_size_copied_x > vid_conwidth)
 858                         tmp_size_x = vid_conwidth - panel_pos_x;
 859                 if (panel_pos_y + panel_size_copied_y > vid_conheight)
 860                         tmp_size_y = vid_conheight - panel_pos_y;
 861
 862                 if (panel_size == tmp_size)
 863                         return true;
 864
 865                 // backup first!
 866                 panel_pos_backup = panel_pos;
 867                 panel_size_backup = panel_size;
 868                 highlightedPanel_backup = highlightedPanel;
 869
 870                 s = strcat(ftos(tmp_size_x/vid_conwidth), " ", ftos(tmp_size_y/vid_conheight));
 871                 cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_size"), s);
 872         }
 873         else if(nPrimary == 'z' && hudShiftState & S_CTRL) // undo last action
 874         {
 875                 if (bInputType == 1 || mouseClicked)
 876                         return true;
 877                 //restore previous values
 878                 if (highlightedPanel_backup)
 879                 {
 880                         s = strcat(ftos(panel_pos_backup_x/vid_conwidth), " ", ftos(panel_pos_backup_y/vid_conheight));
 881                         cvar_set(strcat("hud_panel_", highlightedPanel_backup.panel_name, "_pos"), s);
 882                         s = strcat(ftos(panel_size_backup_x/vid_conwidth), " ", ftos(panel_size_backup_y/vid_conheight));
 883                         cvar_set(strcat("hud_panel_", highlightedPanel_backup.panel_name, "_size"), s);
 884                         highlightedPanel_backup = world;
 885                 }
 886         }
 887         else if(nPrimary == K_UPARROW || nPrimary == K_DOWNARROW || nPrimary == K_LEFTARROW || nPrimary == K_RIGHTARROW)
 888         {
 889                 if (bInputType == 1)
 890                 {
 891                         pressed_key_time = 0;
 892                         return true;
 893                 }
 894                 else if (pressed_key_time == 0)
 895                         pressed_key_time = time;
 896
 897                 if (!mouseClicked)
 898                         HUD_Panel_Arrow_Action(nPrimary); //move or resize panel
 899         }
 900         else if(nPrimary == K_ENTER || nPrimary == K_SPACE || nPrimary == K_KP_ENTER)
 901         {
 902                 if (bInputType == 1)
 903                         return true;
 904                 if (highlightedPanel)
 905                         HUD_Panel_EnableMenu();
 906         }
 907         else if(hit_con_bind)
 908                 return false;
 909
 910         return true;
 911 }
 912
 913 float HUD_Panel_Check_Mouse_Pos(float allow_move)
 914 {
 915         float i, j = 0, border;
 916
 917         while(j < HUD_PANEL_NUM)
 918         {
 919                 i = panel_order[j];
 920                 j += 1;
 921
 922                 panel = hud_panel[i];
 923                 HUD_Panel_UpdatePosSize()
 924
 925                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 926
 927                 // move
 928                 if(allow_move && mousepos_x > panel_pos_x && mousepos_y > panel_pos_y && mousepos_x < panel_pos_x + panel_size_x && mousepos_y < panel_pos_y + panel_size_y)
 929                 {
 930                         return 1;
 931                 }
 932                 // resize from topleft border
 933                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 934                 {
 935                         return 2;
 936                 }
 937                 // resize from topright border
 938                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 939                 {
 940                         return 3;
 941                 }
 942                 // resize from bottomleft border
 943                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
 944                 {
 945                         return 3;
 946                 }
 947                 // resize from bottomright border
 948                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
 949                 {
 950                         return 2;
 951                 }
 952         }
 953         return 0;
 954 }
 955
 956 // move a panel to the beginning of the panel order array (which means it gets drawn last, on top of everything else)
 957 void HUD_Panel_FirstInDrawQ(float id)
 958 {
 959         float i;
 960         var float place = -1;
 961         // find out where in the array our current id is, save into place
 962         for(i = 0; i < HUD_PANEL_NUM; ++i)
 963         {
 964                 if(panel_order[i] == id)
 965                 {
 966                         place = i;
 967                         break;
 968                 }
 969         }
 970         // place last if we didn't find a place for it yet (probably new panel, or screwed up cvar)
 971         if(place == -1)
 972                 place = HUD_PANEL_NUM - 1;
 973
 974         // move all ids up by one step in the array until "place"
 975         for(i = place; i > 0; --i)
 976         {
 977                 panel_order[i] = panel_order[i-1];
 978         }
 979         // now save the new top id
 980         panel_order[0] = id;
 981
 982         // let's save them into the cvar by some strcat trickery
 983         string s = "";
 984         for(i = 0; i < HUD_PANEL_NUM; ++i)
 985         {
 986                 s = strcat(s, ftos(panel_order[i]), " ");
 987         }
 988         cvar_set("_hud_panelorder", s);
 989         if(hud_panelorder_prev)
 990                 strunzone(hud_panelorder_prev);
 991         hud_panelorder_prev = strzone(autocvar__hud_panelorder); // prevent HUD_Main from doing useless update, we already updated here
 992 }
 993
 994 void HUD_Panel_Highlight(float allow_move)
 995 {
 996         float i, j = 0, border;
 997
 998         while(j < HUD_PANEL_NUM)
 999         {
1000                 i = panel_order[j];
1001                 j += 1;
1002
1003                 panel = hud_panel[i];
1004                 HUD_Panel_UpdatePosSize()
1005
1006                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
1007
1008                 // move
1009                 if(allow_move && mousepos_x > panel_pos_x && mousepos_y > panel_pos_y && mousepos_x < panel_pos_x + panel_size_x && mousepos_y < panel_pos_y + panel_size_y)
1010                 {
1011                         highlightedPanel = hud_panel[i];
1012                         HUD_Panel_FirstInDrawQ(i);
1013                         highlightedAction = 1;
1014                         panel_click_distance = mousepos - panel_pos;
1015                         return;
1016                 }
1017                 // resize from topleft border
1018                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
1019                 {
1020                         highlightedPanel = hud_panel[i];
1021                         HUD_Panel_FirstInDrawQ(i);
1022                         highlightedAction = 2;
1023                         resizeCorner = 1;
1024                         panel_click_distance = mousepos - panel_pos;
1025                         panel_click_resizeorigin = panel_pos + panel_size;
1026                         return;
1027                 }
1028                 // resize from topright border
1029                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
1030                 {
1031                         highlightedPanel = hud_panel[i];
1032                         HUD_Panel_FirstInDrawQ(i);
1033                         highlightedAction = 2;
1034                         resizeCorner = 2;
1035                         panel_click_distance_x = panel_size_x - mousepos_x + panel_pos_x;
1036                         panel_click_distance_y = mousepos_y - panel_pos_y;
1037                         panel_click_resizeorigin = panel_pos + eY * panel_size_y;
1038                         return;
1039                 }
1040                 // resize from bottomleft border
1041                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
1042                 {
1043                         highlightedPanel = hud_panel[i];
1044                         HUD_Panel_FirstInDrawQ(i);
1045                         highlightedAction = 2;
1046                         resizeCorner = 3;
1047                         panel_click_distance_x = mousepos_x - panel_pos_x;
1048                         panel_click_distance_y = panel_size_y - mousepos_y + panel_pos_y;
1049                         panel_click_resizeorigin = panel_pos + eX * panel_size_x;
1050                         return;
1051                 }
1052                 // resize from bottomright border
1053                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
1054                 {
1055                         highlightedPanel = hud_panel[i];
1056                         HUD_Panel_FirstInDrawQ(i);
1057                         highlightedAction = 2;
1058                         resizeCorner = 4;
1059                         panel_click_distance = panel_size - mousepos + panel_pos;
1060                         panel_click_resizeorigin = panel_pos;
1061                         return;
1062                 }
1063         }
1064         highlightedPanel = world;
1065         highlightedAction = 0;
1066 }
1067
1068 void HUD_Panel_EnableMenu()
1069 {
1070         menu_enabled = 2;
1071         menu_enabled_time = time;
1072         localcmd("menu_showhudoptions ", highlightedPanel.panel_name, "\n");
1073 }
1074 float mouse_over_panel;
1075 void HUD_Panel_Mouse()
1076 {
1077         // TODO: needs better check... is there any float that contains the current state of the menu? _menu_alpha isn't apparently updated the frame the menu gets enabled
1078         if (autocvar__menu_alpha == 0 && time - menu_enabled_time > 0.5)
1079                 menu_enabled = 0;
1080
1081         /*
1082         print("menu_enabled: ", ftos(menu_enabled), "\n");
1083         print("Highlighted: ", ftos(highlightedPanel), "\n");
1084         print("Menu theAlpha: ", ftos(autocvar__menu_alpha), "\n");
1085         */
1086
1087         if(autocvar__menu_alpha == 1)
1088                 return;
1089
1090         if (!autocvar_hud_cursormode)
1091         {
1092                 mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
1093
1094                 mousepos_x = bound(0, mousepos_x, vid_conwidth);
1095                 mousepos_y = bound(0, mousepos_y, vid_conheight);
1096         }
1097
1098         if(mouseClicked)
1099         {
1100                 if(prevMouseClicked == 0)
1101                 {
1102                         if (tab_panel)
1103                         {
1104                                 //stop ctrl-tab selection
1105                                 tab_panel = world;
1106                                 reset_tab_panels();
1107                         }
1108                         HUD_Panel_Highlight(mouseClicked & S_MOUSE1); // sets highlightedPanel, highlightedAction, panel_click_distance, panel_click_resizeorigin
1109                                                                         // and calls HUD_Panel_UpdatePosSize() for the highlighted panel
1110                         if (highlightedPanel)
1111                         {
1112                                 highlightedPanel_initial_pos = panel_pos;
1113                                 highlightedPanel_initial_size = panel_size;
1114                         }
1115                         // doubleclick check
1116                         if ((mouseClicked & S_MOUSE1) && time - prevMouseClickedTime < 0.4 && highlightedPanel && prevMouseClickedPos == mousepos)
1117                         {
1118                                 mouseClicked = 0; // to prevent spam, I guess.
1119                                 HUD_Panel_EnableMenu();
1120                         }
1121                         else
1122                         {
1123                                 if (mouseClicked & S_MOUSE1)
1124                                 {
1125                                         prevMouseClickedTime = time;
1126                                         prevMouseClickedPos = mousepos;
1127                                 }
1128                                 mouse_over_panel = HUD_Panel_Check_Mouse_Pos(mouseClicked & S_MOUSE1);
1129                         }
1130                 }
1131                 else
1132                 {
1133                         panel = highlightedPanel;
1134                         HUD_Panel_UpdatePosSize()
1135                 }
1136
1137                 if (highlightedPanel)
1138                 {
1139                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1140                         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
1141                         {
1142                                 hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
1143                                 // backup!
1144                                 panel_pos_backup = highlightedPanel_initial_pos;
1145                                 panel_size_backup = highlightedPanel_initial_size;
1146                                 highlightedPanel_backup = highlightedPanel;
1147                         }
1148                         else
1149                                 // in case the clicked panel is inside another panel and we aren't
1150                                 // moving it, avoid the immediate "fix" of its position/size
1151                                 // (often unwanted and hateful) by disabling collisions check
1152                                 hud_configure_checkcollisions = false;
1153                 }
1154
1155                 if(highlightedAction == 1)
1156                         HUD_Panel_SetPos(mousepos - panel_click_distance);
1157                 else if(highlightedAction == 2)
1158                 {
1159                         vector mySize = '0 0 0';
1160                         if(resizeCorner == 1) {
1161                                 mySize_x = panel_click_resizeorigin_x - (mousepos_x - panel_click_distance_x);
1162                                 mySize_y = panel_click_resizeorigin_y - (mousepos_y - panel_click_distance_y);
1163                         } else if(resizeCorner == 2) {
1164                                 mySize_x = mousepos_x + panel_click_distance_x - panel_click_resizeorigin_x;
1165                                 mySize_y = panel_click_distance_y + panel_click_resizeorigin_y - mousepos_y;
1166                         } else if(resizeCorner == 3) {
1167                                 mySize_x = panel_click_resizeorigin_x + panel_click_distance_x - mousepos_x;
1168                                 mySize_y = mousepos_y + panel_click_distance_y - panel_click_resizeorigin_y;
1169                         } else { // resizeCorner == 4
1170                                 mySize_x = mousepos_x - (panel_click_resizeorigin_x - panel_click_distance_x);
1171                                 mySize_y = mousepos_y - (panel_click_resizeorigin_y - panel_click_distance_y);
1172                         }
1173                         HUD_Panel_SetPosSize(mySize);
1174                 }
1175         }
1176         else
1177         {
1178                 if(menu_enabled == 2)
1179                         mouse_over_panel = 0;
1180                 else
1181                         mouse_over_panel = HUD_Panel_Check_Mouse_Pos(TRUE);
1182                 if (mouse_over_panel && !tab_panel)
1183                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1184         }
1185         // draw cursor after performing move/resize to have the panel pos/size updated before mouse_over_panel
1186         const vector cursorsize = '32 32 0';
1187         float cursor_alpha = 1 - autocvar__menu_alpha;
1188
1189         if(!mouse_over_panel)
1190                 drawpic(mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1191         else if(mouse_over_panel == 1)
1192                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_move.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1193         else if(mouse_over_panel == 2)
1194                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1195         else
1196                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize2.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1197
1198         prevMouseClicked = mouseClicked;
1199 }
1200
1201 const float hlBorderSize = 4;
1202 const string hlBorder = "gfx/hud/default/border_highlighted";
1203 const string hlBorder2 = "gfx/hud/default/border_highlighted2";
1204 void HUD_Panel_HlBorder(float myBorder, vector color, float theAlpha)
1205 {
1206         drawfill(panel_pos - '1 1 0' * myBorder, panel_size + '2 2 0' * myBorder, '0 0.5 1', .5 * theAlpha, DRAWFLAG_NORMAL);
1207         drawpic_tiled(panel_pos - '1 1 0' * myBorder, hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1208         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * (panel_size_y + 2 * myBorder - hlBorderSize), hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1209         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize, hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1210         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize + eX * (panel_size_x + 2 * myBorder - hlBorderSize), hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1211 }