qcsrc/client/main.qc

   1 #include "main.qh"
   2 #include "_all.qh"
   3
   4 #include "controlpoint.qh"
   5 #include "csqcmodel_hooks.qh"
   6 #include "damage.qh"
   7 #include "effects.qh"
   8 #include "generator.qh"
   9 #include "gibs.qh"
  10 #include "hook.qh"
  11 #include "hud.qh"
  12 #include "hud_config.qh"
  13 #include "laser.qh"
  14 #include "mapvoting.qh"
  15 #include "modeleffects.qh"
  16 #include "particles.qh"
  17 #include "scoreboard.qh"
  18 #include "shownames.qh"
  19 #include "tuba.qh"
  20 #include "t_items.qh"
  21 #include "wall.qh"
  22
  23 #include "../common/vehicles/all.qh"
  24
  25 #include "mutators/events.qh"
  26
  27 #include "weapons/projectile.qh"
  28
  29 #include "../common/buffs.qh"
  30 #include "../common/deathtypes.qh"
  31 #include "../common/effects.qh"
  32 #include "../common/mapinfo.qh"
  33 #include "../common/monsters/all.qh"
  34 #include "../common/nades.qh"
  35 #include "../common/net_notice.qh"
  36 #include "../common/notifications.qh"
  37 #include "../common/stats.qh"
  38 #include "../common/teams.qh"
  39
  40 #include "../common/items/all.qh"
  41
  42 #include "../common/mutators/base.qh"
  43
  44 #include "../common/weapons/all.qh"
  45
  46 #include "../csqcmodellib/cl_model.qh"
  47 #include "../csqcmodellib/interpolate.qh"
  48
  49 #include "../common/triggers/include.qh"
  50
  51 #include "../common/turrets/cl_turrets.qh"
  52 #include "../common/turrets/turrets.qh"
  53
  54 #include "../warpzonelib/client.qh"
  55
  56 // --------------------------------------------------------------------------
  57 // BEGIN REQUIRED CSQC FUNCTIONS
  58 //include "main.qh"
  59
  60 entity clearentity_ent;
  61 void clearentity(entity e)
  62 {
  63         if (!clearentity_ent)
  64         {
  65                 clearentity_ent = spawn();
  66                 clearentity_ent.classname = "clearentity";
  67         }
  68         int n = e.entnum;
  69         copyentity(clearentity_ent, e);
  70         e.entnum = n;
  71 }
  72
  73 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  74 void menu_show_error()
  75 {
  76         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  77 }
  78
  79 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  80 // Useful for precaching things
  81
  82 void menu_sub_null()
  83 {
  84 }
  85
  86 string forcefog;
  87 void ConsoleCommand_macro_init();
  88 void CSQC_Init(void)
  89 {
  90         prvm_language = strzone(cvar_string("prvm_language"));
  91
  92 #ifdef WATERMARK
  93         LOG_TRACEF("^4CSQC Build information: ^1%s\n", WATERMARK);
  94 #endif
  95
  96         int i;
  97
  98         binddb = db_create();
  99         tempdb = db_create();
 100         ClientProgsDB = db_load("client.db");
 101         compressShortVector_init();
 102
 103         draw_endBoldFont();
 104         menu_visible = false;
 105         menu_show = menu_show_error;
 106         menu_action = func_null;
 107
 108         for(i = 0; i < 255; ++i)
 109                 if(getplayerkeyvalue(i, "viewentity") == "")
 110                         break;
 111         maxclients = i;
 112
 113         //registercommand("hud_configure");
 114         //registercommand("hud_save");
 115         //registercommand("menu_action");
 116
 117         ConsoleCommand_macro_init();
 118
 119         registercvar("hud_usecsqc", "1");
 120         registercvar("scoreboard_columns", "default");
 121
 122         registercvar("cl_nade_type", "3");
 123         registercvar("cl_pokenade_type", "zombie");
 124
 125         registercvar("cl_jumpspeedcap_min", "");
 126         registercvar("cl_jumpspeedcap_max", "");
 127
 128         gametype = 0;
 129
 130         // hud_fields uses strunzone on the titles!
 131         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 132                 hud_title[i] = strzone("(null)");
 133
 134         Cmd_HUD_SetFields(0);
 135
 136         postinit = false;
 137
 138         calledhooks = 0;
 139
 140         teams = Sort_Spawn();
 141         players = Sort_Spawn();
 142
 143         GetTeam(NUM_SPECTATOR, true); // add specs first
 144
 145         // needs to be done so early because of the constants they create
 146         static_init();
 147         CALL_ACCUMULATED_FUNCTION(RegisterTurrets);
 148         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 149         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 150         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
 151
 152         initialize_minigames();
 153
 154         // precaches
 155         precache_model("null");
 156         precache_sound("misc/hit.wav");
 157         precache_sound("misc/typehit.wav");
 158
 159         generator_precache();
 160         Projectile_Precache();
 161         Hook_Precache();
 162         GibSplash_Precache();
 163         Tuba_Precache();
 164         CSQCPlayer_Precache();
 165
 166         if(autocvar_cl_reticle)
 167         {
 168                 precache_pic("gfx/reticle_normal");
 169                 // weapon reticles are precached in weapon files
 170         }
 171
 172         get_mi_min_max_texcoords(1); // try the CLEVER way first
 173         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 174         shortmapname = mi_shortname;
 175
 176         if(precache_pic(minimapname) == "")
 177         {
 178                 // but maybe we have a non-clever minimap
 179                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 180                 if(precache_pic(minimapname) == "")
 181                         minimapname = ""; // FAIL
 182                 else
 183                         get_mi_min_max_texcoords(0); // load new texcoords
 184         }
 185
 186         mi_center = (mi_min + mi_max) * 0.5;
 187         mi_scale = mi_max - mi_min;
 188         minimapname = strzone(minimapname);
 189
 190         WarpZone_Init();
 191
 192         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 193         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 194 }
 195
 196 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 197 void Shutdown(void)
 198 {
 199         WarpZone_Shutdown();
 200
 201         remove(teams);
 202         remove(players);
 203         db_close(binddb);
 204         db_close(tempdb);
 205         if(autocvar_cl_db_saveasdump)
 206                 db_dump(ClientProgsDB, "client.db");
 207         else
 208                 db_save(ClientProgsDB, "client.db");
 209         db_close(ClientProgsDB);
 210
 211         if(camera_active)
 212                 cvar_set("chase_active",ftos(chase_active_backup));
 213
 214         // unset the event chasecam's chase_active
 215         if(autocvar_chase_active < 0)
 216                 cvar_set("chase_active", "0");
 217
 218         if (!isdemo())
 219         {
 220                 if (!(calledhooks & HOOK_START))
 221                         localcmd("\n_cl_hook_gamestart nop\n");
 222                 if (!(calledhooks & HOOK_END))
 223                         localcmd("\ncl_hook_gameend\n");
 224         }
 225
 226         deactivate_minigame();
 227         HUD_MinigameMenu_Close();
 228 }
 229
 230 .float has_team;
 231 float SetTeam(entity o, int Team)
 232 {
 233         entity tm;
 234         if(teamplay)
 235         {
 236                 switch(Team)
 237                 {
 238                         case -1:
 239                         case NUM_TEAM_1:
 240                         case NUM_TEAM_2:
 241                         case NUM_TEAM_3:
 242                         case NUM_TEAM_4:
 243                                 break;
 244                         default:
 245                                 if(GetTeam(Team, false) == world)
 246                                 {
 247                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 248                                         Team = NUM_SPECTATOR;
 249                                 }
 250                                 break;
 251                 }
 252         }
 253         else
 254         {
 255                 switch(Team)
 256                 {
 257                         case -1:
 258                         case 0:
 259                                 break;
 260                         default:
 261                                 if(GetTeam(Team, false) == world)
 262                                 {
 263                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 264                                         Team = NUM_SPECTATOR;
 265                                 }
 266                                 break;
 267                 }
 268         }
 269         if(Team == -1) // leave
 270         {
 271                 if(o.has_team)
 272                 {
 273                         tm = GetTeam(o.team, false);
 274                         tm.team_size -= 1;
 275                         o.has_team = 0;
 276                         return true;
 277                 }
 278         }
 279         else
 280         {
 281                 if (!o.has_team)
 282                 {
 283                         o.team = Team;
 284                         tm = GetTeam(Team, true);
 285                         tm.team_size += 1;
 286                         o.has_team = 1;
 287                         return true;
 288                 }
 289                 else if(Team != o.team)
 290                 {
 291                         tm = GetTeam(o.team, false);
 292                         tm.team_size -= 1;
 293                         o.team = Team;
 294                         tm = GetTeam(Team, true);
 295                         tm.team_size += 1;
 296                         return true;
 297                 }
 298         }
 299         return false;
 300 }
 301
 302 void Playerchecker_Think()
 303 {
 304     int i;
 305         entity e;
 306         for(i = 0; i < maxclients; ++i)
 307         {
 308                 e = playerslots[i];
 309                 if(GetPlayerName(i) == "")
 310                 {
 311                         if(e.sort_prev)
 312                         {
 313                                 // player disconnected
 314                                 SetTeam(e, -1);
 315                                 RemovePlayer(e);
 316                                 e.sort_prev = world;
 317                                 //e.gotscores = 0;
 318                         }
 319                 }
 320                 else
 321                 {
 322                         if (!e.sort_prev)
 323                         {
 324                                 // player connected
 325                                 if (!e)
 326                                         playerslots[i] = e = spawn();
 327                                 e.sv_entnum = i;
 328                                 e.ping = 0;
 329                                 e.ping_packetloss = 0;
 330                                 e.ping_movementloss = 0;
 331                                 //e.gotscores = 0; // we might already have the scores...
 332                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 333                                 RegisterPlayer(e);
 334                                 HUD_UpdatePlayerPos(e);
 335                         }
 336                 }
 337         }
 338         self.nextthink = time + 0.2;
 339 }
 340
 341 void Porto_Init();
 342 void TrueAim_Init();
 343 void PostInit(void)
 344 {
 345         entity playerchecker;
 346         playerchecker = spawn();
 347         playerchecker.think = Playerchecker_Think;
 348         playerchecker.nextthink = time + 0.2;
 349
 350         Porto_Init();
 351         TrueAim_Init();
 352
 353         postinit = true;
 354 }
 355
 356 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 357 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 358 // All keys are in ascii.
 359 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 360 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 361 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 362 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 363 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 364 {
 365         float bSkipKey;
 366         bSkipKey = false;
 367
 368         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 369                 return true;
 370
 371         if (QuickMenu_InputEvent(bInputType, nPrimary, nSecondary))
 372                 return true;
 373
 374         if ( HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary) )
 375                 return true;
 376
 377         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 378                 return true;
 379
 380         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
 381                 return true;
 382
 383         if(menu_visible && menu_action)
 384                 if(menu_action(bInputType, nPrimary, nSecondary))
 385                         return true;
 386
 387         return bSkipKey;
 388 }
 389
 390 // END REQUIRED CSQC FUNCTIONS
 391 // --------------------------------------------------------------------------
 392
 393 // --------------------------------------------------------------------------
 394 // BEGIN OPTIONAL CSQC FUNCTIONS
 395
 396 void Ent_RemoveEntCS()
 397 {
 398         entcs_receiver[self.sv_entnum] = world;
 399 }
 400 void Ent_ReadEntCS()
 401 {
 402     int sf;
 403         InterpolateOrigin_Undo();
 404
 405         self.classname = "entcs_receiver";
 406         sf = ReadByte();
 407
 408         if(sf & 1)
 409                 self.sv_entnum = ReadByte();
 410         if(sf & 2)
 411         {
 412                 self.origin_x = ReadShort();
 413                 self.origin_y = ReadShort();
 414                 self.origin_z = ReadShort();
 415                 setorigin(self, self.origin);
 416         }
 417         if(sf & 4)
 418         {
 419                 self.angles_y = ReadByte() * 360.0 / 256;
 420                 self.angles_x = self.angles_z = 0;
 421         }
 422         if(sf & 8)
 423                 self.healthvalue = ReadByte() * 10;
 424         if(sf & 16)
 425                 self.armorvalue = ReadByte() * 10;
 426
 427         entcs_receiver[self.sv_entnum] = self;
 428         self.entremove = Ent_RemoveEntCS;
 429         self.iflags |= IFLAG_ORIGIN;
 430
 431         InterpolateOrigin_Note();
 432 }
 433
 434 void Ent_Remove();
 435
 436 void Ent_RemovePlayerScore()
 437 {
 438         if(self.owner) {
 439                 SetTeam(self.owner, -1);
 440                 self.owner.gotscores = 0;
 441                 for(int i = 0; i < MAX_SCORE; ++i) {
 442                         self.owner.(scores[i]) = 0; // clear all scores
 443                 }
 444         }
 445 }
 446
 447 void Ent_ReadPlayerScore()
 448 {
 449         int i, n;
 450         bool isNew;
 451         entity o;
 452
 453         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 454         // (no I've never heard of M-x replace-string, sed, or anything like that)
 455         isNew = !self.owner; // workaround for DP bug
 456         n = ReadByte()-1;
 457
 458 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 459         if(!isNew && n != self.sv_entnum)
 460         {
 461                 //print("A CSQC entity changed its owner!\n");
 462                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 463                 isNew = true;
 464                 Ent_Remove();
 465                 self.enttype = ENT_CLIENT_SCORES;
 466         }
 467 #endif
 468
 469         self.sv_entnum = n;
 470
 471         if (!(playerslots[self.sv_entnum]))
 472                 playerslots[self.sv_entnum] = spawn();
 473         o = self.owner = playerslots[self.sv_entnum];
 474         o.sv_entnum = self.sv_entnum;
 475         o.gotscores = 1;
 476
 477         //if (!o.sort_prev)
 478         //      RegisterPlayer(o);
 479         //playerchecker will do this for us later, if it has not already done so
 480
 481     int sf, lf;
 482 #if MAX_SCORE <= 8
 483         sf = ReadByte();
 484         lf = ReadByte();
 485 #else
 486         sf = ReadShort();
 487         lf = ReadShort();
 488 #endif
 489     int p;
 490         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 491                 if(sf & p)
 492                 {
 493                         if(lf & p)
 494                                 o.(scores[i]) = ReadInt24_t();
 495                         else
 496                                 o.(scores[i]) = ReadChar();
 497                 }
 498
 499         if(o.sort_prev)
 500                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 501
 502         self.entremove = Ent_RemovePlayerScore;
 503 }
 504
 505 void Ent_ReadTeamScore()
 506 {
 507         int i;
 508         entity o;
 509
 510         self.team = ReadByte();
 511         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 512
 513     int sf, lf;
 514 #if MAX_TEAMSCORE <= 8
 515         sf = ReadByte();
 516         lf = ReadByte();
 517 #else
 518         sf = ReadShort();
 519         lf = ReadShort();
 520 #endif
 521         int p;
 522         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 523                 if(sf & p)
 524                 {
 525                         if(lf & p)
 526                                 o.(teamscores[i]) = ReadInt24_t();
 527                         else
 528                                 o.(teamscores[i]) = ReadChar();
 529                 }
 530
 531         HUD_UpdateTeamPos(o);
 532 }
 533
 534 void Ent_ClientData()
 535 {
 536         float newspectatee_status;
 537
 538     int f = ReadByte();
 539
 540         scoreboard_showscores_force = (f & 1);
 541
 542         if(f & 2)
 543         {
 544                 newspectatee_status = ReadByte();
 545                 if(newspectatee_status == player_localnum + 1)
 546                         newspectatee_status = -1; // observing
 547         }
 548         else
 549                 newspectatee_status = 0;
 550
 551         spectatorbutton_zoom = (f & 4);
 552
 553         if(f & 8)
 554         {
 555                 angles_held_status = 1;
 556                 angles_held.x = ReadAngle();
 557                 angles_held.y = ReadAngle();
 558                 angles_held.z = 0;
 559         }
 560         else
 561                 angles_held_status = 0;
 562
 563         if(newspectatee_status != spectatee_status)
 564         {
 565                 // clear race stuff
 566                 race_laptime = 0;
 567                 race_checkpointtime = 0;
 568         }
 569         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 570         {
 571                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 572                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 573                 )
 574                         prev_p_health = -1;
 575                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 576                         prev_health = -1;
 577         }
 578         spectatee_status = newspectatee_status;
 579
 580         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 581 }
 582
 583 void Ent_Nagger()
 584 {
 585     int i, j, b, f;
 586
 587     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 588
 589         if(!(nags & 4))
 590         {
 591                 if(vote_called_vote)
 592                         strunzone(vote_called_vote);
 593                 vote_called_vote = string_null;
 594                 vote_active = 0;
 595         }
 596         else
 597         {
 598                 vote_active = 1;
 599         }
 600
 601         if(nags & 64)
 602         {
 603                 vote_yescount = ReadByte();
 604                 vote_nocount = ReadByte();
 605                 vote_needed = ReadByte();
 606                 vote_highlighted = ReadChar();
 607         }
 608
 609         if(nags & 128)
 610         {
 611                 if(vote_called_vote)
 612                         strunzone(vote_called_vote);
 613                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 614         }
 615
 616         if(nags & 1)
 617         {
 618                 for(j = 0; j < maxclients; ++j)
 619                         if(playerslots[j])
 620                                 playerslots[j].ready = 1;
 621                 for(i = 1; i <= maxclients; i += 8)
 622                 {
 623                         f = ReadByte();
 624                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 625                                 if (!(f & b))
 626                                         if(playerslots[j])
 627                                                 playerslots[j].ready = 0;
 628                 }
 629         }
 630
 631         ready_waiting = (nags & 1);
 632         ready_waiting_for_me = (nags & 2);
 633         vote_waiting = (nags & 4);
 634         vote_waiting_for_me = (nags & 8);
 635         warmup_stage = (nags & 16);
 636 }
 637
 638 void Ent_EliminatedPlayers()
 639 {
 640     int i, j, b, f;
 641
 642     int sf = ReadByte();
 643         if(sf & 1)
 644         {
 645                 for(j = 0; j < maxclients; ++j)
 646                         if(playerslots[j])
 647                                 playerslots[j].eliminated = 1;
 648                 for(i = 1; i <= maxclients; i += 8)
 649                 {
 650                         f = ReadByte();
 651                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 652                                 if (!(f & b))
 653                                         if(playerslots[j])
 654                                                 playerslots[j].eliminated = 0;
 655                 }
 656         }
 657 }
 658
 659 void Ent_RandomSeed()
 660 {
 661         float s;
 662         prandom_debug();
 663         s = ReadShort();
 664         psrandom(s);
 665 }
 666
 667 void Ent_ReadAccuracy(void)
 668 {
 669     int f, w;
 670     int sf = ReadInt24_t();
 671         if(sf == 0)
 672         {
 673                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 674                         weapon_accuracy[w] = -1;
 675                 return;
 676         }
 677
 678         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 679         {
 680                 if(sf & f)
 681                 {
 682             int b = ReadByte();
 683                         if(b == 0)
 684                                 weapon_accuracy[w] = -1;
 685                         else if(b == 255)
 686                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 687                         else
 688                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 689                 }
 690                 if(f == 0x800000)
 691                         f = 1;
 692                 else
 693                         f *= 2;
 694         }
 695 }
 696
 697 void Spawn_Draw(void)
 698 {
 699         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 700 }
 701
 702 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 703 {
 704         float teamnum = (ReadByte() - 1);
 705         vector spn_origin;
 706         spn_origin.x = ReadShort();
 707         spn_origin.y = ReadShort();
 708         spn_origin.z = ReadShort();
 709
 710         if(is_new)
 711         {
 712                 self.origin = spn_origin;
 713                 setsize(self, PL_MIN_CONST, PL_MAX_CONST);
 714                 droptofloor();
 715
 716                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 717                 {
 718                         self.mdl = "models/spawnpoint.md3";
 719                         self.colormod = Team_ColorRGB(teamnum);
 720                         precache_model(self.mdl);
 721                         setmodel(self, self.mdl);
 722                         self.drawmask = MASK_NORMAL;
 723                         //self.movetype = MOVETYPE_NOCLIP;
 724                         //self.draw = Spawn_Draw;
 725                 }*/
 726                 if(autocvar_cl_spawn_point_particles)
 727                 {
 728                         if((serverflags & SERVERFLAG_TEAMPLAY))
 729                         {
 730                                 switch(teamnum)
 731                                 {
 732                                         case NUM_TEAM_1: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
 733                                         case NUM_TEAM_2: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
 734                                         case NUM_TEAM_3: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
 735                                         case NUM_TEAM_4: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
 736                                         default: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
 737                                 }
 738                         }
 739                         else { self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
 740
 741                         self.draw = Spawn_Draw;
 742                 }
 743         }
 744
 745         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 746 }
 747
 748 void Ent_ReadSpawnEvent(float is_new)
 749 {
 750         // If entnum is 0, ONLY do the local spawn actions
 751         // this way the server can disable the sending of
 752         // spawn origin or such to clients if wanted.
 753         float entnum = ReadByte();
 754
 755         if(entnum)
 756         {
 757                 self.origin_x = ReadShort();
 758                 self.origin_y = ReadShort();
 759                 self.origin_z = ReadShort();
 760
 761                 if(is_new)
 762                 {
 763                         float teamnum = GetPlayerColor(entnum - 1);
 764
 765                         if(autocvar_cl_spawn_event_particles)
 766                         {
 767                                 switch(teamnum)
 768                                 {
 769                                         case NUM_TEAM_1: pointparticles(particleeffectnum(EFFECT_SPAWN_RED), self.origin, '0 0 0', 1); break;
 770                                         case NUM_TEAM_2: pointparticles(particleeffectnum(EFFECT_SPAWN_BLUE), self.origin, '0 0 0', 1); break;
 771                                         case NUM_TEAM_3: pointparticles(particleeffectnum(EFFECT_SPAWN_YELLOW), self.origin, '0 0 0', 1); break;
 772                                         case NUM_TEAM_4: pointparticles(particleeffectnum(EFFECT_SPAWN_PINK), self.origin, '0 0 0', 1); break;
 773                                         default: pointparticles(particleeffectnum(EFFECT_SPAWN_NEUTRAL), self.origin, '0 0 0', 1); break;
 774                                 }
 775                         }
 776                         if(autocvar_cl_spawn_event_sound)
 777                         {
 778                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
 779                         }
 780                 }
 781         }
 782
 783         // local spawn actions
 784         if(is_new && (!entnum || (entnum == player_localentnum)))
 785         {
 786                 zoomin_effect = 1;
 787                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 788
 789                 if(autocvar_cl_unpress_zoom_on_spawn)
 790                 {
 791                         localcmd("-zoom\n");
 792                         button_zoom = false;
 793                 }
 794         }
 795         HUD_Radar_Hide_Maximized();
 796         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 797 }
 798
 799 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 800 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 801 void Ent_RadarLink();
 802 void Ent_Init();
 803 void Ent_ScoresInfo();
 804 void CSQC_Ent_Update(float bIsNewEntity)
 805 {
 806         float t;
 807         float savetime;
 808         t = ReadByte();
 809
 810         if(autocvar_developer_csqcentities)
 811                 LOG_INFOF("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 812
 813         // set up the "time" global for received entities to be correct for interpolation purposes
 814         savetime = time;
 815         if(servertime)
 816         {
 817                 time = servertime;
 818         }
 819         else
 820         {
 821                 serverprevtime = time;
 822                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 823                 time = serverprevtime + serverdeltatime;
 824         }
 825
 826 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 827         if(self.enttype)
 828         {
 829                 if(t != self.enttype || bIsNewEntity)
 830                 {
 831                         //print("A CSQC entity changed its type!\n");
 832                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 833                         Ent_Remove();
 834                         clearentity(self);
 835                         bIsNewEntity = 1;
 836                 }
 837         }
 838         else
 839         {
 840                 if(!bIsNewEntity)
 841                 {
 842                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 843                         bIsNewEntity = 1;
 844                 }
 845         }
 846 #endif
 847         self.enttype = t;
 848         switch(t)
 849         {
 850                 case ENT_CLIENT_MUTATOR: {
 851                         int mutID = ReadMutator();
 852                         if (!MUTATOR_CALLHOOK(CSQC_Ent_Update, mutID, bIsNewEntity))
 853                         error(sprintf("Unknown mutator type in CSQC_Ent_Update (mutID: %d, edict: %d, classname: %s)\n", mutID, num_for_edict(self), self.classname));
 854                         break;
 855                 }
 856                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 857                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 858                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 859                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 860                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 861                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 862                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 863                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
 864                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 865                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 866                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 867                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 868                 case ENT_CLIENT_INIT: Ent_Init(); break;
 869                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 870                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 871                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 872                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 873                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 874                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 875                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 876                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 877                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 878                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 879                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 880                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 881                 case ENT_CLIENT_INVENTORY: Inventory_Read(self); break;
 882                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
 883                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 884                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 885                 case ENT_CLIENT_TURRET: ent_turret(); break;
 886                 case ENT_CLIENT_GENERATOR: ent_generator(); break;
 887                 case ENT_CLIENT_CONTROLPOINT_ICON: ent_cpicon(); break;
 888                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 889                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 890                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 891                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 892                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 893                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 894                 case ENT_CLIENT_HEALING_ORB: ent_healer(); break;
 895                 case ENT_CLIENT_MINIGAME: ent_read_minigame(); break;
 896                 case ENT_CLIENT_VIEWLOC: ent_viewloc(); break;
 897                 case ENT_CLIENT_VIEWLOC_TRIGGER: ent_viewloc_trigger(); break;
 898                 case ENT_CLIENT_LADDER: ent_func_ladder(); break;
 899                 case ENT_CLIENT_TRIGGER_PUSH: ent_trigger_push(); break;
 900                 case ENT_CLIENT_TARGET_PUSH: ent_target_push(); break;
 901                 case ENT_CLIENT_CONVEYOR: ent_conveyor(); break;
 902                 case ENT_CLIENT_DOOR: ent_door(); break;
 903                 case ENT_CLIENT_PLAT: ent_plat(); break;
 904                 case ENT_CLIENT_SWAMP: ent_swamp(); break;
 905                 case ENT_CLIENT_CORNER: ent_corner(); break;
 906                 case ENT_CLIENT_KEYLOCK: ent_keylock(); break;
 907                 case ENT_CLIENT_TRAIN: ent_train(); break;
 908                 case ENT_CLIENT_TRIGGER_IMPULSE: ent_trigger_impulse(); break;
 909                 case ENT_CLIENT_EFFECT: Read_Effect(bIsNewEntity); break;
 910
 911                 default:
 912                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 913                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
 914                         break;
 915         }
 916
 917         time = savetime;
 918 }
 919 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 920 // used when an entity changes its type. For an entity that someone interacts
 921 // with others, make sure it can no longer do so.
 922 void Ent_Remove()
 923 {
 924         if(self.entremove)
 925                 self.entremove();
 926
 927         if(self.skeletonindex)
 928         {
 929                 skel_delete(self.skeletonindex);
 930                 self.skeletonindex = 0;
 931         }
 932
 933         if(self.snd_looping > 0)
 934         {
 935                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 936                 self.snd_looping = 0;
 937         }
 938
 939         self.enttype = 0;
 940         self.classname = "";
 941         self.draw = menu_sub_null;
 942         self.entremove = menu_sub_null;
 943         // TODO possibly set more stuff to defaults
 944 }
 945 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 946 void CSQC_Ent_Remove()
 947 {
 948         if(autocvar_developer_csqcentities)
 949                 LOG_INFOF("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 950
 951         if(wasfreed(self))
 952         {
 953                 LOG_INFO("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 954                 return;
 955         }
 956         if(self.enttype)
 957                 Ent_Remove();
 958         remove(self);
 959 }
 960
 961 void Gamemode_Init()
 962 {
 963         if (!isdemo())
 964         {
 965                 if(!(calledhooks & HOOK_START))
 966                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 967                 calledhooks |= HOOK_START;
 968         }
 969 }
 970 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 971 void CSQC_Parse_StuffCmd(string strMessage)
 972 {
 973         if(autocvar_developer_csqcentities)
 974                 LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 975
 976         localcmd(strMessage);
 977 }
 978 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 979 void CSQC_Parse_Print(string strMessage)
 980 {
 981         if(autocvar_developer_csqcentities)
 982                 LOG_INFOF("CSQC_Parse_Print(\"%s\")\n", strMessage);
 983
 984         LOG_INFO(ColorTranslateRGB(strMessage));
 985 }
 986
 987 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 988 void CSQC_Parse_CenterPrint(string strMessage)
 989 {
 990         if(autocvar_developer_csqcentities)
 991                 LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 992
 993         centerprint_hud(strMessage);
 994 }
 995
 996 string notranslate_fogcmd1 = "\nfog ";
 997 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 998 void Fog_Force()
 999 {
1000         // TODO somehow thwart prvm_globalset client ...
1001
1002         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
1003                 { localcmd("\nr_drawfog 0\n"); }
1004         else if(forcefog != "")
1005                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
1006 }
1007
1008 void Gamemode_Init();
1009 void Ent_ScoresInfo()
1010 {
1011     int i;
1012         self.classname = "ent_client_scores_info";
1013         gametype = ReadInt24_t();
1014         HUD_ModIcons_SetFunc();
1015         for(i = 0; i < MAX_SCORE; ++i)
1016         {
1017                 if(scores_label[i])
1018                         strunzone(scores_label[i]);
1019                 scores_label[i] = strzone(ReadString());
1020                 scores_flags[i] = ReadByte();
1021         }
1022         for(i = 0; i < MAX_TEAMSCORE; ++i)
1023         {
1024                 if(teamscores_label[i])
1025                         strunzone(teamscores_label[i]);
1026                 teamscores_label[i] = strzone(ReadString());
1027                 teamscores_flags[i] = ReadByte();
1028         }
1029         HUD_InitScores();
1030         Gamemode_Init();
1031 }
1032
1033 void Ent_Init()
1034 {
1035         self.classname = "ent_client_init";
1036
1037         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1038
1039         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1040         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1041         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1042         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1043         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1044         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1045         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1046         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1047
1048         if(forcefog)
1049                 strunzone(forcefog);
1050         forcefog = strzone(ReadString());
1051
1052         armorblockpercent = ReadByte() / 255.0;
1053
1054         g_balance_mortar_bouncefactor = ReadCoord();
1055         g_balance_mortar_bouncestop = ReadCoord();
1056         g_balance_electro_secondary_bouncefactor = ReadCoord();
1057         g_balance_electro_secondary_bouncestop = ReadCoord();
1058
1059         vortex_scope = !ReadByte();
1060         rifle_scope = !ReadByte();
1061
1062         serverflags = ReadByte();
1063
1064         minelayer_maxmines = ReadByte();
1065
1066         hagar_maxrockets = ReadByte();
1067
1068         g_trueaim_minrange = ReadCoord();
1069         g_balance_porto_secondary = ReadByte();
1070
1071         if(!postinit)
1072                 PostInit();
1073 }
1074
1075 void Net_ReadRace()
1076 {
1077         float b;
1078
1079         b = ReadByte();
1080
1081         switch(b)
1082         {
1083                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1084                         race_checkpoint = ReadByte();
1085                         race_time = ReadInt24_t();
1086                         race_previousbesttime = ReadInt24_t();
1087                         if(race_previousbestname)
1088                                 strunzone(race_previousbestname);
1089                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1090
1091                         race_checkpointtime = time;
1092
1093                         if(race_checkpoint == 0 || race_checkpoint == 254)
1094                         {
1095                                 race_penaltyaccumulator = 0;
1096                                 race_laptime = time; // valid
1097                         }
1098
1099                         break;
1100
1101                 case RACE_NET_CHECKPOINT_CLEAR:
1102                         race_laptime = 0;
1103                         race_checkpointtime = 0;
1104                         break;
1105
1106                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1107                         race_laptime = ReadCoord();
1108                         race_checkpointtime = -99999;
1109                         // fall through
1110                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1111                         race_nextcheckpoint = ReadByte();
1112
1113                         race_nextbesttime = ReadInt24_t();
1114                         if(race_nextbestname)
1115                                 strunzone(race_nextbestname);
1116                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1117                         break;
1118
1119                 case RACE_NET_CHECKPOINT_HIT_RACE:
1120                         race_mycheckpoint = ReadByte();
1121                         race_mycheckpointtime = time;
1122                         race_mycheckpointdelta = ReadInt24_t();
1123                         race_mycheckpointlapsdelta = ReadByte();
1124                         if(race_mycheckpointlapsdelta >= 128)
1125                                 race_mycheckpointlapsdelta -= 256;
1126                         if(race_mycheckpointenemy)
1127                                 strunzone(race_mycheckpointenemy);
1128                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1129                         break;
1130
1131                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1132                         race_othercheckpoint = ReadByte();
1133                         race_othercheckpointtime = time;
1134                         race_othercheckpointdelta = ReadInt24_t();
1135                         race_othercheckpointlapsdelta = ReadByte();
1136                         if(race_othercheckpointlapsdelta >= 128)
1137                                 race_othercheckpointlapsdelta -= 256;
1138                         if(race_othercheckpointenemy)
1139                                 strunzone(race_othercheckpointenemy);
1140                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1141                         break;
1142
1143                 case RACE_NET_PENALTY_RACE:
1144                         race_penaltyeventtime = time;
1145                         race_penaltytime = ReadShort();
1146                         //race_penaltyaccumulator += race_penaltytime;
1147                         if(race_penaltyreason)
1148                                 strunzone(race_penaltyreason);
1149                         race_penaltyreason = strzone(ReadString());
1150                         break;
1151
1152                 case RACE_NET_PENALTY_QUALIFYING:
1153                         race_penaltyeventtime = time;
1154                         race_penaltytime = ReadShort();
1155                         race_penaltyaccumulator += race_penaltytime;
1156                         if(race_penaltyreason)
1157                                 strunzone(race_penaltyreason);
1158                         race_penaltyreason = strzone(ReadString());
1159                         break;
1160
1161                 case RACE_NET_SERVER_RECORD:
1162                         race_server_record = ReadInt24_t();
1163                         break;
1164                 case RACE_NET_SPEED_AWARD:
1165                         race_speedaward = ReadInt24_t();
1166                         if(race_speedaward_holder)
1167                                 strunzone(race_speedaward_holder);
1168                         race_speedaward_holder = strzone(ReadString());
1169                         break;
1170                 case RACE_NET_SPEED_AWARD_BEST:
1171                         race_speedaward_alltimebest = ReadInt24_t();
1172                         if(race_speedaward_alltimebest_holder)
1173                                 strunzone(race_speedaward_alltimebest_holder);
1174                         race_speedaward_alltimebest_holder = strzone(ReadString());
1175                         break;
1176                 case RACE_NET_SERVER_RANKINGS:
1177                         float prevpos, del;
1178             int pos = ReadShort();
1179                         prevpos = ReadShort();
1180                         del = ReadShort();
1181
1182                         // move other rankings out of the way
1183             int i;
1184                         if (prevpos) {
1185                                 for (i=prevpos-1;i>pos-1;--i) {
1186                                         grecordtime[i] = grecordtime[i-1];
1187                                         if(grecordholder[i])
1188                                                 strunzone(grecordholder[i]);
1189                                         grecordholder[i] = strzone(grecordholder[i-1]);
1190                                 }
1191                         } else if (del) { // a record has been deleted by the admin
1192                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1193                                         if (i == RANKINGS_CNT-1) { // clear out last record
1194                                                 grecordtime[i] = 0;
1195                                                 if (grecordholder[i])
1196                                                         strunzone(grecordholder[i]);
1197                                                 grecordholder[i] = string_null;
1198                                         }
1199                                         else {
1200                                                 grecordtime[i] = grecordtime[i+1];
1201                                                 if (grecordholder[i])
1202                                                         strunzone(grecordholder[i]);
1203                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1204                                         }
1205                                 }
1206                         } else { // player has no ranked record yet
1207                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1208                                         grecordtime[i] = grecordtime[i-1];
1209                                         if(grecordholder[i])
1210                                                 strunzone(grecordholder[i]);
1211                                         grecordholder[i] = strzone(grecordholder[i-1]);
1212                                 }
1213                         }
1214
1215                         // store new ranking
1216                         if(grecordholder[pos-1] != "")
1217                                 strunzone(grecordholder[pos-1]);
1218                         grecordholder[pos-1] = strzone(ReadString());
1219                         grecordtime[pos-1] = ReadInt24_t();
1220                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1221                                 race_myrank = pos;
1222                         break;
1223                 case RACE_NET_SERVER_STATUS:
1224                         race_status = ReadShort();
1225                         if(race_status_name)
1226                                 strunzone(race_status_name);
1227                         race_status_name = strzone(ReadString());
1228         }
1229 }
1230
1231 void Net_TeamNagger()
1232 {
1233         teamnagger = 1;
1234 }
1235
1236 void Net_ReadPingPLReport()
1237 {
1238         int e, pi, pl, ml;
1239         e = ReadByte();
1240         pi = ReadShort();
1241         pl = ReadByte();
1242         ml = ReadByte();
1243         if (!(playerslots[e]))
1244                 return;
1245         playerslots[e].ping = pi;
1246         playerslots[e].ping_packetloss = pl / 255.0;
1247         playerslots[e].ping_movementloss = ml / 255.0;
1248 }
1249
1250 void Net_WeaponComplain()
1251 {
1252         complain_weapon = ReadByte();
1253
1254         if(complain_weapon_name)
1255                 strunzone(complain_weapon_name);
1256         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1257
1258         complain_weapon_type = ReadByte();
1259
1260         complain_weapon_time = time;
1261         weapontime = time; // ping the weapon panel
1262
1263         switch(complain_weapon_type)
1264         {
1265                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1266                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1267                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1268         }
1269 }
1270
1271 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1272 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1273 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1274 float CSQC_Parse_TempEntity()
1275 {
1276         // Acquire TE ID
1277         int nTEID = ReadByte();
1278
1279         if (autocvar_developer_csqcentities)
1280                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1281
1282         switch (nTEID)
1283         {
1284                 case TE_CSQC_MUTATOR:
1285                         int mutID = ReadMutator();
1286                         if (MUTATOR_CALLHOOK(CSQC_Parse_TempEntity, mutID))
1287                         return true;
1288                 case TE_CSQC_TARGET_MUSIC:
1289                         Net_TargetMusic();
1290                         return true;
1291                 case TE_CSQC_PICTURE:
1292                         Net_MapVote_Picture();
1293                         return true;
1294                 case TE_CSQC_RACE:
1295                         Net_ReadRace();
1296                         return true;
1297                 case TE_CSQC_VORTEXBEAMPARTICLE:
1298                         Net_ReadVortexBeamParticle();
1299                         return true;
1300                 case TE_CSQC_TEAMNAGGER:
1301                         Net_TeamNagger();
1302                         return true;
1303                 case TE_CSQC_ARC:
1304                         Net_ReadArc();
1305                         return true;
1306                 case TE_CSQC_PINGPLREPORT:
1307                         Net_ReadPingPLReport();
1308                         return true;
1309                 case TE_CSQC_WEAPONCOMPLAIN:
1310                         Net_WeaponComplain();
1311                         return true;
1312                 case TE_CSQC_VEHICLESETUP:
1313                         Net_VehicleSetup();
1314                         return true;
1315                 case TE_CSQC_SVNOTICE:
1316                         cl_notice_read();
1317                         return true;
1318                 case TE_CSQC_SHOCKWAVEPARTICLE:
1319                         Net_ReadShockwaveParticle();
1320                         return true;
1321                 default:
1322                         // No special logic for this temporary entity; return 0 so the engine can handle it
1323                         return false;
1324         }
1325 }
1326
1327 string getcommandkey(string text, string command)
1328 {
1329         string keys;
1330         float n, j, k, l = 0;
1331
1332         if (!autocvar_hud_showbinds)
1333                 return text;
1334
1335         keys = db_get(binddb, command);
1336         if (keys == "")
1337         {
1338                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1339                 for(j = 0; j < n; ++j)
1340                 {
1341                         k = stof(argv(j));
1342                         if(k != -1)
1343                         {
1344                                 if ("" == keys)
1345                                         keys = keynumtostring(k);
1346                                 else
1347                                         keys = strcat(keys, ", ", keynumtostring(k));
1348
1349                                 ++l;
1350                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1351                                         break;
1352                         }
1353
1354                 }
1355                 if (keys == "")
1356                         keys = "NO_KEY";
1357                 db_put(binddb, command, keys);
1358         }
1359
1360         if (keys == "NO_KEY") {
1361                 if (autocvar_hud_showbinds > 1)
1362                         return sprintf(_("%s (not bound)"), text);
1363                 else
1364                         return text;
1365         }
1366         else if (autocvar_hud_showbinds > 1)
1367                 return sprintf("%s (%s)", text, keys);
1368         else
1369                 return keys;
1370 }