Merge remote-tracking branch 'origin/master' into terencehill/cursormode
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / hud_config.qc
1 #define HUD_Write(s) fputs(fh, s)
2 // q: quoted, n: not quoted
3 #define HUD_Write_Cvar_n(cvar) HUD_Write(strcat("seta ", cvar, " ", cvar_string(cvar), "\n"))
4 #define HUD_Write_Cvar_q(cvar) HUD_Write(strcat("seta ", cvar, " \"", cvar_string(cvar), "\"\n"))
5 #define HUD_Write_PanelCvar_n(cvar_suf) HUD_Write_Cvar_n(strcat("hud_panel_", panel_name, cvar_suf))
6 #define HUD_Write_PanelCvar_q(cvar_suf) HUD_Write_Cvar_q(strcat("hud_panel_", panel_name, cvar_suf))
7 // Save the config
8 void HUD_Panel_ExportCfg(string cfgname)
9 {
10         float fh;
11         string filename = strcat("hud_", autocvar_hud_skin, "_", cfgname, ".cfg");
12         fh = fopen(filename, FILE_WRITE);
13         if(fh >= 0)
14         {
15                 HUD_Write_Cvar_q("hud_skin");
16                 HUD_Write_Cvar_q("hud_panel_bg");
17                 HUD_Write_Cvar_q("hud_panel_bg_color");
18                 HUD_Write_Cvar_q("hud_panel_bg_color_team");
19                 HUD_Write_Cvar_q("hud_panel_bg_alpha");
20                 HUD_Write_Cvar_q("hud_panel_bg_border");
21                 HUD_Write_Cvar_q("hud_panel_bg_padding");
22                 HUD_Write_Cvar_q("hud_panel_fg_alpha");
23                 HUD_Write("\n");
24
25                 HUD_Write_Cvar_q("hud_dock");
26                 HUD_Write_Cvar_q("hud_dock_color");
27                 HUD_Write_Cvar_q("hud_dock_color_team");
28                 HUD_Write_Cvar_q("hud_dock_alpha");
29                 HUD_Write("\n");
30
31                 HUD_Write_Cvar_q("hud_progressbar_alpha");
32                 HUD_Write_Cvar_q("hud_progressbar_strength_color");
33                 HUD_Write_Cvar_q("hud_progressbar_shield_color");
34                 HUD_Write_Cvar_q("hud_progressbar_health_color");
35                 HUD_Write_Cvar_q("hud_progressbar_armor_color");
36                 HUD_Write_Cvar_q("hud_progressbar_fuel_color");
37                 HUD_Write_Cvar_q("hud_progressbar_nexball_color");
38                 HUD_Write_Cvar_q("hud_progressbar_speed_color");
39                 HUD_Write_Cvar_q("hud_progressbar_acceleration_color");
40                 HUD_Write_Cvar_q("hud_progressbar_acceleration_neg_color");
41                 HUD_Write("\n");
42
43                 HUD_Write_Cvar_q("_hud_panelorder");
44                 HUD_Write("\n");
45
46                 HUD_Write_Cvar_q("hud_configure_grid");
47                 HUD_Write_Cvar_q("hud_configure_grid_xsize");
48                 HUD_Write_Cvar_q("hud_configure_grid_ysize");
49                 HUD_Write("\n");
50
51                 // common cvars for all panels
52                 float i;
53                 for (i = 0; i < HUD_PANEL_NUM; ++i)
54                 {
55                         HUD_Panel_GetName(i);
56
57                         HUD_Write_PanelCvar_n("");
58                         HUD_Write_PanelCvar_q("_pos");
59                         HUD_Write_PanelCvar_q("_size");
60                         HUD_Write_PanelCvar_q("_bg");
61                         HUD_Write_PanelCvar_q("_bg_color");
62                         HUD_Write_PanelCvar_q("_bg_color_team");
63                         HUD_Write_PanelCvar_q("_bg_alpha");
64                         HUD_Write_PanelCvar_q("_bg_border");
65                         HUD_Write_PanelCvar_q("_bg_padding");
66                         switch(i) {
67                                 case HUD_PANEL_WEAPONS:
68                                         HUD_Write_PanelCvar_q("_accuracy");
69                                         HUD_Write_PanelCvar_q("_label");
70                                         HUD_Write_PanelCvar_q("_complainbubble");
71                                         HUD_Write_PanelCvar_q("_complainbubble_padding");
72                                         HUD_Write_PanelCvar_q("_complainbubble_time");
73                                         HUD_Write_PanelCvar_q("_complainbubble_fadetime");
74                                         HUD_Write_PanelCvar_q("_complainbubble_color_outofammo");
75                                         HUD_Write_PanelCvar_q("_complainbubble_color_donthave");
76                                         HUD_Write_PanelCvar_q("_complainbubble_color_unavailable");
77                                         HUD_Write_PanelCvar_q("_ammo");
78                                         HUD_Write_PanelCvar_q("_ammo_color");
79                                         HUD_Write_PanelCvar_q("_ammo_alpha");
80                                         HUD_Write_PanelCvar_q("_aspect");
81                                         HUD_Write_PanelCvar_q("_timeout");
82                                         HUD_Write_PanelCvar_q("_timeout_effect");
83                                         HUD_Write_PanelCvar_q("_onlyowned");
84                                         break;
85                                 case HUD_PANEL_AMMO:
86                                         HUD_Write_PanelCvar_q("_onlycurrent");
87                                         HUD_Write_PanelCvar_q("_iconalign");
88                                         HUD_Write_PanelCvar_q("_progressbar");
89                                         HUD_Write_PanelCvar_q("_progressbar_name");
90                                         HUD_Write_PanelCvar_q("_progressbar_xoffset");
91                                         HUD_Write_PanelCvar_q("_text");
92                                         break;
93                                 case HUD_PANEL_POWERUPS:
94                                         HUD_Write_PanelCvar_q("_flip");
95                                         HUD_Write_PanelCvar_q("_iconalign");
96                                         HUD_Write_PanelCvar_q("_baralign");
97                                         HUD_Write_PanelCvar_q("_progressbar");
98                                         HUD_Write_PanelCvar_q("_progressbar_strength");
99                                         HUD_Write_PanelCvar_q("_progressbar_shield");
100                                         HUD_Write_PanelCvar_q("_text");
101                                         break;
102                                 case HUD_PANEL_HEALTHARMOR:
103                                         HUD_Write_PanelCvar_q("_flip");
104                                         HUD_Write_PanelCvar_q("_iconalign");
105                                         HUD_Write_PanelCvar_q("_baralign");
106                                         HUD_Write_PanelCvar_q("_progressbar");
107                                         HUD_Write_PanelCvar_q("_progressbar_health");
108                                         HUD_Write_PanelCvar_q("_progressbar_armor");
109                                         HUD_Write_PanelCvar_q("_progressbar_gfx");
110                                         HUD_Write_PanelCvar_q("_progressbar_gfx_smooth");
111                                         HUD_Write_PanelCvar_q("_text");
112                                         break;
113                                 case HUD_PANEL_NOTIFY:
114                                         HUD_Write_PanelCvar_q("_flip");
115                                         HUD_Write_PanelCvar_q("_fontsize");
116                                         HUD_Write_PanelCvar_q("_print");
117                                         HUD_Write_PanelCvar_q("_time");
118                                         HUD_Write_PanelCvar_q("_fadetime");
119                                         break;
120                                 case HUD_PANEL_TIMER:
121                                         HUD_Write_PanelCvar_q("_increment");
122                                         break;
123                                 case HUD_PANEL_RADAR:
124                                         HUD_Write_PanelCvar_q("_foreground_alpha");
125                                         HUD_Write_PanelCvar_q("_rotation");
126                                         HUD_Write_PanelCvar_q("_zoommode");
127                                         HUD_Write_PanelCvar_q("_scale");
128                                         HUD_Write_PanelCvar_q("_maximized_scale");
129                                         HUD_Write_PanelCvar_q("_maximized_size");
130                                         break;
131                                 case HUD_PANEL_SCORE:
132                                         HUD_Write_PanelCvar_q("_rankings");
133                                         break;
134                                 case HUD_PANEL_VOTE:
135                                         HUD_Write_PanelCvar_q("_alreadyvoted_alpha");
136                                         break;
137                                 case HUD_PANEL_MODICONS:
138                                         HUD_Write_PanelCvar_q("_dom_layout");
139                                         break;
140                                 case HUD_PANEL_PRESSEDKEYS:
141                                         HUD_Write_PanelCvar_q("_attack");
142                                         HUD_Write_PanelCvar_q("_aspect");
143                                         break;
144                                 case HUD_PANEL_ENGINEINFO:
145                                         HUD_Write_PanelCvar_q("_framecounter_time");
146                                         HUD_Write_PanelCvar_q("_framecounter_decimals");
147                                         break;
148                                 case HUD_PANEL_INFOMESSAGES:
149                                         HUD_Write_PanelCvar_q("_flip");
150                                         break;
151                                 case HUD_PANEL_PHYSICS:
152                                         HUD_Write_PanelCvar_q("_speed_unit");
153                                         HUD_Write_PanelCvar_q("_speed_unit_show");
154                                         HUD_Write_PanelCvar_q("_speed_max");
155                                         HUD_Write_PanelCvar_q("_speed_vertical");
156                                         HUD_Write_PanelCvar_q("_topspeed");
157                                         HUD_Write_PanelCvar_q("_topspeed_time");
158                                         HUD_Write_PanelCvar_q("_acceleration_max");
159                                         HUD_Write_PanelCvar_q("_acceleration_vertical");
160                                         HUD_Write_PanelCvar_q("_flip");
161                                         HUD_Write_PanelCvar_q("_baralign");
162                                         HUD_Write_PanelCvar_q("_progressbar");
163                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_mode");
164                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_scale");
165                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_nonlinear");
166                                         HUD_Write_PanelCvar_q("_text");
167                                         HUD_Write_PanelCvar_q("_text_scale");
168                                         break;
169                                 case HUD_PANEL_CENTERPRINT:
170                                         HUD_Write_PanelCvar_q("_align");
171                                         HUD_Write_PanelCvar_q("_flip");
172                                         HUD_Write_PanelCvar_q("_fontscale");
173                                         HUD_Write_PanelCvar_q("_time");
174                                         HUD_Write_PanelCvar_q("_fade_in");
175                                         HUD_Write_PanelCvar_q("_fade_out");
176                                         HUD_Write_PanelCvar_q("_fade_subsequent");
177                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone");
178                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone_minalpha");
179                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo");
180                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo_minalpha");
181                                         HUD_Write_PanelCvar_q("_fade_subsequent_minfontsize");
182                                         HUD_Write_PanelCvar_q("_fade_minfontsize");
183                                         break;
184                         }
185                         HUD_Write("\n");
186                 }
187                 HUD_Write("menu_sync\n"); // force the menu to reread the cvars, so that the dialogs are updated
188
189                 print(sprintf(_("^2Successfully exported to %s! (Note: It's saved in data/data/)\n"), filename));
190                 fclose(fh);
191         }
192         else
193                 print(sprintf(_("^1Couldn't write to %s\n"), filename));
194 }
195
196 void HUD_Configure_Exit_Force()
197 {
198         if (menu_enabled)
199         {
200                 menu_enabled = 0;
201                 localcmd("togglemenu\n");
202         }
203         cvar_set("_hud_configure", "0");
204 }
205
206 // check if move will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
207 vector HUD_Panel_CheckMove(vector myPos, vector mySize)
208 {
209         float i;
210         float myCenter_x, myCenter_y, targCenter_x, targCenter_y;
211         vector myTarget;
212         myTarget = myPos;
213
214         for (i = 0; i < HUD_PANEL_NUM; ++i) {
215                 if(i == highlightedPanel || !panel_enabled)
216                         continue;
217
218                 HUD_Panel_UpdatePosSizeForId(i);
219
220                 panel_pos -= '1 1 0' * panel_bg_border;
221                 panel_size += '2 2 0' * panel_bg_border;
222
223                 if(myPos_y + mySize_y < panel_pos_y)
224                         continue;
225                 if(myPos_y > panel_pos_y + panel_size_y)
226                         continue;
227
228                 if(myPos_x + mySize_x < panel_pos_x)
229                         continue;
230                 if(myPos_x > panel_pos_x + panel_size_x)
231                         continue;
232
233                 // OK, there IS a collision.
234
235                 myCenter_x = myPos_x + 0.5 * mySize_x;
236                 myCenter_y = myPos_y + 0.5 * mySize_y;
237
238                 targCenter_x = panel_pos_x + 0.5 * panel_size_x;
239                 targCenter_y = panel_pos_y + 0.5 * panel_size_y;
240
241                 if(myCenter_x < targCenter_x && myCenter_y < targCenter_y) // top left (of the target panel)
242                 {
243                         if(myPos_x + mySize_x - panel_pos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
244                                 myTarget_x = panel_pos_x - mySize_x;
245                         else // push it upwards
246                                 myTarget_y = panel_pos_y - mySize_y;
247                 }
248                 else if(myCenter_x > targCenter_x && myCenter_y < targCenter_y) // top right
249                 {
250                         if(panel_pos_x + panel_size_x - myPos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
251                                 myTarget_x = panel_pos_x + panel_size_x;
252                         else // push it upwards
253                                 myTarget_y = panel_pos_y - mySize_y;
254                 }
255                 else if(myCenter_x < targCenter_x && myCenter_y > targCenter_y) // bottom left
256                 {
257                         if(myPos_x + mySize_x - panel_pos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
258                                 myTarget_x = panel_pos_x - mySize_x;
259                         else // push it downwards
260                                 myTarget_y = panel_pos_y + panel_size_y;
261                 }
262                 else if(myCenter_x > targCenter_x && myCenter_y > targCenter_y) // bottom right
263                 {
264                         if(panel_pos_x + panel_size_x - myPos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
265                                 myTarget_x = panel_pos_x + panel_size_x;
266                         else // push it downwards
267                                 myTarget_y = panel_pos_y + panel_size_y;
268                 }
269                 //if(cvar("hud_configure_checkcollisions_debug"))
270                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
271         }
272
273         return myTarget;
274 }
275
276 void HUD_Panel_SetPos(vector pos)
277 {
278         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
279         vector mySize;
280         mySize = panel_size;
281
282         //if(cvar("hud_configure_checkcollisions_debug"))
283                 //drawfill(pos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
284
285         if(autocvar_hud_configure_grid)
286         {
287                 pos_x = floor((pos_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
288                 pos_y = floor((pos_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
289         }
290
291         if(hud_configure_checkcollisions)
292                 pos = HUD_Panel_CheckMove(pos, mySize);
293
294         pos_x = bound(0, pos_x, vid_conwidth - mySize_x);
295         pos_y = bound(0, pos_y, vid_conheight - mySize_y);
296
297         string s;
298         s = strcat(ftos(pos_x/vid_conwidth), " ", ftos(pos_y/vid_conheight));
299
300         HUD_Panel_GetName(highlightedPanel);
301         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
302 }
303
304 // check if resize will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
305 vector HUD_Panel_CheckResize(vector mySize, vector resizeorigin) {
306         float i;
307
308         vector targEndPos;
309
310         float dist_x, dist_y;
311         float ratio;
312         ratio = mySize_x/mySize_y;
313
314         for (i = 0; i < HUD_PANEL_NUM; ++i) {
315                 if(i == highlightedPanel || !panel_enabled)
316                         continue;
317
318                 HUD_Panel_UpdatePosSizeForId(i);
319
320                 panel_pos -= '1 1 0' * panel_bg_border;
321                 panel_size += '2 2 0' * panel_bg_border;
322
323                 targEndPos = panel_pos + panel_size;
324
325                 // resizeorigin is WITHIN target panel, just abort any collision testing against that particular panel to produce expected behaviour!
326                 if(resizeorigin_x > panel_pos_x && resizeorigin_x < targEndPos_x && resizeorigin_y > panel_pos_y && resizeorigin_y < targEndPos_y)
327                         continue;
328
329                 if (resizeCorner == 1)
330                 {
331                         // check if this panel is on our way
332                         if (resizeorigin_x <= panel_pos_x)
333                                 continue;
334                         if (resizeorigin_y <= panel_pos_y)
335                                 continue;
336                         if (targEndPos_x <= resizeorigin_x - mySize_x)
337                                 continue;
338                         if (targEndPos_y <= resizeorigin_y - mySize_y)
339                                 continue;
340
341                         // there is a collision:
342                         // detect which side of the panel we are facing is actually limiting the resizing
343                         // (which side the resize direction finds for first) and reduce the size up to there
344                         //
345                         // dist is the distance between resizeorigin and the "analogous" point of the panel
346                         // in this case between resizeorigin (bottom-right point) and the bottom-right point of the panel
347                         dist_x = resizeorigin_x - targEndPos_x;
348                         dist_y = resizeorigin_y - targEndPos_y;
349                         if (dist_y <= 0 || dist_x / dist_y > ratio)
350                                 mySize_x = min(mySize_x, dist_x);
351                         else
352                                 mySize_y = min(mySize_y, dist_y);
353                 }
354                 else if (resizeCorner == 2)
355                 {
356                         if (resizeorigin_x >= targEndPos_x)
357                                 continue;
358                         if (resizeorigin_y <= panel_pos_y)
359                                 continue;
360                         if (panel_pos_x >= resizeorigin_x + mySize_x)
361                                 continue;
362                         if (targEndPos_y <= resizeorigin_y - mySize_y)
363                                 continue;
364
365                         dist_x = panel_pos_x - resizeorigin_x;
366                         dist_y = resizeorigin_y - targEndPos_y;
367                         if (dist_y <= 0 || dist_x / dist_y > ratio)
368                                 mySize_x = min(mySize_x, dist_x);
369                         else
370                                 mySize_y = min(mySize_y, dist_y);
371                 }
372                 else if (resizeCorner == 3)
373                 {
374                         if (resizeorigin_x <= panel_pos_x)
375                                 continue;
376                         if (resizeorigin_y >= targEndPos_y)
377                                 continue;
378                         if (targEndPos_x <= resizeorigin_x - mySize_x)
379                                 continue;
380                         if (panel_pos_y >= resizeorigin_y + mySize_y)
381                                 continue;
382
383                         dist_x = resizeorigin_x - targEndPos_x;
384                         dist_y = panel_pos_y - resizeorigin_y;
385                         if (dist_y <= 0 || dist_x / dist_y > ratio)
386                                 mySize_x = min(mySize_x, dist_x);
387                         else
388                                 mySize_y = min(mySize_y, dist_y);
389                 }
390                 else if (resizeCorner == 4)
391                 {
392                         if (resizeorigin_x >= targEndPos_x)
393                                 continue;
394                         if (resizeorigin_y >= targEndPos_y)
395                                 continue;
396                         if (panel_pos_x >= resizeorigin_x + mySize_x)
397                                 continue;
398                         if (panel_pos_y >= resizeorigin_y + mySize_y)
399                                 continue;
400
401                         dist_x = panel_pos_x - resizeorigin_x;
402                         dist_y = panel_pos_y - resizeorigin_y;
403                         if (dist_y <= 0 || dist_x / dist_y > ratio)
404                                 mySize_x = min(mySize_x, dist_x);
405                         else
406                                 mySize_y = min(mySize_y, dist_y);
407                 }
408                 //if(cvar("hud_configure_checkcollisions_debug"))
409                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
410         }
411
412         return mySize;
413 }
414
415 void HUD_Panel_SetPosSize(vector mySize)
416 {
417         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
418         vector resizeorigin;
419         resizeorigin = panel_click_resizeorigin;
420         local noref vector myPos; // fteqcc sucks
421
422         // minimum panel size cap
423         mySize_x = max(0.025 * vid_conwidth, mySize_x);
424         mySize_y = max(0.025 * vid_conheight, mySize_y);
425
426         if(highlightedPanel == HUD_PANEL_CHAT) // some panels have their own restrictions, like the chat panel (which actually only moves the engine chat print around). Looks bad if it's too small.
427         {
428                 mySize_x = max(17 * autocvar_con_chatsize, mySize_x);
429                 mySize_y = max(2 * autocvar_con_chatsize + 2 * panel_bg_padding, mySize_y);
430         }
431
432         // collision testing|
433         // -----------------+
434
435         // we need to know pos at this stage, but it might still change later if we hit a screen edge/other panel (?)
436         if(resizeCorner == 1) {
437                 myPos_x = resizeorigin_x - mySize_x;
438                 myPos_y = resizeorigin_y - mySize_y;
439         } else if(resizeCorner == 2) {
440                 myPos_x = resizeorigin_x;
441                 myPos_y = resizeorigin_y - mySize_y;
442         } else if(resizeCorner == 3) {
443                 myPos_x = resizeorigin_x - mySize_x;
444                 myPos_y = resizeorigin_y;
445         } else { // resizeCorner == 4
446                 myPos_x = resizeorigin_x;
447                 myPos_y = resizeorigin_y;
448         }
449
450         // left/top screen edges
451         if(myPos_x < 0)
452                 mySize_x = mySize_x + myPos_x;
453         if(myPos_y < 0)
454                 mySize_y = mySize_y + myPos_y;
455
456         // bottom/right screen edges
457         if(myPos_x + mySize_x > vid_conwidth)
458                 mySize_x = vid_conwidth - myPos_x;
459         if(myPos_y + mySize_y > vid_conheight)
460                 mySize_y = vid_conheight - myPos_y;
461
462         //if(cvar("hud_configure_checkcollisions_debug"))
463                 //drawfill(myPos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
464
465         // before checkresize, otherwise panel can be snapped partially inside another panel or panel aspect ratio can be broken
466         if(autocvar_hud_configure_grid)
467         {
468                 mySize_x = floor((mySize_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
469                 mySize_y = floor((mySize_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
470         }
471
472         if(hud_configure_checkcollisions)
473                 mySize = HUD_Panel_CheckResize(mySize, resizeorigin);
474
475         // minimum panel size cap, do this once more so we NEVER EVER EVER have a panel smaller than this, JUST IN CASE above code still makes the panel eg negative (impossible to resize back without changing cvars manually then)
476         mySize_x = max(0.025 * vid_conwidth, mySize_x);
477         mySize_y = max(0.025 * vid_conheight, mySize_y);
478
479         // do another pos check, as size might have changed by now
480         if(resizeCorner == 1) {
481                 myPos_x = resizeorigin_x - mySize_x;
482                 myPos_y = resizeorigin_y - mySize_y;
483         } else if(resizeCorner == 2) {
484                 myPos_x = resizeorigin_x;
485                 myPos_y = resizeorigin_y - mySize_y;
486         } else if(resizeCorner == 3) {
487                 myPos_x = resizeorigin_x - mySize_x;
488                 myPos_y = resizeorigin_y;
489         } else { // resizeCorner == 4
490                 myPos_x = resizeorigin_x;
491                 myPos_y = resizeorigin_y;
492         }
493
494         //if(cvar("hud_configure_checkcollisions_debug"))
495                 //drawfill(myPos, mySize, '0 1 0', .3, DRAWFLAG_NORMAL);
496
497         HUD_Panel_GetName(highlightedPanel);
498         string s;
499         s = strcat(ftos(mySize_x/vid_conwidth), " ", ftos(mySize_y/vid_conheight));
500         cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
501
502         s = strcat(ftos(myPos_x/vid_conwidth), " ", ftos(myPos_y/vid_conheight));
503         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
504 }
505
506 float pressed_key_time;
507 vector highlightedPanel_initial_pos, highlightedPanel_initial_size;
508 void HUD_Panel_Arrow_Action(float nPrimary)
509 {
510         if (highlightedPanel == -1)
511                 return;
512
513         hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
514
515         float step;
516         if(autocvar_hud_configure_grid)
517         {
518                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
519                 {
520                         if (hudShiftState & S_SHIFT)
521                                 step = hud_configure_realGridSize_y;
522                         else
523                                 step = 2 * hud_configure_realGridSize_y;
524                 }
525                 else
526                 {
527                         if (hudShiftState & S_SHIFT)
528                                 step = hud_configure_realGridSize_x;
529                         else
530                                 step = 2 * hud_configure_realGridSize_x;
531                 }
532         }
533         else
534         {
535                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
536                         step = vid_conheight;
537                 else
538                         step = vid_conwidth;
539                 if (hudShiftState & S_SHIFT)
540                         step = (step / 256); // more precision
541                 else
542                         step = (step / 64) * (1 + 2 * (time - pressed_key_time));
543         }
544
545         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
546
547         highlightedPanel_initial_pos = panel_pos;
548         highlightedPanel_initial_size = panel_size;
549
550         if (hudShiftState & S_ALT) // resize
551         {
552                 highlightedAction = 1;
553                 if(nPrimary == K_UPARROW)
554                         resizeCorner = 1;
555                 else if(nPrimary == K_RIGHTARROW)
556                         resizeCorner = 2;
557                 else if(nPrimary == K_LEFTARROW)
558                         resizeCorner = 3;
559                 else // if(nPrimary == K_DOWNARROW)
560                         resizeCorner = 4;
561
562                 // ctrl+arrow reduces the size, instead of increasing it
563                 // Note that ctrl disables collisions check too, but it's fine
564                 // since we don't collide with anything reducing the size
565                 if (hudShiftState & S_CTRL) {
566                         step = -step;
567                         resizeCorner = 5 - resizeCorner;
568                 }
569
570                 vector mySize;
571                 mySize = panel_size;
572                 panel_click_resizeorigin = panel_pos;
573                 if(resizeCorner == 1) {
574                         panel_click_resizeorigin += mySize;
575                         mySize_y += step;
576                 } else if(resizeCorner == 2) {
577                         panel_click_resizeorigin_y += mySize_y;
578                         mySize_x += step;
579                 } else if(resizeCorner == 3) {
580                         panel_click_resizeorigin_x += mySize_x;
581                         mySize_x += step;
582                 } else { // resizeCorner == 4
583                         mySize_y += step;
584                 }
585                 HUD_Panel_SetPosSize(mySize);
586         }
587         else // move
588         {
589                 highlightedAction = 2;
590                 vector pos;
591                 pos = panel_pos;
592                 if(nPrimary == K_UPARROW)
593                         pos_y -= step;
594                 else if(nPrimary == K_DOWNARROW)
595                         pos_y += step;
596                 else if(nPrimary == K_LEFTARROW)
597                         pos_x -= step;
598                 else // if(nPrimary == K_RIGHTARROW)
599                         pos_x += step;
600
601                 HUD_Panel_SetPos(pos);
602         }
603
604         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
605
606         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
607         {
608                 // backup!
609                 panel_pos_backup = highlightedPanel_initial_pos;
610                 panel_size_backup = highlightedPanel_initial_size;
611                 highlightedPanel_backup = highlightedPanel;
612         }
613 }
614
615 const float S_MOUSE1 = 1;
616 const float S_MOUSE2 = 2;
617 const float S_MOUSE3 = 4;
618 float mouseClicked;
619 float prevMouseClicked; // previous state
620 float prevMouseClickedTime; // time during previous left mouse click, to check for doubleclicks
621 vector prevMouseClickedPos; // pos during previous left mouse click, to check for doubleclicks
622
623 void HUD_Panel_EnableMenu();
624 float tab_panels[HUD_PANEL_NUM];
625 float tab_panel, tab_backward;
626 vector tab_panel_pos;
627 void HUD_Panel_FirstInDrawQ(float id);
628 void reset_tab_panels()
629 {
630         int i;
631         for(i = 0; i < HUD_PANEL_NUM; ++i)
632                 tab_panels[i] = -1;
633 }
634 float HUD_Panel_InputEvent(float bInputType, float nPrimary, float nSecondary)
635 {
636         string s;
637
638         if(bInputType == 2)
639                 return false;
640
641         if(!autocvar__hud_configure)
642                 return false;
643
644         // block any input while a menu dialog is fading
645         if(autocvar__menu_alpha)
646                 return true;
647
648         if(bInputType == 3)
649         {
650                 mousepos_x = nPrimary;
651                 mousepos_y = nSecondary;
652                 return true;
653         }
654
655         // allow console bind to work
656         string con_keys;
657         float keys;
658         con_keys = findkeysforcommand("toggleconsole", 0);
659         keys = tokenize(con_keys); // findkeysforcommand returns data for this
660
661         float hit_con_bind, i;
662         for (i = 0; i < keys; ++i)
663         {
664                 if(nPrimary == stof(argv(i)))
665                         hit_con_bind = 1;
666         }
667
668         if(bInputType == 0) {
669                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
670                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
671                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
672         }
673         else if(bInputType == 1) {
674                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
675                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
676                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
677         }
678
679         if(nPrimary == K_CTRL)
680         {
681                 if (bInputType == 1) //ctrl has been released
682                 {
683                         if (tab_panel != -1)
684                         {
685                                 //switch to selected panel
686                                 highlightedPanel = tab_panel;
687                                 highlightedAction = 0;
688                                 HUD_Panel_FirstInDrawQ(highlightedPanel);
689                         }
690                         tab_panel = -1;
691                         reset_tab_panels();
692                 }
693         }
694
695         if(nPrimary == K_MOUSE1)
696         {
697                 if(bInputType == 0) // key pressed
698                         mouseClicked |= S_MOUSE1;
699                 else if(bInputType == 1) // key released
700                         mouseClicked -= (mouseClicked & S_MOUSE1);
701         }
702         else if(nPrimary == K_MOUSE2)
703         {
704                 if(bInputType == 0) // key pressed
705                         mouseClicked |= S_MOUSE2;
706                 else if(bInputType == 1) // key released
707                         mouseClicked -= (mouseClicked & S_MOUSE2);
708         }
709         else if(nPrimary == K_ESCAPE)
710         {
711                 if (bInputType == 1)
712                         return true;
713                 menu_enabled = 1;
714                 menu_enabled_time = time;
715                 localcmd("menu_showhudexit\n");
716         }
717         else if(nPrimary == K_BACKSPACE && hudShiftState & S_CTRL)
718         {
719                 if (bInputType == 1)
720                         return true;
721                 if (!menu_enabled)
722                         cvar_set("_hud_configure", "0");
723         }
724         else if(nPrimary == K_TAB && hudShiftState & S_CTRL) // select and highlight another panel
725         {
726                 if (bInputType == 1 || mouseClicked)
727                         return true;
728
729                 //FIXME: if a panel is highlighted, has the same pos_x and lays in the same level
730                 //of other panels then next consecutive ctrl-tab will select the highlighted panel too
731                 //(it should only after every other panel of the hud)
732                 //It's a minor bug anyway, we can live with it
733
734                 float starting_panel;
735                 float old_tab_panel = tab_panel;
736                 if (tab_panel == -1) //first press of TAB
737                 {
738                         if (highlightedPanel != -1)
739                                 HUD_Panel_UpdatePosSizeForId(highlightedPanel)
740                         else
741                                 panel_pos = '0 0 0';
742                         starting_panel = highlightedPanel; //can be -1, it means no starting panel
743                         tab_panel_pos = panel_pos; //to compute level
744                 }
745                 else
746                 {
747                         if ( ((!tab_backward) && (hudShiftState & S_SHIFT)) || (tab_backward && !(hudShiftState & S_SHIFT)) ) //tab direction changed?
748                                 reset_tab_panels();
749                         starting_panel = tab_panel;
750                 }
751                 tab_backward = (hudShiftState & S_SHIFT);
752
753                 float k, level, start_pos_x;
754                 vector candidate_pos;
755                 const float LEVELS_NUM = 4;
756                 float level_height = vid_conheight / LEVELS_NUM;
757 :find_tab_panel
758                 level = floor(tab_panel_pos_y / level_height) * level_height; //starting level
759                 candidate_pos_x = (!tab_backward) ? vid_conwidth : 0;
760                 start_pos_x = tab_panel_pos_x;
761                 tab_panel = -1;
762                 k=0;
763                 while(++k)
764                 {
765                         for(i = 0; i < HUD_PANEL_NUM; ++i)
766                         {
767                                 if (i == tab_panels[i] || i == starting_panel)
768                                         continue;
769                                 HUD_Panel_UpdatePosSizeForId(i)
770                                 if (panel_pos_y >= level && (panel_pos_y - level) < level_height)
771                                 if (  ( !tab_backward && panel_pos_x >= start_pos_x && (panel_pos_x < candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y <= candidate_pos_y)) )
772                                         || ( tab_backward && panel_pos_x <= start_pos_x && (panel_pos_x > candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y >= candidate_pos_y)) )  )
773                                 {
774                                         tab_panel = i;
775                                         tab_panel_pos = candidate_pos = panel_pos;
776                                 }
777                         }
778                         if (tab_panel != -1)
779                                 break;
780                         if (k == LEVELS_NUM) //tab_panel not found
781                         {
782                                 reset_tab_panels();
783                                 if (old_tab_panel == -2) //this prevents an infinite loop (should not happen normally)
784                                 {
785                                         tab_panel = -1;
786                                         return true;
787                                 }
788                                 starting_panel = old_tab_panel;
789                                 old_tab_panel = -2;
790                                 goto find_tab_panel; //u must find tab_panel!
791                         }
792                         if (!tab_backward)
793                         {
794                                 level = mod(level + level_height, vid_conheight);
795                                 start_pos_x = 0;
796                                 candidate_pos_x = vid_conwidth;
797                         }
798                         else
799                         {
800                                 level = mod(level - level_height, vid_conheight);
801                                 start_pos_x = vid_conwidth;
802                                 candidate_pos_x = 0;
803                         }
804                 }
805
806                 tab_panels[tab_panel] = tab_panel;
807         }
808         else if(nPrimary == K_SPACE && hudShiftState & S_CTRL) // enable/disable highlighted panel or dock
809         {
810                 if (bInputType == 1 || mouseClicked)
811                         return true;
812
813                 if (highlightedPanel != -1)
814                 {
815                         HUD_Panel_GetName(highlightedPanel);
816                         cvar_set(strcat("hud_panel_", panel_name), ftos(!(panel_enabled)));
817                 }
818                 else
819                         cvar_set(strcat("hud_dock"), (autocvar_hud_dock == "") ? "dock" : "");
820         }
821         else if(nPrimary == 'c' && hudShiftState & S_CTRL) // copy highlighted panel size
822         {
823                 if (bInputType == 1 || mouseClicked)
824                         return true;
825
826                 if (highlightedPanel != -1)
827                 {
828                         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
829                         panel_size_copied = panel_size;
830                         highlightedPanel_copied = highlightedPanel;
831                 }
832         }
833         else if(nPrimary == 'v' && hudShiftState & S_CTRL) // past copied size on the highlighted panel
834         {
835                 if (bInputType == 1 || mouseClicked)
836                         return true;
837
838                 if (highlightedPanel_copied == -1 || highlightedPanel == -1)
839                         return true;
840
841                 HUD_Panel_UpdatePosSizeForId(highlightedPanel);
842
843                 // reduce size if it'd go beyond screen boundaries
844                 vector tmp_size = panel_size_copied;
845                 if (panel_pos_x + panel_size_copied_x > vid_conwidth)
846                         tmp_size_x = vid_conwidth - panel_pos_x;
847                 if (panel_pos_y + panel_size_copied_y > vid_conheight)
848                         tmp_size_y = vid_conheight - panel_pos_y;
849
850                 if (panel_size == tmp_size)
851                         return true;
852
853                 // backup first!
854                 panel_pos_backup = panel_pos;
855                 panel_size_backup = panel_size;
856                 highlightedPanel_backup = highlightedPanel;
857
858                 s = strcat(ftos(tmp_size_x/vid_conwidth), " ", ftos(tmp_size_y/vid_conheight));
859                 HUD_Panel_GetName(highlightedPanel);
860                 cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
861         }
862         else if(nPrimary == 'z' && hudShiftState & S_CTRL) // undo last action
863         {
864                 if (bInputType == 1 || mouseClicked)
865                         return true;
866                 //restore previous values
867                 if (highlightedPanel_backup != -1)
868                 {
869                         HUD_Panel_GetName(highlightedPanel_backup);
870                         s = strcat(ftos(panel_pos_backup_x/vid_conwidth), " ", ftos(panel_pos_backup_y/vid_conheight));
871                         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
872                         s = strcat(ftos(panel_size_backup_x/vid_conwidth), " ", ftos(panel_size_backup_y/vid_conheight));
873                         cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
874                         highlightedPanel_backup = -1;
875                 }
876         }
877         else if(nPrimary == K_UPARROW || nPrimary == K_DOWNARROW || nPrimary == K_LEFTARROW || nPrimary == K_RIGHTARROW)
878         {
879                 if (bInputType == 1)
880                 {
881                         pressed_key_time = 0;
882                         return true;
883                 }
884                 else if (pressed_key_time == 0)
885                         pressed_key_time = time;
886
887                 if (!mouseClicked)
888                         HUD_Panel_Arrow_Action(nPrimary); //move or resize panel
889         }
890         else if(nPrimary == K_ENTER || nPrimary == K_SPACE || nPrimary == K_KP_ENTER)
891         {
892                 if (bInputType == 1)
893                         return true;
894                 if (highlightedPanel != -1)
895                         HUD_Panel_EnableMenu();
896         }
897         else if(hit_con_bind)
898                 return false;
899
900         return true;
901 }
902
903 float HUD_Panel_Check_Mouse_Pos(float allow_move)
904 {
905         float i, j, border;
906
907         while(j < HUD_PANEL_NUM)
908         {
909                 i = panel_order[j];
910                 j += 1;
911
912                 HUD_Panel_UpdatePosSizeForId(i);
913
914                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
915
916                 // move
917                 if(allow_move && mousepos_x > panel_pos_x && mousepos_y > panel_pos_y && mousepos_x < panel_pos_x + panel_size_x && mousepos_y < panel_pos_y + panel_size_y)
918                 {
919                         return 1;
920                 }
921                 // resize from topleft border
922                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
923                 {
924                         return 2;
925                 }
926                 // resize from topright border
927                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
928                 {
929                         return 3;
930                 }
931                 // resize from bottomleft border
932                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
933                 {
934                         return 3;
935                 }
936                 // resize from bottomright border
937                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
938                 {
939                         return 2;
940                 }
941         }
942         return 0;
943 }
944
945 // move a panel to the beginning of the panel order array (which means it gets drawn last, on top of everything else)
946 void HUD_Panel_FirstInDrawQ(float id)
947 {
948         float i;
949         var float place = -1;
950         // find out where in the array our current id is, save into place
951         for(i = 0; i < HUD_PANEL_NUM; ++i)
952         {
953                 if(panel_order[i] == id)
954                 {
955                         place = i;
956                         break;
957                 }
958         }
959         // place last if we didn't find a place for it yet (probably new panel, or screwed up cvar)
960         if(place == -1)
961                 place = HUD_PANEL_NUM - 1;
962
963         // move all ids up by one step in the array until "place"
964         for(i = place; i > 0; --i)
965         {
966                 panel_order[i] = panel_order[i-1];
967         }
968         // now save the new top id
969         panel_order[0] = id;
970         
971         // let's save them into the cvar by some strcat trickery
972         string s;
973         for(i = 0; i < HUD_PANEL_NUM; ++i)
974         {
975                 s = strcat(s, ftos(panel_order[i]), " ");
976         }
977         cvar_set("_hud_panelorder", s);
978         if(hud_panelorder_prev)
979                 strunzone(hud_panelorder_prev);
980         hud_panelorder_prev = strzone(autocvar__hud_panelorder); // prevent HUD_Main from doing useless update, we already updated here
981 }
982
983 void HUD_Panel_Highlight(float allow_move)
984 {
985         float i, j, border;
986
987         while(j < HUD_PANEL_NUM)
988         {
989                 i = panel_order[j];
990                 j += 1;
991
992                 HUD_Panel_UpdatePosSizeForId(i);
993
994                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
995
996                 // move
997                 if(allow_move && mousepos_x > panel_pos_x && mousepos_y > panel_pos_y && mousepos_x < panel_pos_x + panel_size_x && mousepos_y < panel_pos_y + panel_size_y)
998                 {
999                         highlightedPanel = i;
1000                         HUD_Panel_FirstInDrawQ(i);
1001                         highlightedAction = 1;
1002                         panel_click_distance = mousepos - panel_pos;
1003                         return;
1004                 }
1005                 // resize from topleft border
1006                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
1007                 {
1008                         highlightedPanel = i;
1009                         HUD_Panel_FirstInDrawQ(i);
1010                         highlightedAction = 2;
1011                         resizeCorner = 1;
1012                         panel_click_distance = mousepos - panel_pos;
1013                         panel_click_resizeorigin = panel_pos + panel_size;
1014                         return;
1015                 }
1016                 // resize from topright border
1017                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
1018                 {
1019                         highlightedPanel = i;
1020                         HUD_Panel_FirstInDrawQ(i);
1021                         highlightedAction = 2;
1022                         resizeCorner = 2;
1023                         panel_click_distance_x = panel_size_x - mousepos_x + panel_pos_x;
1024                         panel_click_distance_y = mousepos_y - panel_pos_y;
1025                         panel_click_resizeorigin = panel_pos + eY * panel_size_y;
1026                         return;
1027                 }
1028                 // resize from bottomleft border
1029                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
1030                 {
1031                         highlightedPanel = i;
1032                         HUD_Panel_FirstInDrawQ(i);
1033                         highlightedAction = 2;
1034                         resizeCorner = 3;
1035                         panel_click_distance_x = mousepos_x - panel_pos_x;
1036                         panel_click_distance_y = panel_size_y - mousepos_y + panel_pos_y;
1037                         panel_click_resizeorigin = panel_pos + eX * panel_size_x;
1038                         return;
1039                 }
1040                 // resize from bottomright border
1041                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
1042                 {
1043                         highlightedPanel = i;
1044                         HUD_Panel_FirstInDrawQ(i);
1045                         highlightedAction = 2;
1046                         resizeCorner = 4;
1047                         panel_click_distance = panel_size - mousepos + panel_pos;
1048                         panel_click_resizeorigin = panel_pos;
1049                         return;
1050                 }
1051         }
1052         highlightedPanel = -1;
1053         highlightedAction = 0;
1054 }
1055
1056 void HUD_Panel_EnableMenu()
1057 {
1058         menu_enabled = 2;
1059         menu_enabled_time = time;
1060         HUD_Panel_GetName(highlightedPanel);
1061         localcmd("menu_showhudoptions ", panel_name, "\n");
1062 }
1063 float mouse_over_panel;
1064 void HUD_Panel_Mouse()
1065 {
1066         // TODO: needs better check... is there any float that contains the current state of the menu? _menu_alpha isn't apparently updated the frame the menu gets enabled
1067         if (autocvar__menu_alpha == 0 && time - menu_enabled_time > 0.5)
1068                 menu_enabled = 0;
1069
1070         /*
1071         print("menu_enabled: ", ftos(menu_enabled), "\n");
1072         print("Highlighted: ", ftos(highlightedPanel), "\n");
1073         print("Menu theAlpha: ", ftos(autocvar__menu_alpha), "\n");
1074         */
1075
1076         if(autocvar__menu_alpha == 1)
1077                 return;
1078
1079         if(mouseClicked)
1080         {
1081                 if(prevMouseClicked == 0)
1082                 {
1083                         if (tab_panel != -1)
1084                         {
1085                                 //stop ctrl-tab selection
1086                                 tab_panel = -1;
1087                                 reset_tab_panels();
1088                         }
1089                         HUD_Panel_Highlight(mouseClicked & S_MOUSE1); // sets highlightedPanel, highlightedAction, panel_click_distance, panel_click_resizeorigin
1090                                                                         // and calls HUD_Panel_UpdatePosSizeForId() for the highlighted panel
1091                         if (highlightedPanel != -1)
1092                         {
1093                                 highlightedPanel_initial_pos = panel_pos;
1094                                 highlightedPanel_initial_size = panel_size;
1095                         }
1096                         // doubleclick check
1097                         if ((mouseClicked & S_MOUSE1) && time - prevMouseClickedTime < 0.4 && highlightedPanel != -1 && prevMouseClickedPos == mousepos)
1098                         {
1099                                 mouseClicked = 0; // to prevent spam, I guess.
1100                                 HUD_Panel_EnableMenu();
1101                         }
1102                         else
1103                         {
1104                                 if (mouseClicked & S_MOUSE1)
1105                                 {
1106                                         prevMouseClickedTime = time;
1107                                         prevMouseClickedPos = mousepos;
1108                                 }
1109                                 mouse_over_panel = HUD_Panel_Check_Mouse_Pos(mouseClicked & S_MOUSE1);
1110                         }
1111                 }
1112                 else
1113                         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
1114
1115                 if (highlightedPanel != -1)
1116                 {
1117                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1118                         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
1119                         {
1120                                 hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
1121                                 // backup!
1122                                 panel_pos_backup = highlightedPanel_initial_pos;
1123                                 panel_size_backup = highlightedPanel_initial_size;
1124                                 highlightedPanel_backup = highlightedPanel;
1125                         }
1126                         else
1127                                 // in case the clicked panel is inside another panel and we aren't
1128                                 // moving it, avoid the immediate "fix" of its position/size
1129                                 // (often unwanted and hateful) by disabling collisions check
1130                                 hud_configure_checkcollisions = false;
1131                 }
1132
1133                 if(highlightedAction == 1)
1134                         HUD_Panel_SetPos(mousepos - panel_click_distance);
1135                 else if(highlightedAction == 2)
1136                 {
1137                         vector mySize;
1138                         if(resizeCorner == 1) {
1139                                 mySize_x = panel_click_resizeorigin_x - (mousepos_x - panel_click_distance_x);
1140                                 mySize_y = panel_click_resizeorigin_y - (mousepos_y - panel_click_distance_y);
1141                         } else if(resizeCorner == 2) {
1142                                 mySize_x = mousepos_x + panel_click_distance_x - panel_click_resizeorigin_x;
1143                                 mySize_y = panel_click_distance_y + panel_click_resizeorigin_y - mousepos_y;
1144                         } else if(resizeCorner == 3) {
1145                                 mySize_x = panel_click_resizeorigin_x + panel_click_distance_x - mousepos_x;
1146                                 mySize_y = mousepos_y + panel_click_distance_y - panel_click_resizeorigin_y;
1147                         } else { // resizeCorner == 4
1148                                 mySize_x = mousepos_x - (panel_click_resizeorigin_x - panel_click_distance_x);
1149                                 mySize_y = mousepos_y - (panel_click_resizeorigin_y - panel_click_distance_y);
1150                         }
1151                         HUD_Panel_SetPosSize(mySize);
1152                 }
1153         }
1154         else
1155         {
1156                 if(menu_enabled == 2)
1157                         mouse_over_panel = 0;
1158                 else
1159                         mouse_over_panel = HUD_Panel_Check_Mouse_Pos(TRUE);
1160                 if (mouse_over_panel && tab_panel == -1)
1161                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1162         }
1163         // draw cursor after performing move/resize to have the panel pos/size updated before mouse_over_panel
1164         const vector cursorsize = '32 32 0';
1165         float cursor_alpha = 1 - autocvar__menu_alpha;
1166
1167         if(!mouse_over_panel)
1168                 drawpic(mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1169         else if(mouse_over_panel == 1)
1170                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_move.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1171         else if(mouse_over_panel == 2)
1172                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1173         else
1174                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize2.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1175
1176         prevMouseClicked = mouseClicked;
1177 }
1178
1179 const float hlBorderSize = 4;
1180 const string hlBorder = "gfx/hud/default/border_highlighted";
1181 const string hlBorder2 = "gfx/hud/default/border_highlighted2";
1182 void HUD_Panel_HlBorder(float myBorder, vector color, float theAlpha)
1183 {
1184         drawfill(panel_pos - '1 1 0' * myBorder, panel_size + '2 2 0' * myBorder, '0 0.5 1', .5 * theAlpha, DRAWFLAG_NORMAL);
1185         drawpic_tiled(panel_pos - '1 1 0' * myBorder, hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1186         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * (panel_size_y + 2 * myBorder - hlBorderSize), hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1187         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize, hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1188         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize + eX * (panel_size_x + 2 * myBorder - hlBorderSize), hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1189 }