Merge branch 'master' into Mario/showspecs
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / main.qc
1 #include "mapvoting.qh"
2 #include "modeleffects.qh"
3 #include "particles.qh"
4 #include "scoreboard.qh"
5 #include "shownames.qh"
6 #include "target_music.qh"
7 #include "tturrets.qh"
8 #include "tuba.qh"
9 #include "wall.qh"
10 #include "waypointsprites.qh"
11
12 #include "vehicles/vehicles.qh"
13
14 #include "../server/vehicles/bumblebee.qh"
15
16 #include "../common/net_notice.qh"
17
18 #include "../common/monsters/monsters.qh"
19
20 #include "../warpzonelib/client.qh"
21
22 // --------------------------------------------------------------------------
23 // BEGIN REQUIRED CSQC FUNCTIONS
24 //include "main.qh"
25
26 entity clearentity_ent;
27 void clearentity(entity e)
28 {
29         if (!clearentity_ent)
30         {
31                 clearentity_ent = spawn();
32                 clearentity_ent.classname = "clearentity";
33         }
34         int n = e.entnum;
35         copyentity(clearentity_ent, e);
36         e.entnum = n;
37 }
38
39 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
40 void menu_show_error()
41 {
42         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
43 }
44
45 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
46 // Useful for precaching things
47
48 void menu_sub_null()
49 {
50 }
51
52 string forcefog;
53 void WaypointSprite_Load();
54 void ConsoleCommand_macro_init();
55 void CSQC_Init(void)
56 {
57         prvm_language = cvar_string("prvm_language");
58
59 #ifdef WATERMARK
60         dprintf("^4CSQC Build information: ^1%s\n", WATERMARK);
61 #endif
62
63         int i;
64
65         binddb = db_create();
66         tempdb = db_create();
67         ClientProgsDB = db_load("client.db");
68         compressShortVector_init();
69
70         draw_endBoldFont();
71         menu_visible = false;
72         menu_show = menu_show_error;
73         menu_action = func_null;
74
75         for(i = 0; i < 255; ++i)
76                 if(getplayerkeyvalue(i, "viewentity") == "")
77                         break;
78         maxclients = i;
79
80         //registercommand("hud_configure");
81         //registercommand("hud_save");
82         //registercommand("menu_action");
83
84         ConsoleCommand_macro_init();
85
86         registercvar("hud_usecsqc", "1");
87         registercvar("scoreboard_columns", "default");
88
89         registercvar("cl_nade_type", "3");
90         registercvar("cl_pokenade_type", "zombie");
91
92         gametype = 0;
93
94         // hud_fields uses strunzone on the titles!
95         for(i = 0; i < MAX_HUD_FIELDS; ++i)
96                 hud_title[i] = strzone("(null)");
97
98         Cmd_HUD_SetFields(0);
99
100         postinit = false;
101
102         calledhooks = 0;
103
104         teams = Sort_Spawn();
105         players = Sort_Spawn();
106
107         GetTeam(NUM_SPECTATOR, true); // add specs first
108
109         // needs to be done so early because of the constants they create
110         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
111         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
112         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
113         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
114         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
115         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
116         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
117
118         WaypointSprite_Load();
119
120         // precaches
121         precache_model("null");
122         precache_sound("misc/hit.wav");
123         precache_sound("misc/typehit.wav");
124
125         Projectile_Precache();
126         Hook_Precache();
127         GibSplash_Precache();
128         Casings_Precache();
129         Vehicles_Precache();
130         turrets_precache();
131         Tuba_Precache();
132         CSQCPlayer_Precache();
133
134         if(autocvar_cl_reticle)
135         {
136                 precache_pic("gfx/reticle_normal");
137                 // weapon reticles are precached in weapon files
138         }
139
140         get_mi_min_max_texcoords(1); // try the CLEVER way first
141         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
142         shortmapname = mi_shortname;
143
144         if(precache_pic(minimapname) == "")
145         {
146                 // but maybe we have a non-clever minimap
147                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
148                 if(precache_pic(minimapname) == "")
149                         minimapname = ""; // FAIL
150                 else
151                         get_mi_min_max_texcoords(0); // load new texcoords
152         }
153
154         mi_center = (mi_min + mi_max) * 0.5;
155         mi_scale = mi_max - mi_min;
156         minimapname = strzone(minimapname);
157
158         WarpZone_Init();
159
160         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
161         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
162 }
163
164 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
165 void Shutdown(void)
166 {
167         WarpZone_Shutdown();
168
169         remove(teams);
170         remove(players);
171         db_close(binddb);
172         db_close(tempdb);
173         if(autocvar_cl_db_saveasdump)
174                 db_dump(ClientProgsDB, "client.db");
175         else
176                 db_save(ClientProgsDB, "client.db");
177         db_close(ClientProgsDB);
178
179         if(camera_active)
180                 cvar_set("chase_active",ftos(chase_active_backup));
181
182         // unset the event chasecam's chase_active
183         if(autocvar_chase_active < 0)
184                 cvar_set("chase_active", "0");
185
186         if (!isdemo())
187         {
188                 if (!(calledhooks & HOOK_START))
189                         localcmd("\n_cl_hook_gamestart nop\n");
190                 if (!(calledhooks & HOOK_END))
191                         localcmd("\ncl_hook_gameend\n");
192         }
193 }
194
195 .float has_team;
196 float SetTeam(entity o, int Team)
197 {
198         entity tm;
199         if(teamplay)
200         {
201                 switch(Team)
202                 {
203                         case -1:
204                         case NUM_TEAM_1:
205                         case NUM_TEAM_2:
206                         case NUM_TEAM_3:
207                         case NUM_TEAM_4:
208                                 break;
209                         default:
210                                 if(GetTeam(Team, false) == world)
211                                 {
212                                         dprintf("trying to switch to unsupported team %d\n", Team);
213                                         Team = NUM_SPECTATOR;
214                                 }
215                                 break;
216                 }
217         }
218         else
219         {
220                 switch(Team)
221                 {
222                         case -1:
223                         case 0:
224                                 break;
225                         default:
226                                 if(GetTeam(Team, false) == world)
227                                 {
228                                         dprintf("trying to switch to unsupported team %d\n", Team);
229                                         Team = NUM_SPECTATOR;
230                                 }
231                                 break;
232                 }
233         }
234         if(Team == -1) // leave
235         {
236                 if(o.has_team)
237                 {
238                         tm = GetTeam(o.team, false);
239                         tm.team_size -= 1;
240                         o.has_team = 0;
241                         return true;
242                 }
243         }
244         else
245         {
246                 if (!o.has_team)
247                 {
248                         o.team = Team;
249                         tm = GetTeam(Team, true);
250                         tm.team_size += 1;
251                         o.has_team = 1;
252                         return true;
253                 }
254                 else if(Team != o.team)
255                 {
256                         tm = GetTeam(o.team, false);
257                         tm.team_size -= 1;
258                         o.team = Team;
259                         tm = GetTeam(Team, true);
260                         tm.team_size += 1;
261                         return true;
262                 }
263         }
264         return false;
265 }
266
267 void Playerchecker_Think()
268 {
269     int i;
270         entity e;
271         for(i = 0; i < maxclients; ++i)
272         {
273                 e = playerslots[i];
274                 if(GetPlayerName(i) == "")
275                 {
276                         if(e.sort_prev)
277                         {
278                                 // player disconnected
279                                 SetTeam(e, -1);
280                                 RemovePlayer(e);
281                                 e.sort_prev = world;
282                                 //e.gotscores = 0;
283                         }
284                 }
285                 else
286                 {
287                         if (!e.sort_prev)
288                         {
289                                 // player connected
290                                 if (!e)
291                                         playerslots[i] = e = spawn();
292                                 e.sv_entnum = i;
293                                 e.ping = 0;
294                                 e.ping_packetloss = 0;
295                                 e.ping_movementloss = 0;
296                                 //e.gotscores = 0; // we might already have the scores...
297                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
298                                 RegisterPlayer(e);
299                                 HUD_UpdatePlayerPos(e);
300                         }
301                 }
302         }
303         self.nextthink = time + 0.2;
304 }
305
306 void Porto_Init();
307 void TrueAim_Init();
308 void PostInit(void)
309 {
310         entity playerchecker;
311         playerchecker = spawn();
312         playerchecker.think = Playerchecker_Think;
313         playerchecker.nextthink = time + 0.2;
314
315         Porto_Init();
316         TrueAim_Init();
317
318         postinit = true;
319 }
320
321 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
322 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
323 // All keys are in ascii.
324 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
325 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
326 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
327 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
328 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
329 {
330         float bSkipKey;
331         bSkipKey = false;
332
333         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
334                 return true;
335
336         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
337                 return true;
338
339         if(menu_visible && menu_action)
340                 if(menu_action(bInputType, nPrimary, nSecondary))
341                         return true;
342
343         return bSkipKey;
344 }
345
346 // END REQUIRED CSQC FUNCTIONS
347 // --------------------------------------------------------------------------
348
349 // --------------------------------------------------------------------------
350 // BEGIN OPTIONAL CSQC FUNCTIONS
351 void Ent_RemoveEntCS()
352 {
353         entcs_receiver[self.sv_entnum] = world;
354 }
355 void Ent_ReadEntCS()
356 {
357     int sf;
358         InterpolateOrigin_Undo();
359
360         self.classname = "entcs_receiver";
361         sf = ReadByte();
362
363         if(sf & 1)
364                 self.sv_entnum = ReadByte();
365         if(sf & 2)
366         {
367                 self.origin_x = ReadShort();
368                 self.origin_y = ReadShort();
369                 self.origin_z = ReadShort();
370                 setorigin(self, self.origin);
371         }
372         if(sf & 4)
373         {
374                 self.angles_y = ReadByte() * 360.0 / 256;
375                 self.angles_x = self.angles_z = 0;
376         }
377         if(sf & 8)
378                 self.healthvalue = ReadByte() * 10;
379         if(sf & 16)
380                 self.armorvalue = ReadByte() * 10;
381
382         entcs_receiver[self.sv_entnum] = self;
383         self.entremove = Ent_RemoveEntCS;
384         self.iflags |= IFLAG_ORIGIN;
385
386         InterpolateOrigin_Note();
387 }
388
389 void Ent_Remove();
390
391 void Ent_RemovePlayerScore()
392 {
393         if(self.owner) {
394                 SetTeam(self.owner, -1);
395                 self.owner.gotscores = 0;
396                 for(int i = 0; i < MAX_SCORE; ++i) {
397                         self.owner.(scores[i]) = 0; // clear all scores
398                 }
399         }
400 }
401
402 void Ent_ReadPlayerScore()
403 {
404         int i, n;
405         bool isNew;
406         entity o;
407
408         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
409         // (no I've never heard of M-x replace-string, sed, or anything like that)
410         isNew = !self.owner; // workaround for DP bug
411         n = ReadByte()-1;
412
413 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
414         if(!isNew && n != self.sv_entnum)
415         {
416                 //print("A CSQC entity changed its owner!\n");
417                 printf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
418                 isNew = true;
419                 Ent_Remove();
420                 self.enttype = ENT_CLIENT_SCORES;
421         }
422 #endif
423
424         self.sv_entnum = n;
425
426         if (!(playerslots[self.sv_entnum]))
427                 playerslots[self.sv_entnum] = spawn();
428         o = self.owner = playerslots[self.sv_entnum];
429         o.sv_entnum = self.sv_entnum;
430         o.gotscores = 1;
431
432         //if (!o.sort_prev)
433         //      RegisterPlayer(o);
434         //playerchecker will do this for us later, if it has not already done so
435
436     int sf, lf;
437 #if MAX_SCORE <= 8
438         sf = ReadByte();
439         lf = ReadByte();
440 #else
441         sf = ReadShort();
442         lf = ReadShort();
443 #endif
444     int p;
445         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
446                 if(sf & p)
447                 {
448                         if(lf & p)
449                                 o.(scores[i]) = ReadInt24_t();
450                         else
451                                 o.(scores[i]) = ReadChar();
452                 }
453
454         if(o.sort_prev)
455                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
456
457         self.entremove = Ent_RemovePlayerScore;
458 }
459
460 void Ent_ReadTeamScore()
461 {
462         int i;
463         entity o;
464
465         self.team = ReadByte();
466         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
467
468     int sf, lf;
469 #if MAX_TEAMSCORE <= 8
470         sf = ReadByte();
471         lf = ReadByte();
472 #else
473         sf = ReadShort();
474         lf = ReadShort();
475 #endif
476         int p;
477         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
478                 if(sf & p)
479                 {
480                         if(lf & p)
481                                 o.(teamscores[i]) = ReadInt24_t();
482                         else
483                                 o.(teamscores[i]) = ReadChar();
484                 }
485
486         HUD_UpdateTeamPos(o);
487 }
488
489 void Ent_ClientData()
490 {
491         float newspectatee_status;
492
493     int f = ReadByte();
494
495         scoreboard_showscores_force = (f & 1);
496
497         if(f & 2)
498         {
499                 newspectatee_status = ReadByte();
500                 if(newspectatee_status == player_localnum + 1)
501                         newspectatee_status = -1; // observing
502         }
503         else
504                 newspectatee_status = 0;
505
506         spectatorbutton_zoom = (f & 4);
507
508         if(f & 8)
509         {
510                 angles_held_status = 1;
511                 angles_held.x = ReadAngle();
512                 angles_held.y = ReadAngle();
513                 angles_held.z = 0;
514         }
515         else
516                 angles_held_status = 0;
517
518         if(f & 16)
519         {
520                 num_spectators = ReadByte();
521
522                 float i, slot;
523
524                 for(i = 0; i < MAX_SPECTATORS; ++i)
525                         spectatorlist[i] = 0; // reset list first
526
527                 for(i = 0; i < num_spectators; ++i)
528                 {
529                         slot = ReadByte();
530                         spectatorlist[i] = slot - 1;
531                 }
532         }
533
534         if(newspectatee_status != spectatee_status)
535         {
536                 // clear race stuff
537                 race_laptime = 0;
538                 race_checkpointtime = 0;
539         }
540         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
541         {
542                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
543                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
544                 )
545                         prev_p_health = -1;
546                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
547                         prev_health = -1;
548         }
549         spectatee_status = newspectatee_status;
550
551         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
552 }
553
554 void Ent_Nagger()
555 {
556     int i, j, b, f;
557
558     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
559
560         if(!(nags & 4))
561         {
562                 if(vote_called_vote)
563                         strunzone(vote_called_vote);
564                 vote_called_vote = string_null;
565                 vote_active = 0;
566         }
567         else
568         {
569                 vote_active = 1;
570         }
571
572         if(nags & 64)
573         {
574                 vote_yescount = ReadByte();
575                 vote_nocount = ReadByte();
576                 vote_needed = ReadByte();
577                 vote_highlighted = ReadChar();
578         }
579
580         if(nags & 128)
581         {
582                 if(vote_called_vote)
583                         strunzone(vote_called_vote);
584                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
585         }
586
587         if(nags & 1)
588         {
589                 for(j = 0; j < maxclients; ++j)
590                         if(playerslots[j])
591                                 playerslots[j].ready = 1;
592                 for(i = 1; i <= maxclients; i += 8)
593                 {
594                         f = ReadByte();
595                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
596                                 if (!(f & b))
597                                         if(playerslots[j])
598                                                 playerslots[j].ready = 0;
599                 }
600         }
601
602         ready_waiting = (nags & 1);
603         ready_waiting_for_me = (nags & 2);
604         vote_waiting = (nags & 4);
605         vote_waiting_for_me = (nags & 8);
606         warmup_stage = (nags & 16);
607 }
608
609 void Ent_EliminatedPlayers()
610 {
611     int i, j, b, f;
612
613     int sf = ReadByte();
614         if(sf & 1)
615         {
616                 for(j = 0; j < maxclients; ++j)
617                         if(playerslots[j])
618                                 playerslots[j].eliminated = 1;
619                 for(i = 1; i <= maxclients; i += 8)
620                 {
621                         f = ReadByte();
622                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
623                                 if (!(f & b))
624                                         if(playerslots[j])
625                                                 playerslots[j].eliminated = 0;
626                 }
627         }
628 }
629
630 void Ent_RandomSeed()
631 {
632         float s;
633         prandom_debug();
634         s = ReadShort();
635         psrandom(s);
636 }
637
638 void Ent_ReadAccuracy(void)
639 {
640     int f, w;
641     int sf = ReadInt24_t();
642         if(sf == 0)
643         {
644                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
645                         weapon_accuracy[w] = -1;
646                 return;
647         }
648
649         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
650         {
651                 if(sf & f)
652                 {
653             int b = ReadByte();
654                         if(b == 0)
655                                 weapon_accuracy[w] = -1;
656                         else if(b == 255)
657                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
658                         else
659                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
660                 }
661                 if(f == 0x800000)
662                         f = 1;
663                 else
664                         f *= 2;
665         }
666 }
667
668 void Spawn_Draw(void)
669 {
670         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
671 }
672
673 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
674 {
675         float teamnum = (ReadByte() - 1);
676         vector spn_origin;
677         spn_origin.x = ReadShort();
678         spn_origin.y = ReadShort();
679         spn_origin.z = ReadShort();
680
681         if(is_new)
682         {
683                 self.origin = spn_origin;
684                 setsize(self, PL_MIN, PL_MAX);
685                 droptofloor();
686
687                 /*if(autocvar_cl_spawn_point_model) // needs a model first
688                 {
689                         self.mdl = "models/spawnpoint.md3";
690                         self.colormod = Team_ColorRGB(teamnum);
691                         precache_model(self.mdl);
692                         setmodel(self, self.mdl);
693                         self.drawmask = MASK_NORMAL;
694                         //self.movetype = MOVETYPE_NOCLIP;
695                         //self.draw = Spawn_Draw;
696                 }*/
697                 if(autocvar_cl_spawn_point_particles)
698                 {
699                         if((serverflags & SERVERFLAG_TEAMPLAY))
700                         {
701                                 switch(teamnum)
702                                 {
703                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
704                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
705                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
706                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
707                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
708                                 }
709                         }
710                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
711
712                         self.draw = Spawn_Draw;
713                 }
714         }
715
716         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
717 }
718
719 void Ent_ReadSpawnEvent(float is_new)
720 {
721         // If entnum is 0, ONLY do the local spawn actions
722         // this way the server can disable the sending of
723         // spawn origin or such to clients if wanted.
724         float entnum = ReadByte();
725
726         if(entnum)
727         {
728                 self.origin_x = ReadShort();
729                 self.origin_y = ReadShort();
730                 self.origin_z = ReadShort();
731
732                 if(is_new)
733                 {
734                         float teamnum = GetPlayerColor(entnum - 1);
735
736                         if(autocvar_cl_spawn_event_particles)
737                         {
738                                 switch(teamnum)
739                                 {
740                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
741                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
742                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
743                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
744                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
745                                 }
746                         }
747                         if(autocvar_cl_spawn_event_sound)
748                         {
749                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
750                         }
751                 }
752         }
753
754         // local spawn actions
755         if(is_new && (!entnum || (entnum == player_localentnum)))
756         {
757                 zoomin_effect = 1;
758                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
759
760                 if(autocvar_cl_unpress_zoom_on_spawn)
761                 {
762                         localcmd("-zoom\n");
763                         button_zoom = false;
764                 }
765         }
766
767         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
768 }
769
770 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
771 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
772 void Ent_RadarLink();
773 void Ent_Init();
774 void Ent_ScoresInfo();
775 void CSQC_Ent_Update(float bIsNewEntity)
776 {
777         float t;
778         float savetime;
779         t = ReadByte();
780
781         if(autocvar_developer_csqcentities)
782                 printf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
783
784         // set up the "time" global for received entities to be correct for interpolation purposes
785         savetime = time;
786         if(servertime)
787         {
788                 time = servertime;
789         }
790         else
791         {
792                 serverprevtime = time;
793                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
794                 time = serverprevtime + serverdeltatime;
795         }
796
797 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
798         if(self.enttype)
799         {
800                 if(t != self.enttype || bIsNewEntity)
801                 {
802                         //print("A CSQC entity changed its type!\n");
803                         printf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
804                         Ent_Remove();
805                         clearentity(self);
806                         bIsNewEntity = 1;
807                 }
808         }
809         else
810         {
811                 if(!bIsNewEntity)
812                 {
813                         printf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
814                         bIsNewEntity = 1;
815                 }
816         }
817 #endif
818         self.enttype = t;
819         switch(t)
820         {
821                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
822                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
823                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
824                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
825                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
826                 case ENT_CLIENT_LASER: Ent_Laser(); break;
827                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
828                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
829                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
830                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
831                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
832                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
833                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
834                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
835                 case ENT_CLIENT_INIT: Ent_Init(); break;
836                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
837                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
838                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
839                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
840                 case ENT_CLIENT_WALL: Ent_Wall(); break;
841                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
842                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
843                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
844                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
845                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
846                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
847                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
848                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
849                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
850                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
851                 case ENT_CLIENT_TURRET: ent_turret(); break;
852                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
853                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
854                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
855                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
856                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
857                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
858                 case ENT_CLIENT_HEALING_ORB: ent_healer(); break;
859
860                 default:
861                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
862                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
863                         break;
864         }
865
866         time = savetime;
867 }
868 // Destructor, but does NOT deallocate the entity by calling remove(). Also
869 // used when an entity changes its type. For an entity that someone interacts
870 // with others, make sure it can no longer do so.
871 void Ent_Remove()
872 {
873         if(self.entremove)
874                 self.entremove();
875
876         if(self.skeletonindex)
877         {
878                 skel_delete(self.skeletonindex);
879                 self.skeletonindex = 0;
880         }
881
882         if(self.snd_looping > 0)
883         {
884                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
885                 self.snd_looping = 0;
886         }
887
888         self.enttype = 0;
889         self.classname = "";
890         self.draw = menu_sub_null;
891         self.entremove = menu_sub_null;
892         // TODO possibly set more stuff to defaults
893 }
894 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
895 void CSQC_Ent_Remove()
896 {
897         if(autocvar_developer_csqcentities)
898                 printf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
899
900         if(wasfreed(self))
901         {
902                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
903                 return;
904         }
905         if(self.enttype)
906                 Ent_Remove();
907         remove(self);
908 }
909
910 void Gamemode_Init()
911 {
912         if (!isdemo())
913         {
914                 if(!(calledhooks & HOOK_START))
915                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
916                 calledhooks |= HOOK_START;
917         }
918 }
919 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
920 void CSQC_Parse_StuffCmd(string strMessage)
921 {
922         if(autocvar_developer_csqcentities)
923                 printf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
924
925         localcmd(strMessage);
926 }
927 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
928 void CSQC_Parse_Print(string strMessage)
929 {
930         if(autocvar_developer_csqcentities)
931                 printf("CSQC_Parse_Print(\"%s\")\n", strMessage);
932
933         print(ColorTranslateRGB(strMessage));
934 }
935
936 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
937 void CSQC_Parse_CenterPrint(string strMessage)
938 {
939         if(autocvar_developer_csqcentities)
940                 printf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
941
942         centerprint_hud(strMessage);
943 }
944
945 string notranslate_fogcmd1 = "\nfog ";
946 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
947 void Fog_Force()
948 {
949         // TODO somehow thwart prvm_globalset client ...
950
951         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
952                 { localcmd("\nr_drawfog 0\n"); }
953         else if(forcefog != "")
954                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
955 }
956
957 void Gamemode_Init();
958 void Ent_ScoresInfo()
959 {
960     int i;
961         self.classname = "ent_client_scores_info";
962         gametype = ReadInt24_t();
963         HUD_ModIcons_SetFunc();
964         for(i = 0; i < MAX_SCORE; ++i)
965         {
966                 if(scores_label[i])
967                         strunzone(scores_label[i]);
968                 scores_label[i] = strzone(ReadString());
969                 scores_flags[i] = ReadByte();
970         }
971         for(i = 0; i < MAX_TEAMSCORE; ++i)
972         {
973                 if(teamscores_label[i])
974                         strunzone(teamscores_label[i]);
975                 teamscores_label[i] = strzone(ReadString());
976                 teamscores_flags[i] = ReadByte();
977         }
978         HUD_InitScores();
979         Gamemode_Init();
980 }
981
982 void Ent_Init()
983 {
984         self.classname = "ent_client_init";
985
986         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
987
988         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
989         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
990         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
991         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
992         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
993         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
994         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
995         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
996
997         if(forcefog)
998                 strunzone(forcefog);
999         forcefog = strzone(ReadString());
1000
1001         armorblockpercent = ReadByte() / 255.0;
1002
1003         g_balance_mortar_bouncefactor = ReadCoord();
1004         g_balance_mortar_bouncestop = ReadCoord();
1005         g_balance_electro_secondary_bouncefactor = ReadCoord();
1006         g_balance_electro_secondary_bouncestop = ReadCoord();
1007
1008         vortex_scope = !ReadByte();
1009         rifle_scope = !ReadByte();
1010
1011         serverflags = ReadByte();
1012
1013         minelayer_maxmines = ReadByte();
1014
1015         hagar_maxrockets = ReadByte();
1016
1017         g_trueaim_minrange = ReadCoord();
1018         g_balance_porto_secondary = ReadByte();
1019
1020         if(!postinit)
1021                 PostInit();
1022 }
1023
1024 void Net_ReadRace()
1025 {
1026         float b;
1027
1028         b = ReadByte();
1029
1030         switch(b)
1031         {
1032                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1033                         race_checkpoint = ReadByte();
1034                         race_time = ReadInt24_t();
1035                         race_previousbesttime = ReadInt24_t();
1036                         if(race_previousbestname)
1037                                 strunzone(race_previousbestname);
1038                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1039
1040                         race_checkpointtime = time;
1041
1042                         if(race_checkpoint == 0 || race_checkpoint == 254)
1043                         {
1044                                 race_penaltyaccumulator = 0;
1045                                 race_laptime = time; // valid
1046                         }
1047
1048                         break;
1049
1050                 case RACE_NET_CHECKPOINT_CLEAR:
1051                         race_laptime = 0;
1052                         race_checkpointtime = 0;
1053                         break;
1054
1055                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1056                         race_laptime = ReadCoord();
1057                         race_checkpointtime = -99999;
1058                         // fall through
1059                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1060                         race_nextcheckpoint = ReadByte();
1061
1062                         race_nextbesttime = ReadInt24_t();
1063                         if(race_nextbestname)
1064                                 strunzone(race_nextbestname);
1065                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1066                         break;
1067
1068                 case RACE_NET_CHECKPOINT_HIT_RACE:
1069                         race_mycheckpoint = ReadByte();
1070                         race_mycheckpointtime = time;
1071                         race_mycheckpointdelta = ReadInt24_t();
1072                         race_mycheckpointlapsdelta = ReadByte();
1073                         if(race_mycheckpointlapsdelta >= 128)
1074                                 race_mycheckpointlapsdelta -= 256;
1075                         if(race_mycheckpointenemy)
1076                                 strunzone(race_mycheckpointenemy);
1077                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1078                         break;
1079
1080                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1081                         race_othercheckpoint = ReadByte();
1082                         race_othercheckpointtime = time;
1083                         race_othercheckpointdelta = ReadInt24_t();
1084                         race_othercheckpointlapsdelta = ReadByte();
1085                         if(race_othercheckpointlapsdelta >= 128)
1086                                 race_othercheckpointlapsdelta -= 256;
1087                         if(race_othercheckpointenemy)
1088                                 strunzone(race_othercheckpointenemy);
1089                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1090                         break;
1091
1092                 case RACE_NET_PENALTY_RACE:
1093                         race_penaltyeventtime = time;
1094                         race_penaltytime = ReadShort();
1095                         //race_penaltyaccumulator += race_penaltytime;
1096                         if(race_penaltyreason)
1097                                 strunzone(race_penaltyreason);
1098                         race_penaltyreason = strzone(ReadString());
1099                         break;
1100
1101                 case RACE_NET_PENALTY_QUALIFYING:
1102                         race_penaltyeventtime = time;
1103                         race_penaltytime = ReadShort();
1104                         race_penaltyaccumulator += race_penaltytime;
1105                         if(race_penaltyreason)
1106                                 strunzone(race_penaltyreason);
1107                         race_penaltyreason = strzone(ReadString());
1108                         break;
1109
1110                 case RACE_NET_SERVER_RECORD:
1111                         race_server_record = ReadInt24_t();
1112                         break;
1113                 case RACE_NET_SPEED_AWARD:
1114                         race_speedaward = ReadInt24_t();
1115                         if(race_speedaward_holder)
1116                                 strunzone(race_speedaward_holder);
1117                         race_speedaward_holder = strzone(ReadString());
1118                         break;
1119                 case RACE_NET_SPEED_AWARD_BEST:
1120                         race_speedaward_alltimebest = ReadInt24_t();
1121                         if(race_speedaward_alltimebest_holder)
1122                                 strunzone(race_speedaward_alltimebest_holder);
1123                         race_speedaward_alltimebest_holder = strzone(ReadString());
1124                         break;
1125                 case RACE_NET_SERVER_RANKINGS:
1126                         float prevpos, del;
1127             int pos = ReadShort();
1128                         prevpos = ReadShort();
1129                         del = ReadShort();
1130
1131                         // move other rankings out of the way
1132             int i;
1133                         if (prevpos) {
1134                                 for (i=prevpos-1;i>pos-1;--i) {
1135                                         grecordtime[i] = grecordtime[i-1];
1136                                         if(grecordholder[i])
1137                                                 strunzone(grecordholder[i]);
1138                                         grecordholder[i] = strzone(grecordholder[i-1]);
1139                                 }
1140                         } else if (del) { // a record has been deleted by the admin
1141                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1142                                         if (i == RANKINGS_CNT-1) { // clear out last record
1143                                                 grecordtime[i] = 0;
1144                                                 if (grecordholder[i])
1145                                                         strunzone(grecordholder[i]);
1146                                                 grecordholder[i] = string_null;
1147                                         }
1148                                         else {
1149                                                 grecordtime[i] = grecordtime[i+1];
1150                                                 if (grecordholder[i])
1151                                                         strunzone(grecordholder[i]);
1152                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1153                                         }
1154                                 }
1155                         } else { // player has no ranked record yet
1156                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1157                                         grecordtime[i] = grecordtime[i-1];
1158                                         if(grecordholder[i])
1159                                                 strunzone(grecordholder[i]);
1160                                         grecordholder[i] = strzone(grecordholder[i-1]);
1161                                 }
1162                         }
1163
1164                         // store new ranking
1165                         if(grecordholder[pos-1] != "")
1166                                 strunzone(grecordholder[pos-1]);
1167                         grecordholder[pos-1] = strzone(ReadString());
1168                         grecordtime[pos-1] = ReadInt24_t();
1169                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1170                                 race_myrank = pos;
1171                         break;
1172                 case RACE_NET_SERVER_STATUS:
1173                         race_status = ReadShort();
1174                         if(race_status_name)
1175                                 strunzone(race_status_name);
1176                         race_status_name = strzone(ReadString());
1177         }
1178 }
1179
1180 void Net_TeamNagger()
1181 {
1182         teamnagger = 1;
1183 }
1184
1185 void Net_ReadPingPLReport()
1186 {
1187         int e, pi, pl, ml;
1188         e = ReadByte();
1189         pi = ReadShort();
1190         pl = ReadByte();
1191         ml = ReadByte();
1192         if (!(playerslots[e]))
1193                 return;
1194         playerslots[e].ping = pi;
1195         playerslots[e].ping_packetloss = pl / 255.0;
1196         playerslots[e].ping_movementloss = ml / 255.0;
1197 }
1198
1199 void Net_WeaponComplain()
1200 {
1201         complain_weapon = ReadByte();
1202
1203         if(complain_weapon_name)
1204                 strunzone(complain_weapon_name);
1205         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1206
1207         complain_weapon_type = ReadByte();
1208
1209         complain_weapon_time = time;
1210         weapontime = time; // ping the weapon panel
1211
1212         switch(complain_weapon_type)
1213         {
1214                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1215                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1216                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1217         }
1218 }
1219
1220 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1221 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1222 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1223 float CSQC_Parse_TempEntity()
1224 {
1225         float bHandled;
1226                 bHandled  = true;
1227         // Acquire TE ID
1228         float nTEID;
1229                 nTEID = ReadByte();
1230
1231         if(autocvar_developer_csqcentities)
1232                 printf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1233
1234                 // NOTE: Could just do return instead of break...
1235         switch(nTEID)
1236         {
1237                 case TE_CSQC_TARGET_MUSIC:
1238                         Net_TargetMusic();
1239                         bHandled = true;
1240                         break;
1241                 case TE_CSQC_PICTURE:
1242                         Net_MapVote_Picture();
1243                         bHandled = true;
1244                         break;
1245                 case TE_CSQC_RACE:
1246                         Net_ReadRace();
1247                         bHandled = true;
1248                         break;
1249                 case TE_CSQC_VORTEXBEAMPARTICLE:
1250                         Net_ReadVortexBeamParticle();
1251                         bHandled = true;
1252                         break;
1253                 case TE_CSQC_TEAMNAGGER:
1254                         Net_TeamNagger();
1255                         bHandled = true;
1256                         break;
1257                 case TE_CSQC_ARC:
1258                         Net_ReadArc();
1259                         bHandled = true;
1260                         break;
1261                 case TE_CSQC_PINGPLREPORT:
1262                         Net_ReadPingPLReport();
1263                         bHandled = true;
1264                         break;
1265                 case TE_CSQC_WEAPONCOMPLAIN:
1266                         Net_WeaponComplain();
1267                         bHandled = true;
1268                         break;
1269                 case TE_CSQC_VEHICLESETUP:
1270                         Net_VehicleSetup();
1271                         bHandled = true;
1272                         break;
1273                 case TE_CSQC_SVNOTICE:
1274                         cl_notice_read();
1275                         bHandled = true;
1276                         break;
1277                 case TE_CSQC_SHOCKWAVEPARTICLE:
1278                         Net_ReadShockwaveParticle();
1279                         bHandled = true;
1280                         break;
1281                 default:
1282                         // No special logic for this temporary entity; return 0 so the engine can handle it
1283                         bHandled = false;
1284                         break;
1285         }
1286
1287         return bHandled;
1288 }
1289
1290 string getcommandkey(string text, string command)
1291 {
1292         string keys;
1293         float n, j, k, l = 0;
1294
1295         if (!autocvar_hud_showbinds)
1296                 return text;
1297
1298         keys = db_get(binddb, command);
1299         if (keys == "")
1300         {
1301                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1302                 for(j = 0; j < n; ++j)
1303                 {
1304                         k = stof(argv(j));
1305                         if(k != -1)
1306                         {
1307                                 if ("" == keys)
1308                                         keys = keynumtostring(k);
1309                                 else
1310                                         keys = strcat(keys, ", ", keynumtostring(k));
1311
1312                                 ++l;
1313                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1314                                         break;
1315                         }
1316
1317                 }
1318                 if (keys == "")
1319                         keys = "NO_KEY";
1320                 db_put(binddb, command, keys);
1321         }
1322
1323         if (keys == "NO_KEY") {
1324                 if (autocvar_hud_showbinds > 1)
1325                         return sprintf(_("%s (not bound)"), text);
1326                 else
1327                         return text;
1328         }
1329         else if (autocvar_hud_showbinds > 1)
1330                 return sprintf("%s (%s)", text, keys);
1331         else
1332                 return keys;
1333 }