qcsrc/client/main.qc

   1 #include "main.qh"
   2 #include "_all.qh"
   3
   4 #include "controlpoint.qh"
   5 #include "damage.qh"
   6 #include "effects.qh"
   7 #include "generator.qh"
   8 #include "gibs.qh"
   9 #include "hook.qh"
  10 #include "hud.qh"
  11 #include "hud_config.qh"
  12 #include "laser.qh"
  13 #include "mapvoting.qh"
  14 #include "modeleffects.qh"
  15 #include "particles.qh"
  16 #include "scoreboard.qh"
  17 #include "shownames.qh"
  18 #include "tuba.qh"
  19 #include "t_items.qh"
  20 #include "wall.qh"
  21
  22 #include "../common/vehicles/all.qh"
  23
  24 #include "mutators/events.qh"
  25
  26 #include "weapons/projectile.qh"
  27
  28 #include "../common/buffs.qh"
  29 #include "../common/deathtypes.qh"
  30 #include "../common/effects/effects.qh"
  31 #include "../common/mapinfo.qh"
  32 #include "../common/monsters/all.qh"
  33 #include "../common/nades.qh"
  34 #include "../common/net_notice.qh"
  35 #include "../common/notifications.qh"
  36 #include "../common/stats.qh"
  37 #include "../common/teams.qh"
  38
  39 #include "../common/items/all.qh"
  40
  41 #include "../common/mutators/base.qh"
  42
  43 #include "../common/weapons/all.qh"
  44
  45 #include "../csqcmodellib/cl_model.qh"
  46 #include "../csqcmodellib/interpolate.qh"
  47
  48 #include "../common/triggers/include.qh"
  49
  50 #include "../common/turrets/cl_turrets.qh"
  51
  52 #include "../warpzonelib/client.qh"
  53
  54 // --------------------------------------------------------------------------
  55 // BEGIN REQUIRED CSQC FUNCTIONS
  56 //include "main.qh"
  57
  58 entity clearentity_ent;
  59 void clearentity(entity e)
  60 {
  61         if (!clearentity_ent)
  62         {
  63                 clearentity_ent = spawn();
  64                 clearentity_ent.classname = "clearentity";
  65         }
  66         int n = e.entnum;
  67         copyentity(clearentity_ent, e);
  68         e.entnum = n;
  69 }
  70
  71 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  72 void menu_show_error()
  73 {
  74         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  75 }
  76
  77 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  78 // Useful for precaching things
  79
  80 void menu_sub_null()
  81 {
  82 }
  83
  84 string forcefog;
  85 void ConsoleCommand_macro_init();
  86 void CSQC_Init(void)
  87 {
  88         prvm_language = strzone(cvar_string("prvm_language"));
  89
  90 #ifdef WATERMARK
  91         LOG_TRACEF("^4CSQC Build information: ^1%s\n", WATERMARK);
  92 #endif
  93
  94         int i;
  95
  96         binddb = db_create();
  97         tempdb = db_create();
  98         ClientProgsDB = db_load("client.db");
  99         compressShortVector_init();
 100
 101         draw_endBoldFont();
 102         menu_visible = false;
 103         menu_show = menu_show_error;
 104         menu_action = func_null;
 105
 106         for(i = 0; i < 255; ++i)
 107                 if(getplayerkeyvalue(i, "viewentity") == "")
 108                         break;
 109         maxclients = i;
 110
 111         //registercommand("hud_configure");
 112         //registercommand("hud_save");
 113         //registercommand("menu_action");
 114
 115         ConsoleCommand_macro_init();
 116
 117         registercvar("hud_usecsqc", "1");
 118         registercvar("scoreboard_columns", "default");
 119
 120         registercvar("cl_nade_type", "3");
 121         registercvar("cl_pokenade_type", "zombie");
 122
 123         registercvar("cl_jumpspeedcap_min", "");
 124         registercvar("cl_jumpspeedcap_max", "");
 125
 126         registercvar("cl_multijump", "0");
 127
 128         registercvar("cl_spawn_near_teammate", "1");
 129
 130         gametype = 0;
 131
 132         // hud_fields uses strunzone on the titles!
 133         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 134                 hud_title[i] = strzone("(null)");
 135
 136         Cmd_HUD_SetFields(0);
 137
 138         postinit = false;
 139
 140         calledhooks = 0;
 141
 142         teams = Sort_Spawn();
 143         players = Sort_Spawn();
 144
 145         GetTeam(NUM_SPECTATOR, true); // add specs first
 146
 147         // needs to be done so early because of the constants they create
 148         static_init();
 149         CALL_ACCUMULATED_FUNCTION(RegisterTurrets);
 150         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 151         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 152         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
 153
 154         // precaches
 155
 156         Projectile_Precache();
 157         Tuba_Precache();
 158
 159         if(autocvar_cl_reticle)
 160         {
 161                 precache_pic("gfx/reticle_normal");
 162                 // weapon reticles are precached in weapon files
 163         }
 164
 165         get_mi_min_max_texcoords(1); // try the CLEVER way first
 166         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 167         shortmapname = mi_shortname;
 168
 169         if(precache_pic(minimapname) == "")
 170         {
 171                 // but maybe we have a non-clever minimap
 172                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 173                 if(precache_pic(minimapname) == "")
 174                         minimapname = ""; // FAIL
 175                 else
 176                         get_mi_min_max_texcoords(0); // load new texcoords
 177         }
 178
 179         mi_center = (mi_min + mi_max) * 0.5;
 180         mi_scale = mi_max - mi_min;
 181         minimapname = strzone(minimapname);
 182
 183         WarpZone_Init();
 184
 185         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 186         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 187 }
 188
 189 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 190 void Shutdown(void)
 191 {
 192         WarpZone_Shutdown();
 193
 194         remove(teams);
 195         remove(players);
 196         db_close(binddb);
 197         db_close(tempdb);
 198         if(autocvar_cl_db_saveasdump)
 199                 db_dump(ClientProgsDB, "client.db");
 200         else
 201                 db_save(ClientProgsDB, "client.db");
 202         db_close(ClientProgsDB);
 203
 204         if(camera_active)
 205                 cvar_set("chase_active",ftos(chase_active_backup));
 206
 207         // unset the event chasecam's chase_active
 208         if(autocvar_chase_active < 0)
 209                 cvar_set("chase_active", "0");
 210
 211         if (!isdemo())
 212         {
 213                 if (!(calledhooks & HOOK_START))
 214                         localcmd("\n_cl_hook_gamestart nop\n");
 215                 if (!(calledhooks & HOOK_END))
 216                         localcmd("\ncl_hook_gameend\n");
 217         }
 218
 219         deactivate_minigame();
 220         HUD_MinigameMenu_Close();
 221 }
 222
 223 .float has_team;
 224 float SetTeam(entity o, int Team)
 225 {
 226         entity tm;
 227         if(teamplay)
 228         {
 229                 switch(Team)
 230                 {
 231                         case -1:
 232                         case NUM_TEAM_1:
 233                         case NUM_TEAM_2:
 234                         case NUM_TEAM_3:
 235                         case NUM_TEAM_4:
 236                                 break;
 237                         default:
 238                                 if(GetTeam(Team, false) == world)
 239                                 {
 240                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 241                                         Team = NUM_SPECTATOR;
 242                                 }
 243                                 break;
 244                 }
 245         }
 246         else
 247         {
 248                 switch(Team)
 249                 {
 250                         case -1:
 251                         case 0:
 252                                 break;
 253                         default:
 254                                 if(GetTeam(Team, false) == world)
 255                                 {
 256                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 257                                         Team = NUM_SPECTATOR;
 258                                 }
 259                                 break;
 260                 }
 261         }
 262         if(Team == -1) // leave
 263         {
 264                 if(o.has_team)
 265                 {
 266                         tm = GetTeam(o.team, false);
 267                         tm.team_size -= 1;
 268                         o.has_team = 0;
 269                         return true;
 270                 }
 271         }
 272         else
 273         {
 274                 if (!o.has_team)
 275                 {
 276                         o.team = Team;
 277                         tm = GetTeam(Team, true);
 278                         tm.team_size += 1;
 279                         o.has_team = 1;
 280                         return true;
 281                 }
 282                 else if(Team != o.team)
 283                 {
 284                         tm = GetTeam(o.team, false);
 285                         tm.team_size -= 1;
 286                         o.team = Team;
 287                         tm = GetTeam(Team, true);
 288                         tm.team_size += 1;
 289                         return true;
 290                 }
 291         }
 292         return false;
 293 }
 294
 295 void Playerchecker_Think()
 296 {SELFPARAM();
 297     int i;
 298         entity e;
 299         for(i = 0; i < maxclients; ++i)
 300         {
 301                 e = playerslots[i];
 302                 if(GetPlayerName(i) == "")
 303                 {
 304                         if(e.sort_prev)
 305                         {
 306                                 // player disconnected
 307                                 SetTeam(e, -1);
 308                                 RemovePlayer(e);
 309                                 e.sort_prev = world;
 310                                 //e.gotscores = 0;
 311                         }
 312                 }
 313                 else
 314                 {
 315                         if (!e.sort_prev)
 316                         {
 317                                 // player connected
 318                                 if (!e)
 319                                         playerslots[i] = e = spawn();
 320                                 e.sv_entnum = i;
 321                                 e.ping = 0;
 322                                 e.ping_packetloss = 0;
 323                                 e.ping_movementloss = 0;
 324                                 //e.gotscores = 0; // we might already have the scores...
 325                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 326                                 RegisterPlayer(e);
 327                                 HUD_UpdatePlayerPos(e);
 328                         }
 329                 }
 330         }
 331         self.nextthink = time + 0.2;
 332 }
 333
 334 void Porto_Init();
 335 void TrueAim_Init();
 336 void PostInit(void)
 337 {
 338         entity playerchecker;
 339         playerchecker = spawn();
 340         playerchecker.think = Playerchecker_Think;
 341         playerchecker.nextthink = time + 0.2;
 342
 343         Porto_Init();
 344         TrueAim_Init();
 345
 346         postinit = true;
 347 }
 348
 349 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 350 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 351 // All keys are in ascii.
 352 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 353 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 354 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 355 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 356 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 357 {
 358         float bSkipKey;
 359         bSkipKey = false;
 360
 361         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 362                 return true;
 363
 364         if (QuickMenu_InputEvent(bInputType, nPrimary, nSecondary))
 365                 return true;
 366
 367         if ( HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary) )
 368                 return true;
 369
 370         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 371                 return true;
 372
 373         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
 374                 return true;
 375
 376         if(menu_visible && menu_action)
 377                 if(menu_action(bInputType, nPrimary, nSecondary))
 378                         return true;
 379
 380         return bSkipKey;
 381 }
 382
 383 // END REQUIRED CSQC FUNCTIONS
 384 // --------------------------------------------------------------------------
 385
 386 // --------------------------------------------------------------------------
 387 // BEGIN OPTIONAL CSQC FUNCTIONS
 388
 389 void Ent_RemoveEntCS()
 390 {SELFPARAM();
 391         entcs_receiver[self.sv_entnum] = world;
 392 }
 393 void Ent_ReadEntCS()
 394 {SELFPARAM();
 395     int sf;
 396         InterpolateOrigin_Undo();
 397
 398         self.classname = "entcs_receiver";
 399         sf = ReadByte();
 400
 401         if(sf & 1)
 402                 self.sv_entnum = ReadByte();
 403         if(sf & 2)
 404         {
 405                 self.origin_x = ReadShort();
 406                 self.origin_y = ReadShort();
 407                 self.origin_z = ReadShort();
 408                 setorigin(self, self.origin);
 409         }
 410         if(sf & 4)
 411         {
 412                 self.angles_y = ReadByte() * 360.0 / 256;
 413                 self.angles_x = self.angles_z = 0;
 414         }
 415         if(sf & 8)
 416                 self.healthvalue = ReadByte() * 10;
 417         if(sf & 16)
 418                 self.armorvalue = ReadByte() * 10;
 419
 420         entcs_receiver[self.sv_entnum] = self;
 421         self.entremove = Ent_RemoveEntCS;
 422         self.iflags |= IFLAG_ORIGIN;
 423
 424         InterpolateOrigin_Note();
 425 }
 426
 427 void Ent_Remove();
 428
 429 void Ent_RemovePlayerScore()
 430 {SELFPARAM();
 431         if(self.owner) {
 432                 SetTeam(self.owner, -1);
 433                 self.owner.gotscores = 0;
 434                 for(int i = 0; i < MAX_SCORE; ++i) {
 435                         self.owner.(scores[i]) = 0; // clear all scores
 436                 }
 437         }
 438 }
 439
 440 void Ent_ReadPlayerScore()
 441 {SELFPARAM();
 442         int i, n;
 443         bool isNew;
 444         entity o;
 445
 446         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 447         // (no I've never heard of M-x replace-string, sed, or anything like that)
 448         isNew = !self.owner; // workaround for DP bug
 449         n = ReadByte()-1;
 450
 451 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 452         if(!isNew && n != self.sv_entnum)
 453         {
 454                 //print("A CSQC entity changed its owner!\n");
 455                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 456                 isNew = true;
 457                 Ent_Remove();
 458                 self.enttype = ENT_CLIENT_SCORES;
 459         }
 460 #endif
 461
 462         self.sv_entnum = n;
 463
 464         if (!(playerslots[self.sv_entnum]))
 465                 playerslots[self.sv_entnum] = spawn();
 466         o = self.owner = playerslots[self.sv_entnum];
 467         o.sv_entnum = self.sv_entnum;
 468         o.gotscores = 1;
 469
 470         //if (!o.sort_prev)
 471         //      RegisterPlayer(o);
 472         //playerchecker will do this for us later, if it has not already done so
 473
 474     int sf, lf;
 475 #if MAX_SCORE <= 8
 476         sf = ReadByte();
 477         lf = ReadByte();
 478 #else
 479         sf = ReadShort();
 480         lf = ReadShort();
 481 #endif
 482     int p;
 483         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 484                 if(sf & p)
 485                 {
 486                         if(lf & p)
 487                                 o.(scores[i]) = ReadInt24_t();
 488                         else
 489                                 o.(scores[i]) = ReadChar();
 490                 }
 491
 492         if(o.sort_prev)
 493                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 494
 495         self.entremove = Ent_RemovePlayerScore;
 496 }
 497
 498 void Ent_ReadTeamScore()
 499 {SELFPARAM();
 500         int i;
 501         entity o;
 502
 503         self.team = ReadByte();
 504         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 505
 506     int sf, lf;
 507 #if MAX_TEAMSCORE <= 8
 508         sf = ReadByte();
 509         lf = ReadByte();
 510 #else
 511         sf = ReadShort();
 512         lf = ReadShort();
 513 #endif
 514         int p;
 515         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 516                 if(sf & p)
 517                 {
 518                         if(lf & p)
 519                                 o.(teamscores[i]) = ReadInt24_t();
 520                         else
 521                                 o.(teamscores[i]) = ReadChar();
 522                 }
 523
 524         HUD_UpdateTeamPos(o);
 525 }
 526
 527 void Ent_ClientData()
 528 {
 529         float newspectatee_status;
 530
 531     int f = ReadByte();
 532
 533         scoreboard_showscores_force = (f & 1);
 534
 535         if(f & 2)
 536         {
 537                 newspectatee_status = ReadByte();
 538                 if(newspectatee_status == player_localnum + 1)
 539                         newspectatee_status = -1; // observing
 540         }
 541         else
 542                 newspectatee_status = 0;
 543
 544         spectatorbutton_zoom = (f & 4);
 545
 546         if(f & 8)
 547         {
 548                 angles_held_status = 1;
 549                 angles_held.x = ReadAngle();
 550                 angles_held.y = ReadAngle();
 551                 angles_held.z = 0;
 552         }
 553         else
 554                 angles_held_status = 0;
 555
 556         if(newspectatee_status != spectatee_status)
 557         {
 558                 // clear race stuff
 559                 race_laptime = 0;
 560                 race_checkpointtime = 0;
 561         }
 562         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 563         {
 564                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 565                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 566                 )
 567                         prev_p_health = -1;
 568                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 569                         prev_health = -1;
 570         }
 571         spectatee_status = newspectatee_status;
 572
 573         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 574 }
 575
 576 void Ent_Nagger()
 577 {
 578     int i, j, b, f;
 579
 580     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 581
 582         if(!(nags & 4))
 583         {
 584                 if(vote_called_vote)
 585                         strunzone(vote_called_vote);
 586                 vote_called_vote = string_null;
 587                 vote_active = 0;
 588         }
 589         else
 590         {
 591                 vote_active = 1;
 592         }
 593
 594         if(nags & 64)
 595         {
 596                 vote_yescount = ReadByte();
 597                 vote_nocount = ReadByte();
 598                 vote_needed = ReadByte();
 599                 vote_highlighted = ReadChar();
 600         }
 601
 602         if(nags & 128)
 603         {
 604                 if(vote_called_vote)
 605                         strunzone(vote_called_vote);
 606                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 607         }
 608
 609         if(nags & 1)
 610         {
 611                 for(j = 0; j < maxclients; ++j)
 612                         if(playerslots[j])
 613                                 playerslots[j].ready = 1;
 614                 for(i = 1; i <= maxclients; i += 8)
 615                 {
 616                         f = ReadByte();
 617                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 618                                 if (!(f & b))
 619                                         if(playerslots[j])
 620                                                 playerslots[j].ready = 0;
 621                 }
 622         }
 623
 624         ready_waiting = (nags & 1);
 625         ready_waiting_for_me = (nags & 2);
 626         vote_waiting = (nags & 4);
 627         vote_waiting_for_me = (nags & 8);
 628         warmup_stage = (nags & 16);
 629 }
 630
 631 void Ent_EliminatedPlayers()
 632 {
 633     int i, j, b, f;
 634
 635     int sf = ReadByte();
 636         if(sf & 1)
 637         {
 638                 for(j = 0; j < maxclients; ++j)
 639                         if(playerslots[j])
 640                                 playerslots[j].eliminated = 1;
 641                 for(i = 1; i <= maxclients; i += 8)
 642                 {
 643                         f = ReadByte();
 644                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 645                                 if (!(f & b))
 646                                         if(playerslots[j])
 647                                                 playerslots[j].eliminated = 0;
 648                 }
 649         }
 650 }
 651
 652 void Ent_RandomSeed()
 653 {
 654         float s;
 655         prandom_debug();
 656         s = ReadShort();
 657         psrandom(s);
 658 }
 659
 660 void Ent_ReadAccuracy(void)
 661 {
 662     int f, w;
 663     int sf = ReadInt24_t();
 664         if(sf == 0)
 665         {
 666                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 667                         weapon_accuracy[w] = -1;
 668                 return;
 669         }
 670
 671         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 672         {
 673                 if(sf & f)
 674                 {
 675             int b = ReadByte();
 676                         if(b == 0)
 677                                 weapon_accuracy[w] = -1;
 678                         else if(b == 255)
 679                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 680                         else
 681                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 682                 }
 683                 if(f == 0x800000)
 684                         f = 1;
 685                 else
 686                         f *= 2;
 687         }
 688 }
 689
 690 void Spawn_Draw(void)
 691 {SELFPARAM();
 692         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 693 }
 694
 695 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 696 {SELFPARAM();
 697         float teamnum = (ReadByte() - 1);
 698         vector spn_origin;
 699         spn_origin.x = ReadShort();
 700         spn_origin.y = ReadShort();
 701         spn_origin.z = ReadShort();
 702
 703         if(is_new)
 704         {
 705                 self.origin = spn_origin;
 706                 setsize(self, PL_MIN_CONST, PL_MAX_CONST);
 707                 droptofloor();
 708
 709                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 710                 {
 711                         self.mdl = "models/spawnpoint.md3";
 712                         self.colormod = Team_ColorRGB(teamnum);
 713                         precache_model(self.mdl);
 714                         setmodel(self, self.mdl);
 715                         self.drawmask = MASK_NORMAL;
 716                         //self.movetype = MOVETYPE_NOCLIP;
 717                         //self.draw = Spawn_Draw;
 718                 }*/
 719                 if(autocvar_cl_spawn_point_particles)
 720                 {
 721                         if((serverflags & SERVERFLAG_TEAMPLAY))
 722                         {
 723                                 switch(teamnum)
 724                                 {
 725                                         case NUM_TEAM_1: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
 726                                         case NUM_TEAM_2: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
 727                                         case NUM_TEAM_3: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
 728                                         case NUM_TEAM_4: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
 729                                         default: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
 730                                 }
 731                         }
 732                         else { self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
 733
 734                         self.draw = Spawn_Draw;
 735                 }
 736         }
 737
 738         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 739 }
 740
 741 void Ent_ReadSpawnEvent(float is_new)
 742 {SELFPARAM();
 743         // If entnum is 0, ONLY do the local spawn actions
 744         // this way the server can disable the sending of
 745         // spawn origin or such to clients if wanted.
 746         float entnum = ReadByte();
 747
 748         if(entnum)
 749         {
 750                 self.origin_x = ReadShort();
 751                 self.origin_y = ReadShort();
 752                 self.origin_z = ReadShort();
 753
 754                 if(is_new)
 755                 {
 756                         float teamnum = GetPlayerColor(entnum - 1);
 757
 758                         if(autocvar_cl_spawn_event_particles)
 759                         {
 760                                 switch(teamnum)
 761                                 {
 762                                         case NUM_TEAM_1: pointparticles(particleeffectnum(EFFECT_SPAWN_RED), self.origin, '0 0 0', 1); break;
 763                                         case NUM_TEAM_2: pointparticles(particleeffectnum(EFFECT_SPAWN_BLUE), self.origin, '0 0 0', 1); break;
 764                                         case NUM_TEAM_3: pointparticles(particleeffectnum(EFFECT_SPAWN_YELLOW), self.origin, '0 0 0', 1); break;
 765                                         case NUM_TEAM_4: pointparticles(particleeffectnum(EFFECT_SPAWN_PINK), self.origin, '0 0 0', 1); break;
 766                                         default: pointparticles(particleeffectnum(EFFECT_SPAWN_NEUTRAL), self.origin, '0 0 0', 1); break;
 767                                 }
 768                         }
 769                         if(autocvar_cl_spawn_event_sound)
 770                         {
 771                                 sound(self, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 772                         }
 773                 }
 774         }
 775
 776         // local spawn actions
 777         if(is_new && (!entnum || (entnum == player_localentnum)))
 778         {
 779                 zoomin_effect = 1;
 780                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 781
 782                 if(autocvar_cl_unpress_zoom_on_spawn)
 783                 {
 784                         localcmd("-zoom\n");
 785                         button_zoom = false;
 786                 }
 787         }
 788         HUD_Radar_Hide_Maximized();
 789         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 790 }
 791
 792 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 793 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 794 void Ent_RadarLink();
 795 void Ent_Init();
 796 void Ent_ScoresInfo();
 797 void CSQC_Ent_Update(float bIsNewEntity)
 798 {SELFPARAM();
 799         int t = ReadByte();
 800
 801         if(autocvar_developer_csqcentities)
 802                 LOG_INFOF("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 803
 804         // set up the "time" global for received entities to be correct for interpolation purposes
 805         float savetime = time;
 806         if(servertime)
 807         {
 808                 time = servertime;
 809         }
 810         else
 811         {
 812                 serverprevtime = time;
 813                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 814                 time = serverprevtime + serverdeltatime;
 815         }
 816
 817 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 818         if(self.enttype)
 819         {
 820                 if(t != self.enttype || bIsNewEntity)
 821                 {
 822                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 823                         Ent_Remove();
 824                         clearentity(self);
 825                         bIsNewEntity = 1;
 826                 }
 827         }
 828         else
 829         {
 830                 if(!bIsNewEntity)
 831                 {
 832                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 833                         bIsNewEntity = 1;
 834                 }
 835         }
 836 #endif
 837         self.enttype = t;
 838         bool done = false;
 839         FOREACH(Linked, it.m_id == t, LAMBDA(
 840                 it.m_read(self, bIsNewEntity);
 841                 done = true;
 842                 break;
 843         ));
 844         if (!done)
 845         switch(t)
 846         {
 847                 case ENT_CLIENT_MUTATOR: {
 848                         int mutID = ReadMutator();
 849                         if (!MUTATOR_CALLHOOK(CSQC_Ent_Update, mutID, bIsNewEntity))
 850                         error(sprintf("Unknown mutator type in CSQC_Ent_Update (mutID: %d, edict: %d, classname: %s)\n", mutID, num_for_edict(self), self.classname));
 851                         break;
 852                 }
 853                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 854                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 855                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 856                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 857                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 858                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 859                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 860                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
 861                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 862                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 863                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 864                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 865                 case ENT_CLIENT_INIT: Ent_Init(); break;
 866                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 867                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 868                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 869                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 870                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 871                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 872                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 873                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 874                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 875                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 876                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 877                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 878                 case ENT_CLIENT_INVENTORY: Inventory_Read(self); break;
 879                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
 880                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 881                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 882                 case ENT_CLIENT_TURRET: ent_turret(); break;
 883                 case ENT_CLIENT_GENERATOR: ent_generator(); break;
 884                 case ENT_CLIENT_CONTROLPOINT_ICON: ent_cpicon(); break;
 885                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 886                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 887                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 888                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 889                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 890                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 891                 case ENT_CLIENT_MINIGAME: ent_read_minigame(); break;
 892                 case ENT_CLIENT_VIEWLOC: ent_viewloc(); break;
 893                 case ENT_CLIENT_VIEWLOC_TRIGGER: ent_viewloc_trigger(); break;
 894                 case ENT_CLIENT_LADDER: ent_func_ladder(); break;
 895                 case ENT_CLIENT_TRIGGER_PUSH: ent_trigger_push(); break;
 896                 case ENT_CLIENT_TARGET_PUSH: ent_target_push(); break;
 897                 case ENT_CLIENT_CONVEYOR: ent_conveyor(); break;
 898                 case ENT_CLIENT_DOOR: ent_door(); break;
 899                 case ENT_CLIENT_PLAT: ent_plat(); break;
 900                 case ENT_CLIENT_SWAMP: ent_swamp(); break;
 901                 case ENT_CLIENT_CORNER: ent_corner(); break;
 902                 case ENT_CLIENT_KEYLOCK: ent_keylock(); break;
 903                 case ENT_CLIENT_TRAIN: ent_train(); break;
 904                 case ENT_CLIENT_TRIGGER_IMPULSE: ent_trigger_impulse(); break;
 905                 case ENT_CLIENT_EFFECT: Read_Effect(bIsNewEntity); break;
 906
 907                 default:
 908                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 909                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
 910                         break;
 911         }
 912
 913         time = savetime;
 914 }
 915 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 916 // used when an entity changes its type. For an entity that someone interacts
 917 // with others, make sure it can no longer do so.
 918 void Ent_Remove()
 919 {SELFPARAM();
 920         if(self.entremove)
 921                 self.entremove();
 922
 923         if(self.skeletonindex)
 924         {
 925                 skel_delete(self.skeletonindex);
 926                 self.skeletonindex = 0;
 927         }
 928
 929         if(self.snd_looping > 0)
 930         {
 931                 sound(self, self.snd_looping, SND_Null, VOL_BASE, autocvar_g_jetpack_attenuation);
 932                 self.snd_looping = 0;
 933         }
 934
 935         self.enttype = 0;
 936         self.classname = "";
 937         self.draw = menu_sub_null;
 938         self.entremove = menu_sub_null;
 939         // TODO possibly set more stuff to defaults
 940 }
 941 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 942 void CSQC_Ent_Remove()
 943 {SELFPARAM();
 944         if(autocvar_developer_csqcentities)
 945                 LOG_INFOF("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 946
 947         if(wasfreed(self))
 948         {
 949                 LOG_INFO("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 950                 return;
 951         }
 952         if(self.enttype)
 953                 Ent_Remove();
 954         remove(self);
 955 }
 956
 957 void Gamemode_Init()
 958 {
 959         if (!isdemo())
 960         {
 961                 if(!(calledhooks & HOOK_START))
 962                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 963                 calledhooks |= HOOK_START;
 964         }
 965 }
 966 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 967 void CSQC_Parse_StuffCmd(string strMessage)
 968 {
 969         if(autocvar_developer_csqcentities)
 970                 LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 971
 972         localcmd(strMessage);
 973 }
 974 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 975 void CSQC_Parse_Print(string strMessage)
 976 {
 977         if(autocvar_developer_csqcentities)
 978                 LOG_INFOF("CSQC_Parse_Print(\"%s\")\n", strMessage);
 979
 980         print(ColorTranslateRGB(strMessage));
 981 }
 982
 983 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 984 void CSQC_Parse_CenterPrint(string strMessage)
 985 {
 986         if(autocvar_developer_csqcentities)
 987                 LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 988
 989         centerprint_hud(strMessage);
 990 }
 991
 992 string notranslate_fogcmd1 = "\nfog ";
 993 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 994 void Fog_Force()
 995 {
 996         // TODO somehow thwart prvm_globalset client ...
 997
 998         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 999                 { localcmd("\nr_drawfog 0\n"); }
1000         else if(forcefog != "")
1001                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
1002 }
1003
1004 void Gamemode_Init();
1005 void Ent_ScoresInfo()
1006 {SELFPARAM();
1007     int i;
1008         self.classname = "ent_client_scores_info";
1009         gametype = ReadInt24_t();
1010         HUD_ModIcons_SetFunc();
1011         for(i = 0; i < MAX_SCORE; ++i)
1012         {
1013                 if(scores_label[i])
1014                         strunzone(scores_label[i]);
1015                 scores_label[i] = strzone(ReadString());
1016                 scores_flags[i] = ReadByte();
1017         }
1018         for(i = 0; i < MAX_TEAMSCORE; ++i)
1019         {
1020                 if(teamscores_label[i])
1021                         strunzone(teamscores_label[i]);
1022                 teamscores_label[i] = strzone(ReadString());
1023                 teamscores_flags[i] = ReadByte();
1024         }
1025         HUD_InitScores();
1026         Gamemode_Init();
1027 }
1028
1029 void Ent_Init()
1030 {SELFPARAM();
1031         self.classname = "ent_client_init";
1032
1033         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1034
1035         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1036         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1037         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1038         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1039         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1040         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1041         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1042         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1043
1044         if(forcefog)
1045                 strunzone(forcefog);
1046         forcefog = strzone(ReadString());
1047
1048         armorblockpercent = ReadByte() / 255.0;
1049
1050         g_balance_mortar_bouncefactor = ReadCoord();
1051         g_balance_mortar_bouncestop = ReadCoord();
1052         g_balance_electro_secondary_bouncefactor = ReadCoord();
1053         g_balance_electro_secondary_bouncestop = ReadCoord();
1054
1055         vortex_scope = !ReadByte();
1056         rifle_scope = !ReadByte();
1057
1058         serverflags = ReadByte();
1059
1060         minelayer_maxmines = ReadByte();
1061
1062         hagar_maxrockets = ReadByte();
1063
1064         g_trueaim_minrange = ReadCoord();
1065         g_balance_porto_secondary = ReadByte();
1066
1067         if(!postinit)
1068                 PostInit();
1069 }
1070
1071 void Net_ReadRace()
1072 {
1073         float b;
1074
1075         b = ReadByte();
1076
1077         switch(b)
1078         {
1079                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1080                         race_checkpoint = ReadByte();
1081                         race_time = ReadInt24_t();
1082                         race_previousbesttime = ReadInt24_t();
1083                         if(race_previousbestname)
1084                                 strunzone(race_previousbestname);
1085                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1086
1087                         race_checkpointtime = time;
1088
1089                         if(race_checkpoint == 0 || race_checkpoint == 254)
1090                         {
1091                                 race_penaltyaccumulator = 0;
1092                                 race_laptime = time; // valid
1093                         }
1094
1095                         break;
1096
1097                 case RACE_NET_CHECKPOINT_CLEAR:
1098                         race_laptime = 0;
1099                         race_checkpointtime = 0;
1100                         break;
1101
1102                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1103                         race_laptime = ReadCoord();
1104                         race_checkpointtime = -99999;
1105                         // fall through
1106                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1107                         race_nextcheckpoint = ReadByte();
1108
1109                         race_nextbesttime = ReadInt24_t();
1110                         if(race_nextbestname)
1111                                 strunzone(race_nextbestname);
1112                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1113                         break;
1114
1115                 case RACE_NET_CHECKPOINT_HIT_RACE:
1116                         race_mycheckpoint = ReadByte();
1117                         race_mycheckpointtime = time;
1118                         race_mycheckpointdelta = ReadInt24_t();
1119                         race_mycheckpointlapsdelta = ReadByte();
1120                         if(race_mycheckpointlapsdelta >= 128)
1121                                 race_mycheckpointlapsdelta -= 256;
1122                         if(race_mycheckpointenemy)
1123                                 strunzone(race_mycheckpointenemy);
1124                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1125                         break;
1126
1127                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1128                         race_othercheckpoint = ReadByte();
1129                         race_othercheckpointtime = time;
1130                         race_othercheckpointdelta = ReadInt24_t();
1131                         race_othercheckpointlapsdelta = ReadByte();
1132                         if(race_othercheckpointlapsdelta >= 128)
1133                                 race_othercheckpointlapsdelta -= 256;
1134                         if(race_othercheckpointenemy)
1135                                 strunzone(race_othercheckpointenemy);
1136                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1137                         break;
1138
1139                 case RACE_NET_PENALTY_RACE:
1140                         race_penaltyeventtime = time;
1141                         race_penaltytime = ReadShort();
1142                         //race_penaltyaccumulator += race_penaltytime;
1143                         if(race_penaltyreason)
1144                                 strunzone(race_penaltyreason);
1145                         race_penaltyreason = strzone(ReadString());
1146                         break;
1147
1148                 case RACE_NET_PENALTY_QUALIFYING:
1149                         race_penaltyeventtime = time;
1150                         race_penaltytime = ReadShort();
1151                         race_penaltyaccumulator += race_penaltytime;
1152                         if(race_penaltyreason)
1153                                 strunzone(race_penaltyreason);
1154                         race_penaltyreason = strzone(ReadString());
1155                         break;
1156
1157                 case RACE_NET_SERVER_RECORD:
1158                         race_server_record = ReadInt24_t();
1159                         break;
1160                 case RACE_NET_SPEED_AWARD:
1161                         race_speedaward = ReadInt24_t();
1162                         if(race_speedaward_holder)
1163                                 strunzone(race_speedaward_holder);
1164                         race_speedaward_holder = strzone(ReadString());
1165                         break;
1166                 case RACE_NET_SPEED_AWARD_BEST:
1167                         race_speedaward_alltimebest = ReadInt24_t();
1168                         if(race_speedaward_alltimebest_holder)
1169                                 strunzone(race_speedaward_alltimebest_holder);
1170                         race_speedaward_alltimebest_holder = strzone(ReadString());
1171                         break;
1172                 case RACE_NET_SERVER_RANKINGS:
1173                         float prevpos, del;
1174             int pos = ReadShort();
1175                         prevpos = ReadShort();
1176                         del = ReadShort();
1177
1178                         // move other rankings out of the way
1179             int i;
1180                         if (prevpos) {
1181                                 for (i=prevpos-1;i>pos-1;--i) {
1182                                         grecordtime[i] = grecordtime[i-1];
1183                                         if(grecordholder[i])
1184                                                 strunzone(grecordholder[i]);
1185                                         grecordholder[i] = strzone(grecordholder[i-1]);
1186                                 }
1187                         } else if (del) { // a record has been deleted by the admin
1188                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1189                                         if (i == RANKINGS_CNT-1) { // clear out last record
1190                                                 grecordtime[i] = 0;
1191                                                 if (grecordholder[i])
1192                                                         strunzone(grecordholder[i]);
1193                                                 grecordholder[i] = string_null;
1194                                         }
1195                                         else {
1196                                                 grecordtime[i] = grecordtime[i+1];
1197                                                 if (grecordholder[i])
1198                                                         strunzone(grecordholder[i]);
1199                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1200                                         }
1201                                 }
1202                         } else { // player has no ranked record yet
1203                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1204                                         grecordtime[i] = grecordtime[i-1];
1205                                         if(grecordholder[i])
1206                                                 strunzone(grecordholder[i]);
1207                                         grecordholder[i] = strzone(grecordholder[i-1]);
1208                                 }
1209                         }
1210
1211                         // store new ranking
1212                         if(grecordholder[pos-1] != "")
1213                                 strunzone(grecordholder[pos-1]);
1214                         grecordholder[pos-1] = strzone(ReadString());
1215                         grecordtime[pos-1] = ReadInt24_t();
1216                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1217                                 race_myrank = pos;
1218                         break;
1219                 case RACE_NET_SERVER_STATUS:
1220                         race_status = ReadShort();
1221                         if(race_status_name)
1222                                 strunzone(race_status_name);
1223                         race_status_name = strzone(ReadString());
1224         }
1225 }
1226
1227 void Net_TeamNagger()
1228 {
1229         teamnagger = 1;
1230 }
1231
1232 void Net_ReadPingPLReport()
1233 {
1234         int e, pi, pl, ml;
1235         e = ReadByte();
1236         pi = ReadShort();
1237         pl = ReadByte();
1238         ml = ReadByte();
1239         if (!(playerslots[e]))
1240                 return;
1241         playerslots[e].ping = pi;
1242         playerslots[e].ping_packetloss = pl / 255.0;
1243         playerslots[e].ping_movementloss = ml / 255.0;
1244 }
1245
1246 void Net_WeaponComplain()
1247 {
1248         complain_weapon = ReadByte();
1249
1250         if(complain_weapon_name)
1251                 strunzone(complain_weapon_name);
1252         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1253
1254         complain_weapon_type = ReadByte();
1255
1256         complain_weapon_time = time;
1257         weapontime = time; // ping the weapon panel
1258
1259         switch(complain_weapon_type)
1260         {
1261                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1262                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1263                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1264         }
1265 }
1266
1267 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1268 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1269 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1270 float CSQC_Parse_TempEntity()
1271 {
1272         // Acquire TE ID
1273         int nTEID = ReadByte();
1274
1275         if (autocvar_developer_csqcentities)
1276                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1277
1278         switch (nTEID)
1279         {
1280                 case TE_CSQC_MUTATOR:
1281                         int mutID = ReadMutator();
1282                         if (MUTATOR_CALLHOOK(CSQC_Parse_TempEntity, mutID))
1283                         return true;
1284                 case TE_CSQC_TARGET_MUSIC:
1285                         Net_TargetMusic();
1286                         return true;
1287                 case TE_CSQC_PICTURE:
1288                         Net_MapVote_Picture();
1289                         return true;
1290                 case TE_CSQC_RACE:
1291                         Net_ReadRace();
1292                         return true;
1293                 case TE_CSQC_VORTEXBEAMPARTICLE:
1294                         Net_ReadVortexBeamParticle();
1295                         return true;
1296                 case TE_CSQC_TEAMNAGGER:
1297                         Net_TeamNagger();
1298                         return true;
1299                 case TE_CSQC_ARC:
1300                         Net_ReadArc();
1301                         return true;
1302                 case TE_CSQC_PINGPLREPORT:
1303                         Net_ReadPingPLReport();
1304                         return true;
1305                 case TE_CSQC_WEAPONCOMPLAIN:
1306                         Net_WeaponComplain();
1307                         return true;
1308                 case TE_CSQC_VEHICLESETUP:
1309                         Net_VehicleSetup();
1310                         return true;
1311                 case TE_CSQC_SVNOTICE:
1312                         cl_notice_read();
1313                         return true;
1314                 case TE_CSQC_SHOCKWAVEPARTICLE:
1315                         Net_ReadShockwaveParticle();
1316                         return true;
1317                 default:
1318                         // No special logic for this temporary entity; return 0 so the engine can handle it
1319                         return false;
1320         }
1321 }
1322
1323 string getcommandkey(string text, string command)
1324 {
1325         string keys;
1326         float n, j, k, l = 0;
1327
1328         if (!autocvar_hud_showbinds)
1329                 return text;
1330
1331         keys = db_get(binddb, command);
1332         if (keys == "")
1333         {
1334                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1335                 for(j = 0; j < n; ++j)
1336                 {
1337                         k = stof(argv(j));
1338                         if(k != -1)
1339                         {
1340                                 if ("" == keys)
1341                                         keys = keynumtostring(k);
1342                                 else
1343                                         keys = strcat(keys, ", ", keynumtostring(k));
1344
1345                                 ++l;
1346                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1347                                         break;
1348                         }
1349
1350                 }
1351                 if (keys == "")
1352                         keys = "NO_KEY";
1353                 db_put(binddb, command, keys);
1354         }
1355
1356         if (keys == "NO_KEY") {
1357                 if (autocvar_hud_showbinds > 1)
1358                         return sprintf(_("%s (not bound)"), text);
1359                 else
1360                         return text;
1361         }
1362         else if (autocvar_hud_showbinds > 1)
1363                 return sprintf("%s (%s)", text, keys);
1364         else
1365                 return keys;
1366 }