qcsrc/client/hud_config.qc

   1 #define HUD_Write(s) fputs(fh, s)
   2 // q: quoted, n: not quoted
   3 #define HUD_Write_Cvar_n(cvar) HUD_Write(strcat("seta ", cvar, " ", cvar_string(cvar), "\n"))
   4 #define HUD_Write_Cvar_q(cvar) HUD_Write(strcat("seta ", cvar, " \"", cvar_string(cvar), "\"\n"))
   5 #define HUD_Write_PanelCvar_n(cvar_suf) HUD_Write_Cvar_n(strcat("hud_panel_", panel_name, cvar_suf))
   6 #define HUD_Write_PanelCvar_q(cvar_suf) HUD_Write_Cvar_q(strcat("hud_panel_", panel_name, cvar_suf))
   7 // Save the config
   8 void HUD_Panel_ExportCfg(string cfgname)
   9 {
  10         float fh;
  11         string filename = strcat("hud_", autocvar_hud_skin, "_", cfgname, ".cfg");
  12         fh = fopen(filename, FILE_WRITE);
  13         if(fh >= 0)
  14         {
  15                 HUD_Write_Cvar_q("hud_skin");
  16                 HUD_Write_Cvar_q("hud_panel_bg");
  17                 HUD_Write_Cvar_q("hud_panel_bg_color");
  18                 HUD_Write_Cvar_q("hud_panel_bg_color_team");
  19                 HUD_Write_Cvar_q("hud_panel_bg_alpha");
  20                 HUD_Write_Cvar_q("hud_panel_bg_border");
  21                 HUD_Write_Cvar_q("hud_panel_bg_padding");
  22                 HUD_Write_Cvar_q("hud_panel_fg_alpha");
  23                 HUD_Write("\n");
  24
  25                 HUD_Write_Cvar_q("hud_dock");
  26                 HUD_Write_Cvar_q("hud_dock_color");
  27                 HUD_Write_Cvar_q("hud_dock_color_team");
  28                 HUD_Write_Cvar_q("hud_dock_alpha");
  29                 HUD_Write("\n");
  30
  31                 HUD_Write_Cvar_q("hud_progressbar_alpha");
  32                 HUD_Write_Cvar_q("hud_progressbar_strength_color");
  33                 HUD_Write_Cvar_q("hud_progressbar_shield_color");
  34                 HUD_Write_Cvar_q("hud_progressbar_health_color");
  35                 HUD_Write_Cvar_q("hud_progressbar_armor_color");
  36                 HUD_Write_Cvar_q("hud_progressbar_fuel_color");
  37                 HUD_Write_Cvar_q("hud_progressbar_nexball_color");
  38                 HUD_Write_Cvar_q("hud_progressbar_speed_color");
  39                 HUD_Write_Cvar_q("hud_progressbar_acceleration_color");
  40                 HUD_Write_Cvar_q("hud_progressbar_acceleration_neg_color");
  41                 HUD_Write("\n");
  42
  43                 HUD_Write_Cvar_q("_hud_panelorder");
  44                 HUD_Write("\n");
  45
  46                 HUD_Write_Cvar_q("hud_configure_grid");
  47                 HUD_Write_Cvar_q("hud_configure_grid_xsize");
  48                 HUD_Write_Cvar_q("hud_configure_grid_ysize");
  49                 HUD_Write("\n");
  50
  51                 // common cvars for all panels
  52                 float i;
  53                 for (i = 0; i < HUD_PANEL_NUM; ++i)
  54                 {
  55                         HUD_Panel_GetName(i);
  56
  57                         HUD_Write_PanelCvar_n("");
  58                         HUD_Write_PanelCvar_q("_pos");
  59                         HUD_Write_PanelCvar_q("_size");
  60                         HUD_Write_PanelCvar_q("_bg");
  61                         HUD_Write_PanelCvar_q("_bg_color");
  62                         HUD_Write_PanelCvar_q("_bg_color_team");
  63                         HUD_Write_PanelCvar_q("_bg_alpha");
  64                         HUD_Write_PanelCvar_q("_bg_border");
  65                         HUD_Write_PanelCvar_q("_bg_padding");
  66                         switch(i) {
  67                                 case HUD_PANEL_WEAPONS:
  68                                         HUD_Write_PanelCvar_q("_accuracy");
  69                                         HUD_Write_PanelCvar_q("_label");
  70                                         HUD_Write_PanelCvar_q("_complainbubble");
  71                                         HUD_Write_PanelCvar_q("_complainbubble_padding");
  72                                         HUD_Write_PanelCvar_q("_complainbubble_time");
  73                                         HUD_Write_PanelCvar_q("_complainbubble_fadetime");
  74                                         HUD_Write_PanelCvar_q("_complainbubble_color_outofammo");
  75                                         HUD_Write_PanelCvar_q("_complainbubble_color_donthave");
  76                                         HUD_Write_PanelCvar_q("_complainbubble_color_unavailable");
  77                                         HUD_Write_PanelCvar_q("_ammo");
  78                                         HUD_Write_PanelCvar_q("_ammo_color");
  79                                         HUD_Write_PanelCvar_q("_ammo_alpha");
  80                                         HUD_Write_PanelCvar_q("_aspect");
  81                                         HUD_Write_PanelCvar_q("_timeout");
  82                                         HUD_Write_PanelCvar_q("_timeout_effect");
  83                                         HUD_Write_PanelCvar_q("_timeout_fadebgmin");
  84                                         HUD_Write_PanelCvar_q("_timeout_fadefgmin");
  85                                         HUD_Write_PanelCvar_q("_timeout_speed_in");
  86                                         HUD_Write_PanelCvar_q("_timeout_speed_out");
  87                                         HUD_Write_PanelCvar_q("_onlyowned");
  88                                         break;
  89                                 case HUD_PANEL_AMMO:
  90                                         HUD_Write_PanelCvar_q("_onlycurrent");
  91                                         HUD_Write_PanelCvar_q("_iconalign");
  92                                         HUD_Write_PanelCvar_q("_progressbar");
  93                                         HUD_Write_PanelCvar_q("_progressbar_name");
  94                                         HUD_Write_PanelCvar_q("_progressbar_xoffset");
  95                                         HUD_Write_PanelCvar_q("_text");
  96                                         break;
  97                                 case HUD_PANEL_POWERUPS:
  98                                         HUD_Write_PanelCvar_q("_flip");
  99                                         HUD_Write_PanelCvar_q("_iconalign");
 100                                         HUD_Write_PanelCvar_q("_baralign");
 101                                         HUD_Write_PanelCvar_q("_progressbar");
 102                                         HUD_Write_PanelCvar_q("_progressbar_strength");
 103                                         HUD_Write_PanelCvar_q("_progressbar_shield");
 104                                         HUD_Write_PanelCvar_q("_text");
 105                                         break;
 106                                 case HUD_PANEL_HEALTHARMOR:
 107                                         HUD_Write_PanelCvar_q("_flip");
 108                                         HUD_Write_PanelCvar_q("_iconalign");
 109                                         HUD_Write_PanelCvar_q("_baralign");
 110                                         HUD_Write_PanelCvar_q("_progressbar");
 111                                         HUD_Write_PanelCvar_q("_progressbar_health");
 112                                         HUD_Write_PanelCvar_q("_progressbar_armor");
 113                                         HUD_Write_PanelCvar_q("_progressbar_gfx");
 114                                         HUD_Write_PanelCvar_q("_progressbar_gfx_smooth");
 115                                         HUD_Write_PanelCvar_q("_text");
 116                                         break;
 117                                 case HUD_PANEL_NOTIFY:
 118                                         HUD_Write_PanelCvar_q("_flip");
 119                                         HUD_Write_PanelCvar_q("_fontsize");
 120                                         HUD_Write_PanelCvar_q("_print");
 121                                         HUD_Write_PanelCvar_q("_time");
 122                                         HUD_Write_PanelCvar_q("_fadetime");
 123                                         break;
 124                                 case HUD_PANEL_TIMER:
 125                                         HUD_Write_PanelCvar_q("_increment");
 126                                         break;
 127                                 case HUD_PANEL_RADAR:
 128                                         HUD_Write_PanelCvar_q("_foreground_alpha");
 129                                         HUD_Write_PanelCvar_q("_rotation");
 130                                         HUD_Write_PanelCvar_q("_zoommode");
 131                                         HUD_Write_PanelCvar_q("_scale");
 132                                         HUD_Write_PanelCvar_q("_maximized_scale");
 133                                         HUD_Write_PanelCvar_q("_maximized_size");
 134                                         HUD_Write_PanelCvar_q("_maximized_rotation");
 135                                         HUD_Write_PanelCvar_q("_maximized_zoommode");
 136                                         break;
 137                                 case HUD_PANEL_SCORE:
 138                                         HUD_Write_PanelCvar_q("_rankings");
 139                                         break;
 140                                 case HUD_PANEL_VOTE:
 141                                         HUD_Write_PanelCvar_q("_alreadyvoted_alpha");
 142                                         break;
 143                                 case HUD_PANEL_MODICONS:
 144                                         HUD_Write_PanelCvar_q("_dom_layout");
 145                                         break;
 146                                 case HUD_PANEL_PRESSEDKEYS:
 147                                         HUD_Write_PanelCvar_q("_aspect");
 148                                         HUD_Write_PanelCvar_q("_attack");
 149                                         break;
 150                                 case HUD_PANEL_ENGINEINFO:
 151                                         HUD_Write_PanelCvar_q("_framecounter_time");
 152                                         HUD_Write_PanelCvar_q("_framecounter_decimals");
 153                                         break;
 154                                 case HUD_PANEL_INFOMESSAGES:
 155                                         HUD_Write_PanelCvar_q("_flip");
 156                                         break;
 157                                 case HUD_PANEL_PHYSICS:
 158                                         HUD_Write_PanelCvar_q("_speed_unit");
 159                                         HUD_Write_PanelCvar_q("_speed_unit_show");
 160                                         HUD_Write_PanelCvar_q("_speed_max");
 161                                         HUD_Write_PanelCvar_q("_speed_vertical");
 162                                         HUD_Write_PanelCvar_q("_topspeed");
 163                                         HUD_Write_PanelCvar_q("_topspeed_time");
 164                                         HUD_Write_PanelCvar_q("_acceleration_max");
 165                                         HUD_Write_PanelCvar_q("_acceleration_vertical");
 166                                         HUD_Write_PanelCvar_q("_flip");
 167                                         HUD_Write_PanelCvar_q("_baralign");
 168                                         HUD_Write_PanelCvar_q("_progressbar");
 169                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_mode");
 170                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_scale");
 171                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_nonlinear");
 172                                         HUD_Write_PanelCvar_q("_text");
 173                                         HUD_Write_PanelCvar_q("_text_scale");
 174                                         break;
 175                                 case HUD_PANEL_CENTERPRINT:
 176                                         HUD_Write_PanelCvar_q("_align");
 177                                         HUD_Write_PanelCvar_q("_flip");
 178                                         HUD_Write_PanelCvar_q("_fontscale");
 179                                         HUD_Write_PanelCvar_q("_time");
 180                                         HUD_Write_PanelCvar_q("_fade_in");
 181                                         HUD_Write_PanelCvar_q("_fade_out");
 182                                         HUD_Write_PanelCvar_q("_fade_subsequent");
 183                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone");
 184                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone_minalpha");
 185                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo");
 186                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo_minalpha");
 187                                         HUD_Write_PanelCvar_q("_fade_subsequent_minfontsize");
 188                                         HUD_Write_PanelCvar_q("_fade_minfontsize");
 189                                         break;
 190                         }
 191                         HUD_Write("\n");
 192                 }
 193                 HUD_Write("menu_sync\n"); // force the menu to reread the cvars, so that the dialogs are updated
 194
 195                 print(sprintf(_("^2Successfully exported to %s! (Note: It's saved in data/data/)\n"), filename));
 196                 fclose(fh);
 197         }
 198         else
 199                 print(sprintf(_("^1Couldn't write to %s\n"), filename));
 200 }
 201
 202 void HUD_Configure_Exit_Force()
 203 {
 204         if (menu_enabled)
 205         {
 206                 menu_enabled = 0;
 207                 localcmd("togglemenu\n");
 208         }
 209         cvar_set("_hud_configure", "0");
 210 }
 211
 212 // check if move will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 213 vector HUD_Panel_CheckMove(vector myPos, vector mySize)
 214 {
 215         float i;
 216         float myCenter_x, myCenter_y, targCenter_x, targCenter_y;
 217         vector myTarget;
 218         myTarget = myPos;
 219
 220         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 221                 if(i == highlightedPanel || !panel_enabled)
 222                         continue;
 223
 224                 HUD_Panel_UpdatePosSizeForId(i);
 225
 226                 panel_pos -= '1 1 0' * panel_bg_border;
 227                 panel_size += '2 2 0' * panel_bg_border;
 228
 229                 if(myPos_y + mySize_y < panel_pos_y)
 230                         continue;
 231                 if(myPos_y > panel_pos_y + panel_size_y)
 232                         continue;
 233
 234                 if(myPos_x + mySize_x < panel_pos_x)
 235                         continue;
 236                 if(myPos_x > panel_pos_x + panel_size_x)
 237                         continue;
 238
 239                 // OK, there IS a collision.
 240
 241                 myCenter_x = myPos_x + 0.5 * mySize_x;
 242                 myCenter_y = myPos_y + 0.5 * mySize_y;
 243
 244                 targCenter_x = panel_pos_x + 0.5 * panel_size_x;
 245                 targCenter_y = panel_pos_y + 0.5 * panel_size_y;
 246
 247                 if(myCenter_x < targCenter_x && myCenter_y < targCenter_y) // top left (of the target panel)
 248                 {
 249                         if(myPos_x + mySize_x - panel_pos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 250                                 myTarget_x = panel_pos_x - mySize_x;
 251                         else // push it upwards
 252                                 myTarget_y = panel_pos_y - mySize_y;
 253                 }
 254                 else if(myCenter_x > targCenter_x && myCenter_y < targCenter_y) // top right
 255                 {
 256                         if(panel_pos_x + panel_size_x - myPos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 257                                 myTarget_x = panel_pos_x + panel_size_x;
 258                         else // push it upwards
 259                                 myTarget_y = panel_pos_y - mySize_y;
 260                 }
 261                 else if(myCenter_x < targCenter_x && myCenter_y > targCenter_y) // bottom left
 262                 {
 263                         if(myPos_x + mySize_x - panel_pos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 264                                 myTarget_x = panel_pos_x - mySize_x;
 265                         else // push it downwards
 266                                 myTarget_y = panel_pos_y + panel_size_y;
 267                 }
 268                 else if(myCenter_x > targCenter_x && myCenter_y > targCenter_y) // bottom right
 269                 {
 270                         if(panel_pos_x + panel_size_x - myPos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 271                                 myTarget_x = panel_pos_x + panel_size_x;
 272                         else // push it downwards
 273                                 myTarget_y = panel_pos_y + panel_size_y;
 274                 }
 275                 //if(cvar("hud_configure_checkcollisions_debug"))
 276                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 277         }
 278
 279         return myTarget;
 280 }
 281
 282 void HUD_Panel_SetPos(vector pos)
 283 {
 284         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 285         vector mySize;
 286         mySize = panel_size;
 287
 288         //if(cvar("hud_configure_checkcollisions_debug"))
 289                 //drawfill(pos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 290
 291         if(autocvar_hud_configure_grid)
 292         {
 293                 pos_x = floor((pos_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 294                 pos_y = floor((pos_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 295         }
 296
 297         if(hud_configure_checkcollisions)
 298                 pos = HUD_Panel_CheckMove(pos, mySize);
 299
 300         pos_x = bound(0, pos_x, vid_conwidth - mySize_x);
 301         pos_y = bound(0, pos_y, vid_conheight - mySize_y);
 302
 303         string s;
 304         s = strcat(ftos(pos_x/vid_conwidth), " ", ftos(pos_y/vid_conheight));
 305
 306         HUD_Panel_GetName(highlightedPanel);
 307         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 308 }
 309
 310 // check if resize will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 311 vector HUD_Panel_CheckResize(vector mySize, vector resizeorigin) {
 312         float i;
 313
 314         vector targEndPos;
 315
 316         float dist_x, dist_y;
 317         float ratio;
 318         ratio = mySize_x/mySize_y;
 319
 320         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 321                 if(i == highlightedPanel || !panel_enabled)
 322                         continue;
 323
 324                 HUD_Panel_UpdatePosSizeForId(i);
 325
 326                 panel_pos -= '1 1 0' * panel_bg_border;
 327                 panel_size += '2 2 0' * panel_bg_border;
 328
 329                 targEndPos = panel_pos + panel_size;
 330
 331                 // resizeorigin is WITHIN target panel, just abort any collision testing against that particular panel to produce expected behaviour!
 332                 if(resizeorigin_x > panel_pos_x && resizeorigin_x < targEndPos_x && resizeorigin_y > panel_pos_y && resizeorigin_y < targEndPos_y)
 333                         continue;
 334
 335                 if (resizeCorner == 1)
 336                 {
 337                         // check if this panel is on our way
 338                         if (resizeorigin_x <= panel_pos_x)
 339                                 continue;
 340                         if (resizeorigin_y <= panel_pos_y)
 341                                 continue;
 342                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 343                                 continue;
 344                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 345                                 continue;
 346
 347                         // there is a collision:
 348                         // detect which side of the panel we are facing is actually limiting the resizing
 349                         // (which side the resize direction finds for first) and reduce the size up to there
 350                         //
 351                         // dist is the distance between resizeorigin and the "analogous" point of the panel
 352                         // in this case between resizeorigin (bottom-right point) and the bottom-right point of the panel
 353                         dist_x = resizeorigin_x - targEndPos_x;
 354                         dist_y = resizeorigin_y - targEndPos_y;
 355                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 356                                 mySize_x = min(mySize_x, dist_x);
 357                         else
 358                                 mySize_y = min(mySize_y, dist_y);
 359                 }
 360                 else if (resizeCorner == 2)
 361                 {
 362                         if (resizeorigin_x >= targEndPos_x)
 363                                 continue;
 364                         if (resizeorigin_y <= panel_pos_y)
 365                                 continue;
 366                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 367                                 continue;
 368                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 369                                 continue;
 370
 371                         dist_x = panel_pos_x - resizeorigin_x;
 372                         dist_y = resizeorigin_y - targEndPos_y;
 373                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 374                                 mySize_x = min(mySize_x, dist_x);
 375                         else
 376                                 mySize_y = min(mySize_y, dist_y);
 377                 }
 378                 else if (resizeCorner == 3)
 379                 {
 380                         if (resizeorigin_x <= panel_pos_x)
 381                                 continue;
 382                         if (resizeorigin_y >= targEndPos_y)
 383                                 continue;
 384                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 385                                 continue;
 386                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 387                                 continue;
 388
 389                         dist_x = resizeorigin_x - targEndPos_x;
 390                         dist_y = panel_pos_y - resizeorigin_y;
 391                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 392                                 mySize_x = min(mySize_x, dist_x);
 393                         else
 394                                 mySize_y = min(mySize_y, dist_y);
 395                 }
 396                 else if (resizeCorner == 4)
 397                 {
 398                         if (resizeorigin_x >= targEndPos_x)
 399                                 continue;
 400                         if (resizeorigin_y >= targEndPos_y)
 401                                 continue;
 402                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 403                                 continue;
 404                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 405                                 continue;
 406
 407                         dist_x = panel_pos_x - resizeorigin_x;
 408                         dist_y = panel_pos_y - resizeorigin_y;
 409                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 410                                 mySize_x = min(mySize_x, dist_x);
 411                         else
 412                                 mySize_y = min(mySize_y, dist_y);
 413                 }
 414                 //if(cvar("hud_configure_checkcollisions_debug"))
 415                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 416         }
 417
 418         return mySize;
 419 }
 420
 421 void HUD_Panel_SetPosSize(vector mySize)
 422 {
 423         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 424         vector resizeorigin;
 425         resizeorigin = panel_click_resizeorigin;
 426         local noref vector myPos; // fteqcc sucks
 427
 428         // minimum panel size cap
 429         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 430         mySize_y = max(0.025 * vid_conheight, mySize_y);
 431
 432         if(highlightedPanel == HUD_PANEL_CHAT) // some panels have their own restrictions, like the chat panel (which actually only moves the engine chat print around). Looks bad if it's too small.
 433         {
 434                 mySize_x = max(17 * autocvar_con_chatsize, mySize_x);
 435                 mySize_y = max(2 * autocvar_con_chatsize + 2 * panel_bg_padding, mySize_y);
 436         }
 437
 438         // collision testing|
 439         // -----------------+
 440
 441         // we need to know pos at this stage, but it might still change later if we hit a screen edge/other panel (?)
 442         if(resizeCorner == 1) {
 443                 myPos_x = resizeorigin_x - mySize_x;
 444                 myPos_y = resizeorigin_y - mySize_y;
 445         } else if(resizeCorner == 2) {
 446                 myPos_x = resizeorigin_x;
 447                 myPos_y = resizeorigin_y - mySize_y;
 448         } else if(resizeCorner == 3) {
 449                 myPos_x = resizeorigin_x - mySize_x;
 450                 myPos_y = resizeorigin_y;
 451         } else { // resizeCorner == 4
 452                 myPos_x = resizeorigin_x;
 453                 myPos_y = resizeorigin_y;
 454         }
 455
 456         // left/top screen edges
 457         if(myPos_x < 0)
 458                 mySize_x = mySize_x + myPos_x;
 459         if(myPos_y < 0)
 460                 mySize_y = mySize_y + myPos_y;
 461
 462         // bottom/right screen edges
 463         if(myPos_x + mySize_x > vid_conwidth)
 464                 mySize_x = vid_conwidth - myPos_x;
 465         if(myPos_y + mySize_y > vid_conheight)
 466                 mySize_y = vid_conheight - myPos_y;
 467
 468         //if(cvar("hud_configure_checkcollisions_debug"))
 469                 //drawfill(myPos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 470
 471         // before checkresize, otherwise panel can be snapped partially inside another panel or panel aspect ratio can be broken
 472         if(autocvar_hud_configure_grid)
 473         {
 474                 mySize_x = floor((mySize_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 475                 mySize_y = floor((mySize_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 476         }
 477
 478         if(hud_configure_checkcollisions)
 479                 mySize = HUD_Panel_CheckResize(mySize, resizeorigin);
 480
 481         // minimum panel size cap, do this once more so we NEVER EVER EVER have a panel smaller than this, JUST IN CASE above code still makes the panel eg negative (impossible to resize back without changing cvars manually then)
 482         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 483         mySize_y = max(0.025 * vid_conheight, mySize_y);
 484
 485         // do another pos check, as size might have changed by now
 486         if(resizeCorner == 1) {
 487                 myPos_x = resizeorigin_x - mySize_x;
 488                 myPos_y = resizeorigin_y - mySize_y;
 489         } else if(resizeCorner == 2) {
 490                 myPos_x = resizeorigin_x;
 491                 myPos_y = resizeorigin_y - mySize_y;
 492         } else if(resizeCorner == 3) {
 493                 myPos_x = resizeorigin_x - mySize_x;
 494                 myPos_y = resizeorigin_y;
 495         } else { // resizeCorner == 4
 496                 myPos_x = resizeorigin_x;
 497                 myPos_y = resizeorigin_y;
 498         }
 499
 500         //if(cvar("hud_configure_checkcollisions_debug"))
 501                 //drawfill(myPos, mySize, '0 1 0', .3, DRAWFLAG_NORMAL);
 502
 503         HUD_Panel_GetName(highlightedPanel);
 504         string s;
 505         s = strcat(ftos(mySize_x/vid_conwidth), " ", ftos(mySize_y/vid_conheight));
 506         cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 507
 508         s = strcat(ftos(myPos_x/vid_conwidth), " ", ftos(myPos_y/vid_conheight));
 509         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 510 }
 511
 512 float pressed_key_time;
 513 vector highlightedPanel_initial_pos, highlightedPanel_initial_size;
 514 void HUD_Panel_Arrow_Action(float nPrimary)
 515 {
 516         if (highlightedPanel == -1)
 517                 return;
 518
 519         hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
 520
 521         float step;
 522         if(autocvar_hud_configure_grid)
 523         {
 524                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 525                 {
 526                         if (hudShiftState & S_SHIFT)
 527                                 step = hud_configure_realGridSize_y;
 528                         else
 529                                 step = 2 * hud_configure_realGridSize_y;
 530                 }
 531                 else
 532                 {
 533                         if (hudShiftState & S_SHIFT)
 534                                 step = hud_configure_realGridSize_x;
 535                         else
 536                                 step = 2 * hud_configure_realGridSize_x;
 537                 }
 538         }
 539         else
 540         {
 541                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 542                         step = vid_conheight;
 543                 else
 544                         step = vid_conwidth;
 545                 if (hudShiftState & S_SHIFT)
 546                         step = (step / 256); // more precision
 547                 else
 548                         step = (step / 64) * (1 + 2 * (time - pressed_key_time));
 549         }
 550
 551         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 552
 553         highlightedPanel_initial_pos = panel_pos;
 554         highlightedPanel_initial_size = panel_size;
 555
 556         if (hudShiftState & S_ALT) // resize
 557         {
 558                 highlightedAction = 1;
 559                 if(nPrimary == K_UPARROW)
 560                         resizeCorner = 1;
 561                 else if(nPrimary == K_RIGHTARROW)
 562                         resizeCorner = 2;
 563                 else if(nPrimary == K_LEFTARROW)
 564                         resizeCorner = 3;
 565                 else // if(nPrimary == K_DOWNARROW)
 566                         resizeCorner = 4;
 567
 568                 // ctrl+arrow reduces the size, instead of increasing it
 569                 // Note that ctrl disables collisions check too, but it's fine
 570                 // since we don't collide with anything reducing the size
 571                 if (hudShiftState & S_CTRL) {
 572                         step = -step;
 573                         resizeCorner = 5 - resizeCorner;
 574                 }
 575
 576                 vector mySize;
 577                 mySize = panel_size;
 578                 panel_click_resizeorigin = panel_pos;
 579                 if(resizeCorner == 1) {
 580                         panel_click_resizeorigin += mySize;
 581                         mySize_y += step;
 582                 } else if(resizeCorner == 2) {
 583                         panel_click_resizeorigin_y += mySize_y;
 584                         mySize_x += step;
 585                 } else if(resizeCorner == 3) {
 586                         panel_click_resizeorigin_x += mySize_x;
 587                         mySize_x += step;
 588                 } else { // resizeCorner == 4
 589                         mySize_y += step;
 590                 }
 591                 HUD_Panel_SetPosSize(mySize);
 592         }
 593         else // move
 594         {
 595                 highlightedAction = 2;
 596                 vector pos;
 597                 pos = panel_pos;
 598                 if(nPrimary == K_UPARROW)
 599                         pos_y -= step;
 600                 else if(nPrimary == K_DOWNARROW)
 601                         pos_y += step;
 602                 else if(nPrimary == K_LEFTARROW)
 603                         pos_x -= step;
 604                 else // if(nPrimary == K_RIGHTARROW)
 605                         pos_x += step;
 606
 607                 HUD_Panel_SetPos(pos);
 608         }
 609
 610         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 611
 612         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
 613         {
 614                 // backup!
 615                 panel_pos_backup = highlightedPanel_initial_pos;
 616                 panel_size_backup = highlightedPanel_initial_size;
 617                 highlightedPanel_backup = highlightedPanel;
 618         }
 619 }
 620
 621 const float S_MOUSE1 = 1;
 622 const float S_MOUSE2 = 2;
 623 const float S_MOUSE3 = 4;
 624 float mouseClicked;
 625 float prevMouseClicked; // previous state
 626 float prevMouseClickedTime; // time during previous left mouse click, to check for doubleclicks
 627 vector prevMouseClickedPos; // pos during previous left mouse click, to check for doubleclicks
 628
 629 void HUD_Panel_EnableMenu();
 630 float tab_panels[HUD_PANEL_NUM];
 631 float tab_panel, tab_backward;
 632 vector tab_panel_pos;
 633 void HUD_Panel_FirstInDrawQ(float id);
 634 void reset_tab_panels()
 635 {
 636         int i;
 637         for(i = 0; i < HUD_PANEL_NUM; ++i)
 638                 tab_panels[i] = -1;
 639 }
 640 float HUD_Panel_InputEvent(float bInputType, float nPrimary, float nSecondary)
 641 {
 642         string s;
 643
 644         if(bInputType == 2)
 645                 return false;
 646
 647         if(!autocvar__hud_configure)
 648                 return false;
 649
 650         // block any input while a menu dialog is fading
 651         if(autocvar__menu_alpha)
 652                 return true;
 653
 654         if(bInputType == 3)
 655         {
 656                 mousepos_x = nPrimary;
 657                 mousepos_y = nSecondary;
 658                 return true;
 659         }
 660
 661         // allow console bind to work
 662         string con_keys;
 663         float keys;
 664         con_keys = findkeysforcommand("toggleconsole", 0);
 665         keys = tokenize(con_keys); // findkeysforcommand returns data for this
 666
 667         float hit_con_bind = 0, i;
 668         for (i = 0; i < keys; ++i)
 669         {
 670                 if(nPrimary == stof(argv(i)))
 671                         hit_con_bind = 1;
 672         }
 673
 674         if(bInputType == 0) {
 675                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 676                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 677                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 678         }
 679         else if(bInputType == 1) {
 680                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 681                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 682                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 683         }
 684
 685         if(nPrimary == K_CTRL)
 686         {
 687                 if (bInputType == 1) //ctrl has been released
 688                 {
 689                         if (tab_panel != -1)
 690                         {
 691                                 //switch to selected panel
 692                                 highlightedPanel = tab_panel;
 693                                 highlightedAction = 0;
 694                                 HUD_Panel_FirstInDrawQ(highlightedPanel);
 695                         }
 696                         tab_panel = -1;
 697                         reset_tab_panels();
 698                 }
 699         }
 700
 701         if(nPrimary == K_MOUSE1)
 702         {
 703                 if(bInputType == 0) // key pressed
 704                         mouseClicked |= S_MOUSE1;
 705                 else if(bInputType == 1) // key released
 706                         mouseClicked -= (mouseClicked & S_MOUSE1);
 707         }
 708         else if(nPrimary == K_MOUSE2)
 709         {
 710                 if(bInputType == 0) // key pressed
 711                         mouseClicked |= S_MOUSE2;
 712                 else if(bInputType == 1) // key released
 713                         mouseClicked -= (mouseClicked & S_MOUSE2);
 714         }
 715         else if(nPrimary == K_ESCAPE)
 716         {
 717                 if (bInputType == 1)
 718                         return true;
 719                 menu_enabled = 1;
 720                 menu_enabled_time = time;
 721                 localcmd("menu_showhudexit\n");
 722         }
 723         else if(nPrimary == K_BACKSPACE && hudShiftState & S_CTRL)
 724         {
 725                 if (bInputType == 1)
 726                         return true;
 727                 if (!menu_enabled)
 728                         cvar_set("_hud_configure", "0");
 729         }
 730         else if(nPrimary == K_TAB && hudShiftState & S_CTRL) // select and highlight another panel
 731         {
 732                 if (bInputType == 1 || mouseClicked)
 733                         return true;
 734
 735                 //FIXME: if a panel is highlighted, has the same pos_x and lays in the same level
 736                 //of other panels then next consecutive ctrl-tab will select the highlighted panel too
 737                 //(it should only after every other panel of the hud)
 738                 //It's a minor bug anyway, we can live with it
 739
 740                 float starting_panel;
 741                 float old_tab_panel = tab_panel;
 742                 if (tab_panel == -1) //first press of TAB
 743                 {
 744                         if (highlightedPanel != -1)
 745                                 HUD_Panel_UpdatePosSizeForId(highlightedPanel)
 746                         else
 747                                 panel_pos = '0 0 0';
 748                         starting_panel = highlightedPanel; //can be -1, it means no starting panel
 749                         tab_panel_pos = panel_pos; //to compute level
 750                 }
 751                 else
 752                 {
 753                         if ( ((!tab_backward) && (hudShiftState & S_SHIFT)) || (tab_backward && !(hudShiftState & S_SHIFT)) ) //tab direction changed?
 754                                 reset_tab_panels();
 755                         starting_panel = tab_panel;
 756                 }
 757                 tab_backward = (hudShiftState & S_SHIFT);
 758
 759                 float k, level = 0, start_pos_x;
 760                 vector candidate_pos = '0 0 0';
 761                 const float LEVELS_NUM = 4;
 762                 float level_height = vid_conheight / LEVELS_NUM;
 763 :find_tab_panel
 764                 level = floor(tab_panel_pos_y / level_height) * level_height; //starting level
 765                 candidate_pos_x = (!tab_backward) ? vid_conwidth : 0;
 766                 start_pos_x = tab_panel_pos_x;
 767                 tab_panel = -1;
 768                 k=0;
 769                 while(++k)
 770                 {
 771                         for(i = 0; i < HUD_PANEL_NUM; ++i)
 772                         {
 773                                 if (i == tab_panels[i] || i == starting_panel)
 774                                         continue;
 775                                 HUD_Panel_UpdatePosSizeForId(i)
 776                                 if (panel_pos_y >= level && (panel_pos_y - level) < level_height)
 777                                 if (  ( !tab_backward && panel_pos_x >= start_pos_x && (panel_pos_x < candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y <= candidate_pos_y)) )
 778                                         || ( tab_backward && panel_pos_x <= start_pos_x && (panel_pos_x > candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y >= candidate_pos_y)) )  )
 779                                 {
 780                                         tab_panel = i;
 781                                         tab_panel_pos = candidate_pos = panel_pos;
 782                                 }
 783                         }
 784                         if (tab_panel != -1)
 785                                 break;
 786                         if (k == LEVELS_NUM) //tab_panel not found
 787                         {
 788                                 reset_tab_panels();
 789                                 if (old_tab_panel == -2) //this prevents an infinite loop (should not happen normally)
 790                                 {
 791                                         tab_panel = -1;
 792                                         return true;
 793                                 }
 794                                 starting_panel = old_tab_panel;
 795                                 old_tab_panel = -2;
 796                                 goto find_tab_panel; //u must find tab_panel!
 797                         }
 798                         if (!tab_backward)
 799                         {
 800                                 level = mod(level + level_height, vid_conheight);
 801                                 start_pos_x = 0;
 802                                 candidate_pos_x = vid_conwidth;
 803                         }
 804                         else
 805                         {
 806                                 level = mod(level - level_height, vid_conheight);
 807                                 start_pos_x = vid_conwidth;
 808                                 candidate_pos_x = 0;
 809                         }
 810                 }
 811
 812                 tab_panels[tab_panel] = tab_panel;
 813         }
 814         else if(nPrimary == K_SPACE && hudShiftState & S_CTRL) // enable/disable highlighted panel or dock
 815         {
 816                 if (bInputType == 1 || mouseClicked)
 817                         return true;
 818
 819                 if (highlightedPanel != -1)
 820                 {
 821                         HUD_Panel_GetName(highlightedPanel);
 822                         cvar_set(strcat("hud_panel_", panel_name), ftos(!(panel_enabled)));
 823                 }
 824                 else
 825                         cvar_set(strcat("hud_dock"), (autocvar_hud_dock == "") ? "dock" : "");
 826         }
 827         else if(nPrimary == 'c' && hudShiftState & S_CTRL) // copy highlighted panel size
 828         {
 829                 if (bInputType == 1 || mouseClicked)
 830                         return true;
 831
 832                 if (highlightedPanel != -1)
 833                 {
 834                         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 835                         panel_size_copied = panel_size;
 836                         highlightedPanel_copied = highlightedPanel;
 837                 }
 838         }
 839         else if(nPrimary == 'v' && hudShiftState & S_CTRL) // past copied size on the highlighted panel
 840         {
 841                 if (bInputType == 1 || mouseClicked)
 842                         return true;
 843
 844                 if (highlightedPanel_copied == -1 || highlightedPanel == -1)
 845                         return true;
 846
 847                 HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 848
 849                 // reduce size if it'd go beyond screen boundaries
 850                 vector tmp_size = panel_size_copied;
 851                 if (panel_pos_x + panel_size_copied_x > vid_conwidth)
 852                         tmp_size_x = vid_conwidth - panel_pos_x;
 853                 if (panel_pos_y + panel_size_copied_y > vid_conheight)
 854                         tmp_size_y = vid_conheight - panel_pos_y;
 855
 856                 if (panel_size == tmp_size)
 857                         return true;
 858
 859                 // backup first!
 860                 panel_pos_backup = panel_pos;
 861                 panel_size_backup = panel_size;
 862                 highlightedPanel_backup = highlightedPanel;
 863
 864                 s = strcat(ftos(tmp_size_x/vid_conwidth), " ", ftos(tmp_size_y/vid_conheight));
 865                 HUD_Panel_GetName(highlightedPanel);
 866                 cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 867         }
 868         else if(nPrimary == 'z' && hudShiftState & S_CTRL) // undo last action
 869         {
 870                 if (bInputType == 1 || mouseClicked)
 871                         return true;
 872                 //restore previous values
 873                 if (highlightedPanel_backup != -1)
 874                 {
 875                         HUD_Panel_GetName(highlightedPanel_backup);
 876                         s = strcat(ftos(panel_pos_backup_x/vid_conwidth), " ", ftos(panel_pos_backup_y/vid_conheight));
 877                         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 878                         s = strcat(ftos(panel_size_backup_x/vid_conwidth), " ", ftos(panel_size_backup_y/vid_conheight));
 879                         cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 880                         highlightedPanel_backup = -1;
 881                 }
 882         }
 883         else if(nPrimary == K_UPARROW || nPrimary == K_DOWNARROW || nPrimary == K_LEFTARROW || nPrimary == K_RIGHTARROW)
 884         {
 885                 if (bInputType == 1)
 886                 {
 887                         pressed_key_time = 0;
 888                         return true;
 889                 }
 890                 else if (pressed_key_time == 0)
 891                         pressed_key_time = time;
 892
 893                 if (!mouseClicked)
 894                         HUD_Panel_Arrow_Action(nPrimary); //move or resize panel
 895         }
 896         else if(nPrimary == K_ENTER || nPrimary == K_SPACE || nPrimary == K_KP_ENTER)
 897         {
 898                 if (bInputType == 1)
 899                         return true;
 900                 if (highlightedPanel != -1)
 901                         HUD_Panel_EnableMenu();
 902         }
 903         else if(hit_con_bind)
 904                 return false;
 905
 906         return true;
 907 }
 908
 909 float HUD_Panel_Check_Mouse_Pos(float allow_move)
 910 {
 911         float i, j = 0, border;
 912
 913         while(j < HUD_PANEL_NUM)
 914         {
 915                 i = panel_order[j];
 916                 j += 1;
 917
 918                 HUD_Panel_UpdatePosSizeForId(i);
 919
 920                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 921
 922                 // move
 923                 if(allow_move && mousepos_x > panel_pos_x && mousepos_y > panel_pos_y && mousepos_x < panel_pos_x + panel_size_x && mousepos_y < panel_pos_y + panel_size_y)
 924                 {
 925                         return 1;
 926                 }
 927                 // resize from topleft border
 928                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 929                 {
 930                         return 2;
 931                 }
 932                 // resize from topright border
 933                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 934                 {
 935                         return 3;
 936                 }
 937                 // resize from bottomleft border
 938                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
 939                 {
 940                         return 3;
 941                 }
 942                 // resize from bottomright border
 943                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
 944                 {
 945                         return 2;
 946                 }
 947         }
 948         return 0;
 949 }
 950
 951 // move a panel to the beginning of the panel order array (which means it gets drawn last, on top of everything else)
 952 void HUD_Panel_FirstInDrawQ(float id)
 953 {
 954         float i;
 955         var float place = -1;
 956         // find out where in the array our current id is, save into place
 957         for(i = 0; i < HUD_PANEL_NUM; ++i)
 958         {
 959                 if(panel_order[i] == id)
 960                 {
 961                         place = i;
 962                         break;
 963                 }
 964         }
 965         // place last if we didn't find a place for it yet (probably new panel, or screwed up cvar)
 966         if(place == -1)
 967                 place = HUD_PANEL_NUM - 1;
 968
 969         // move all ids up by one step in the array until "place"
 970         for(i = place; i > 0; --i)
 971         {
 972                 panel_order[i] = panel_order[i-1];
 973         }
 974         // now save the new top id
 975         panel_order[0] = id;
 976
 977         // let's save them into the cvar by some strcat trickery
 978         string s = "";
 979         for(i = 0; i < HUD_PANEL_NUM; ++i)
 980         {
 981                 s = strcat(s, ftos(panel_order[i]), " ");
 982         }
 983         cvar_set("_hud_panelorder", s);
 984         if(hud_panelorder_prev)
 985                 strunzone(hud_panelorder_prev);
 986         hud_panelorder_prev = strzone(autocvar__hud_panelorder); // prevent HUD_Main from doing useless update, we already updated here
 987 }
 988
 989 void HUD_Panel_Highlight(float allow_move)
 990 {
 991         float i, j = 0, border;
 992
 993         while(j < HUD_PANEL_NUM)
 994         {
 995                 i = panel_order[j];
 996                 j += 1;
 997
 998                 HUD_Panel_UpdatePosSizeForId(i);
 999
1000                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
1001
1002                 // move
1003                 if(allow_move && mousepos_x > panel_pos_x && mousepos_y > panel_pos_y && mousepos_x < panel_pos_x + panel_size_x && mousepos_y < panel_pos_y + panel_size_y)
1004                 {
1005                         highlightedPanel = i;
1006                         HUD_Panel_FirstInDrawQ(i);
1007                         highlightedAction = 1;
1008                         panel_click_distance = mousepos - panel_pos;
1009                         return;
1010                 }
1011                 // resize from topleft border
1012                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
1013                 {
1014                         highlightedPanel = i;
1015                         HUD_Panel_FirstInDrawQ(i);
1016                         highlightedAction = 2;
1017                         resizeCorner = 1;
1018                         panel_click_distance = mousepos - panel_pos;
1019                         panel_click_resizeorigin = panel_pos + panel_size;
1020                         return;
1021                 }
1022                 // resize from topright border
1023                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
1024                 {
1025                         highlightedPanel = i;
1026                         HUD_Panel_FirstInDrawQ(i);
1027                         highlightedAction = 2;
1028                         resizeCorner = 2;
1029                         panel_click_distance_x = panel_size_x - mousepos_x + panel_pos_x;
1030                         panel_click_distance_y = mousepos_y - panel_pos_y;
1031                         panel_click_resizeorigin = panel_pos + eY * panel_size_y;
1032                         return;
1033                 }
1034                 // resize from bottomleft border
1035                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
1036                 {
1037                         highlightedPanel = i;
1038                         HUD_Panel_FirstInDrawQ(i);
1039                         highlightedAction = 2;
1040                         resizeCorner = 3;
1041                         panel_click_distance_x = mousepos_x - panel_pos_x;
1042                         panel_click_distance_y = panel_size_y - mousepos_y + panel_pos_y;
1043                         panel_click_resizeorigin = panel_pos + eX * panel_size_x;
1044                         return;
1045                 }
1046                 // resize from bottomright border
1047                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
1048                 {
1049                         highlightedPanel = i;
1050                         HUD_Panel_FirstInDrawQ(i);
1051                         highlightedAction = 2;
1052                         resizeCorner = 4;
1053                         panel_click_distance = panel_size - mousepos + panel_pos;
1054                         panel_click_resizeorigin = panel_pos;
1055                         return;
1056                 }
1057         }
1058         highlightedPanel = -1;
1059         highlightedAction = 0;
1060 }
1061
1062 void HUD_Panel_EnableMenu()
1063 {
1064         menu_enabled = 2;
1065         menu_enabled_time = time;
1066         HUD_Panel_GetName(highlightedPanel);
1067         localcmd("menu_showhudoptions ", panel_name, "\n");
1068 }
1069 float mouse_over_panel;
1070 void HUD_Panel_Mouse()
1071 {
1072         // TODO: needs better check... is there any float that contains the current state of the menu? _menu_alpha isn't apparently updated the frame the menu gets enabled
1073         if (autocvar__menu_alpha == 0 && time - menu_enabled_time > 0.5)
1074                 menu_enabled = 0;
1075
1076         /*
1077         print("menu_enabled: ", ftos(menu_enabled), "\n");
1078         print("Highlighted: ", ftos(highlightedPanel), "\n");
1079         print("Menu theAlpha: ", ftos(autocvar__menu_alpha), "\n");
1080         */
1081
1082         if(autocvar__menu_alpha == 1)
1083                 return;
1084
1085         if not(autocvar_hud_cursormode)
1086         {
1087                 mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
1088
1089                 mousepos_x = bound(0, mousepos_x, vid_conwidth);
1090                 mousepos_y = bound(0, mousepos_y, vid_conheight);
1091         }
1092
1093         if(mouseClicked)
1094         {
1095                 if(prevMouseClicked == 0)
1096                 {
1097                         if (tab_panel != -1)
1098                         {
1099                                 //stop ctrl-tab selection
1100                                 tab_panel = -1;
1101                                 reset_tab_panels();
1102                         }
1103                         HUD_Panel_Highlight(mouseClicked & S_MOUSE1); // sets highlightedPanel, highlightedAction, panel_click_distance, panel_click_resizeorigin
1104                                                                         // and calls HUD_Panel_UpdatePosSizeForId() for the highlighted panel
1105                         if (highlightedPanel != -1)
1106                         {
1107                                 highlightedPanel_initial_pos = panel_pos;
1108                                 highlightedPanel_initial_size = panel_size;
1109                         }
1110                         // doubleclick check
1111                         if ((mouseClicked & S_MOUSE1) && time - prevMouseClickedTime < 0.4 && highlightedPanel != -1 && prevMouseClickedPos == mousepos)
1112                         {
1113                                 mouseClicked = 0; // to prevent spam, I guess.
1114                                 HUD_Panel_EnableMenu();
1115                         }
1116                         else
1117                         {
1118                                 if (mouseClicked & S_MOUSE1)
1119                                 {
1120                                         prevMouseClickedTime = time;
1121                                         prevMouseClickedPos = mousepos;
1122                                 }
1123                                 mouse_over_panel = HUD_Panel_Check_Mouse_Pos(mouseClicked & S_MOUSE1);
1124                         }
1125                 }
1126                 else
1127                         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
1128
1129                 if (highlightedPanel != -1)
1130                 {
1131                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1132                         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
1133                         {
1134                                 hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
1135                                 // backup!
1136                                 panel_pos_backup = highlightedPanel_initial_pos;
1137                                 panel_size_backup = highlightedPanel_initial_size;
1138                                 highlightedPanel_backup = highlightedPanel;
1139                         }
1140                         else
1141                                 // in case the clicked panel is inside another panel and we aren't
1142                                 // moving it, avoid the immediate "fix" of its position/size
1143                                 // (often unwanted and hateful) by disabling collisions check
1144                                 hud_configure_checkcollisions = false;
1145                 }
1146
1147                 if(highlightedAction == 1)
1148                         HUD_Panel_SetPos(mousepos - panel_click_distance);
1149                 else if(highlightedAction == 2)
1150                 {
1151                         vector mySize = '0 0 0';
1152                         if(resizeCorner == 1) {
1153                                 mySize_x = panel_click_resizeorigin_x - (mousepos_x - panel_click_distance_x);
1154                                 mySize_y = panel_click_resizeorigin_y - (mousepos_y - panel_click_distance_y);
1155                         } else if(resizeCorner == 2) {
1156                                 mySize_x = mousepos_x + panel_click_distance_x - panel_click_resizeorigin_x;
1157                                 mySize_y = panel_click_distance_y + panel_click_resizeorigin_y - mousepos_y;
1158                         } else if(resizeCorner == 3) {
1159                                 mySize_x = panel_click_resizeorigin_x + panel_click_distance_x - mousepos_x;
1160                                 mySize_y = mousepos_y + panel_click_distance_y - panel_click_resizeorigin_y;
1161                         } else { // resizeCorner == 4
1162                                 mySize_x = mousepos_x - (panel_click_resizeorigin_x - panel_click_distance_x);
1163                                 mySize_y = mousepos_y - (panel_click_resizeorigin_y - panel_click_distance_y);
1164                         }
1165                         HUD_Panel_SetPosSize(mySize);
1166                 }
1167         }
1168         else
1169         {
1170                 if(menu_enabled == 2)
1171                         mouse_over_panel = 0;
1172                 else
1173                         mouse_over_panel = HUD_Panel_Check_Mouse_Pos(TRUE);
1174                 if (mouse_over_panel && tab_panel == -1)
1175                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1176         }
1177         // draw cursor after performing move/resize to have the panel pos/size updated before mouse_over_panel
1178         const vector cursorsize = '32 32 0';
1179         float cursor_alpha = 1 - autocvar__menu_alpha;
1180
1181         if(!mouse_over_panel)
1182                 drawpic(mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1183         else if(mouse_over_panel == 1)
1184                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_move.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1185         else if(mouse_over_panel == 2)
1186                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1187         else
1188                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize2.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1189
1190         prevMouseClicked = mouseClicked;
1191 }
1192
1193 const float hlBorderSize = 4;
1194 const string hlBorder = "gfx/hud/default/border_highlighted";
1195 const string hlBorder2 = "gfx/hud/default/border_highlighted2";
1196 void HUD_Panel_HlBorder(float myBorder, vector color, float theAlpha)
1197 {
1198         drawfill(panel_pos - '1 1 0' * myBorder, panel_size + '2 2 0' * myBorder, '0 0.5 1', .5 * theAlpha, DRAWFLAG_NORMAL);
1199         drawpic_tiled(panel_pos - '1 1 0' * myBorder, hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1200         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * (panel_size_y + 2 * myBorder - hlBorderSize), hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1201         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize, hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1202         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize + eX * (panel_size_x + 2 * myBorder - hlBorderSize), hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1203 }