qcsrc/client/hud_config.qc

   1 #define HUD_Write(s) fputs(fh, s)
   2 // q: quoted, n: not quoted
   3 #define HUD_Write_Cvar_n(cvar) HUD_Write(strcat("seta ", cvar, " ", cvar_string(cvar), "\n"))
   4 #define HUD_Write_Cvar_q(cvar) HUD_Write(strcat("seta ", cvar, " \"", cvar_string(cvar), "\"\n"))
   5 #define HUD_Write_PanelCvar_n(cvar_suf) HUD_Write_Cvar_n(strcat("hud_panel_", panel_name, cvar_suf))
   6 #define HUD_Write_PanelCvar_q(cvar_suf) HUD_Write_Cvar_q(strcat("hud_panel_", panel_name, cvar_suf))
   7 // Save the config
   8 void HUD_Panel_ExportCfg(string cfgname)
   9 {
  10         float fh;
  11         string filename = strcat("hud_", autocvar_hud_skin, "_", cfgname, ".cfg");
  12         fh = fopen(filename, FILE_WRITE);
  13         if(fh >= 0)
  14         {
  15                 HUD_Write_Cvar_q("hud_skin");
  16                 HUD_Write_Cvar_q("hud_panel_bg");
  17                 HUD_Write_Cvar_q("hud_panel_bg_color");
  18                 HUD_Write_Cvar_q("hud_panel_bg_color_team");
  19                 HUD_Write_Cvar_q("hud_panel_bg_alpha");
  20                 HUD_Write_Cvar_q("hud_panel_bg_border");
  21                 HUD_Write_Cvar_q("hud_panel_bg_padding");
  22                 HUD_Write_Cvar_q("hud_panel_fg_alpha");
  23                 HUD_Write("\n");
  24
  25                 HUD_Write_Cvar_q("hud_dock");
  26                 HUD_Write_Cvar_q("hud_dock_color");
  27                 HUD_Write_Cvar_q("hud_dock_color_team");
  28                 HUD_Write_Cvar_q("hud_dock_alpha");
  29                 HUD_Write("\n");
  30
  31                 HUD_Write_Cvar_q("hud_progressbar_alpha");
  32                 HUD_Write_Cvar_q("hud_progressbar_strength_color");
  33                 HUD_Write_Cvar_q("hud_progressbar_shield_color");
  34                 HUD_Write_Cvar_q("hud_progressbar_health_color");
  35                 HUD_Write_Cvar_q("hud_progressbar_armor_color");
  36                 HUD_Write_Cvar_q("hud_progressbar_fuel_color");
  37                 HUD_Write_Cvar_q("hud_progressbar_nexball_color");
  38                 HUD_Write_Cvar_q("hud_progressbar_speed_color");
  39                 HUD_Write_Cvar_q("hud_progressbar_acceleration_color");
  40                 HUD_Write_Cvar_q("hud_progressbar_acceleration_neg_color");
  41                 HUD_Write("\n");
  42
  43                 HUD_Write_Cvar_q("_hud_panelorder");
  44                 HUD_Write("\n");
  45
  46                 HUD_Write_Cvar_q("hud_configure_grid");
  47                 HUD_Write_Cvar_q("hud_configure_grid_xsize");
  48                 HUD_Write_Cvar_q("hud_configure_grid_ysize");
  49                 HUD_Write("\n");
  50
  51                 // common cvars for all panels
  52                 float i;
  53                 for (i = 0; i < HUD_PANEL_NUM; ++i)
  54                 {
  55                         HUD_Panel_GetName(i);
  56
  57                         HUD_Write_PanelCvar_n("");
  58                         HUD_Write_PanelCvar_q("_pos");
  59                         HUD_Write_PanelCvar_q("_size");
  60                         HUD_Write_PanelCvar_q("_bg");
  61                         HUD_Write_PanelCvar_q("_bg_color");
  62                         HUD_Write_PanelCvar_q("_bg_color_team");
  63                         HUD_Write_PanelCvar_q("_bg_alpha");
  64                         HUD_Write_PanelCvar_q("_bg_border");
  65                         HUD_Write_PanelCvar_q("_bg_padding");
  66                         switch(i) {
  67                                 case HUD_PANEL_WEAPONS:
  68                                         HUD_Write_PanelCvar_q("_accuracy");
  69                                         HUD_Write_PanelCvar_q("_label");
  70                                         HUD_Write_PanelCvar_q("_complainbubble");
  71                                         HUD_Write_PanelCvar_q("_complainbubble_padding");
  72                                         HUD_Write_PanelCvar_q("_complainbubble_time");
  73                                         HUD_Write_PanelCvar_q("_complainbubble_fadetime");
  74                                         HUD_Write_PanelCvar_q("_complainbubble_color_outofammo");
  75                                         HUD_Write_PanelCvar_q("_complainbubble_color_donthave");
  76                                         HUD_Write_PanelCvar_q("_complainbubble_color_unavailable");
  77                                         HUD_Write_PanelCvar_q("_ammo");
  78                                         HUD_Write_PanelCvar_q("_ammo_color");
  79                                         HUD_Write_PanelCvar_q("_ammo_alpha");
  80                                         HUD_Write_PanelCvar_q("_aspect");
  81                                         HUD_Write_PanelCvar_q("_timeout");
  82                                         HUD_Write_PanelCvar_q("_timeout_effect");
  83                                         HUD_Write_PanelCvar_q("_timeout_fadebgmin");
  84                                         HUD_Write_PanelCvar_q("_timeout_fadefgmin");
  85                                         HUD_Write_PanelCvar_q("_timeout_speed_in");
  86                                         HUD_Write_PanelCvar_q("_timeout_speed_out");
  87                                         HUD_Write_PanelCvar_q("_onlyowned");
  88                                         break;
  89                                 case HUD_PANEL_AMMO:
  90                                         HUD_Write_PanelCvar_q("_onlycurrent");
  91                                         HUD_Write_PanelCvar_q("_iconalign");
  92                                         HUD_Write_PanelCvar_q("_progressbar");
  93                                         HUD_Write_PanelCvar_q("_progressbar_name");
  94                                         HUD_Write_PanelCvar_q("_progressbar_xoffset");
  95                                         HUD_Write_PanelCvar_q("_text");
  96                                         break;
  97                                 case HUD_PANEL_POWERUPS:
  98                                         HUD_Write_PanelCvar_q("_flip");
  99                                         HUD_Write_PanelCvar_q("_iconalign");
 100                                         HUD_Write_PanelCvar_q("_baralign");
 101                                         HUD_Write_PanelCvar_q("_progressbar");
 102                                         HUD_Write_PanelCvar_q("_progressbar_strength");
 103                                         HUD_Write_PanelCvar_q("_progressbar_shield");
 104                                         HUD_Write_PanelCvar_q("_text");
 105                                         break;
 106                                 case HUD_PANEL_HEALTHARMOR:
 107                                         HUD_Write_PanelCvar_q("_flip");
 108                                         HUD_Write_PanelCvar_q("_iconalign");
 109                                         HUD_Write_PanelCvar_q("_baralign");
 110                                         HUD_Write_PanelCvar_q("_progressbar");
 111                                         HUD_Write_PanelCvar_q("_progressbar_health");
 112                                         HUD_Write_PanelCvar_q("_progressbar_armor");
 113                                         HUD_Write_PanelCvar_q("_progressbar_gfx");
 114                                         HUD_Write_PanelCvar_q("_progressbar_gfx_smooth");
 115                                         HUD_Write_PanelCvar_q("_text");
 116                                         break;
 117                                 case HUD_PANEL_NOTIFY:
 118                                         HUD_Write_PanelCvar_q("_flip");
 119                                         HUD_Write_PanelCvar_q("_fontsize");
 120                                         HUD_Write_PanelCvar_q("_print");
 121                                         HUD_Write_PanelCvar_q("_time");
 122                                         HUD_Write_PanelCvar_q("_fadetime");
 123                                         break;
 124                                 case HUD_PANEL_TIMER:
 125                                         HUD_Write_PanelCvar_q("_increment");
 126                                         break;
 127                                 case HUD_PANEL_RADAR:
 128                                         HUD_Write_PanelCvar_q("_foreground_alpha");
 129                                         HUD_Write_PanelCvar_q("_rotation");
 130                                         HUD_Write_PanelCvar_q("_zoommode");
 131                                         HUD_Write_PanelCvar_q("_scale");
 132                                         HUD_Write_PanelCvar_q("_maximized_scale");
 133                                         HUD_Write_PanelCvar_q("_maximized_size");
 134                                         break;
 135                                 case HUD_PANEL_SCORE:
 136                                         HUD_Write_PanelCvar_q("_rankings");
 137                                         break;
 138                                 case HUD_PANEL_VOTE:
 139                                         HUD_Write_PanelCvar_q("_alreadyvoted_alpha");
 140                                         break;
 141                                 case HUD_PANEL_MODICONS:
 142                                         HUD_Write_PanelCvar_q("_dom_layout");
 143                                         break;
 144                                 case HUD_PANEL_PRESSEDKEYS:
 145                                         HUD_Write_PanelCvar_q("_attack");
 146                                         HUD_Write_PanelCvar_q("_aspect");
 147                                         break;
 148                                 case HUD_PANEL_ENGINEINFO:
 149                                         HUD_Write_PanelCvar_q("_framecounter_time");
 150                                         HUD_Write_PanelCvar_q("_framecounter_decimals");
 151                                         break;
 152                                 case HUD_PANEL_INFOMESSAGES:
 153                                         HUD_Write_PanelCvar_q("_flip");
 154                                         break;
 155                                 case HUD_PANEL_PHYSICS:
 156                                         HUD_Write_PanelCvar_q("_speed_unit");
 157                                         HUD_Write_PanelCvar_q("_speed_unit_show");
 158                                         HUD_Write_PanelCvar_q("_speed_max");
 159                                         HUD_Write_PanelCvar_q("_speed_vertical");
 160                                         HUD_Write_PanelCvar_q("_topspeed");
 161                                         HUD_Write_PanelCvar_q("_topspeed_time");
 162                                         HUD_Write_PanelCvar_q("_acceleration_max");
 163                                         HUD_Write_PanelCvar_q("_acceleration_vertical");
 164                                         HUD_Write_PanelCvar_q("_flip");
 165                                         HUD_Write_PanelCvar_q("_baralign");
 166                                         HUD_Write_PanelCvar_q("_progressbar");
 167                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_mode");
 168                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_scale");
 169                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_nonlinear");
 170                                         HUD_Write_PanelCvar_q("_text");
 171                                         HUD_Write_PanelCvar_q("_text_scale");
 172                                         break;
 173                                 case HUD_PANEL_CENTERPRINT:
 174                                         HUD_Write_PanelCvar_q("_align");
 175                                         HUD_Write_PanelCvar_q("_flip");
 176                                         HUD_Write_PanelCvar_q("_fontscale");
 177                                         HUD_Write_PanelCvar_q("_time");
 178                                         HUD_Write_PanelCvar_q("_fade_in");
 179                                         HUD_Write_PanelCvar_q("_fade_out");
 180                                         HUD_Write_PanelCvar_q("_fade_subsequent");
 181                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone");
 182                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone_minalpha");
 183                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo");
 184                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo_minalpha");
 185                                         HUD_Write_PanelCvar_q("_fade_subsequent_minfontsize");
 186                                         HUD_Write_PanelCvar_q("_fade_minfontsize");
 187                                         break;
 188                         }
 189                         HUD_Write("\n");
 190                 }
 191                 HUD_Write("menu_sync\n"); // force the menu to reread the cvars, so that the dialogs are updated
 192
 193                 print(sprintf(_("^2Successfully exported to %s! (Note: It's saved in data/data/)\n"), filename));
 194                 fclose(fh);
 195         }
 196         else
 197                 print(sprintf(_("^1Couldn't write to %s\n"), filename));
 198 }
 199
 200 void HUD_Configure_Exit_Force()
 201 {
 202         if (menu_enabled)
 203         {
 204                 menu_enabled = 0;
 205                 localcmd("togglemenu\n");
 206         }
 207         cvar_set("_hud_configure", "0");
 208 }
 209
 210 // check if move will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 211 vector HUD_Panel_CheckMove(vector myPos, vector mySize)
 212 {
 213         float i;
 214         float myCenter_x, myCenter_y, targCenter_x, targCenter_y;
 215         vector myTarget;
 216         myTarget = myPos;
 217
 218         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 219                 if(i == highlightedPanel || !panel_enabled)
 220                         continue;
 221
 222                 HUD_Panel_UpdatePosSizeForId(i);
 223
 224                 panel_pos -= '1 1 0' * panel_bg_border;
 225                 panel_size += '2 2 0' * panel_bg_border;
 226
 227                 if(myPos_y + mySize_y < panel_pos_y)
 228                         continue;
 229                 if(myPos_y > panel_pos_y + panel_size_y)
 230                         continue;
 231
 232                 if(myPos_x + mySize_x < panel_pos_x)
 233                         continue;
 234                 if(myPos_x > panel_pos_x + panel_size_x)
 235                         continue;
 236
 237                 // OK, there IS a collision.
 238
 239                 myCenter_x = myPos_x + 0.5 * mySize_x;
 240                 myCenter_y = myPos_y + 0.5 * mySize_y;
 241
 242                 targCenter_x = panel_pos_x + 0.5 * panel_size_x;
 243                 targCenter_y = panel_pos_y + 0.5 * panel_size_y;
 244
 245                 if(myCenter_x < targCenter_x && myCenter_y < targCenter_y) // top left (of the target panel)
 246                 {
 247                         if(myPos_x + mySize_x - panel_pos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 248                                 myTarget_x = panel_pos_x - mySize_x;
 249                         else // push it upwards
 250                                 myTarget_y = panel_pos_y - mySize_y;
 251                 }
 252                 else if(myCenter_x > targCenter_x && myCenter_y < targCenter_y) // top right
 253                 {
 254                         if(panel_pos_x + panel_size_x - myPos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 255                                 myTarget_x = panel_pos_x + panel_size_x;
 256                         else // push it upwards
 257                                 myTarget_y = panel_pos_y - mySize_y;
 258                 }
 259                 else if(myCenter_x < targCenter_x && myCenter_y > targCenter_y) // bottom left
 260                 {
 261                         if(myPos_x + mySize_x - panel_pos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 262                                 myTarget_x = panel_pos_x - mySize_x;
 263                         else // push it downwards
 264                                 myTarget_y = panel_pos_y + panel_size_y;
 265                 }
 266                 else if(myCenter_x > targCenter_x && myCenter_y > targCenter_y) // bottom right
 267                 {
 268                         if(panel_pos_x + panel_size_x - myPos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 269                                 myTarget_x = panel_pos_x + panel_size_x;
 270                         else // push it downwards
 271                                 myTarget_y = panel_pos_y + panel_size_y;
 272                 }
 273                 //if(cvar("hud_configure_checkcollisions_debug"))
 274                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 275         }
 276
 277         return myTarget;
 278 }
 279
 280 void HUD_Panel_SetPos(vector pos)
 281 {
 282         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 283         vector mySize;
 284         mySize = panel_size;
 285
 286         //if(cvar("hud_configure_checkcollisions_debug"))
 287                 //drawfill(pos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 288
 289         if(autocvar_hud_configure_grid)
 290         {
 291                 pos_x = floor((pos_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 292                 pos_y = floor((pos_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 293         }
 294
 295         if(hud_configure_checkcollisions)
 296                 pos = HUD_Panel_CheckMove(pos, mySize);
 297
 298         pos_x = bound(0, pos_x, vid_conwidth - mySize_x);
 299         pos_y = bound(0, pos_y, vid_conheight - mySize_y);
 300
 301         string s;
 302         s = strcat(ftos(pos_x/vid_conwidth), " ", ftos(pos_y/vid_conheight));
 303
 304         HUD_Panel_GetName(highlightedPanel);
 305         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 306 }
 307
 308 // check if resize will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 309 vector HUD_Panel_CheckResize(vector mySize, vector resizeorigin) {
 310         float i;
 311
 312         vector targEndPos;
 313
 314         float dist_x, dist_y;
 315         float ratio;
 316         ratio = mySize_x/mySize_y;
 317
 318         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 319                 if(i == highlightedPanel || !panel_enabled)
 320                         continue;
 321
 322                 HUD_Panel_UpdatePosSizeForId(i);
 323
 324                 panel_pos -= '1 1 0' * panel_bg_border;
 325                 panel_size += '2 2 0' * panel_bg_border;
 326
 327                 targEndPos = panel_pos + panel_size;
 328
 329                 // resizeorigin is WITHIN target panel, just abort any collision testing against that particular panel to produce expected behaviour!
 330                 if(resizeorigin_x > panel_pos_x && resizeorigin_x < targEndPos_x && resizeorigin_y > panel_pos_y && resizeorigin_y < targEndPos_y)
 331                         continue;
 332
 333                 if (resizeCorner == 1)
 334                 {
 335                         // check if this panel is on our way
 336                         if (resizeorigin_x <= panel_pos_x)
 337                                 continue;
 338                         if (resizeorigin_y <= panel_pos_y)
 339                                 continue;
 340                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 341                                 continue;
 342                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 343                                 continue;
 344
 345                         // there is a collision:
 346                         // detect which side of the panel we are facing is actually limiting the resizing
 347                         // (which side the resize direction finds for first) and reduce the size up to there
 348                         //
 349                         // dist is the distance between resizeorigin and the "analogous" point of the panel
 350                         // in this case between resizeorigin (bottom-right point) and the bottom-right point of the panel
 351                         dist_x = resizeorigin_x - targEndPos_x;
 352                         dist_y = resizeorigin_y - targEndPos_y;
 353                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 354                                 mySize_x = min(mySize_x, dist_x);
 355                         else
 356                                 mySize_y = min(mySize_y, dist_y);
 357                 }
 358                 else if (resizeCorner == 2)
 359                 {
 360                         if (resizeorigin_x >= targEndPos_x)
 361                                 continue;
 362                         if (resizeorigin_y <= panel_pos_y)
 363                                 continue;
 364                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 365                                 continue;
 366                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 367                                 continue;
 368
 369                         dist_x = panel_pos_x - resizeorigin_x;
 370                         dist_y = resizeorigin_y - targEndPos_y;
 371                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 372                                 mySize_x = min(mySize_x, dist_x);
 373                         else
 374                                 mySize_y = min(mySize_y, dist_y);
 375                 }
 376                 else if (resizeCorner == 3)
 377                 {
 378                         if (resizeorigin_x <= panel_pos_x)
 379                                 continue;
 380                         if (resizeorigin_y >= targEndPos_y)
 381                                 continue;
 382                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 383                                 continue;
 384                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 385                                 continue;
 386
 387                         dist_x = resizeorigin_x - targEndPos_x;
 388                         dist_y = panel_pos_y - resizeorigin_y;
 389                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 390                                 mySize_x = min(mySize_x, dist_x);
 391                         else
 392                                 mySize_y = min(mySize_y, dist_y);
 393                 }
 394                 else if (resizeCorner == 4)
 395                 {
 396                         if (resizeorigin_x >= targEndPos_x)
 397                                 continue;
 398                         if (resizeorigin_y >= targEndPos_y)
 399                                 continue;
 400                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 401                                 continue;
 402                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 403                                 continue;
 404
 405                         dist_x = panel_pos_x - resizeorigin_x;
 406                         dist_y = panel_pos_y - resizeorigin_y;
 407                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 408                                 mySize_x = min(mySize_x, dist_x);
 409                         else
 410                                 mySize_y = min(mySize_y, dist_y);
 411                 }
 412                 //if(cvar("hud_configure_checkcollisions_debug"))
 413                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 414         }
 415
 416         return mySize;
 417 }
 418
 419 void HUD_Panel_SetPosSize(vector mySize)
 420 {
 421         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 422         vector resizeorigin;
 423         resizeorigin = panel_click_resizeorigin;
 424         local noref vector myPos; // fteqcc sucks
 425
 426         // minimum panel size cap
 427         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 428         mySize_y = max(0.025 * vid_conheight, mySize_y);
 429
 430         if(highlightedPanel == HUD_PANEL_CHAT) // some panels have their own restrictions, like the chat panel (which actually only moves the engine chat print around). Looks bad if it's too small.
 431         {
 432                 mySize_x = max(17 * autocvar_con_chatsize, mySize_x);
 433                 mySize_y = max(2 * autocvar_con_chatsize + 2 * panel_bg_padding, mySize_y);
 434         }
 435
 436         // collision testing|
 437         // -----------------+
 438
 439         // we need to know pos at this stage, but it might still change later if we hit a screen edge/other panel (?)
 440         if(resizeCorner == 1) {
 441                 myPos_x = resizeorigin_x - mySize_x;
 442                 myPos_y = resizeorigin_y - mySize_y;
 443         } else if(resizeCorner == 2) {
 444                 myPos_x = resizeorigin_x;
 445                 myPos_y = resizeorigin_y - mySize_y;
 446         } else if(resizeCorner == 3) {
 447                 myPos_x = resizeorigin_x - mySize_x;
 448                 myPos_y = resizeorigin_y;
 449         } else { // resizeCorner == 4
 450                 myPos_x = resizeorigin_x;
 451                 myPos_y = resizeorigin_y;
 452         }
 453
 454         // left/top screen edges
 455         if(myPos_x < 0)
 456                 mySize_x = mySize_x + myPos_x;
 457         if(myPos_y < 0)
 458                 mySize_y = mySize_y + myPos_y;
 459
 460         // bottom/right screen edges
 461         if(myPos_x + mySize_x > vid_conwidth)
 462                 mySize_x = vid_conwidth - myPos_x;
 463         if(myPos_y + mySize_y > vid_conheight)
 464                 mySize_y = vid_conheight - myPos_y;
 465
 466         //if(cvar("hud_configure_checkcollisions_debug"))
 467                 //drawfill(myPos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 468
 469         // before checkresize, otherwise panel can be snapped partially inside another panel or panel aspect ratio can be broken
 470         if(autocvar_hud_configure_grid)
 471         {
 472                 mySize_x = floor((mySize_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 473                 mySize_y = floor((mySize_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 474         }
 475
 476         if(hud_configure_checkcollisions)
 477                 mySize = HUD_Panel_CheckResize(mySize, resizeorigin);
 478
 479         // minimum panel size cap, do this once more so we NEVER EVER EVER have a panel smaller than this, JUST IN CASE above code still makes the panel eg negative (impossible to resize back without changing cvars manually then)
 480         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 481         mySize_y = max(0.025 * vid_conheight, mySize_y);
 482
 483         // do another pos check, as size might have changed by now
 484         if(resizeCorner == 1) {
 485                 myPos_x = resizeorigin_x - mySize_x;
 486                 myPos_y = resizeorigin_y - mySize_y;
 487         } else if(resizeCorner == 2) {
 488                 myPos_x = resizeorigin_x;
 489                 myPos_y = resizeorigin_y - mySize_y;
 490         } else if(resizeCorner == 3) {
 491                 myPos_x = resizeorigin_x - mySize_x;
 492                 myPos_y = resizeorigin_y;
 493         } else { // resizeCorner == 4
 494                 myPos_x = resizeorigin_x;
 495                 myPos_y = resizeorigin_y;
 496         }
 497
 498         //if(cvar("hud_configure_checkcollisions_debug"))
 499                 //drawfill(myPos, mySize, '0 1 0', .3, DRAWFLAG_NORMAL);
 500
 501         HUD_Panel_GetName(highlightedPanel);
 502         string s;
 503         s = strcat(ftos(mySize_x/vid_conwidth), " ", ftos(mySize_y/vid_conheight));
 504         cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 505
 506         s = strcat(ftos(myPos_x/vid_conwidth), " ", ftos(myPos_y/vid_conheight));
 507         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 508 }
 509
 510 float pressed_key_time;
 511 vector highlightedPanel_initial_pos, highlightedPanel_initial_size;
 512 void HUD_Panel_Arrow_Action(float nPrimary)
 513 {
 514         if (highlightedPanel == -1)
 515                 return;
 516
 517         hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
 518
 519         float step;
 520         if(autocvar_hud_configure_grid)
 521         {
 522                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 523                 {
 524                         if (hudShiftState & S_SHIFT)
 525                                 step = hud_configure_realGridSize_y;
 526                         else
 527                                 step = 2 * hud_configure_realGridSize_y;
 528                 }
 529                 else
 530                 {
 531                         if (hudShiftState & S_SHIFT)
 532                                 step = hud_configure_realGridSize_x;
 533                         else
 534                                 step = 2 * hud_configure_realGridSize_x;
 535                 }
 536         }
 537         else
 538         {
 539                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 540                         step = vid_conheight;
 541                 else
 542                         step = vid_conwidth;
 543                 if (hudShiftState & S_SHIFT)
 544                         step = (step / 256); // more precision
 545                 else
 546                         step = (step / 64) * (1 + 2 * (time - pressed_key_time));
 547         }
 548
 549         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 550
 551         highlightedPanel_initial_pos = panel_pos;
 552         highlightedPanel_initial_size = panel_size;
 553
 554         if (hudShiftState & S_ALT) // resize
 555         {
 556                 highlightedAction = 1;
 557                 if(nPrimary == K_UPARROW)
 558                         resizeCorner = 1;
 559                 else if(nPrimary == K_RIGHTARROW)
 560                         resizeCorner = 2;
 561                 else if(nPrimary == K_LEFTARROW)
 562                         resizeCorner = 3;
 563                 else // if(nPrimary == K_DOWNARROW)
 564                         resizeCorner = 4;
 565
 566                 // ctrl+arrow reduces the size, instead of increasing it
 567                 // Note that ctrl disables collisions check too, but it's fine
 568                 // since we don't collide with anything reducing the size
 569                 if (hudShiftState & S_CTRL) {
 570                         step = -step;
 571                         resizeCorner = 5 - resizeCorner;
 572                 }
 573
 574                 vector mySize;
 575                 mySize = panel_size;
 576                 panel_click_resizeorigin = panel_pos;
 577                 if(resizeCorner == 1) {
 578                         panel_click_resizeorigin += mySize;
 579                         mySize_y += step;
 580                 } else if(resizeCorner == 2) {
 581                         panel_click_resizeorigin_y += mySize_y;
 582                         mySize_x += step;
 583                 } else if(resizeCorner == 3) {
 584                         panel_click_resizeorigin_x += mySize_x;
 585                         mySize_x += step;
 586                 } else { // resizeCorner == 4
 587                         mySize_y += step;
 588                 }
 589                 HUD_Panel_SetPosSize(mySize);
 590         }
 591         else // move
 592         {
 593                 highlightedAction = 2;
 594                 vector pos;
 595                 pos = panel_pos;
 596                 if(nPrimary == K_UPARROW)
 597                         pos_y -= step;
 598                 else if(nPrimary == K_DOWNARROW)
 599                         pos_y += step;
 600                 else if(nPrimary == K_LEFTARROW)
 601                         pos_x -= step;
 602                 else // if(nPrimary == K_RIGHTARROW)
 603                         pos_x += step;
 604
 605                 HUD_Panel_SetPos(pos);
 606         }
 607
 608         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 609
 610         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
 611         {
 612                 // backup!
 613                 panel_pos_backup = highlightedPanel_initial_pos;
 614                 panel_size_backup = highlightedPanel_initial_size;
 615                 highlightedPanel_backup = highlightedPanel;
 616         }
 617 }
 618
 619 const float S_MOUSE1 = 1;
 620 const float S_MOUSE2 = 2;
 621 const float S_MOUSE3 = 4;
 622 float mouseClicked;
 623 float prevMouseClicked; // previous state
 624 float prevMouseClickedTime; // time during previous left mouse click, to check for doubleclicks
 625 vector prevMouseClickedPos; // pos during previous left mouse click, to check for doubleclicks
 626
 627 void HUD_Panel_EnableMenu();
 628 float tab_panels[HUD_PANEL_NUM];
 629 float tab_panel, tab_backward;
 630 vector tab_panel_pos;
 631 void HUD_Panel_FirstInDrawQ(float id);
 632 void reset_tab_panels()
 633 {
 634         int i;
 635         for(i = 0; i < HUD_PANEL_NUM; ++i)
 636                 tab_panels[i] = -1;
 637 }
 638 float HUD_Panel_InputEvent(float bInputType, float nPrimary, float nSecondary)
 639 {
 640         string s;
 641
 642         if(bInputType == 2)
 643                 return false;
 644
 645         if(!autocvar__hud_configure)
 646                 return false;
 647
 648         // block any input while a menu dialog is fading
 649         if(autocvar__menu_alpha)
 650                 return true;
 651
 652         if(bInputType == 3)
 653         {
 654                 mousepos_x = nPrimary;
 655                 mousepos_y = nSecondary;
 656                 return true;
 657         }
 658
 659         // allow console bind to work
 660         string con_keys;
 661         float keys;
 662         con_keys = findkeysforcommand("toggleconsole", 0);
 663         keys = tokenize(con_keys); // findkeysforcommand returns data for this
 664
 665         float hit_con_bind = 0, i;
 666         for (i = 0; i < keys; ++i)
 667         {
 668                 if(nPrimary == stof(argv(i)))
 669                         hit_con_bind = 1;
 670         }
 671
 672         if(bInputType == 0) {
 673                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 674                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 675                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 676         }
 677         else if(bInputType == 1) {
 678                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 679                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 680                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 681         }
 682
 683         if(nPrimary == K_CTRL)
 684         {
 685                 if (bInputType == 1) //ctrl has been released
 686                 {
 687                         if (tab_panel != -1)
 688                         {
 689                                 //switch to selected panel
 690                                 highlightedPanel = tab_panel;
 691                                 highlightedAction = 0;
 692                                 HUD_Panel_FirstInDrawQ(highlightedPanel);
 693                         }
 694                         tab_panel = -1;
 695                         reset_tab_panels();
 696                 }
 697         }
 698
 699         if(nPrimary == K_MOUSE1)
 700         {
 701                 if(bInputType == 0) // key pressed
 702                         mouseClicked |= S_MOUSE1;
 703                 else if(bInputType == 1) // key released
 704                         mouseClicked -= (mouseClicked & S_MOUSE1);
 705         }
 706         else if(nPrimary == K_MOUSE2)
 707         {
 708                 if(bInputType == 0) // key pressed
 709                         mouseClicked |= S_MOUSE2;
 710                 else if(bInputType == 1) // key released
 711                         mouseClicked -= (mouseClicked & S_MOUSE2);
 712         }
 713         else if(nPrimary == K_ESCAPE)
 714         {
 715                 if (bInputType == 1)
 716                         return true;
 717                 menu_enabled = 1;
 718                 menu_enabled_time = time;
 719                 localcmd("menu_showhudexit\n");
 720         }
 721         else if(nPrimary == K_BACKSPACE && hudShiftState & S_CTRL)
 722         {
 723                 if (bInputType == 1)
 724                         return true;
 725                 if (!menu_enabled)
 726                         cvar_set("_hud_configure", "0");
 727         }
 728         else if(nPrimary == K_TAB && hudShiftState & S_CTRL) // select and highlight another panel
 729         {
 730                 if (bInputType == 1 || mouseClicked)
 731                         return true;
 732
 733                 //FIXME: if a panel is highlighted, has the same pos_x and lays in the same level
 734                 //of other panels then next consecutive ctrl-tab will select the highlighted panel too
 735                 //(it should only after every other panel of the hud)
 736                 //It's a minor bug anyway, we can live with it
 737
 738                 float starting_panel;
 739                 float old_tab_panel = tab_panel;
 740                 if (tab_panel == -1) //first press of TAB
 741                 {
 742                         if (highlightedPanel != -1)
 743                                 HUD_Panel_UpdatePosSizeForId(highlightedPanel)
 744                         else
 745                                 panel_pos = '0 0 0';
 746                         starting_panel = highlightedPanel; //can be -1, it means no starting panel
 747                         tab_panel_pos = panel_pos; //to compute level
 748                 }
 749                 else
 750                 {
 751                         if ( ((!tab_backward) && (hudShiftState & S_SHIFT)) || (tab_backward && !(hudShiftState & S_SHIFT)) ) //tab direction changed?
 752                                 reset_tab_panels();
 753                         starting_panel = tab_panel;
 754                 }
 755                 tab_backward = (hudShiftState & S_SHIFT);
 756
 757                 float k, level = 0, start_pos_x;
 758                 vector candidate_pos = '0 0 0';
 759                 const float LEVELS_NUM = 4;
 760                 float level_height = vid_conheight / LEVELS_NUM;
 761 :find_tab_panel
 762                 level = floor(tab_panel_pos_y / level_height) * level_height; //starting level
 763                 candidate_pos_x = (!tab_backward) ? vid_conwidth : 0;
 764                 start_pos_x = tab_panel_pos_x;
 765                 tab_panel = -1;
 766                 k=0;
 767                 while(++k)
 768                 {
 769                         for(i = 0; i < HUD_PANEL_NUM; ++i)
 770                         {
 771                                 if (i == tab_panels[i] || i == starting_panel)
 772                                         continue;
 773                                 HUD_Panel_UpdatePosSizeForId(i)
 774                                 if (panel_pos_y >= level && (panel_pos_y - level) < level_height)
 775                                 if (  ( !tab_backward && panel_pos_x >= start_pos_x && (panel_pos_x < candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y <= candidate_pos_y)) )
 776                                         || ( tab_backward && panel_pos_x <= start_pos_x && (panel_pos_x > candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y >= candidate_pos_y)) )  )
 777                                 {
 778                                         tab_panel = i;
 779                                         tab_panel_pos = candidate_pos = panel_pos;
 780                                 }
 781                         }
 782                         if (tab_panel != -1)
 783                                 break;
 784                         if (k == LEVELS_NUM) //tab_panel not found
 785                         {
 786                                 reset_tab_panels();
 787                                 if (old_tab_panel == -2) //this prevents an infinite loop (should not happen normally)
 788                                 {
 789                                         tab_panel = -1;
 790                                         return true;
 791                                 }
 792                                 starting_panel = old_tab_panel;
 793                                 old_tab_panel = -2;
 794                                 goto find_tab_panel; //u must find tab_panel!
 795                         }
 796                         if (!tab_backward)
 797                         {
 798                                 level = mod(level + level_height, vid_conheight);
 799                                 start_pos_x = 0;
 800                                 candidate_pos_x = vid_conwidth;
 801                         }
 802                         else
 803                         {
 804                                 level = mod(level - level_height, vid_conheight);
 805                                 start_pos_x = vid_conwidth;
 806                                 candidate_pos_x = 0;
 807                         }
 808                 }
 809
 810                 tab_panels[tab_panel] = tab_panel;
 811         }
 812         else if(nPrimary == K_SPACE && hudShiftState & S_CTRL) // enable/disable highlighted panel or dock
 813         {
 814                 if (bInputType == 1 || mouseClicked)
 815                         return true;
 816
 817                 if (highlightedPanel != -1)
 818                 {
 819                         HUD_Panel_GetName(highlightedPanel);
 820                         cvar_set(strcat("hud_panel_", panel_name), ftos(!(panel_enabled)));
 821                 }
 822                 else
 823                         cvar_set(strcat("hud_dock"), (autocvar_hud_dock == "") ? "dock" : "");
 824         }
 825         else if(nPrimary == 'c' && hudShiftState & S_CTRL) // copy highlighted panel size
 826         {
 827                 if (bInputType == 1 || mouseClicked)
 828                         return true;
 829
 830                 if (highlightedPanel != -1)
 831                 {
 832                         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 833                         panel_size_copied = panel_size;
 834                         highlightedPanel_copied = highlightedPanel;
 835                 }
 836         }
 837         else if(nPrimary == 'v' && hudShiftState & S_CTRL) // past copied size on the highlighted panel
 838         {
 839                 if (bInputType == 1 || mouseClicked)
 840                         return true;
 841
 842                 if (highlightedPanel_copied == -1 || highlightedPanel == -1)
 843                         return true;
 844
 845                 HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 846
 847                 // reduce size if it'd go beyond screen boundaries
 848                 vector tmp_size = panel_size_copied;
 849                 if (panel_pos_x + panel_size_copied_x > vid_conwidth)
 850                         tmp_size_x = vid_conwidth - panel_pos_x;
 851                 if (panel_pos_y + panel_size_copied_y > vid_conheight)
 852                         tmp_size_y = vid_conheight - panel_pos_y;
 853
 854                 if (panel_size == tmp_size)
 855                         return true;
 856
 857                 // backup first!
 858                 panel_pos_backup = panel_pos;
 859                 panel_size_backup = panel_size;
 860                 highlightedPanel_backup = highlightedPanel;
 861
 862                 s = strcat(ftos(tmp_size_x/vid_conwidth), " ", ftos(tmp_size_y/vid_conheight));
 863                 HUD_Panel_GetName(highlightedPanel);
 864                 cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 865         }
 866         else if(nPrimary == 'z' && hudShiftState & S_CTRL) // undo last action
 867         {
 868                 if (bInputType == 1 || mouseClicked)
 869                         return true;
 870                 //restore previous values
 871                 if (highlightedPanel_backup != -1)
 872                 {
 873                         HUD_Panel_GetName(highlightedPanel_backup);
 874                         s = strcat(ftos(panel_pos_backup_x/vid_conwidth), " ", ftos(panel_pos_backup_y/vid_conheight));
 875                         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 876                         s = strcat(ftos(panel_size_backup_x/vid_conwidth), " ", ftos(panel_size_backup_y/vid_conheight));
 877                         cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 878                         highlightedPanel_backup = -1;
 879                 }
 880         }
 881         else if(nPrimary == K_UPARROW || nPrimary == K_DOWNARROW || nPrimary == K_LEFTARROW || nPrimary == K_RIGHTARROW)
 882         {
 883                 if (bInputType == 1)
 884                 {
 885                         pressed_key_time = 0;
 886                         return true;
 887                 }
 888                 else if (pressed_key_time == 0)
 889                         pressed_key_time = time;
 890
 891                 if (!mouseClicked)
 892                         HUD_Panel_Arrow_Action(nPrimary); //move or resize panel
 893         }
 894         else if(nPrimary == K_ENTER || nPrimary == K_SPACE || nPrimary == K_KP_ENTER)
 895         {
 896                 if (bInputType == 1)
 897                         return true;
 898                 if (highlightedPanel != -1)
 899                         HUD_Panel_EnableMenu();
 900         }
 901         else if(hit_con_bind)
 902                 return false;
 903
 904         return true;
 905 }
 906
 907 float HUD_Panel_Check_Mouse_Pos(float allow_move)
 908 {
 909         float i, j = 0, border;
 910
 911         while(j < HUD_PANEL_NUM)
 912         {
 913                 i = panel_order[j];
 914                 j += 1;
 915
 916                 HUD_Panel_UpdatePosSizeForId(i);
 917
 918                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 919
 920                 // move
 921                 if(allow_move && mousepos_x > panel_pos_x && mousepos_y > panel_pos_y && mousepos_x < panel_pos_x + panel_size_x && mousepos_y < panel_pos_y + panel_size_y)
 922                 {
 923                         return 1;
 924                 }
 925                 // resize from topleft border
 926                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 927                 {
 928                         return 2;
 929                 }
 930                 // resize from topright border
 931                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 932                 {
 933                         return 3;
 934                 }
 935                 // resize from bottomleft border
 936                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
 937                 {
 938                         return 3;
 939                 }
 940                 // resize from bottomright border
 941                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
 942                 {
 943                         return 2;
 944                 }
 945         }
 946         return 0;
 947 }
 948
 949 // move a panel to the beginning of the panel order array (which means it gets drawn last, on top of everything else)
 950 void HUD_Panel_FirstInDrawQ(float id)
 951 {
 952         float i;
 953         var float place = -1;
 954         // find out where in the array our current id is, save into place
 955         for(i = 0; i < HUD_PANEL_NUM; ++i)
 956         {
 957                 if(panel_order[i] == id)
 958                 {
 959                         place = i;
 960                         break;
 961                 }
 962         }
 963         // place last if we didn't find a place for it yet (probably new panel, or screwed up cvar)
 964         if(place == -1)
 965                 place = HUD_PANEL_NUM - 1;
 966
 967         // move all ids up by one step in the array until "place"
 968         for(i = place; i > 0; --i)
 969         {
 970                 panel_order[i] = panel_order[i-1];
 971         }
 972         // now save the new top id
 973         panel_order[0] = id;
 974
 975         // let's save them into the cvar by some strcat trickery
 976         string s = "";
 977         for(i = 0; i < HUD_PANEL_NUM; ++i)
 978         {
 979                 s = strcat(s, ftos(panel_order[i]), " ");
 980         }
 981         cvar_set("_hud_panelorder", s);
 982         if(hud_panelorder_prev)
 983                 strunzone(hud_panelorder_prev);
 984         hud_panelorder_prev = strzone(autocvar__hud_panelorder); // prevent HUD_Main from doing useless update, we already updated here
 985 }
 986
 987 void HUD_Panel_Highlight(float allow_move)
 988 {
 989         float i, j = 0, border;
 990
 991         while(j < HUD_PANEL_NUM)
 992         {
 993                 i = panel_order[j];
 994                 j += 1;
 995
 996                 HUD_Panel_UpdatePosSizeForId(i);
 997
 998                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 999
1000                 // move
1001                 if(allow_move && mousepos_x > panel_pos_x && mousepos_y > panel_pos_y && mousepos_x < panel_pos_x + panel_size_x && mousepos_y < panel_pos_y + panel_size_y)
1002                 {
1003                         highlightedPanel = i;
1004                         HUD_Panel_FirstInDrawQ(i);
1005                         highlightedAction = 1;
1006                         panel_click_distance = mousepos - panel_pos;
1007                         return;
1008                 }
1009                 // resize from topleft border
1010                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
1011                 {
1012                         highlightedPanel = i;
1013                         HUD_Panel_FirstInDrawQ(i);
1014                         highlightedAction = 2;
1015                         resizeCorner = 1;
1016                         panel_click_distance = mousepos - panel_pos;
1017                         panel_click_resizeorigin = panel_pos + panel_size;
1018                         return;
1019                 }
1020                 // resize from topright border
1021                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
1022                 {
1023                         highlightedPanel = i;
1024                         HUD_Panel_FirstInDrawQ(i);
1025                         highlightedAction = 2;
1026                         resizeCorner = 2;
1027                         panel_click_distance_x = panel_size_x - mousepos_x + panel_pos_x;
1028                         panel_click_distance_y = mousepos_y - panel_pos_y;
1029                         panel_click_resizeorigin = panel_pos + eY * panel_size_y;
1030                         return;
1031                 }
1032                 // resize from bottomleft border
1033                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
1034                 {
1035                         highlightedPanel = i;
1036                         HUD_Panel_FirstInDrawQ(i);
1037                         highlightedAction = 2;
1038                         resizeCorner = 3;
1039                         panel_click_distance_x = mousepos_x - panel_pos_x;
1040                         panel_click_distance_y = panel_size_y - mousepos_y + panel_pos_y;
1041                         panel_click_resizeorigin = panel_pos + eX * panel_size_x;
1042                         return;
1043                 }
1044                 // resize from bottomright border
1045                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
1046                 {
1047                         highlightedPanel = i;
1048                         HUD_Panel_FirstInDrawQ(i);
1049                         highlightedAction = 2;
1050                         resizeCorner = 4;
1051                         panel_click_distance = panel_size - mousepos + panel_pos;
1052                         panel_click_resizeorigin = panel_pos;
1053                         return;
1054                 }
1055         }
1056         highlightedPanel = -1;
1057         highlightedAction = 0;
1058 }
1059
1060 void HUD_Panel_EnableMenu()
1061 {
1062         menu_enabled = 2;
1063         menu_enabled_time = time;
1064         HUD_Panel_GetName(highlightedPanel);
1065         localcmd("menu_showhudoptions ", panel_name, "\n");
1066 }
1067 float mouse_over_panel;
1068 void HUD_Panel_Mouse()
1069 {
1070         // TODO: needs better check... is there any float that contains the current state of the menu? _menu_alpha isn't apparently updated the frame the menu gets enabled
1071         if (autocvar__menu_alpha == 0 && time - menu_enabled_time > 0.5)
1072                 menu_enabled = 0;
1073
1074         /*
1075         print("menu_enabled: ", ftos(menu_enabled), "\n");
1076         print("Highlighted: ", ftos(highlightedPanel), "\n");
1077         print("Menu theAlpha: ", ftos(autocvar__menu_alpha), "\n");
1078         */
1079
1080         if(autocvar__menu_alpha == 1)
1081                 return;
1082
1083         if not(autocvar_hud_cursormode)
1084         {
1085                 mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
1086
1087                 mousepos_x = bound(0, mousepos_x, vid_conwidth);
1088                 mousepos_y = bound(0, mousepos_y, vid_conheight);
1089         }
1090
1091         if(mouseClicked)
1092         {
1093                 if(prevMouseClicked == 0)
1094                 {
1095                         if (tab_panel != -1)
1096                         {
1097                                 //stop ctrl-tab selection
1098                                 tab_panel = -1;
1099                                 reset_tab_panels();
1100                         }
1101                         HUD_Panel_Highlight(mouseClicked & S_MOUSE1); // sets highlightedPanel, highlightedAction, panel_click_distance, panel_click_resizeorigin
1102                                                                         // and calls HUD_Panel_UpdatePosSizeForId() for the highlighted panel
1103                         if (highlightedPanel != -1)
1104                         {
1105                                 highlightedPanel_initial_pos = panel_pos;
1106                                 highlightedPanel_initial_size = panel_size;
1107                         }
1108                         // doubleclick check
1109                         if ((mouseClicked & S_MOUSE1) && time - prevMouseClickedTime < 0.4 && highlightedPanel != -1 && prevMouseClickedPos == mousepos)
1110                         {
1111                                 mouseClicked = 0; // to prevent spam, I guess.
1112                                 HUD_Panel_EnableMenu();
1113                         }
1114                         else
1115                         {
1116                                 if (mouseClicked & S_MOUSE1)
1117                                 {
1118                                         prevMouseClickedTime = time;
1119                                         prevMouseClickedPos = mousepos;
1120                                 }
1121                                 mouse_over_panel = HUD_Panel_Check_Mouse_Pos(mouseClicked & S_MOUSE1);
1122                         }
1123                 }
1124                 else
1125                         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
1126
1127                 if (highlightedPanel != -1)
1128                 {
1129                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1130                         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
1131                         {
1132                                 hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
1133                                 // backup!
1134                                 panel_pos_backup = highlightedPanel_initial_pos;
1135                                 panel_size_backup = highlightedPanel_initial_size;
1136                                 highlightedPanel_backup = highlightedPanel;
1137                         }
1138                         else
1139                                 // in case the clicked panel is inside another panel and we aren't
1140                                 // moving it, avoid the immediate "fix" of its position/size
1141                                 // (often unwanted and hateful) by disabling collisions check
1142                                 hud_configure_checkcollisions = false;
1143                 }
1144
1145                 if(highlightedAction == 1)
1146                         HUD_Panel_SetPos(mousepos - panel_click_distance);
1147                 else if(highlightedAction == 2)
1148                 {
1149                         vector mySize = '0 0 0';
1150                         if(resizeCorner == 1) {
1151                                 mySize_x = panel_click_resizeorigin_x - (mousepos_x - panel_click_distance_x);
1152                                 mySize_y = panel_click_resizeorigin_y - (mousepos_y - panel_click_distance_y);
1153                         } else if(resizeCorner == 2) {
1154                                 mySize_x = mousepos_x + panel_click_distance_x - panel_click_resizeorigin_x;
1155                                 mySize_y = panel_click_distance_y + panel_click_resizeorigin_y - mousepos_y;
1156                         } else if(resizeCorner == 3) {
1157                                 mySize_x = panel_click_resizeorigin_x + panel_click_distance_x - mousepos_x;
1158                                 mySize_y = mousepos_y + panel_click_distance_y - panel_click_resizeorigin_y;
1159                         } else { // resizeCorner == 4
1160                                 mySize_x = mousepos_x - (panel_click_resizeorigin_x - panel_click_distance_x);
1161                                 mySize_y = mousepos_y - (panel_click_resizeorigin_y - panel_click_distance_y);
1162                         }
1163                         HUD_Panel_SetPosSize(mySize);
1164                 }
1165         }
1166         else
1167         {
1168                 if(menu_enabled == 2)
1169                         mouse_over_panel = 0;
1170                 else
1171                         mouse_over_panel = HUD_Panel_Check_Mouse_Pos(TRUE);
1172                 if (mouse_over_panel && tab_panel == -1)
1173                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1174         }
1175         // draw cursor after performing move/resize to have the panel pos/size updated before mouse_over_panel
1176         const vector cursorsize = '32 32 0';
1177         float cursor_alpha = 1 - autocvar__menu_alpha;
1178
1179         if(!mouse_over_panel)
1180                 drawpic(mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1181         else if(mouse_over_panel == 1)
1182                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_move.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1183         else if(mouse_over_panel == 2)
1184                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1185         else
1186                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize2.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1187
1188         prevMouseClicked = mouseClicked;
1189 }
1190
1191 const float hlBorderSize = 4;
1192 const string hlBorder = "gfx/hud/default/border_highlighted";
1193 const string hlBorder2 = "gfx/hud/default/border_highlighted2";
1194 void HUD_Panel_HlBorder(float myBorder, vector color, float theAlpha)
1195 {
1196         drawfill(panel_pos - '1 1 0' * myBorder, panel_size + '2 2 0' * myBorder, '0 0.5 1', .5 * theAlpha, DRAWFLAG_NORMAL);
1197         drawpic_tiled(panel_pos - '1 1 0' * myBorder, hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1198         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * (panel_size_y + 2 * myBorder - hlBorderSize), hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1199         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize, hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1200         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize + eX * (panel_size_x + 2 * myBorder - hlBorderSize), hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1201 }