qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include "defs.qh"
   4 #include <common/ent_cs.qh>
   5 #include "miscfunctions.qh"
   6 #include <common/effects/effect.qh>
   7 #include <common/effects/qc/_mod.qh>
   8 #include <common/effects/all.qh>
   9 #include <common/effects/all.inc>
  10 #include "hud/_mod.qh"
  11 #include "mapvoting.qh"
  12 #include "mutators/events.qh"
  13 #include "hud/panel/scoreboard.qh"
  14 #include "hud/panel/quickmenu.qh"
  15 #include "shownames.qh"
  16 #include <common/t_items.qh>
  17 #include "wall.qh"
  18 #include "weapons/projectile.qh"
  19 #include <common/deathtypes/all.qh>
  20 #include <common/items/_mod.qh>
  21 #include <common/mapinfo.qh>
  22 #include <common/minigames/cl_minigames.qh>
  23 #include <common/minigames/cl_minigames_hud.qh>
  24 #include <common/net_linked.qh>
  25 #include <common/net_notice.qh>
  26 #include <common/scores.qh>
  27 #include <common/triggers/include.qh>
  28 #include <common/vehicles/all.qh>
  29 #include <lib/csqcmodel/cl_model.qh>
  30 #include <lib/csqcmodel/interpolate.qh>
  31 #include <lib/warpzone/client.qh>
  32
  33 // --------------------------------------------------------------------------
  34 // BEGIN REQUIRED CSQC FUNCTIONS
  35 //include "main.qh"
  36
  37 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  38
  39 void draw_cursor(vector pos, vector ofs, string img, vector col, float a)
  40 {
  41         ofs = vec2(ofs.x * SIZE_CURSOR.x, ofs.y * SIZE_CURSOR.y);
  42         drawpic(pos - ofs, strcat(draw_currentSkin, img), SIZE_CURSOR, col, a, DRAWFLAG_NORMAL);
  43 }
  44
  45 void draw_cursor_normal(vector pos, vector col, float a)
  46 {
  47         draw_cursor(pos, OFFSET_CURSOR, "/cursor", col, a);
  48 }
  49
  50 void LoadMenuSkinValues()
  51 {
  52         int fh = -1;
  53         if(cvar_string("menu_skin") != "")
  54         {
  55                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  56                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  57         }
  58         if(fh < 0 && cvar_defstring("menu_skin") != "")
  59         {
  60                 cvar_set("menu_skin", cvar_defstring("menu_skin"));
  61                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  62                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  63         }
  64         if(fh < 0)
  65         {
  66                 draw_currentSkin = "gfx/menu/default";
  67                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  68         }
  69
  70         draw_currentSkin = strzone(draw_currentSkin);
  71
  72         if(fh >= 0)
  73         {
  74                 string s;
  75                 while((s = fgets(fh)))
  76                 {
  77                         int n = tokenize_console(s);
  78                         if (n < 2)
  79                                 continue;
  80                         if(substring(argv(0), 0, 2) == "//")
  81                                 continue;
  82                         if(argv(0) == "SIZE_CURSOR")
  83                                 SIZE_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  84                         else if(argv(0) == "OFFSET_CURSOR")
  85                                 OFFSET_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  86                 }
  87                 fclose(fh);
  88         }
  89 }
  90
  91 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  92 // Useful for precaching things
  93
  94 void ConsoleCommand_macro_init();
  95 void CSQC_Init()
  96 {
  97         prvm_language = strzone(cvar_string("prvm_language"));
  98
  99 #ifdef WATERMARK
 100         LOG_INFOF("^4CSQC Build information: ^1%s", WATERMARK);
 101 #endif
 102
 103         {
 104                 int i = 0;
 105                 for ( ; i < 255; ++i)
 106                         if (getplayerkeyvalue(i, "viewentity") == "")
 107                                 break;
 108                 maxclients = i;
 109         }
 110
 111         // needs to be done so early because of the constants they create
 112         static_init();
 113         static_init_late();
 114         static_init_precache();
 115
 116         binddb = db_create();
 117         tempdb = db_create();
 118         ClientProgsDB = db_load("client.db");
 119
 120         draw_endBoldFont();
 121
 122         //registercommand("hud_configure");
 123         //registercommand("hud_save");
 124         //registercommand("menu_action");
 125
 126         ConsoleCommand_macro_init();
 127
 128         registercvar("hud_usecsqc", "1");
 129         registercvar("scoreboard_columns", "default");
 130
 131         registercvar("cl_nade_type", "3");
 132         registercvar("cl_pokenade_type", "zombie");
 133
 134         registercvar("cl_jumpspeedcap_min", "");
 135         registercvar("cl_jumpspeedcap_max", "");
 136
 137         registercvar("cl_multijump", "1");
 138
 139         registercvar("cl_spawn_near_teammate", "1");
 140
 141         if(autocvar_cl_lockview)
 142                 cvar_set("cl_lockview", "0");
 143
 144         gametype = NULL;
 145
 146         postinit = false;
 147
 148         calledhooks = 0;
 149
 150         teams = Sort_Spawn();
 151         players = Sort_Spawn();
 152
 153         GetTeam(NUM_SPECTATOR, true); // add specs first
 154
 155         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 156                 weapon_accuracy[w] = -1;
 157
 158         // precaches
 159
 160         if(autocvar_cl_reticle)
 161         {
 162                 precache_pic("gfx/reticle_normal");
 163                 // weapon reticles are precached in weapon files
 164         }
 165
 166         {
 167                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 168                 minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 169                 shortmapname = mi_shortname;
 170
 171                 if (precache_pic(minimapname) == "")
 172                 {
 173                         // but maybe we have a non-clever minimap
 174                         minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 175                         if (precache_pic(minimapname) == "")
 176                                 minimapname = ""; // FAIL
 177                         else
 178                                 get_mi_min_max_texcoords(0); // load new texcoords
 179                 }
 180
 181                 mi_center = (mi_min + mi_max) * 0.5;
 182                 mi_scale = mi_max - mi_min;
 183                 minimapname = strzone(minimapname);
 184         }
 185
 186         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 187         LoadMenuSkinValues();
 188 }
 189
 190 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 191 void Shutdown()
 192 {
 193         WarpZone_Shutdown();
 194
 195         delete(teams);
 196         delete(players);
 197         db_close(binddb);
 198         db_close(tempdb);
 199         if(autocvar_cl_db_saveasdump)
 200                 db_dump(ClientProgsDB, "client.db");
 201         else
 202                 db_save(ClientProgsDB, "client.db");
 203         db_close(ClientProgsDB);
 204
 205         if(camera_active)
 206                 cvar_set("chase_active",ftos(chase_active_backup));
 207
 208         // unset the event chasecam's chase_active
 209         if(autocvar_chase_active < 0)
 210                 cvar_set("chase_active", "0");
 211
 212         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 213
 214         if (!isdemo())
 215         {
 216                 if (!(calledhooks & HOOK_START))
 217                         localcmd("\n_cl_hook_gamestart nop\n");
 218                 if (!(calledhooks & HOOK_END))
 219                         localcmd("\ncl_hook_gameend\n");
 220         }
 221
 222         localcmd("\ncl_hook_shutdown\n");
 223
 224         deactivate_minigame();
 225         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 226 }
 227
 228 .float has_team;
 229 float SetTeam(entity o, int Team)
 230 {
 231     TC(int, Team);
 232         devassert_once(Team);
 233         entity tm;
 234         if(teamplay)
 235         {
 236                 switch(Team)
 237                 {
 238                         case -1:
 239                         case NUM_TEAM_1:
 240                         case NUM_TEAM_2:
 241                         case NUM_TEAM_3:
 242                         case NUM_TEAM_4:
 243                                 break;
 244                         default:
 245                                 if(GetTeam(Team, false) == NULL)
 246                                 {
 247                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 248                                         Team = NUM_SPECTATOR;
 249                                 }
 250                                 break;
 251                 }
 252         }
 253         else
 254         {
 255                 switch(Team)
 256                 {
 257                         case -1:
 258                         case 0:
 259                                 break;
 260                         default:
 261                                 if(GetTeam(Team, false) == NULL)
 262                                 {
 263                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 264                                         Team = NUM_SPECTATOR;
 265                                 }
 266                                 break;
 267                 }
 268         }
 269         if(Team == -1) // leave
 270         {
 271                 if(o.has_team)
 272                 {
 273                         tm = GetTeam(o.team, false);
 274                         tm.team_size -= 1;
 275                         o.has_team = 0;
 276                         return true;
 277                 }
 278         }
 279         else
 280         {
 281                 if (!o.has_team)
 282                 {
 283                         o.team = Team;
 284                         tm = GetTeam(Team, true);
 285                         tm.team_size += 1;
 286                         o.has_team = 1;
 287                         return true;
 288                 }
 289                 else if(Team != o.team)
 290                 {
 291                         tm = GetTeam(o.team, false);
 292                         tm.team_size -= 1;
 293                         o.team = Team;
 294                         tm = GetTeam(Team, true);
 295                         tm.team_size += 1;
 296                         return true;
 297                 }
 298         }
 299         return false;
 300 }
 301
 302 void Playerchecker_Think(entity this)
 303 {
 304     int i;
 305         entity e;
 306         for(i = 0; i < maxclients; ++i)
 307         {
 308                 e = playerslots[i];
 309                 if(entcs_GetName(i) == "")
 310                 {
 311                         if(e.sort_prev)
 312                         {
 313                                 // player disconnected
 314                                 SetTeam(e, -1);
 315                                 RemovePlayer(e);
 316                                 e.sort_prev = NULL;
 317                                 //e.gotscores = 0;
 318                         }
 319                 }
 320                 else
 321                 {
 322                         if (!e.sort_prev)
 323                         {
 324                                 // player connected
 325                                 if (!e)
 326                                 {
 327                                         playerslots[i] = e = new_pure(playerslot);
 328                                 }
 329                                 e.sv_entnum = i;
 330                                 e.ping = 0;
 331                                 e.ping_packetloss = 0;
 332                                 e.ping_movementloss = 0;
 333                                 //e.gotscores = 0; // we might already have the scores...
 334                                 int t = entcs_GetScoreTeam(i);
 335                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 336                                 RegisterPlayer(e);
 337                                 Scoreboard_UpdatePlayerPos(e);
 338                         }
 339                 }
 340         }
 341         this.nextthink = time + 0.2;
 342 }
 343
 344 void TrueAim_Init();
 345 void PostInit()
 346 {
 347         entity playerchecker = new_pure(playerchecker);
 348         setthink(playerchecker, Playerchecker_Think);
 349         playerchecker.nextthink = time + 0.2;
 350
 351         TrueAim_Init();
 352
 353         postinit = true;
 354 }
 355
 356 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 357 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 358 // All keys are in ascii.
 359 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 360 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 361 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 362 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 363 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 364 {
 365     TC(int, bInputType);
 366         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 367                 return true;
 368
 369         if (QuickMenu_InputEvent(bInputType, nPrimary, nSecondary))
 370                 return true;
 371
 372         if (HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary))
 373                 return true;
 374
 375         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 376                 return true;
 377
 378         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
 379                 return true;
 380
 381         return false;
 382 }
 383
 384 // END REQUIRED CSQC FUNCTIONS
 385 // --------------------------------------------------------------------------
 386
 387 // --------------------------------------------------------------------------
 388 // BEGIN OPTIONAL CSQC FUNCTIONS
 389
 390 void Ent_Remove(entity this);
 391
 392 void Ent_RemovePlayerScore(entity this)
 393 {
 394         if(this.owner) {
 395                 SetTeam(this.owner, -1);
 396                 this.owner.gotscores = 0;
 397                 FOREACH(Scores, true, {
 398                         this.owner.(scores(it)) = 0; // clear all scores
 399                 });
 400         }
 401 }
 402
 403 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 404 {
 405         make_pure(this);
 406         entity o;
 407
 408         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 409         // (no I've never heard of M-x replace-string, sed, or anything like that)
 410         bool isNew = !this.owner; // workaround for DP bug
 411         int n = ReadByte()-1;
 412
 413 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 414         if(!isNew && n != this.sv_entnum)
 415         {
 416                 //print("A CSQC entity changed its owner!\n");
 417                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
 418                 isNew = true;
 419                 Ent_Remove(this);
 420         }
 421 #endif
 422
 423         this.sv_entnum = n;
 424
 425         o = playerslots[this.sv_entnum];
 426         if (!o)
 427         {
 428                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 429         }
 430         this.owner = o;
 431         o.sv_entnum = this.sv_entnum;
 432         o.gotscores = 1;
 433
 434         //if (!o.sort_prev)
 435         //      RegisterPlayer(o);
 436         //playerchecker will do this for us later, if it has not already done so
 437
 438         int sf = ReadShort();
 439         int lf = ReadShort();
 440         FOREACH(Scores, true, {
 441                 int p = 1 << (i % 16);
 442                 if (sf & p)
 443                 {
 444                         if (lf & p)
 445                                 o.(scores(it)) = ReadInt24_t();
 446                         else
 447                                 o.(scores(it)) = ReadChar();
 448                 }
 449         });
 450
 451         return = true;
 452
 453         if(o.sort_prev)
 454                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 455
 456         this.entremove = Ent_RemovePlayerScore;
 457 }
 458
 459 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 460 {
 461         make_pure(this);
 462         int i;
 463
 464         this.team = ReadByte();
 465         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 466
 467 #if MAX_TEAMSCORE <= 8
 468         int sf = ReadByte();
 469         int lf = ReadByte();
 470 #else
 471         int sf = ReadShort();
 472         int lf = ReadShort();
 473 #endif
 474         for(i = 0; i < MAX_TEAMSCORE; ++i)
 475                 if(sf & BIT(i))
 476                 {
 477                         if(lf & BIT(i))
 478                                 o.(teamscores(i)) = ReadInt24_t();
 479                         else
 480                                 o.(teamscores(i)) = ReadChar();
 481                 }
 482
 483         return = true;
 484
 485         Scoreboard_UpdateTeamPos(o);
 486 }
 487
 488 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 489 {
 490         make_pure(this);
 491         float newspectatee_status;
 492
 493         int f = ReadByte();
 494
 495         scoreboard_showscores_force = (f & BIT(0));
 496
 497         if(f & BIT(1))
 498         {
 499                 newspectatee_status = ReadByte();
 500                 if(newspectatee_status == player_localnum + 1)
 501                         newspectatee_status = -1; // observing
 502         }
 503         else
 504                 newspectatee_status = 0;
 505
 506         spectatorbutton_zoom = (f & BIT(2));
 507
 508         if(f & BIT(4))
 509         {
 510                 num_spectators = ReadByte();
 511
 512                 float i, slot;
 513
 514                 for(i = 0; i < MAX_SPECTATORS; ++i)
 515                         spectatorlist[i] = 0; // reset list first
 516
 517                 for(i = 0; i < num_spectators; ++i)
 518                 {
 519                         slot = ReadByte();
 520                         spectatorlist[i] = slot - 1;
 521                 }
 522         }
 523
 524         return = true;
 525
 526         if(newspectatee_status != spectatee_status)
 527         {
 528                 // clear race stuff
 529                 race_laptime = 0;
 530                 race_checkpointtime = 0;
 531                 hud_dynamic_shake_factor = -1;
 532         }
 533         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 534         {
 535                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 536                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 537                 )
 538                         prev_p_health = -1;
 539                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 540                         prev_health = -1;
 541         }
 542         spectatee_status = newspectatee_status;
 543
 544         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 545 }
 546
 547 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 548 {
 549         make_pure(this);
 550         int i, j, b, f;
 551
 552         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 553
 554         if(!(nags & BIT(2)))
 555         {
 556                 if(vote_called_vote)
 557                         strunzone(vote_called_vote);
 558                 vote_called_vote = string_null;
 559                 vote_active = 0;
 560         }
 561         else
 562         {
 563                 vote_active = 1;
 564         }
 565
 566         if(nags & BIT(6))
 567         {
 568                 vote_yescount = ReadByte();
 569                 vote_nocount = ReadByte();
 570                 vote_needed = ReadByte();
 571                 vote_highlighted = ReadChar();
 572         }
 573
 574         if(nags & BIT(7))
 575         {
 576                 if(vote_called_vote)
 577                         strunzone(vote_called_vote);
 578                 vote_called_vote = strzone(ReadString());
 579         }
 580
 581         if(nags & 1)
 582         {
 583                 for(j = 0; j < maxclients; ++j)
 584                         if(playerslots[j])
 585                                 playerslots[j].ready = 1;
 586                 for(i = 1; i <= maxclients; i += 8)
 587                 {
 588                         f = ReadByte();
 589                         for(j = i-1, b = BIT(0); b < BIT(8); b <<= 1, ++j)
 590                                 if (!(f & b))
 591                                         if(playerslots[j])
 592                                                 playerslots[j].ready = 0;
 593                 }
 594         }
 595
 596         return = true;
 597
 598         ready_waiting = (nags & BIT(0));
 599         ready_waiting_for_me = (nags & BIT(1));
 600         vote_waiting = (nags & BIT(2));
 601         vote_waiting_for_me = (nags & BIT(3));
 602         warmup_stage = (nags & BIT(4));
 603 }
 604
 605 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 606 {
 607         make_pure(this);
 608         int sf = 0;
 609         serialize(byte, 0, sf);
 610         if (sf & 1) {
 611                 for (int j = 0; j < maxclients; ++j) {
 612                         if (playerslots[j]) {
 613                                 playerslots[j].eliminated = 1;
 614                         }
 615                 }
 616                 for (int i = 1; i <= maxclients; i += 8) {
 617                         int f = 0;
 618                         serialize(byte, 0, f);
 619                         for (int b = 0; b < 8; ++b) {
 620                                 if (f & BIT(b)) continue;
 621                                 int j = i - 1 + b;
 622                                 if (playerslots[j]) {
 623                                         playerslots[j].eliminated = 0;
 624                                 }
 625                         }
 626                 }
 627         }
 628         return true;
 629 }
 630
 631 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 632 {
 633         make_pure(this);
 634         prandom_debug();
 635         float s = ReadShort();
 636         psrandom(s);
 637         return true;
 638 }
 639
 640 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 641 {
 642         make_pure(this);
 643         int sf = ReadInt24_t();
 644         if (sf == 0) {
 645                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 646                         weapon_accuracy[w] = -1;
 647                 return true;
 648         }
 649
 650         int f = 1;
 651         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 652                 if (sf & f) {
 653                         int b = ReadByte();
 654                         if (b == 0)
 655                                 weapon_accuracy[w] = -1;
 656                         else if (b == 255)
 657                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 658                         else
 659                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 660                 }
 661                 f = (f == 0x800000) ? 1 : f * 2;
 662         }
 663         return true;
 664 }
 665
 666 void Spawn_Draw(entity this)
 667 {
 668         if(this.alpha <= 0)
 669                 return;
 670
 671         __pointparticles(this.cnt, this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 672 }
 673
 674 void Spawn_PreDraw(entity this)
 675 {
 676         float alph;
 677         vector org = getpropertyvec(VF_ORIGIN);
 678         if(this.fade_start)
 679         {
 680                 if(vdist(org - this.origin, >, this.fade_end))
 681                         alph = 0; // save on some processing
 682                 else if(vdist(org - this.origin, <, this.fade_start))
 683                         alph = 1; // more processing saved
 684                 else
 685                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 686         }
 687         else
 688                 alph = 1;
 689         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 690         this.alpha = alph;
 691         if(alph <= 0)
 692                 this.drawmask = 0;
 693         else
 694                 this.drawmask = MASK_NORMAL;
 695 }
 696
 697 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 698 {
 699         float teamnum = (ReadByte() - 1);
 700         vector spn_origin;
 701         spn_origin.x = ReadCoord();
 702         spn_origin.y = ReadCoord();
 703         spn_origin.z = ReadCoord();
 704
 705         this.team = (teamnum + 1);
 706
 707         //if(is_new)
 708         //{
 709                 this.origin = spn_origin;
 710                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 711                 //droptofloor();
 712
 713                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 714                 {
 715                         this.mdl = "models/spawnpoint.md3";
 716                         this.colormod = Team_ColorRGB(teamnum);
 717                         precache_model(this.mdl);
 718                         setmodel(this, this.mdl);
 719                         this.drawmask = MASK_NORMAL;
 720                         //this.move_movetype = MOVETYPE_NOCLIP;
 721                         //this.draw = Spawn_Draw;
 722                         IL_PUSH(g_drawables, this);
 723                 }*/
 724                 if(autocvar_cl_spawn_point_particles)
 725                 {
 726                         if(teamplay)
 727                         {
 728                                 switch(teamnum)
 729                                 {
 730                                         case NUM_TEAM_1: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
 731                                         case NUM_TEAM_2: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
 732                                         case NUM_TEAM_3: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
 733                                         case NUM_TEAM_4: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
 734                                         default: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
 735                                 }
 736                         }
 737                         else { this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
 738
 739                         this.draw = Spawn_Draw;
 740                         if (is_new) IL_PUSH(g_drawables, this);
 741                         setpredraw(this, Spawn_PreDraw);
 742                         this.fade_start = autocvar_cl_spawn_point_dist_min;
 743                         this.fade_end = autocvar_cl_spawn_point_dist_max;
 744                 }
 745         //}
 746
 747         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 748         return true;
 749 }
 750
 751 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 752 {
 753         // If entnum is 0, ONLY do the local spawn actions
 754         // this way the server can disable the sending of
 755         // spawn origin or such to clients if wanted.
 756         float entnum = ReadByte();
 757
 758         if(entnum)
 759         {
 760                 this.origin_x = ReadCoord();
 761                 this.origin_y = ReadCoord();
 762                 this.origin_z = ReadCoord();
 763
 764                 if(is_new)
 765                 {
 766                         float teamnum = entcs_GetTeam(entnum - 1);
 767
 768                         if(autocvar_cl_spawn_event_particles)
 769                         {
 770                                 switch(teamnum)
 771                                 {
 772                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 773                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 774                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 775                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 776                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 777                                 }
 778                         }
 779                         if(autocvar_cl_spawn_event_sound)
 780                         {
 781                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 782                         }
 783                 }
 784         }
 785         return = true;
 786
 787         // local spawn actions
 788         if(is_new && (!entnum || (entnum == player_localentnum)))
 789         {
 790                 zoomin_effect = 1;
 791                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 792
 793                 if(autocvar_cl_unpress_zoom_on_spawn)
 794                 {
 795                         localcmd("-zoom\n");
 796                         button_zoom = false;
 797                 }
 798                 HUD_Radar_Hide_Maximized();
 799         }
 800         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 801 }
 802
 803 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 804 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 805 void CSQC_Ent_Update(entity this, bool isnew)
 806 {
 807         this.sourceLoc = __FILE__ ":" STR(__LINE__);
 808         int t = ReadByte();
 809
 810         // set up the "time" global for received entities to be correct for interpolation purposes
 811         float savetime = time;
 812         if(servertime)
 813         {
 814                 time = servertime;
 815         }
 816         else
 817         {
 818                 serverprevtime = time;
 819                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 820                 time = serverprevtime + serverdeltatime;
 821         }
 822
 823 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 824         if (this.enttype)
 825         {
 826                 if (t != this.enttype || isnew)
 827                 {
 828                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
 829                         Ent_Remove(this);
 830                         clearentity(this);
 831                         isnew = true;
 832                 }
 833         }
 834         else
 835         {
 836                 if (!isnew)
 837                 {
 838                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
 839                         isnew = true;
 840                 }
 841         }
 842 #endif
 843         this.enttype = t;
 844         bool done = false;
 845         FOREACH(LinkedEntities, it.m_id == t, {
 846                 if (isnew) this.classname = it.netname;
 847                 if (autocvar_developer_csqcentities)
 848             LOG_INFOF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 849                 done = it.m_read(this, NULL, isnew);
 850                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 851                 break;
 852         });
 853         time = savetime;
 854         if (!done)
 855         {
 856                 LOG_FATALF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 857         }
 858 }
 859
 860 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 861 // used when an entity changes its type. For an entity that someone interacts
 862 // with others, make sure it can no longer do so.
 863 void Ent_Remove(entity this)
 864 {
 865         if(this.entremove) this.entremove(this);
 866
 867         if(this.skeletonindex)
 868         {
 869                 skel_delete(this.skeletonindex);
 870                 this.skeletonindex = 0;
 871         }
 872
 873         if(this.snd_looping > 0)
 874         {
 875                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 876                 this.snd_looping = 0;
 877         }
 878
 879         this.enttype = 0;
 880         this.classname = "";
 881         this.draw = func_null;
 882         this.entremove = func_null;
 883         // TODO possibly set more stuff to defaults
 884 }
 885 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 886 void CSQC_Ent_Remove(entity this)
 887 {
 888         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
 889         if (wasfreed(this))
 890         {
 891                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
 892                 return;
 893         }
 894         if (this.enttype) Ent_Remove(this);
 895         delete(this);
 896 }
 897
 898 void Gamemode_Init()
 899 {
 900         if (!isdemo())
 901         {
 902                 if(!(calledhooks & HOOK_START))
 903                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 904                 calledhooks |= HOOK_START;
 905         }
 906 }
 907 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 908 void CSQC_Parse_StuffCmd(string strMessage)
 909 {
 910         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
 911         localcmd(strMessage);
 912 }
 913 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 914 void CSQC_Parse_Print(string strMessage)
 915 {
 916         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
 917         print(ColorTranslateRGB(strMessage));
 918 }
 919
 920 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 921 void CSQC_Parse_CenterPrint(string strMessage)
 922 {
 923         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
 924         centerprint_hud(strMessage);
 925 }
 926
 927 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
 928 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
 929 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
 930 bool CSQC_Parse_TempEntity()
 931 {
 932         // Acquire TE ID
 933         int nTEID = ReadByte();
 934
 935         FOREACH(TempEntities, it.m_id == nTEID, {
 936                 if (autocvar_developer_csqcentities)
 937                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
 938                 return it.m_read(NULL, NULL, true);
 939         });
 940
 941         if (autocvar_developer_csqcentities)
 942                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
 943
 944         // No special logic for this temporary entity; return 0 so the engine can handle it
 945         return false;
 946 }
 947
 948 string forcefog;
 949 void Fog_Force()
 950 {
 951         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 952                 localcmd("\nr_drawfog 0\n");
 953         else if (forcefog != "")
 954                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
 955 }
 956
 957 void Gamemode_Init();
 958 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
 959 {
 960         make_pure(this);
 961         gametype = ReadRegistered(Gametypes);
 962         teamplay = _MapInfo_GetTeamPlayBool(gametype);
 963         HUD_ModIcons_SetFunc();
 964         FOREACH(Scores, true, {
 965                 if (scores_label(it)) strunzone(scores_label(it));
 966                 scores_label(it) = strzone(ReadString());
 967                 scores_flags(it) = ReadByte();
 968         });
 969         for (int i = 0; i < MAX_TEAMSCORE; ++i)
 970         {
 971                 if (teamscores_label(i)) strunzone(teamscores_label(i));
 972                 teamscores_label(i) = strzone(ReadString());
 973                 teamscores_flags(i) = ReadByte();
 974         }
 975         return = true;
 976         Scoreboard_InitScores();
 977         Gamemode_Init();
 978 }
 979
 980 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
 981 {
 982         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 983
 984         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 985         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 986         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 987         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 988         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 989         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 990         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 991         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 992
 993         if (forcefog) strunzone(forcefog);
 994         forcefog = strzone(ReadString());
 995
 996         armorblockpercent = ReadByte() / 255.0;
 997         damagepush_speedfactor = ReadByte() / 255.0;
 998
 999         serverflags = ReadByte();
1000
1001         g_trueaim_minrange = ReadCoord();
1002
1003         return = true;
1004
1005         MUTATOR_CALLHOOK(Ent_Init);
1006
1007         if (!postinit) PostInit();
1008 }
1009
1010 float GetSpeedUnitFactor(int speed_unit)
1011 {
1012         switch(speed_unit)
1013         {
1014                 default:
1015                 case 1:
1016                         return 1.0;
1017                 case 2:
1018                         return 0.0254;
1019                 case 3:
1020                         return 0.0254 * 3.6;
1021                 case 4:
1022                         return 0.0254 * 3.6 * 0.6213711922;
1023                 case 5:
1024                         return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1025         }
1026 }
1027
1028 string GetSpeedUnit(int speed_unit)
1029 {
1030         switch(speed_unit)
1031         {
1032                 default:
1033                 case 1:
1034                         return _(" qu/s");
1035                 case 2:
1036                         return _(" m/s");
1037                 case 3:
1038                         return _(" km/h");
1039                 case 4:
1040                         return _(" mph");
1041                 case 5:
1042                         return _(" knots");
1043         }
1044 }
1045
1046 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1047 {
1048         int b = ReadByte();
1049
1050         switch (b)
1051         {
1052                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1053                         race_checkpoint = ReadByte();
1054                         race_time = ReadInt24_t();
1055                         race_previousbesttime = ReadInt24_t();
1056                         race_mypreviousbesttime = ReadInt24_t();
1057                         if(race_previousbestname)
1058                                 strunzone(race_previousbestname);
1059                         string pbestname = ReadString();
1060                         if(autocvar_cl_race_cptimes_onlyself)
1061                         {
1062                                 race_previousbesttime = race_mypreviousbesttime;
1063                                 race_mypreviousbesttime = 0;
1064                                 race_previousbestname = strzone("");
1065                         }
1066                         else
1067                                 race_previousbestname = strzone(pbestname);
1068
1069                         race_checkpointtime = time;
1070
1071                         if(race_checkpoint == 0 || race_checkpoint == 254)
1072                         {
1073                                 race_penaltyaccumulator = 0;
1074                                 race_laptime = time; // valid
1075                         }
1076                         break;
1077
1078                 case RACE_NET_CHECKPOINT_CLEAR:
1079                         race_laptime = 0;
1080                         race_checkpointtime = 0;
1081                         break;
1082
1083                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1084                         race_laptime = ReadCoord();
1085                         race_checkpointtime = -99999;
1086                         // fall through
1087                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1088                         race_nextcheckpoint = ReadByte();
1089
1090                         race_nextbesttime = ReadInt24_t();
1091                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1092                                 race_mybesttime = ReadInt24_t();
1093                         if(race_nextbestname)
1094                                 strunzone(race_nextbestname);
1095                         string newname = ReadString();
1096                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1097                         {
1098                                 race_nextbesttime = race_mybesttime;
1099                                 race_mybesttime = 0;
1100                                 race_nextbestname = strzone("");
1101                         }
1102                         else
1103                                 race_nextbestname = strzone(newname);
1104                         break;
1105
1106                 case RACE_NET_CHECKPOINT_HIT_RACE:
1107                         race_mycheckpoint = ReadByte();
1108                         race_mycheckpointtime = time;
1109                         race_mycheckpointdelta = ReadInt24_t();
1110                         race_mycheckpointlapsdelta = ReadByte();
1111                         if(race_mycheckpointlapsdelta >= 128)
1112                                 race_mycheckpointlapsdelta -= 256;
1113                         if(race_mycheckpointenemy)
1114                                 strunzone(race_mycheckpointenemy);
1115                         int who = ReadByte();
1116                         if(who)
1117                                 race_mycheckpointenemy = strzone(entcs_GetName(who - 1));
1118                         else
1119                                 race_mycheckpointenemy = strzone(""); // TODO: maybe string_null works fine here?
1120                         break;
1121
1122                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1123                         race_othercheckpoint = ReadByte();
1124                         race_othercheckpointtime = time;
1125                         race_othercheckpointdelta = ReadInt24_t();
1126                         race_othercheckpointlapsdelta = ReadByte();
1127                         if(race_othercheckpointlapsdelta >= 128)
1128                                 race_othercheckpointlapsdelta -= 256;
1129                         if(race_othercheckpointenemy)
1130                                 strunzone(race_othercheckpointenemy);
1131                         int what = ReadByte();
1132                         if(what)
1133                                 race_othercheckpointenemy = strzone(entcs_GetName(what - 1));
1134                         else
1135                                 race_othercheckpointenemy = strzone(""); // TODO: maybe string_null works fine here?
1136                         break;
1137
1138                 case RACE_NET_PENALTY_RACE:
1139                         race_penaltyeventtime = time;
1140                         race_penaltytime = ReadShort();
1141                         //race_penaltyaccumulator += race_penaltytime;
1142                         if(race_penaltyreason)
1143                                 strunzone(race_penaltyreason);
1144                         race_penaltyreason = strzone(ReadString());
1145                         break;
1146
1147                 case RACE_NET_PENALTY_QUALIFYING:
1148                         race_penaltyeventtime = time;
1149                         race_penaltytime = ReadShort();
1150                         race_penaltyaccumulator += race_penaltytime;
1151                         if(race_penaltyreason)
1152                                 strunzone(race_penaltyreason);
1153                         race_penaltyreason = strzone(ReadString());
1154                         break;
1155
1156                 case RACE_NET_SERVER_RECORD:
1157                         race_server_record = ReadInt24_t();
1158                         break;
1159                 case RACE_NET_SPEED_AWARD:
1160                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1161                         if(race_speedaward_holder)
1162                                 strunzone(race_speedaward_holder);
1163                         race_speedaward_holder = strzone(ReadString());
1164                         if(race_speedaward_unit)
1165                                 strunzone(race_speedaward_unit);
1166                         race_speedaward_unit = strzone(GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1167                         break;
1168                 case RACE_NET_SPEED_AWARD_BEST:
1169                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1170                         if(race_speedaward_alltimebest_holder)
1171                                 strunzone(race_speedaward_alltimebest_holder);
1172                         race_speedaward_alltimebest_holder = strzone(ReadString());
1173                         if(race_speedaward_alltimebest_unit)
1174                                 strunzone(race_speedaward_alltimebest_unit);
1175                         race_speedaward_alltimebest_unit = strzone(GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1176                         break;
1177                 case RACE_NET_SERVER_RANKINGS:
1178                         float prevpos, del;
1179             int pos = ReadShort();
1180                         prevpos = ReadShort();
1181                         del = ReadShort();
1182
1183                         // move other rankings out of the way
1184             int i;
1185                         if (prevpos) {
1186                                 for (i=prevpos-1;i>pos-1;--i) {
1187                                         grecordtime[i] = grecordtime[i-1];
1188                                         if(grecordholder[i])
1189                                                 strunzone(grecordholder[i]);
1190                                         grecordholder[i] = strzone(grecordholder[i-1]);
1191                                 }
1192                         } else if (del) { // a record has been deleted by the admin
1193                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1194                                         if (i == RANKINGS_CNT-1) { // clear out last record
1195                                                 grecordtime[i] = 0;
1196                                                 if (grecordholder[i])
1197                                                         strunzone(grecordholder[i]);
1198                                                 grecordholder[i] = string_null;
1199                                         }
1200                                         else {
1201                                                 grecordtime[i] = grecordtime[i+1];
1202                                                 if (grecordholder[i])
1203                                                         strunzone(grecordholder[i]);
1204                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1205                                         }
1206                                 }
1207                         } else { // player has no ranked record yet
1208                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1209                                         grecordtime[i] = grecordtime[i-1];
1210                                         if(grecordholder[i])
1211                                                 strunzone(grecordholder[i]);
1212                                         grecordholder[i] = strzone(grecordholder[i-1]);
1213                                 }
1214                         }
1215
1216                         // store new ranking
1217                         if(grecordholder[pos-1] != "")
1218                                 strunzone(grecordholder[pos-1]);
1219                         grecordholder[pos-1] = strzone(ReadString());
1220                         grecordtime[pos-1] = ReadInt24_t();
1221                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1222                                 race_myrank = pos;
1223                         break;
1224                 case RACE_NET_SERVER_STATUS:
1225                         race_status = ReadShort();
1226                         if(race_status_name)
1227                                 strunzone(race_status_name);
1228                         race_status_name = strzone(ReadString());
1229         }
1230         return true;
1231 }
1232
1233 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1234 {
1235         teamnagger = 1;
1236         return true;
1237 }
1238
1239 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1240 {
1241         int i = ReadByte();
1242         int pi = ReadShort();
1243         int pl = ReadByte();
1244         int ml = ReadByte();
1245         return = true;
1246         entity e = playerslots[i];
1247         if (!e) return;
1248         e.ping = pi;
1249         e.ping_packetloss = pl / 255.0;
1250         e.ping_movementloss = ml / 255.0;
1251 }
1252
1253 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1254 {
1255         complain_weapon = ReadByte();
1256         complain_weapon_type = ReadByte();
1257         return = true;
1258
1259         complain_weapon_time = time;
1260         weapontime = time; // ping the weapon panel
1261
1262         switch(complain_weapon_type)
1263         {
1264                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1265                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1266                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1267         }
1268 }
1269
1270 string _getcommandkey(string cmd_name, string command, bool forcename)
1271 {
1272         string keys;
1273         float n, j, k, l = 0;
1274
1275         if (!autocvar_hud_showbinds)
1276                 return cmd_name;
1277
1278         keys = db_get(binddb, command);
1279         if (keys == "")
1280         {
1281                 bool joy_active = cvar("joy_active");
1282                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1283                 for(j = 0; j < n; ++j)
1284                 {
1285                         k = stof(argv(j));
1286                         if(k != -1)
1287                         {
1288                                 string key = keynumtostring(k);
1289                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1290                                         continue;
1291
1292                                 if (keys == "")
1293                                         keys = key;
1294                                 else
1295                                         keys = strcat(keys, ", ", key);
1296
1297                                 ++l;
1298                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1299                                         break;
1300                         }
1301
1302                 }
1303                 if (keys == "")
1304                         keys = "NO_KEY";
1305                 db_put(binddb, command, keys);
1306         }
1307
1308         if (keys == "NO_KEY") {
1309                 if (autocvar_hud_showbinds > 1)
1310                         return sprintf(_("%s (not bound)"), cmd_name);
1311                 else
1312                         return cmd_name;
1313         }
1314         else if (autocvar_hud_showbinds > 1 || forcename)
1315                 return sprintf("%s (%s)", cmd_name, keys);
1316         else
1317                 return keys;
1318 }