qcsrc/client/hud_config.qc

   1 #define HUD_Write(s) fputs(fh, s)
   2 // q: quoted, n: not quoted
   3 #define HUD_Write_Cvar_n(cvar) HUD_Write(strcat("seta ", cvar, " ", cvar_string(cvar), "\n"))
   4 #define HUD_Write_Cvar_q(cvar) HUD_Write(strcat("seta ", cvar, " \"", cvar_string(cvar), "\"\n"))
   5 #define HUD_Write_PanelCvar_n(cvar_suf) HUD_Write_Cvar_n(strcat("hud_panel_", panel.panel_name, cvar_suf))
   6 #define HUD_Write_PanelCvar_q(cvar_suf) HUD_Write_Cvar_q(strcat("hud_panel_", panel.panel_name, cvar_suf))
   7 // Save the config
   8 void HUD_Panel_ExportCfg(string cfgname)
   9 {
  10         float fh;
  11         string filename = strcat("hud_", autocvar_hud_skin, "_", cfgname, ".cfg");
  12         fh = fopen(filename, FILE_WRITE);
  13         if(fh >= 0)
  14         {
  15                 HUD_Write_Cvar_q("hud_skin");
  16                 HUD_Write_Cvar_q("hud_panel_bg");
  17                 HUD_Write_Cvar_q("hud_panel_bg_color");
  18                 HUD_Write_Cvar_q("hud_panel_bg_color_team");
  19                 HUD_Write_Cvar_q("hud_panel_bg_alpha");
  20                 HUD_Write_Cvar_q("hud_panel_bg_border");
  21                 HUD_Write_Cvar_q("hud_panel_bg_padding");
  22                 HUD_Write_Cvar_q("hud_panel_fg_alpha");
  23                 HUD_Write("\n");
  24
  25                 HUD_Write_Cvar_q("hud_dock");
  26                 HUD_Write_Cvar_q("hud_dock_color");
  27                 HUD_Write_Cvar_q("hud_dock_color_team");
  28                 HUD_Write_Cvar_q("hud_dock_alpha");
  29                 HUD_Write("\n");
  30
  31                 HUD_Write_Cvar_q("hud_progressbar_alpha");
  32                 HUD_Write_Cvar_q("hud_progressbar_strength_color");
  33                 HUD_Write_Cvar_q("hud_progressbar_shield_color");
  34                 HUD_Write_Cvar_q("hud_progressbar_health_color");
  35                 HUD_Write_Cvar_q("hud_progressbar_armor_color");
  36                 HUD_Write_Cvar_q("hud_progressbar_fuel_color");
  37                 HUD_Write_Cvar_q("hud_progressbar_nexball_color");
  38                 HUD_Write_Cvar_q("hud_progressbar_speed_color");
  39                 HUD_Write_Cvar_q("hud_progressbar_acceleration_color");
  40                 HUD_Write_Cvar_q("hud_progressbar_acceleration_neg_color");
  41                 HUD_Write("\n");
  42
  43                 HUD_Write_Cvar_q("_hud_panelorder");
  44                 HUD_Write("\n");
  45
  46                 HUD_Write_Cvar_q("hud_configure_grid");
  47                 HUD_Write_Cvar_q("hud_configure_grid_xsize");
  48                 HUD_Write_Cvar_q("hud_configure_grid_ysize");
  49                 HUD_Write("\n");
  50
  51                 // common cvars for all panels
  52                 float i;
  53                 for (i = 0; i < HUD_PANEL_NUM; ++i)
  54                 {
  55                         panel = hud_panel[i];
  56
  57                         HUD_Write_PanelCvar_n("");
  58                         HUD_Write_PanelCvar_q("_pos");
  59                         HUD_Write_PanelCvar_q("_size");
  60                         HUD_Write_PanelCvar_q("_bg");
  61                         HUD_Write_PanelCvar_q("_bg_color");
  62                         HUD_Write_PanelCvar_q("_bg_color_team");
  63                         HUD_Write_PanelCvar_q("_bg_alpha");
  64                         HUD_Write_PanelCvar_q("_bg_border");
  65                         HUD_Write_PanelCvar_q("_bg_padding");
  66                         switch(i) {
  67                                 case HUD_PANEL_WEAPONS:
  68                                         HUD_Write_PanelCvar_q("_accuracy");
  69                                         HUD_Write_PanelCvar_q("_label");
  70                                         HUD_Write_PanelCvar_q("_complainbubble");
  71                                         HUD_Write_PanelCvar_q("_complainbubble_padding");
  72                                         HUD_Write_PanelCvar_q("_complainbubble_time");
  73                                         HUD_Write_PanelCvar_q("_complainbubble_fadetime");
  74                                         HUD_Write_PanelCvar_q("_complainbubble_color_outofammo");
  75                                         HUD_Write_PanelCvar_q("_complainbubble_color_donthave");
  76                                         HUD_Write_PanelCvar_q("_complainbubble_color_unavailable");
  77                                         HUD_Write_PanelCvar_q("_ammo");
  78                                         HUD_Write_PanelCvar_q("_ammo_color");
  79                                         HUD_Write_PanelCvar_q("_ammo_alpha");
  80                                         HUD_Write_PanelCvar_q("_aspect");
  81                                         HUD_Write_PanelCvar_q("_timeout");
  82                                         HUD_Write_PanelCvar_q("_timeout_effect");
  83                                         HUD_Write_PanelCvar_q("_timeout_fadebgmin");
  84                                         HUD_Write_PanelCvar_q("_timeout_fadefgmin");
  85                                         HUD_Write_PanelCvar_q("_timeout_speed_in");
  86                                         HUD_Write_PanelCvar_q("_timeout_speed_out");
  87                                         HUD_Write_PanelCvar_q("_onlyowned");
  88                                         break;
  89                                 case HUD_PANEL_AMMO:
  90                                         HUD_Write_PanelCvar_q("_onlycurrent");
  91                                         HUD_Write_PanelCvar_q("_iconalign");
  92                                         HUD_Write_PanelCvar_q("_progressbar");
  93                                         HUD_Write_PanelCvar_q("_progressbar_name");
  94                                         HUD_Write_PanelCvar_q("_progressbar_xoffset");
  95                                         HUD_Write_PanelCvar_q("_text");
  96                                         break;
  97                                 case HUD_PANEL_POWERUPS:
  98                                         HUD_Write_PanelCvar_q("_flip");
  99                                         HUD_Write_PanelCvar_q("_iconalign");
 100                                         HUD_Write_PanelCvar_q("_baralign");
 101                                         HUD_Write_PanelCvar_q("_progressbar");
 102                                         HUD_Write_PanelCvar_q("_progressbar_strength");
 103                                         HUD_Write_PanelCvar_q("_progressbar_shield");
 104                                         HUD_Write_PanelCvar_q("_text");
 105                                         break;
 106                                 case HUD_PANEL_HEALTHARMOR:
 107                                         HUD_Write_PanelCvar_q("_flip");
 108                                         HUD_Write_PanelCvar_q("_iconalign");
 109                                         HUD_Write_PanelCvar_q("_baralign");
 110                                         HUD_Write_PanelCvar_q("_progressbar");
 111                                         HUD_Write_PanelCvar_q("_progressbar_health");
 112                                         HUD_Write_PanelCvar_q("_progressbar_armor");
 113                                         HUD_Write_PanelCvar_q("_progressbar_gfx");
 114                                         HUD_Write_PanelCvar_q("_progressbar_gfx_smooth");
 115                                         HUD_Write_PanelCvar_q("_text");
 116                                         break;
 117                                 case HUD_PANEL_NOTIFY:
 118                                         HUD_Write_PanelCvar_q("_flip");
 119                                         HUD_Write_PanelCvar_q("_fontsize");
 120                                         HUD_Write_PanelCvar_q("_time");
 121                                         HUD_Write_PanelCvar_q("_fadetime");
 122                                         break;
 123                                 case HUD_PANEL_TIMER:
 124                                         HUD_Write_PanelCvar_q("_increment");
 125                                         break;
 126                                 case HUD_PANEL_RADAR:
 127                                         HUD_Write_PanelCvar_q("_foreground_alpha");
 128                                         HUD_Write_PanelCvar_q("_rotation");
 129                                         HUD_Write_PanelCvar_q("_zoommode");
 130                                         HUD_Write_PanelCvar_q("_scale");
 131                                         HUD_Write_PanelCvar_q("_maximized_scale");
 132                                         HUD_Write_PanelCvar_q("_maximized_size");
 133                                         HUD_Write_PanelCvar_q("_maximized_rotation");
 134                                         HUD_Write_PanelCvar_q("_maximized_zoommode");
 135                                         break;
 136                                 case HUD_PANEL_SCORE:
 137                                         HUD_Write_PanelCvar_q("_rankings");
 138                                         break;
 139                                 case HUD_PANEL_VOTE:
 140                                         HUD_Write_PanelCvar_q("_alreadyvoted_alpha");
 141                                         break;
 142                                 case HUD_PANEL_MODICONS:
 143                                         HUD_Write_PanelCvar_q("_dom_layout");
 144                                         break;
 145                                 case HUD_PANEL_PRESSEDKEYS:
 146                                         HUD_Write_PanelCvar_q("_aspect");
 147                                         HUD_Write_PanelCvar_q("_attack");
 148                                         break;
 149                                 case HUD_PANEL_ENGINEINFO:
 150                                         HUD_Write_PanelCvar_q("_framecounter_time");
 151                                         HUD_Write_PanelCvar_q("_framecounter_decimals");
 152                                         break;
 153                                 case HUD_PANEL_INFOMESSAGES:
 154                                         HUD_Write_PanelCvar_q("_flip");
 155                                         break;
 156                                 case HUD_PANEL_PHYSICS:
 157                                         HUD_Write_PanelCvar_q("_speed_unit");
 158                                         HUD_Write_PanelCvar_q("_speed_unit_show");
 159                                         HUD_Write_PanelCvar_q("_speed_max");
 160                                         HUD_Write_PanelCvar_q("_speed_vertical");
 161                                         HUD_Write_PanelCvar_q("_topspeed");
 162                                         HUD_Write_PanelCvar_q("_topspeed_time");
 163                                         HUD_Write_PanelCvar_q("_acceleration_max");
 164                                         HUD_Write_PanelCvar_q("_acceleration_vertical");
 165                                         HUD_Write_PanelCvar_q("_flip");
 166                                         HUD_Write_PanelCvar_q("_baralign");
 167                                         HUD_Write_PanelCvar_q("_progressbar");
 168                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_mode");
 169                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_scale");
 170                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_nonlinear");
 171                                         HUD_Write_PanelCvar_q("_text");
 172                                         HUD_Write_PanelCvar_q("_text_scale");
 173                                         break;
 174                                 case HUD_PANEL_CENTERPRINT:
 175                                         HUD_Write_PanelCvar_q("_align");
 176                                         HUD_Write_PanelCvar_q("_flip");
 177                                         HUD_Write_PanelCvar_q("_fontscale");
 178                                         HUD_Write_PanelCvar_q("_time");
 179                                         HUD_Write_PanelCvar_q("_fade_in");
 180                                         HUD_Write_PanelCvar_q("_fade_out");
 181                                         HUD_Write_PanelCvar_q("_fade_subsequent");
 182                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone");
 183                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone_minalpha");
 184                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo");
 185                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo_minalpha");
 186                                         HUD_Write_PanelCvar_q("_fade_subsequent_minfontsize");
 187                                         HUD_Write_PanelCvar_q("_fade_minfontsize");
 188                                         break;
 189                         }
 190                         HUD_Write("\n");
 191                 }
 192                 HUD_Write("menu_sync\n"); // force the menu to reread the cvars, so that the dialogs are updated
 193
 194                 print(sprintf(_("^2Successfully exported to %s! (Note: It's saved in data/data/)\n"), filename));
 195                 fclose(fh);
 196         }
 197         else
 198                 print(sprintf(_("^1Couldn't write to %s\n"), filename));
 199 }
 200
 201 void HUD_Configure_Exit_Force()
 202 {
 203         if (menu_enabled)
 204         {
 205                 menu_enabled = 0;
 206                 localcmd("togglemenu\n");
 207         }
 208         cvar_set("_hud_configure", "0");
 209 }
 210
 211 // check if move will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 212 vector HUD_Panel_CheckMove(vector myPos, vector mySize)
 213 {
 214         float i;
 215         float myCenter_x, myCenter_y, targCenter_x, targCenter_y;
 216         vector myTarget;
 217         myTarget = myPos;
 218
 219         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 220                 if(i == highlightedPanel || !panel_enabled)
 221                         continue;
 222
 223                 panel = hud_panel[i];
 224                 HUD_Panel_UpdatePosSize()
 225
 226                 panel_pos -= '1 1 0' * panel_bg_border;
 227                 panel_size += '2 2 0' * panel_bg_border;
 228
 229                 if(myPos_y + mySize_y < panel_pos_y)
 230                         continue;
 231                 if(myPos_y > panel_pos_y + panel_size_y)
 232                         continue;
 233
 234                 if(myPos_x + mySize_x < panel_pos_x)
 235                         continue;
 236                 if(myPos_x > panel_pos_x + panel_size_x)
 237                         continue;
 238
 239                 // OK, there IS a collision.
 240
 241                 myCenter_x = myPos_x + 0.5 * mySize_x;
 242                 myCenter_y = myPos_y + 0.5 * mySize_y;
 243
 244                 targCenter_x = panel_pos_x + 0.5 * panel_size_x;
 245                 targCenter_y = panel_pos_y + 0.5 * panel_size_y;
 246
 247                 if(myCenter_x < targCenter_x && myCenter_y < targCenter_y) // top left (of the target panel)
 248                 {
 249                         if(myPos_x + mySize_x - panel_pos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 250                                 myTarget_x = panel_pos_x - mySize_x;
 251                         else // push it upwards
 252                                 myTarget_y = panel_pos_y - mySize_y;
 253                 }
 254                 else if(myCenter_x > targCenter_x && myCenter_y < targCenter_y) // top right
 255                 {
 256                         if(panel_pos_x + panel_size_x - myPos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 257                                 myTarget_x = panel_pos_x + panel_size_x;
 258                         else // push it upwards
 259                                 myTarget_y = panel_pos_y - mySize_y;
 260                 }
 261                 else if(myCenter_x < targCenter_x && myCenter_y > targCenter_y) // bottom left
 262                 {
 263                         if(myPos_x + mySize_x - panel_pos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 264                                 myTarget_x = panel_pos_x - mySize_x;
 265                         else // push it downwards
 266                                 myTarget_y = panel_pos_y + panel_size_y;
 267                 }
 268                 else if(myCenter_x > targCenter_x && myCenter_y > targCenter_y) // bottom right
 269                 {
 270                         if(panel_pos_x + panel_size_x - myPos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 271                                 myTarget_x = panel_pos_x + panel_size_x;
 272                         else // push it downwards
 273                                 myTarget_y = panel_pos_y + panel_size_y;
 274                 }
 275                 //if(cvar("hud_configure_checkcollisions_debug"))
 276                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 277         }
 278
 279         return myTarget;
 280 }
 281
 282 void HUD_Panel_SetPos(vector pos)
 283 {
 284         panel = hud_panel[highlightedPanel];
 285         HUD_Panel_UpdatePosSize()
 286         vector mySize;
 287         mySize = panel_size;
 288
 289         //if(cvar("hud_configure_checkcollisions_debug"))
 290                 //drawfill(pos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 291
 292         if(autocvar_hud_configure_grid)
 293         {
 294                 pos_x = floor((pos_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 295                 pos_y = floor((pos_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 296         }
 297
 298         if(hud_configure_checkcollisions)
 299                 pos = HUD_Panel_CheckMove(pos, mySize);
 300
 301         pos_x = bound(0, pos_x, vid_conwidth - mySize_x);
 302         pos_y = bound(0, pos_y, vid_conheight - mySize_y);
 303
 304         string s;
 305         s = strcat(ftos(pos_x/vid_conwidth), " ", ftos(pos_y/vid_conheight));
 306
 307         cvar_set(strcat("hud_panel_", hud_panel[highlightedPanel].panel_name, "_pos"), s);
 308 }
 309
 310 // check if resize will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 311 vector HUD_Panel_CheckResize(vector mySize, vector resizeorigin) {
 312         float i;
 313
 314         vector targEndPos;
 315
 316         float dist_x, dist_y;
 317         float ratio;
 318         ratio = mySize_x/mySize_y;
 319
 320         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 321                 if(i == highlightedPanel || !panel_enabled)
 322                         continue;
 323
 324                 panel = hud_panel[i];
 325                 HUD_Panel_UpdatePosSize()
 326
 327                 panel_pos -= '1 1 0' * panel_bg_border;
 328                 panel_size += '2 2 0' * panel_bg_border;
 329
 330                 targEndPos = panel_pos + panel_size;
 331
 332                 // resizeorigin is WITHIN target panel, just abort any collision testing against that particular panel to produce expected behaviour!
 333                 if(resizeorigin_x > panel_pos_x && resizeorigin_x < targEndPos_x && resizeorigin_y > panel_pos_y && resizeorigin_y < targEndPos_y)
 334                         continue;
 335
 336                 if (resizeCorner == 1)
 337                 {
 338                         // check if this panel is on our way
 339                         if (resizeorigin_x <= panel_pos_x)
 340                                 continue;
 341                         if (resizeorigin_y <= panel_pos_y)
 342                                 continue;
 343                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 344                                 continue;
 345                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 346                                 continue;
 347
 348                         // there is a collision:
 349                         // detect which side of the panel we are facing is actually limiting the resizing
 350                         // (which side the resize direction finds for first) and reduce the size up to there
 351                         //
 352                         // dist is the distance between resizeorigin and the "analogous" point of the panel
 353                         // in this case between resizeorigin (bottom-right point) and the bottom-right point of the panel
 354                         dist_x = resizeorigin_x - targEndPos_x;
 355                         dist_y = resizeorigin_y - targEndPos_y;
 356                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 357                                 mySize_x = min(mySize_x, dist_x);
 358                         else
 359                                 mySize_y = min(mySize_y, dist_y);
 360                 }
 361                 else if (resizeCorner == 2)
 362                 {
 363                         if (resizeorigin_x >= targEndPos_x)
 364                                 continue;
 365                         if (resizeorigin_y <= panel_pos_y)
 366                                 continue;
 367                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 368                                 continue;
 369                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 370                                 continue;
 371
 372                         dist_x = panel_pos_x - resizeorigin_x;
 373                         dist_y = resizeorigin_y - targEndPos_y;
 374                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 375                                 mySize_x = min(mySize_x, dist_x);
 376                         else
 377                                 mySize_y = min(mySize_y, dist_y);
 378                 }
 379                 else if (resizeCorner == 3)
 380                 {
 381                         if (resizeorigin_x <= panel_pos_x)
 382                                 continue;
 383                         if (resizeorigin_y >= targEndPos_y)
 384                                 continue;
 385                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 386                                 continue;
 387                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 388                                 continue;
 389
 390                         dist_x = resizeorigin_x - targEndPos_x;
 391                         dist_y = panel_pos_y - resizeorigin_y;
 392                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 393                                 mySize_x = min(mySize_x, dist_x);
 394                         else
 395                                 mySize_y = min(mySize_y, dist_y);
 396                 }
 397                 else if (resizeCorner == 4)
 398                 {
 399                         if (resizeorigin_x >= targEndPos_x)
 400                                 continue;
 401                         if (resizeorigin_y >= targEndPos_y)
 402                                 continue;
 403                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 404                                 continue;
 405                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 406                                 continue;
 407
 408                         dist_x = panel_pos_x - resizeorigin_x;
 409                         dist_y = panel_pos_y - resizeorigin_y;
 410                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 411                                 mySize_x = min(mySize_x, dist_x);
 412                         else
 413                                 mySize_y = min(mySize_y, dist_y);
 414                 }
 415                 //if(cvar("hud_configure_checkcollisions_debug"))
 416                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 417         }
 418
 419         return mySize;
 420 }
 421
 422 void HUD_Panel_SetPosSize(vector mySize)
 423 {
 424         panel = hud_panel[highlightedPanel];
 425         HUD_Panel_UpdatePosSize()
 426         vector resizeorigin;
 427         resizeorigin = panel_click_resizeorigin;
 428         local noref vector myPos; // fteqcc sucks
 429
 430         // minimum panel size cap
 431         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 432         mySize_y = max(0.025 * vid_conheight, mySize_y);
 433
 434         if(highlightedPanel == HUD_PANEL_CHAT) // some panels have their own restrictions, like the chat panel (which actually only moves the engine chat print around). Looks bad if it's too small.
 435         {
 436                 mySize_x = max(17 * autocvar_con_chatsize, mySize_x);
 437                 mySize_y = max(2 * autocvar_con_chatsize + 2 * panel_bg_padding, mySize_y);
 438         }
 439
 440         // collision testing|
 441         // -----------------+
 442
 443         // we need to know pos at this stage, but it might still change later if we hit a screen edge/other panel (?)
 444         if(resizeCorner == 1) {
 445                 myPos_x = resizeorigin_x - mySize_x;
 446                 myPos_y = resizeorigin_y - mySize_y;
 447         } else if(resizeCorner == 2) {
 448                 myPos_x = resizeorigin_x;
 449                 myPos_y = resizeorigin_y - mySize_y;
 450         } else if(resizeCorner == 3) {
 451                 myPos_x = resizeorigin_x - mySize_x;
 452                 myPos_y = resizeorigin_y;
 453         } else { // resizeCorner == 4
 454                 myPos_x = resizeorigin_x;
 455                 myPos_y = resizeorigin_y;
 456         }
 457
 458         // left/top screen edges
 459         if(myPos_x < 0)
 460                 mySize_x = mySize_x + myPos_x;
 461         if(myPos_y < 0)
 462                 mySize_y = mySize_y + myPos_y;
 463
 464         // bottom/right screen edges
 465         if(myPos_x + mySize_x > vid_conwidth)
 466                 mySize_x = vid_conwidth - myPos_x;
 467         if(myPos_y + mySize_y > vid_conheight)
 468                 mySize_y = vid_conheight - myPos_y;
 469
 470         //if(cvar("hud_configure_checkcollisions_debug"))
 471                 //drawfill(myPos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 472
 473         // before checkresize, otherwise panel can be snapped partially inside another panel or panel aspect ratio can be broken
 474         if(autocvar_hud_configure_grid)
 475         {
 476                 mySize_x = floor((mySize_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 477                 mySize_y = floor((mySize_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 478         }
 479
 480         if(hud_configure_checkcollisions)
 481                 mySize = HUD_Panel_CheckResize(mySize, resizeorigin);
 482
 483         // minimum panel size cap, do this once more so we NEVER EVER EVER have a panel smaller than this, JUST IN CASE above code still makes the panel eg negative (impossible to resize back without changing cvars manually then)
 484         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 485         mySize_y = max(0.025 * vid_conheight, mySize_y);
 486
 487         // do another pos check, as size might have changed by now
 488         if(resizeCorner == 1) {
 489                 myPos_x = resizeorigin_x - mySize_x;
 490                 myPos_y = resizeorigin_y - mySize_y;
 491         } else if(resizeCorner == 2) {
 492                 myPos_x = resizeorigin_x;
 493                 myPos_y = resizeorigin_y - mySize_y;
 494         } else if(resizeCorner == 3) {
 495                 myPos_x = resizeorigin_x - mySize_x;
 496                 myPos_y = resizeorigin_y;
 497         } else { // resizeCorner == 4
 498                 myPos_x = resizeorigin_x;
 499                 myPos_y = resizeorigin_y;
 500         }
 501
 502         //if(cvar("hud_configure_checkcollisions_debug"))
 503                 //drawfill(myPos, mySize, '0 1 0', .3, DRAWFLAG_NORMAL);
 504
 505         entity e = hud_panel[highlightedPanel];
 506         string s;
 507         s = strcat(ftos(mySize_x/vid_conwidth), " ", ftos(mySize_y/vid_conheight));
 508         cvar_set(strcat("hud_panel_", e.panel_name, "_size"), s);
 509
 510         s = strcat(ftos(myPos_x/vid_conwidth), " ", ftos(myPos_y/vid_conheight));
 511         cvar_set(strcat("hud_panel_", e.panel_name, "_pos"), s);
 512 }
 513
 514 float pressed_key_time;
 515 vector highlightedPanel_initial_pos, highlightedPanel_initial_size;
 516 void HUD_Panel_Arrow_Action(float nPrimary)
 517 {
 518         if (highlightedPanel == -1)
 519                 return;
 520
 521         hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
 522
 523         float step;
 524         if(autocvar_hud_configure_grid)
 525         {
 526                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 527                 {
 528                         if (hudShiftState & S_SHIFT)
 529                                 step = hud_configure_realGridSize_y;
 530                         else
 531                                 step = 2 * hud_configure_realGridSize_y;
 532                 }
 533                 else
 534                 {
 535                         if (hudShiftState & S_SHIFT)
 536                                 step = hud_configure_realGridSize_x;
 537                         else
 538                                 step = 2 * hud_configure_realGridSize_x;
 539                 }
 540         }
 541         else
 542         {
 543                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 544                         step = vid_conheight;
 545                 else
 546                         step = vid_conwidth;
 547                 if (hudShiftState & S_SHIFT)
 548                         step = (step / 256); // more precision
 549                 else
 550                         step = (step / 64) * (1 + 2 * (time - pressed_key_time));
 551         }
 552
 553         panel = hud_panel[highlightedPanel];
 554         HUD_Panel_UpdatePosSize()
 555
 556         highlightedPanel_initial_pos = panel_pos;
 557         highlightedPanel_initial_size = panel_size;
 558
 559         if (hudShiftState & S_ALT) // resize
 560         {
 561                 highlightedAction = 1;
 562                 if(nPrimary == K_UPARROW)
 563                         resizeCorner = 1;
 564                 else if(nPrimary == K_RIGHTARROW)
 565                         resizeCorner = 2;
 566                 else if(nPrimary == K_LEFTARROW)
 567                         resizeCorner = 3;
 568                 else // if(nPrimary == K_DOWNARROW)
 569                         resizeCorner = 4;
 570
 571                 // ctrl+arrow reduces the size, instead of increasing it
 572                 // Note that ctrl disables collisions check too, but it's fine
 573                 // since we don't collide with anything reducing the size
 574                 if (hudShiftState & S_CTRL) {
 575                         step = -step;
 576                         resizeCorner = 5 - resizeCorner;
 577                 }
 578
 579                 vector mySize;
 580                 mySize = panel_size;
 581                 panel_click_resizeorigin = panel_pos;
 582                 if(resizeCorner == 1) {
 583                         panel_click_resizeorigin += mySize;
 584                         mySize_y += step;
 585                 } else if(resizeCorner == 2) {
 586                         panel_click_resizeorigin_y += mySize_y;
 587                         mySize_x += step;
 588                 } else if(resizeCorner == 3) {
 589                         panel_click_resizeorigin_x += mySize_x;
 590                         mySize_x += step;
 591                 } else { // resizeCorner == 4
 592                         mySize_y += step;
 593                 }
 594                 HUD_Panel_SetPosSize(mySize);
 595         }
 596         else // move
 597         {
 598                 highlightedAction = 2;
 599                 vector pos;
 600                 pos = panel_pos;
 601                 if(nPrimary == K_UPARROW)
 602                         pos_y -= step;
 603                 else if(nPrimary == K_DOWNARROW)
 604                         pos_y += step;
 605                 else if(nPrimary == K_LEFTARROW)
 606                         pos_x -= step;
 607                 else // if(nPrimary == K_RIGHTARROW)
 608                         pos_x += step;
 609
 610                 HUD_Panel_SetPos(pos);
 611         }
 612
 613         panel = hud_panel[highlightedPanel];
 614         HUD_Panel_UpdatePosSize()
 615
 616         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
 617         {
 618                 // backup!
 619                 panel_pos_backup = highlightedPanel_initial_pos;
 620                 panel_size_backup = highlightedPanel_initial_size;
 621                 highlightedPanel_backup = highlightedPanel;
 622         }
 623 }
 624
 625 const float S_MOUSE1 = 1;
 626 const float S_MOUSE2 = 2;
 627 const float S_MOUSE3 = 4;
 628 float mouseClicked;
 629 float prevMouseClicked; // previous state
 630 float prevMouseClickedTime; // time during previous left mouse click, to check for doubleclicks
 631 vector prevMouseClickedPos; // pos during previous left mouse click, to check for doubleclicks
 632
 633 void HUD_Panel_EnableMenu();
 634 float tab_panels[HUD_PANEL_MAX];
 635 float tab_panel, tab_backward;
 636 vector tab_panel_pos;
 637 void HUD_Panel_FirstInDrawQ(float id);
 638 void reset_tab_panels()
 639 {
 640         int i;
 641         for(i = 0; i < HUD_PANEL_NUM; ++i)
 642                 tab_panels[i] = -1;
 643 }
 644 float HUD_Panel_InputEvent(float bInputType, float nPrimary, float nSecondary)
 645 {
 646         string s;
 647
 648         if(bInputType == 2)
 649                 return false;
 650
 651         if(!autocvar__hud_configure)
 652                 return false;
 653
 654         // block any input while a menu dialog is fading
 655         if(autocvar__menu_alpha)
 656                 return true;
 657
 658         if(bInputType == 3)
 659         {
 660                 mousepos_x = nPrimary;
 661                 mousepos_y = nSecondary;
 662                 return true;
 663         }
 664
 665         // allow console bind to work
 666         string con_keys;
 667         float keys;
 668         con_keys = findkeysforcommand("toggleconsole", 0);
 669         keys = tokenize(con_keys); // findkeysforcommand returns data for this
 670
 671         float hit_con_bind = 0, i;
 672         for (i = 0; i < keys; ++i)
 673         {
 674                 if(nPrimary == stof(argv(i)))
 675                         hit_con_bind = 1;
 676         }
 677
 678         if(bInputType == 0) {
 679                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 680                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 681                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 682         }
 683         else if(bInputType == 1) {
 684                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 685                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 686                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 687         }
 688
 689         if(nPrimary == K_CTRL)
 690         {
 691                 if (bInputType == 1) //ctrl has been released
 692                 {
 693                         if (tab_panel != -1)
 694                         {
 695                                 //switch to selected panel
 696                                 highlightedPanel = tab_panel;
 697                                 highlightedAction = 0;
 698                                 HUD_Panel_FirstInDrawQ(highlightedPanel);
 699                         }
 700                         tab_panel = -1;
 701                         reset_tab_panels();
 702                 }
 703         }
 704
 705         if(nPrimary == K_MOUSE1)
 706         {
 707                 if(bInputType == 0) // key pressed
 708                         mouseClicked |= S_MOUSE1;
 709                 else if(bInputType == 1) // key released
 710                         mouseClicked -= (mouseClicked & S_MOUSE1);
 711         }
 712         else if(nPrimary == K_MOUSE2)
 713         {
 714                 if(bInputType == 0) // key pressed
 715                         mouseClicked |= S_MOUSE2;
 716                 else if(bInputType == 1) // key released
 717                         mouseClicked -= (mouseClicked & S_MOUSE2);
 718         }
 719         else if(nPrimary == K_ESCAPE)
 720         {
 721                 if (bInputType == 1)
 722                         return true;
 723                 menu_enabled = 1;
 724                 menu_enabled_time = time;
 725                 localcmd("menu_showhudexit\n");
 726         }
 727         else if(nPrimary == K_BACKSPACE && hudShiftState & S_CTRL)
 728         {
 729                 if (bInputType == 1)
 730                         return true;
 731                 if (!menu_enabled)
 732                         cvar_set("_hud_configure", "0");
 733         }
 734         else if(nPrimary == K_TAB && hudShiftState & S_CTRL) // select and highlight another panel
 735         {
 736                 if (bInputType == 1 || mouseClicked)
 737                         return true;
 738
 739                 //FIXME: if a panel is highlighted, has the same pos_x and lays in the same level
 740                 //of other panels then next consecutive ctrl-tab will select the highlighted panel too
 741                 //(it should only after every other panel of the hud)
 742                 //It's a minor bug anyway, we can live with it
 743
 744                 float starting_panel;
 745                 float old_tab_panel = tab_panel;
 746                 if (tab_panel == -1) //first press of TAB
 747                 {
 748                         if (highlightedPanel != -1)
 749                         if (highlightedPanel)
 750                         {
 751                                 panel = hud_panel[highlightedPanel];
 752                                 HUD_Panel_UpdatePosSize()
 753                         }
 754                         else
 755                                 panel_pos = '0 0 0';
 756                         starting_panel = highlightedPanel; //can be -1, it means no starting panel
 757                         tab_panel_pos = panel_pos; //to compute level
 758                 }
 759                 else
 760                 {
 761                         if ( ((!tab_backward) && (hudShiftState & S_SHIFT)) || (tab_backward && !(hudShiftState & S_SHIFT)) ) //tab direction changed?
 762                                 reset_tab_panels();
 763                         starting_panel = tab_panel;
 764                 }
 765                 tab_backward = (hudShiftState & S_SHIFT);
 766
 767                 float k, level = 0, start_pos_x;
 768                 vector candidate_pos = '0 0 0';
 769                 const float LEVELS_NUM = 4;
 770                 float level_height = vid_conheight / LEVELS_NUM;
 771 :find_tab_panel
 772                 level = floor(tab_panel_pos_y / level_height) * level_height; //starting level
 773                 candidate_pos_x = (!tab_backward) ? vid_conwidth : 0;
 774                 start_pos_x = tab_panel_pos_x;
 775                 tab_panel = -1;
 776                 k=0;
 777                 while(++k)
 778                 {
 779                         for(i = 0; i < HUD_PANEL_NUM; ++i)
 780                         {
 781                                 if (i == tab_panels[i] || i == starting_panel)
 782                                         continue;
 783                                 panel = hud_panel[i];
 784                                 HUD_Panel_UpdatePosSize()
 785                                 if (panel_pos_y >= level && (panel_pos_y - level) < level_height)
 786                                 if (  ( !tab_backward && panel_pos_x >= start_pos_x && (panel_pos_x < candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y <= candidate_pos_y)) )
 787                                         || ( tab_backward && panel_pos_x <= start_pos_x && (panel_pos_x > candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y >= candidate_pos_y)) )  )
 788                                 {
 789                                         tab_panel = i;
 790                                         tab_panel_pos = candidate_pos = panel_pos;
 791                                 }
 792                         }
 793                         if (tab_panel != -1)
 794                                 break;
 795                         if (k == LEVELS_NUM) //tab_panel not found
 796                         {
 797                                 reset_tab_panels();
 798                                 if (old_tab_panel == -2) //this prevents an infinite loop (should not happen normally)
 799                                 {
 800                                         tab_panel = -1;
 801                                         return true;
 802                                 }
 803                                 starting_panel = old_tab_panel;
 804                                 old_tab_panel = -2;
 805                                 goto find_tab_panel; //u must find tab_panel!
 806                         }
 807                         if (!tab_backward)
 808                         {
 809                                 level = mod(level + level_height, vid_conheight);
 810                                 start_pos_x = 0;
 811                                 candidate_pos_x = vid_conwidth;
 812                         }
 813                         else
 814                         {
 815                                 level = mod(level - level_height, vid_conheight);
 816                                 start_pos_x = vid_conwidth;
 817                                 candidate_pos_x = 0;
 818                         }
 819                 }
 820
 821                 tab_panels[tab_panel] = tab_panel;
 822         }
 823         else if(nPrimary == K_SPACE && hudShiftState & S_CTRL) // enable/disable highlighted panel or dock
 824         {
 825                 if (bInputType == 1 || mouseClicked)
 826                         return true;
 827
 828                 if (highlightedPanel != -1)
 829                 {
 830                         entity e = hud_panel[highlightedPanel];
 831                         cvar_set(strcat("hud_panel_", e.panel_name), ftos(!(panel_enabled)));
 832                 }
 833                 else
 834                         cvar_set(strcat("hud_dock"), (autocvar_hud_dock == "") ? "dock" : "");
 835         }
 836         else if(nPrimary == 'c' && hudShiftState & S_CTRL) // copy highlighted panel size
 837         {
 838                 if (bInputType == 1 || mouseClicked)
 839                         return true;
 840
 841                 if (highlightedPanel != -1)
 842                 {
 843                         panel = hud_panel[highlightedPanel];
 844                         HUD_Panel_UpdatePosSize()
 845                         panel_size_copied = panel_size;
 846                         highlightedPanel_copied = highlightedPanel;
 847                 }
 848         }
 849         else if(nPrimary == 'v' && hudShiftState & S_CTRL) // past copied size on the highlighted panel
 850         {
 851                 if (bInputType == 1 || mouseClicked)
 852                         return true;
 853
 854                 if (highlightedPanel_copied == -1 || highlightedPanel == -1)
 855                         return true;
 856
 857                 panel = hud_panel[highlightedPanel];
 858                 HUD_Panel_UpdatePosSize()
 859
 860                 // reduce size if it'd go beyond screen boundaries
 861                 vector tmp_size = panel_size_copied;
 862                 if (panel_pos_x + panel_size_copied_x > vid_conwidth)
 863                         tmp_size_x = vid_conwidth - panel_pos_x;
 864                 if (panel_pos_y + panel_size_copied_y > vid_conheight)
 865                         tmp_size_y = vid_conheight - panel_pos_y;
 866
 867                 if (panel_size == tmp_size)
 868                         return true;
 869
 870                 // backup first!
 871                 panel_pos_backup = panel_pos;
 872                 panel_size_backup = panel_size;
 873                 highlightedPanel_backup = highlightedPanel;
 874
 875                 s = strcat(ftos(tmp_size_x/vid_conwidth), " ", ftos(tmp_size_y/vid_conheight));
 876                 entity e = hud_panel[highlightedPanel];
 877                 cvar_set(strcat("hud_panel_", e.panel_name, "_size"), s);
 878         }
 879         else if(nPrimary == 'z' && hudShiftState & S_CTRL) // undo last action
 880         {
 881                 if (bInputType == 1 || mouseClicked)
 882                         return true;
 883                 //restore previous values
 884                 if (highlightedPanel_backup != -1)
 885                 {
 886                         entity e = hud_panel[highlightedPanel_backup];
 887                         s = strcat(ftos(panel_pos_backup_x/vid_conwidth), " ", ftos(panel_pos_backup_y/vid_conheight));
 888                         cvar_set(strcat("hud_panel_", e.panel_name, "_pos"), s);
 889                         s = strcat(ftos(panel_size_backup_x/vid_conwidth), " ", ftos(panel_size_backup_y/vid_conheight));
 890                         cvar_set(strcat("hud_panel_", e.panel_name, "_size"), s);
 891                         highlightedPanel_backup = -1;
 892                 }
 893         }
 894         else if(nPrimary == K_UPARROW || nPrimary == K_DOWNARROW || nPrimary == K_LEFTARROW || nPrimary == K_RIGHTARROW)
 895         {
 896                 if (bInputType == 1)
 897                 {
 898                         pressed_key_time = 0;
 899                         return true;
 900                 }
 901                 else if (pressed_key_time == 0)
 902                         pressed_key_time = time;
 903
 904                 if (!mouseClicked)
 905                         HUD_Panel_Arrow_Action(nPrimary); //move or resize panel
 906         }
 907         else if(nPrimary == K_ENTER || nPrimary == K_SPACE || nPrimary == K_KP_ENTER)
 908         {
 909                 if (bInputType == 1)
 910                         return true;
 911                 if (highlightedPanel != -1)
 912                         HUD_Panel_EnableMenu();
 913         }
 914         else if(hit_con_bind)
 915                 return false;
 916
 917         return true;
 918 }
 919
 920 float HUD_Panel_Check_Mouse_Pos(float allow_move)
 921 {
 922         float i, j = 0, border;
 923
 924         while(j < HUD_PANEL_NUM)
 925         {
 926                 i = panel_order[j];
 927                 j += 1;
 928
 929                 panel = hud_panel[i];
 930                 HUD_Panel_UpdatePosSize()
 931
 932                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 933
 934                 // move
 935                 if(allow_move && mousepos_x > panel_pos_x && mousepos_y > panel_pos_y && mousepos_x < panel_pos_x + panel_size_x && mousepos_y < panel_pos_y + panel_size_y)
 936                 {
 937                         return 1;
 938                 }
 939                 // resize from topleft border
 940                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 941                 {
 942                         return 2;
 943                 }
 944                 // resize from topright border
 945                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 946                 {
 947                         return 3;
 948                 }
 949                 // resize from bottomleft border
 950                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
 951                 {
 952                         return 3;
 953                 }
 954                 // resize from bottomright border
 955                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
 956                 {
 957                         return 2;
 958                 }
 959         }
 960         return 0;
 961 }
 962
 963 // move a panel to the beginning of the panel order array (which means it gets drawn last, on top of everything else)
 964 void HUD_Panel_FirstInDrawQ(float id)
 965 {
 966         float i;
 967         var float place = -1;
 968         // find out where in the array our current id is, save into place
 969         for(i = 0; i < HUD_PANEL_NUM; ++i)
 970         {
 971                 if(panel_order[i] == id)
 972                 {
 973                         place = i;
 974                         break;
 975                 }
 976         }
 977         // place last if we didn't find a place for it yet (probably new panel, or screwed up cvar)
 978         if(place == -1)
 979                 place = HUD_PANEL_NUM - 1;
 980
 981         // move all ids up by one step in the array until "place"
 982         for(i = place; i > 0; --i)
 983         {
 984                 panel_order[i] = panel_order[i-1];
 985         }
 986         // now save the new top id
 987         panel_order[0] = id;
 988
 989         // let's save them into the cvar by some strcat trickery
 990         string s = "";
 991         for(i = 0; i < HUD_PANEL_NUM; ++i)
 992         {
 993                 s = strcat(s, ftos(panel_order[i]), " ");
 994         }
 995         cvar_set("_hud_panelorder", s);
 996         if(hud_panelorder_prev)
 997                 strunzone(hud_panelorder_prev);
 998         hud_panelorder_prev = strzone(autocvar__hud_panelorder); // prevent HUD_Main from doing useless update, we already updated here
 999 }
1000
1001 void HUD_Panel_Highlight(float allow_move)
1002 {
1003         float i, j = 0, border;
1004
1005         while(j < HUD_PANEL_NUM)
1006         {
1007                 i = panel_order[j];
1008                 j += 1;
1009
1010                 panel = hud_panel[i];
1011                 HUD_Panel_UpdatePosSize()
1012
1013                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
1014
1015                 // move
1016                 if(allow_move && mousepos_x > panel_pos_x && mousepos_y > panel_pos_y && mousepos_x < panel_pos_x + panel_size_x && mousepos_y < panel_pos_y + panel_size_y)
1017                 {
1018                         highlightedPanel = i;
1019                         HUD_Panel_FirstInDrawQ(i);
1020                         highlightedAction = 1;
1021                         panel_click_distance = mousepos - panel_pos;
1022                         return;
1023                 }
1024                 // resize from topleft border
1025                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
1026                 {
1027                         highlightedPanel = i;
1028                         HUD_Panel_FirstInDrawQ(i);
1029                         highlightedAction = 2;
1030                         resizeCorner = 1;
1031                         panel_click_distance = mousepos - panel_pos;
1032                         panel_click_resizeorigin = panel_pos + panel_size;
1033                         return;
1034                 }
1035                 // resize from topright border
1036                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
1037                 {
1038                         highlightedPanel = i;
1039                         HUD_Panel_FirstInDrawQ(i);
1040                         highlightedAction = 2;
1041                         resizeCorner = 2;
1042                         panel_click_distance_x = panel_size_x - mousepos_x + panel_pos_x;
1043                         panel_click_distance_y = mousepos_y - panel_pos_y;
1044                         panel_click_resizeorigin = panel_pos + eY * panel_size_y;
1045                         return;
1046                 }
1047                 // resize from bottomleft border
1048                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
1049                 {
1050                         highlightedPanel = i;
1051                         HUD_Panel_FirstInDrawQ(i);
1052                         highlightedAction = 2;
1053                         resizeCorner = 3;
1054                         panel_click_distance_x = mousepos_x - panel_pos_x;
1055                         panel_click_distance_y = panel_size_y - mousepos_y + panel_pos_y;
1056                         panel_click_resizeorigin = panel_pos + eX * panel_size_x;
1057                         return;
1058                 }
1059                 // resize from bottomright border
1060                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
1061                 {
1062                         highlightedPanel = i;
1063                         HUD_Panel_FirstInDrawQ(i);
1064                         highlightedAction = 2;
1065                         resizeCorner = 4;
1066                         panel_click_distance = panel_size - mousepos + panel_pos;
1067                         panel_click_resizeorigin = panel_pos;
1068                         return;
1069                 }
1070         }
1071         highlightedPanel = -1;
1072         highlightedAction = 0;
1073 }
1074
1075 void HUD_Panel_EnableMenu()
1076 {
1077         menu_enabled = 2;
1078         menu_enabled_time = time;
1079         localcmd("menu_showhudoptions ", hud_panel[highlightedPanel].panel_name, "\n");
1080 }
1081 float mouse_over_panel;
1082 void HUD_Panel_Mouse()
1083 {
1084         // TODO: needs better check... is there any float that contains the current state of the menu? _menu_alpha isn't apparently updated the frame the menu gets enabled
1085         if (autocvar__menu_alpha == 0 && time - menu_enabled_time > 0.5)
1086                 menu_enabled = 0;
1087
1088         /*
1089         print("menu_enabled: ", ftos(menu_enabled), "\n");
1090         print("Highlighted: ", ftos(highlightedPanel), "\n");
1091         print("Menu theAlpha: ", ftos(autocvar__menu_alpha), "\n");
1092         */
1093
1094         if(autocvar__menu_alpha == 1)
1095                 return;
1096
1097         if not(autocvar_hud_cursormode)
1098         {
1099                 mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
1100
1101                 mousepos_x = bound(0, mousepos_x, vid_conwidth);
1102                 mousepos_y = bound(0, mousepos_y, vid_conheight);
1103         }
1104
1105         if(mouseClicked)
1106         {
1107                 if(prevMouseClicked == 0)
1108                 {
1109                         if (tab_panel != -1)
1110                         {
1111                                 //stop ctrl-tab selection
1112                                 tab_panel = -1;
1113                                 reset_tab_panels();
1114                         }
1115                         HUD_Panel_Highlight(mouseClicked & S_MOUSE1); // sets highlightedPanel, highlightedAction, panel_click_distance, panel_click_resizeorigin
1116                                                                         // and calls HUD_Panel_UpdatePosSize() for the highlighted panel
1117                         if (highlightedPanel != -1)
1118                         {
1119                                 highlightedPanel_initial_pos = panel_pos;
1120                                 highlightedPanel_initial_size = panel_size;
1121                         }
1122                         // doubleclick check
1123                         if ((mouseClicked & S_MOUSE1) && time - prevMouseClickedTime < 0.4 && highlightedPanel != -1 && prevMouseClickedPos == mousepos)
1124                         {
1125                                 mouseClicked = 0; // to prevent spam, I guess.
1126                                 HUD_Panel_EnableMenu();
1127                         }
1128                         else
1129                         {
1130                                 if (mouseClicked & S_MOUSE1)
1131                                 {
1132                                         prevMouseClickedTime = time;
1133                                         prevMouseClickedPos = mousepos;
1134                                 }
1135                                 mouse_over_panel = HUD_Panel_Check_Mouse_Pos(mouseClicked & S_MOUSE1);
1136                         }
1137                 }
1138                 else
1139                 {
1140                         panel = hud_panel[highlightedPanel];
1141                         HUD_Panel_UpdatePosSize()
1142                 }
1143
1144                 if (highlightedPanel != -1)
1145                 {
1146                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1147                         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
1148                         {
1149                                 hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
1150                                 // backup!
1151                                 panel_pos_backup = highlightedPanel_initial_pos;
1152                                 panel_size_backup = highlightedPanel_initial_size;
1153                                 highlightedPanel_backup = highlightedPanel;
1154                         }
1155                         else
1156                                 // in case the clicked panel is inside another panel and we aren't
1157                                 // moving it, avoid the immediate "fix" of its position/size
1158                                 // (often unwanted and hateful) by disabling collisions check
1159                                 hud_configure_checkcollisions = false;
1160                 }
1161
1162                 if(highlightedAction == 1)
1163                         HUD_Panel_SetPos(mousepos - panel_click_distance);
1164                 else if(highlightedAction == 2)
1165                 {
1166                         vector mySize = '0 0 0';
1167                         if(resizeCorner == 1) {
1168                                 mySize_x = panel_click_resizeorigin_x - (mousepos_x - panel_click_distance_x);
1169                                 mySize_y = panel_click_resizeorigin_y - (mousepos_y - panel_click_distance_y);
1170                         } else if(resizeCorner == 2) {
1171                                 mySize_x = mousepos_x + panel_click_distance_x - panel_click_resizeorigin_x;
1172                                 mySize_y = panel_click_distance_y + panel_click_resizeorigin_y - mousepos_y;
1173                         } else if(resizeCorner == 3) {
1174                                 mySize_x = panel_click_resizeorigin_x + panel_click_distance_x - mousepos_x;
1175                                 mySize_y = mousepos_y + panel_click_distance_y - panel_click_resizeorigin_y;
1176                         } else { // resizeCorner == 4
1177                                 mySize_x = mousepos_x - (panel_click_resizeorigin_x - panel_click_distance_x);
1178                                 mySize_y = mousepos_y - (panel_click_resizeorigin_y - panel_click_distance_y);
1179                         }
1180                         HUD_Panel_SetPosSize(mySize);
1181                 }
1182         }
1183         else
1184         {
1185                 if(menu_enabled == 2)
1186                         mouse_over_panel = 0;
1187                 else
1188                         mouse_over_panel = HUD_Panel_Check_Mouse_Pos(TRUE);
1189                 if (mouse_over_panel && tab_panel == -1)
1190                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1191         }
1192         // draw cursor after performing move/resize to have the panel pos/size updated before mouse_over_panel
1193         const vector cursorsize = '32 32 0';
1194         float cursor_alpha = 1 - autocvar__menu_alpha;
1195
1196         if(!mouse_over_panel)
1197                 drawpic(mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1198         else if(mouse_over_panel == 1)
1199                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_move.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1200         else if(mouse_over_panel == 2)
1201                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1202         else
1203                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize2.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1204
1205         prevMouseClicked = mouseClicked;
1206 }
1207
1208 const float hlBorderSize = 4;
1209 const string hlBorder = "gfx/hud/default/border_highlighted";
1210 const string hlBorder2 = "gfx/hud/default/border_highlighted2";
1211 void HUD_Panel_HlBorder(float myBorder, vector color, float theAlpha)
1212 {
1213         drawfill(panel_pos - '1 1 0' * myBorder, panel_size + '2 2 0' * myBorder, '0 0.5 1', .5 * theAlpha, DRAWFLAG_NORMAL);
1214         drawpic_tiled(panel_pos - '1 1 0' * myBorder, hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1215         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * (panel_size_y + 2 * myBorder - hlBorderSize), hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1216         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize, hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1217         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize + eX * (panel_size_x + 2 * myBorder - hlBorderSize), hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1218 }