qcsrc/client/hud_config.qc

   1 #define HUD_Write(s) fputs(fh, s)
   2 // q: quoted, n: not quoted
   3 #define HUD_Write_Cvar_n(cvar) HUD_Write(strcat("seta ", cvar, " ", cvar_string(cvar), "\n"))
   4 #define HUD_Write_Cvar_q(cvar) HUD_Write(strcat("seta ", cvar, " \"", cvar_string(cvar), "\"\n"))
   5 #define HUD_Write_PanelCvar_n(cvar_suf) HUD_Write_Cvar_n(strcat("hud_panel_", panel.panel_name, cvar_suf))
   6 #define HUD_Write_PanelCvar_q(cvar_suf) HUD_Write_Cvar_q(strcat("hud_panel_", panel.panel_name, cvar_suf))
   7 // Save the config
   8 void HUD_Panel_ExportCfg(string cfgname)
   9 {
  10         float fh;
  11         string filename = strcat("hud_", autocvar_hud_skin, "_", cfgname, ".cfg");
  12         fh = fopen(filename, FILE_WRITE);
  13         if(fh >= 0)
  14         {
  15                 HUD_Write_Cvar_q("hud_skin");
  16                 HUD_Write_Cvar_q("hud_panel_bg");
  17                 HUD_Write_Cvar_q("hud_panel_bg_color");
  18                 HUD_Write_Cvar_q("hud_panel_bg_color_team");
  19                 HUD_Write_Cvar_q("hud_panel_bg_alpha");
  20                 HUD_Write_Cvar_q("hud_panel_bg_border");
  21                 HUD_Write_Cvar_q("hud_panel_bg_padding");
  22                 HUD_Write_Cvar_q("hud_panel_fg_alpha");
  23                 HUD_Write("\n");
  24
  25                 HUD_Write_Cvar_q("hud_dock");
  26                 HUD_Write_Cvar_q("hud_dock_color");
  27                 HUD_Write_Cvar_q("hud_dock_color_team");
  28                 HUD_Write_Cvar_q("hud_dock_alpha");
  29                 HUD_Write("\n");
  30
  31                 HUD_Write_Cvar_q("hud_progressbar_alpha");
  32                 HUD_Write_Cvar_q("hud_progressbar_strength_color");
  33                 HUD_Write_Cvar_q("hud_progressbar_shield_color");
  34                 HUD_Write_Cvar_q("hud_progressbar_health_color");
  35                 HUD_Write_Cvar_q("hud_progressbar_armor_color");
  36                 HUD_Write_Cvar_q("hud_progressbar_fuel_color");
  37                 HUD_Write_Cvar_q("hud_progressbar_nexball_color");
  38                 HUD_Write_Cvar_q("hud_progressbar_speed_color");
  39                 HUD_Write_Cvar_q("hud_progressbar_acceleration_color");
  40                 HUD_Write_Cvar_q("hud_progressbar_acceleration_neg_color");
  41                 HUD_Write("\n");
  42
  43                 HUD_Write_Cvar_q("_hud_panelorder");
  44                 HUD_Write("\n");
  45
  46                 HUD_Write_Cvar_q("hud_configure_grid");
  47                 HUD_Write_Cvar_q("hud_configure_grid_xsize");
  48                 HUD_Write_Cvar_q("hud_configure_grid_ysize");
  49                 HUD_Write("\n");
  50
  51                 // common cvars for all panels
  52                 float i;
  53                 for (i = 0; i < HUD_PANEL_NUM; ++i)
  54                 {
  55                         panel = hud_panel[i];
  56
  57                         HUD_Write_PanelCvar_n("");
  58                         HUD_Write_PanelCvar_q("_pos");
  59                         HUD_Write_PanelCvar_q("_size");
  60                         HUD_Write_PanelCvar_q("_bg");
  61                         HUD_Write_PanelCvar_q("_bg_color");
  62                         HUD_Write_PanelCvar_q("_bg_color_team");
  63                         HUD_Write_PanelCvar_q("_bg_alpha");
  64                         HUD_Write_PanelCvar_q("_bg_border");
  65                         HUD_Write_PanelCvar_q("_bg_padding");
  66                         switch(i) {
  67                                 case HUD_PANEL_WEAPONS:
  68                                         HUD_Write_PanelCvar_q("_accuracy");
  69                                         HUD_Write_PanelCvar_q("_label");
  70                                         HUD_Write_PanelCvar_q("_complainbubble");
  71                                         HUD_Write_PanelCvar_q("_complainbubble_padding");
  72                                         HUD_Write_PanelCvar_q("_complainbubble_time");
  73                                         HUD_Write_PanelCvar_q("_complainbubble_fadetime");
  74                                         HUD_Write_PanelCvar_q("_complainbubble_color_outofammo");
  75                                         HUD_Write_PanelCvar_q("_complainbubble_color_donthave");
  76                                         HUD_Write_PanelCvar_q("_complainbubble_color_unavailable");
  77                                         HUD_Write_PanelCvar_q("_ammo");
  78                                         HUD_Write_PanelCvar_q("_ammo_color");
  79                                         HUD_Write_PanelCvar_q("_ammo_alpha");
  80                                         HUD_Write_PanelCvar_q("_aspect");
  81                                         HUD_Write_PanelCvar_q("_timeout");
  82                                         HUD_Write_PanelCvar_q("_timeout_effect");
  83                                         HUD_Write_PanelCvar_q("_timeout_fadebgmin");
  84                                         HUD_Write_PanelCvar_q("_timeout_fadefgmin");
  85                                         HUD_Write_PanelCvar_q("_timeout_speed_in");
  86                                         HUD_Write_PanelCvar_q("_timeout_speed_out");
  87                                         HUD_Write_PanelCvar_q("_onlyowned");
  88                                         break;
  89                                 case HUD_PANEL_AMMO:
  90                                         HUD_Write_PanelCvar_q("_onlycurrent");
  91                                         HUD_Write_PanelCvar_q("_iconalign");
  92                                         HUD_Write_PanelCvar_q("_progressbar");
  93                                         HUD_Write_PanelCvar_q("_progressbar_name");
  94                                         HUD_Write_PanelCvar_q("_progressbar_xoffset");
  95                                         HUD_Write_PanelCvar_q("_text");
  96                                         break;
  97                                 case HUD_PANEL_POWERUPS:
  98                                         HUD_Write_PanelCvar_q("_flip");
  99                                         HUD_Write_PanelCvar_q("_iconalign");
 100                                         HUD_Write_PanelCvar_q("_baralign");
 101                                         HUD_Write_PanelCvar_q("_progressbar");
 102                                         HUD_Write_PanelCvar_q("_progressbar_strength");
 103                                         HUD_Write_PanelCvar_q("_progressbar_shield");
 104                                         HUD_Write_PanelCvar_q("_text");
 105                                         break;
 106                                 case HUD_PANEL_HEALTHARMOR:
 107                                         HUD_Write_PanelCvar_q("_flip");
 108                                         HUD_Write_PanelCvar_q("_iconalign");
 109                                         HUD_Write_PanelCvar_q("_baralign");
 110                                         HUD_Write_PanelCvar_q("_progressbar");
 111                                         HUD_Write_PanelCvar_q("_progressbar_health");
 112                                         HUD_Write_PanelCvar_q("_progressbar_armor");
 113                                         HUD_Write_PanelCvar_q("_progressbar_gfx");
 114                                         HUD_Write_PanelCvar_q("_progressbar_gfx_smooth");
 115                                         HUD_Write_PanelCvar_q("_text");
 116                                         break;
 117                                 case HUD_PANEL_NOTIFY:
 118                                         HUD_Write_PanelCvar_q("_flip");
 119                                         HUD_Write_PanelCvar_q("_fontsize");
 120                                         HUD_Write_PanelCvar_q("_time");
 121                                         HUD_Write_PanelCvar_q("_fadetime");
 122                                         break;
 123                                 case HUD_PANEL_TIMER:
 124                                         HUD_Write_PanelCvar_q("_increment");
 125                                         break;
 126                                 case HUD_PANEL_RADAR:
 127                                         HUD_Write_PanelCvar_q("_foreground_alpha");
 128                                         HUD_Write_PanelCvar_q("_rotation");
 129                                         HUD_Write_PanelCvar_q("_zoommode");
 130                                         HUD_Write_PanelCvar_q("_scale");
 131                                         HUD_Write_PanelCvar_q("_maximized_scale");
 132                                         HUD_Write_PanelCvar_q("_maximized_size");
 133                                         HUD_Write_PanelCvar_q("_maximized_rotation");
 134                                         HUD_Write_PanelCvar_q("_maximized_zoommode");
 135                                         break;
 136                                 case HUD_PANEL_SCORE:
 137                                         HUD_Write_PanelCvar_q("_rankings");
 138                                         break;
 139                                 case HUD_PANEL_VOTE:
 140                                         HUD_Write_PanelCvar_q("_alreadyvoted_alpha");
 141                                         break;
 142                                 case HUD_PANEL_MODICONS:
 143                                         HUD_Write_PanelCvar_q("_dom_layout");
 144                                         break;
 145                                 case HUD_PANEL_PRESSEDKEYS:
 146                                         HUD_Write_PanelCvar_q("_aspect");
 147                                         HUD_Write_PanelCvar_q("_attack");
 148                                         break;
 149                                 case HUD_PANEL_ENGINEINFO:
 150                                         HUD_Write_PanelCvar_q("_framecounter_time");
 151                                         HUD_Write_PanelCvar_q("_framecounter_decimals");
 152                                         break;
 153                                 case HUD_PANEL_INFOMESSAGES:
 154                                         HUD_Write_PanelCvar_q("_flip");
 155                                         break;
 156                                 case HUD_PANEL_PHYSICS:
 157                                         HUD_Write_PanelCvar_q("_speed_unit");
 158                                         HUD_Write_PanelCvar_q("_speed_unit_show");
 159                                         HUD_Write_PanelCvar_q("_speed_max");
 160                                         HUD_Write_PanelCvar_q("_speed_vertical");
 161                                         HUD_Write_PanelCvar_q("_topspeed");
 162                                         HUD_Write_PanelCvar_q("_topspeed_time");
 163                                         HUD_Write_PanelCvar_q("_acceleration_max");
 164                                         HUD_Write_PanelCvar_q("_acceleration_vertical");
 165                                         HUD_Write_PanelCvar_q("_flip");
 166                                         HUD_Write_PanelCvar_q("_baralign");
 167                                         HUD_Write_PanelCvar_q("_progressbar");
 168                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_mode");
 169                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_scale");
 170                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_nonlinear");
 171                                         HUD_Write_PanelCvar_q("_text");
 172                                         HUD_Write_PanelCvar_q("_text_scale");
 173                                         break;
 174                                 case HUD_PANEL_CENTERPRINT:
 175                                         HUD_Write_PanelCvar_q("_align");
 176                                         HUD_Write_PanelCvar_q("_flip");
 177                                         HUD_Write_PanelCvar_q("_fontscale");
 178                                         HUD_Write_PanelCvar_q("_time");
 179                                         HUD_Write_PanelCvar_q("_fade_in");
 180                                         HUD_Write_PanelCvar_q("_fade_out");
 181                                         HUD_Write_PanelCvar_q("_fade_subsequent");
 182                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone");
 183                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone_minalpha");
 184                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo");
 185                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo_minalpha");
 186                                         HUD_Write_PanelCvar_q("_fade_subsequent_minfontsize");
 187                                         HUD_Write_PanelCvar_q("_fade_minfontsize");
 188                                         break;
 189                         }
 190                         HUD_Write("\n");
 191                 }
 192                 HUD_Write("menu_sync\n"); // force the menu to reread the cvars, so that the dialogs are updated
 193
 194                 print(sprintf(_("^2Successfully exported to %s! (Note: It's saved in data/data/)\n"), filename));
 195                 fclose(fh);
 196         }
 197         else
 198                 print(sprintf(_("^1Couldn't write to %s\n"), filename));
 199 }
 200
 201 void HUD_Configure_Exit_Force()
 202 {
 203         if (menu_enabled)
 204         {
 205                 menu_enabled = 0;
 206                 localcmd("togglemenu\n");
 207         }
 208         cvar_set("_hud_configure", "0");
 209 }
 210
 211 // check if move will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 212 vector HUD_Panel_CheckMove(vector myPos, vector mySize)
 213 {
 214         float i;
 215         float myCenter_x, myCenter_y, targCenter_x, targCenter_y;
 216         vector myTarget;
 217         myTarget = myPos;
 218
 219         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 220                 panel = hud_panel[i];
 221                 if(panel == highlightedPanel) continue;
 222                 HUD_Panel_UpdatePosSize()
 223                 if(!panel_enabled) continue;
 224
 225                 panel_pos -= '1 1 0' * panel_bg_border;
 226                 panel_size += '2 2 0' * panel_bg_border;
 227
 228                 if(myPos_y + mySize_y < panel_pos_y)
 229                         continue;
 230                 if(myPos_y > panel_pos_y + panel_size_y)
 231                         continue;
 232
 233                 if(myPos_x + mySize_x < panel_pos_x)
 234                         continue;
 235                 if(myPos_x > panel_pos_x + panel_size_x)
 236                         continue;
 237
 238                 // OK, there IS a collision.
 239
 240                 myCenter_x = myPos_x + 0.5 * mySize_x;
 241                 myCenter_y = myPos_y + 0.5 * mySize_y;
 242
 243                 targCenter_x = panel_pos_x + 0.5 * panel_size_x;
 244                 targCenter_y = panel_pos_y + 0.5 * panel_size_y;
 245
 246                 if(myCenter_x < targCenter_x && myCenter_y < targCenter_y) // top left (of the target panel)
 247                 {
 248                         if(myPos_x + mySize_x - panel_pos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 249                                 myTarget_x = panel_pos_x - mySize_x;
 250                         else // push it upwards
 251                                 myTarget_y = panel_pos_y - mySize_y;
 252                 }
 253                 else if(myCenter_x > targCenter_x && myCenter_y < targCenter_y) // top right
 254                 {
 255                         if(panel_pos_x + panel_size_x - myPos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 256                                 myTarget_x = panel_pos_x + panel_size_x;
 257                         else // push it upwards
 258                                 myTarget_y = panel_pos_y - mySize_y;
 259                 }
 260                 else if(myCenter_x < targCenter_x && myCenter_y > targCenter_y) // bottom left
 261                 {
 262                         if(myPos_x + mySize_x - panel_pos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 263                                 myTarget_x = panel_pos_x - mySize_x;
 264                         else // push it downwards
 265                                 myTarget_y = panel_pos_y + panel_size_y;
 266                 }
 267                 else if(myCenter_x > targCenter_x && myCenter_y > targCenter_y) // bottom right
 268                 {
 269                         if(panel_pos_x + panel_size_x - myPos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 270                                 myTarget_x = panel_pos_x + panel_size_x;
 271                         else // push it downwards
 272                                 myTarget_y = panel_pos_y + panel_size_y;
 273                 }
 274                 //if(cvar("hud_configure_checkcollisions_debug"))
 275                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 276         }
 277
 278         return myTarget;
 279 }
 280
 281 void HUD_Panel_SetPos(vector pos)
 282 {
 283         panel = highlightedPanel;
 284         HUD_Panel_UpdatePosSize()
 285         vector mySize;
 286         mySize = panel_size;
 287
 288         //if(cvar("hud_configure_checkcollisions_debug"))
 289                 //drawfill(pos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 290
 291         if(autocvar_hud_configure_grid)
 292         {
 293                 pos_x = floor((pos_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 294                 pos_y = floor((pos_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 295         }
 296
 297         if(hud_configure_checkcollisions)
 298                 pos = HUD_Panel_CheckMove(pos, mySize);
 299
 300         pos_x = bound(0, pos_x, vid_conwidth - mySize_x);
 301         pos_y = bound(0, pos_y, vid_conheight - mySize_y);
 302
 303         string s;
 304         s = strcat(ftos(pos_x/vid_conwidth), " ", ftos(pos_y/vid_conheight));
 305
 306         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_pos"), s);
 307 }
 308
 309 // check if resize will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 310 vector HUD_Panel_CheckResize(vector mySize, vector resizeorigin) {
 311         float i;
 312
 313         vector targEndPos;
 314
 315         float dist_x, dist_y;
 316         float ratio;
 317         ratio = mySize_x/mySize_y;
 318
 319         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 320                 panel = hud_panel[i];
 321                 if(panel == highlightedPanel) continue;
 322                 HUD_Panel_UpdatePosSize()
 323                 if(!panel_enabled) continue;
 324
 325                 panel_pos -= '1 1 0' * panel_bg_border;
 326                 panel_size += '2 2 0' * panel_bg_border;
 327
 328                 targEndPos = panel_pos + panel_size;
 329
 330                 // resizeorigin is WITHIN target panel, just abort any collision testing against that particular panel to produce expected behaviour!
 331                 if(resizeorigin_x > panel_pos_x && resizeorigin_x < targEndPos_x && resizeorigin_y > panel_pos_y && resizeorigin_y < targEndPos_y)
 332                         continue;
 333
 334                 if (resizeCorner == 1)
 335                 {
 336                         // check if this panel is on our way
 337                         if (resizeorigin_x <= panel_pos_x)
 338                                 continue;
 339                         if (resizeorigin_y <= panel_pos_y)
 340                                 continue;
 341                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 342                                 continue;
 343                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 344                                 continue;
 345
 346                         // there is a collision:
 347                         // detect which side of the panel we are facing is actually limiting the resizing
 348                         // (which side the resize direction finds for first) and reduce the size up to there
 349                         //
 350                         // dist is the distance between resizeorigin and the "analogous" point of the panel
 351                         // in this case between resizeorigin (bottom-right point) and the bottom-right point of the panel
 352                         dist_x = resizeorigin_x - targEndPos_x;
 353                         dist_y = resizeorigin_y - targEndPos_y;
 354                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 355                                 mySize_x = min(mySize_x, dist_x);
 356                         else
 357                                 mySize_y = min(mySize_y, dist_y);
 358                 }
 359                 else if (resizeCorner == 2)
 360                 {
 361                         if (resizeorigin_x >= targEndPos_x)
 362                                 continue;
 363                         if (resizeorigin_y <= panel_pos_y)
 364                                 continue;
 365                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 366                                 continue;
 367                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 368                                 continue;
 369
 370                         dist_x = panel_pos_x - resizeorigin_x;
 371                         dist_y = resizeorigin_y - targEndPos_y;
 372                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 373                                 mySize_x = min(mySize_x, dist_x);
 374                         else
 375                                 mySize_y = min(mySize_y, dist_y);
 376                 }
 377                 else if (resizeCorner == 3)
 378                 {
 379                         if (resizeorigin_x <= panel_pos_x)
 380                                 continue;
 381                         if (resizeorigin_y >= targEndPos_y)
 382                                 continue;
 383                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 384                                 continue;
 385                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 386                                 continue;
 387
 388                         dist_x = resizeorigin_x - targEndPos_x;
 389                         dist_y = panel_pos_y - resizeorigin_y;
 390                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 391                                 mySize_x = min(mySize_x, dist_x);
 392                         else
 393                                 mySize_y = min(mySize_y, dist_y);
 394                 }
 395                 else if (resizeCorner == 4)
 396                 {
 397                         if (resizeorigin_x >= targEndPos_x)
 398                                 continue;
 399                         if (resizeorigin_y >= targEndPos_y)
 400                                 continue;
 401                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 402                                 continue;
 403                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 404                                 continue;
 405
 406                         dist_x = panel_pos_x - resizeorigin_x;
 407                         dist_y = panel_pos_y - resizeorigin_y;
 408                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 409                                 mySize_x = min(mySize_x, dist_x);
 410                         else
 411                                 mySize_y = min(mySize_y, dist_y);
 412                 }
 413                 //if(cvar("hud_configure_checkcollisions_debug"))
 414                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 415         }
 416
 417         return mySize;
 418 }
 419
 420 void HUD_Panel_SetPosSize(vector mySize)
 421 {
 422         panel = highlightedPanel;
 423         HUD_Panel_UpdatePosSize()
 424         vector resizeorigin;
 425         resizeorigin = panel_click_resizeorigin;
 426         local noref vector myPos; // fteqcc sucks
 427
 428         // minimum panel size cap
 429         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 430         mySize_y = max(0.025 * vid_conheight, mySize_y);
 431
 432         if(highlightedPanel == HUD_PANEL(CHAT)) // some panels have their own restrictions, like the chat panel (which actually only moves the engine chat print around). Looks bad if it's too small.
 433         {
 434                 mySize_x = max(17 * autocvar_con_chatsize, mySize_x);
 435                 mySize_y = max(2 * autocvar_con_chatsize + 2 * panel_bg_padding, mySize_y);
 436         }
 437
 438         // collision testing|
 439         // -----------------+
 440
 441         // we need to know pos at this stage, but it might still change later if we hit a screen edge/other panel (?)
 442         if(resizeCorner == 1) {
 443                 myPos_x = resizeorigin_x - mySize_x;
 444                 myPos_y = resizeorigin_y - mySize_y;
 445         } else if(resizeCorner == 2) {
 446                 myPos_x = resizeorigin_x;
 447                 myPos_y = resizeorigin_y - mySize_y;
 448         } else if(resizeCorner == 3) {
 449                 myPos_x = resizeorigin_x - mySize_x;
 450                 myPos_y = resizeorigin_y;
 451         } else { // resizeCorner == 4
 452                 myPos_x = resizeorigin_x;
 453                 myPos_y = resizeorigin_y;
 454         }
 455
 456         // left/top screen edges
 457         if(myPos_x < 0)
 458                 mySize_x = mySize_x + myPos_x;
 459         if(myPos_y < 0)
 460                 mySize_y = mySize_y + myPos_y;
 461
 462         // bottom/right screen edges
 463         if(myPos_x + mySize_x > vid_conwidth)
 464                 mySize_x = vid_conwidth - myPos_x;
 465         if(myPos_y + mySize_y > vid_conheight)
 466                 mySize_y = vid_conheight - myPos_y;
 467
 468         //if(cvar("hud_configure_checkcollisions_debug"))
 469                 //drawfill(myPos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 470
 471         // before checkresize, otherwise panel can be snapped partially inside another panel or panel aspect ratio can be broken
 472         if(autocvar_hud_configure_grid)
 473         {
 474                 mySize_x = floor((mySize_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 475                 mySize_y = floor((mySize_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 476         }
 477
 478         if(hud_configure_checkcollisions)
 479                 mySize = HUD_Panel_CheckResize(mySize, resizeorigin);
 480
 481         // minimum panel size cap, do this once more so we NEVER EVER EVER have a panel smaller than this, JUST IN CASE above code still makes the panel eg negative (impossible to resize back without changing cvars manually then)
 482         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 483         mySize_y = max(0.025 * vid_conheight, mySize_y);
 484
 485         // do another pos check, as size might have changed by now
 486         if(resizeCorner == 1) {
 487                 myPos_x = resizeorigin_x - mySize_x;
 488                 myPos_y = resizeorigin_y - mySize_y;
 489         } else if(resizeCorner == 2) {
 490                 myPos_x = resizeorigin_x;
 491                 myPos_y = resizeorigin_y - mySize_y;
 492         } else if(resizeCorner == 3) {
 493                 myPos_x = resizeorigin_x - mySize_x;
 494                 myPos_y = resizeorigin_y;
 495         } else { // resizeCorner == 4
 496                 myPos_x = resizeorigin_x;
 497                 myPos_y = resizeorigin_y;
 498         }
 499
 500         //if(cvar("hud_configure_checkcollisions_debug"))
 501                 //drawfill(myPos, mySize, '0 1 0', .3, DRAWFLAG_NORMAL);
 502
 503         string s;
 504         s = strcat(ftos(mySize_x/vid_conwidth), " ", ftos(mySize_y/vid_conheight));
 505         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_size"), s);
 506
 507         s = strcat(ftos(myPos_x/vid_conwidth), " ", ftos(myPos_y/vid_conheight));
 508         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_pos"), s);
 509 }
 510
 511 float pressed_key_time;
 512 vector highlightedPanel_initial_pos, highlightedPanel_initial_size;
 513 void HUD_Panel_Arrow_Action(float nPrimary)
 514 {
 515         if(!highlightedPanel)
 516                 return;
 517
 518         hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
 519
 520         float step;
 521         if(autocvar_hud_configure_grid)
 522         {
 523                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 524                 {
 525                         if (hudShiftState & S_SHIFT)
 526                                 step = hud_configure_realGridSize_y;
 527                         else
 528                                 step = 2 * hud_configure_realGridSize_y;
 529                 }
 530                 else
 531                 {
 532                         if (hudShiftState & S_SHIFT)
 533                                 step = hud_configure_realGridSize_x;
 534                         else
 535                                 step = 2 * hud_configure_realGridSize_x;
 536                 }
 537         }
 538         else
 539         {
 540                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 541                         step = vid_conheight;
 542                 else
 543                         step = vid_conwidth;
 544                 if (hudShiftState & S_SHIFT)
 545                         step = (step / 256); // more precision
 546                 else
 547                         step = (step / 64) * (1 + 2 * (time - pressed_key_time));
 548         }
 549
 550         panel = highlightedPanel;
 551         HUD_Panel_UpdatePosSize()
 552
 553         highlightedPanel_initial_pos = panel_pos;
 554         highlightedPanel_initial_size = panel_size;
 555
 556         if (hudShiftState & S_ALT) // resize
 557         {
 558                 highlightedAction = 1;
 559                 if(nPrimary == K_UPARROW)
 560                         resizeCorner = 1;
 561                 else if(nPrimary == K_RIGHTARROW)
 562                         resizeCorner = 2;
 563                 else if(nPrimary == K_LEFTARROW)
 564                         resizeCorner = 3;
 565                 else // if(nPrimary == K_DOWNARROW)
 566                         resizeCorner = 4;
 567
 568                 // ctrl+arrow reduces the size, instead of increasing it
 569                 // Note that ctrl disables collisions check too, but it's fine
 570                 // since we don't collide with anything reducing the size
 571                 if (hudShiftState & S_CTRL) {
 572                         step = -step;
 573                         resizeCorner = 5 - resizeCorner;
 574                 }
 575
 576                 vector mySize;
 577                 mySize = panel_size;
 578                 panel_click_resizeorigin = panel_pos;
 579                 if(resizeCorner == 1) {
 580                         panel_click_resizeorigin += mySize;
 581                         mySize_y += step;
 582                 } else if(resizeCorner == 2) {
 583                         panel_click_resizeorigin_y += mySize_y;
 584                         mySize_x += step;
 585                 } else if(resizeCorner == 3) {
 586                         panel_click_resizeorigin_x += mySize_x;
 587                         mySize_x += step;
 588                 } else { // resizeCorner == 4
 589                         mySize_y += step;
 590                 }
 591                 HUD_Panel_SetPosSize(mySize);
 592         }
 593         else // move
 594         {
 595                 highlightedAction = 2;
 596                 vector pos;
 597                 pos = panel_pos;
 598                 if(nPrimary == K_UPARROW)
 599                         pos_y -= step;
 600                 else if(nPrimary == K_DOWNARROW)
 601                         pos_y += step;
 602                 else if(nPrimary == K_LEFTARROW)
 603                         pos_x -= step;
 604                 else // if(nPrimary == K_RIGHTARROW)
 605                         pos_x += step;
 606
 607                 HUD_Panel_SetPos(pos);
 608         }
 609
 610         panel = highlightedPanel;
 611         HUD_Panel_UpdatePosSize()
 612
 613         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
 614         {
 615                 // backup!
 616                 panel_pos_backup = highlightedPanel_initial_pos;
 617                 panel_size_backup = highlightedPanel_initial_size;
 618                 highlightedPanel_backup = highlightedPanel;
 619         }
 620 }
 621
 622 const float S_MOUSE1 = 1;
 623 const float S_MOUSE2 = 2;
 624 const float S_MOUSE3 = 4;
 625 float mouseClicked;
 626 float prevMouseClicked; // previous state
 627 float prevMouseClickedTime; // time during previous left mouse click, to check for doubleclicks
 628 vector prevMouseClickedPos; // pos during previous left mouse click, to check for doubleclicks
 629
 630 void HUD_Panel_EnableMenu();
 631 entity tab_panels[HUD_PANEL_MAX];
 632 entity tab_panel;
 633 vector tab_panel_pos;
 634 float tab_backward;
 635 void HUD_Panel_FirstInDrawQ(float id);
 636 void reset_tab_panels()
 637 {
 638         int i;
 639         for(i = 0; i < HUD_PANEL_NUM; ++i)
 640                 tab_panels[i] = world;
 641 }
 642 float HUD_Panel_InputEvent(float bInputType, float nPrimary, float nSecondary)
 643 {
 644         string s;
 645
 646         if(bInputType == 2)
 647                 return false;
 648
 649         if(!autocvar__hud_configure)
 650                 return false;
 651
 652         // block any input while a menu dialog is fading
 653         if(autocvar__menu_alpha)
 654                 return true;
 655
 656         if(bInputType == 3)
 657         {
 658                 mousepos_x = nPrimary;
 659                 mousepos_y = nSecondary;
 660                 return true;
 661         }
 662
 663         // allow console bind to work
 664         string con_keys;
 665         float keys;
 666         con_keys = findkeysforcommand("toggleconsole", 0);
 667         keys = tokenize(con_keys); // findkeysforcommand returns data for this
 668
 669         float hit_con_bind = 0, i;
 670         for (i = 0; i < keys; ++i)
 671         {
 672                 if(nPrimary == stof(argv(i)))
 673                         hit_con_bind = 1;
 674         }
 675
 676         if(bInputType == 0) {
 677                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 678                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 679                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 680         }
 681         else if(bInputType == 1) {
 682                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 683                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 684                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 685         }
 686
 687         if(nPrimary == K_CTRL)
 688         {
 689                 if (bInputType == 1) //ctrl has been released
 690                 {
 691                         if (tab_panel)
 692                         {
 693                                 //switch to selected panel
 694                                 highlightedPanel = tab_panel;
 695                                 highlightedAction = 0;
 696                                 HUD_Panel_FirstInDrawQ(highlightedPanel.panel_id);
 697                         }
 698                         tab_panel = world;
 699                         reset_tab_panels();
 700                 }
 701         }
 702
 703         if(nPrimary == K_MOUSE1)
 704         {
 705                 if(bInputType == 0) // key pressed
 706                         mouseClicked |= S_MOUSE1;
 707                 else if(bInputType == 1) // key released
 708                         mouseClicked -= (mouseClicked & S_MOUSE1);
 709         }
 710         else if(nPrimary == K_MOUSE2)
 711         {
 712                 if(bInputType == 0) // key pressed
 713                         mouseClicked |= S_MOUSE2;
 714                 else if(bInputType == 1) // key released
 715                         mouseClicked -= (mouseClicked & S_MOUSE2);
 716         }
 717         else if(nPrimary == K_ESCAPE)
 718         {
 719                 if (bInputType == 1)
 720                         return true;
 721                 menu_enabled = 1;
 722                 menu_enabled_time = time;
 723                 localcmd("menu_showhudexit\n");
 724         }
 725         else if(nPrimary == K_BACKSPACE && hudShiftState & S_CTRL)
 726         {
 727                 if (bInputType == 1)
 728                         return true;
 729                 if (!menu_enabled)
 730                         cvar_set("_hud_configure", "0");
 731         }
 732         else if(nPrimary == K_TAB && hudShiftState & S_CTRL) // select and highlight another panel
 733         {
 734                 if (bInputType == 1 || mouseClicked)
 735                         return true;
 736
 737                 //FIXME: if a panel is highlighted, has the same pos_x and lays in the same level
 738                 //of other panels then next consecutive ctrl-tab will select the highlighted panel too
 739                 //(it should only after every other panel of the hud)
 740                 //It's a minor bug anyway, we can live with it
 741
 742                 entity starting_panel;
 743                 entity old_tab_panel = tab_panel;
 744                 if (!tab_panel) //first press of TAB
 745                 {
 746                         if (highlightedPanel)
 747                         {
 748                                 panel = highlightedPanel;
 749                                 HUD_Panel_UpdatePosSize()
 750                         }
 751                         else
 752                                 panel_pos = '0 0 0';
 753                         starting_panel = highlightedPanel;
 754                         tab_panel_pos = panel_pos; //to compute level
 755                 }
 756                 else
 757                 {
 758                         if ( ((!tab_backward) && (hudShiftState & S_SHIFT)) || (tab_backward && !(hudShiftState & S_SHIFT)) ) //tab direction changed?
 759                                 reset_tab_panels();
 760                         starting_panel = tab_panel;
 761                 }
 762                 tab_backward = (hudShiftState & S_SHIFT);
 763
 764                 float k, level = 0, start_pos_x;
 765                 vector candidate_pos = '0 0 0';
 766                 const float LEVELS_NUM = 4;
 767                 float level_height = vid_conheight / LEVELS_NUM;
 768 :find_tab_panel
 769                 level = floor(tab_panel_pos_y / level_height) * level_height; //starting level
 770                 candidate_pos_x = (!tab_backward) ? vid_conwidth : 0;
 771                 start_pos_x = tab_panel_pos_x;
 772                 tab_panel = world;
 773                 k=0;
 774                 while(++k)
 775                 {
 776                         for(i = 0; i < HUD_PANEL_NUM; ++i)
 777                         {
 778                                 panel = hud_panel[i];
 779                                 if (panel == tab_panels[i] || panel == starting_panel)
 780                                         continue;
 781                                 HUD_Panel_UpdatePosSize()
 782                                 if (panel_pos_y >= level && (panel_pos_y - level) < level_height)
 783                                 if (  ( !tab_backward && panel_pos_x >= start_pos_x && (panel_pos_x < candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y <= candidate_pos_y)) )
 784                                         || ( tab_backward && panel_pos_x <= start_pos_x && (panel_pos_x > candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y >= candidate_pos_y)) )  )
 785                                 {
 786                                         tab_panel = panel;
 787                                         tab_panel_pos = candidate_pos = panel_pos;
 788                                 }
 789                         }
 790                         if (tab_panel)
 791                                 break;
 792                         if (k == LEVELS_NUM) //tab_panel not found
 793                         {
 794                                 reset_tab_panels();
 795                                 if (!old_tab_panel)
 796                                 {
 797                                         tab_panel = world;
 798                                         return true;
 799                                 }
 800                                 starting_panel = old_tab_panel;
 801                                 old_tab_panel = world;
 802                                 goto find_tab_panel; //u must find tab_panel!
 803                         }
 804                         if (!tab_backward)
 805                         {
 806                                 level = mod(level + level_height, vid_conheight);
 807                                 start_pos_x = 0;
 808                                 candidate_pos_x = vid_conwidth;
 809                         }
 810                         else
 811                         {
 812                                 level = mod(level - level_height, vid_conheight);
 813                                 start_pos_x = vid_conwidth;
 814                                 candidate_pos_x = 0;
 815                         }
 816                 }
 817
 818                 tab_panels[tab_panel.panel_id] = tab_panel;
 819         }
 820         else if(nPrimary == K_SPACE && hudShiftState & S_CTRL) // enable/disable highlighted panel or dock
 821         {
 822                 if (bInputType == 1 || mouseClicked)
 823                         return true;
 824
 825                 if (highlightedPanel)
 826                         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name), ftos(!cvar(strcat("hud_panel_", highlightedPanel.panel_name))));
 827                 else
 828                         cvar_set(strcat("hud_dock"), (autocvar_hud_dock == "") ? "dock" : "");
 829         }
 830         else if(nPrimary == 'c' && hudShiftState & S_CTRL) // copy highlighted panel size
 831         {
 832                 if (bInputType == 1 || mouseClicked)
 833                         return true;
 834
 835                 if (highlightedPanel)
 836                 {
 837                         panel = highlightedPanel;
 838                         HUD_Panel_UpdatePosSize()
 839                         panel_size_copied = panel_size;
 840                 }
 841         }
 842         else if(nPrimary == 'v' && hudShiftState & S_CTRL) // past copied size on the highlighted panel
 843         {
 844                 if (bInputType == 1 || mouseClicked)
 845                         return true;
 846
 847                 if (panel_size_copied == '0 0 0' || !highlightedPanel)
 848                         return true;
 849
 850                 panel = highlightedPanel;
 851                 HUD_Panel_UpdatePosSize()
 852
 853                 // reduce size if it'd go beyond screen boundaries
 854                 vector tmp_size = panel_size_copied;
 855                 if (panel_pos_x + panel_size_copied_x > vid_conwidth)
 856                         tmp_size_x = vid_conwidth - panel_pos_x;
 857                 if (panel_pos_y + panel_size_copied_y > vid_conheight)
 858                         tmp_size_y = vid_conheight - panel_pos_y;
 859
 860                 if (panel_size == tmp_size)
 861                         return true;
 862
 863                 // backup first!
 864                 panel_pos_backup = panel_pos;
 865                 panel_size_backup = panel_size;
 866                 highlightedPanel_backup = highlightedPanel;
 867
 868                 s = strcat(ftos(tmp_size_x/vid_conwidth), " ", ftos(tmp_size_y/vid_conheight));
 869                 cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_size"), s);
 870         }
 871         else if(nPrimary == 'z' && hudShiftState & S_CTRL) // undo last action
 872         {
 873                 if (bInputType == 1 || mouseClicked)
 874                         return true;
 875                 //restore previous values
 876                 if (highlightedPanel_backup)
 877                 {
 878                         s = strcat(ftos(panel_pos_backup_x/vid_conwidth), " ", ftos(panel_pos_backup_y/vid_conheight));
 879                         cvar_set(strcat("hud_panel_", highlightedPanel_backup.panel_name, "_pos"), s);
 880                         s = strcat(ftos(panel_size_backup_x/vid_conwidth), " ", ftos(panel_size_backup_y/vid_conheight));
 881                         cvar_set(strcat("hud_panel_", highlightedPanel_backup.panel_name, "_size"), s);
 882                         highlightedPanel_backup = world;
 883                 }
 884         }
 885         else if(nPrimary == K_UPARROW || nPrimary == K_DOWNARROW || nPrimary == K_LEFTARROW || nPrimary == K_RIGHTARROW)
 886         {
 887                 if (bInputType == 1)
 888                 {
 889                         pressed_key_time = 0;
 890                         return true;
 891                 }
 892                 else if (pressed_key_time == 0)
 893                         pressed_key_time = time;
 894
 895                 if (!mouseClicked)
 896                         HUD_Panel_Arrow_Action(nPrimary); //move or resize panel
 897         }
 898         else if(nPrimary == K_ENTER || nPrimary == K_SPACE || nPrimary == K_KP_ENTER)
 899         {
 900                 if (bInputType == 1)
 901                         return true;
 902                 if (highlightedPanel)
 903                         HUD_Panel_EnableMenu();
 904         }
 905         else if(hit_con_bind)
 906                 return false;
 907
 908         return true;
 909 }
 910
 911 float HUD_Panel_Check_Mouse_Pos(float allow_move)
 912 {
 913         float i, j = 0, border;
 914
 915         while(j < HUD_PANEL_NUM)
 916         {
 917                 i = panel_order[j];
 918                 j += 1;
 919
 920                 panel = hud_panel[i];
 921                 HUD_Panel_UpdatePosSize()
 922
 923                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 924
 925                 // move
 926                 if(allow_move && mousepos_x > panel_pos_x && mousepos_y > panel_pos_y && mousepos_x < panel_pos_x + panel_size_x && mousepos_y < panel_pos_y + panel_size_y)
 927                 {
 928                         return 1;
 929                 }
 930                 // resize from topleft border
 931                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 932                 {
 933                         return 2;
 934                 }
 935                 // resize from topright border
 936                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 937                 {
 938                         return 3;
 939                 }
 940                 // resize from bottomleft border
 941                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
 942                 {
 943                         return 3;
 944                 }
 945                 // resize from bottomright border
 946                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
 947                 {
 948                         return 2;
 949                 }
 950         }
 951         return 0;
 952 }
 953
 954 // move a panel to the beginning of the panel order array (which means it gets drawn last, on top of everything else)
 955 void HUD_Panel_FirstInDrawQ(float id)
 956 {
 957         float i;
 958         var float place = -1;
 959         // find out where in the array our current id is, save into place
 960         for(i = 0; i < HUD_PANEL_NUM; ++i)
 961         {
 962                 if(panel_order[i] == id)
 963                 {
 964                         place = i;
 965                         break;
 966                 }
 967         }
 968         // place last if we didn't find a place for it yet (probably new panel, or screwed up cvar)
 969         if(place == -1)
 970                 place = HUD_PANEL_NUM - 1;
 971
 972         // move all ids up by one step in the array until "place"
 973         for(i = place; i > 0; --i)
 974         {
 975                 panel_order[i] = panel_order[i-1];
 976         }
 977         // now save the new top id
 978         panel_order[0] = id;
 979
 980         // let's save them into the cvar by some strcat trickery
 981         string s = "";
 982         for(i = 0; i < HUD_PANEL_NUM; ++i)
 983         {
 984                 s = strcat(s, ftos(panel_order[i]), " ");
 985         }
 986         cvar_set("_hud_panelorder", s);
 987         if(hud_panelorder_prev)
 988                 strunzone(hud_panelorder_prev);
 989         hud_panelorder_prev = strzone(autocvar__hud_panelorder); // prevent HUD_Main from doing useless update, we already updated here
 990 }
 991
 992 void HUD_Panel_Highlight(float allow_move)
 993 {
 994         float i, j = 0, border;
 995
 996         while(j < HUD_PANEL_NUM)
 997         {
 998                 i = panel_order[j];
 999                 j += 1;
1000
1001                 panel = hud_panel[i];
1002                 HUD_Panel_UpdatePosSize()
1003
1004                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
1005
1006                 // move
1007                 if(allow_move && mousepos_x > panel_pos_x && mousepos_y > panel_pos_y && mousepos_x < panel_pos_x + panel_size_x && mousepos_y < panel_pos_y + panel_size_y)
1008                 {
1009                         highlightedPanel = hud_panel[i];
1010                         HUD_Panel_FirstInDrawQ(i);
1011                         highlightedAction = 1;
1012                         panel_click_distance = mousepos - panel_pos;
1013                         return;
1014                 }
1015                 // resize from topleft border
1016                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
1017                 {
1018                         highlightedPanel = hud_panel[i];
1019                         HUD_Panel_FirstInDrawQ(i);
1020                         highlightedAction = 2;
1021                         resizeCorner = 1;
1022                         panel_click_distance = mousepos - panel_pos;
1023                         panel_click_resizeorigin = panel_pos + panel_size;
1024                         return;
1025                 }
1026                 // resize from topright border
1027                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
1028                 {
1029                         highlightedPanel = hud_panel[i];
1030                         HUD_Panel_FirstInDrawQ(i);
1031                         highlightedAction = 2;
1032                         resizeCorner = 2;
1033                         panel_click_distance_x = panel_size_x - mousepos_x + panel_pos_x;
1034                         panel_click_distance_y = mousepos_y - panel_pos_y;
1035                         panel_click_resizeorigin = panel_pos + eY * panel_size_y;
1036                         return;
1037                 }
1038                 // resize from bottomleft border
1039                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
1040                 {
1041                         highlightedPanel = hud_panel[i];
1042                         HUD_Panel_FirstInDrawQ(i);
1043                         highlightedAction = 2;
1044                         resizeCorner = 3;
1045                         panel_click_distance_x = mousepos_x - panel_pos_x;
1046                         panel_click_distance_y = panel_size_y - mousepos_y + panel_pos_y;
1047                         panel_click_resizeorigin = panel_pos + eX * panel_size_x;
1048                         return;
1049                 }
1050                 // resize from bottomright border
1051                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
1052                 {
1053                         highlightedPanel = hud_panel[i];
1054                         HUD_Panel_FirstInDrawQ(i);
1055                         highlightedAction = 2;
1056                         resizeCorner = 4;
1057                         panel_click_distance = panel_size - mousepos + panel_pos;
1058                         panel_click_resizeorigin = panel_pos;
1059                         return;
1060                 }
1061         }
1062         highlightedPanel = world;
1063         highlightedAction = 0;
1064 }
1065
1066 void HUD_Panel_EnableMenu()
1067 {
1068         menu_enabled = 2;
1069         menu_enabled_time = time;
1070         localcmd("menu_showhudoptions ", highlightedPanel.panel_name, "\n");
1071 }
1072 float mouse_over_panel;
1073 void HUD_Panel_Mouse()
1074 {
1075         // TODO: needs better check... is there any float that contains the current state of the menu? _menu_alpha isn't apparently updated the frame the menu gets enabled
1076         if (autocvar__menu_alpha == 0 && time - menu_enabled_time > 0.5)
1077                 menu_enabled = 0;
1078
1079         /*
1080         print("menu_enabled: ", ftos(menu_enabled), "\n");
1081         print("Highlighted: ", ftos(highlightedPanel), "\n");
1082         print("Menu theAlpha: ", ftos(autocvar__menu_alpha), "\n");
1083         */
1084
1085         if(autocvar__menu_alpha == 1)
1086                 return;
1087
1088         if not(autocvar_hud_cursormode)
1089         {
1090                 mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
1091
1092                 mousepos_x = bound(0, mousepos_x, vid_conwidth);
1093                 mousepos_y = bound(0, mousepos_y, vid_conheight);
1094         }
1095
1096         if(mouseClicked)
1097         {
1098                 if(prevMouseClicked == 0)
1099                 {
1100                         if (tab_panel)
1101                         {
1102                                 //stop ctrl-tab selection
1103                                 tab_panel = world;
1104                                 reset_tab_panels();
1105                         }
1106                         HUD_Panel_Highlight(mouseClicked & S_MOUSE1); // sets highlightedPanel, highlightedAction, panel_click_distance, panel_click_resizeorigin
1107                                                                         // and calls HUD_Panel_UpdatePosSize() for the highlighted panel
1108                         if (highlightedPanel)
1109                         {
1110                                 highlightedPanel_initial_pos = panel_pos;
1111                                 highlightedPanel_initial_size = panel_size;
1112                         }
1113                         // doubleclick check
1114                         if ((mouseClicked & S_MOUSE1) && time - prevMouseClickedTime < 0.4 && highlightedPanel && prevMouseClickedPos == mousepos)
1115                         {
1116                                 mouseClicked = 0; // to prevent spam, I guess.
1117                                 HUD_Panel_EnableMenu();
1118                         }
1119                         else
1120                         {
1121                                 if (mouseClicked & S_MOUSE1)
1122                                 {
1123                                         prevMouseClickedTime = time;
1124                                         prevMouseClickedPos = mousepos;
1125                                 }
1126                                 mouse_over_panel = HUD_Panel_Check_Mouse_Pos(mouseClicked & S_MOUSE1);
1127                         }
1128                 }
1129                 else
1130                 {
1131                         panel = highlightedPanel;
1132                         HUD_Panel_UpdatePosSize()
1133                 }
1134
1135                 if (highlightedPanel)
1136                 {
1137                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1138                         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
1139                         {
1140                                 hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
1141                                 // backup!
1142                                 panel_pos_backup = highlightedPanel_initial_pos;
1143                                 panel_size_backup = highlightedPanel_initial_size;
1144                                 highlightedPanel_backup = highlightedPanel;
1145                         }
1146                         else
1147                                 // in case the clicked panel is inside another panel and we aren't
1148                                 // moving it, avoid the immediate "fix" of its position/size
1149                                 // (often unwanted and hateful) by disabling collisions check
1150                                 hud_configure_checkcollisions = false;
1151                 }
1152
1153                 if(highlightedAction == 1)
1154                         HUD_Panel_SetPos(mousepos - panel_click_distance);
1155                 else if(highlightedAction == 2)
1156                 {
1157                         vector mySize = '0 0 0';
1158                         if(resizeCorner == 1) {
1159                                 mySize_x = panel_click_resizeorigin_x - (mousepos_x - panel_click_distance_x);
1160                                 mySize_y = panel_click_resizeorigin_y - (mousepos_y - panel_click_distance_y);
1161                         } else if(resizeCorner == 2) {
1162                                 mySize_x = mousepos_x + panel_click_distance_x - panel_click_resizeorigin_x;
1163                                 mySize_y = panel_click_distance_y + panel_click_resizeorigin_y - mousepos_y;
1164                         } else if(resizeCorner == 3) {
1165                                 mySize_x = panel_click_resizeorigin_x + panel_click_distance_x - mousepos_x;
1166                                 mySize_y = mousepos_y + panel_click_distance_y - panel_click_resizeorigin_y;
1167                         } else { // resizeCorner == 4
1168                                 mySize_x = mousepos_x - (panel_click_resizeorigin_x - panel_click_distance_x);
1169                                 mySize_y = mousepos_y - (panel_click_resizeorigin_y - panel_click_distance_y);
1170                         }
1171                         HUD_Panel_SetPosSize(mySize);
1172                 }
1173         }
1174         else
1175         {
1176                 if(menu_enabled == 2)
1177                         mouse_over_panel = 0;
1178                 else
1179                         mouse_over_panel = HUD_Panel_Check_Mouse_Pos(TRUE);
1180                 if (mouse_over_panel && !tab_panel)
1181                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1182         }
1183         // draw cursor after performing move/resize to have the panel pos/size updated before mouse_over_panel
1184         const vector cursorsize = '32 32 0';
1185         float cursor_alpha = 1 - autocvar__menu_alpha;
1186
1187         if(!mouse_over_panel)
1188                 drawpic(mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1189         else if(mouse_over_panel == 1)
1190                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_move.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1191         else if(mouse_over_panel == 2)
1192                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1193         else
1194                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize2.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1195
1196         prevMouseClicked = mouseClicked;
1197 }
1198
1199 const float hlBorderSize = 4;
1200 const string hlBorder = "gfx/hud/default/border_highlighted";
1201 const string hlBorder2 = "gfx/hud/default/border_highlighted2";
1202 void HUD_Panel_HlBorder(float myBorder, vector color, float theAlpha)
1203 {
1204         drawfill(panel_pos - '1 1 0' * myBorder, panel_size + '2 2 0' * myBorder, '0 0.5 1', .5 * theAlpha, DRAWFLAG_NORMAL);
1205         drawpic_tiled(panel_pos - '1 1 0' * myBorder, hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1206         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * (panel_size_y + 2 * myBorder - hlBorderSize), hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1207         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize, hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1208         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize + eX * (panel_size_x + 2 * myBorder - hlBorderSize), hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1209 }