0cedf8fd7ce5fdba8d5a1dcf59f1b8829f10a7f3
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / main.qc
1 #include "main.qh"
2 #include "_all.qh"
3
4 #include "casings.qh"
5 #include "csqcmodel_hooks.qh"
6 #include "damage.qh"
7 #include "effects.qh"
8 #include "gibs.qh"
9 #include "hook.qh"
10 #include "hud.qh"
11 #include "hud_config.qh"
12 #include "laser.qh"
13 #include "mapvoting.qh"
14 #include "modeleffects.qh"
15 #include "particles.qh"
16 #include "prandom.qh"
17 #include "scoreboard.qh"
18 #include "shownames.qh"
19 #include "sortlist.qh"
20 #include "target_music.qh"
21 #include "tturrets.qh"
22 #include "tuba.qh"
23 #include "t_items.qh"
24 #include "wall.qh"
25 #include "waypointsprites.qh"
26
27 #include "vehicles/bumblebee.qh"
28 #include "vehicles/vehicles.qh"
29
30 #include "weapons/projectile.qh"
31
32 #include "../common/buffs.qh"
33 #include "../common/deathtypes.qh"
34 #include "../common/mapinfo.qh"
35 #include "../common/monsters/monsters.qh"
36 #include "../common/nades.qh"
37 #include "../common/net_notice.qh"
38 #include "../common/notifications.qh"
39 #include "../common/stats.qh"
40 #include "../common/teams.qh"
41
42 #include "../common/items/all.qh"
43
44 #include "../common/weapons/weapons.qh"
45
46 #include "../csqcmodellib/cl_model.qh"
47 #include "../csqcmodellib/interpolate.qh"
48
49 #include "../warpzonelib/client.qh"
50
51 // --------------------------------------------------------------------------
52 // BEGIN REQUIRED CSQC FUNCTIONS
53 //include "main.qh"
54
55 entity clearentity_ent;
56 void clearentity(entity e)
57 {
58         if (!clearentity_ent)
59         {
60                 clearentity_ent = spawn();
61                 clearentity_ent.classname = "clearentity";
62         }
63         int n = e.entnum;
64         copyentity(clearentity_ent, e);
65         e.entnum = n;
66 }
67
68 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
69 void menu_show_error()
70 {
71         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
72 }
73
74 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
75 // Useful for precaching things
76
77 void menu_sub_null()
78 {
79 }
80
81 string forcefog;
82 void WaypointSprite_Load();
83 void ConsoleCommand_macro_init();
84 void CSQC_Init(void)
85 {
86         prvm_language = cvar_string("prvm_language");
87
88 #ifdef WATERMARK
89         dprintf("^4CSQC Build information: ^1%s\n", WATERMARK);
90 #endif
91
92         int i;
93
94         binddb = db_create();
95         tempdb = db_create();
96         ClientProgsDB = db_load("client.db");
97         compressShortVector_init();
98
99         draw_endBoldFont();
100         menu_visible = false;
101         menu_show = menu_show_error;
102         menu_action = func_null;
103
104         for(i = 0; i < 255; ++i)
105                 if(getplayerkeyvalue(i, "viewentity") == "")
106                         break;
107         maxclients = i;
108
109         //registercommand("hud_configure");
110         //registercommand("hud_save");
111         //registercommand("menu_action");
112
113         ConsoleCommand_macro_init();
114
115         registercvar("hud_usecsqc", "1");
116         registercvar("scoreboard_columns", "default");
117
118         registercvar("cl_nade_type", "3");
119         registercvar("cl_pokenade_type", "zombie");
120
121         gametype = 0;
122
123         // hud_fields uses strunzone on the titles!
124         for(i = 0; i < MAX_HUD_FIELDS; ++i)
125                 hud_title[i] = strzone("(null)");
126
127         Cmd_HUD_SetFields(0);
128
129         postinit = false;
130
131         calledhooks = 0;
132
133         teams = Sort_Spawn();
134         players = Sort_Spawn();
135
136         GetTeam(NUM_SPECTATOR, true); // add specs first
137
138         // needs to be done so early because of the constants they create
139         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
140         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
141         CALL_ACCUMULATED_FUNCTION(RegisterItems);
142         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
143         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
144         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
145         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
146         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
147
148         WaypointSprite_Load();
149
150         // precaches
151         precache_model("null");
152         precache_sound("misc/hit.wav");
153         precache_sound("misc/typehit.wav");
154
155         Projectile_Precache();
156         Hook_Precache();
157         GibSplash_Precache();
158         Casings_Precache();
159         Vehicles_Precache();
160         turrets_precache();
161         Tuba_Precache();
162         CSQCPlayer_Precache();
163
164         if(autocvar_cl_reticle)
165         {
166                 precache_pic("gfx/reticle_normal");
167                 // weapon reticles are precached in weapon files
168         }
169
170         get_mi_min_max_texcoords(1); // try the CLEVER way first
171         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
172         shortmapname = mi_shortname;
173
174         if(precache_pic(minimapname) == "")
175         {
176                 // but maybe we have a non-clever minimap
177                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
178                 if(precache_pic(minimapname) == "")
179                         minimapname = ""; // FAIL
180                 else
181                         get_mi_min_max_texcoords(0); // load new texcoords
182         }
183
184         mi_center = (mi_min + mi_max) * 0.5;
185         mi_scale = mi_max - mi_min;
186         minimapname = strzone(minimapname);
187
188         WarpZone_Init();
189
190         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
191         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
192 }
193
194 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
195 void Shutdown(void)
196 {
197         WarpZone_Shutdown();
198
199         remove(teams);
200         remove(players);
201         db_close(binddb);
202         db_close(tempdb);
203         if(autocvar_cl_db_saveasdump)
204                 db_dump(ClientProgsDB, "client.db");
205         else
206                 db_save(ClientProgsDB, "client.db");
207         db_close(ClientProgsDB);
208
209         if(camera_active)
210                 cvar_set("chase_active",ftos(chase_active_backup));
211
212         // unset the event chasecam's chase_active
213         if(autocvar_chase_active < 0)
214                 cvar_set("chase_active", "0");
215
216         if (!isdemo())
217         {
218                 if (!(calledhooks & HOOK_START))
219                         localcmd("\n_cl_hook_gamestart nop\n");
220                 if (!(calledhooks & HOOK_END))
221                         localcmd("\ncl_hook_gameend\n");
222         }
223 }
224
225 .float has_team;
226 float SetTeam(entity o, int Team)
227 {
228         entity tm;
229         if(teamplay)
230         {
231                 switch(Team)
232                 {
233                         case -1:
234                         case NUM_TEAM_1:
235                         case NUM_TEAM_2:
236                         case NUM_TEAM_3:
237                         case NUM_TEAM_4:
238                                 break;
239                         default:
240                                 if(GetTeam(Team, false) == world)
241                                 {
242                                         dprintf("trying to switch to unsupported team %d\n", Team);
243                                         Team = NUM_SPECTATOR;
244                                 }
245                                 break;
246                 }
247         }
248         else
249         {
250                 switch(Team)
251                 {
252                         case -1:
253                         case 0:
254                                 break;
255                         default:
256                                 if(GetTeam(Team, false) == world)
257                                 {
258                                         dprintf("trying to switch to unsupported team %d\n", Team);
259                                         Team = NUM_SPECTATOR;
260                                 }
261                                 break;
262                 }
263         }
264         if(Team == -1) // leave
265         {
266                 if(o.has_team)
267                 {
268                         tm = GetTeam(o.team, false);
269                         tm.team_size -= 1;
270                         o.has_team = 0;
271                         return true;
272                 }
273         }
274         else
275         {
276                 if (!o.has_team)
277                 {
278                         o.team = Team;
279                         tm = GetTeam(Team, true);
280                         tm.team_size += 1;
281                         o.has_team = 1;
282                         return true;
283                 }
284                 else if(Team != o.team)
285                 {
286                         tm = GetTeam(o.team, false);
287                         tm.team_size -= 1;
288                         o.team = Team;
289                         tm = GetTeam(Team, true);
290                         tm.team_size += 1;
291                         return true;
292                 }
293         }
294         return false;
295 }
296
297 void Playerchecker_Think()
298 {
299     int i;
300         entity e;
301         for(i = 0; i < maxclients; ++i)
302         {
303                 e = playerslots[i];
304                 if(GetPlayerName(i) == "")
305                 {
306                         if(e.sort_prev)
307                         {
308                                 // player disconnected
309                                 SetTeam(e, -1);
310                                 RemovePlayer(e);
311                                 e.sort_prev = world;
312                                 //e.gotscores = 0;
313                         }
314                 }
315                 else
316                 {
317                         if (!e.sort_prev)
318                         {
319                                 // player connected
320                                 if (!e)
321                                         playerslots[i] = e = spawn();
322                                 e.sv_entnum = i;
323                                 e.ping = 0;
324                                 e.ping_packetloss = 0;
325                                 e.ping_movementloss = 0;
326                                 //e.gotscores = 0; // we might already have the scores...
327                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
328                                 RegisterPlayer(e);
329                                 HUD_UpdatePlayerPos(e);
330                         }
331                 }
332         }
333         self.nextthink = time + 0.2;
334 }
335
336 void Porto_Init();
337 void TrueAim_Init();
338 void PostInit(void)
339 {
340         entity playerchecker;
341         playerchecker = spawn();
342         playerchecker.think = Playerchecker_Think;
343         playerchecker.nextthink = time + 0.2;
344
345         Porto_Init();
346         TrueAim_Init();
347
348         postinit = true;
349 }
350
351 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
352 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
353 // All keys are in ascii.
354 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
355 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
356 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
357 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
358 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
359 {
360         float bSkipKey;
361         bSkipKey = false;
362
363         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
364                 return true;
365
366         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
367                 return true;
368
369         if(menu_visible && menu_action)
370                 if(menu_action(bInputType, nPrimary, nSecondary))
371                         return true;
372
373         return bSkipKey;
374 }
375
376 // END REQUIRED CSQC FUNCTIONS
377 // --------------------------------------------------------------------------
378
379 // --------------------------------------------------------------------------
380 // BEGIN OPTIONAL CSQC FUNCTIONS
381 void Ent_RemoveEntCS()
382 {
383         entcs_receiver[self.sv_entnum] = world;
384 }
385 void Ent_ReadEntCS()
386 {
387     int sf;
388         InterpolateOrigin_Undo();
389
390         self.classname = "entcs_receiver";
391         sf = ReadByte();
392
393         if(sf & 1)
394                 self.sv_entnum = ReadByte();
395         if(sf & 2)
396         {
397                 self.origin_x = ReadShort();
398                 self.origin_y = ReadShort();
399                 self.origin_z = ReadShort();
400                 setorigin(self, self.origin);
401         }
402         if(sf & 4)
403         {
404                 self.angles_y = ReadByte() * 360.0 / 256;
405                 self.angles_x = self.angles_z = 0;
406         }
407         if(sf & 8)
408                 self.healthvalue = ReadByte() * 10;
409         if(sf & 16)
410                 self.armorvalue = ReadByte() * 10;
411
412         entcs_receiver[self.sv_entnum] = self;
413         self.entremove = Ent_RemoveEntCS;
414         self.iflags |= IFLAG_ORIGIN;
415
416         InterpolateOrigin_Note();
417 }
418
419 void Ent_Remove();
420
421 void Ent_RemovePlayerScore()
422 {
423         if(self.owner) {
424                 SetTeam(self.owner, -1);
425                 self.owner.gotscores = 0;
426                 for(int i = 0; i < MAX_SCORE; ++i) {
427                         self.owner.(scores[i]) = 0; // clear all scores
428                 }
429         }
430 }
431
432 void Ent_ReadPlayerScore()
433 {
434         int i, n;
435         bool isNew;
436         entity o;
437
438         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
439         // (no I've never heard of M-x replace-string, sed, or anything like that)
440         isNew = !self.owner; // workaround for DP bug
441         n = ReadByte()-1;
442
443 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
444         if(!isNew && n != self.sv_entnum)
445         {
446                 //print("A CSQC entity changed its owner!\n");
447                 printf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
448                 isNew = true;
449                 Ent_Remove();
450                 self.enttype = ENT_CLIENT_SCORES;
451         }
452 #endif
453
454         self.sv_entnum = n;
455
456         if (!(playerslots[self.sv_entnum]))
457                 playerslots[self.sv_entnum] = spawn();
458         o = self.owner = playerslots[self.sv_entnum];
459         o.sv_entnum = self.sv_entnum;
460         o.gotscores = 1;
461
462         //if (!o.sort_prev)
463         //      RegisterPlayer(o);
464         //playerchecker will do this for us later, if it has not already done so
465
466     int sf, lf;
467 #if MAX_SCORE <= 8
468         sf = ReadByte();
469         lf = ReadByte();
470 #else
471         sf = ReadShort();
472         lf = ReadShort();
473 #endif
474     int p;
475         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
476                 if(sf & p)
477                 {
478                         if(lf & p)
479                                 o.(scores[i]) = ReadInt24_t();
480                         else
481                                 o.(scores[i]) = ReadChar();
482                 }
483
484         if(o.sort_prev)
485                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
486
487         self.entremove = Ent_RemovePlayerScore;
488 }
489
490 void Ent_ReadTeamScore()
491 {
492         int i;
493         entity o;
494
495         self.team = ReadByte();
496         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
497
498     int sf, lf;
499 #if MAX_TEAMSCORE <= 8
500         sf = ReadByte();
501         lf = ReadByte();
502 #else
503         sf = ReadShort();
504         lf = ReadShort();
505 #endif
506         int p;
507         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
508                 if(sf & p)
509                 {
510                         if(lf & p)
511                                 o.(teamscores[i]) = ReadInt24_t();
512                         else
513                                 o.(teamscores[i]) = ReadChar();
514                 }
515
516         HUD_UpdateTeamPos(o);
517 }
518
519 void Ent_ClientData()
520 {
521         float newspectatee_status;
522
523     int f = ReadByte();
524
525         scoreboard_showscores_force = (f & 1);
526
527         if(f & 2)
528         {
529                 newspectatee_status = ReadByte();
530                 if(newspectatee_status == player_localnum + 1)
531                         newspectatee_status = -1; // observing
532         }
533         else
534                 newspectatee_status = 0;
535
536         spectatorbutton_zoom = (f & 4);
537
538         if(f & 8)
539         {
540                 angles_held_status = 1;
541                 angles_held.x = ReadAngle();
542                 angles_held.y = ReadAngle();
543                 angles_held.z = 0;
544         }
545         else
546                 angles_held_status = 0;
547
548         if(newspectatee_status != spectatee_status)
549         {
550                 // clear race stuff
551                 race_laptime = 0;
552                 race_checkpointtime = 0;
553         }
554         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
555         {
556                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
557                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
558                 )
559                         prev_p_health = -1;
560                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
561                         prev_health = -1;
562         }
563         spectatee_status = newspectatee_status;
564
565         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
566 }
567
568 void Ent_Nagger()
569 {
570     int i, j, b, f;
571
572     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
573
574         if(!(nags & 4))
575         {
576                 if(vote_called_vote)
577                         strunzone(vote_called_vote);
578                 vote_called_vote = string_null;
579                 vote_active = 0;
580         }
581         else
582         {
583                 vote_active = 1;
584         }
585
586         if(nags & 64)
587         {
588                 vote_yescount = ReadByte();
589                 vote_nocount = ReadByte();
590                 vote_needed = ReadByte();
591                 vote_highlighted = ReadChar();
592         }
593
594         if(nags & 128)
595         {
596                 if(vote_called_vote)
597                         strunzone(vote_called_vote);
598                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
599         }
600
601         if(nags & 1)
602         {
603                 for(j = 0; j < maxclients; ++j)
604                         if(playerslots[j])
605                                 playerslots[j].ready = 1;
606                 for(i = 1; i <= maxclients; i += 8)
607                 {
608                         f = ReadByte();
609                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
610                                 if (!(f & b))
611                                         if(playerslots[j])
612                                                 playerslots[j].ready = 0;
613                 }
614         }
615
616         ready_waiting = (nags & 1);
617         ready_waiting_for_me = (nags & 2);
618         vote_waiting = (nags & 4);
619         vote_waiting_for_me = (nags & 8);
620         warmup_stage = (nags & 16);
621 }
622
623 void Ent_EliminatedPlayers()
624 {
625     int i, j, b, f;
626
627     int sf = ReadByte();
628         if(sf & 1)
629         {
630                 for(j = 0; j < maxclients; ++j)
631                         if(playerslots[j])
632                                 playerslots[j].eliminated = 1;
633                 for(i = 1; i <= maxclients; i += 8)
634                 {
635                         f = ReadByte();
636                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
637                                 if (!(f & b))
638                                         if(playerslots[j])
639                                                 playerslots[j].eliminated = 0;
640                 }
641         }
642 }
643
644 void Ent_RandomSeed()
645 {
646         float s;
647         prandom_debug();
648         s = ReadShort();
649         psrandom(s);
650 }
651
652 void Ent_ReadAccuracy(void)
653 {
654     int f, w;
655     int sf = ReadInt24_t();
656         if(sf == 0)
657         {
658                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
659                         weapon_accuracy[w] = -1;
660                 return;
661         }
662
663         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
664         {
665                 if(sf & f)
666                 {
667             int b = ReadByte();
668                         if(b == 0)
669                                 weapon_accuracy[w] = -1;
670                         else if(b == 255)
671                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
672                         else
673                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
674                 }
675                 if(f == 0x800000)
676                         f = 1;
677                 else
678                         f *= 2;
679         }
680 }
681
682 void Spawn_Draw(void)
683 {
684         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
685 }
686
687 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
688 {
689         float teamnum = (ReadByte() - 1);
690         vector spn_origin;
691         spn_origin.x = ReadShort();
692         spn_origin.y = ReadShort();
693         spn_origin.z = ReadShort();
694
695         if(is_new)
696         {
697                 self.origin = spn_origin;
698                 setsize(self, PL_MIN, PL_MAX);
699                 droptofloor();
700
701                 /*if(autocvar_cl_spawn_point_model) // needs a model first
702                 {
703                         self.mdl = "models/spawnpoint.md3";
704                         self.colormod = Team_ColorRGB(teamnum);
705                         precache_model(self.mdl);
706                         setmodel(self, self.mdl);
707                         self.drawmask = MASK_NORMAL;
708                         //self.movetype = MOVETYPE_NOCLIP;
709                         //self.draw = Spawn_Draw;
710                 }*/
711                 if(autocvar_cl_spawn_point_particles)
712                 {
713                         if((serverflags & SERVERFLAG_TEAMPLAY))
714                         {
715                                 switch(teamnum)
716                                 {
717                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
718                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
719                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
720                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
721                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
722                                 }
723                         }
724                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
725
726                         self.draw = Spawn_Draw;
727                 }
728         }
729
730         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
731 }
732
733 void Ent_ReadSpawnEvent(float is_new)
734 {
735         // If entnum is 0, ONLY do the local spawn actions
736         // this way the server can disable the sending of
737         // spawn origin or such to clients if wanted.
738         float entnum = ReadByte();
739
740         if(entnum)
741         {
742                 self.origin_x = ReadShort();
743                 self.origin_y = ReadShort();
744                 self.origin_z = ReadShort();
745
746                 if(is_new)
747                 {
748                         float teamnum = GetPlayerColor(entnum - 1);
749
750                         if(autocvar_cl_spawn_event_particles)
751                         {
752                                 switch(teamnum)
753                                 {
754                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
755                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
756                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
757                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
758                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
759                                 }
760                         }
761                         if(autocvar_cl_spawn_event_sound)
762                         {
763                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
764                         }
765                 }
766         }
767
768         // local spawn actions
769         if(is_new && (!entnum || (entnum == player_localentnum)))
770         {
771                 zoomin_effect = 1;
772                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
773
774                 if(autocvar_cl_unpress_zoom_on_spawn)
775                 {
776                         localcmd("-zoom\n");
777                         button_zoom = false;
778                 }
779         }
780
781         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
782 }
783
784 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
785 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
786 void Ent_RadarLink();
787 void Ent_Init();
788 void Ent_ScoresInfo();
789 void CSQC_Ent_Update(float bIsNewEntity)
790 {
791         float t;
792         float savetime;
793         t = ReadByte();
794
795         if(autocvar_developer_csqcentities)
796                 printf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
797
798         // set up the "time" global for received entities to be correct for interpolation purposes
799         savetime = time;
800         if(servertime)
801         {
802                 time = servertime;
803         }
804         else
805         {
806                 serverprevtime = time;
807                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
808                 time = serverprevtime + serverdeltatime;
809         }
810
811 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
812         if(self.enttype)
813         {
814                 if(t != self.enttype || bIsNewEntity)
815                 {
816                         //print("A CSQC entity changed its type!\n");
817                         printf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
818                         Ent_Remove();
819                         clearentity(self);
820                         bIsNewEntity = 1;
821                 }
822         }
823         else
824         {
825                 if(!bIsNewEntity)
826                 {
827                         printf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
828                         bIsNewEntity = 1;
829                 }
830         }
831 #endif
832         self.enttype = t;
833         switch(t)
834         {
835                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
836                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
837                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
838                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
839                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
840                 case ENT_CLIENT_LASER: Ent_Laser(); break;
841                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
842                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
843                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
844                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
845                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
846                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
847                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
848                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
849                 case ENT_CLIENT_INIT: Ent_Init(); break;
850                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
851                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
852                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
853                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
854                 case ENT_CLIENT_WALL: Ent_Wall(); break;
855                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
856                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
857                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
858                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
859                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
860                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
861                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
862                 case ENT_CLIENT_INVENTORY: Inventory_Read(self); break;
863                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
864                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
865                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
866                 case ENT_CLIENT_TURRET: ent_turret(); break;
867                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
868                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
869                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
870                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
871                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
872                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
873                 case ENT_CLIENT_HEALING_ORB: ent_healer(); break;
874
875                 default:
876                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
877                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
878                         break;
879         }
880
881         time = savetime;
882 }
883 // Destructor, but does NOT deallocate the entity by calling remove(). Also
884 // used when an entity changes its type. For an entity that someone interacts
885 // with others, make sure it can no longer do so.
886 void Ent_Remove()
887 {
888         if(self.entremove)
889                 self.entremove();
890
891         if(self.skeletonindex)
892         {
893                 skel_delete(self.skeletonindex);
894                 self.skeletonindex = 0;
895         }
896
897         if(self.snd_looping > 0)
898         {
899                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
900                 self.snd_looping = 0;
901         }
902
903         self.enttype = 0;
904         self.classname = "";
905         self.draw = menu_sub_null;
906         self.entremove = menu_sub_null;
907         // TODO possibly set more stuff to defaults
908 }
909 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
910 void CSQC_Ent_Remove()
911 {
912         if(autocvar_developer_csqcentities)
913                 printf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
914
915         if(wasfreed(self))
916         {
917                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
918                 return;
919         }
920         if(self.enttype)
921                 Ent_Remove();
922         remove(self);
923 }
924
925 void Gamemode_Init()
926 {
927         if (!isdemo())
928         {
929                 if(!(calledhooks & HOOK_START))
930                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
931                 calledhooks |= HOOK_START;
932         }
933 }
934 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
935 void CSQC_Parse_StuffCmd(string strMessage)
936 {
937         if(autocvar_developer_csqcentities)
938                 printf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
939
940         localcmd(strMessage);
941 }
942 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
943 void CSQC_Parse_Print(string strMessage)
944 {
945         if(autocvar_developer_csqcentities)
946                 printf("CSQC_Parse_Print(\"%s\")\n", strMessage);
947
948         print(ColorTranslateRGB(strMessage));
949 }
950
951 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
952 void CSQC_Parse_CenterPrint(string strMessage)
953 {
954         if(autocvar_developer_csqcentities)
955                 printf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
956
957         centerprint_hud(strMessage);
958 }
959
960 string notranslate_fogcmd1 = "\nfog ";
961 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
962 void Fog_Force()
963 {
964         // TODO somehow thwart prvm_globalset client ...
965
966         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
967                 { localcmd("\nr_drawfog 0\n"); }
968         else if(forcefog != "")
969                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
970 }
971
972 void Gamemode_Init();
973 void Ent_ScoresInfo()
974 {
975     int i;
976         self.classname = "ent_client_scores_info";
977         gametype = ReadInt24_t();
978         HUD_ModIcons_SetFunc();
979         for(i = 0; i < MAX_SCORE; ++i)
980         {
981                 if(scores_label[i])
982                         strunzone(scores_label[i]);
983                 scores_label[i] = strzone(ReadString());
984                 scores_flags[i] = ReadByte();
985         }
986         for(i = 0; i < MAX_TEAMSCORE; ++i)
987         {
988                 if(teamscores_label[i])
989                         strunzone(teamscores_label[i]);
990                 teamscores_label[i] = strzone(ReadString());
991                 teamscores_flags[i] = ReadByte();
992         }
993         HUD_InitScores();
994         Gamemode_Init();
995 }
996
997 void Ent_Init()
998 {
999         self.classname = "ent_client_init";
1000
1001         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1002
1003         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1004         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1005         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1006         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1007         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1008         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1009         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1010         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1011
1012         if(forcefog)
1013                 strunzone(forcefog);
1014         forcefog = strzone(ReadString());
1015
1016         armorblockpercent = ReadByte() / 255.0;
1017
1018         g_balance_mortar_bouncefactor = ReadCoord();
1019         g_balance_mortar_bouncestop = ReadCoord();
1020         g_balance_electro_secondary_bouncefactor = ReadCoord();
1021         g_balance_electro_secondary_bouncestop = ReadCoord();
1022
1023         vortex_scope = !ReadByte();
1024         rifle_scope = !ReadByte();
1025
1026         serverflags = ReadByte();
1027
1028         minelayer_maxmines = ReadByte();
1029
1030         hagar_maxrockets = ReadByte();
1031
1032         g_trueaim_minrange = ReadCoord();
1033         g_balance_porto_secondary = ReadByte();
1034
1035         if(!postinit)
1036                 PostInit();
1037 }
1038
1039 void Net_ReadRace()
1040 {
1041         float b;
1042
1043         b = ReadByte();
1044
1045         switch(b)
1046         {
1047                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1048                         race_checkpoint = ReadByte();
1049                         race_time = ReadInt24_t();
1050                         race_previousbesttime = ReadInt24_t();
1051                         if(race_previousbestname)
1052                                 strunzone(race_previousbestname);
1053                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1054
1055                         race_checkpointtime = time;
1056
1057                         if(race_checkpoint == 0 || race_checkpoint == 254)
1058                         {
1059                                 race_penaltyaccumulator = 0;
1060                                 race_laptime = time; // valid
1061                         }
1062
1063                         break;
1064
1065                 case RACE_NET_CHECKPOINT_CLEAR:
1066                         race_laptime = 0;
1067                         race_checkpointtime = 0;
1068                         break;
1069
1070                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1071                         race_laptime = ReadCoord();
1072                         race_checkpointtime = -99999;
1073                         // fall through
1074                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1075                         race_nextcheckpoint = ReadByte();
1076
1077                         race_nextbesttime = ReadInt24_t();
1078                         if(race_nextbestname)
1079                                 strunzone(race_nextbestname);
1080                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1081                         break;
1082
1083                 case RACE_NET_CHECKPOINT_HIT_RACE:
1084                         race_mycheckpoint = ReadByte();
1085                         race_mycheckpointtime = time;
1086                         race_mycheckpointdelta = ReadInt24_t();
1087                         race_mycheckpointlapsdelta = ReadByte();
1088                         if(race_mycheckpointlapsdelta >= 128)
1089                                 race_mycheckpointlapsdelta -= 256;
1090                         if(race_mycheckpointenemy)
1091                                 strunzone(race_mycheckpointenemy);
1092                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1093                         break;
1094
1095                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1096                         race_othercheckpoint = ReadByte();
1097                         race_othercheckpointtime = time;
1098                         race_othercheckpointdelta = ReadInt24_t();
1099                         race_othercheckpointlapsdelta = ReadByte();
1100                         if(race_othercheckpointlapsdelta >= 128)
1101                                 race_othercheckpointlapsdelta -= 256;
1102                         if(race_othercheckpointenemy)
1103                                 strunzone(race_othercheckpointenemy);
1104                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1105                         break;
1106
1107                 case RACE_NET_PENALTY_RACE:
1108                         race_penaltyeventtime = time;
1109                         race_penaltytime = ReadShort();
1110                         //race_penaltyaccumulator += race_penaltytime;
1111                         if(race_penaltyreason)
1112                                 strunzone(race_penaltyreason);
1113                         race_penaltyreason = strzone(ReadString());
1114                         break;
1115
1116                 case RACE_NET_PENALTY_QUALIFYING:
1117                         race_penaltyeventtime = time;
1118                         race_penaltytime = ReadShort();
1119                         race_penaltyaccumulator += race_penaltytime;
1120                         if(race_penaltyreason)
1121                                 strunzone(race_penaltyreason);
1122                         race_penaltyreason = strzone(ReadString());
1123                         break;
1124
1125                 case RACE_NET_SERVER_RECORD:
1126                         race_server_record = ReadInt24_t();
1127                         break;
1128                 case RACE_NET_SPEED_AWARD:
1129                         race_speedaward = ReadInt24_t();
1130                         if(race_speedaward_holder)
1131                                 strunzone(race_speedaward_holder);
1132                         race_speedaward_holder = strzone(ReadString());
1133                         break;
1134                 case RACE_NET_SPEED_AWARD_BEST:
1135                         race_speedaward_alltimebest = ReadInt24_t();
1136                         if(race_speedaward_alltimebest_holder)
1137                                 strunzone(race_speedaward_alltimebest_holder);
1138                         race_speedaward_alltimebest_holder = strzone(ReadString());
1139                         break;
1140                 case RACE_NET_SERVER_RANKINGS:
1141                         float prevpos, del;
1142             int pos = ReadShort();
1143                         prevpos = ReadShort();
1144                         del = ReadShort();
1145
1146                         // move other rankings out of the way
1147             int i;
1148                         if (prevpos) {
1149                                 for (i=prevpos-1;i>pos-1;--i) {
1150                                         grecordtime[i] = grecordtime[i-1];
1151                                         if(grecordholder[i])
1152                                                 strunzone(grecordholder[i]);
1153                                         grecordholder[i] = strzone(grecordholder[i-1]);
1154                                 }
1155                         } else if (del) { // a record has been deleted by the admin
1156                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1157                                         if (i == RANKINGS_CNT-1) { // clear out last record
1158                                                 grecordtime[i] = 0;
1159                                                 if (grecordholder[i])
1160                                                         strunzone(grecordholder[i]);
1161                                                 grecordholder[i] = string_null;
1162                                         }
1163                                         else {
1164                                                 grecordtime[i] = grecordtime[i+1];
1165                                                 if (grecordholder[i])
1166                                                         strunzone(grecordholder[i]);
1167                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1168                                         }
1169                                 }
1170                         } else { // player has no ranked record yet
1171                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1172                                         grecordtime[i] = grecordtime[i-1];
1173                                         if(grecordholder[i])
1174                                                 strunzone(grecordholder[i]);
1175                                         grecordholder[i] = strzone(grecordholder[i-1]);
1176                                 }
1177                         }
1178
1179                         // store new ranking
1180                         if(grecordholder[pos-1] != "")
1181                                 strunzone(grecordholder[pos-1]);
1182                         grecordholder[pos-1] = strzone(ReadString());
1183                         grecordtime[pos-1] = ReadInt24_t();
1184                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1185                                 race_myrank = pos;
1186                         break;
1187                 case RACE_NET_SERVER_STATUS:
1188                         race_status = ReadShort();
1189                         if(race_status_name)
1190                                 strunzone(race_status_name);
1191                         race_status_name = strzone(ReadString());
1192         }
1193 }
1194
1195 void Net_TeamNagger()
1196 {
1197         teamnagger = 1;
1198 }
1199
1200 void Net_ReadPingPLReport()
1201 {
1202         int e, pi, pl, ml;
1203         e = ReadByte();
1204         pi = ReadShort();
1205         pl = ReadByte();
1206         ml = ReadByte();
1207         if (!(playerslots[e]))
1208                 return;
1209         playerslots[e].ping = pi;
1210         playerslots[e].ping_packetloss = pl / 255.0;
1211         playerslots[e].ping_movementloss = ml / 255.0;
1212 }
1213
1214 void Net_WeaponComplain()
1215 {
1216         complain_weapon = ReadByte();
1217
1218         if(complain_weapon_name)
1219                 strunzone(complain_weapon_name);
1220         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1221
1222         complain_weapon_type = ReadByte();
1223
1224         complain_weapon_time = time;
1225         weapontime = time; // ping the weapon panel
1226
1227         switch(complain_weapon_type)
1228         {
1229                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1230                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1231                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1232         }
1233 }
1234
1235 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1236 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1237 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1238 float CSQC_Parse_TempEntity()
1239 {
1240         float bHandled;
1241                 bHandled  = true;
1242         // Acquire TE ID
1243         float nTEID;
1244                 nTEID = ReadByte();
1245
1246         if(autocvar_developer_csqcentities)
1247                 printf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1248
1249                 // NOTE: Could just do return instead of break...
1250         switch(nTEID)
1251         {
1252                 case TE_CSQC_TARGET_MUSIC:
1253                         Net_TargetMusic();
1254                         bHandled = true;
1255                         break;
1256                 case TE_CSQC_PICTURE:
1257                         Net_MapVote_Picture();
1258                         bHandled = true;
1259                         break;
1260                 case TE_CSQC_RACE:
1261                         Net_ReadRace();
1262                         bHandled = true;
1263                         break;
1264                 case TE_CSQC_VORTEXBEAMPARTICLE:
1265                         Net_ReadVortexBeamParticle();
1266                         bHandled = true;
1267                         break;
1268                 case TE_CSQC_TEAMNAGGER:
1269                         Net_TeamNagger();
1270                         bHandled = true;
1271                         break;
1272                 case TE_CSQC_ARC:
1273                         Net_ReadArc();
1274                         bHandled = true;
1275                         break;
1276                 case TE_CSQC_PINGPLREPORT:
1277                         Net_ReadPingPLReport();
1278                         bHandled = true;
1279                         break;
1280                 case TE_CSQC_WEAPONCOMPLAIN:
1281                         Net_WeaponComplain();
1282                         bHandled = true;
1283                         break;
1284                 case TE_CSQC_VEHICLESETUP:
1285                         Net_VehicleSetup();
1286                         bHandled = true;
1287                         break;
1288                 case TE_CSQC_SVNOTICE:
1289                         cl_notice_read();
1290                         bHandled = true;
1291                         break;
1292                 case TE_CSQC_SHOCKWAVEPARTICLE:
1293                         Net_ReadShockwaveParticle();
1294                         bHandled = true;
1295                         break;
1296                 default:
1297                         // No special logic for this temporary entity; return 0 so the engine can handle it
1298                         bHandled = false;
1299                         break;
1300         }
1301
1302         return bHandled;
1303 }
1304
1305 string getcommandkey(string text, string command)
1306 {
1307         string keys;
1308         float n, j, k, l = 0;
1309
1310         if (!autocvar_hud_showbinds)
1311                 return text;
1312
1313         keys = db_get(binddb, command);
1314         if (keys == "")
1315         {
1316                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1317                 for(j = 0; j < n; ++j)
1318                 {
1319                         k = stof(argv(j));
1320                         if(k != -1)
1321                         {
1322                                 if ("" == keys)
1323                                         keys = keynumtostring(k);
1324                                 else
1325                                         keys = strcat(keys, ", ", keynumtostring(k));
1326
1327                                 ++l;
1328                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1329                                         break;
1330                         }
1331
1332                 }
1333                 if (keys == "")
1334                         keys = "NO_KEY";
1335                 db_put(binddb, command, keys);
1336         }
1337
1338         if (keys == "NO_KEY") {
1339                 if (autocvar_hud_showbinds > 1)
1340                         return sprintf(_("%s (not bound)"), text);
1341                 else
1342                         return text;
1343         }
1344         else if (autocvar_hud_showbinds > 1)
1345                 return sprintf("%s (%s)", text, keys);
1346         else
1347                 return keys;
1348 }