qcsrc/client/hud_config.qc

   1 #define HUD_Write(s) fputs(fh, s)
   2 // q: quoted, n: not quoted
   3 #define HUD_Write_Cvar_n(cvar) HUD_Write(strcat("seta ", cvar, " ", cvar_string(cvar), "\n"))
   4 #define HUD_Write_Cvar_q(cvar) HUD_Write(strcat("seta ", cvar, " \"", cvar_string(cvar), "\"\n"))
   5 #define HUD_Write_PanelCvar_n(cvar_suf) HUD_Write_Cvar_n(strcat("hud_panel_", panel_name, cvar_suf))
   6 #define HUD_Write_PanelCvar_q(cvar_suf) HUD_Write_Cvar_q(strcat("hud_panel_", panel_name, cvar_suf))
   7 // Save the config
   8 void HUD_Panel_ExportCfg(string cfgname)
   9 {
  10         float fh;
  11         string filename = strcat("hud_", autocvar_hud_skin, "_", cfgname, ".cfg");
  12         fh = fopen(filename, FILE_WRITE);
  13         if(fh >= 0)
  14         {
  15                 HUD_Write_Cvar_q("hud_skin");
  16                 HUD_Write_Cvar_q("hud_panel_bg");
  17                 HUD_Write_Cvar_q("hud_panel_bg_color");
  18                 HUD_Write_Cvar_q("hud_panel_bg_color_team");
  19                 HUD_Write_Cvar_q("hud_panel_bg_alpha");
  20                 HUD_Write_Cvar_q("hud_panel_bg_border");
  21                 HUD_Write_Cvar_q("hud_panel_bg_padding");
  22                 HUD_Write_Cvar_q("hud_panel_fg_alpha");
  23                 HUD_Write("\n");
  24
  25                 HUD_Write_Cvar_q("hud_dock");
  26                 HUD_Write_Cvar_q("hud_dock_color");
  27                 HUD_Write_Cvar_q("hud_dock_color_team");
  28                 HUD_Write_Cvar_q("hud_dock_alpha");
  29                 HUD_Write("\n");
  30
  31                 HUD_Write_Cvar_q("hud_progressbar_alpha");
  32                 HUD_Write_Cvar_q("hud_progressbar_strength_color");
  33                 HUD_Write_Cvar_q("hud_progressbar_shield_color");
  34                 HUD_Write_Cvar_q("hud_progressbar_health_color");
  35                 HUD_Write_Cvar_q("hud_progressbar_armor_color");
  36                 HUD_Write_Cvar_q("hud_progressbar_fuel_color");
  37                 HUD_Write_Cvar_q("hud_progressbar_nexball_color");
  38                 HUD_Write_Cvar_q("hud_progressbar_speed_color");
  39                 HUD_Write_Cvar_q("hud_progressbar_acceleration_color");
  40                 HUD_Write_Cvar_q("hud_progressbar_acceleration_neg_color");
  41                 HUD_Write("\n");
  42
  43                 HUD_Write_Cvar_q("_hud_panelorder");
  44                 HUD_Write("\n");
  45
  46                 HUD_Write_Cvar_q("hud_configure_grid");
  47                 HUD_Write_Cvar_q("hud_configure_grid_xsize");
  48                 HUD_Write_Cvar_q("hud_configure_grid_ysize");
  49                 HUD_Write("\n");
  50
  51                 // common cvars for all panels
  52                 float i;
  53                 for (i = 0; i < HUD_PANEL_NUM; ++i)
  54                 {
  55                         HUD_Panel_GetName(i);
  56
  57                         HUD_Write_PanelCvar_n("");
  58                         HUD_Write_PanelCvar_q("_pos");
  59                         HUD_Write_PanelCvar_q("_size");
  60                         HUD_Write_PanelCvar_q("_bg");
  61                         HUD_Write_PanelCvar_q("_bg_color");
  62                         HUD_Write_PanelCvar_q("_bg_color_team");
  63                         HUD_Write_PanelCvar_q("_bg_alpha");
  64                         HUD_Write_PanelCvar_q("_bg_border");
  65                         HUD_Write_PanelCvar_q("_bg_padding");
  66                         switch(i) {
  67                                 case HUD_PANEL_WEAPONS:
  68                                         HUD_Write_PanelCvar_q("_accuracy");
  69                                         HUD_Write_PanelCvar_q("_label");
  70                                         HUD_Write_PanelCvar_q("_complainbubble");
  71                                         HUD_Write_PanelCvar_q("_complainbubble_padding");
  72                                         HUD_Write_PanelCvar_q("_complainbubble_time");
  73                                         HUD_Write_PanelCvar_q("_complainbubble_fadetime");
  74                                         HUD_Write_PanelCvar_q("_complainbubble_color_outofammo");
  75                                         HUD_Write_PanelCvar_q("_complainbubble_color_donthave");
  76                                         HUD_Write_PanelCvar_q("_complainbubble_color_unavailable");
  77                                         HUD_Write_PanelCvar_q("_ammo");
  78                                         HUD_Write_PanelCvar_q("_ammo_color");
  79                                         HUD_Write_PanelCvar_q("_ammo_alpha");
  80                                         HUD_Write_PanelCvar_q("_aspect");
  81                                         HUD_Write_PanelCvar_q("_timeout");
  82                                         HUD_Write_PanelCvar_q("_timeout_effect");
  83                                         HUD_Write_PanelCvar_q("_onlyowned");
  84                                         break;
  85                                 case HUD_PANEL_AMMO:
  86                                         HUD_Write_PanelCvar_q("_onlycurrent");
  87                                         HUD_Write_PanelCvar_q("_iconalign");
  88                                         HUD_Write_PanelCvar_q("_progressbar");
  89                                         HUD_Write_PanelCvar_q("_progressbar_name");
  90                                         HUD_Write_PanelCvar_q("_progressbar_xoffset");
  91                                         HUD_Write_PanelCvar_q("_text");
  92                                         break;
  93                                 case HUD_PANEL_POWERUPS:
  94                                         HUD_Write_PanelCvar_q("_flip");
  95                                         HUD_Write_PanelCvar_q("_iconalign");
  96                                         HUD_Write_PanelCvar_q("_baralign");
  97                                         HUD_Write_PanelCvar_q("_progressbar");
  98                                         HUD_Write_PanelCvar_q("_progressbar_strength");
  99                                         HUD_Write_PanelCvar_q("_progressbar_shield");
 100                                         HUD_Write_PanelCvar_q("_text");
 101                                         break;
 102                                 case HUD_PANEL_HEALTHARMOR:
 103                                         HUD_Write_PanelCvar_q("_flip");
 104                                         HUD_Write_PanelCvar_q("_iconalign");
 105                                         HUD_Write_PanelCvar_q("_baralign");
 106                                         HUD_Write_PanelCvar_q("_progressbar");
 107                                         HUD_Write_PanelCvar_q("_progressbar_health");
 108                                         HUD_Write_PanelCvar_q("_progressbar_armor");
 109                                         HUD_Write_PanelCvar_q("_progressbar_gfx");
 110                                         HUD_Write_PanelCvar_q("_progressbar_gfx_smooth");
 111                                         HUD_Write_PanelCvar_q("_text");
 112                                         break;
 113                                 case HUD_PANEL_NOTIFY:
 114                                         HUD_Write_PanelCvar_q("_flip");
 115                                         HUD_Write_PanelCvar_q("_fontsize");
 116                                         HUD_Write_PanelCvar_q("_print");
 117                                         HUD_Write_PanelCvar_q("_time");
 118                                         HUD_Write_PanelCvar_q("_fadetime");
 119                                         break;
 120                                 case HUD_PANEL_TIMER:
 121                                         HUD_Write_PanelCvar_q("_increment");
 122                                         break;
 123                                 case HUD_PANEL_RADAR:
 124                                         HUD_Write_PanelCvar_q("_foreground_alpha");
 125                                         HUD_Write_PanelCvar_q("_rotation");
 126                                         HUD_Write_PanelCvar_q("_zoommode");
 127                                         HUD_Write_PanelCvar_q("_scale");
 128                                         HUD_Write_PanelCvar_q("_maximized_scale");
 129                                         HUD_Write_PanelCvar_q("_maximized_size");
 130                                         break;
 131                                 case HUD_PANEL_SCORE:
 132                                         HUD_Write_PanelCvar_q("_rankings");
 133                                         break;
 134                                 case HUD_PANEL_VOTE:
 135                                         HUD_Write_PanelCvar_q("_alreadyvoted_alpha");
 136                                         break;
 137                                 case HUD_PANEL_MODICONS:
 138                                         HUD_Write_PanelCvar_q("_dom_layout");
 139                                         break;
 140                                 case HUD_PANEL_PRESSEDKEYS:
 141                                         HUD_Write_PanelCvar_q("_aspect");
 142                                         break;
 143                                 case HUD_PANEL_ENGINEINFO:
 144                                         HUD_Write_PanelCvar_q("_framecounter_time");
 145                                         HUD_Write_PanelCvar_q("_framecounter_decimals");
 146                                         break;
 147                                 case HUD_PANEL_INFOMESSAGES:
 148                                         HUD_Write_PanelCvar_q("_flip");
 149                                         break;
 150                                 case HUD_PANEL_PHYSICS:
 151                                         HUD_Write_PanelCvar_q("_speed_unit");
 152                                         HUD_Write_PanelCvar_q("_speed_unit_show");
 153                                         HUD_Write_PanelCvar_q("_speed_max");
 154                                         HUD_Write_PanelCvar_q("_speed_vertical");
 155                                         HUD_Write_PanelCvar_q("_topspeed");
 156                                         HUD_Write_PanelCvar_q("_topspeed_time");
 157                                         HUD_Write_PanelCvar_q("_acceleration_max");
 158                                         HUD_Write_PanelCvar_q("_acceleration_vertical");
 159                                         HUD_Write_PanelCvar_q("_flip");
 160                                         HUD_Write_PanelCvar_q("_baralign");
 161                                         HUD_Write_PanelCvar_q("_progressbar");
 162                                         HUD_Write_PanelCvar_q("_acceleration_mode");
 163                                         HUD_Write_PanelCvar_q("_text");
 164                                         break;
 165                                 case HUD_PANEL_CENTERPRINT:
 166                                         HUD_Write_PanelCvar_q("_align");
 167                                         HUD_Write_PanelCvar_q("_flip");
 168                                         HUD_Write_PanelCvar_q("_fontscale");
 169                                         HUD_Write_PanelCvar_q("_time");
 170                                         HUD_Write_PanelCvar_q("_fade_in");
 171                                         HUD_Write_PanelCvar_q("_fade_out");
 172                                         HUD_Write_PanelCvar_q("_fade_subsequent");
 173                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone");
 174                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone_minalpha");
 175                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo");
 176                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo_minalpha");
 177                                         HUD_Write_PanelCvar_q("_fade_subsequent_minfontsize");
 178                                         HUD_Write_PanelCvar_q("_fade_minfontsize");
 179                                         break;
 180                         }
 181                         HUD_Write("\n");
 182                 }
 183                 HUD_Write("menu_sync\n"); // force the menu to reread the cvars, so that the dialogs are updated
 184
 185                 print(sprintf(_("^2Successfully exported to %s! (Note: It's saved in data/data/)\n"), filename));
 186                 fclose(fh);
 187         }
 188         else
 189                 print(sprintf(_("^1Couldn't write to %s\n"), filename));
 190 }
 191
 192 // check if move will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 193 vector HUD_Panel_CheckMove(vector myPos, vector mySize)
 194 {
 195         float i;
 196         float myCenter_x, myCenter_y, targCenter_x, targCenter_y;
 197         vector myTarget;
 198         myTarget = myPos;
 199
 200         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 201                 if(i == highlightedPanel || !panel_enabled)
 202                         continue;
 203
 204                 HUD_Panel_UpdatePosSizeForId(i);
 205
 206                 panel_pos -= '1 1 0' * panel_bg_border;
 207                 panel_size += '2 2 0' * panel_bg_border;
 208
 209                 if(myPos_y + mySize_y < panel_pos_y)
 210                         continue;
 211                 if(myPos_y > panel_pos_y + panel_size_y)
 212                         continue;
 213
 214                 if(myPos_x + mySize_x < panel_pos_x)
 215                         continue;
 216                 if(myPos_x > panel_pos_x + panel_size_x)
 217                         continue;
 218
 219                 // OK, there IS a collision.
 220
 221                 myCenter_x = myPos_x + 0.5 * mySize_x;
 222                 myCenter_y = myPos_y + 0.5 * mySize_y;
 223
 224                 targCenter_x = panel_pos_x + 0.5 * panel_size_x;
 225                 targCenter_y = panel_pos_y + 0.5 * panel_size_y;
 226
 227                 if(myCenter_x < targCenter_x && myCenter_y < targCenter_y) // top left (of the target panel)
 228                 {
 229                         if(myPos_x + mySize_x - panel_pos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 230                                 myTarget_x = panel_pos_x - mySize_x;
 231                         else // push it upwards
 232                                 myTarget_y = panel_pos_y - mySize_y;
 233                 }
 234                 else if(myCenter_x > targCenter_x && myCenter_y < targCenter_y) // top right
 235                 {
 236                         if(panel_pos_x + panel_size_x - myPos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 237                                 myTarget_x = panel_pos_x + panel_size_x;
 238                         else // push it upwards
 239                                 myTarget_y = panel_pos_y - mySize_y;
 240                 }
 241                 else if(myCenter_x < targCenter_x && myCenter_y > targCenter_y) // bottom left
 242                 {
 243                         if(myPos_x + mySize_x - panel_pos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 244                                 myTarget_x = panel_pos_x - mySize_x;
 245                         else // push it downwards
 246                                 myTarget_y = panel_pos_y + panel_size_y;
 247                 }
 248                 else if(myCenter_x > targCenter_x && myCenter_y > targCenter_y) // bottom right
 249                 {
 250                         if(panel_pos_x + panel_size_x - myPos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 251                                 myTarget_x = panel_pos_x + panel_size_x;
 252                         else // push it downwards
 253                                 myTarget_y = panel_pos_y + panel_size_y;
 254                 }
 255                 //if(cvar("hud_configure_checkcollisions_debug"))
 256                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 257         }
 258
 259         return myTarget;
 260 }
 261
 262 void HUD_Panel_SetPos(vector pos)
 263 {
 264         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 265         vector mySize;
 266         mySize = panel_size;
 267
 268         //if(cvar("hud_configure_checkcollisions_debug"))
 269                 //drawfill(pos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 270
 271         if(autocvar_hud_configure_grid)
 272         {
 273                 pos_x = floor((pos_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 274                 pos_y = floor((pos_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 275         }
 276
 277         if(hud_configure_checkcollisions)
 278                 pos = HUD_Panel_CheckMove(pos, mySize);
 279
 280         pos_x = bound(0, pos_x, vid_conwidth - mySize_x);
 281         pos_y = bound(0, pos_y, vid_conheight - mySize_y);
 282
 283         string s;
 284         s = strcat(ftos(pos_x/vid_conwidth), " ", ftos(pos_y/vid_conheight));
 285
 286         HUD_Panel_GetName(highlightedPanel);
 287         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 288 }
 289
 290 // check if resize will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 291 vector HUD_Panel_CheckResize(vector mySize, vector resizeorigin) {
 292         float i;
 293
 294         vector targEndPos;
 295
 296         float dist_x, dist_y;
 297         float ratio;
 298         ratio = mySize_x/mySize_y;
 299
 300         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 301                 if(i == highlightedPanel || !panel_enabled)
 302                         continue;
 303
 304                 HUD_Panel_UpdatePosSizeForId(i);
 305
 306                 panel_pos -= '1 1 0' * panel_bg_border;
 307                 panel_size += '2 2 0' * panel_bg_border;
 308
 309                 targEndPos = panel_pos + panel_size;
 310
 311                 // resizeorigin is WITHIN target panel, just abort any collision testing against that particular panel to produce expected behaviour!
 312                 if(resizeorigin_x > panel_pos_x && resizeorigin_x < targEndPos_x && resizeorigin_y > panel_pos_y && resizeorigin_y < targEndPos_y)
 313                         continue;
 314
 315                 if (resizeCorner == 1)
 316                 {
 317                         // check if this panel is on our way
 318                         if (resizeorigin_x <= panel_pos_x)
 319                                 continue;
 320                         if (resizeorigin_y <= panel_pos_y)
 321                                 continue;
 322                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 323                                 continue;
 324                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 325                                 continue;
 326
 327                         // there is a collision:
 328                         // detect which side of the panel we are facing is actually limiting the resizing
 329                         // (which side the resize direction finds for first) and reduce the size up to there
 330                         //
 331                         // dist is the distance between resizeorigin and the "analogous" point of the panel
 332                         // in this case between resizeorigin (bottom-right point) and the bottom-right point of the panel
 333                         dist_x = resizeorigin_x - targEndPos_x;
 334                         dist_y = resizeorigin_y - targEndPos_y;
 335                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 336                                 mySize_x = min(mySize_x, dist_x);
 337                         else
 338                                 mySize_y = min(mySize_y, dist_y);
 339                 }
 340                 else if (resizeCorner == 2)
 341                 {
 342                         if (resizeorigin_x >= targEndPos_x)
 343                                 continue;
 344                         if (resizeorigin_y <= panel_pos_y)
 345                                 continue;
 346                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 347                                 continue;
 348                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 349                                 continue;
 350
 351                         dist_x = panel_pos_x - resizeorigin_x;
 352                         dist_y = resizeorigin_y - targEndPos_y;
 353                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 354                                 mySize_x = min(mySize_x, dist_x);
 355                         else
 356                                 mySize_y = min(mySize_y, dist_y);
 357                 }
 358                 else if (resizeCorner == 3)
 359                 {
 360                         if (resizeorigin_x <= panel_pos_x)
 361                                 continue;
 362                         if (resizeorigin_y >= targEndPos_y)
 363                                 continue;
 364                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 365                                 continue;
 366                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 367                                 continue;
 368
 369                         dist_x = resizeorigin_x - targEndPos_x;
 370                         dist_y = panel_pos_y - resizeorigin_y;
 371                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 372                                 mySize_x = min(mySize_x, dist_x);
 373                         else
 374                                 mySize_y = min(mySize_y, dist_y);
 375                 }
 376                 else if (resizeCorner == 4)
 377                 {
 378                         if (resizeorigin_x >= targEndPos_x)
 379                                 continue;
 380                         if (resizeorigin_y >= targEndPos_y)
 381                                 continue;
 382                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 383                                 continue;
 384                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 385                                 continue;
 386
 387                         dist_x = panel_pos_x - resizeorigin_x;
 388                         dist_y = panel_pos_y - resizeorigin_y;
 389                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 390                                 mySize_x = min(mySize_x, dist_x);
 391                         else
 392                                 mySize_y = min(mySize_y, dist_y);
 393                 }
 394                 //if(cvar("hud_configure_checkcollisions_debug"))
 395                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 396         }
 397
 398         return mySize;
 399 }
 400
 401 void HUD_Panel_SetPosSize(vector mySize)
 402 {
 403         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 404         vector resizeorigin;
 405         resizeorigin = panel_click_resizeorigin;
 406         local noref vector myPos; // fteqcc sucks
 407
 408         // minimum panel size cap
 409         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 410         mySize_y = max(0.025 * vid_conheight, mySize_y);
 411
 412         if(highlightedPanel == HUD_PANEL_CHAT) // some panels have their own restrictions, like the chat panel (which actually only moves the engine chat print around). Looks bad if it's too small.
 413         {
 414                 mySize_x = max(17 * autocvar_con_chatsize, mySize_x);
 415                 mySize_y = max(2 * autocvar_con_chatsize + 2 * panel_bg_padding, mySize_y);
 416         }
 417
 418         // collision testing|
 419         // -----------------+
 420
 421         // we need to know pos at this stage, but it might still change later if we hit a screen edge/other panel (?)
 422         if(resizeCorner == 1) {
 423                 myPos_x = resizeorigin_x - mySize_x;
 424                 myPos_y = resizeorigin_y - mySize_y;
 425         } else if(resizeCorner == 2) {
 426                 myPos_x = resizeorigin_x;
 427                 myPos_y = resizeorigin_y - mySize_y;
 428         } else if(resizeCorner == 3) {
 429                 myPos_x = resizeorigin_x - mySize_x;
 430                 myPos_y = resizeorigin_y;
 431         } else { // resizeCorner == 4
 432                 myPos_x = resizeorigin_x;
 433                 myPos_y = resizeorigin_y;
 434         }
 435
 436         // left/top screen edges
 437         if(myPos_x < 0)
 438                 mySize_x = mySize_x + myPos_x;
 439         if(myPos_y < 0)
 440                 mySize_y = mySize_y + myPos_y;
 441
 442         // bottom/right screen edges
 443         if(myPos_x + mySize_x > vid_conwidth)
 444                 mySize_x = vid_conwidth - myPos_x;
 445         if(myPos_y + mySize_y > vid_conheight)
 446                 mySize_y = vid_conheight - myPos_y;
 447
 448         //if(cvar("hud_configure_checkcollisions_debug"))
 449                 //drawfill(myPos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 450
 451         // before checkresize, otherwise panel can be snapped partially inside another panel or panel aspect ratio can be broken
 452         if(autocvar_hud_configure_grid)
 453         {
 454                 mySize_x = floor((mySize_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 455                 mySize_y = floor((mySize_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 456         }
 457
 458         if(hud_configure_checkcollisions)
 459                 mySize = HUD_Panel_CheckResize(mySize, resizeorigin);
 460
 461         // minimum panel size cap, do this once more so we NEVER EVER EVER have a panel smaller than this, JUST IN CASE above code still makes the panel eg negative (impossible to resize back without changing cvars manually then)
 462         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 463         mySize_y = max(0.025 * vid_conheight, mySize_y);
 464
 465         // do another pos check, as size might have changed by now
 466         if(resizeCorner == 1) {
 467                 myPos_x = resizeorigin_x - mySize_x;
 468                 myPos_y = resizeorigin_y - mySize_y;
 469         } else if(resizeCorner == 2) {
 470                 myPos_x = resizeorigin_x;
 471                 myPos_y = resizeorigin_y - mySize_y;
 472         } else if(resizeCorner == 3) {
 473                 myPos_x = resizeorigin_x - mySize_x;
 474                 myPos_y = resizeorigin_y;
 475         } else { // resizeCorner == 4
 476                 myPos_x = resizeorigin_x;
 477                 myPos_y = resizeorigin_y;
 478         }
 479
 480         //if(cvar("hud_configure_checkcollisions_debug"))
 481                 //drawfill(myPos, mySize, '0 1 0', .3, DRAWFLAG_NORMAL);
 482
 483         HUD_Panel_GetName(highlightedPanel);
 484         string s;
 485         s = strcat(ftos(mySize_x/vid_conwidth), " ", ftos(mySize_y/vid_conheight));
 486         cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 487
 488         s = strcat(ftos(myPos_x/vid_conwidth), " ", ftos(myPos_y/vid_conheight));
 489         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 490 }
 491
 492 float pressed_key_time;
 493 vector highlightedPanel_initial_pos, highlightedPanel_initial_size;
 494 void HUD_Panel_Arrow_Action(float nPrimary)
 495 {
 496         if (highlightedPanel == -1)
 497                 return;
 498
 499         hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
 500
 501         float step;
 502         if(autocvar_hud_configure_grid)
 503         {
 504                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 505                 {
 506                         if (hudShiftState & S_SHIFT)
 507                                 step = hud_configure_realGridSize_y;
 508                         else
 509                                 step = 2 * hud_configure_realGridSize_y;
 510                 }
 511                 else
 512                 {
 513                         if (hudShiftState & S_SHIFT)
 514                                 step = hud_configure_realGridSize_x;
 515                         else
 516                                 step = 2 * hud_configure_realGridSize_x;
 517                 }
 518         }
 519         else
 520         {
 521                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 522                         step = vid_conheight;
 523                 else
 524                         step = vid_conwidth;
 525                 if (hudShiftState & S_SHIFT)
 526                         step = (step / 256); // more precision
 527                 else
 528                         step = (step / 64) * (1 + 2 * (time - pressed_key_time));
 529         }
 530
 531         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 532
 533         highlightedPanel_initial_pos = panel_pos;
 534         highlightedPanel_initial_size = panel_size;
 535
 536         if (hudShiftState & S_ALT) // resize
 537         {
 538                 highlightedAction = 1;
 539                 if(nPrimary == K_UPARROW)
 540                         resizeCorner = 1;
 541                 else if(nPrimary == K_RIGHTARROW)
 542                         resizeCorner = 2;
 543                 else if(nPrimary == K_LEFTARROW)
 544                         resizeCorner = 3;
 545                 else // if(nPrimary == K_DOWNARROW)
 546                         resizeCorner = 4;
 547
 548                 // ctrl+arrow reduces the size, instead of increasing it
 549                 // Note that ctrl disables collisions check too, but it's fine
 550                 // since we don't collide with anything reducing the size
 551                 if (hudShiftState & S_CTRL) {
 552                         step = -step;
 553                         resizeCorner = 5 - resizeCorner;
 554                 }
 555
 556                 vector mySize;
 557                 mySize = panel_size;
 558                 panel_click_resizeorigin = panel_pos;
 559                 if(resizeCorner == 1) {
 560                         panel_click_resizeorigin += mySize;
 561                         mySize_y += step;
 562                 } else if(resizeCorner == 2) {
 563                         panel_click_resizeorigin_y += mySize_y;
 564                         mySize_x += step;
 565                 } else if(resizeCorner == 3) {
 566                         panel_click_resizeorigin_x += mySize_x;
 567                         mySize_x += step;
 568                 } else { // resizeCorner == 4
 569                         mySize_y += step;
 570                 }
 571                 HUD_Panel_SetPosSize(mySize);
 572         }
 573         else // move
 574         {
 575                 highlightedAction = 2;
 576                 vector pos;
 577                 pos = panel_pos;
 578                 if(nPrimary == K_UPARROW)
 579                         pos_y -= step;
 580                 else if(nPrimary == K_DOWNARROW)
 581                         pos_y += step;
 582                 else if(nPrimary == K_LEFTARROW)
 583                         pos_x -= step;
 584                 else // if(nPrimary == K_RIGHTARROW)
 585                         pos_x += step;
 586
 587                 HUD_Panel_SetPos(pos);
 588         }
 589
 590         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 591
 592         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
 593         {
 594                 // backup!
 595                 panel_pos_backup = highlightedPanel_initial_pos;
 596                 panel_size_backup = highlightedPanel_initial_size;
 597                 highlightedPanel_backup = highlightedPanel;
 598         }
 599 }
 600
 601 const float S_MOUSE1 = 1;
 602 const float S_MOUSE2 = 2;
 603 const float S_MOUSE3 = 4;
 604 float mouseClicked;
 605 float prevMouseClicked; // previous state
 606 float prevMouseClickedTime; // time during previous left mouse click, to check for doubleclicks
 607 vector prevMouseClickedPos; // pos during previous left mouse click, to check for doubleclicks
 608
 609 void HUD_Panel_EnableMenu();
 610 float tab_panels[HUD_PANEL_NUM];
 611 float tab_panel, tab_backward;
 612 vector tab_panel_pos;
 613 void HUD_Panel_FirstInDrawQ(float id);
 614 void reset_tab_panels()
 615 {
 616         int i;
 617         for(i = 0; i < HUD_PANEL_NUM; ++i)
 618                 tab_panels[i] = -1;
 619 }
 620 float HUD_Panel_InputEvent(float bInputType, float nPrimary, float nSecondary)
 621 {
 622         string s;
 623
 624         // we only care for keyboard events
 625         if(bInputType != 0 && bInputType != 1)
 626                 return false;
 627
 628         if(!autocvar__hud_configure)
 629                 return false;
 630
 631         // allow console bind to work
 632         string con_keys;
 633         float keys;
 634         con_keys = findkeysforcommand("toggleconsole", 0);
 635         keys = tokenize(con_keys); // findkeysforcommand returns data for this
 636
 637         float hit_con_bind, i;
 638         for (i = 0; i < keys; ++i)
 639         {
 640                 if(nPrimary == stof(argv(i)))
 641                         hit_con_bind = 1;
 642         }
 643
 644         if(bInputType == 0) {
 645                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 646                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 647                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 648         }
 649         else if(bInputType == 1) {
 650                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 651                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 652                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 653         }
 654
 655         if(nPrimary == K_CTRL)
 656         {
 657                 if (bInputType == 1) //ctrl has been released
 658                 {
 659                         if (tab_panel != -1)
 660                         {
 661                                 //switch to selected panel
 662                                 highlightedPanel = tab_panel;
 663                                 highlightedAction = 0;
 664                                 HUD_Panel_FirstInDrawQ(highlightedPanel);
 665                         }
 666                         tab_panel = -1;
 667                         reset_tab_panels();
 668                 }
 669         }
 670
 671         if(nPrimary == K_MOUSE1)
 672         {
 673                 if(bInputType == 0) // key pressed
 674                         mouseClicked |= S_MOUSE1;
 675                 else if(bInputType == 1) // key released
 676                         mouseClicked -= (mouseClicked & S_MOUSE1);
 677         }
 678         else if(nPrimary == K_MOUSE2)
 679         {
 680                 if(bInputType == 0) // key pressed
 681                         mouseClicked |= S_MOUSE2;
 682                 else if(bInputType == 1) // key released
 683                         mouseClicked -= (mouseClicked & S_MOUSE2);
 684         }
 685         else if(nPrimary == K_ESCAPE)
 686         {
 687                 if (bInputType == 1)
 688                         return true;
 689                 menu_enabled = 1;
 690                 menu_enabled_time = time;
 691                 localcmd("menu_showhudexit\n");
 692         }
 693         else if(nPrimary == K_BACKSPACE && hudShiftState & S_CTRL)
 694         {
 695                 if (bInputType == 1)
 696                         return true;
 697                 if (!menu_enabled)
 698                         cvar_set("_hud_configure", "0");
 699         }
 700         else if(nPrimary == K_TAB && hudShiftState & S_CTRL) // select and highlight another panel
 701         {
 702                 if (bInputType == 1 || mouseClicked)
 703                         return true;
 704
 705                 //FIXME: if a panel is highlighted, has the same pos_x and lays in the same level
 706                 //of other panels then next consecutive ctrl-tab will select the highlighted panel too
 707                 //(it should only after every other panel of the hud)
 708                 //It's a minor bug anyway, we can live with it
 709
 710                 float starting_panel;
 711                 float old_tab_panel = tab_panel;
 712                 if (tab_panel == -1) //first press of TAB
 713                 {
 714                         if (highlightedPanel != -1)
 715                                 HUD_Panel_UpdatePosSizeForId(highlightedPanel)
 716                         else
 717                                 panel_pos = '0 0 0';
 718                         starting_panel = highlightedPanel; //can be -1, it means no starting panel
 719                         tab_panel_pos = panel_pos; //to compute level
 720                 }
 721                 else
 722                 {
 723                         if ( ((!tab_backward) && (hudShiftState & S_SHIFT)) || (tab_backward && !(hudShiftState & S_SHIFT)) ) //tab direction changed?
 724                                 reset_tab_panels();
 725                         starting_panel = tab_panel;
 726                 }
 727                 tab_backward = (hudShiftState & S_SHIFT);
 728
 729                 float k, level, start_pos_x;
 730                 vector candidate_pos;
 731                 const float LEVELS_NUM = 4;
 732                 float level_height = vid_conheight / LEVELS_NUM;
 733 :find_tab_panel
 734                 level = floor(tab_panel_pos_y / level_height) * level_height; //starting level
 735                 candidate_pos_x = (!tab_backward) ? vid_conwidth : 0;
 736                 start_pos_x = tab_panel_pos_x;
 737                 tab_panel = -1;
 738                 k=0;
 739                 while(++k)
 740                 {
 741                         for(i = 0; i < HUD_PANEL_NUM; ++i)
 742                         {
 743                                 if (i == tab_panels[i] || i == starting_panel)
 744                                         continue;
 745                                 HUD_Panel_UpdatePosSizeForId(i)
 746                                 if (panel_pos_y >= level && (panel_pos_y - level) < level_height)
 747                                 if (  ( !tab_backward && panel_pos_x >= start_pos_x && (panel_pos_x < candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y <= candidate_pos_y)) )
 748                                         || ( tab_backward && panel_pos_x <= start_pos_x && (panel_pos_x > candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y >= candidate_pos_y)) )  )
 749                                 {
 750                                         tab_panel = i;
 751                                         tab_panel_pos = candidate_pos = panel_pos;
 752                                 }
 753                         }
 754                         if (tab_panel != -1)
 755                                 break;
 756                         if (k == LEVELS_NUM) //tab_panel not found
 757                         {
 758                                 reset_tab_panels();
 759                                 if (old_tab_panel == -2) //this prevents an infinite loop (should not happen normally)
 760                                 {
 761                                         tab_panel = -1;
 762                                         return true;
 763                                 }
 764                                 starting_panel = old_tab_panel;
 765                                 old_tab_panel = -2;
 766                                 goto find_tab_panel; //u must find tab_panel!
 767                         }
 768                         if (!tab_backward)
 769                         {
 770                                 level = mod(level + level_height, vid_conheight);
 771                                 start_pos_x = 0;
 772                                 candidate_pos_x = vid_conwidth;
 773                         }
 774                         else
 775                         {
 776                                 level = mod(level - level_height, vid_conheight);
 777                                 start_pos_x = vid_conwidth;
 778                                 candidate_pos_x = 0;
 779                         }
 780                 }
 781
 782                 tab_panels[tab_panel] = tab_panel;
 783         }
 784         else if(nPrimary == K_SPACE && hudShiftState & S_CTRL) // enable/disable highlighted panel or dock
 785         {
 786                 if (bInputType == 1 || mouseClicked)
 787                         return true;
 788
 789                 if (highlightedPanel != -1)
 790                 {
 791                         HUD_Panel_GetName(highlightedPanel);
 792                         cvar_set(strcat("hud_panel_", panel_name), ftos(!(panel_enabled)));
 793                 }
 794                 else
 795                         cvar_set(strcat("hud_dock"), (autocvar_hud_dock == "") ? "dock" : "");
 796         }
 797         else if(nPrimary == 'c' && hudShiftState & S_CTRL) // copy highlighted panel size
 798         {
 799                 if (bInputType == 1 || mouseClicked)
 800                         return true;
 801
 802                 if (highlightedPanel != -1)
 803                 {
 804                         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 805                         panel_size_copied = panel_size;
 806                         highlightedPanel_copied = highlightedPanel;
 807                 }
 808         }
 809         else if(nPrimary == 'v' && hudShiftState & S_CTRL) // past copied size on the highlighted panel
 810         {
 811                 if (bInputType == 1 || mouseClicked)
 812                         return true;
 813
 814                 if (highlightedPanel_copied == -1 || highlightedPanel == -1)
 815                         return true;
 816
 817                 HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 818
 819                 // reduce size if it'd go beyond screen boundaries
 820                 vector tmp_size = panel_size_copied;
 821                 if (panel_pos_x + panel_size_copied_x > vid_conwidth)
 822                         tmp_size_x = vid_conwidth - panel_pos_x;
 823                 if (panel_pos_y + panel_size_copied_y > vid_conheight)
 824                         tmp_size_y = vid_conheight - panel_pos_y;
 825
 826                 if (panel_size == tmp_size)
 827                         return true;
 828
 829                 // backup first!
 830                 panel_pos_backup = panel_pos;
 831                 panel_size_backup = panel_size;
 832                 highlightedPanel_backup = highlightedPanel;
 833
 834                 s = strcat(ftos(tmp_size_x/vid_conwidth), " ", ftos(tmp_size_y/vid_conheight));
 835                 HUD_Panel_GetName(highlightedPanel);
 836                 cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 837         }
 838         else if(nPrimary == 'z' && hudShiftState & S_CTRL) // undo last action
 839         {
 840                 if (bInputType == 1 || mouseClicked)
 841                         return true;
 842                 //restore previous values
 843                 if (highlightedPanel_backup != -1)
 844                 {
 845                         HUD_Panel_GetName(highlightedPanel_backup);
 846                         s = strcat(ftos(panel_pos_backup_x/vid_conwidth), " ", ftos(panel_pos_backup_y/vid_conheight));
 847                         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 848                         s = strcat(ftos(panel_size_backup_x/vid_conwidth), " ", ftos(panel_size_backup_y/vid_conheight));
 849                         cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 850                         highlightedPanel_backup = -1;
 851                 }
 852         }
 853         else if(nPrimary == K_UPARROW || nPrimary == K_DOWNARROW || nPrimary == K_LEFTARROW || nPrimary == K_RIGHTARROW)
 854         {
 855                 if (bInputType == 1)
 856                 {
 857                         pressed_key_time = 0;
 858                         return true;
 859                 }
 860                 else if (pressed_key_time == 0)
 861                         pressed_key_time = time;
 862
 863                 if (!mouseClicked)
 864                         HUD_Panel_Arrow_Action(nPrimary); //move or resize panel
 865         }
 866         else if(nPrimary == K_ENTER || nPrimary == K_SPACE || nPrimary == K_KP_ENTER)
 867         {
 868                 if (bInputType == 1)
 869                         return true;
 870                 if (highlightedPanel != -1)
 871                         HUD_Panel_EnableMenu();
 872         }
 873         else if(hit_con_bind)
 874                 return false;
 875
 876         return true;
 877 }
 878
 879 float HUD_Panel_Check_Mouse_Pos(float allow_move)
 880 {
 881         float i, j, border;
 882
 883         while(j < HUD_PANEL_NUM)
 884         {
 885                 i = panel_order[j];
 886                 j += 1;
 887
 888                 HUD_Panel_UpdatePosSizeForId(i);
 889
 890                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 891
 892                 // move
 893                 if(allow_move && mousepos_x >= panel_pos_x && mousepos_y >= panel_pos_y && mousepos_x <= panel_pos_x + panel_size_x && mousepos_y <= panel_pos_y + panel_size_y)
 894                 {
 895                         return 1;
 896                 }
 897                 // resize from topleft border
 898                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 899                 {
 900                         return 2;
 901                 }
 902                 // resize from topright border
 903                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 904                 {
 905                         return 3;
 906                 }
 907                 // resize from bottomleft border
 908                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
 909                 {
 910                         return 3;
 911                 }
 912                 // resize from bottomright border
 913                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
 914                 {
 915                         return 2;
 916                 }
 917         }
 918         return 0;
 919 }
 920
 921 // move a panel to the beginning of the panel order array (which means it gets drawn last, on top of everything else)
 922 void HUD_Panel_FirstInDrawQ(float id)
 923 {
 924         float i;
 925         var float place = -1;
 926         // find out where in the array our current id is, save into place
 927         for(i = 0; i < HUD_PANEL_NUM; ++i)
 928         {
 929                 if(panel_order[i] == id)
 930                 {
 931                         place = i;
 932                         break;
 933                 }
 934         }
 935         // place last if we didn't find a place for it yet (probably new panel, or screwed up cvar)
 936         if(place == -1)
 937                 place = HUD_PANEL_NUM - 1;
 938
 939         // move all ids up by one step in the array until "place"
 940         for(i = place; i > 0; --i)
 941         {
 942                 panel_order[i] = panel_order[i-1];
 943         }
 944         // now save the new top id
 945         panel_order[0] = id;
 946
 947         // let's save them into the cvar by some strcat trickery
 948         string s;
 949         for(i = 0; i < HUD_PANEL_NUM; ++i)
 950         {
 951                 s = strcat(s, ftos(panel_order[i]), " ");
 952         }
 953         cvar_set("_hud_panelorder", s);
 954         if(hud_panelorder_prev)
 955                 strunzone(hud_panelorder_prev);
 956         hud_panelorder_prev = strzone(autocvar__hud_panelorder); // prevent HUD_Main from doing useless update, we already updated here
 957 }
 958
 959 void HUD_Panel_Highlight(float allow_move)
 960 {
 961         float i, j, border;
 962
 963         while(j < HUD_PANEL_NUM)
 964         {
 965                 i = panel_order[j];
 966                 j += 1;
 967
 968                 HUD_Panel_UpdatePosSizeForId(i);
 969
 970                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 971
 972                 // move
 973                 if(allow_move && mousepos_x >= panel_pos_x && mousepos_y >= panel_pos_y && mousepos_x <= panel_pos_x + panel_size_x && mousepos_y <= panel_pos_y + panel_size_y)
 974                 {
 975                         highlightedPanel = i;
 976                         HUD_Panel_FirstInDrawQ(i);
 977                         highlightedAction = 1;
 978                         panel_click_distance = mousepos - panel_pos;
 979                         return;
 980                 }
 981                 // resize from topleft border
 982                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 983                 {
 984                         highlightedPanel = i;
 985                         HUD_Panel_FirstInDrawQ(i);
 986                         highlightedAction = 2;
 987                         resizeCorner = 1;
 988                         panel_click_distance = mousepos - panel_pos;
 989                         panel_click_resizeorigin = panel_pos + panel_size;
 990                         return;
 991                 }
 992                 // resize from topright border
 993                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 994                 {
 995                         highlightedPanel = i;
 996                         HUD_Panel_FirstInDrawQ(i);
 997                         highlightedAction = 2;
 998                         resizeCorner = 2;
 999                         panel_click_distance_x = panel_size_x - mousepos_x + panel_pos_x;
1000                         panel_click_distance_y = mousepos_y - panel_pos_y;
1001                         panel_click_resizeorigin = panel_pos + eY * panel_size_y;
1002                         return;
1003                 }
1004                 // resize from bottomleft border
1005                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
1006                 {
1007                         highlightedPanel = i;
1008                         HUD_Panel_FirstInDrawQ(i);
1009                         highlightedAction = 2;
1010                         resizeCorner = 3;
1011                         panel_click_distance_x = mousepos_x - panel_pos_x;
1012                         panel_click_distance_y = panel_size_y - mousepos_y + panel_pos_y;
1013                         panel_click_resizeorigin = panel_pos + eX * panel_size_x;
1014                         return;
1015                 }
1016                 // resize from bottomright border
1017                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
1018                 {
1019                         highlightedPanel = i;
1020                         HUD_Panel_FirstInDrawQ(i);
1021                         highlightedAction = 2;
1022                         resizeCorner = 4;
1023                         panel_click_distance = panel_size - mousepos + panel_pos;
1024                         panel_click_resizeorigin = panel_pos;
1025                         return;
1026                 }
1027         }
1028         highlightedPanel = -1;
1029         highlightedAction = 0;
1030 }
1031
1032 void HUD_Panel_EnableMenu()
1033 {
1034         menu_enabled = 2;
1035         menu_enabled_time = time;
1036         HUD_Panel_GetName(highlightedPanel);
1037         localcmd("menu_showhudoptions ", panel_name, "\n");
1038 }
1039 float mouse_over_panel;
1040 void HUD_Panel_Mouse()
1041 {
1042         // TODO: needs better check... is there any float that contains the current state of the menu? _menu_alpha isn't apparently updated the frame the menu gets enabled
1043         if (autocvar__menu_alpha == 0 && time - menu_enabled_time > 0.5)
1044                 menu_enabled = 0;
1045
1046         /*
1047         print("menu_enabled: ", ftos(menu_enabled), "\n");
1048         print("Highlighted: ", ftos(highlightedPanel), "\n");
1049         print("Menu alpha: ", ftos(autocvar__menu_alpha), "\n");
1050         */
1051
1052         // instantly hide the editor cursor if we open the HUDExit dialog
1053         // as hud_fade_alpha doesn't decrease to 0 in this case
1054         // TODO: find a way to fade the cursor out even in this case
1055         if(menu_enabled == 1 || (menu_enabled == 2 && !hud_fade_alpha))
1056                 return;
1057
1058         mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
1059
1060         mousepos_x = bound(0, mousepos_x, vid_conwidth);
1061         mousepos_y = bound(0, mousepos_y, vid_conheight);
1062
1063         if(mouseClicked)
1064         {
1065                 if(prevMouseClicked == 0)
1066                 {
1067                         if (tab_panel != -1)
1068                         {
1069                                 //stop ctrl-tab selection
1070                                 tab_panel = -1;
1071                                 reset_tab_panels();
1072                         }
1073                         HUD_Panel_Highlight(mouseClicked & S_MOUSE1); // sets highlightedPanel, highlightedAction, panel_click_distance, panel_click_resizeorigin
1074                                                                         // and calls HUD_Panel_UpdatePosSizeForId() for the highlighted panel
1075                         if (highlightedPanel != -1)
1076                         {
1077                                 highlightedPanel_initial_pos = panel_pos;
1078                                 highlightedPanel_initial_size = panel_size;
1079                         }
1080                         // doubleclick check
1081                         if ((mouseClicked & S_MOUSE1) && time - prevMouseClickedTime < 0.4 && highlightedPanel != -1 && prevMouseClickedPos == mousepos)
1082                         {
1083                                 mouseClicked = 0; // to prevent spam, I guess.
1084                                 HUD_Panel_EnableMenu();
1085                         }
1086                         else
1087                         {
1088                                 if (mouseClicked & S_MOUSE1)
1089                                 {
1090                                         prevMouseClickedTime = time;
1091                                         prevMouseClickedPos = mousepos;
1092                                 }
1093                                 mouse_over_panel = HUD_Panel_Check_Mouse_Pos(mouseClicked & S_MOUSE1);
1094                         }
1095                 }
1096                 else
1097                         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
1098
1099                 if (highlightedPanel != -1)
1100                 {
1101                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1102                         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
1103                         {
1104                                 hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
1105                                 // backup!
1106                                 panel_pos_backup = highlightedPanel_initial_pos;
1107                                 panel_size_backup = highlightedPanel_initial_size;
1108                                 highlightedPanel_backup = highlightedPanel;
1109                         }
1110                         else
1111                                 // in case the clicked panel is inside another panel and we aren't
1112                                 // moving it, avoid the immediate "fix" of its position/size
1113                                 // (often unwanted and hateful) by disabling collisions check
1114                                 hud_configure_checkcollisions = false;
1115                 }
1116
1117                 if(highlightedAction == 1)
1118                         HUD_Panel_SetPos(mousepos - panel_click_distance);
1119                 else if(highlightedAction == 2)
1120                 {
1121                         vector mySize;
1122                         if(resizeCorner == 1) {
1123                                 mySize_x = panel_click_resizeorigin_x - (mousepos_x - panel_click_distance_x);
1124                                 mySize_y = panel_click_resizeorigin_y - (mousepos_y - panel_click_distance_y);
1125                         } else if(resizeCorner == 2) {
1126                                 mySize_x = mousepos_x + panel_click_distance_x - panel_click_resizeorigin_x;
1127                                 mySize_y = panel_click_distance_y + panel_click_resizeorigin_y - mousepos_y;
1128                         } else if(resizeCorner == 3) {
1129                                 mySize_x = panel_click_resizeorigin_x + panel_click_distance_x - mousepos_x;
1130                                 mySize_y = mousepos_y + panel_click_distance_y - panel_click_resizeorigin_y;
1131                         } else { // resizeCorner == 4
1132                                 mySize_x = mousepos_x - (panel_click_resizeorigin_x - panel_click_distance_x);
1133                                 mySize_y = mousepos_y - (panel_click_resizeorigin_y - panel_click_distance_y);
1134                         }
1135                         HUD_Panel_SetPosSize(mySize);
1136                 }
1137         }
1138         else
1139         {
1140                 if(menu_enabled == 2)
1141                         mouse_over_panel = 0;
1142                 else
1143                         mouse_over_panel = HUD_Panel_Check_Mouse_Pos(TRUE);
1144                 if (mouse_over_panel && tab_panel == -1)
1145                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1146         }
1147         // draw cursor after performing move/resize to have the panel pos/size updated before mouse_over_panel
1148         const vector cursorsize = '32 32 0';
1149
1150         if(!mouse_over_panel)
1151                 drawpic(mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), cursorsize, '1 1 1', hud_fade_alpha, DRAWFLAG_NORMAL);
1152         else if(mouse_over_panel == 1)
1153                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_move.tga"), cursorsize, '1 1 1', hud_fade_alpha, DRAWFLAG_NORMAL);
1154         else if(mouse_over_panel == 2)
1155                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize.tga"), cursorsize, '1 1 1', hud_fade_alpha, DRAWFLAG_NORMAL);
1156         else
1157                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize2.tga"), cursorsize, '1 1 1', hud_fade_alpha, DRAWFLAG_NORMAL);
1158
1159         prevMouseClicked = mouseClicked;
1160 }
1161
1162 const float hlBorderSize = 4;
1163 const string hlBorder = "gfx/hud/default/border_highlighted";
1164 const string hlBorder2 = "gfx/hud/default/border_highlighted2";
1165 void HUD_Panel_HlBorder(float myBorder, vector color, float alpha)
1166 {
1167         drawfill(panel_pos - '1 1 0' * myBorder, panel_size + '2 2 0' * myBorder, '0 0.5 1', .5 * alpha, DRAWFLAG_NORMAL);
1168         drawpic_tiled(panel_pos - '1 1 0' * myBorder, hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, alpha, DRAWFLAG_NORMAL);
1169         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * (panel_size_y + 2 * myBorder - hlBorderSize), hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, alpha, DRAWFLAG_NORMAL);
1170         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize, hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, alpha, DRAWFLAG_NORMAL);
1171         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize + eX * (panel_size_x + 2 * myBorder - hlBorderSize), hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, alpha, DRAWFLAG_NORMAL);
1172 }