qcsrc/client/hud_config.qc

   1 #include "hud_config.qh"
   2 #include "_all.qh"
   3
   4 #include "hud.qh"
   5
   6 #include "../common/constants.qh"
   7
   8 #include "../dpdefs/keycodes.qh"
   9
  10
  11 #define HUD_Write(s) fputs(fh, s)
  12 // q: quoted, n: not quoted
  13 #define HUD_Write_Cvar_n(cvar) HUD_Write(strcat("seta ", cvar, " ", cvar_string(cvar), "\n"))
  14 #define HUD_Write_Cvar_q(cvar) HUD_Write(strcat("seta ", cvar, " \"", cvar_string(cvar), "\"\n"))
  15 #define HUD_Write_PanelCvar_n(cvar_suf) HUD_Write_Cvar_n(strcat("hud_panel_", panel.panel_name, cvar_suf))
  16 #define HUD_Write_PanelCvar_q(cvar_suf) HUD_Write_Cvar_q(strcat("hud_panel_", panel.panel_name, cvar_suf))
  17 // Save the config
  18 void HUD_Panel_ExportCfg(string cfgname)
  19 {
  20         float fh;
  21         string filename = strcat("hud_", autocvar_hud_skin, "_", cfgname, ".cfg");
  22         fh = fopen(filename, FILE_WRITE);
  23         if(fh >= 0)
  24         {
  25                 HUD_Write_Cvar_q("hud_skin");
  26                 HUD_Write_Cvar_q("hud_panel_bg");
  27                 HUD_Write_Cvar_q("hud_panel_bg_color");
  28                 HUD_Write_Cvar_q("hud_panel_bg_color_team");
  29                 HUD_Write_Cvar_q("hud_panel_bg_alpha");
  30                 HUD_Write_Cvar_q("hud_panel_bg_border");
  31                 HUD_Write_Cvar_q("hud_panel_bg_padding");
  32                 HUD_Write_Cvar_q("hud_panel_fg_alpha");
  33                 HUD_Write("\n");
  34
  35                 HUD_Write_Cvar_q("hud_dock");
  36                 HUD_Write_Cvar_q("hud_dock_color");
  37                 HUD_Write_Cvar_q("hud_dock_color_team");
  38                 HUD_Write_Cvar_q("hud_dock_alpha");
  39                 HUD_Write("\n");
  40
  41                 HUD_Write_Cvar_q("hud_progressbar_alpha");
  42                 HUD_Write_Cvar_q("hud_progressbar_strength_color");
  43                 HUD_Write_Cvar_q("hud_progressbar_shield_color");
  44                 HUD_Write_Cvar_q("hud_progressbar_health_color");
  45                 HUD_Write_Cvar_q("hud_progressbar_armor_color");
  46                 HUD_Write_Cvar_q("hud_progressbar_fuel_color");
  47                 HUD_Write_Cvar_q("hud_progressbar_nexball_color");
  48                 HUD_Write_Cvar_q("hud_progressbar_speed_color");
  49                 HUD_Write_Cvar_q("hud_progressbar_acceleration_color");
  50                 HUD_Write_Cvar_q("hud_progressbar_acceleration_neg_color");
  51                 HUD_Write("\n");
  52
  53                 HUD_Write_Cvar_q("_hud_panelorder");
  54                 HUD_Write("\n");
  55
  56                 HUD_Write_Cvar_q("hud_configure_grid");
  57                 HUD_Write_Cvar_q("hud_configure_grid_xsize");
  58                 HUD_Write_Cvar_q("hud_configure_grid_ysize");
  59                 HUD_Write("\n");
  60
  61                 // common cvars for all panels
  62                 int i;
  63                 for (i = 0; i < HUD_PANEL_NUM; ++i)
  64                 {
  65                         panel = hud_panel[i];
  66
  67                         HUD_Write_PanelCvar_n("");
  68                         HUD_Write_PanelCvar_q("_pos");
  69                         HUD_Write_PanelCvar_q("_size");
  70                         HUD_Write_PanelCvar_q("_bg");
  71                         HUD_Write_PanelCvar_q("_bg_color");
  72                         HUD_Write_PanelCvar_q("_bg_color_team");
  73                         HUD_Write_PanelCvar_q("_bg_alpha");
  74                         HUD_Write_PanelCvar_q("_bg_border");
  75                         HUD_Write_PanelCvar_q("_bg_padding");
  76                         switch(i) {
  77                                 case HUD_PANEL_WEAPONS:
  78                                         HUD_Write_PanelCvar_q("_accuracy");
  79                                         HUD_Write_PanelCvar_q("_label");
  80                                         HUD_Write_PanelCvar_q("_label_scale");
  81                                         HUD_Write_PanelCvar_q("_complainbubble");
  82                                         HUD_Write_PanelCvar_q("_complainbubble_padding");
  83                                         HUD_Write_PanelCvar_q("_complainbubble_time");
  84                                         HUD_Write_PanelCvar_q("_complainbubble_fadetime");
  85                                         HUD_Write_PanelCvar_q("_complainbubble_color_outofammo");
  86                                         HUD_Write_PanelCvar_q("_complainbubble_color_donthave");
  87                                         HUD_Write_PanelCvar_q("_complainbubble_color_unavailable");
  88                                         HUD_Write_PanelCvar_q("_ammo");
  89                                         HUD_Write_PanelCvar_q("_ammo_color");
  90                                         HUD_Write_PanelCvar_q("_ammo_alpha");
  91                                         HUD_Write_PanelCvar_q("_aspect");
  92                                         HUD_Write_PanelCvar_q("_timeout");
  93                                         HUD_Write_PanelCvar_q("_timeout_effect");
  94                                         HUD_Write_PanelCvar_q("_timeout_fadebgmin");
  95                                         HUD_Write_PanelCvar_q("_timeout_fadefgmin");
  96                                         HUD_Write_PanelCvar_q("_timeout_speed_in");
  97                                         HUD_Write_PanelCvar_q("_timeout_speed_out");
  98                                         HUD_Write_PanelCvar_q("_onlyowned");
  99                                         HUD_Write_PanelCvar_q("_noncurrent_alpha");
 100                                         HUD_Write_PanelCvar_q("_noncurrent_scale");
 101                                         break;
 102                                 case HUD_PANEL_AMMO:
 103                                         HUD_Write_PanelCvar_q("_onlycurrent");
 104                                         HUD_Write_PanelCvar_q("_noncurrent_alpha");
 105                                         HUD_Write_PanelCvar_q("_noncurrent_scale");
 106                                         HUD_Write_PanelCvar_q("_iconalign");
 107                                         HUD_Write_PanelCvar_q("_progressbar");
 108                                         HUD_Write_PanelCvar_q("_progressbar_name");
 109                                         HUD_Write_PanelCvar_q("_progressbar_xoffset");
 110                                         HUD_Write_PanelCvar_q("_text");
 111                                         break;
 112                                 case HUD_PANEL_POWERUPS:
 113                                         HUD_Write_PanelCvar_q("_iconalign");
 114                                         HUD_Write_PanelCvar_q("_baralign");
 115                                         HUD_Write_PanelCvar_q("_progressbar");
 116                                         HUD_Write_PanelCvar_q("_text");
 117                                         break;
 118                                 case HUD_PANEL_HEALTHARMOR:
 119                                         HUD_Write_PanelCvar_q("_flip");
 120                                         HUD_Write_PanelCvar_q("_iconalign");
 121                                         HUD_Write_PanelCvar_q("_baralign");
 122                                         HUD_Write_PanelCvar_q("_progressbar");
 123                                         HUD_Write_PanelCvar_q("_progressbar_health");
 124                                         HUD_Write_PanelCvar_q("_progressbar_armor");
 125                                         HUD_Write_PanelCvar_q("_progressbar_gfx");
 126                                         HUD_Write_PanelCvar_q("_progressbar_gfx_smooth");
 127                                         HUD_Write_PanelCvar_q("_text");
 128                                         break;
 129                                 case HUD_PANEL_NOTIFY:
 130                                         HUD_Write_PanelCvar_q("_flip");
 131                                         HUD_Write_PanelCvar_q("_fontsize");
 132                                         HUD_Write_PanelCvar_q("_time");
 133                                         HUD_Write_PanelCvar_q("_fadetime");
 134                                         HUD_Write_PanelCvar_q("_icon_aspect");
 135                                         break;
 136                                 case HUD_PANEL_TIMER:
 137                                         HUD_Write_PanelCvar_q("_increment");
 138                                         break;
 139                                 case HUD_PANEL_RADAR:
 140                                         HUD_Write_PanelCvar_q("_foreground_alpha");
 141                                         HUD_Write_PanelCvar_q("_rotation");
 142                                         HUD_Write_PanelCvar_q("_zoommode");
 143                                         HUD_Write_PanelCvar_q("_scale");
 144                                         HUD_Write_PanelCvar_q("_maximized_scale");
 145                                         HUD_Write_PanelCvar_q("_maximized_size");
 146                                         HUD_Write_PanelCvar_q("_maximized_rotation");
 147                                         HUD_Write_PanelCvar_q("_maximized_zoommode");
 148                                         break;
 149                                 case HUD_PANEL_SCORE:
 150                                         HUD_Write_PanelCvar_q("_rankings");
 151                                         break;
 152                                 case HUD_PANEL_VOTE:
 153                                         HUD_Write_PanelCvar_q("_alreadyvoted_alpha");
 154                                         break;
 155                                 case HUD_PANEL_MODICONS:
 156                                         HUD_Write_PanelCvar_q("_ca_layout");
 157                                         HUD_Write_PanelCvar_q("_dom_layout");
 158                                         HUD_Write_PanelCvar_q("_freezetag_layout");
 159                                         break;
 160                                 case HUD_PANEL_PRESSEDKEYS:
 161                                         HUD_Write_PanelCvar_q("_aspect");
 162                                         HUD_Write_PanelCvar_q("_attack");
 163                                         break;
 164                                 case HUD_PANEL_ENGINEINFO:
 165                                         HUD_Write_PanelCvar_q("_framecounter_time");
 166                                         HUD_Write_PanelCvar_q("_framecounter_decimals");
 167                                         break;
 168                                 case HUD_PANEL_INFOMESSAGES:
 169                                         HUD_Write_PanelCvar_q("_flip");
 170                                         break;
 171                                 case HUD_PANEL_PHYSICS:
 172                                         HUD_Write_PanelCvar_q("_speed_unit");
 173                                         HUD_Write_PanelCvar_q("_speed_unit_show");
 174                                         HUD_Write_PanelCvar_q("_speed_max");
 175                                         HUD_Write_PanelCvar_q("_speed_vertical");
 176                                         HUD_Write_PanelCvar_q("_topspeed");
 177                                         HUD_Write_PanelCvar_q("_topspeed_time");
 178                                         HUD_Write_PanelCvar_q("_acceleration_max");
 179                                         HUD_Write_PanelCvar_q("_acceleration_vertical");
 180                                         HUD_Write_PanelCvar_q("_flip");
 181                                         HUD_Write_PanelCvar_q("_baralign");
 182                                         HUD_Write_PanelCvar_q("_progressbar");
 183                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_mode");
 184                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_scale");
 185                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_nonlinear");
 186                                         HUD_Write_PanelCvar_q("_text");
 187                                         HUD_Write_PanelCvar_q("_text_scale");
 188                                         break;
 189                                 case HUD_PANEL_CENTERPRINT:
 190                                         HUD_Write_PanelCvar_q("_align");
 191                                         HUD_Write_PanelCvar_q("_flip");
 192                                         HUD_Write_PanelCvar_q("_fontscale");
 193                                         HUD_Write_PanelCvar_q("_time");
 194                                         HUD_Write_PanelCvar_q("_fade_in");
 195                                         HUD_Write_PanelCvar_q("_fade_out");
 196                                         HUD_Write_PanelCvar_q("_fade_subsequent");
 197                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone");
 198                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone_minalpha");
 199                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo");
 200                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo_minalpha");
 201                                         HUD_Write_PanelCvar_q("_fade_subsequent_minfontsize");
 202                                         HUD_Write_PanelCvar_q("_fade_minfontsize");
 203                         }
 204                         HUD_Write("\n");
 205                 }
 206                 HUD_Write("menu_sync\n"); // force the menu to reread the cvars, so that the dialogs are updated
 207
 208                 printf(_("^2Successfully exported to %s! (Note: It's saved in data/data/)\n"), filename);
 209                 fclose(fh);
 210         }
 211         else
 212                 printf(_("^1Couldn't write to %s\n"), filename);
 213 }
 214
 215 void HUD_Configure_Exit_Force()
 216 {
 217         if (menu_enabled)
 218         {
 219                 menu_enabled = 0;
 220                 localcmd("togglemenu\n");
 221         }
 222         cvar_set("_hud_configure", "0");
 223 }
 224
 225 // check if move will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 226 vector HUD_Panel_CheckMove(vector myPos, vector mySize)
 227 {
 228         vector myCenter, targCenter;
 229         vector myTarget = myPos;
 230         int i;
 231         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 232                 panel = hud_panel[i];
 233                 if(panel == HUD_PANEL(MAPVOTE)) continue;
 234                 if(panel == highlightedPanel) continue;
 235                 HUD_Panel_UpdatePosSize();
 236                 if(!panel_enabled) continue;
 237
 238                 panel_pos -= '1 1 0' * panel_bg_border;
 239                 panel_size += '2 2 0' * panel_bg_border;
 240
 241                 if(myPos.y + mySize.y < panel_pos.y)
 242                         continue;
 243                 if(myPos.y > panel_pos.y + panel_size.y)
 244                         continue;
 245
 246                 if(myPos.x + mySize.x < panel_pos.x)
 247                         continue;
 248                 if(myPos.x > panel_pos.x + panel_size.x)
 249                         continue;
 250
 251                 // OK, there IS a collision.
 252
 253                 myCenter.x = myPos.x + 0.5 * mySize.x;
 254                 myCenter.y = myPos.y + 0.5 * mySize.y;
 255
 256                 targCenter.x = panel_pos.x + 0.5 * panel_size.x;
 257                 targCenter.y = panel_pos.y + 0.5 * panel_size.y;
 258
 259                 if(myCenter.x < targCenter.x && myCenter.y < targCenter.y) // top left (of the target panel)
 260                 {
 261                         if(myPos.x + mySize.x - panel_pos.x < myPos.y + mySize.y - panel_pos.y) // push it to the side
 262                                 myTarget.x = panel_pos.x - mySize.x;
 263                         else // push it upwards
 264                                 myTarget.y = panel_pos.y - mySize.y;
 265                 }
 266                 else if(myCenter.x > targCenter.x && myCenter.y < targCenter.y) // top right
 267                 {
 268                         if(panel_pos.x + panel_size.x - myPos.x < myPos.y + mySize.y - panel_pos.y) // push it to the side
 269                                 myTarget.x = panel_pos.x + panel_size.x;
 270                         else // push it upwards
 271                                 myTarget.y = panel_pos.y - mySize.y;
 272                 }
 273                 else if(myCenter.x < targCenter.x && myCenter.y > targCenter.y) // bottom left
 274                 {
 275                         if(myPos.x + mySize.x - panel_pos.x < panel_pos.y + panel_size.y - myPos.y) // push it to the side
 276                                 myTarget.x = panel_pos.x - mySize.x;
 277                         else // push it downwards
 278                                 myTarget.y = panel_pos.y + panel_size.y;
 279                 }
 280                 else if(myCenter.x > targCenter.x && myCenter.y > targCenter.y) // bottom right
 281                 {
 282                         if(panel_pos.x + panel_size.x - myPos.x < panel_pos.y + panel_size.y - myPos.y) // push it to the side
 283                                 myTarget.x = panel_pos.x + panel_size.x;
 284                         else // push it downwards
 285                                 myTarget.y = panel_pos.y + panel_size.y;
 286                 }
 287                 //if(cvar("hud_configure_checkcollisions_debug"))
 288                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 289         }
 290
 291         return myTarget;
 292 }
 293
 294 void HUD_Panel_SetPos(vector pos)
 295 {
 296         panel = highlightedPanel;
 297         HUD_Panel_UpdatePosSize();
 298         vector mySize;
 299         mySize = panel_size;
 300
 301         //if(cvar("hud_configure_checkcollisions_debug"))
 302                 //drawfill(pos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 303
 304         if(autocvar_hud_configure_grid)
 305         {
 306                 pos.x = floor((pos.x/vid_conwidth)/hud_configure_gridSize.x + 0.5) * hud_configure_realGridSize.x;
 307                 pos.y = floor((pos.y/vid_conheight)/hud_configure_gridSize.y + 0.5) * hud_configure_realGridSize.y;
 308         }
 309
 310         if(hud_configure_checkcollisions)
 311                 pos = HUD_Panel_CheckMove(pos, mySize);
 312
 313         pos.x = bound(0, pos.x, vid_conwidth - mySize.x);
 314         pos.y = bound(0, pos.y, vid_conheight - mySize.y);
 315
 316         string s;
 317         s = strcat(ftos(pos.x/vid_conwidth), " ", ftos(pos.y/vid_conheight));
 318
 319         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_pos"), s);
 320 }
 321
 322 // check if resize will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 323 vector HUD_Panel_CheckResize(vector mySize, vector resizeorigin) {
 324         vector targEndPos;
 325         vector dist;
 326         float ratio = mySize.x/mySize.y;
 327         int i;
 328         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 329                 panel = hud_panel[i];
 330                 if(panel == HUD_PANEL(MAPVOTE)) continue;
 331                 if(panel == highlightedPanel) continue;
 332                 HUD_Panel_UpdatePosSize();
 333                 if(!panel_enabled) continue;
 334
 335                 panel_pos -= '1 1 0' * panel_bg_border;
 336                 panel_size += '2 2 0' * panel_bg_border;
 337
 338                 targEndPos = panel_pos + panel_size;
 339
 340                 // resizeorigin is WITHIN target panel, just abort any collision testing against that particular panel to produce expected behaviour!
 341                 if(resizeorigin.x > panel_pos.x && resizeorigin.x < targEndPos.x && resizeorigin.y > panel_pos.y && resizeorigin.y < targEndPos.y)
 342                         continue;
 343
 344                 if (resizeCorner == 1)
 345                 {
 346                         // check if this panel is on our way
 347                         if (resizeorigin.x <= panel_pos.x)
 348                                 continue;
 349                         if (resizeorigin.y <= panel_pos.y)
 350                                 continue;
 351                         if (targEndPos.x <= resizeorigin.x - mySize.x)
 352                                 continue;
 353                         if (targEndPos.y <= resizeorigin.y - mySize.y)
 354                                 continue;
 355
 356                         // there is a collision:
 357                         // detect which side of the panel we are facing is actually limiting the resizing
 358                         // (which side the resize direction finds for first) and reduce the size up to there
 359                         //
 360                         // dist is the distance between resizeorigin and the "analogous" point of the panel
 361                         // in this case between resizeorigin (bottom-right point) and the bottom-right point of the panel
 362                         dist.x = resizeorigin.x - targEndPos.x;
 363                         dist.y = resizeorigin.y - targEndPos.y;
 364                         if (dist.y <= 0 || dist.x / dist.y > ratio)
 365                                 mySize.x = min(mySize.x, dist.x);
 366                         else
 367                                 mySize.y = min(mySize.y, dist.y);
 368                 }
 369                 else if (resizeCorner == 2)
 370                 {
 371                         if (resizeorigin.x >= targEndPos.x)
 372                                 continue;
 373                         if (resizeorigin.y <= panel_pos.y)
 374                                 continue;
 375                         if (panel_pos.x >= resizeorigin.x + mySize.x)
 376                                 continue;
 377                         if (targEndPos.y <= resizeorigin.y - mySize.y)
 378                                 continue;
 379
 380                         dist.x = panel_pos.x - resizeorigin.x;
 381                         dist.y = resizeorigin.y - targEndPos.y;
 382                         if (dist.y <= 0 || dist.x / dist.y > ratio)
 383                                 mySize.x = min(mySize.x, dist.x);
 384                         else
 385                                 mySize.y = min(mySize.y, dist.y);
 386                 }
 387                 else if (resizeCorner == 3)
 388                 {
 389                         if (resizeorigin.x <= panel_pos.x)
 390                                 continue;
 391                         if (resizeorigin.y >= targEndPos.y)
 392                                 continue;
 393                         if (targEndPos.x <= resizeorigin.x - mySize.x)
 394                                 continue;
 395                         if (panel_pos.y >= resizeorigin.y + mySize.y)
 396                                 continue;
 397
 398                         dist.x = resizeorigin.x - targEndPos.x;
 399                         dist.y = panel_pos.y - resizeorigin.y;
 400                         if (dist.y <= 0 || dist.x / dist.y > ratio)
 401                                 mySize.x = min(mySize.x, dist.x);
 402                         else
 403                                 mySize.y = min(mySize.y, dist.y);
 404                 }
 405                 else if (resizeCorner == 4)
 406                 {
 407                         if (resizeorigin.x >= targEndPos.x)
 408                                 continue;
 409                         if (resizeorigin.y >= targEndPos.y)
 410                                 continue;
 411                         if (panel_pos.x >= resizeorigin.x + mySize.x)
 412                                 continue;
 413                         if (panel_pos.y >= resizeorigin.y + mySize.y)
 414                                 continue;
 415
 416                         dist.x = panel_pos.x - resizeorigin.x;
 417                         dist.y = panel_pos.y - resizeorigin.y;
 418                         if (dist.y <= 0 || dist.x / dist.y > ratio)
 419                                 mySize.x = min(mySize.x, dist.x);
 420                         else
 421                                 mySize.y = min(mySize.y, dist.y);
 422                 }
 423                 //if(cvar("hud_configure_checkcollisions_debug"))
 424                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 425         }
 426
 427         return mySize;
 428 }
 429
 430 void HUD_Panel_SetPosSize(vector mySize)
 431 {
 432         panel = highlightedPanel;
 433         HUD_Panel_UpdatePosSize();
 434         vector resizeorigin = panel_click_resizeorigin;
 435         vector myPos;
 436
 437         // minimum panel size cap
 438         mySize.x = max(0.025 * vid_conwidth, mySize.x);
 439         mySize.y = max(0.025 * vid_conheight, mySize.y);
 440
 441         if(highlightedPanel == HUD_PANEL(CHAT)) // some panels have their own restrictions, like the chat panel (which actually only moves the engine chat print around). Looks bad if it's too small.
 442         {
 443                 mySize.x = max(17 * autocvar_con_chatsize, mySize.x);
 444                 mySize.y = max(2 * autocvar_con_chatsize + 2 * panel_bg_padding, mySize.y);
 445         }
 446
 447         // collision testing|
 448         // -----------------+
 449
 450         // we need to know pos at this stage, but it might still change later if we hit a screen edge/other panel (?)
 451         if(resizeCorner == 1) {
 452                 myPos.x = resizeorigin.x - mySize.x;
 453                 myPos.y = resizeorigin.y - mySize.y;
 454         } else if(resizeCorner == 2) {
 455                 myPos.x = resizeorigin.x;
 456                 myPos.y = resizeorigin.y - mySize.y;
 457         } else if(resizeCorner == 3) {
 458                 myPos.x = resizeorigin.x - mySize.x;
 459                 myPos.y = resizeorigin.y;
 460         } else { // resizeCorner == 4
 461                 myPos.x = resizeorigin.x;
 462                 myPos.y = resizeorigin.y;
 463         }
 464
 465         // left/top screen edges
 466         if(myPos.x < 0)
 467                 mySize.x = mySize.x + myPos.x;
 468         if(myPos.y < 0)
 469                 mySize.y = mySize.y + myPos.y;
 470
 471         // bottom/right screen edges
 472         if(myPos.x + mySize.x > vid_conwidth)
 473                 mySize.x = vid_conwidth - myPos.x;
 474         if(myPos.y + mySize.y > vid_conheight)
 475                 mySize.y = vid_conheight - myPos.y;
 476
 477         //if(cvar("hud_configure_checkcollisions_debug"))
 478                 //drawfill(myPos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 479
 480         // before checkresize, otherwise panel can be snapped partially inside another panel or panel aspect ratio can be broken
 481         if(autocvar_hud_configure_grid)
 482         {
 483                 mySize.x = floor((mySize.x/vid_conwidth)/hud_configure_gridSize.x + 0.5) * hud_configure_realGridSize.x;
 484                 mySize.y = floor((mySize.y/vid_conheight)/hud_configure_gridSize.y + 0.5) * hud_configure_realGridSize.y;
 485         }
 486
 487         if(hud_configure_checkcollisions)
 488                 mySize = HUD_Panel_CheckResize(mySize, resizeorigin);
 489
 490         // minimum panel size cap, do this once more so we NEVER EVER EVER have a panel smaller than this, JUST IN CASE above code still makes the panel eg negative (impossible to resize back without changing cvars manually then)
 491         mySize.x = max(0.025 * vid_conwidth, mySize.x);
 492         mySize.y = max(0.025 * vid_conheight, mySize.y);
 493
 494         // do another pos check, as size might have changed by now
 495         if(resizeCorner == 1) {
 496                 myPos.x = resizeorigin.x - mySize.x;
 497                 myPos.y = resizeorigin.y - mySize.y;
 498         } else if(resizeCorner == 2) {
 499                 myPos.x = resizeorigin.x;
 500                 myPos.y = resizeorigin.y - mySize.y;
 501         } else if(resizeCorner == 3) {
 502                 myPos.x = resizeorigin.x - mySize.x;
 503                 myPos.y = resizeorigin.y;
 504         } else { // resizeCorner == 4
 505                 myPos.x = resizeorigin.x;
 506                 myPos.y = resizeorigin.y;
 507         }
 508
 509         //if(cvar("hud_configure_checkcollisions_debug"))
 510                 //drawfill(myPos, mySize, '0 1 0', .3, DRAWFLAG_NORMAL);
 511
 512         string s;
 513         s = strcat(ftos(mySize.x/vid_conwidth), " ", ftos(mySize.y/vid_conheight));
 514         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_size"), s);
 515
 516         s = strcat(ftos(myPos.x/vid_conwidth), " ", ftos(myPos.y/vid_conheight));
 517         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_pos"), s);
 518 }
 519
 520 float pressed_key_time;
 521 vector highlightedPanel_initial_pos, highlightedPanel_initial_size;
 522 void HUD_Panel_Arrow_Action(float nPrimary)
 523 {
 524         if(!highlightedPanel)
 525                 return;
 526
 527         hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
 528
 529         float step;
 530         if(autocvar_hud_configure_grid)
 531         {
 532                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 533                 {
 534                         if (hudShiftState & S_SHIFT)
 535                                 step = hud_configure_realGridSize.y;
 536                         else
 537                                 step = 2 * hud_configure_realGridSize.y;
 538                 }
 539                 else
 540                 {
 541                         if (hudShiftState & S_SHIFT)
 542                                 step = hud_configure_realGridSize.x;
 543                         else
 544                                 step = 2 * hud_configure_realGridSize.x;
 545                 }
 546         }
 547         else
 548         {
 549                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 550                         step = vid_conheight;
 551                 else
 552                         step = vid_conwidth;
 553                 if (hudShiftState & S_SHIFT)
 554                         step = (step / 256); // more precision
 555                 else
 556                         step = (step / 64) * (1 + 2 * (time - pressed_key_time));
 557         }
 558
 559         panel = highlightedPanel;
 560         HUD_Panel_UpdatePosSize();
 561
 562         highlightedPanel_initial_pos = panel_pos;
 563         highlightedPanel_initial_size = panel_size;
 564
 565         if (hudShiftState & S_ALT) // resize
 566         {
 567                 if(nPrimary == K_UPARROW)
 568                         resizeCorner = 1;
 569                 else if(nPrimary == K_RIGHTARROW)
 570                         resizeCorner = 2;
 571                 else if(nPrimary == K_LEFTARROW)
 572                         resizeCorner = 3;
 573                 else // if(nPrimary == K_DOWNARROW)
 574                         resizeCorner = 4;
 575
 576                 // ctrl+arrow reduces the size, instead of increasing it
 577                 // Note that ctrl disables collisions check too, but it's fine
 578                 // since we don't collide with anything reducing the size
 579                 if (hudShiftState & S_CTRL) {
 580                         step = -step;
 581                         resizeCorner = 5 - resizeCorner;
 582                 }
 583
 584                 vector mySize;
 585                 mySize = panel_size;
 586                 panel_click_resizeorigin = panel_pos;
 587                 if(resizeCorner == 1) {
 588                         panel_click_resizeorigin += mySize;
 589                         mySize.y += step;
 590                 } else if(resizeCorner == 2) {
 591                         panel_click_resizeorigin.y += mySize.y;
 592                         mySize.x += step;
 593                 } else if(resizeCorner == 3) {
 594                         panel_click_resizeorigin.x += mySize.x;
 595                         mySize.x += step;
 596                 } else { // resizeCorner == 4
 597                         mySize.y += step;
 598                 }
 599                 HUD_Panel_SetPosSize(mySize);
 600         }
 601         else // move
 602         {
 603                 vector pos;
 604                 pos = panel_pos;
 605                 if(nPrimary == K_UPARROW)
 606                         pos.y -= step;
 607                 else if(nPrimary == K_DOWNARROW)
 608                         pos.y += step;
 609                 else if(nPrimary == K_LEFTARROW)
 610                         pos.x -= step;
 611                 else // if(nPrimary == K_RIGHTARROW)
 612                         pos.x += step;
 613
 614                 HUD_Panel_SetPos(pos);
 615         }
 616
 617         panel = highlightedPanel;
 618         HUD_Panel_UpdatePosSize();
 619
 620         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
 621         {
 622                 // backup!
 623                 panel_pos_backup = highlightedPanel_initial_pos;
 624                 panel_size_backup = highlightedPanel_initial_size;
 625                 highlightedPanel_backup = highlightedPanel;
 626         }
 627 }
 628
 629 const int S_MOUSE1 = 1;
 630 const int S_MOUSE2 = 2;
 631 const int S_MOUSE3 = 4;
 632 int mouseClicked;
 633 int prevMouseClicked; // previous state
 634 float prevMouseClickedTime; // time during previous left mouse click, to check for doubleclicks
 635 vector prevMouseClickedPos; // pos during previous left mouse click, to check for doubleclicks
 636
 637 void HUD_Panel_EnableMenu();
 638 entity tab_panels[HUD_PANEL_MAX];
 639 entity tab_panel;
 640 vector tab_panel_pos;
 641 float tab_backward;
 642 void HUD_Panel_FirstInDrawQ(float id);
 643 void reset_tab_panels()
 644 {
 645         int i;
 646         for(i = 0; i < HUD_PANEL_NUM; ++i)
 647                 tab_panels[i] = world;
 648 }
 649 float HUD_Panel_InputEvent(float bInputType, float nPrimary, float nSecondary)
 650 {
 651         string s;
 652
 653         if(bInputType == 2)
 654                 return false;
 655
 656         if(!autocvar__hud_configure)
 657                 return false;
 658
 659         if(bInputType == 3)
 660         {
 661                 mousepos.x = nPrimary;
 662                 mousepos.y = nSecondary;
 663                 return true;
 664         }
 665
 666         // block any input while a menu dialog is fading
 667         // don't block mousepos read as it leads to cursor jumps in the interaction with the menu
 668         if(autocvar__menu_alpha)
 669         {
 670                 hudShiftState = 0;
 671                 mouseClicked = 0;
 672                 return true;
 673         }
 674
 675         // allow console bind to work
 676         string con_keys;
 677         float keys;
 678         con_keys = findkeysforcommand("toggleconsole", 0);
 679         keys = tokenize(con_keys); // findkeysforcommand returns data for this
 680
 681         bool hit_con_bind = false;
 682         int i;
 683         for (i = 0; i < keys; ++i)
 684         {
 685                 if(nPrimary == stof(argv(i)))
 686                         hit_con_bind = true;
 687         }
 688
 689         if(bInputType == 0) {
 690                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 691                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 692                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 693         }
 694         else if(bInputType == 1) {
 695                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 696                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 697                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 698         }
 699
 700         if(nPrimary == K_CTRL)
 701         {
 702                 if (bInputType == 1) //ctrl has been released
 703                 {
 704                         if (tab_panel)
 705                         {
 706                                 //switch to selected panel
 707                                 highlightedPanel = tab_panel;
 708                                 highlightedAction = 0;
 709                                 HUD_Panel_FirstInDrawQ(highlightedPanel.panel_id);
 710                         }
 711                         tab_panel = world;
 712                         reset_tab_panels();
 713                 }
 714         }
 715
 716         if(nPrimary == K_MOUSE1)
 717         {
 718                 if(bInputType == 0) // key pressed
 719                         mouseClicked |= S_MOUSE1;
 720                 else if(bInputType == 1) // key released
 721                         mouseClicked -= (mouseClicked & S_MOUSE1);
 722         }
 723         else if(nPrimary == K_MOUSE2)
 724         {
 725                 if(bInputType == 0) // key pressed
 726                         mouseClicked |= S_MOUSE2;
 727                 else if(bInputType == 1) // key released
 728                         mouseClicked -= (mouseClicked & S_MOUSE2);
 729         }
 730         else if(nPrimary == K_ESCAPE)
 731         {
 732                 if (bInputType == 1)
 733                         return true;
 734                 menu_enabled = 1;
 735                 localcmd("menu_showhudexit\n");
 736         }
 737         else if(nPrimary == K_BACKSPACE && hudShiftState & S_CTRL)
 738         {
 739                 if (bInputType == 1)
 740                         return true;
 741                 if (!menu_enabled)
 742                         cvar_set("_hud_configure", "0");
 743         }
 744         else if(nPrimary == K_TAB && hudShiftState & S_CTRL) // switch panel
 745         {
 746                 if (bInputType == 1 || mouseClicked)
 747                         return true;
 748
 749                 // FIXME minor bug: if a panel is highlighted, has the same pos_x and
 750                 // lays in the same level of another panel then the next consecutive
 751                 // CTRL TAB presses will reselect once more the highlighted panel
 752
 753                 entity starting_panel;
 754                 entity old_tab_panel = tab_panel;
 755                 if (!tab_panel) //first press of TAB
 756                 {
 757                         if (highlightedPanel)
 758                         {
 759                                 panel = highlightedPanel;
 760                                 HUD_Panel_UpdatePosSize();
 761                         }
 762                         else
 763                                 panel_pos = '0 0 0';
 764                         starting_panel = highlightedPanel;
 765                         tab_panel_pos = panel_pos; //to compute level
 766                 }
 767                 else
 768                 {
 769                         if ( ((!tab_backward) && (hudShiftState & S_SHIFT)) || (tab_backward && !(hudShiftState & S_SHIFT)) ) //tab direction changed?
 770                                 reset_tab_panels();
 771                         starting_panel = tab_panel;
 772                 }
 773                 tab_backward = (hudShiftState & S_SHIFT);
 774
 775                 float k, level = 0, start_posX;
 776                 vector candidate_pos = '0 0 0';
 777                 const float LEVELS_NUM = 4;
 778                 float level_height = vid_conheight / LEVELS_NUM;
 779 :find_tab_panel
 780                 level = floor(tab_panel_pos.y / level_height) * level_height; //starting level
 781                 candidate_pos.x = (!tab_backward) ? vid_conwidth : 0;
 782                 start_posX = tab_panel_pos.x;
 783                 tab_panel = world;
 784                 k=0;
 785                 while(++k)
 786                 {
 787                         for(i = 0; i < HUD_PANEL_NUM; ++i)
 788                         {
 789                                 panel = hud_panel[i];
 790                                 if(panel == HUD_PANEL(MAPVOTE))
 791                                         continue;
 792                                 if (panel == tab_panels[i] || panel == starting_panel)
 793                                         continue;
 794                                 HUD_Panel_UpdatePosSize();
 795                                 if (panel_pos.y >= level && (panel_pos.y - level) < level_height)
 796                                 if (  ( !tab_backward && panel_pos.x >= start_posX && (panel_pos.x < candidate_pos.x || (panel_pos.x == candidate_pos.x && panel_pos.y <= candidate_pos.y)) )
 797                                         || ( tab_backward && panel_pos.x <= start_posX && (panel_pos.x > candidate_pos.x || (panel_pos.x == candidate_pos.x && panel_pos.y >= candidate_pos.y)) )  )
 798                                 {
 799                                         tab_panel = panel;
 800                                         tab_panel_pos = candidate_pos = panel_pos;
 801                                 }
 802                         }
 803                         if (tab_panel)
 804                                 break;
 805                         if (k == LEVELS_NUM) //tab_panel not found
 806                         {
 807                                 reset_tab_panels();
 808                                 if (!old_tab_panel)
 809                                 {
 810                                         tab_panel = world;
 811                                         return true;
 812                                 }
 813                                 starting_panel = old_tab_panel;
 814                                 old_tab_panel = world;
 815                                 goto find_tab_panel; //u must find tab_panel!
 816                         }
 817                         if (!tab_backward)
 818                         {
 819                                 level = (level + level_height) % vid_conheight;
 820                                 start_posX = 0;
 821                                 candidate_pos.x = vid_conwidth;
 822                         }
 823                         else
 824                         {
 825                                 level = (level - level_height) % vid_conheight;
 826                                 start_posX = vid_conwidth;
 827                                 candidate_pos.x = 0;
 828                         }
 829                 }
 830
 831                 tab_panels[tab_panel.panel_id] = tab_panel;
 832         }
 833         else if(nPrimary == K_SPACE && hudShiftState & S_CTRL) // enable/disable highlighted panel or dock
 834         {
 835                 if (bInputType == 1 || mouseClicked)
 836                         return true;
 837
 838                 if (highlightedPanel)
 839                         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name), ftos(!cvar(strcat("hud_panel_", highlightedPanel.panel_name))));
 840                 else
 841                         cvar_set(strcat("hud_dock"), (autocvar_hud_dock == "") ? "dock" : "");
 842         }
 843         else if(nPrimary == 'c' && hudShiftState & S_CTRL) // copy highlighted panel size
 844         {
 845                 if (bInputType == 1 || mouseClicked)
 846                         return true;
 847
 848                 if (highlightedPanel)
 849                 {
 850                         panel = highlightedPanel;
 851                         HUD_Panel_UpdatePosSize();
 852                         panel_size_copied = panel_size;
 853                 }
 854         }
 855         else if(nPrimary == 'v' && hudShiftState & S_CTRL) // past copied size on the highlighted panel
 856         {
 857                 if (bInputType == 1 || mouseClicked)
 858                         return true;
 859
 860                 if (panel_size_copied == '0 0 0' || !highlightedPanel)
 861                         return true;
 862
 863                 panel = highlightedPanel;
 864                 HUD_Panel_UpdatePosSize();
 865
 866                 // reduce size if it'd go beyond screen boundaries
 867                 vector tmp_size = panel_size_copied;
 868                 if (panel_pos.x + panel_size_copied.x > vid_conwidth)
 869                         tmp_size.x = vid_conwidth - panel_pos.x;
 870                 if (panel_pos.y + panel_size_copied.y > vid_conheight)
 871                         tmp_size.y = vid_conheight - panel_pos.y;
 872
 873                 if (panel_size == tmp_size)
 874                         return true;
 875
 876                 // backup first!
 877                 panel_pos_backup = panel_pos;
 878                 panel_size_backup = panel_size;
 879                 highlightedPanel_backup = highlightedPanel;
 880
 881                 s = strcat(ftos(tmp_size.x/vid_conwidth), " ", ftos(tmp_size.y/vid_conheight));
 882                 cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_size"), s);
 883         }
 884         else if(nPrimary == 'z' && hudShiftState & S_CTRL) // undo last action
 885         {
 886                 if (bInputType == 1 || mouseClicked)
 887                         return true;
 888                 //restore previous values
 889                 if (highlightedPanel_backup)
 890                 {
 891                         s = strcat(ftos(panel_pos_backup.x/vid_conwidth), " ", ftos(panel_pos_backup.y/vid_conheight));
 892                         cvar_set(strcat("hud_panel_", highlightedPanel_backup.panel_name, "_pos"), s);
 893                         s = strcat(ftos(panel_size_backup.x/vid_conwidth), " ", ftos(panel_size_backup.y/vid_conheight));
 894                         cvar_set(strcat("hud_panel_", highlightedPanel_backup.panel_name, "_size"), s);
 895                         highlightedPanel_backup = world;
 896                 }
 897         }
 898         else if(nPrimary == 's' && hudShiftState & S_CTRL) // save config
 899         {
 900                 if (bInputType == 1 || mouseClicked)
 901                         return true;
 902                 localcmd("hud save myconfig\n");
 903         }
 904         else if(nPrimary == K_UPARROW || nPrimary == K_DOWNARROW || nPrimary == K_LEFTARROW || nPrimary == K_RIGHTARROW)
 905         {
 906                 if (bInputType == 1)
 907                 {
 908                         pressed_key_time = 0;
 909                         return true;
 910                 }
 911                 else if (pressed_key_time == 0)
 912                         pressed_key_time = time;
 913
 914                 if (!mouseClicked)
 915                         HUD_Panel_Arrow_Action(nPrimary); //move or resize panel
 916         }
 917         else if(nPrimary == K_ENTER || nPrimary == K_SPACE || nPrimary == K_KP_ENTER)
 918         {
 919                 if (bInputType == 1)
 920                         return true;
 921                 if (highlightedPanel)
 922                         HUD_Panel_EnableMenu();
 923         }
 924         else if(hit_con_bind || nPrimary == K_PAUSE)
 925                 return false;
 926
 927         return true;
 928 }
 929
 930 float HUD_Panel_Check_Mouse_Pos(float allow_move)
 931 {
 932         int i, j = 0;
 933         while(j < HUD_PANEL_NUM)
 934         {
 935                 i = panel_order[j];
 936                 j += 1;
 937
 938                 panel = hud_panel[i];
 939                 if(panel == HUD_PANEL(MAPVOTE)) continue;
 940                 HUD_Panel_UpdatePosSize();
 941
 942                 float border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 943
 944                 // move
 945                 if(allow_move && mousepos.x > panel_pos.x && mousepos.y > panel_pos.y && mousepos.x < panel_pos.x + panel_size.x && mousepos.y < panel_pos.y + panel_size.y)
 946                 {
 947                         return 1;
 948                 }
 949                 // resize from topleft border
 950                 else if(mousepos.x >= panel_pos.x - border && mousepos.y >= panel_pos.y - border && mousepos.x <= panel_pos.x + 0.5 * panel_size.x && mousepos.y <= panel_pos.y + 0.5 * panel_size.y)
 951                 {
 952                         return 2;
 953                 }
 954                 // resize from topright border
 955                 else if(mousepos.x >= panel_pos.x + 0.5 * panel_size.x && mousepos.y >= panel_pos.y - border && mousepos.x <= panel_pos.x + panel_size.x + border && mousepos.y <= panel_pos.y + 0.5 * panel_size.y)
 956                 {
 957                         return 3;
 958                 }
 959                 // resize from bottomleft border
 960                 else if(mousepos.x >= panel_pos.x - border && mousepos.y >= panel_pos.y + 0.5 * panel_size.y && mousepos.x <= panel_pos.x + 0.5 * panel_size.x && mousepos.y <= panel_pos.y + panel_size.y + border)
 961                 {
 962                         return 3;
 963                 }
 964                 // resize from bottomright border
 965                 else if(mousepos.x >= panel_pos.x + 0.5 * panel_size.x && mousepos.y >= panel_pos.y + 0.5 * panel_size.y && mousepos.x <= panel_pos.x + panel_size.x + border && mousepos.y <= panel_pos.y + panel_size.y + border)
 966                 {
 967                         return 2;
 968                 }
 969         }
 970         return 0;
 971 }
 972
 973 // move a panel to the beginning of the panel order array (which means it gets drawn last, on top of everything else)
 974 void HUD_Panel_FirstInDrawQ(float id)
 975 {
 976         int i;
 977         int place = -1;
 978         // find out where in the array our current id is, save into place
 979         for(i = 0; i < HUD_PANEL_NUM; ++i)
 980         {
 981                 if(panel_order[i] == id)
 982                 {
 983                         place = i;
 984                         break;
 985                 }
 986         }
 987         // place last if we didn't find a place for it yet (probably new panel, or screwed up cvar)
 988         if(place == -1)
 989                 place = HUD_PANEL_NUM - 1;
 990
 991         // move all ids up by one step in the array until "place"
 992         for(i = place; i > 0; --i)
 993         {
 994                 panel_order[i] = panel_order[i-1];
 995         }
 996         // now save the new top id
 997         panel_order[0] = id;
 998
 999         // let's save them into the cvar by some strcat trickery
1000         string s = "";
1001         for(i = 0; i < HUD_PANEL_NUM; ++i)
1002         {
1003                 s = strcat(s, ftos(panel_order[i]), " ");
1004         }
1005         cvar_set("_hud_panelorder", s);
1006         if(hud_panelorder_prev)
1007                 strunzone(hud_panelorder_prev);
1008         hud_panelorder_prev = strzone(autocvar__hud_panelorder); // prevent HUD_Main from doing useless update, we already updated here
1009 }
1010
1011 void HUD_Panel_Highlight(float allow_move)
1012 {
1013         int i, j = 0;
1014
1015         while(j < HUD_PANEL_NUM)
1016         {
1017                 i = panel_order[j];
1018                 j += 1;
1019
1020                 panel = hud_panel[i];
1021                 if(panel == HUD_PANEL(MAPVOTE))
1022                         continue;
1023                 HUD_Panel_UpdatePosSize();
1024
1025                 float border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
1026
1027                 // move
1028                 if(allow_move && mousepos.x > panel_pos.x && mousepos.y > panel_pos.y && mousepos.x < panel_pos.x + panel_size.x && mousepos.y < panel_pos.y + panel_size.y)
1029                 {
1030                         highlightedPanel = hud_panel[i];
1031                         HUD_Panel_FirstInDrawQ(i);
1032                         highlightedAction = 1;
1033                         panel_click_distance = mousepos - panel_pos;
1034                         return;
1035                 }
1036                 // resize from topleft border
1037                 else if(mousepos.x >= panel_pos.x - border && mousepos.y >= panel_pos.y - border && mousepos.x <= panel_pos.x + 0.5 * panel_size.x && mousepos.y <= panel_pos.y + 0.5 * panel_size.y)
1038                 {
1039                         highlightedPanel = hud_panel[i];
1040                         HUD_Panel_FirstInDrawQ(i);
1041                         highlightedAction = 2;
1042                         resizeCorner = 1;
1043                         panel_click_distance = mousepos - panel_pos;
1044                         panel_click_resizeorigin = panel_pos + panel_size;
1045                         return;
1046                 }
1047                 // resize from topright border
1048                 else if(mousepos.x >= panel_pos.x + 0.5 * panel_size.x && mousepos.y >= panel_pos.y - border && mousepos.x <= panel_pos.x + panel_size.x + border && mousepos.y <= panel_pos.y + 0.5 * panel_size.y)
1049                 {
1050                         highlightedPanel = hud_panel[i];
1051                         HUD_Panel_FirstInDrawQ(i);
1052                         highlightedAction = 2;
1053                         resizeCorner = 2;
1054                         panel_click_distance.x = panel_size.x - mousepos.x + panel_pos.x;
1055                         panel_click_distance.y = mousepos.y - panel_pos.y;
1056                         panel_click_resizeorigin = panel_pos + eY * panel_size.y;
1057                         return;
1058                 }
1059                 // resize from bottomleft border
1060                 else if(mousepos.x >= panel_pos.x - border && mousepos.y >= panel_pos.y + 0.5 * panel_size.y && mousepos.x <= panel_pos.x + 0.5 * panel_size.x && mousepos.y <= panel_pos.y + panel_size.y + border)
1061                 {
1062                         highlightedPanel = hud_panel[i];
1063                         HUD_Panel_FirstInDrawQ(i);
1064                         highlightedAction = 2;
1065                         resizeCorner = 3;
1066                         panel_click_distance.x = mousepos.x - panel_pos.x;
1067                         panel_click_distance.y = panel_size.y - mousepos.y + panel_pos.y;
1068                         panel_click_resizeorigin = panel_pos + eX * panel_size.x;
1069                         return;
1070                 }
1071                 // resize from bottomright border
1072                 else if(mousepos.x >= panel_pos.x + 0.5 * panel_size.x && mousepos.y >= panel_pos.y + 0.5 * panel_size.y && mousepos.x <= panel_pos.x + panel_size.x + border && mousepos.y <= panel_pos.y + panel_size.y + border)
1073                 {
1074                         highlightedPanel = hud_panel[i];
1075                         HUD_Panel_FirstInDrawQ(i);
1076                         highlightedAction = 2;
1077                         resizeCorner = 4;
1078                         panel_click_distance = panel_size - mousepos + panel_pos;
1079                         panel_click_resizeorigin = panel_pos;
1080                         return;
1081                 }
1082         }
1083         highlightedPanel = world;
1084         highlightedAction = 0;
1085 }
1086
1087 void HUD_Panel_EnableMenu()
1088 {
1089         menu_enabled = 2;
1090         localcmd("menu_showhudoptions ", highlightedPanel.panel_name, "\n");
1091 }
1092 float mouse_over_panel;
1093 void HUD_Panel_Mouse()
1094 {
1095         if(autocvar__menu_alpha == 1)
1096                 return;
1097
1098         if (!autocvar_hud_cursormode)
1099         {
1100                 mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
1101
1102                 mousepos.x = bound(0, mousepos.x, vid_conwidth);
1103                 mousepos.y = bound(0, mousepos.y, vid_conheight);
1104         }
1105
1106         if(mouseClicked)
1107         {
1108                 if(prevMouseClicked == 0)
1109                 {
1110                         if (tab_panel)
1111                         {
1112                                 //stop ctrl-tab selection
1113                                 tab_panel = world;
1114                                 reset_tab_panels();
1115                         }
1116                         HUD_Panel_Highlight(mouseClicked & S_MOUSE1); // sets highlightedPanel, highlightedAction, panel_click_distance, panel_click_resizeorigin
1117                                                                         // and calls HUD_Panel_UpdatePosSize() for the highlighted panel
1118                         if (highlightedPanel)
1119                         {
1120                                 highlightedPanel_initial_pos = panel_pos;
1121                                 highlightedPanel_initial_size = panel_size;
1122                         }
1123                         // doubleclick check
1124                         if ((mouseClicked & S_MOUSE1) && time - prevMouseClickedTime < 0.4 && highlightedPanel && prevMouseClickedPos == mousepos)
1125                         {
1126                                 mouseClicked = 0; // to prevent spam, I guess.
1127                                 HUD_Panel_EnableMenu();
1128                         }
1129                         else
1130                         {
1131                                 if (mouseClicked & S_MOUSE1)
1132                                 {
1133                                         prevMouseClickedTime = time;
1134                                         prevMouseClickedPos = mousepos;
1135                                 }
1136                                 mouse_over_panel = HUD_Panel_Check_Mouse_Pos(mouseClicked & S_MOUSE1);
1137                         }
1138                 }
1139                 else
1140                 {
1141                         panel = highlightedPanel;
1142                         HUD_Panel_UpdatePosSize();
1143                 }
1144
1145                 if (highlightedPanel)
1146                 {
1147                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1148                         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
1149                         {
1150                                 hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
1151                                 // backup!
1152                                 panel_pos_backup = highlightedPanel_initial_pos;
1153                                 panel_size_backup = highlightedPanel_initial_size;
1154                                 highlightedPanel_backup = highlightedPanel;
1155                         }
1156                         else
1157                                 // in case the clicked panel is inside another panel and we aren't
1158                                 // moving it, avoid the immediate "fix" of its position/size
1159                                 // (often unwanted and hateful) by disabling collisions check
1160                                 hud_configure_checkcollisions = false;
1161                 }
1162
1163                 if(highlightedAction == 1)
1164                         HUD_Panel_SetPos(mousepos - panel_click_distance);
1165                 else if(highlightedAction == 2)
1166                 {
1167                         vector mySize = '0 0 0';
1168                         if(resizeCorner == 1) {
1169                                 mySize.x = panel_click_resizeorigin.x - (mousepos.x - panel_click_distance.x);
1170                                 mySize.y = panel_click_resizeorigin.y - (mousepos.y - panel_click_distance.y);
1171                         } else if(resizeCorner == 2) {
1172                                 mySize.x = mousepos.x + panel_click_distance.x - panel_click_resizeorigin.x;
1173                                 mySize.y = panel_click_distance.y + panel_click_resizeorigin.y - mousepos.y;
1174                         } else if(resizeCorner == 3) {
1175                                 mySize.x = panel_click_resizeorigin.x + panel_click_distance.x - mousepos.x;
1176                                 mySize.y = mousepos.y + panel_click_distance.y - panel_click_resizeorigin.y;
1177                         } else { // resizeCorner == 4
1178                                 mySize.x = mousepos.x - (panel_click_resizeorigin.x - panel_click_distance.x);
1179                                 mySize.y = mousepos.y - (panel_click_resizeorigin.y - panel_click_distance.y);
1180                         }
1181                         HUD_Panel_SetPosSize(mySize);
1182                 }
1183         }
1184         else
1185         {
1186                 if(prevMouseClicked)
1187                         highlightedAction = 0;
1188                 if(menu_enabled == 2)
1189                         mouse_over_panel = 0;
1190                 else
1191                         mouse_over_panel = HUD_Panel_Check_Mouse_Pos(true);
1192                 if (mouse_over_panel && !tab_panel)
1193                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1194         }
1195         // draw cursor after performing move/resize to have the panel pos/size updated before mouse_over_panel
1196         const vector cursorsize = '32 32 0';
1197         float cursor_alpha = 1 - autocvar__menu_alpha;
1198
1199         if(!mouse_over_panel)
1200                 drawpic(mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1201         else if(mouse_over_panel == 1)
1202                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_move.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1203         else if(mouse_over_panel == 2)
1204                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1205         else
1206                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize2.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1207
1208         prevMouseClicked = mouseClicked;
1209 }
1210 void HUD_Configure_DrawGrid()
1211 {
1212         float i;
1213         if(autocvar_hud_configure_grid && autocvar_hud_configure_grid_alpha)
1214         {
1215                 hud_configure_gridSize.x = bound(0.005, cvar("hud_configure_grid_xsize"), 0.2);
1216                 hud_configure_gridSize.y = bound(0.005, cvar("hud_configure_grid_ysize"), 0.2);
1217                 hud_configure_realGridSize.x = hud_configure_gridSize.x * vid_conwidth;
1218                 hud_configure_realGridSize.y = hud_configure_gridSize.y * vid_conheight;
1219                 vector s;
1220                 // x-axis
1221                 s = eX + eY * vid_conheight;
1222                 for(i = 1; i < 1/hud_configure_gridSize.x; ++i)
1223                         drawfill(eX * i * hud_configure_realGridSize.x, s, '0.5 0.5 0.5', autocvar_hud_configure_grid_alpha, DRAWFLAG_NORMAL);
1224                 // y-axis
1225                 s = eY + eX * vid_conwidth;
1226                 for(i = 1; i < 1/hud_configure_gridSize.y; ++i)
1227                         drawfill(eY * i * hud_configure_realGridSize.y, s, '0.5 0.5 0.5', autocvar_hud_configure_grid_alpha, DRAWFLAG_NORMAL);
1228         }
1229 }
1230
1231 float _menu_alpha_prev;
1232 void HUD_Configure_Frame()
1233 {
1234         int i;
1235         if(autocvar__hud_configure)
1236         {
1237                 if(isdemo() || intermission == 2)
1238                 {
1239                         HUD_Configure_Exit_Force();
1240                         return;
1241                 }
1242
1243                 if(!hud_configure_prev)
1244                 {
1245                         if(autocvar_hud_cursormode)
1246                                 setcursormode(1);
1247                         hudShiftState = 0;
1248                         for(i = HUD_PANEL_NUM - 1; i >= 0; --i)
1249                                 hud_panel[panel_order[i]].update_time = time;
1250                 }
1251
1252                 // NOTE this check is necessary because _menu_alpha isn't updated the frame the menu gets enabled
1253                 if(autocvar__menu_alpha != _menu_alpha_prev)
1254                 {
1255                         if(autocvar__menu_alpha == 0)
1256                                 menu_enabled = 0;
1257                         _menu_alpha_prev = autocvar__menu_alpha;
1258                 }
1259
1260                 HUD_Configure_DrawGrid();
1261         }
1262         else if(hud_configure_prev)
1263         {
1264                 if(menu_enabled)
1265                         menu_enabled = 0;
1266                 if(autocvar_hud_cursormode)
1267                         setcursormode(0);
1268         }
1269 }
1270
1271 const float hlBorderSize = 2;
1272 const string hlBorder = "gfx/hud/default/border_highlighted";
1273 const string hlBorder2 = "gfx/hud/default/border_highlighted2";
1274 void HUD_Panel_HlBorder(float myBorder, vector color, float theAlpha)
1275 {
1276         drawfill(panel_pos - '1 1 0' * myBorder, panel_size + '2 2 0' * myBorder, '0 0.5 1', .5 * theAlpha, DRAWFLAG_NORMAL);
1277         drawpic_tiled(panel_pos - '1 1 0' * myBorder, hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size.x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1278         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * (panel_size.y + 2 * myBorder - hlBorderSize), hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size.x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1279         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize, hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size.y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1280         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize + eX * (panel_size.x + 2 * myBorder - hlBorderSize), hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size.y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1281 }
1282
1283 void HUD_Configure_PostDraw()
1284 {
1285         if(autocvar__hud_configure)
1286         {
1287                 if(tab_panel)
1288                 {
1289                         panel = tab_panel;
1290                         HUD_Panel_UpdatePosSize();
1291                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .2, DRAWFLAG_NORMAL);
1292                 }
1293                 if(highlightedPanel)
1294                 {
1295                         panel = highlightedPanel;
1296                         HUD_Panel_UpdatePosSize();
1297                         HUD_Panel_HlBorder(panel_bg_border * hlBorderSize, '0 0.5 1', 0.4 * (1 - autocvar__menu_alpha));
1298                 }
1299         }
1300 }