6844b1e078d7ad30380aae9913c1301832a5bc1d
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / main.qc
1 #include "main.qh"
2
3 #include "defs.qh"
4 #include <common/ent_cs.qh>
5 #include "miscfunctions.qh"
6 #include <common/effects/effect.qh>
7 #include <common/effects/qc/_mod.qh>
8 #include <common/effects/all.qh>
9 #include <common/effects/all.inc>
10 #include "hud/_mod.qh"
11 #include "commands/cl_cmd.qh"
12 #include "mapvoting.qh"
13 #include <client/mutators/_mod.qh>
14 #include "hud/panel/scoreboard.qh"
15 #include "hud/panel/quickmenu.qh"
16 #include "shownames.qh"
17 #include "view.qh"
18 #include <common/t_items.qh>
19 #include "weapons/projectile.qh"
20 #include <common/deathtypes/all.qh>
21 #include <common/items/_mod.qh>
22 #include <common/mapinfo.qh>
23 #include <common/minigames/cl_minigames.qh>
24 #include <common/minigames/cl_minigames_hud.qh>
25 #include <common/net_linked.qh>
26 #include <common/net_notice.qh>
27 #include <common/scores.qh>
28 #include <common/mapobjects/_mod.qh>
29 #include <common/vehicles/all.qh>
30 #include <lib/csqcmodel/cl_model.qh>
31 #include <lib/csqcmodel/interpolate.qh>
32 #include <lib/warpzone/client.qh>
33
34 // --------------------------------------------------------------------------
35 // BEGIN REQUIRED CSQC FUNCTIONS
36 //include "main.qh"
37
38 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
39
40 void draw_cursor(vector pos, vector ofs, string img, vector col, float a)
41 {
42         ofs = vec2(ofs.x * SIZE_CURSOR.x, ofs.y * SIZE_CURSOR.y);
43         drawpic(pos - ofs, strcat(draw_currentSkin, img), SIZE_CURSOR, col, a, DRAWFLAG_NORMAL);
44 }
45
46 void draw_cursor_normal(vector pos, vector col, float a)
47 {
48         draw_cursor(pos, OFFSET_CURSOR, "/cursor", col, a);
49 }
50
51 void LoadMenuSkinValues()
52 {
53         int fh = -1;
54         if(cvar_string("menu_skin") != "")
55         {
56                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
57                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
58         }
59         if(fh < 0 && cvar_defstring("menu_skin") != "")
60         {
61                 cvar_set("menu_skin", cvar_defstring("menu_skin"));
62                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
63                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
64         }
65         if(fh < 0)
66         {
67                 draw_currentSkin = "gfx/menu/default";
68                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
69         }
70
71         draw_currentSkin = strzone(draw_currentSkin);
72
73         if(fh >= 0)
74         {
75                 string s;
76                 while((s = fgets(fh)))
77                 {
78                         int n = tokenize_console(s);
79                         if (n < 2)
80                                 continue;
81                         if(substring(argv(0), 0, 2) == "//")
82                                 continue;
83                         if(argv(0) == "SIZE_CURSOR")
84                                 SIZE_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
85                         else if(argv(0) == "OFFSET_CURSOR")
86                                 OFFSET_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
87                 }
88                 fclose(fh);
89         }
90 }
91
92 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
93 // Useful for precaching things
94
95 void CSQC_Init()
96 {
97         prvm_language = strzone(cvar_string("prvm_language"));
98
99 #ifdef WATERMARK
100         LOG_INFOF("^4CSQC Build information: ^1%s", WATERMARK);
101 #endif
102
103         {
104                 int i = 0;
105                 for ( ; i < 255; ++i)
106                         if (getplayerkeyvalue(i, "viewentity") == "")
107                                 break;
108                 maxclients = i;
109         }
110
111         // needs to be done so early because of the constants they create
112         static_init();
113         static_init_late();
114         static_init_precache();
115
116         binddb = db_create();
117         tempdb = db_create();
118         ClientProgsDB = db_load("client.db");
119
120         draw_endBoldFont();
121
122         //registercommand("hud_configure");
123         //registercommand("hud_save");
124         //registercommand("menu_action");
125
126         ConsoleCommand_macro_init();
127
128         registercvar("hud_usecsqc", "1");
129         registercvar("scoreboard_columns", "default");
130
131         registercvar("cl_nade_type", "3");
132         registercvar("cl_pokenade_type", "zombie");
133
134         registercvar("cl_jumpspeedcap_min", "");
135         registercvar("cl_jumpspeedcap_max", "");
136
137         registercvar("cl_shootfromfixedorigin", "");
138
139         registercvar("cl_multijump", "1");
140
141         registercvar("cl_spawn_near_teammate", "1");
142
143         if(autocvar_cl_lockview)
144                 cvar_set("cl_lockview", "0");
145
146         gametype = NULL;
147
148         postinit = false;
149
150         calledhooks = 0;
151
152         teams = Sort_Spawn();
153         players = Sort_Spawn();
154
155         GetTeam(NUM_SPECTATOR, true); // add specs first
156
157         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
158                 weapon_accuracy[w] = -1;
159
160         // precaches
161
162         if(autocvar_cl_reticle)
163         {
164                 precache_pic("gfx/reticle_normal");
165                 // weapon reticles are precached in weapon files
166         }
167
168         {
169                 get_mi_min_max_texcoords(1); // try the CLEVER way first
170                 minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
171                 shortmapname = mi_shortname;
172
173                 if (precache_pic(minimapname) == "")
174                 {
175                         // but maybe we have a non-clever minimap
176                         minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
177                         if (precache_pic(minimapname) == "")
178                                 minimapname = ""; // FAIL
179                         else
180                                 get_mi_min_max_texcoords(0); // load new texcoords
181                 }
182
183                 mi_center = (mi_min + mi_max) * 0.5;
184                 mi_scale = mi_max - mi_min;
185                 minimapname = strzone(minimapname);
186         }
187
188         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
189         LoadMenuSkinValues();
190 }
191
192 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
193 void Shutdown()
194 {
195         WarpZone_Shutdown();
196
197         delete(teams);
198         delete(players);
199         db_close(binddb);
200         db_close(tempdb);
201         if(autocvar_cl_db_saveasdump)
202                 db_dump(ClientProgsDB, "client.db");
203         else
204                 db_save(ClientProgsDB, "client.db");
205         db_close(ClientProgsDB);
206
207         if(camera_active)
208                 cvar_set("chase_active",ftos(chase_active_backup));
209
210         // unset the event chasecam's chase_active
211         if(autocvar_chase_active < 0)
212                 cvar_set("chase_active", "0");
213
214         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
215
216         if (!isdemo())
217         {
218                 if (!(calledhooks & HOOK_START))
219                         localcmd("\n_cl_hook_gamestart nop\n");
220                 if (!(calledhooks & HOOK_END))
221                         localcmd("\ncl_hook_gameend\n");
222         }
223
224         localcmd("\ncl_hook_shutdown\n");
225
226         deactivate_minigame();
227         HUD_MinigameMenu_Close(NULL, NULL, NULL);
228 }
229
230 .float has_team;
231 bool SetTeam(entity o, int Team)
232 {
233         TC(int, Team);
234         devassert_once(Team);
235         entity tm;
236         if(teamplay)
237         {
238                 switch(Team)
239                 {
240                         case -1:
241                         case NUM_TEAM_1:
242                         case NUM_TEAM_2:
243                         case NUM_TEAM_3:
244                         case NUM_TEAM_4:
245                                 break;
246                         default:
247                                 if(GetTeam(Team, false) == NULL)
248                                 {
249                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
250                                         Team = NUM_SPECTATOR;
251                                 }
252                                 break;
253                 }
254         }
255         else
256         {
257                 switch(Team)
258                 {
259                         case -1:
260                         case 0:
261                                 break;
262                         default:
263                                 if(GetTeam(Team, false) == NULL)
264                                 {
265                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
266                                         Team = NUM_SPECTATOR;
267                                 }
268                                 break;
269                 }
270         }
271         if(Team == -1) // leave
272         {
273                 if(o.has_team)
274                 {
275                         tm = GetTeam(o.team, false);
276                         tm.team_size -= 1;
277                         o.has_team = 0;
278                         return true;
279                 }
280         }
281         else
282         {
283                 if (!o.has_team)
284                 {
285                         o.team = Team;
286                         tm = GetTeam(Team, true);
287                         tm.team_size += 1;
288                         o.has_team = 1;
289                         return true;
290                 }
291                 else if(Team != o.team)
292                 {
293                         tm = GetTeam(o.team, false);
294                         tm.team_size -= 1;
295                         o.team = Team;
296                         tm = GetTeam(Team, true);
297                         tm.team_size += 1;
298                         return true;
299                 }
300         }
301         return false;
302 }
303
304 void Playerchecker_Think(entity this)
305 {
306     int i;
307         entity e;
308         for(i = 0; i < maxclients; ++i)
309         {
310                 e = playerslots[i];
311                 if(entcs_GetName(i) == "")
312                 {
313                         if(e.sort_prev)
314                         {
315                                 // player disconnected
316                                 SetTeam(e, -1);
317                                 RemovePlayer(e);
318                                 e.sort_prev = NULL;
319                                 //e.gotscores = 0;
320                         }
321                 }
322                 else
323                 {
324                         if (!e.sort_prev)
325                         {
326                                 // player connected
327                                 if (!e)
328                                 {
329                                         playerslots[i] = e = new_pure(playerslot);
330                                 }
331                                 e.sv_entnum = i;
332                                 e.ping = 0;
333                                 e.ping_packetloss = 0;
334                                 e.ping_movementloss = 0;
335                                 //e.gotscores = 0; // we might already have the scores...
336                                 int t = entcs_GetScoreTeam(i);
337                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
338                                 RegisterPlayer(e);
339                                 Scoreboard_UpdatePlayerPos(e);
340                         }
341                 }
342         }
343         this.nextthink = time + 0.2;
344 }
345
346 void PostInit()
347 {
348         entity playerchecker = new_pure(playerchecker);
349         setthink(playerchecker, Playerchecker_Think);
350         playerchecker.nextthink = time + 0.2;
351
352         TrueAim_Init();
353
354         postinit = true;
355 }
356
357 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
358 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
359 // All keys are in ascii.
360 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
361 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
362 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
363 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
364 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
365 {
366     TC(int, bInputType);
367         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
368                 return true;
369
370         if (QuickMenu_InputEvent(bInputType, nPrimary, nSecondary))
371                 return true;
372
373         if (HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary))
374                 return true;
375
376         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
377                 return true;
378
379         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
380                 return true;
381
382         return false;
383 }
384
385 // END REQUIRED CSQC FUNCTIONS
386 // --------------------------------------------------------------------------
387
388 // --------------------------------------------------------------------------
389 // BEGIN OPTIONAL CSQC FUNCTIONS
390
391 void Ent_RemovePlayerScore(entity this)
392 {
393         if(this.owner) {
394                 SetTeam(this.owner, -1);
395                 this.owner.gotscores = 0;
396                 FOREACH(Scores, true, {
397                         this.owner.(scores(it)) = 0; // clear all scores
398                 });
399         }
400 }
401
402 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
403 {
404         make_pure(this);
405         entity o;
406
407         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
408         // (no I've never heard of M-x replace-string, sed, or anything like that)
409         bool isNew = !this.owner; // workaround for DP bug
410         int n = ReadByte()-1;
411
412 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
413         if(!isNew && n != this.sv_entnum)
414         {
415                 //print("A CSQC entity changed its owner!\n");
416                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
417                 isNew = true;
418                 Ent_Remove(this);
419         }
420 #endif
421
422         this.sv_entnum = n;
423
424         o = playerslots[this.sv_entnum];
425         if (!o)
426         {
427                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
428         }
429         this.owner = o;
430         o.sv_entnum = this.sv_entnum;
431         o.gotscores = 1;
432
433         //if (!o.sort_prev)
434         //      RegisterPlayer(o);
435         //playerchecker will do this for us later, if it has not already done so
436
437         int sf = ReadShort();
438         int lf = ReadShort();
439         FOREACH(Scores, true, {
440                 int p = 1 << (i % 16);
441                 if (sf & p)
442                 {
443                         if (lf & p)
444                                 o.(scores(it)) = ReadInt24_t();
445                         else
446                                 o.(scores(it)) = ReadChar();
447                 }
448         });
449
450         return = true;
451
452         if(o.sort_prev)
453                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
454
455         this.entremove = Ent_RemovePlayerScore;
456 }
457
458 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
459 {
460         make_pure(this);
461         int i;
462
463         this.team = ReadByte();
464         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
465
466 #if MAX_TEAMSCORE <= 8
467         int sf = ReadByte();
468         int lf = ReadByte();
469 #else
470         int sf = ReadShort();
471         int lf = ReadShort();
472 #endif
473         for(i = 0; i < MAX_TEAMSCORE; ++i)
474                 if(sf & BIT(i))
475                 {
476                         if(lf & BIT(i))
477                                 o.(teamscores(i)) = ReadInt24_t();
478                         else
479                                 o.(teamscores(i)) = ReadChar();
480                 }
481
482         return = true;
483
484         Scoreboard_UpdateTeamPos(o);
485 }
486
487 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
488 {
489         make_pure(this);
490         float newspectatee_status;
491
492         int f = ReadByte();
493
494         scoreboard_showscores_force = (f & BIT(0));
495
496         if(f & BIT(1))
497         {
498                 newspectatee_status = ReadByte();
499                 if(newspectatee_status == player_localnum + 1)
500                         newspectatee_status = -1; // observing
501         }
502         else
503                 newspectatee_status = 0;
504
505         spectatorbutton_zoom = (f & BIT(2));
506
507         if(f & BIT(4))
508         {
509                 num_spectators = ReadByte();
510
511                 float i, slot;
512
513                 for(i = 0; i < MAX_SPECTATORS; ++i)
514                         spectatorlist[i] = 0; // reset list first
515
516                 for(i = 0; i < num_spectators; ++i)
517                 {
518                         slot = ReadByte();
519                         spectatorlist[i] = slot - 1;
520                 }
521         }
522
523         return = true;
524
525         if(newspectatee_status != spectatee_status)
526         {
527                 // clear race stuff
528                 race_laptime = 0;
529                 race_checkpointtime = 0;
530                 hud_dynamic_shake_factor = -1;
531         }
532         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
533         {
534                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
535                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
536                 )
537                         prev_p_health = -1;
538                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
539                         prev_health = -1;
540         }
541         spectatee_status = newspectatee_status;
542
543         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
544 }
545
546 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
547 {
548         make_pure(this);
549         int i, j, b, f;
550
551         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
552
553         if(!(nags & BIT(2)))
554         {
555                 strfree(vote_called_vote);
556                 vote_active = 0;
557         }
558         else
559         {
560                 vote_active = 1;
561         }
562
563         if(nags & BIT(6))
564         {
565                 vote_yescount = ReadByte();
566                 vote_nocount = ReadByte();
567                 vote_needed = ReadByte();
568                 vote_highlighted = ReadChar();
569         }
570
571         if(nags & BIT(7))
572         {
573                 strcpy(vote_called_vote, ReadString());
574         }
575
576         if(nags & 1)
577         {
578                 for(j = 0; j < maxclients; ++j)
579                         if(playerslots[j])
580                                 playerslots[j].ready = true;
581                 for(i = 1; i <= maxclients; i += 8)
582                 {
583                         f = ReadByte();
584                         for(j = i-1, b = BIT(0); b < BIT(8); b <<= 1, ++j)
585                                 if (!(f & b))
586                                         if(playerslots[j])
587                                                 playerslots[j].ready = false;
588                 }
589         }
590
591         return = true;
592
593         ready_waiting = (nags & BIT(0));
594         ready_waiting_for_me = (nags & BIT(1));
595         vote_waiting = (nags & BIT(2));
596         vote_waiting_for_me = (nags & BIT(3));
597         warmup_stage = (nags & BIT(4));
598 }
599
600 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
601 {
602         make_pure(this);
603         int sf = 0;
604         serialize(byte, 0, sf);
605         if (sf & 1) {
606                 for (int j = 0; j < maxclients; ++j) {
607                         if (playerslots[j]) {
608                                 playerslots[j].eliminated = true;
609                         }
610                 }
611                 for (int i = 1; i <= maxclients; i += 8) {
612                         int f = 0;
613                         serialize(byte, 0, f);
614                         for (int b = 0; b < 8; ++b) {
615                                 if (f & BIT(b)) continue;
616                                 int j = i - 1 + b;
617                                 if (playerslots[j]) {
618                                         playerslots[j].eliminated = false;
619                                 }
620                         }
621                 }
622         }
623         return true;
624 }
625
626 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
627 {
628         make_pure(this);
629         prandom_debug();
630         float s = ReadShort();
631         psrandom(s);
632         return true;
633 }
634
635 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
636 {
637         make_pure(this);
638         int sf = ReadInt24_t();
639         if (sf == 0) {
640                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
641                         weapon_accuracy[w] = -1;
642                 return true;
643         }
644
645         int f = 1;
646         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
647                 if (sf & f) {
648                         int b = ReadByte();
649                         if (b == 0)
650                                 weapon_accuracy[w] = -1;
651                         else if (b == 255)
652                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
653                         else
654                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
655                 }
656                 f = (f == 0x800000) ? 1 : f * 2;
657         }
658         return true;
659 }
660
661 void Spawn_Draw(entity this)
662 {
663         if(this.alpha <= 0)
664                 return;
665
666         __pointparticles(this.cnt, this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
667 }
668
669 void Spawn_PreDraw(entity this)
670 {
671         float alph;
672         vector org = getpropertyvec(VF_ORIGIN);
673         if(this.fade_start)
674         {
675                 if(vdist(org - this.origin, >, this.fade_end))
676                         alph = 0; // save on some processing
677                 else if(vdist(org - this.origin, <, this.fade_start))
678                         alph = 1; // more processing saved
679                 else
680                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
681         }
682         else
683                 alph = 1;
684         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
685         this.alpha = alph;
686         if(alph <= 0)
687                 this.drawmask = 0;
688         else
689                 this.drawmask = MASK_NORMAL;
690 }
691
692 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
693 {
694         float teamnum = (ReadByte() - 1);
695         vector spn_origin = ReadVector();
696
697         this.team = (teamnum + 1);
698
699         //if(is_new)
700         //{
701                 this.origin = spn_origin;
702                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
703                 //droptofloor();
704
705                 /*if(autocvar_cl_spawn_point_model) // needs a model first
706                 {
707                         this.mdl = "models/spawnpoint.md3";
708                         this.colormod = Team_ColorRGB(teamnum);
709                         precache_model(this.mdl);
710                         setmodel(this, this.mdl);
711                         this.drawmask = MASK_NORMAL;
712                         //this.move_movetype = MOVETYPE_NOCLIP;
713                         //this.draw = Spawn_Draw;
714                         IL_PUSH(g_drawables, this);
715                 }*/
716                 if(autocvar_cl_spawn_point_particles)
717                 {
718                         if(teamplay)
719                         {
720                                 switch(teamnum)
721                                 {
722                                         case NUM_TEAM_1: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
723                                         case NUM_TEAM_2: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
724                                         case NUM_TEAM_3: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
725                                         case NUM_TEAM_4: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
726                                         default: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
727                                 }
728                         }
729                         else { this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
730
731                         this.draw = Spawn_Draw;
732                         if (is_new) IL_PUSH(g_drawables, this);
733                         setpredraw(this, Spawn_PreDraw);
734                         this.fade_start = autocvar_cl_spawn_point_dist_min;
735                         this.fade_end = autocvar_cl_spawn_point_dist_max;
736                 }
737         //}
738
739         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
740         return true;
741 }
742
743 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
744 {
745         // If entnum is 0, ONLY do the local spawn actions
746         // this way the server can disable the sending of
747         // spawn origin or such to clients if wanted.
748         float entnum = ReadByte();
749
750         if(entnum)
751         {
752                 this.origin = ReadVector();
753
754                 if(is_new)
755                 {
756                         float teamnum = entcs_GetTeam(entnum - 1);
757
758                         if(autocvar_cl_spawn_event_particles)
759                         {
760                                 switch(teamnum)
761                                 {
762                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
763                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
764                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
765                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
766                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
767                                 }
768                         }
769                         if(autocvar_cl_spawn_event_sound)
770                         {
771                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
772                         }
773                 }
774         }
775         return = true;
776
777         // local spawn actions
778         if(is_new && (!entnum || (entnum == player_localentnum)))
779         {
780                 zoomin_effect = 1;
781                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
782
783                 if(autocvar_cl_unpress_zoom_on_spawn)
784                 {
785                         localcmd("-zoom\n");
786                         button_zoom = false;
787                 }
788                 HUD_Radar_Hide_Maximized();
789         }
790         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
791 }
792
793 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
794 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
795 void CSQC_Ent_Update(entity this, bool isnew)
796 {
797         this.sourceLoc = __FILE__ ":" STR(__LINE__);
798         int t = ReadByte();
799
800         // set up the "time" global for received entities to be correct for interpolation purposes
801         float savetime = time;
802         if(servertime)
803         {
804                 time = servertime;
805         }
806         else
807         {
808                 serverprevtime = time;
809                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
810                 time = serverprevtime + serverdeltatime;
811         }
812
813 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
814         if (this.enttype)
815         {
816                 if (t != this.enttype || isnew)
817                 {
818                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
819                         Ent_Remove(this);
820                         clearentity(this);
821                         isnew = true;
822                 }
823         }
824         else
825         {
826                 if (!isnew)
827                 {
828                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
829                         isnew = true;
830                 }
831         }
832 #endif
833         this.enttype = t;
834         bool done = false;
835         FOREACH(LinkedEntities, it.m_id == t, {
836                 if (isnew) this.classname = it.netname;
837                 if (autocvar_developer_csqcentities)
838             LOG_INFOF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
839                 done = it.m_read(this, NULL, isnew);
840                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
841                 break;
842         });
843         time = savetime;
844         if (!done)
845         {
846                 LOG_FATALF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
847         }
848 }
849
850 // Destructor, but does NOT deallocate the entity by calling remove(). Also
851 // used when an entity changes its type. For an entity that someone interacts
852 // with others, make sure it can no longer do so.
853 void Ent_Remove(entity this)
854 {
855         if(this.entremove) this.entremove(this);
856
857         if(this.skeletonindex)
858         {
859                 skel_delete(this.skeletonindex);
860                 this.skeletonindex = 0;
861         }
862
863         if(this.snd_looping > 0)
864         {
865                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
866                 this.snd_looping = 0;
867         }
868
869         this.enttype = 0;
870         this.classname = "";
871         this.draw = func_null;
872         this.entremove = func_null;
873         // TODO possibly set more stuff to defaults
874 }
875 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
876 void CSQC_Ent_Remove(entity this)
877 {
878         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
879         if (wasfreed(this))
880         {
881                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
882                 return;
883         }
884         if (this.enttype) Ent_Remove(this);
885         delete(this);
886 }
887
888 void Gamemode_Init()
889 {
890         if (!isdemo())
891         {
892                 if(!(calledhooks & HOOK_START))
893                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
894                 calledhooks |= HOOK_START;
895         }
896 }
897 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
898 void CSQC_Parse_StuffCmd(string strMessage)
899 {
900         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
901         localcmd(strMessage);
902 }
903 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
904 void CSQC_Parse_Print(string strMessage)
905 {
906         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
907         print(ColorTranslateRGB(strMessage));
908 }
909
910 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
911 void CSQC_Parse_CenterPrint(string strMessage)
912 {
913         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
914         centerprint_hud(strMessage);
915 }
916
917 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
918 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
919 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
920 bool CSQC_Parse_TempEntity()
921 {
922         // Acquire TE ID
923         int nTEID = ReadByte();
924
925         FOREACH(TempEntities, it.m_id == nTEID, {
926                 if (autocvar_developer_csqcentities)
927                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
928                 return it.m_read(NULL, NULL, true);
929         });
930
931         if (autocvar_developer_csqcentities)
932                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
933
934         // No special logic for this temporary entity; return 0 so the engine can handle it
935         return false;
936 }
937
938 string forcefog;
939 void Fog_Force()
940 {
941         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
942                 localcmd("\nr_drawfog 0\n");
943         else if (forcefog != "")
944                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
945 }
946
947 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
948 {
949         make_pure(this);
950         gametype = ReadRegistered(Gametypes);
951         teamplay = _MapInfo_GetTeamPlayBool(gametype);
952         HUD_ModIcons_SetFunc();
953         FOREACH(Scores, true, {
954                 strcpy(scores_label(it), ReadString());
955                 scores_flags(it) = ReadByte();
956         });
957         for (int i = 0; i < MAX_TEAMSCORE; ++i)
958         {
959                 strcpy(teamscores_label(i), ReadString());
960                 teamscores_flags(i) = ReadByte();
961         }
962         return = true;
963         Scoreboard_InitScores();
964         Gamemode_Init();
965 }
966
967 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
968 {
969         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
970
971         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
972         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
973         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
974         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
975         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
976         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
977         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
978         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
979
980         strcpy(forcefog, ReadString());
981
982         armorblockpercent = ReadByte() / 255.0;
983         damagepush_speedfactor = ReadByte() / 255.0;
984
985         serverflags = ReadByte();
986
987         g_trueaim_minrange = ReadCoord();
988
989         return = true;
990
991         MUTATOR_CALLHOOK(Ent_Init);
992
993         if (!postinit) PostInit();
994 }
995
996 float GetSpeedUnitFactor(int speed_unit)
997 {
998         switch(speed_unit)
999         {
1000                 default:
1001                 case 1:
1002                         return 1.0;
1003                 case 2:
1004                         return 0.0254;
1005                 case 3:
1006                         return 0.0254 * 3.6;
1007                 case 4:
1008                         return 0.0254 * 3.6 * 0.6213711922;
1009                 case 5:
1010                         return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1011         }
1012 }
1013
1014 string GetSpeedUnit(int speed_unit)
1015 {
1016         switch(speed_unit)
1017         {
1018                 default:
1019                 case 1:
1020                         return _(" qu/s");
1021                 case 2:
1022                         return _(" m/s");
1023                 case 3:
1024                         return _(" km/h");
1025                 case 4:
1026                         return _(" mph");
1027                 case 5:
1028                         return _(" knots");
1029         }
1030 }
1031
1032 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1033 {
1034         int b = ReadByte();
1035
1036         switch (b)
1037         {
1038                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1039                         race_checkpoint = ReadByte();
1040                         race_time = ReadInt24_t();
1041                         race_previousbesttime = ReadInt24_t();
1042                         race_mypreviousbesttime = ReadInt24_t();
1043                         string pbestname = ReadString();
1044                         if(autocvar_cl_race_cptimes_onlyself)
1045                         {
1046                                 race_previousbesttime = race_mypreviousbesttime;
1047                                 race_mypreviousbesttime = 0;
1048                                 strcpy(race_previousbestname, "");
1049                         }
1050                         else
1051                                 strcpy(race_previousbestname, pbestname);
1052
1053                         race_checkpointtime = time;
1054
1055                         if(race_checkpoint == 0 || race_checkpoint == 254)
1056                         {
1057                                 race_penaltyaccumulator = 0;
1058                                 race_laptime = time; // valid
1059                         }
1060                         break;
1061
1062                 case RACE_NET_CHECKPOINT_CLEAR:
1063                         race_laptime = 0;
1064                         race_checkpointtime = 0;
1065                         break;
1066
1067                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1068                         race_laptime = ReadCoord();
1069                         race_checkpointtime = -99999;
1070                         // fall through
1071                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1072                         race_nextcheckpoint = ReadByte();
1073
1074                         race_nextbesttime = ReadInt24_t();
1075                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1076                                 race_mybesttime = ReadInt24_t();
1077                         string newname = ReadString();
1078                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1079                         {
1080                                 race_nextbesttime = race_mybesttime;
1081                                 race_mybesttime = 0;
1082                                 strcpy(race_nextbestname, "");
1083                         }
1084                         else
1085                                 strcpy(race_nextbestname, newname);
1086                         break;
1087
1088                 case RACE_NET_CHECKPOINT_HIT_RACE:
1089                         race_mycheckpoint = ReadByte();
1090                         race_mycheckpointtime = time;
1091                         race_mycheckpointdelta = ReadInt24_t();
1092                         race_mycheckpointlapsdelta = ReadByte();
1093                         if(race_mycheckpointlapsdelta >= 128)
1094                                 race_mycheckpointlapsdelta -= 256;
1095                         int who = ReadByte();
1096                         if(who)
1097                                 strcpy(race_mycheckpointenemy, entcs_GetName(who - 1));
1098                         else
1099                                 strcpy(race_mycheckpointenemy, ""); // TODO: maybe string_null works fine here?
1100                         break;
1101
1102                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1103                         race_othercheckpoint = ReadByte();
1104                         race_othercheckpointtime = time;
1105                         race_othercheckpointdelta = ReadInt24_t();
1106                         race_othercheckpointlapsdelta = ReadByte();
1107                         if(race_othercheckpointlapsdelta >= 128)
1108                                 race_othercheckpointlapsdelta -= 256;
1109                         int what = ReadByte();
1110                         if(what)
1111                                 strcpy(race_othercheckpointenemy, entcs_GetName(what - 1));
1112                         else
1113                                 strcpy(race_othercheckpointenemy, ""); // TODO: maybe string_null works fine here?
1114                         break;
1115
1116                 case RACE_NET_PENALTY_RACE:
1117                         race_penaltyeventtime = time;
1118                         race_penaltytime = ReadShort();
1119                         //race_penaltyaccumulator += race_penaltytime;
1120                         strcpy(race_penaltyreason, ReadString());
1121                         break;
1122
1123                 case RACE_NET_PENALTY_QUALIFYING:
1124                         race_penaltyeventtime = time;
1125                         race_penaltytime = ReadShort();
1126                         race_penaltyaccumulator += race_penaltytime;
1127                         strcpy(race_penaltyreason, ReadString());
1128                         break;
1129
1130                 case RACE_NET_SERVER_RECORD:
1131                         race_server_record = ReadInt24_t();
1132                         break;
1133                 case RACE_NET_SPEED_AWARD:
1134                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1135                         strcpy(race_speedaward_holder, ReadString());
1136                         strcpy(race_speedaward_unit, GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1137                         break;
1138                 case RACE_NET_SPEED_AWARD_BEST:
1139                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1140                         strcpy(race_speedaward_alltimebest_holder, ReadString());
1141                         strcpy(race_speedaward_alltimebest_unit, GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1142                         break;
1143                 case RACE_NET_RANKINGS_CNT:
1144                         RANKINGS_DISPLAY_CNT = ReadByte();
1145                         break;
1146                 case RACE_NET_SERVER_RANKINGS:
1147                         float prevpos, del;
1148             int pos = ReadShort();
1149                         prevpos = ReadShort();
1150                         del = ReadShort();
1151
1152                         // move other rankings out of the way
1153             int i;
1154                         if (prevpos) {
1155                                 int m = min(prevpos, RANKINGS_DISPLAY_CNT);
1156                                 for (i=m-1; i>pos-1; --i) {
1157                                         grecordtime[i] = grecordtime[i-1];
1158                                         strcpy(grecordholder[i], grecordholder[i-1]);
1159                                 }
1160                         } else if (del) { // a record has been deleted by the admin
1161                                 for (i=pos-1; i<= RANKINGS_DISPLAY_CNT-1; ++i) {
1162                                         if (i == RANKINGS_DISPLAY_CNT-1) { // clear out last record
1163                                                 grecordtime[i] = 0;
1164                                                 strfree(grecordholder[i]);
1165                                         }
1166                                         else {
1167                                                 grecordtime[i] = grecordtime[i+1];
1168                                                 strcpy(grecordholder[i], grecordholder[i+1]);
1169                                         }
1170                                 }
1171                         } else { // player has no ranked record yet
1172                                 for (i=RANKINGS_DISPLAY_CNT-1;i>pos-1;--i) {
1173                                         grecordtime[i] = grecordtime[i-1];
1174                                         strcpy(grecordholder[i], grecordholder[i-1]);
1175                                 }
1176                         }
1177
1178                         if (grecordtime[RANKINGS_DISPLAY_CNT]) {
1179                                 // kick off the player who fell from the last displayed position
1180                                 grecordtime[RANKINGS_DISPLAY_CNT] = 0;
1181                                 strfree(grecordholder[RANKINGS_DISPLAY_CNT]);
1182                         }
1183
1184                         // store new ranking
1185                         strcpy(grecordholder[pos-1], ReadString());
1186                         grecordtime[pos-1] = ReadInt24_t();
1187                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1188                                 race_myrank = pos;
1189                         break;
1190                 case RACE_NET_SERVER_STATUS:
1191                         race_status = ReadShort();
1192                         strcpy(race_status_name, ReadString());
1193         }
1194         return true;
1195 }
1196
1197 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1198 {
1199         teamnagger = 1;
1200         return true;
1201 }
1202
1203 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1204 {
1205         int i = ReadByte();
1206         int pi = ReadShort();
1207         int pl = ReadByte();
1208         int ml = ReadByte();
1209         return = true;
1210         entity e = playerslots[i];
1211         if (!e) return;
1212         e.ping = pi;
1213         e.ping_packetloss = pl / 255.0;
1214         e.ping_movementloss = ml / 255.0;
1215 }
1216
1217 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1218 {
1219         int weapon_id = ReadByte();
1220         complain_weapon = Weapons_from(weapon_id);
1221         complain_weapon_type = ReadByte();
1222         return = true;
1223
1224         complain_weapon_time = time;
1225         weapontime = time; // ping the weapon panel
1226
1227         switch(complain_weapon_type)
1228         {
1229                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, weapon_id); break;
1230                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, weapon_id); break;
1231                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, weapon_id); break;
1232         }
1233 }
1234
1235 string _getcommandkey(string cmd_name, string command, bool forcename)
1236 {
1237         string keys;
1238         float n, j, k, l = 0;
1239
1240         if (!autocvar_hud_showbinds)
1241                 return cmd_name;
1242
1243         keys = db_get(binddb, command);
1244         if (keys == "")
1245         {
1246                 bool joy_active = cvar("joy_active");
1247                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1248                 for(j = 0; j < n; ++j)
1249                 {
1250                         k = stof(argv(j));
1251                         if(k != -1)
1252                         {
1253                                 string key = keynumtostring(k);
1254                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1255                                         continue;
1256
1257                                 if (keys == "")
1258                                         keys = key;
1259                                 else
1260                                         keys = strcat(keys, ", ", key);
1261
1262                                 ++l;
1263                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1264                                         break;
1265                         }
1266
1267                 }
1268                 if (keys == "")
1269                         keys = "NO_KEY";
1270                 db_put(binddb, command, keys);
1271         }
1272
1273         if (keys == "NO_KEY") {
1274                 if (autocvar_hud_showbinds > 1)
1275                         return sprintf(_("%s (not bound)"), cmd_name);
1276                 else
1277                         return cmd_name;
1278         }
1279         else if (autocvar_hud_showbinds > 1 || forcename)
1280                 return sprintf("%s (%s)", cmd_name, keys);
1281         else
1282                 return keys;
1283 }