qcsrc/client/main.qc

   1 #include "main.qh"
   2 #include "_all.qh"
   3
   4 #include "casings.qh"
   5 #include "csqcmodel_hooks.qh"
   6 #include "damage.qh"
   7 #include "effects.qh"
   8 #include "gibs.qh"
   9 #include "hook.qh"
  10 #include "hud.qh"
  11 #include "hud_config.qh"
  12 #include "laser.qh"
  13 #include "mapvoting.qh"
  14 #include "modeleffects.qh"
  15 #include "particles.qh"
  16 #include "prandom.qh"
  17 #include "scoreboard.qh"
  18 #include "shownames.qh"
  19 #include "sortlist.qh"
  20 #include "tturrets.qh"
  21 #include "tuba.qh"
  22 #include "t_items.qh"
  23 #include "wall.qh"
  24 #include "waypointsprites.qh"
  25
  26 #include "../common/vehicles/all.qh"
  27
  28 #include "weapons/projectile.qh"
  29
  30 #include "../common/buffs.qh"
  31 #include "../common/deathtypes.qh"
  32 #include "../common/effects.qh"
  33 #include "../common/mapinfo.qh"
  34 #include "../common/monsters/all.qh"
  35 #include "../common/nades.qh"
  36 #include "../common/net_notice.qh"
  37 #include "../common/notifications.qh"
  38 #include "../common/stats.qh"
  39 #include "../common/teams.qh"
  40
  41 #include "../common/items/all.qh"
  42
  43 #include "../common/mutators/base.qh"
  44
  45 #include "../common/weapons/all.qh"
  46
  47 #include "../csqcmodellib/cl_model.qh"
  48 #include "../csqcmodellib/interpolate.qh"
  49
  50 #include "../common/triggers/include.qh"
  51
  52 #include "../warpzonelib/client.qh"
  53
  54 // --------------------------------------------------------------------------
  55 // BEGIN REQUIRED CSQC FUNCTIONS
  56 //include "main.qh"
  57
  58 entity clearentity_ent;
  59 void clearentity(entity e)
  60 {
  61         if (!clearentity_ent)
  62         {
  63                 clearentity_ent = spawn();
  64                 clearentity_ent.classname = "clearentity";
  65         }
  66         int n = e.entnum;
  67         copyentity(clearentity_ent, e);
  68         e.entnum = n;
  69 }
  70
  71 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  72 void menu_show_error()
  73 {
  74         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  75 }
  76
  77 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  78 // Useful for precaching things
  79
  80 void menu_sub_null()
  81 {
  82 }
  83
  84 string forcefog;
  85 void WaypointSprite_Load();
  86 void ConsoleCommand_macro_init();
  87 void CSQC_Init(void)
  88 {
  89         prvm_language = cvar_string("prvm_language");
  90
  91 #ifdef WATERMARK
  92         dprintf("^4CSQC Build information: ^1%s\n", WATERMARK);
  93 #endif
  94
  95         int i;
  96
  97         binddb = db_create();
  98         tempdb = db_create();
  99         ClientProgsDB = db_load("client.db");
 100         compressShortVector_init();
 101
 102         draw_endBoldFont();
 103         menu_visible = false;
 104         menu_show = menu_show_error;
 105         menu_action = func_null;
 106
 107         for(i = 0; i < 255; ++i)
 108                 if(getplayerkeyvalue(i, "viewentity") == "")
 109                         break;
 110         maxclients = i;
 111
 112         //registercommand("hud_configure");
 113         //registercommand("hud_save");
 114         //registercommand("menu_action");
 115
 116         ConsoleCommand_macro_init();
 117
 118         registercvar("hud_usecsqc", "1");
 119         registercvar("scoreboard_columns", "default");
 120
 121         registercvar("cl_nade_type", "3");
 122         registercvar("cl_pokenade_type", "zombie");
 123
 124         registercvar("cl_jumpspeedcap_min", "");
 125         registercvar("cl_jumpspeedcap_max", "");
 126
 127         gametype = 0;
 128
 129         // hud_fields uses strunzone on the titles!
 130         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 131                 hud_title[i] = strzone("(null)");
 132
 133         Cmd_HUD_SetFields(0);
 134
 135         postinit = false;
 136
 137         calledhooks = 0;
 138
 139         teams = Sort_Spawn();
 140         players = Sort_Spawn();
 141
 142         GetTeam(NUM_SPECTATOR, true); // add specs first
 143
 144         // needs to be done so early because of the constants they create
 145         static_init();
 146         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 147         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 148         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
 149         CALL_ACCUMULATED_FUNCTION(RegisterEffects);
 150
 151         WaypointSprite_Load();
 152
 153         // precaches
 154         precache_model("null");
 155         precache_sound("misc/hit.wav");
 156         precache_sound("misc/typehit.wav");
 157
 158         Projectile_Precache();
 159         Hook_Precache();
 160         GibSplash_Precache();
 161         Casings_Precache();
 162         turrets_precache();
 163         Tuba_Precache();
 164         CSQCPlayer_Precache();
 165
 166         if(autocvar_cl_reticle)
 167         {
 168                 precache_pic("gfx/reticle_normal");
 169                 // weapon reticles are precached in weapon files
 170         }
 171
 172         get_mi_min_max_texcoords(1); // try the CLEVER way first
 173         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 174         shortmapname = mi_shortname;
 175
 176         if(precache_pic(minimapname) == "")
 177         {
 178                 // but maybe we have a non-clever minimap
 179                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 180                 if(precache_pic(minimapname) == "")
 181                         minimapname = ""; // FAIL
 182                 else
 183                         get_mi_min_max_texcoords(0); // load new texcoords
 184         }
 185
 186         mi_center = (mi_min + mi_max) * 0.5;
 187         mi_scale = mi_max - mi_min;
 188         minimapname = strzone(minimapname);
 189
 190         WarpZone_Init();
 191
 192         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 193         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 194 }
 195
 196 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 197 void Shutdown(void)
 198 {
 199         WarpZone_Shutdown();
 200
 201         remove(teams);
 202         remove(players);
 203         db_close(binddb);
 204         db_close(tempdb);
 205         if(autocvar_cl_db_saveasdump)
 206                 db_dump(ClientProgsDB, "client.db");
 207         else
 208                 db_save(ClientProgsDB, "client.db");
 209         db_close(ClientProgsDB);
 210
 211         if(camera_active)
 212                 cvar_set("chase_active",ftos(chase_active_backup));
 213
 214         // unset the event chasecam's chase_active
 215         if(autocvar_chase_active < 0)
 216                 cvar_set("chase_active", "0");
 217
 218         if (!isdemo())
 219         {
 220                 if (!(calledhooks & HOOK_START))
 221                         localcmd("\n_cl_hook_gamestart nop\n");
 222                 if (!(calledhooks & HOOK_END))
 223                         localcmd("\ncl_hook_gameend\n");
 224         }
 225 }
 226
 227 .float has_team;
 228 float SetTeam(entity o, int Team)
 229 {
 230         entity tm;
 231         if(teamplay)
 232         {
 233                 switch(Team)
 234                 {
 235                         case -1:
 236                         case NUM_TEAM_1:
 237                         case NUM_TEAM_2:
 238                         case NUM_TEAM_3:
 239                         case NUM_TEAM_4:
 240                                 break;
 241                         default:
 242                                 if(GetTeam(Team, false) == world)
 243                                 {
 244                                         dprintf("trying to switch to unsupported team %d\n", Team);
 245                                         Team = NUM_SPECTATOR;
 246                                 }
 247                                 break;
 248                 }
 249         }
 250         else
 251         {
 252                 switch(Team)
 253                 {
 254                         case -1:
 255                         case 0:
 256                                 break;
 257                         default:
 258                                 if(GetTeam(Team, false) == world)
 259                                 {
 260                                         dprintf("trying to switch to unsupported team %d\n", Team);
 261                                         Team = NUM_SPECTATOR;
 262                                 }
 263                                 break;
 264                 }
 265         }
 266         if(Team == -1) // leave
 267         {
 268                 if(o.has_team)
 269                 {
 270                         tm = GetTeam(o.team, false);
 271                         tm.team_size -= 1;
 272                         o.has_team = 0;
 273                         return true;
 274                 }
 275         }
 276         else
 277         {
 278                 if (!o.has_team)
 279                 {
 280                         o.team = Team;
 281                         tm = GetTeam(Team, true);
 282                         tm.team_size += 1;
 283                         o.has_team = 1;
 284                         return true;
 285                 }
 286                 else if(Team != o.team)
 287                 {
 288                         tm = GetTeam(o.team, false);
 289                         tm.team_size -= 1;
 290                         o.team = Team;
 291                         tm = GetTeam(Team, true);
 292                         tm.team_size += 1;
 293                         return true;
 294                 }
 295         }
 296         return false;
 297 }
 298
 299 void Playerchecker_Think()
 300 {
 301     int i;
 302         entity e;
 303         for(i = 0; i < maxclients; ++i)
 304         {
 305                 e = playerslots[i];
 306                 if(GetPlayerName(i) == "")
 307                 {
 308                         if(e.sort_prev)
 309                         {
 310                                 // player disconnected
 311                                 SetTeam(e, -1);
 312                                 RemovePlayer(e);
 313                                 e.sort_prev = world;
 314                                 //e.gotscores = 0;
 315                         }
 316                 }
 317                 else
 318                 {
 319                         if (!e.sort_prev)
 320                         {
 321                                 // player connected
 322                                 if (!e)
 323                                         playerslots[i] = e = spawn();
 324                                 e.sv_entnum = i;
 325                                 e.ping = 0;
 326                                 e.ping_packetloss = 0;
 327                                 e.ping_movementloss = 0;
 328                                 //e.gotscores = 0; // we might already have the scores...
 329                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 330                                 RegisterPlayer(e);
 331                                 HUD_UpdatePlayerPos(e);
 332                         }
 333                 }
 334         }
 335         self.nextthink = time + 0.2;
 336 }
 337
 338 void Porto_Init();
 339 void TrueAim_Init();
 340 void PostInit(void)
 341 {
 342         entity playerchecker;
 343         playerchecker = spawn();
 344         playerchecker.think = Playerchecker_Think;
 345         playerchecker.nextthink = time + 0.2;
 346
 347         Porto_Init();
 348         TrueAim_Init();
 349
 350         postinit = true;
 351 }
 352
 353 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 354 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 355 // All keys are in ascii.
 356 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 357 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 358 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 359 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 360 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 361 {
 362         float bSkipKey;
 363         bSkipKey = false;
 364
 365         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 366                 return true;
 367
 368         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 369                 return true;
 370
 371         if(menu_visible && menu_action)
 372                 if(menu_action(bInputType, nPrimary, nSecondary))
 373                         return true;
 374
 375         return bSkipKey;
 376 }
 377
 378 // END REQUIRED CSQC FUNCTIONS
 379 // --------------------------------------------------------------------------
 380
 381 // --------------------------------------------------------------------------
 382 // BEGIN OPTIONAL CSQC FUNCTIONS
 383
 384 void Ent_RemoveEntCS()
 385 {
 386         entcs_receiver[self.sv_entnum] = world;
 387 }
 388 void Ent_ReadEntCS()
 389 {
 390     int sf;
 391         InterpolateOrigin_Undo();
 392
 393         self.classname = "entcs_receiver";
 394         sf = ReadByte();
 395
 396         if(sf & 1)
 397                 self.sv_entnum = ReadByte();
 398         if(sf & 2)
 399         {
 400                 self.origin_x = ReadShort();
 401                 self.origin_y = ReadShort();
 402                 self.origin_z = ReadShort();
 403                 setorigin(self, self.origin);
 404         }
 405         if(sf & 4)
 406         {
 407                 self.angles_y = ReadByte() * 360.0 / 256;
 408                 self.angles_x = self.angles_z = 0;
 409         }
 410         if(sf & 8)
 411                 self.healthvalue = ReadByte() * 10;
 412         if(sf & 16)
 413                 self.armorvalue = ReadByte() * 10;
 414
 415         entcs_receiver[self.sv_entnum] = self;
 416         self.entremove = Ent_RemoveEntCS;
 417         self.iflags |= IFLAG_ORIGIN;
 418
 419         InterpolateOrigin_Note();
 420 }
 421
 422 void Ent_Remove();
 423
 424 void Ent_RemovePlayerScore()
 425 {
 426         if(self.owner) {
 427                 SetTeam(self.owner, -1);
 428                 self.owner.gotscores = 0;
 429                 for(int i = 0; i < MAX_SCORE; ++i) {
 430                         self.owner.(scores[i]) = 0; // clear all scores
 431                 }
 432         }
 433 }
 434
 435 void Ent_ReadPlayerScore()
 436 {
 437         int i, n;
 438         bool isNew;
 439         entity o;
 440
 441         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 442         // (no I've never heard of M-x replace-string, sed, or anything like that)
 443         isNew = !self.owner; // workaround for DP bug
 444         n = ReadByte()-1;
 445
 446 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 447         if(!isNew && n != self.sv_entnum)
 448         {
 449                 //print("A CSQC entity changed its owner!\n");
 450                 printf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 451                 isNew = true;
 452                 Ent_Remove();
 453                 self.enttype = ENT_CLIENT_SCORES;
 454         }
 455 #endif
 456
 457         self.sv_entnum = n;
 458
 459         if (!(playerslots[self.sv_entnum]))
 460                 playerslots[self.sv_entnum] = spawn();
 461         o = self.owner = playerslots[self.sv_entnum];
 462         o.sv_entnum = self.sv_entnum;
 463         o.gotscores = 1;
 464
 465         //if (!o.sort_prev)
 466         //      RegisterPlayer(o);
 467         //playerchecker will do this for us later, if it has not already done so
 468
 469     int sf, lf;
 470 #if MAX_SCORE <= 8
 471         sf = ReadByte();
 472         lf = ReadByte();
 473 #else
 474         sf = ReadShort();
 475         lf = ReadShort();
 476 #endif
 477     int p;
 478         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 479                 if(sf & p)
 480                 {
 481                         if(lf & p)
 482                                 o.(scores[i]) = ReadInt24_t();
 483                         else
 484                                 o.(scores[i]) = ReadChar();
 485                 }
 486
 487         if(o.sort_prev)
 488                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 489
 490         self.entremove = Ent_RemovePlayerScore;
 491 }
 492
 493 void Ent_ReadTeamScore()
 494 {
 495         int i;
 496         entity o;
 497
 498         self.team = ReadByte();
 499         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 500
 501     int sf, lf;
 502 #if MAX_TEAMSCORE <= 8
 503         sf = ReadByte();
 504         lf = ReadByte();
 505 #else
 506         sf = ReadShort();
 507         lf = ReadShort();
 508 #endif
 509         int p;
 510         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 511                 if(sf & p)
 512                 {
 513                         if(lf & p)
 514                                 o.(teamscores[i]) = ReadInt24_t();
 515                         else
 516                                 o.(teamscores[i]) = ReadChar();
 517                 }
 518
 519         HUD_UpdateTeamPos(o);
 520 }
 521
 522 void Ent_ClientData()
 523 {
 524         float newspectatee_status;
 525
 526     int f = ReadByte();
 527
 528         scoreboard_showscores_force = (f & 1);
 529
 530         if(f & 2)
 531         {
 532                 newspectatee_status = ReadByte();
 533                 if(newspectatee_status == player_localnum + 1)
 534                         newspectatee_status = -1; // observing
 535         }
 536         else
 537                 newspectatee_status = 0;
 538
 539         spectatorbutton_zoom = (f & 4);
 540
 541         if(f & 8)
 542         {
 543                 angles_held_status = 1;
 544                 angles_held.x = ReadAngle();
 545                 angles_held.y = ReadAngle();
 546                 angles_held.z = 0;
 547         }
 548         else
 549                 angles_held_status = 0;
 550
 551         if(newspectatee_status != spectatee_status)
 552         {
 553                 // clear race stuff
 554                 race_laptime = 0;
 555                 race_checkpointtime = 0;
 556         }
 557         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 558         {
 559                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 560                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 561                 )
 562                         prev_p_health = -1;
 563                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 564                         prev_health = -1;
 565         }
 566         spectatee_status = newspectatee_status;
 567
 568         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 569 }
 570
 571 void Ent_Nagger()
 572 {
 573     int i, j, b, f;
 574
 575     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 576
 577         if(!(nags & 4))
 578         {
 579                 if(vote_called_vote)
 580                         strunzone(vote_called_vote);
 581                 vote_called_vote = string_null;
 582                 vote_active = 0;
 583         }
 584         else
 585         {
 586                 vote_active = 1;
 587         }
 588
 589         if(nags & 64)
 590         {
 591                 vote_yescount = ReadByte();
 592                 vote_nocount = ReadByte();
 593                 vote_needed = ReadByte();
 594                 vote_highlighted = ReadChar();
 595         }
 596
 597         if(nags & 128)
 598         {
 599                 if(vote_called_vote)
 600                         strunzone(vote_called_vote);
 601                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 602         }
 603
 604         if(nags & 1)
 605         {
 606                 for(j = 0; j < maxclients; ++j)
 607                         if(playerslots[j])
 608                                 playerslots[j].ready = 1;
 609                 for(i = 1; i <= maxclients; i += 8)
 610                 {
 611                         f = ReadByte();
 612                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 613                                 if (!(f & b))
 614                                         if(playerslots[j])
 615                                                 playerslots[j].ready = 0;
 616                 }
 617         }
 618
 619         ready_waiting = (nags & 1);
 620         ready_waiting_for_me = (nags & 2);
 621         vote_waiting = (nags & 4);
 622         vote_waiting_for_me = (nags & 8);
 623         warmup_stage = (nags & 16);
 624 }
 625
 626 void Ent_EliminatedPlayers()
 627 {
 628     int i, j, b, f;
 629
 630     int sf = ReadByte();
 631         if(sf & 1)
 632         {
 633                 for(j = 0; j < maxclients; ++j)
 634                         if(playerslots[j])
 635                                 playerslots[j].eliminated = 1;
 636                 for(i = 1; i <= maxclients; i += 8)
 637                 {
 638                         f = ReadByte();
 639                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 640                                 if (!(f & b))
 641                                         if(playerslots[j])
 642                                                 playerslots[j].eliminated = 0;
 643                 }
 644         }
 645 }
 646
 647 void Ent_RandomSeed()
 648 {
 649         float s;
 650         prandom_debug();
 651         s = ReadShort();
 652         psrandom(s);
 653 }
 654
 655 void Ent_ReadAccuracy(void)
 656 {
 657     int f, w;
 658     int sf = ReadInt24_t();
 659         if(sf == 0)
 660         {
 661                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 662                         weapon_accuracy[w] = -1;
 663                 return;
 664         }
 665
 666         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 667         {
 668                 if(sf & f)
 669                 {
 670             int b = ReadByte();
 671                         if(b == 0)
 672                                 weapon_accuracy[w] = -1;
 673                         else if(b == 255)
 674                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 675                         else
 676                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 677                 }
 678                 if(f == 0x800000)
 679                         f = 1;
 680                 else
 681                         f *= 2;
 682         }
 683 }
 684
 685 void Spawn_Draw(void)
 686 {
 687         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 688 }
 689
 690 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 691 {
 692         float teamnum = (ReadByte() - 1);
 693         vector spn_origin;
 694         spn_origin.x = ReadShort();
 695         spn_origin.y = ReadShort();
 696         spn_origin.z = ReadShort();
 697
 698         if(is_new)
 699         {
 700                 self.origin = spn_origin;
 701                 setsize(self, PL_MIN_CONST, PL_MAX_CONST);
 702                 droptofloor();
 703
 704                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 705                 {
 706                         self.mdl = "models/spawnpoint.md3";
 707                         self.colormod = Team_ColorRGB(teamnum);
 708                         precache_model(self.mdl);
 709                         setmodel(self, self.mdl);
 710                         self.drawmask = MASK_NORMAL;
 711                         //self.movetype = MOVETYPE_NOCLIP;
 712                         //self.draw = Spawn_Draw;
 713                 }*/
 714                 if(autocvar_cl_spawn_point_particles)
 715                 {
 716                         if((serverflags & SERVERFLAG_TEAMPLAY))
 717                         {
 718                                 switch(teamnum)
 719                                 {
 720                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
 721                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
 722                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
 723                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
 724                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
 725                                 }
 726                         }
 727                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
 728
 729                         self.draw = Spawn_Draw;
 730                 }
 731         }
 732
 733         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 734 }
 735
 736 void Ent_ReadSpawnEvent(float is_new)
 737 {
 738         // If entnum is 0, ONLY do the local spawn actions
 739         // this way the server can disable the sending of
 740         // spawn origin or such to clients if wanted.
 741         float entnum = ReadByte();
 742
 743         if(entnum)
 744         {
 745                 self.origin_x = ReadShort();
 746                 self.origin_y = ReadShort();
 747                 self.origin_z = ReadShort();
 748
 749                 if(is_new)
 750                 {
 751                         float teamnum = GetPlayerColor(entnum - 1);
 752
 753                         if(autocvar_cl_spawn_event_particles)
 754                         {
 755                                 switch(teamnum)
 756                                 {
 757                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
 758                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
 759                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
 760                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
 761                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
 762                                 }
 763                         }
 764                         if(autocvar_cl_spawn_event_sound)
 765                         {
 766                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
 767                         }
 768                 }
 769         }
 770
 771         // local spawn actions
 772         if(is_new && (!entnum || (entnum == player_localentnum)))
 773         {
 774                 zoomin_effect = 1;
 775                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 776
 777                 if(autocvar_cl_unpress_zoom_on_spawn)
 778                 {
 779                         localcmd("-zoom\n");
 780                         button_zoom = false;
 781                 }
 782         }
 783
 784         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 785 }
 786
 787 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 788 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 789 void Ent_RadarLink();
 790 void Ent_Init();
 791 void Ent_ScoresInfo();
 792 void CSQC_Ent_Update(float bIsNewEntity)
 793 {
 794         float t;
 795         float savetime;
 796         t = ReadByte();
 797
 798         if(autocvar_developer_csqcentities)
 799                 printf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 800
 801         // set up the "time" global for received entities to be correct for interpolation purposes
 802         savetime = time;
 803         if(servertime)
 804         {
 805                 time = servertime;
 806         }
 807         else
 808         {
 809                 serverprevtime = time;
 810                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 811                 time = serverprevtime + serverdeltatime;
 812         }
 813
 814 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 815         if(self.enttype)
 816         {
 817                 if(t != self.enttype || bIsNewEntity)
 818                 {
 819                         //print("A CSQC entity changed its type!\n");
 820                         printf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 821                         Ent_Remove();
 822                         clearentity(self);
 823                         bIsNewEntity = 1;
 824                 }
 825         }
 826         else
 827         {
 828                 if(!bIsNewEntity)
 829                 {
 830                         printf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 831                         bIsNewEntity = 1;
 832                 }
 833         }
 834 #endif
 835         self.enttype = t;
 836         switch(t)
 837         {
 838                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 839                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 840                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 841                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 842                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 843                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 844                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 845                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
 846                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 847                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 848                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 849                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 850                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 851                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 852                 case ENT_CLIENT_INIT: Ent_Init(); break;
 853                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 854                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 855                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 856                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 857                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 858                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 859                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 860                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 861                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 862                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 863                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 864                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 865                 case ENT_CLIENT_INVENTORY: Inventory_Read(self); break;
 866                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
 867                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 868                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 869                 case ENT_CLIENT_TURRET: ent_turret(); break;
 870                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 871                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 872                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 873                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 874                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 875                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 876                 case ENT_CLIENT_HEALING_ORB: ent_healer(); break;
 877                 case ENT_CLIENT_VIEWLOC: ent_viewloc(); break;
 878                 case ENT_CLIENT_VIEWLOC_TRIGGER: ent_viewloc_trigger(); break;
 879                 case ENT_CLIENT_LADDER: ent_func_ladder(); break;
 880                 case ENT_CLIENT_TRIGGER_PUSH: ent_trigger_push(); break;
 881                 case ENT_CLIENT_TARGET_PUSH: ent_target_push(); break;
 882                 case ENT_CLIENT_CONVEYOR: ent_conveyor(); break;
 883                 case ENT_CLIENT_DOOR: ent_door(); break;
 884                 case ENT_CLIENT_PLAT: ent_plat(); break;
 885                 case ENT_CLIENT_SWAMP: ent_swamp(); break;
 886                 case ENT_CLIENT_CORNER: ent_corner(); break;
 887                 case ENT_CLIENT_KEYLOCK: ent_keylock(); break;
 888                 case ENT_CLIENT_TRAIN: ent_train(); break;
 889                 case ENT_CLIENT_TRIGGER_IMPULSE: ent_trigger_impulse(); break;
 890                 case ENT_CLIENT_EFFECT: Read_Effect(bIsNewEntity); break;
 891
 892                 default:
 893                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 894                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
 895                         break;
 896         }
 897
 898         time = savetime;
 899 }
 900 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 901 // used when an entity changes its type. For an entity that someone interacts
 902 // with others, make sure it can no longer do so.
 903 void Ent_Remove()
 904 {
 905         if(self.entremove)
 906                 self.entremove();
 907
 908         if(self.skeletonindex)
 909         {
 910                 skel_delete(self.skeletonindex);
 911                 self.skeletonindex = 0;
 912         }
 913
 914         if(self.snd_looping > 0)
 915         {
 916                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 917                 self.snd_looping = 0;
 918         }
 919
 920         self.enttype = 0;
 921         self.classname = "";
 922         self.draw = menu_sub_null;
 923         self.entremove = menu_sub_null;
 924         // TODO possibly set more stuff to defaults
 925 }
 926 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 927 void CSQC_Ent_Remove()
 928 {
 929         if(autocvar_developer_csqcentities)
 930                 printf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 931
 932         if(wasfreed(self))
 933         {
 934                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 935                 return;
 936         }
 937         if(self.enttype)
 938                 Ent_Remove();
 939         remove(self);
 940 }
 941
 942 void Gamemode_Init()
 943 {
 944         if (!isdemo())
 945         {
 946                 if(!(calledhooks & HOOK_START))
 947                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 948                 calledhooks |= HOOK_START;
 949         }
 950 }
 951 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 952 void CSQC_Parse_StuffCmd(string strMessage)
 953 {
 954         if(autocvar_developer_csqcentities)
 955                 printf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 956
 957         localcmd(strMessage);
 958 }
 959 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 960 void CSQC_Parse_Print(string strMessage)
 961 {
 962         if(autocvar_developer_csqcentities)
 963                 printf("CSQC_Parse_Print(\"%s\")\n", strMessage);
 964
 965         print(ColorTranslateRGB(strMessage));
 966 }
 967
 968 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 969 void CSQC_Parse_CenterPrint(string strMessage)
 970 {
 971         if(autocvar_developer_csqcentities)
 972                 printf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 973
 974         centerprint_hud(strMessage);
 975 }
 976
 977 string notranslate_fogcmd1 = "\nfog ";
 978 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 979 void Fog_Force()
 980 {
 981         // TODO somehow thwart prvm_globalset client ...
 982
 983         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 984                 { localcmd("\nr_drawfog 0\n"); }
 985         else if(forcefog != "")
 986                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
 987 }
 988
 989 void Gamemode_Init();
 990 void Ent_ScoresInfo()
 991 {
 992     int i;
 993         self.classname = "ent_client_scores_info";
 994         gametype = ReadInt24_t();
 995         HUD_ModIcons_SetFunc();
 996         for(i = 0; i < MAX_SCORE; ++i)
 997         {
 998                 if(scores_label[i])
 999                         strunzone(scores_label[i]);
1000                 scores_label[i] = strzone(ReadString());
1001                 scores_flags[i] = ReadByte();
1002         }
1003         for(i = 0; i < MAX_TEAMSCORE; ++i)
1004         {
1005                 if(teamscores_label[i])
1006                         strunzone(teamscores_label[i]);
1007                 teamscores_label[i] = strzone(ReadString());
1008                 teamscores_flags[i] = ReadByte();
1009         }
1010         HUD_InitScores();
1011         Gamemode_Init();
1012 }
1013
1014 void Ent_Init()
1015 {
1016         self.classname = "ent_client_init";
1017
1018         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1019
1020         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1021         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1022         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1023         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1024         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1025         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1026         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1027         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1028
1029         if(forcefog)
1030                 strunzone(forcefog);
1031         forcefog = strzone(ReadString());
1032
1033         armorblockpercent = ReadByte() / 255.0;
1034
1035         g_balance_mortar_bouncefactor = ReadCoord();
1036         g_balance_mortar_bouncestop = ReadCoord();
1037         g_balance_electro_secondary_bouncefactor = ReadCoord();
1038         g_balance_electro_secondary_bouncestop = ReadCoord();
1039
1040         vortex_scope = !ReadByte();
1041         rifle_scope = !ReadByte();
1042
1043         serverflags = ReadByte();
1044
1045         minelayer_maxmines = ReadByte();
1046
1047         hagar_maxrockets = ReadByte();
1048
1049         g_trueaim_minrange = ReadCoord();
1050         g_balance_porto_secondary = ReadByte();
1051
1052         if(!postinit)
1053                 PostInit();
1054 }
1055
1056 void Net_ReadRace()
1057 {
1058         float b;
1059
1060         b = ReadByte();
1061
1062         switch(b)
1063         {
1064                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1065                         race_checkpoint = ReadByte();
1066                         race_time = ReadInt24_t();
1067                         race_previousbesttime = ReadInt24_t();
1068                         if(race_previousbestname)
1069                                 strunzone(race_previousbestname);
1070                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1071
1072                         race_checkpointtime = time;
1073
1074                         if(race_checkpoint == 0 || race_checkpoint == 254)
1075                         {
1076                                 race_penaltyaccumulator = 0;
1077                                 race_laptime = time; // valid
1078                         }
1079
1080                         break;
1081
1082                 case RACE_NET_CHECKPOINT_CLEAR:
1083                         race_laptime = 0;
1084                         race_checkpointtime = 0;
1085                         break;
1086
1087                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1088                         race_laptime = ReadCoord();
1089                         race_checkpointtime = -99999;
1090                         // fall through
1091                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1092                         race_nextcheckpoint = ReadByte();
1093
1094                         race_nextbesttime = ReadInt24_t();
1095                         if(race_nextbestname)
1096                                 strunzone(race_nextbestname);
1097                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1098                         break;
1099
1100                 case RACE_NET_CHECKPOINT_HIT_RACE:
1101                         race_mycheckpoint = ReadByte();
1102                         race_mycheckpointtime = time;
1103                         race_mycheckpointdelta = ReadInt24_t();
1104                         race_mycheckpointlapsdelta = ReadByte();
1105                         if(race_mycheckpointlapsdelta >= 128)
1106                                 race_mycheckpointlapsdelta -= 256;
1107                         if(race_mycheckpointenemy)
1108                                 strunzone(race_mycheckpointenemy);
1109                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1110                         break;
1111
1112                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1113                         race_othercheckpoint = ReadByte();
1114                         race_othercheckpointtime = time;
1115                         race_othercheckpointdelta = ReadInt24_t();
1116                         race_othercheckpointlapsdelta = ReadByte();
1117                         if(race_othercheckpointlapsdelta >= 128)
1118                                 race_othercheckpointlapsdelta -= 256;
1119                         if(race_othercheckpointenemy)
1120                                 strunzone(race_othercheckpointenemy);
1121                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1122                         break;
1123
1124                 case RACE_NET_PENALTY_RACE:
1125                         race_penaltyeventtime = time;
1126                         race_penaltytime = ReadShort();
1127                         //race_penaltyaccumulator += race_penaltytime;
1128                         if(race_penaltyreason)
1129                                 strunzone(race_penaltyreason);
1130                         race_penaltyreason = strzone(ReadString());
1131                         break;
1132
1133                 case RACE_NET_PENALTY_QUALIFYING:
1134                         race_penaltyeventtime = time;
1135                         race_penaltytime = ReadShort();
1136                         race_penaltyaccumulator += race_penaltytime;
1137                         if(race_penaltyreason)
1138                                 strunzone(race_penaltyreason);
1139                         race_penaltyreason = strzone(ReadString());
1140                         break;
1141
1142                 case RACE_NET_SERVER_RECORD:
1143                         race_server_record = ReadInt24_t();
1144                         break;
1145                 case RACE_NET_SPEED_AWARD:
1146                         race_speedaward = ReadInt24_t();
1147                         if(race_speedaward_holder)
1148                                 strunzone(race_speedaward_holder);
1149                         race_speedaward_holder = strzone(ReadString());
1150                         break;
1151                 case RACE_NET_SPEED_AWARD_BEST:
1152                         race_speedaward_alltimebest = ReadInt24_t();
1153                         if(race_speedaward_alltimebest_holder)
1154                                 strunzone(race_speedaward_alltimebest_holder);
1155                         race_speedaward_alltimebest_holder = strzone(ReadString());
1156                         break;
1157                 case RACE_NET_SERVER_RANKINGS:
1158                         float prevpos, del;
1159             int pos = ReadShort();
1160                         prevpos = ReadShort();
1161                         del = ReadShort();
1162
1163                         // move other rankings out of the way
1164             int i;
1165                         if (prevpos) {
1166                                 for (i=prevpos-1;i>pos-1;--i) {
1167                                         grecordtime[i] = grecordtime[i-1];
1168                                         if(grecordholder[i])
1169                                                 strunzone(grecordholder[i]);
1170                                         grecordholder[i] = strzone(grecordholder[i-1]);
1171                                 }
1172                         } else if (del) { // a record has been deleted by the admin
1173                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1174                                         if (i == RANKINGS_CNT-1) { // clear out last record
1175                                                 grecordtime[i] = 0;
1176                                                 if (grecordholder[i])
1177                                                         strunzone(grecordholder[i]);
1178                                                 grecordholder[i] = string_null;
1179                                         }
1180                                         else {
1181                                                 grecordtime[i] = grecordtime[i+1];
1182                                                 if (grecordholder[i])
1183                                                         strunzone(grecordholder[i]);
1184                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1185                                         }
1186                                 }
1187                         } else { // player has no ranked record yet
1188                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1189                                         grecordtime[i] = grecordtime[i-1];
1190                                         if(grecordholder[i])
1191                                                 strunzone(grecordholder[i]);
1192                                         grecordholder[i] = strzone(grecordholder[i-1]);
1193                                 }
1194                         }
1195
1196                         // store new ranking
1197                         if(grecordholder[pos-1] != "")
1198                                 strunzone(grecordholder[pos-1]);
1199                         grecordholder[pos-1] = strzone(ReadString());
1200                         grecordtime[pos-1] = ReadInt24_t();
1201                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1202                                 race_myrank = pos;
1203                         break;
1204                 case RACE_NET_SERVER_STATUS:
1205                         race_status = ReadShort();
1206                         if(race_status_name)
1207                                 strunzone(race_status_name);
1208                         race_status_name = strzone(ReadString());
1209         }
1210 }
1211
1212 void Net_TeamNagger()
1213 {
1214         teamnagger = 1;
1215 }
1216
1217 void Net_ReadPingPLReport()
1218 {
1219         int e, pi, pl, ml;
1220         e = ReadByte();
1221         pi = ReadShort();
1222         pl = ReadByte();
1223         ml = ReadByte();
1224         if (!(playerslots[e]))
1225                 return;
1226         playerslots[e].ping = pi;
1227         playerslots[e].ping_packetloss = pl / 255.0;
1228         playerslots[e].ping_movementloss = ml / 255.0;
1229 }
1230
1231 void Net_WeaponComplain()
1232 {
1233         complain_weapon = ReadByte();
1234
1235         if(complain_weapon_name)
1236                 strunzone(complain_weapon_name);
1237         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1238
1239         complain_weapon_type = ReadByte();
1240
1241         complain_weapon_time = time;
1242         weapontime = time; // ping the weapon panel
1243
1244         switch(complain_weapon_type)
1245         {
1246                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1247                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1248                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1249         }
1250 }
1251
1252 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1253 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1254 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1255 float CSQC_Parse_TempEntity()
1256 {
1257         float bHandled;
1258                 bHandled  = true;
1259         // Acquire TE ID
1260         float nTEID;
1261                 nTEID = ReadByte();
1262
1263         if(autocvar_developer_csqcentities)
1264                 printf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1265
1266                 // NOTE: Could just do return instead of break...
1267         switch(nTEID)
1268         {
1269                 case TE_CSQC_TARGET_MUSIC:
1270                         Net_TargetMusic();
1271                         bHandled = true;
1272                         break;
1273                 case TE_CSQC_PICTURE:
1274                         Net_MapVote_Picture();
1275                         bHandled = true;
1276                         break;
1277                 case TE_CSQC_RACE:
1278                         Net_ReadRace();
1279                         bHandled = true;
1280                         break;
1281                 case TE_CSQC_VORTEXBEAMPARTICLE:
1282                         Net_ReadVortexBeamParticle();
1283                         bHandled = true;
1284                         break;
1285                 case TE_CSQC_TEAMNAGGER:
1286                         Net_TeamNagger();
1287                         bHandled = true;
1288                         break;
1289                 case TE_CSQC_ARC:
1290                         Net_ReadArc();
1291                         bHandled = true;
1292                         break;
1293                 case TE_CSQC_PINGPLREPORT:
1294                         Net_ReadPingPLReport();
1295                         bHandled = true;
1296                         break;
1297                 case TE_CSQC_WEAPONCOMPLAIN:
1298                         Net_WeaponComplain();
1299                         bHandled = true;
1300                         break;
1301                 case TE_CSQC_VEHICLESETUP:
1302                         Net_VehicleSetup();
1303                         bHandled = true;
1304                         break;
1305                 case TE_CSQC_SVNOTICE:
1306                         cl_notice_read();
1307                         bHandled = true;
1308                         break;
1309                 case TE_CSQC_SHOCKWAVEPARTICLE:
1310                         Net_ReadShockwaveParticle();
1311                         bHandled = true;
1312                         break;
1313                 default:
1314                         // No special logic for this temporary entity; return 0 so the engine can handle it
1315                         bHandled = false;
1316                         break;
1317         }
1318
1319         return bHandled;
1320 }
1321
1322 string getcommandkey(string text, string command)
1323 {
1324         string keys;
1325         float n, j, k, l = 0;
1326
1327         if (!autocvar_hud_showbinds)
1328                 return text;
1329
1330         keys = db_get(binddb, command);
1331         if (keys == "")
1332         {
1333                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1334                 for(j = 0; j < n; ++j)
1335                 {
1336                         k = stof(argv(j));
1337                         if(k != -1)
1338                         {
1339                                 if ("" == keys)
1340                                         keys = keynumtostring(k);
1341                                 else
1342                                         keys = strcat(keys, ", ", keynumtostring(k));
1343
1344                                 ++l;
1345                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1346                                         break;
1347                         }
1348
1349                 }
1350                 if (keys == "")
1351                         keys = "NO_KEY";
1352                 db_put(binddb, command, keys);
1353         }
1354
1355         if (keys == "NO_KEY") {
1356                 if (autocvar_hud_showbinds > 1)
1357                         return sprintf(_("%s (not bound)"), text);
1358                 else
1359                         return text;
1360         }
1361         else if (autocvar_hud_showbinds > 1)
1362                 return sprintf("%s (%s)", text, keys);
1363         else
1364                 return keys;
1365 }