qcsrc/client/main.qc

   1 #include "main.qh"
   2 #include "_all.qh"
   3
   4 #include "controlpoint.qh"
   5 #include "csqcmodel_hooks.qh"
   6 #include "damage.qh"
   7 #include "effects.qh"
   8 #include "generator.qh"
   9 #include "gibs.qh"
  10 #include "hook.qh"
  11 #include "hud.qh"
  12 #include "hud_config.qh"
  13 #include "laser.qh"
  14 #include "mapvoting.qh"
  15 #include "modeleffects.qh"
  16 #include "particles.qh"
  17 #include "scoreboard.qh"
  18 #include "shownames.qh"
  19 #include "sortlist.qh"
  20 #include "tuba.qh"
  21 #include "t_items.qh"
  22 #include "wall.qh"
  23
  24 #include "../common/vehicles/all.qh"
  25
  26 #include "mutators/events.qh"
  27
  28 #include "weapons/projectile.qh"
  29
  30 #include "../common/buffs.qh"
  31 #include "../common/deathtypes.qh"
  32 #include "../common/effects.qh"
  33 #include "../common/mapinfo.qh"
  34 #include "../common/monsters/all.qh"
  35 #include "../common/nades.qh"
  36 #include "../common/net_notice.qh"
  37 #include "../common/notifications.qh"
  38 #include "../common/stats.qh"
  39 #include "../common/teams.qh"
  40
  41 #include "../common/items/all.qh"
  42
  43 #include "../common/mutators/base.qh"
  44
  45 #include "../common/weapons/all.qh"
  46
  47 #include "../csqcmodellib/cl_model.qh"
  48 #include "../csqcmodellib/interpolate.qh"
  49
  50 #include "../common/triggers/include.qh"
  51
  52 #include "../common/turrets/cl_turrets.qh"
  53 #include "../common/turrets/turrets.qh"
  54
  55 #include "../warpzonelib/client.qh"
  56
  57 // --------------------------------------------------------------------------
  58 // BEGIN REQUIRED CSQC FUNCTIONS
  59 //include "main.qh"
  60
  61 entity clearentity_ent;
  62 void clearentity(entity e)
  63 {
  64         if (!clearentity_ent)
  65         {
  66                 clearentity_ent = spawn();
  67                 clearentity_ent.classname = "clearentity";
  68         }
  69         int n = e.entnum;
  70         copyentity(clearentity_ent, e);
  71         e.entnum = n;
  72 }
  73
  74 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  75 void menu_show_error()
  76 {
  77         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  78 }
  79
  80 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  81 // Useful for precaching things
  82
  83 void menu_sub_null()
  84 {
  85 }
  86
  87 string forcefog;
  88 void ConsoleCommand_macro_init();
  89 void CSQC_Init(void)
  90 {
  91         prvm_language = cvar_string("prvm_language");
  92
  93 #ifdef WATERMARK
  94         dprintf("^4CSQC Build information: ^1%s\n", WATERMARK);
  95 #endif
  96
  97         int i;
  98
  99         binddb = db_create();
 100         tempdb = db_create();
 101         ClientProgsDB = db_load("client.db");
 102         compressShortVector_init();
 103
 104         draw_endBoldFont();
 105         menu_visible = false;
 106         menu_show = menu_show_error;
 107         menu_action = func_null;
 108
 109         for(i = 0; i < 255; ++i)
 110                 if(getplayerkeyvalue(i, "viewentity") == "")
 111                         break;
 112         maxclients = i;
 113
 114         //registercommand("hud_configure");
 115         //registercommand("hud_save");
 116         //registercommand("menu_action");
 117
 118         ConsoleCommand_macro_init();
 119
 120         registercvar("hud_usecsqc", "1");
 121         registercvar("scoreboard_columns", "default");
 122
 123         registercvar("cl_nade_type", "3");
 124         registercvar("cl_pokenade_type", "zombie");
 125
 126         registercvar("cl_jumpspeedcap_min", "");
 127         registercvar("cl_jumpspeedcap_max", "");
 128
 129         gametype = 0;
 130
 131         // hud_fields uses strunzone on the titles!
 132         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 133                 hud_title[i] = strzone("(null)");
 134
 135         Cmd_HUD_SetFields(0);
 136
 137         postinit = false;
 138
 139         calledhooks = 0;
 140
 141         teams = Sort_Spawn();
 142         players = Sort_Spawn();
 143
 144         GetTeam(NUM_SPECTATOR, true); // add specs first
 145
 146         // needs to be done so early because of the constants they create
 147         static_init();
 148         CALL_ACCUMULATED_FUNCTION(RegisterTurrets);
 149         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 150         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 151         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
 152         CALL_ACCUMULATED_FUNCTION(RegisterEffects);
 153
 154         initialize_minigames();
 155
 156         // precaches
 157         precache_model("null");
 158         precache_sound("misc/hit.wav");
 159         precache_sound("misc/typehit.wav");
 160
 161         generator_precache();
 162         Projectile_Precache();
 163         Hook_Precache();
 164         GibSplash_Precache();
 165         Tuba_Precache();
 166         CSQCPlayer_Precache();
 167
 168         if(autocvar_cl_reticle)
 169         {
 170                 precache_pic("gfx/reticle_normal");
 171                 // weapon reticles are precached in weapon files
 172         }
 173
 174         get_mi_min_max_texcoords(1); // try the CLEVER way first
 175         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 176         shortmapname = mi_shortname;
 177
 178         if(precache_pic(minimapname) == "")
 179         {
 180                 // but maybe we have a non-clever minimap
 181                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 182                 if(precache_pic(minimapname) == "")
 183                         minimapname = ""; // FAIL
 184                 else
 185                         get_mi_min_max_texcoords(0); // load new texcoords
 186         }
 187
 188         mi_center = (mi_min + mi_max) * 0.5;
 189         mi_scale = mi_max - mi_min;
 190         minimapname = strzone(minimapname);
 191
 192         WarpZone_Init();
 193
 194         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 195         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 196 }
 197
 198 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 199 void Shutdown(void)
 200 {
 201         WarpZone_Shutdown();
 202
 203         remove(teams);
 204         remove(players);
 205         db_close(binddb);
 206         db_close(tempdb);
 207         if(autocvar_cl_db_saveasdump)
 208                 db_dump(ClientProgsDB, "client.db");
 209         else
 210                 db_save(ClientProgsDB, "client.db");
 211         db_close(ClientProgsDB);
 212
 213         if(camera_active)
 214                 cvar_set("chase_active",ftos(chase_active_backup));
 215
 216         // unset the event chasecam's chase_active
 217         if(autocvar_chase_active < 0)
 218                 cvar_set("chase_active", "0");
 219
 220         if (!isdemo())
 221         {
 222                 if (!(calledhooks & HOOK_START))
 223                         localcmd("\n_cl_hook_gamestart nop\n");
 224                 if (!(calledhooks & HOOK_END))
 225                         localcmd("\ncl_hook_gameend\n");
 226         }
 227
 228         deactivate_minigame();
 229         HUD_MinigameMenu_Close();
 230 }
 231
 232 .float has_team;
 233 float SetTeam(entity o, int Team)
 234 {
 235         entity tm;
 236         if(teamplay)
 237         {
 238                 switch(Team)
 239                 {
 240                         case -1:
 241                         case NUM_TEAM_1:
 242                         case NUM_TEAM_2:
 243                         case NUM_TEAM_3:
 244                         case NUM_TEAM_4:
 245                                 break;
 246                         default:
 247                                 if(GetTeam(Team, false) == world)
 248                                 {
 249                                         dprintf("trying to switch to unsupported team %d\n", Team);
 250                                         Team = NUM_SPECTATOR;
 251                                 }
 252                                 break;
 253                 }
 254         }
 255         else
 256         {
 257                 switch(Team)
 258                 {
 259                         case -1:
 260                         case 0:
 261                                 break;
 262                         default:
 263                                 if(GetTeam(Team, false) == world)
 264                                 {
 265                                         dprintf("trying to switch to unsupported team %d\n", Team);
 266                                         Team = NUM_SPECTATOR;
 267                                 }
 268                                 break;
 269                 }
 270         }
 271         if(Team == -1) // leave
 272         {
 273                 if(o.has_team)
 274                 {
 275                         tm = GetTeam(o.team, false);
 276                         tm.team_size -= 1;
 277                         o.has_team = 0;
 278                         return true;
 279                 }
 280         }
 281         else
 282         {
 283                 if (!o.has_team)
 284                 {
 285                         o.team = Team;
 286                         tm = GetTeam(Team, true);
 287                         tm.team_size += 1;
 288                         o.has_team = 1;
 289                         return true;
 290                 }
 291                 else if(Team != o.team)
 292                 {
 293                         tm = GetTeam(o.team, false);
 294                         tm.team_size -= 1;
 295                         o.team = Team;
 296                         tm = GetTeam(Team, true);
 297                         tm.team_size += 1;
 298                         return true;
 299                 }
 300         }
 301         return false;
 302 }
 303
 304 void Playerchecker_Think()
 305 {
 306     int i;
 307         entity e;
 308         for(i = 0; i < maxclients; ++i)
 309         {
 310                 e = playerslots[i];
 311                 if(GetPlayerName(i) == "")
 312                 {
 313                         if(e.sort_prev)
 314                         {
 315                                 // player disconnected
 316                                 SetTeam(e, -1);
 317                                 RemovePlayer(e);
 318                                 e.sort_prev = world;
 319                                 //e.gotscores = 0;
 320                         }
 321                 }
 322                 else
 323                 {
 324                         if (!e.sort_prev)
 325                         {
 326                                 // player connected
 327                                 if (!e)
 328                                         playerslots[i] = e = spawn();
 329                                 e.sv_entnum = i;
 330                                 e.ping = 0;
 331                                 e.ping_packetloss = 0;
 332                                 e.ping_movementloss = 0;
 333                                 //e.gotscores = 0; // we might already have the scores...
 334                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 335                                 RegisterPlayer(e);
 336                                 HUD_UpdatePlayerPos(e);
 337                         }
 338                 }
 339         }
 340         self.nextthink = time + 0.2;
 341 }
 342
 343 void Porto_Init();
 344 void TrueAim_Init();
 345 void PostInit(void)
 346 {
 347         entity playerchecker;
 348         playerchecker = spawn();
 349         playerchecker.think = Playerchecker_Think;
 350         playerchecker.nextthink = time + 0.2;
 351
 352         Porto_Init();
 353         TrueAim_Init();
 354
 355         postinit = true;
 356 }
 357
 358 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 359 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 360 // All keys are in ascii.
 361 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 362 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 363 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 364 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 365 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 366 {
 367         float bSkipKey;
 368         bSkipKey = false;
 369
 370         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 371                 return true;
 372
 373         if ( HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary) )
 374                 return true;
 375
 376         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 377                 return true;
 378
 379         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
 380                 return true;
 381
 382         if(menu_visible && menu_action)
 383                 if(menu_action(bInputType, nPrimary, nSecondary))
 384                         return true;
 385
 386         return bSkipKey;
 387 }
 388
 389 // END REQUIRED CSQC FUNCTIONS
 390 // --------------------------------------------------------------------------
 391
 392 // --------------------------------------------------------------------------
 393 // BEGIN OPTIONAL CSQC FUNCTIONS
 394
 395 void Ent_RemoveEntCS()
 396 {
 397         entcs_receiver[self.sv_entnum] = world;
 398 }
 399 void Ent_ReadEntCS()
 400 {
 401     int sf;
 402         InterpolateOrigin_Undo();
 403
 404         self.classname = "entcs_receiver";
 405         sf = ReadByte();
 406
 407         if(sf & 1)
 408                 self.sv_entnum = ReadByte();
 409         if(sf & 2)
 410         {
 411                 self.origin_x = ReadShort();
 412                 self.origin_y = ReadShort();
 413                 self.origin_z = ReadShort();
 414                 setorigin(self, self.origin);
 415         }
 416         if(sf & 4)
 417         {
 418                 self.angles_y = ReadByte() * 360.0 / 256;
 419                 self.angles_x = self.angles_z = 0;
 420         }
 421         if(sf & 8)
 422                 self.healthvalue = ReadByte() * 10;
 423         if(sf & 16)
 424                 self.armorvalue = ReadByte() * 10;
 425
 426         entcs_receiver[self.sv_entnum] = self;
 427         self.entremove = Ent_RemoveEntCS;
 428         self.iflags |= IFLAG_ORIGIN;
 429
 430         InterpolateOrigin_Note();
 431 }
 432
 433 void Ent_Remove();
 434
 435 void Ent_RemovePlayerScore()
 436 {
 437         if(self.owner) {
 438                 SetTeam(self.owner, -1);
 439                 self.owner.gotscores = 0;
 440                 for(int i = 0; i < MAX_SCORE; ++i) {
 441                         self.owner.(scores[i]) = 0; // clear all scores
 442                 }
 443         }
 444 }
 445
 446 void Ent_ReadPlayerScore()
 447 {
 448         int i, n;
 449         bool isNew;
 450         entity o;
 451
 452         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 453         // (no I've never heard of M-x replace-string, sed, or anything like that)
 454         isNew = !self.owner; // workaround for DP bug
 455         n = ReadByte()-1;
 456
 457 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 458         if(!isNew && n != self.sv_entnum)
 459         {
 460                 //print("A CSQC entity changed its owner!\n");
 461                 printf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 462                 isNew = true;
 463                 Ent_Remove();
 464                 self.enttype = ENT_CLIENT_SCORES;
 465         }
 466 #endif
 467
 468         self.sv_entnum = n;
 469
 470         if (!(playerslots[self.sv_entnum]))
 471                 playerslots[self.sv_entnum] = spawn();
 472         o = self.owner = playerslots[self.sv_entnum];
 473         o.sv_entnum = self.sv_entnum;
 474         o.gotscores = 1;
 475
 476         //if (!o.sort_prev)
 477         //      RegisterPlayer(o);
 478         //playerchecker will do this for us later, if it has not already done so
 479
 480     int sf, lf;
 481 #if MAX_SCORE <= 8
 482         sf = ReadByte();
 483         lf = ReadByte();
 484 #else
 485         sf = ReadShort();
 486         lf = ReadShort();
 487 #endif
 488     int p;
 489         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 490                 if(sf & p)
 491                 {
 492                         if(lf & p)
 493                                 o.(scores[i]) = ReadInt24_t();
 494                         else
 495                                 o.(scores[i]) = ReadChar();
 496                 }
 497
 498         if(o.sort_prev)
 499                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 500
 501         self.entremove = Ent_RemovePlayerScore;
 502 }
 503
 504 void Ent_ReadTeamScore()
 505 {
 506         int i;
 507         entity o;
 508
 509         self.team = ReadByte();
 510         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 511
 512     int sf, lf;
 513 #if MAX_TEAMSCORE <= 8
 514         sf = ReadByte();
 515         lf = ReadByte();
 516 #else
 517         sf = ReadShort();
 518         lf = ReadShort();
 519 #endif
 520         int p;
 521         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 522                 if(sf & p)
 523                 {
 524                         if(lf & p)
 525                                 o.(teamscores[i]) = ReadInt24_t();
 526                         else
 527                                 o.(teamscores[i]) = ReadChar();
 528                 }
 529
 530         HUD_UpdateTeamPos(o);
 531 }
 532
 533 void Ent_ClientData()
 534 {
 535         float newspectatee_status;
 536
 537     int f = ReadByte();
 538
 539         scoreboard_showscores_force = (f & 1);
 540
 541         if(f & 2)
 542         {
 543                 newspectatee_status = ReadByte();
 544                 if(newspectatee_status == player_localnum + 1)
 545                         newspectatee_status = -1; // observing
 546         }
 547         else
 548                 newspectatee_status = 0;
 549
 550         spectatorbutton_zoom = (f & 4);
 551
 552         if(f & 8)
 553         {
 554                 angles_held_status = 1;
 555                 angles_held.x = ReadAngle();
 556                 angles_held.y = ReadAngle();
 557                 angles_held.z = 0;
 558         }
 559         else
 560                 angles_held_status = 0;
 561
 562         if(newspectatee_status != spectatee_status)
 563         {
 564                 // clear race stuff
 565                 race_laptime = 0;
 566                 race_checkpointtime = 0;
 567         }
 568         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 569         {
 570                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 571                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 572                 )
 573                         prev_p_health = -1;
 574                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 575                         prev_health = -1;
 576         }
 577         spectatee_status = newspectatee_status;
 578
 579         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 580 }
 581
 582 void Ent_Nagger()
 583 {
 584     int i, j, b, f;
 585
 586     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 587
 588         if(!(nags & 4))
 589         {
 590                 if(vote_called_vote)
 591                         strunzone(vote_called_vote);
 592                 vote_called_vote = string_null;
 593                 vote_active = 0;
 594         }
 595         else
 596         {
 597                 vote_active = 1;
 598         }
 599
 600         if(nags & 64)
 601         {
 602                 vote_yescount = ReadByte();
 603                 vote_nocount = ReadByte();
 604                 vote_needed = ReadByte();
 605                 vote_highlighted = ReadChar();
 606         }
 607
 608         if(nags & 128)
 609         {
 610                 if(vote_called_vote)
 611                         strunzone(vote_called_vote);
 612                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 613         }
 614
 615         if(nags & 1)
 616         {
 617                 for(j = 0; j < maxclients; ++j)
 618                         if(playerslots[j])
 619                                 playerslots[j].ready = 1;
 620                 for(i = 1; i <= maxclients; i += 8)
 621                 {
 622                         f = ReadByte();
 623                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 624                                 if (!(f & b))
 625                                         if(playerslots[j])
 626                                                 playerslots[j].ready = 0;
 627                 }
 628         }
 629
 630         ready_waiting = (nags & 1);
 631         ready_waiting_for_me = (nags & 2);
 632         vote_waiting = (nags & 4);
 633         vote_waiting_for_me = (nags & 8);
 634         warmup_stage = (nags & 16);
 635 }
 636
 637 void Ent_EliminatedPlayers()
 638 {
 639     int i, j, b, f;
 640
 641     int sf = ReadByte();
 642         if(sf & 1)
 643         {
 644                 for(j = 0; j < maxclients; ++j)
 645                         if(playerslots[j])
 646                                 playerslots[j].eliminated = 1;
 647                 for(i = 1; i <= maxclients; i += 8)
 648                 {
 649                         f = ReadByte();
 650                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 651                                 if (!(f & b))
 652                                         if(playerslots[j])
 653                                                 playerslots[j].eliminated = 0;
 654                 }
 655         }
 656 }
 657
 658 void Ent_RandomSeed()
 659 {
 660         float s;
 661         prandom_debug();
 662         s = ReadShort();
 663         psrandom(s);
 664 }
 665
 666 void Ent_ReadAccuracy(void)
 667 {
 668     int f, w;
 669     int sf = ReadInt24_t();
 670         if(sf == 0)
 671         {
 672                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 673                         weapon_accuracy[w] = -1;
 674                 return;
 675         }
 676
 677         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 678         {
 679                 if(sf & f)
 680                 {
 681             int b = ReadByte();
 682                         if(b == 0)
 683                                 weapon_accuracy[w] = -1;
 684                         else if(b == 255)
 685                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 686                         else
 687                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 688                 }
 689                 if(f == 0x800000)
 690                         f = 1;
 691                 else
 692                         f *= 2;
 693         }
 694 }
 695
 696 void Spawn_Draw(void)
 697 {
 698         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 699 }
 700
 701 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 702 {
 703         float teamnum = (ReadByte() - 1);
 704         vector spn_origin;
 705         spn_origin.x = ReadShort();
 706         spn_origin.y = ReadShort();
 707         spn_origin.z = ReadShort();
 708
 709         if(is_new)
 710         {
 711                 self.origin = spn_origin;
 712                 setsize(self, PL_MIN_CONST, PL_MAX_CONST);
 713                 droptofloor();
 714
 715                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 716                 {
 717                         self.mdl = "models/spawnpoint.md3";
 718                         self.colormod = Team_ColorRGB(teamnum);
 719                         precache_model(self.mdl);
 720                         setmodel(self, self.mdl);
 721                         self.drawmask = MASK_NORMAL;
 722                         //self.movetype = MOVETYPE_NOCLIP;
 723                         //self.draw = Spawn_Draw;
 724                 }*/
 725                 if(autocvar_cl_spawn_point_particles)
 726                 {
 727                         if((serverflags & SERVERFLAG_TEAMPLAY))
 728                         {
 729                                 switch(teamnum)
 730                                 {
 731                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
 732                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
 733                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
 734                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
 735                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
 736                                 }
 737                         }
 738                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
 739
 740                         self.draw = Spawn_Draw;
 741                 }
 742         }
 743
 744         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 745 }
 746
 747 void Ent_ReadSpawnEvent(float is_new)
 748 {
 749         // If entnum is 0, ONLY do the local spawn actions
 750         // this way the server can disable the sending of
 751         // spawn origin or such to clients if wanted.
 752         float entnum = ReadByte();
 753
 754         if(entnum)
 755         {
 756                 self.origin_x = ReadShort();
 757                 self.origin_y = ReadShort();
 758                 self.origin_z = ReadShort();
 759
 760                 if(is_new)
 761                 {
 762                         float teamnum = GetPlayerColor(entnum - 1);
 763
 764                         if(autocvar_cl_spawn_event_particles)
 765                         {
 766                                 switch(teamnum)
 767                                 {
 768                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
 769                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
 770                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
 771                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
 772                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
 773                                 }
 774                         }
 775                         if(autocvar_cl_spawn_event_sound)
 776                         {
 777                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
 778                         }
 779                 }
 780         }
 781
 782         // local spawn actions
 783         if(is_new && (!entnum || (entnum == player_localentnum)))
 784         {
 785                 zoomin_effect = 1;
 786                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 787
 788                 if(autocvar_cl_unpress_zoom_on_spawn)
 789                 {
 790                         localcmd("-zoom\n");
 791                         button_zoom = false;
 792                 }
 793         }
 794         HUD_Radar_Hide_Maximized();
 795         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 796 }
 797
 798 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 799 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 800 void Ent_RadarLink();
 801 void Ent_Init();
 802 void Ent_ScoresInfo();
 803 void CSQC_Ent_Update(float bIsNewEntity)
 804 {
 805         float t;
 806         float savetime;
 807         t = ReadByte();
 808
 809         if(autocvar_developer_csqcentities)
 810                 printf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 811
 812         // set up the "time" global for received entities to be correct for interpolation purposes
 813         savetime = time;
 814         if(servertime)
 815         {
 816                 time = servertime;
 817         }
 818         else
 819         {
 820                 serverprevtime = time;
 821                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 822                 time = serverprevtime + serverdeltatime;
 823         }
 824
 825 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 826         if(self.enttype)
 827         {
 828                 if(t != self.enttype || bIsNewEntity)
 829                 {
 830                         //print("A CSQC entity changed its type!\n");
 831                         printf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 832                         Ent_Remove();
 833                         clearentity(self);
 834                         bIsNewEntity = 1;
 835                 }
 836         }
 837         else
 838         {
 839                 if(!bIsNewEntity)
 840                 {
 841                         printf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 842                         bIsNewEntity = 1;
 843                 }
 844         }
 845 #endif
 846         self.enttype = t;
 847         switch(t)
 848         {
 849                 case ENT_CLIENT_MUTATOR: {
 850                         int mutID = ReadMutator();
 851                         if (!MUTATOR_CALLHOOK(CSQC_Ent_Update, mutID, bIsNewEntity))
 852                         error(sprintf("Unknown mutator type in CSQC_Ent_Update (mutID: %d, edict: %d, classname: %s)\n", mutID, num_for_edict(self), self.classname));
 853                         break;
 854                 }
 855                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 856                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 857                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 858                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 859                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 860                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 861                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 862                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
 863                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 864                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 865                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 866                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 867                 case ENT_CLIENT_INIT: Ent_Init(); break;
 868                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 869                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 870                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 871                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 872                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 873                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 874                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 875                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 876                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 877                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 878                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 879                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 880                 case ENT_CLIENT_INVENTORY: Inventory_Read(self); break;
 881                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
 882                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 883                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 884                 case ENT_CLIENT_TURRET: ent_turret(); break;
 885                 case ENT_CLIENT_GENERATOR: ent_generator(); break;
 886                 case ENT_CLIENT_CONTROLPOINT_ICON: ent_cpicon(); break;
 887                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 888                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 889                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 890                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 891                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 892                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 893                 case ENT_CLIENT_HEALING_ORB: ent_healer(); break;
 894                 case ENT_CLIENT_MINIGAME: ent_read_minigame(); break;
 895                 case ENT_CLIENT_VIEWLOC: ent_viewloc(); break;
 896                 case ENT_CLIENT_VIEWLOC_TRIGGER: ent_viewloc_trigger(); break;
 897                 case ENT_CLIENT_LADDER: ent_func_ladder(); break;
 898                 case ENT_CLIENT_TRIGGER_PUSH: ent_trigger_push(); break;
 899                 case ENT_CLIENT_TARGET_PUSH: ent_target_push(); break;
 900                 case ENT_CLIENT_CONVEYOR: ent_conveyor(); break;
 901                 case ENT_CLIENT_DOOR: ent_door(); break;
 902                 case ENT_CLIENT_PLAT: ent_plat(); break;
 903                 case ENT_CLIENT_SWAMP: ent_swamp(); break;
 904                 case ENT_CLIENT_CORNER: ent_corner(); break;
 905                 case ENT_CLIENT_KEYLOCK: ent_keylock(); break;
 906                 case ENT_CLIENT_TRAIN: ent_train(); break;
 907                 case ENT_CLIENT_TRIGGER_IMPULSE: ent_trigger_impulse(); break;
 908                 case ENT_CLIENT_EFFECT: Read_Effect(bIsNewEntity); break;
 909
 910                 default:
 911                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 912                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
 913                         break;
 914         }
 915
 916         time = savetime;
 917 }
 918 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 919 // used when an entity changes its type. For an entity that someone interacts
 920 // with others, make sure it can no longer do so.
 921 void Ent_Remove()
 922 {
 923         if(self.entremove)
 924                 self.entremove();
 925
 926         if(self.skeletonindex)
 927         {
 928                 skel_delete(self.skeletonindex);
 929                 self.skeletonindex = 0;
 930         }
 931
 932         if(self.snd_looping > 0)
 933         {
 934                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 935                 self.snd_looping = 0;
 936         }
 937
 938         self.enttype = 0;
 939         self.classname = "";
 940         self.draw = menu_sub_null;
 941         self.entremove = menu_sub_null;
 942         // TODO possibly set more stuff to defaults
 943 }
 944 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 945 void CSQC_Ent_Remove()
 946 {
 947         if(autocvar_developer_csqcentities)
 948                 printf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 949
 950         if(wasfreed(self))
 951         {
 952                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 953                 return;
 954         }
 955         if(self.enttype)
 956                 Ent_Remove();
 957         remove(self);
 958 }
 959
 960 void Gamemode_Init()
 961 {
 962         if (!isdemo())
 963         {
 964                 if(!(calledhooks & HOOK_START))
 965                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 966                 calledhooks |= HOOK_START;
 967         }
 968 }
 969 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 970 void CSQC_Parse_StuffCmd(string strMessage)
 971 {
 972         if(autocvar_developer_csqcentities)
 973                 printf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 974
 975         localcmd(strMessage);
 976 }
 977 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 978 void CSQC_Parse_Print(string strMessage)
 979 {
 980         if(autocvar_developer_csqcentities)
 981                 printf("CSQC_Parse_Print(\"%s\")\n", strMessage);
 982
 983         print(ColorTranslateRGB(strMessage));
 984 }
 985
 986 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 987 void CSQC_Parse_CenterPrint(string strMessage)
 988 {
 989         if(autocvar_developer_csqcentities)
 990                 printf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 991
 992         centerprint_hud(strMessage);
 993 }
 994
 995 string notranslate_fogcmd1 = "\nfog ";
 996 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 997 void Fog_Force()
 998 {
 999         // TODO somehow thwart prvm_globalset client ...
1000
1001         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
1002                 { localcmd("\nr_drawfog 0\n"); }
1003         else if(forcefog != "")
1004                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
1005 }
1006
1007 void Gamemode_Init();
1008 void Ent_ScoresInfo()
1009 {
1010     int i;
1011         self.classname = "ent_client_scores_info";
1012         gametype = ReadInt24_t();
1013         HUD_ModIcons_SetFunc();
1014         for(i = 0; i < MAX_SCORE; ++i)
1015         {
1016                 if(scores_label[i])
1017                         strunzone(scores_label[i]);
1018                 scores_label[i] = strzone(ReadString());
1019                 scores_flags[i] = ReadByte();
1020         }
1021         for(i = 0; i < MAX_TEAMSCORE; ++i)
1022         {
1023                 if(teamscores_label[i])
1024                         strunzone(teamscores_label[i]);
1025                 teamscores_label[i] = strzone(ReadString());
1026                 teamscores_flags[i] = ReadByte();
1027         }
1028         HUD_InitScores();
1029         Gamemode_Init();
1030 }
1031
1032 void Ent_Init()
1033 {
1034         self.classname = "ent_client_init";
1035
1036         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1037
1038         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1039         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1040         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1041         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1042         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1043         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1044         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1045         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1046
1047         if(forcefog)
1048                 strunzone(forcefog);
1049         forcefog = strzone(ReadString());
1050
1051         armorblockpercent = ReadByte() / 255.0;
1052
1053         g_balance_mortar_bouncefactor = ReadCoord();
1054         g_balance_mortar_bouncestop = ReadCoord();
1055         g_balance_electro_secondary_bouncefactor = ReadCoord();
1056         g_balance_electro_secondary_bouncestop = ReadCoord();
1057
1058         vortex_scope = !ReadByte();
1059         rifle_scope = !ReadByte();
1060
1061         serverflags = ReadByte();
1062
1063         minelayer_maxmines = ReadByte();
1064
1065         hagar_maxrockets = ReadByte();
1066
1067         g_trueaim_minrange = ReadCoord();
1068         g_balance_porto_secondary = ReadByte();
1069
1070         if(!postinit)
1071                 PostInit();
1072 }
1073
1074 void Net_ReadRace()
1075 {
1076         float b;
1077
1078         b = ReadByte();
1079
1080         switch(b)
1081         {
1082                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1083                         race_checkpoint = ReadByte();
1084                         race_time = ReadInt24_t();
1085                         race_previousbesttime = ReadInt24_t();
1086                         if(race_previousbestname)
1087                                 strunzone(race_previousbestname);
1088                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1089
1090                         race_checkpointtime = time;
1091
1092                         if(race_checkpoint == 0 || race_checkpoint == 254)
1093                         {
1094                                 race_penaltyaccumulator = 0;
1095                                 race_laptime = time; // valid
1096                         }
1097
1098                         break;
1099
1100                 case RACE_NET_CHECKPOINT_CLEAR:
1101                         race_laptime = 0;
1102                         race_checkpointtime = 0;
1103                         break;
1104
1105                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1106                         race_laptime = ReadCoord();
1107                         race_checkpointtime = -99999;
1108                         // fall through
1109                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1110                         race_nextcheckpoint = ReadByte();
1111
1112                         race_nextbesttime = ReadInt24_t();
1113                         if(race_nextbestname)
1114                                 strunzone(race_nextbestname);
1115                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1116                         break;
1117
1118                 case RACE_NET_CHECKPOINT_HIT_RACE:
1119                         race_mycheckpoint = ReadByte();
1120                         race_mycheckpointtime = time;
1121                         race_mycheckpointdelta = ReadInt24_t();
1122                         race_mycheckpointlapsdelta = ReadByte();
1123                         if(race_mycheckpointlapsdelta >= 128)
1124                                 race_mycheckpointlapsdelta -= 256;
1125                         if(race_mycheckpointenemy)
1126                                 strunzone(race_mycheckpointenemy);
1127                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1128                         break;
1129
1130                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1131                         race_othercheckpoint = ReadByte();
1132                         race_othercheckpointtime = time;
1133                         race_othercheckpointdelta = ReadInt24_t();
1134                         race_othercheckpointlapsdelta = ReadByte();
1135                         if(race_othercheckpointlapsdelta >= 128)
1136                                 race_othercheckpointlapsdelta -= 256;
1137                         if(race_othercheckpointenemy)
1138                                 strunzone(race_othercheckpointenemy);
1139                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1140                         break;
1141
1142                 case RACE_NET_PENALTY_RACE:
1143                         race_penaltyeventtime = time;
1144                         race_penaltytime = ReadShort();
1145                         //race_penaltyaccumulator += race_penaltytime;
1146                         if(race_penaltyreason)
1147                                 strunzone(race_penaltyreason);
1148                         race_penaltyreason = strzone(ReadString());
1149                         break;
1150
1151                 case RACE_NET_PENALTY_QUALIFYING:
1152                         race_penaltyeventtime = time;
1153                         race_penaltytime = ReadShort();
1154                         race_penaltyaccumulator += race_penaltytime;
1155                         if(race_penaltyreason)
1156                                 strunzone(race_penaltyreason);
1157                         race_penaltyreason = strzone(ReadString());
1158                         break;
1159
1160                 case RACE_NET_SERVER_RECORD:
1161                         race_server_record = ReadInt24_t();
1162                         break;
1163                 case RACE_NET_SPEED_AWARD:
1164                         race_speedaward = ReadInt24_t();
1165                         if(race_speedaward_holder)
1166                                 strunzone(race_speedaward_holder);
1167                         race_speedaward_holder = strzone(ReadString());
1168                         break;
1169                 case RACE_NET_SPEED_AWARD_BEST:
1170                         race_speedaward_alltimebest = ReadInt24_t();
1171                         if(race_speedaward_alltimebest_holder)
1172                                 strunzone(race_speedaward_alltimebest_holder);
1173                         race_speedaward_alltimebest_holder = strzone(ReadString());
1174                         break;
1175                 case RACE_NET_SERVER_RANKINGS:
1176                         float prevpos, del;
1177             int pos = ReadShort();
1178                         prevpos = ReadShort();
1179                         del = ReadShort();
1180
1181                         // move other rankings out of the way
1182             int i;
1183                         if (prevpos) {
1184                                 for (i=prevpos-1;i>pos-1;--i) {
1185                                         grecordtime[i] = grecordtime[i-1];
1186                                         if(grecordholder[i])
1187                                                 strunzone(grecordholder[i]);
1188                                         grecordholder[i] = strzone(grecordholder[i-1]);
1189                                 }
1190                         } else if (del) { // a record has been deleted by the admin
1191                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1192                                         if (i == RANKINGS_CNT-1) { // clear out last record
1193                                                 grecordtime[i] = 0;
1194                                                 if (grecordholder[i])
1195                                                         strunzone(grecordholder[i]);
1196                                                 grecordholder[i] = string_null;
1197                                         }
1198                                         else {
1199                                                 grecordtime[i] = grecordtime[i+1];
1200                                                 if (grecordholder[i])
1201                                                         strunzone(grecordholder[i]);
1202                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1203                                         }
1204                                 }
1205                         } else { // player has no ranked record yet
1206                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1207                                         grecordtime[i] = grecordtime[i-1];
1208                                         if(grecordholder[i])
1209                                                 strunzone(grecordholder[i]);
1210                                         grecordholder[i] = strzone(grecordholder[i-1]);
1211                                 }
1212                         }
1213
1214                         // store new ranking
1215                         if(grecordholder[pos-1] != "")
1216                                 strunzone(grecordholder[pos-1]);
1217                         grecordholder[pos-1] = strzone(ReadString());
1218                         grecordtime[pos-1] = ReadInt24_t();
1219                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1220                                 race_myrank = pos;
1221                         break;
1222                 case RACE_NET_SERVER_STATUS:
1223                         race_status = ReadShort();
1224                         if(race_status_name)
1225                                 strunzone(race_status_name);
1226                         race_status_name = strzone(ReadString());
1227         }
1228 }
1229
1230 void Net_TeamNagger()
1231 {
1232         teamnagger = 1;
1233 }
1234
1235 void Net_ReadPingPLReport()
1236 {
1237         int e, pi, pl, ml;
1238         e = ReadByte();
1239         pi = ReadShort();
1240         pl = ReadByte();
1241         ml = ReadByte();
1242         if (!(playerslots[e]))
1243                 return;
1244         playerslots[e].ping = pi;
1245         playerslots[e].ping_packetloss = pl / 255.0;
1246         playerslots[e].ping_movementloss = ml / 255.0;
1247 }
1248
1249 void Net_WeaponComplain()
1250 {
1251         complain_weapon = ReadByte();
1252
1253         if(complain_weapon_name)
1254                 strunzone(complain_weapon_name);
1255         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1256
1257         complain_weapon_type = ReadByte();
1258
1259         complain_weapon_time = time;
1260         weapontime = time; // ping the weapon panel
1261
1262         switch(complain_weapon_type)
1263         {
1264                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1265                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1266                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1267         }
1268 }
1269
1270 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1271 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1272 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1273 float CSQC_Parse_TempEntity()
1274 {
1275         // Acquire TE ID
1276         int nTEID = ReadByte();
1277
1278         if (autocvar_developer_csqcentities)
1279                 printf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1280
1281         switch (nTEID)
1282         {
1283                 case TE_CSQC_MUTATOR:
1284                         int mutID = ReadMutator();
1285                         if (MUTATOR_CALLHOOK(CSQC_Parse_TempEntity, mutID))
1286                         return true;
1287                 case TE_CSQC_TARGET_MUSIC:
1288                         Net_TargetMusic();
1289                         return true;
1290                 case TE_CSQC_PICTURE:
1291                         Net_MapVote_Picture();
1292                         return true;
1293                 case TE_CSQC_RACE:
1294                         Net_ReadRace();
1295                         return true;
1296                 case TE_CSQC_VORTEXBEAMPARTICLE:
1297                         Net_ReadVortexBeamParticle();
1298                         return true;
1299                 case TE_CSQC_TEAMNAGGER:
1300                         Net_TeamNagger();
1301                         return true;
1302                 case TE_CSQC_ARC:
1303                         Net_ReadArc();
1304                         return true;
1305                 case TE_CSQC_PINGPLREPORT:
1306                         Net_ReadPingPLReport();
1307                         return true;
1308                 case TE_CSQC_WEAPONCOMPLAIN:
1309                         Net_WeaponComplain();
1310                         return true;
1311                 case TE_CSQC_VEHICLESETUP:
1312                         Net_VehicleSetup();
1313                         return true;
1314                 case TE_CSQC_SVNOTICE:
1315                         cl_notice_read();
1316                         return true;
1317                 case TE_CSQC_SHOCKWAVEPARTICLE:
1318                         Net_ReadShockwaveParticle();
1319                         return true;
1320                 default:
1321                         // No special logic for this temporary entity; return 0 so the engine can handle it
1322                         return false;
1323         }
1324 }
1325
1326 string getcommandkey(string text, string command)
1327 {
1328         string keys;
1329         float n, j, k, l = 0;
1330
1331         if (!autocvar_hud_showbinds)
1332                 return text;
1333
1334         keys = db_get(binddb, command);
1335         if (keys == "")
1336         {
1337                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1338                 for(j = 0; j < n; ++j)
1339                 {
1340                         k = stof(argv(j));
1341                         if(k != -1)
1342                         {
1343                                 if ("" == keys)
1344                                         keys = keynumtostring(k);
1345                                 else
1346                                         keys = strcat(keys, ", ", keynumtostring(k));
1347
1348                                 ++l;
1349                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1350                                         break;
1351                         }
1352
1353                 }
1354                 if (keys == "")
1355                         keys = "NO_KEY";
1356                 db_put(binddb, command, keys);
1357         }
1358
1359         if (keys == "NO_KEY") {
1360                 if (autocvar_hud_showbinds > 1)
1361                         return sprintf(_("%s (not bound)"), text);
1362                 else
1363                         return text;
1364         }
1365         else if (autocvar_hud_showbinds > 1)
1366                 return sprintf("%s (%s)", text, keys);
1367         else
1368                 return keys;
1369 }