qcsrc/client/main.qc

   1 #include "main.qh"
   2 #include "_all.qh"
   3
   4 #include "controlpoint.qh"
   5 #include "csqcmodel_hooks.qh"
   6 #include "damage.qh"
   7 #include "effects.qh"
   8 #include "generator.qh"
   9 #include "gibs.qh"
  10 #include "hook.qh"
  11 #include "hud.qh"
  12 #include "hud_config.qh"
  13 #include "laser.qh"
  14 #include "mapvoting.qh"
  15 #include "modeleffects.qh"
  16 #include "particles.qh"
  17 #include "scoreboard.qh"
  18 #include "shownames.qh"
  19 #include "tuba.qh"
  20 #include "t_items.qh"
  21 #include "wall.qh"
  22
  23 #include "../common/vehicles/all.qh"
  24
  25 #include "mutators/events.qh"
  26
  27 #include "weapons/projectile.qh"
  28
  29 #include "../common/buffs.qh"
  30 #include "../common/deathtypes.qh"
  31 #include "../common/effects.qh"
  32 #include "../common/mapinfo.qh"
  33 #include "../common/monsters/all.qh"
  34 #include "../common/nades.qh"
  35 #include "../common/net_notice.qh"
  36 #include "../common/notifications.qh"
  37 #include "../common/stats.qh"
  38 #include "../common/teams.qh"
  39
  40 #include "../common/items/all.qh"
  41
  42 #include "../common/mutators/base.qh"
  43
  44 #include "../common/weapons/all.qh"
  45
  46 #include "../csqcmodellib/cl_model.qh"
  47 #include "../csqcmodellib/interpolate.qh"
  48
  49 #include "../common/triggers/include.qh"
  50
  51 #include "../common/turrets/cl_turrets.qh"
  52 #include "../common/turrets/turrets.qh"
  53
  54 #include "../warpzonelib/client.qh"
  55
  56 // --------------------------------------------------------------------------
  57 // BEGIN REQUIRED CSQC FUNCTIONS
  58 //include "main.qh"
  59
  60 entity clearentity_ent;
  61 void clearentity(entity e)
  62 {
  63         if (!clearentity_ent)
  64         {
  65                 clearentity_ent = spawn();
  66                 clearentity_ent.classname = "clearentity";
  67         }
  68         int n = e.entnum;
  69         copyentity(clearentity_ent, e);
  70         e.entnum = n;
  71 }
  72
  73 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  74 void menu_show_error()
  75 {
  76         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  77 }
  78
  79 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  80 // Useful for precaching things
  81
  82 void menu_sub_null()
  83 {
  84 }
  85
  86 string forcefog;
  87 void ConsoleCommand_macro_init();
  88 void CSQC_Init(void)
  89 {
  90         prvm_language = strzone(cvar_string("prvm_language"));
  91
  92 #ifdef WATERMARK
  93         LOG_TRACEF("^4CSQC Build information: ^1%s\n", WATERMARK);
  94 #endif
  95
  96         int i;
  97
  98         binddb = db_create();
  99         tempdb = db_create();
 100         ClientProgsDB = db_load("client.db");
 101         compressShortVector_init();
 102
 103         draw_endBoldFont();
 104         menu_visible = false;
 105         menu_show = menu_show_error;
 106         menu_action = func_null;
 107
 108         for(i = 0; i < 255; ++i)
 109                 if(getplayerkeyvalue(i, "viewentity") == "")
 110                         break;
 111         maxclients = i;
 112
 113         //registercommand("hud_configure");
 114         //registercommand("hud_save");
 115         //registercommand("menu_action");
 116
 117         ConsoleCommand_macro_init();
 118
 119         registercvar("hud_usecsqc", "1");
 120         registercvar("scoreboard_columns", "default");
 121
 122         registercvar("cl_nade_type", "3");
 123         registercvar("cl_pokenade_type", "zombie");
 124
 125         registercvar("cl_jumpspeedcap_min", "");
 126         registercvar("cl_jumpspeedcap_max", "");
 127
 128         registercvar("cl_multijump", "1");
 129
 130         registercvar("cl_spawn_near_teammate", "1");
 131
 132         gametype = 0;
 133
 134         // hud_fields uses strunzone on the titles!
 135         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 136                 hud_title[i] = strzone("(null)");
 137
 138         Cmd_HUD_SetFields(0);
 139
 140         postinit = false;
 141
 142         calledhooks = 0;
 143
 144         teams = Sort_Spawn();
 145         players = Sort_Spawn();
 146
 147         GetTeam(NUM_SPECTATOR, true); // add specs first
 148
 149         // needs to be done so early because of the constants they create
 150         static_init();
 151         CALL_ACCUMULATED_FUNCTION(RegisterTurrets);
 152         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 153         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 154         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
 155
 156         initialize_minigames();
 157
 158         // precaches
 159         precache_model("null");
 160         precache_sound("misc/hit.wav");
 161         precache_sound("misc/typehit.wav");
 162
 163         generator_precache();
 164         Projectile_Precache();
 165         Hook_Precache();
 166         GibSplash_Precache();
 167         Tuba_Precache();
 168         CSQCPlayer_Precache();
 169
 170         if(autocvar_cl_reticle)
 171         {
 172                 precache_pic("gfx/reticle_normal");
 173                 // weapon reticles are precached in weapon files
 174         }
 175
 176         get_mi_min_max_texcoords(1); // try the CLEVER way first
 177         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 178         shortmapname = mi_shortname;
 179
 180         if(precache_pic(minimapname) == "")
 181         {
 182                 // but maybe we have a non-clever minimap
 183                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 184                 if(precache_pic(minimapname) == "")
 185                         minimapname = ""; // FAIL
 186                 else
 187                         get_mi_min_max_texcoords(0); // load new texcoords
 188         }
 189
 190         mi_center = (mi_min + mi_max) * 0.5;
 191         mi_scale = mi_max - mi_min;
 192         minimapname = strzone(minimapname);
 193
 194         WarpZone_Init();
 195
 196         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 197         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 198 }
 199
 200 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 201 void Shutdown(void)
 202 {
 203         WarpZone_Shutdown();
 204
 205         remove(teams);
 206         remove(players);
 207         db_close(binddb);
 208         db_close(tempdb);
 209         if(autocvar_cl_db_saveasdump)
 210                 db_dump(ClientProgsDB, "client.db");
 211         else
 212                 db_save(ClientProgsDB, "client.db");
 213         db_close(ClientProgsDB);
 214
 215         if(camera_active)
 216                 cvar_set("chase_active",ftos(chase_active_backup));
 217
 218         // unset the event chasecam's chase_active
 219         if(autocvar_chase_active < 0)
 220                 cvar_set("chase_active", "0");
 221
 222         if (!isdemo())
 223         {
 224                 if (!(calledhooks & HOOK_START))
 225                         localcmd("\n_cl_hook_gamestart nop\n");
 226                 if (!(calledhooks & HOOK_END))
 227                         localcmd("\ncl_hook_gameend\n");
 228         }
 229
 230         deactivate_minigame();
 231         HUD_MinigameMenu_Close();
 232 }
 233
 234 .float has_team;
 235 float SetTeam(entity o, int Team)
 236 {
 237         entity tm;
 238         if(teamplay)
 239         {
 240                 switch(Team)
 241                 {
 242                         case -1:
 243                         case NUM_TEAM_1:
 244                         case NUM_TEAM_2:
 245                         case NUM_TEAM_3:
 246                         case NUM_TEAM_4:
 247                                 break;
 248                         default:
 249                                 if(GetTeam(Team, false) == world)
 250                                 {
 251                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 252                                         Team = NUM_SPECTATOR;
 253                                 }
 254                                 break;
 255                 }
 256         }
 257         else
 258         {
 259                 switch(Team)
 260                 {
 261                         case -1:
 262                         case 0:
 263                                 break;
 264                         default:
 265                                 if(GetTeam(Team, false) == world)
 266                                 {
 267                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 268                                         Team = NUM_SPECTATOR;
 269                                 }
 270                                 break;
 271                 }
 272         }
 273         if(Team == -1) // leave
 274         {
 275                 if(o.has_team)
 276                 {
 277                         tm = GetTeam(o.team, false);
 278                         tm.team_size -= 1;
 279                         o.has_team = 0;
 280                         return true;
 281                 }
 282         }
 283         else
 284         {
 285                 if (!o.has_team)
 286                 {
 287                         o.team = Team;
 288                         tm = GetTeam(Team, true);
 289                         tm.team_size += 1;
 290                         o.has_team = 1;
 291                         return true;
 292                 }
 293                 else if(Team != o.team)
 294                 {
 295                         tm = GetTeam(o.team, false);
 296                         tm.team_size -= 1;
 297                         o.team = Team;
 298                         tm = GetTeam(Team, true);
 299                         tm.team_size += 1;
 300                         return true;
 301                 }
 302         }
 303         return false;
 304 }
 305
 306 void Playerchecker_Think()
 307 {SELFPARAM();
 308     int i;
 309         entity e;
 310         for(i = 0; i < maxclients; ++i)
 311         {
 312                 e = playerslots[i];
 313                 if(GetPlayerName(i) == "")
 314                 {
 315                         if(e.sort_prev)
 316                         {
 317                                 // player disconnected
 318                                 SetTeam(e, -1);
 319                                 RemovePlayer(e);
 320                                 e.sort_prev = world;
 321                                 //e.gotscores = 0;
 322                         }
 323                 }
 324                 else
 325                 {
 326                         if (!e.sort_prev)
 327                         {
 328                                 // player connected
 329                                 if (!e)
 330                                         playerslots[i] = e = spawn();
 331                                 e.sv_entnum = i;
 332                                 e.ping = 0;
 333                                 e.ping_packetloss = 0;
 334                                 e.ping_movementloss = 0;
 335                                 //e.gotscores = 0; // we might already have the scores...
 336                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 337                                 RegisterPlayer(e);
 338                                 HUD_UpdatePlayerPos(e);
 339                         }
 340                 }
 341         }
 342         self.nextthink = time + 0.2;
 343 }
 344
 345 void Porto_Init();
 346 void TrueAim_Init();
 347 void PostInit(void)
 348 {
 349         entity playerchecker;
 350         playerchecker = spawn();
 351         playerchecker.think = Playerchecker_Think;
 352         playerchecker.nextthink = time + 0.2;
 353
 354         Porto_Init();
 355         TrueAim_Init();
 356
 357         postinit = true;
 358 }
 359
 360 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 361 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 362 // All keys are in ascii.
 363 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 364 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 365 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 366 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 367 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 368 {
 369         float bSkipKey;
 370         bSkipKey = false;
 371
 372         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 373                 return true;
 374
 375         if (QuickMenu_InputEvent(bInputType, nPrimary, nSecondary))
 376                 return true;
 377
 378         if ( HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary) )
 379                 return true;
 380
 381         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 382                 return true;
 383
 384         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
 385                 return true;
 386
 387         if(menu_visible && menu_action)
 388                 if(menu_action(bInputType, nPrimary, nSecondary))
 389                         return true;
 390
 391         return bSkipKey;
 392 }
 393
 394 // END REQUIRED CSQC FUNCTIONS
 395 // --------------------------------------------------------------------------
 396
 397 // --------------------------------------------------------------------------
 398 // BEGIN OPTIONAL CSQC FUNCTIONS
 399
 400 void Ent_RemoveEntCS()
 401 {SELFPARAM();
 402         entcs_receiver[self.sv_entnum] = world;
 403 }
 404 void Ent_ReadEntCS()
 405 {SELFPARAM();
 406     int sf;
 407         InterpolateOrigin_Undo();
 408
 409         self.classname = "entcs_receiver";
 410         sf = ReadByte();
 411
 412         if(sf & 1)
 413                 self.sv_entnum = ReadByte();
 414         if(sf & 2)
 415         {
 416                 self.origin_x = ReadShort();
 417                 self.origin_y = ReadShort();
 418                 self.origin_z = ReadShort();
 419                 setorigin(self, self.origin);
 420         }
 421         if(sf & 4)
 422         {
 423                 self.angles_y = ReadByte() * 360.0 / 256;
 424                 self.angles_x = self.angles_z = 0;
 425         }
 426         if(sf & 8)
 427                 self.healthvalue = ReadByte() * 10;
 428         if(sf & 16)
 429                 self.armorvalue = ReadByte() * 10;
 430
 431         entcs_receiver[self.sv_entnum] = self;
 432         self.entremove = Ent_RemoveEntCS;
 433         self.iflags |= IFLAG_ORIGIN;
 434
 435         InterpolateOrigin_Note();
 436 }
 437
 438 void Ent_Remove();
 439
 440 void Ent_RemovePlayerScore()
 441 {SELFPARAM();
 442         if(self.owner) {
 443                 SetTeam(self.owner, -1);
 444                 self.owner.gotscores = 0;
 445                 for(int i = 0; i < MAX_SCORE; ++i) {
 446                         self.owner.(scores[i]) = 0; // clear all scores
 447                 }
 448         }
 449 }
 450
 451 void Ent_ReadPlayerScore()
 452 {SELFPARAM();
 453         int i, n;
 454         bool isNew;
 455         entity o;
 456
 457         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 458         // (no I've never heard of M-x replace-string, sed, or anything like that)
 459         isNew = !self.owner; // workaround for DP bug
 460         n = ReadByte()-1;
 461
 462 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 463         if(!isNew && n != self.sv_entnum)
 464         {
 465                 //print("A CSQC entity changed its owner!\n");
 466                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 467                 isNew = true;
 468                 Ent_Remove();
 469                 self.enttype = ENT_CLIENT_SCORES;
 470         }
 471 #endif
 472
 473         self.sv_entnum = n;
 474
 475         if (!(playerslots[self.sv_entnum]))
 476                 playerslots[self.sv_entnum] = spawn();
 477         o = self.owner = playerslots[self.sv_entnum];
 478         o.sv_entnum = self.sv_entnum;
 479         o.gotscores = 1;
 480
 481         //if (!o.sort_prev)
 482         //      RegisterPlayer(o);
 483         //playerchecker will do this for us later, if it has not already done so
 484
 485     int sf, lf;
 486 #if MAX_SCORE <= 8
 487         sf = ReadByte();
 488         lf = ReadByte();
 489 #else
 490         sf = ReadShort();
 491         lf = ReadShort();
 492 #endif
 493     int p;
 494         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 495                 if(sf & p)
 496                 {
 497                         if(lf & p)
 498                                 o.(scores[i]) = ReadInt24_t();
 499                         else
 500                                 o.(scores[i]) = ReadChar();
 501                 }
 502
 503         if(o.sort_prev)
 504                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 505
 506         self.entremove = Ent_RemovePlayerScore;
 507 }
 508
 509 void Ent_ReadTeamScore()
 510 {SELFPARAM();
 511         int i;
 512         entity o;
 513
 514         self.team = ReadByte();
 515         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 516
 517     int sf, lf;
 518 #if MAX_TEAMSCORE <= 8
 519         sf = ReadByte();
 520         lf = ReadByte();
 521 #else
 522         sf = ReadShort();
 523         lf = ReadShort();
 524 #endif
 525         int p;
 526         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 527                 if(sf & p)
 528                 {
 529                         if(lf & p)
 530                                 o.(teamscores[i]) = ReadInt24_t();
 531                         else
 532                                 o.(teamscores[i]) = ReadChar();
 533                 }
 534
 535         HUD_UpdateTeamPos(o);
 536 }
 537
 538 void Ent_ClientData()
 539 {
 540         float newspectatee_status;
 541
 542     int f = ReadByte();
 543
 544         scoreboard_showscores_force = (f & 1);
 545
 546         if(f & 2)
 547         {
 548                 newspectatee_status = ReadByte();
 549                 if(newspectatee_status == player_localnum + 1)
 550                         newspectatee_status = -1; // observing
 551         }
 552         else
 553                 newspectatee_status = 0;
 554
 555         spectatorbutton_zoom = (f & 4);
 556
 557         if(f & 8)
 558         {
 559                 angles_held_status = 1;
 560                 angles_held.x = ReadAngle();
 561                 angles_held.y = ReadAngle();
 562                 angles_held.z = 0;
 563         }
 564         else
 565                 angles_held_status = 0;
 566
 567         if(newspectatee_status != spectatee_status)
 568         {
 569                 // clear race stuff
 570                 race_laptime = 0;
 571                 race_checkpointtime = 0;
 572         }
 573         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 574         {
 575                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 576                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 577                 )
 578                         prev_p_health = -1;
 579                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 580                         prev_health = -1;
 581         }
 582         spectatee_status = newspectatee_status;
 583
 584         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 585 }
 586
 587 void Ent_Nagger()
 588 {
 589     int i, j, b, f;
 590
 591     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 592
 593         if(!(nags & 4))
 594         {
 595                 if(vote_called_vote)
 596                         strunzone(vote_called_vote);
 597                 vote_called_vote = string_null;
 598                 vote_active = 0;
 599         }
 600         else
 601         {
 602                 vote_active = 1;
 603         }
 604
 605         if(nags & 64)
 606         {
 607                 vote_yescount = ReadByte();
 608                 vote_nocount = ReadByte();
 609                 vote_needed = ReadByte();
 610                 vote_highlighted = ReadChar();
 611         }
 612
 613         if(nags & 128)
 614         {
 615                 if(vote_called_vote)
 616                         strunzone(vote_called_vote);
 617                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 618         }
 619
 620         if(nags & 1)
 621         {
 622                 for(j = 0; j < maxclients; ++j)
 623                         if(playerslots[j])
 624                                 playerslots[j].ready = 1;
 625                 for(i = 1; i <= maxclients; i += 8)
 626                 {
 627                         f = ReadByte();
 628                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 629                                 if (!(f & b))
 630                                         if(playerslots[j])
 631                                                 playerslots[j].ready = 0;
 632                 }
 633         }
 634
 635         ready_waiting = (nags & 1);
 636         ready_waiting_for_me = (nags & 2);
 637         vote_waiting = (nags & 4);
 638         vote_waiting_for_me = (nags & 8);
 639         warmup_stage = (nags & 16);
 640 }
 641
 642 void Ent_EliminatedPlayers()
 643 {
 644     int i, j, b, f;
 645
 646     int sf = ReadByte();
 647         if(sf & 1)
 648         {
 649                 for(j = 0; j < maxclients; ++j)
 650                         if(playerslots[j])
 651                                 playerslots[j].eliminated = 1;
 652                 for(i = 1; i <= maxclients; i += 8)
 653                 {
 654                         f = ReadByte();
 655                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 656                                 if (!(f & b))
 657                                         if(playerslots[j])
 658                                                 playerslots[j].eliminated = 0;
 659                 }
 660         }
 661 }
 662
 663 void Ent_RandomSeed()
 664 {
 665         float s;
 666         prandom_debug();
 667         s = ReadShort();
 668         psrandom(s);
 669 }
 670
 671 void Ent_ReadAccuracy(void)
 672 {
 673     int f, w;
 674     int sf = ReadInt24_t();
 675         if(sf == 0)
 676         {
 677                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 678                         weapon_accuracy[w] = -1;
 679                 return;
 680         }
 681
 682         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 683         {
 684                 if(sf & f)
 685                 {
 686             int b = ReadByte();
 687                         if(b == 0)
 688                                 weapon_accuracy[w] = -1;
 689                         else if(b == 255)
 690                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 691                         else
 692                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 693                 }
 694                 if(f == 0x800000)
 695                         f = 1;
 696                 else
 697                         f *= 2;
 698         }
 699 }
 700
 701 void Spawn_Draw(void)
 702 {SELFPARAM();
 703         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 704 }
 705
 706 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 707 {SELFPARAM();
 708         float teamnum = (ReadByte() - 1);
 709         vector spn_origin;
 710         spn_origin.x = ReadShort();
 711         spn_origin.y = ReadShort();
 712         spn_origin.z = ReadShort();
 713
 714         if(is_new)
 715         {
 716                 self.origin = spn_origin;
 717                 setsize(self, PL_MIN_CONST, PL_MAX_CONST);
 718                 droptofloor();
 719
 720                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 721                 {
 722                         self.mdl = "models/spawnpoint.md3";
 723                         self.colormod = Team_ColorRGB(teamnum);
 724                         precache_model(self.mdl);
 725                         setmodel(self, self.mdl);
 726                         self.drawmask = MASK_NORMAL;
 727                         //self.movetype = MOVETYPE_NOCLIP;
 728                         //self.draw = Spawn_Draw;
 729                 }*/
 730                 if(autocvar_cl_spawn_point_particles)
 731                 {
 732                         if((serverflags & SERVERFLAG_TEAMPLAY))
 733                         {
 734                                 switch(teamnum)
 735                                 {
 736                                         case NUM_TEAM_1: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
 737                                         case NUM_TEAM_2: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
 738                                         case NUM_TEAM_3: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
 739                                         case NUM_TEAM_4: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
 740                                         default: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
 741                                 }
 742                         }
 743                         else { self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
 744
 745                         self.draw = Spawn_Draw;
 746                 }
 747         }
 748
 749         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 750 }
 751
 752 void Ent_ReadSpawnEvent(float is_new)
 753 {SELFPARAM();
 754         // If entnum is 0, ONLY do the local spawn actions
 755         // this way the server can disable the sending of
 756         // spawn origin or such to clients if wanted.
 757         float entnum = ReadByte();
 758
 759         if(entnum)
 760         {
 761                 self.origin_x = ReadShort();
 762                 self.origin_y = ReadShort();
 763                 self.origin_z = ReadShort();
 764
 765                 if(is_new)
 766                 {
 767                         float teamnum = GetPlayerColor(entnum - 1);
 768
 769                         if(autocvar_cl_spawn_event_particles)
 770                         {
 771                                 switch(teamnum)
 772                                 {
 773                                         case NUM_TEAM_1: pointparticles(particleeffectnum(EFFECT_SPAWN_RED), self.origin, '0 0 0', 1); break;
 774                                         case NUM_TEAM_2: pointparticles(particleeffectnum(EFFECT_SPAWN_BLUE), self.origin, '0 0 0', 1); break;
 775                                         case NUM_TEAM_3: pointparticles(particleeffectnum(EFFECT_SPAWN_YELLOW), self.origin, '0 0 0', 1); break;
 776                                         case NUM_TEAM_4: pointparticles(particleeffectnum(EFFECT_SPAWN_PINK), self.origin, '0 0 0', 1); break;
 777                                         default: pointparticles(particleeffectnum(EFFECT_SPAWN_NEUTRAL), self.origin, '0 0 0', 1); break;
 778                                 }
 779                         }
 780                         if(autocvar_cl_spawn_event_sound)
 781                         {
 782                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
 783                         }
 784                 }
 785         }
 786
 787         // local spawn actions
 788         if(is_new && (!entnum || (entnum == player_localentnum)))
 789         {
 790                 zoomin_effect = 1;
 791                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 792
 793                 if(autocvar_cl_unpress_zoom_on_spawn)
 794                 {
 795                         localcmd("-zoom\n");
 796                         button_zoom = false;
 797                 }
 798         }
 799         HUD_Radar_Hide_Maximized();
 800         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 801 }
 802
 803 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 804 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 805 void Ent_RadarLink();
 806 void Ent_Init();
 807 void Ent_ScoresInfo();
 808 void CSQC_Ent_Update(float bIsNewEntity)
 809 {SELFPARAM();
 810         float t;
 811         float savetime;
 812         t = ReadByte();
 813
 814         if(autocvar_developer_csqcentities)
 815                 LOG_INFOF("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 816
 817         // set up the "time" global for received entities to be correct for interpolation purposes
 818         savetime = time;
 819         if(servertime)
 820         {
 821                 time = servertime;
 822         }
 823         else
 824         {
 825                 serverprevtime = time;
 826                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 827                 time = serverprevtime + serverdeltatime;
 828         }
 829
 830 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 831         if(self.enttype)
 832         {
 833                 if(t != self.enttype || bIsNewEntity)
 834                 {
 835                         //print("A CSQC entity changed its type!\n");
 836                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 837                         Ent_Remove();
 838                         clearentity(self);
 839                         bIsNewEntity = 1;
 840                 }
 841         }
 842         else
 843         {
 844                 if(!bIsNewEntity)
 845                 {
 846                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 847                         bIsNewEntity = 1;
 848                 }
 849         }
 850 #endif
 851         self.enttype = t;
 852         switch(t)
 853         {
 854                 case ENT_CLIENT_MUTATOR: {
 855                         int mutID = ReadMutator();
 856                         if (!MUTATOR_CALLHOOK(CSQC_Ent_Update, mutID, bIsNewEntity))
 857                         error(sprintf("Unknown mutator type in CSQC_Ent_Update (mutID: %d, edict: %d, classname: %s)\n", mutID, num_for_edict(self), self.classname));
 858                         break;
 859                 }
 860                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 861                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 862                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 863                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 864                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 865                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 866                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 867                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
 868                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 869                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 870                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 871                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 872                 case ENT_CLIENT_INIT: Ent_Init(); break;
 873                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 874                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 875                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 876                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 877                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 878                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 879                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 880                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 881                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 882                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 883                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 884                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 885                 case ENT_CLIENT_INVENTORY: Inventory_Read(self); break;
 886                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
 887                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 888                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 889                 case ENT_CLIENT_TURRET: ent_turret(); break;
 890                 case ENT_CLIENT_GENERATOR: ent_generator(); break;
 891                 case ENT_CLIENT_CONTROLPOINT_ICON: ent_cpicon(); break;
 892                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 893                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 894                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 895                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 896                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 897                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 898                 case ENT_CLIENT_HEALING_ORB: ent_healer(); break;
 899                 case ENT_CLIENT_MINIGAME: ent_read_minigame(); break;
 900                 case ENT_CLIENT_VIEWLOC: ent_viewloc(); break;
 901                 case ENT_CLIENT_VIEWLOC_TRIGGER: ent_viewloc_trigger(); break;
 902                 case ENT_CLIENT_LADDER: ent_func_ladder(); break;
 903                 case ENT_CLIENT_TRIGGER_PUSH: ent_trigger_push(); break;
 904                 case ENT_CLIENT_TARGET_PUSH: ent_target_push(); break;
 905                 case ENT_CLIENT_CONVEYOR: ent_conveyor(); break;
 906                 case ENT_CLIENT_DOOR: ent_door(); break;
 907                 case ENT_CLIENT_PLAT: ent_plat(); break;
 908                 case ENT_CLIENT_SWAMP: ent_swamp(); break;
 909                 case ENT_CLIENT_CORNER: ent_corner(); break;
 910                 case ENT_CLIENT_KEYLOCK: ent_keylock(); break;
 911                 case ENT_CLIENT_TRAIN: ent_train(); break;
 912                 case ENT_CLIENT_TRIGGER_IMPULSE: ent_trigger_impulse(); break;
 913                 case ENT_CLIENT_EFFECT: Read_Effect(bIsNewEntity); break;
 914
 915                 default:
 916                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 917                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
 918                         break;
 919         }
 920
 921         time = savetime;
 922 }
 923 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 924 // used when an entity changes its type. For an entity that someone interacts
 925 // with others, make sure it can no longer do so.
 926 void Ent_Remove()
 927 {SELFPARAM();
 928         if(self.entremove)
 929                 self.entremove();
 930
 931         if(self.skeletonindex)
 932         {
 933                 skel_delete(self.skeletonindex);
 934                 self.skeletonindex = 0;
 935         }
 936
 937         if(self.snd_looping > 0)
 938         {
 939                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 940                 self.snd_looping = 0;
 941         }
 942
 943         self.enttype = 0;
 944         self.classname = "";
 945         self.draw = menu_sub_null;
 946         self.entremove = menu_sub_null;
 947         // TODO possibly set more stuff to defaults
 948 }
 949 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 950 void CSQC_Ent_Remove()
 951 {SELFPARAM();
 952         if(autocvar_developer_csqcentities)
 953                 LOG_INFOF("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 954
 955         if(wasfreed(self))
 956         {
 957                 LOG_INFO("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 958                 return;
 959         }
 960         if(self.enttype)
 961                 Ent_Remove();
 962         remove(self);
 963 }
 964
 965 void Gamemode_Init()
 966 {
 967         if (!isdemo())
 968         {
 969                 if(!(calledhooks & HOOK_START))
 970                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 971                 calledhooks |= HOOK_START;
 972         }
 973 }
 974 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 975 void CSQC_Parse_StuffCmd(string strMessage)
 976 {
 977         if(autocvar_developer_csqcentities)
 978                 LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 979
 980         localcmd(strMessage);
 981 }
 982 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 983 void CSQC_Parse_Print(string strMessage)
 984 {
 985         if(autocvar_developer_csqcentities)
 986                 LOG_INFOF("CSQC_Parse_Print(\"%s\")\n", strMessage);
 987
 988         LOG_INFO(ColorTranslateRGB(strMessage));
 989 }
 990
 991 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 992 void CSQC_Parse_CenterPrint(string strMessage)
 993 {
 994         if(autocvar_developer_csqcentities)
 995                 LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 996
 997         centerprint_hud(strMessage);
 998 }
 999
1000 string notranslate_fogcmd1 = "\nfog ";
1001 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
1002 void Fog_Force()
1003 {
1004         // TODO somehow thwart prvm_globalset client ...
1005
1006         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
1007                 { localcmd("\nr_drawfog 0\n"); }
1008         else if(forcefog != "")
1009                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
1010 }
1011
1012 void Gamemode_Init();
1013 void Ent_ScoresInfo()
1014 {SELFPARAM();
1015     int i;
1016         self.classname = "ent_client_scores_info";
1017         gametype = ReadInt24_t();
1018         HUD_ModIcons_SetFunc();
1019         for(i = 0; i < MAX_SCORE; ++i)
1020         {
1021                 if(scores_label[i])
1022                         strunzone(scores_label[i]);
1023                 scores_label[i] = strzone(ReadString());
1024                 scores_flags[i] = ReadByte();
1025         }
1026         for(i = 0; i < MAX_TEAMSCORE; ++i)
1027         {
1028                 if(teamscores_label[i])
1029                         strunzone(teamscores_label[i]);
1030                 teamscores_label[i] = strzone(ReadString());
1031                 teamscores_flags[i] = ReadByte();
1032         }
1033         HUD_InitScores();
1034         Gamemode_Init();
1035 }
1036
1037 void Ent_Init()
1038 {SELFPARAM();
1039         self.classname = "ent_client_init";
1040
1041         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1042
1043         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1044         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1045         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1046         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1047         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1048         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1049         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1050         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1051
1052         if(forcefog)
1053                 strunzone(forcefog);
1054         forcefog = strzone(ReadString());
1055
1056         armorblockpercent = ReadByte() / 255.0;
1057
1058         g_balance_mortar_bouncefactor = ReadCoord();
1059         g_balance_mortar_bouncestop = ReadCoord();
1060         g_balance_electro_secondary_bouncefactor = ReadCoord();
1061         g_balance_electro_secondary_bouncestop = ReadCoord();
1062
1063         vortex_scope = !ReadByte();
1064         rifle_scope = !ReadByte();
1065
1066         serverflags = ReadByte();
1067
1068         minelayer_maxmines = ReadByte();
1069
1070         hagar_maxrockets = ReadByte();
1071
1072         g_trueaim_minrange = ReadCoord();
1073         g_balance_porto_secondary = ReadByte();
1074
1075         if(!postinit)
1076                 PostInit();
1077 }
1078
1079 void Net_ReadRace()
1080 {
1081         float b;
1082
1083         b = ReadByte();
1084
1085         switch(b)
1086         {
1087                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1088                         race_checkpoint = ReadByte();
1089                         race_time = ReadInt24_t();
1090                         race_previousbesttime = ReadInt24_t();
1091                         if(race_previousbestname)
1092                                 strunzone(race_previousbestname);
1093                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1094
1095                         race_checkpointtime = time;
1096
1097                         if(race_checkpoint == 0 || race_checkpoint == 254)
1098                         {
1099                                 race_penaltyaccumulator = 0;
1100                                 race_laptime = time; // valid
1101                         }
1102
1103                         break;
1104
1105                 case RACE_NET_CHECKPOINT_CLEAR:
1106                         race_laptime = 0;
1107                         race_checkpointtime = 0;
1108                         break;
1109
1110                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1111                         race_laptime = ReadCoord();
1112                         race_checkpointtime = -99999;
1113                         // fall through
1114                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1115                         race_nextcheckpoint = ReadByte();
1116
1117                         race_nextbesttime = ReadInt24_t();
1118                         if(race_nextbestname)
1119                                 strunzone(race_nextbestname);
1120                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1121                         break;
1122
1123                 case RACE_NET_CHECKPOINT_HIT_RACE:
1124                         race_mycheckpoint = ReadByte();
1125                         race_mycheckpointtime = time;
1126                         race_mycheckpointdelta = ReadInt24_t();
1127                         race_mycheckpointlapsdelta = ReadByte();
1128                         if(race_mycheckpointlapsdelta >= 128)
1129                                 race_mycheckpointlapsdelta -= 256;
1130                         if(race_mycheckpointenemy)
1131                                 strunzone(race_mycheckpointenemy);
1132                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1133                         break;
1134
1135                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1136                         race_othercheckpoint = ReadByte();
1137                         race_othercheckpointtime = time;
1138                         race_othercheckpointdelta = ReadInt24_t();
1139                         race_othercheckpointlapsdelta = ReadByte();
1140                         if(race_othercheckpointlapsdelta >= 128)
1141                                 race_othercheckpointlapsdelta -= 256;
1142                         if(race_othercheckpointenemy)
1143                                 strunzone(race_othercheckpointenemy);
1144                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1145                         break;
1146
1147                 case RACE_NET_PENALTY_RACE:
1148                         race_penaltyeventtime = time;
1149                         race_penaltytime = ReadShort();
1150                         //race_penaltyaccumulator += race_penaltytime;
1151                         if(race_penaltyreason)
1152                                 strunzone(race_penaltyreason);
1153                         race_penaltyreason = strzone(ReadString());
1154                         break;
1155
1156                 case RACE_NET_PENALTY_QUALIFYING:
1157                         race_penaltyeventtime = time;
1158                         race_penaltytime = ReadShort();
1159                         race_penaltyaccumulator += race_penaltytime;
1160                         if(race_penaltyreason)
1161                                 strunzone(race_penaltyreason);
1162                         race_penaltyreason = strzone(ReadString());
1163                         break;
1164
1165                 case RACE_NET_SERVER_RECORD:
1166                         race_server_record = ReadInt24_t();
1167                         break;
1168                 case RACE_NET_SPEED_AWARD:
1169                         race_speedaward = ReadInt24_t();
1170                         if(race_speedaward_holder)
1171                                 strunzone(race_speedaward_holder);
1172                         race_speedaward_holder = strzone(ReadString());
1173                         break;
1174                 case RACE_NET_SPEED_AWARD_BEST:
1175                         race_speedaward_alltimebest = ReadInt24_t();
1176                         if(race_speedaward_alltimebest_holder)
1177                                 strunzone(race_speedaward_alltimebest_holder);
1178                         race_speedaward_alltimebest_holder = strzone(ReadString());
1179                         break;
1180                 case RACE_NET_SERVER_RANKINGS:
1181                         float prevpos, del;
1182             int pos = ReadShort();
1183                         prevpos = ReadShort();
1184                         del = ReadShort();
1185
1186                         // move other rankings out of the way
1187             int i;
1188                         if (prevpos) {
1189                                 for (i=prevpos-1;i>pos-1;--i) {
1190                                         grecordtime[i] = grecordtime[i-1];
1191                                         if(grecordholder[i])
1192                                                 strunzone(grecordholder[i]);
1193                                         grecordholder[i] = strzone(grecordholder[i-1]);
1194                                 }
1195                         } else if (del) { // a record has been deleted by the admin
1196                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1197                                         if (i == RANKINGS_CNT-1) { // clear out last record
1198                                                 grecordtime[i] = 0;
1199                                                 if (grecordholder[i])
1200                                                         strunzone(grecordholder[i]);
1201                                                 grecordholder[i] = string_null;
1202                                         }
1203                                         else {
1204                                                 grecordtime[i] = grecordtime[i+1];
1205                                                 if (grecordholder[i])
1206                                                         strunzone(grecordholder[i]);
1207                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1208                                         }
1209                                 }
1210                         } else { // player has no ranked record yet
1211                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1212                                         grecordtime[i] = grecordtime[i-1];
1213                                         if(grecordholder[i])
1214                                                 strunzone(grecordholder[i]);
1215                                         grecordholder[i] = strzone(grecordholder[i-1]);
1216                                 }
1217                         }
1218
1219                         // store new ranking
1220                         if(grecordholder[pos-1] != "")
1221                                 strunzone(grecordholder[pos-1]);
1222                         grecordholder[pos-1] = strzone(ReadString());
1223                         grecordtime[pos-1] = ReadInt24_t();
1224                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1225                                 race_myrank = pos;
1226                         break;
1227                 case RACE_NET_SERVER_STATUS:
1228                         race_status = ReadShort();
1229                         if(race_status_name)
1230                                 strunzone(race_status_name);
1231                         race_status_name = strzone(ReadString());
1232         }
1233 }
1234
1235 void Net_TeamNagger()
1236 {
1237         teamnagger = 1;
1238 }
1239
1240 void Net_ReadPingPLReport()
1241 {
1242         int e, pi, pl, ml;
1243         e = ReadByte();
1244         pi = ReadShort();
1245         pl = ReadByte();
1246         ml = ReadByte();
1247         if (!(playerslots[e]))
1248                 return;
1249         playerslots[e].ping = pi;
1250         playerslots[e].ping_packetloss = pl / 255.0;
1251         playerslots[e].ping_movementloss = ml / 255.0;
1252 }
1253
1254 void Net_WeaponComplain()
1255 {
1256         complain_weapon = ReadByte();
1257
1258         if(complain_weapon_name)
1259                 strunzone(complain_weapon_name);
1260         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1261
1262         complain_weapon_type = ReadByte();
1263
1264         complain_weapon_time = time;
1265         weapontime = time; // ping the weapon panel
1266
1267         switch(complain_weapon_type)
1268         {
1269                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1270                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1271                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1272         }
1273 }
1274
1275 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1276 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1277 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1278 float CSQC_Parse_TempEntity()
1279 {
1280         // Acquire TE ID
1281         int nTEID = ReadByte();
1282
1283         if (autocvar_developer_csqcentities)
1284                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1285
1286         switch (nTEID)
1287         {
1288                 case TE_CSQC_MUTATOR:
1289                         int mutID = ReadMutator();
1290                         if (MUTATOR_CALLHOOK(CSQC_Parse_TempEntity, mutID))
1291                         return true;
1292                 case TE_CSQC_TARGET_MUSIC:
1293                         Net_TargetMusic();
1294                         return true;
1295                 case TE_CSQC_PICTURE:
1296                         Net_MapVote_Picture();
1297                         return true;
1298                 case TE_CSQC_RACE:
1299                         Net_ReadRace();
1300                         return true;
1301                 case TE_CSQC_VORTEXBEAMPARTICLE:
1302                         Net_ReadVortexBeamParticle();
1303                         return true;
1304                 case TE_CSQC_TEAMNAGGER:
1305                         Net_TeamNagger();
1306                         return true;
1307                 case TE_CSQC_ARC:
1308                         Net_ReadArc();
1309                         return true;
1310                 case TE_CSQC_PINGPLREPORT:
1311                         Net_ReadPingPLReport();
1312                         return true;
1313                 case TE_CSQC_WEAPONCOMPLAIN:
1314                         Net_WeaponComplain();
1315                         return true;
1316                 case TE_CSQC_VEHICLESETUP:
1317                         Net_VehicleSetup();
1318                         return true;
1319                 case TE_CSQC_SVNOTICE:
1320                         cl_notice_read();
1321                         return true;
1322                 case TE_CSQC_SHOCKWAVEPARTICLE:
1323                         Net_ReadShockwaveParticle();
1324                         return true;
1325                 default:
1326                         // No special logic for this temporary entity; return 0 so the engine can handle it
1327                         return false;
1328         }
1329 }
1330
1331 string getcommandkey(string text, string command)
1332 {
1333         string keys;
1334         float n, j, k, l = 0;
1335
1336         if (!autocvar_hud_showbinds)
1337                 return text;
1338
1339         keys = db_get(binddb, command);
1340         if (keys == "")
1341         {
1342                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1343                 for(j = 0; j < n; ++j)
1344                 {
1345                         k = stof(argv(j));
1346                         if(k != -1)
1347                         {
1348                                 if ("" == keys)
1349                                         keys = keynumtostring(k);
1350                                 else
1351                                         keys = strcat(keys, ", ", keynumtostring(k));
1352
1353                                 ++l;
1354                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1355                                         break;
1356                         }
1357
1358                 }
1359                 if (keys == "")
1360                         keys = "NO_KEY";
1361                 db_put(binddb, command, keys);
1362         }
1363
1364         if (keys == "NO_KEY") {
1365                 if (autocvar_hud_showbinds > 1)
1366                         return sprintf(_("%s (not bound)"), text);
1367                 else
1368                         return text;
1369         }
1370         else if (autocvar_hud_showbinds > 1)
1371                 return sprintf("%s (%s)", text, keys);
1372         else
1373                 return keys;
1374 }