Merge branch 'master' into Mario/turrets
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / main.qc
1 #include "mapvoting.qh"
2 #include "modeleffects.qh"
3 #include "particles.qh"
4 #include "scoreboard.qh"
5 #include "shownames.qh"
6 #include "target_music.qh"
7 #include "tuba.qh"
8 #include "wall.qh"
9 #include "waypointsprites.qh"
10
11 #include "vehicles/vehicles.qh"
12
13 #include "../server/vehicles/bumblebee.qh"
14
15 #include "../common/net_notice.qh"
16
17 #include "../common/monsters/monsters.qh"
18
19 #include "../common/turrets/cl_turrets.qh"
20 #include "../common/turrets/turrets.qh"
21
22 #include "../warpzonelib/client.qh"
23
24 // --------------------------------------------------------------------------
25 // BEGIN REQUIRED CSQC FUNCTIONS
26 //include "main.qh"
27
28 entity clearentity_ent;
29 void clearentity(entity e)
30 {
31         if (!clearentity_ent)
32         {
33                 clearentity_ent = spawn();
34                 clearentity_ent.classname = "clearentity";
35         }
36         int n = e.entnum;
37         copyentity(clearentity_ent, e);
38         e.entnum = n;
39 }
40
41 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
42 void menu_show_error()
43 {
44         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
45 }
46
47 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
48 // Useful for precaching things
49
50 void menu_sub_null()
51 {
52 }
53
54 string forcefog;
55 void WaypointSprite_Load();
56 void ConsoleCommand_macro_init();
57 void CSQC_Init(void)
58 {
59         prvm_language = cvar_string("prvm_language");
60
61 #ifdef WATERMARK
62         dprintf("^4CSQC Build information: ^1%s\n", WATERMARK);
63 #endif
64
65         int i;
66
67         binddb = db_create();
68         tempdb = db_create();
69         ClientProgsDB = db_load("client.db");
70         compressShortVector_init();
71
72         draw_endBoldFont();
73         menu_visible = false;
74         menu_show = menu_show_error;
75         menu_action = func_null;
76
77         for(i = 0; i < 255; ++i)
78                 if(getplayerkeyvalue(i, "viewentity") == "")
79                         break;
80         maxclients = i;
81
82         //registercommand("hud_configure");
83         //registercommand("hud_save");
84         //registercommand("menu_action");
85
86         ConsoleCommand_macro_init();
87
88         registercvar("hud_usecsqc", "1");
89         registercvar("scoreboard_columns", "default");
90
91         registercvar("cl_nade_type", "3");
92         registercvar("cl_pokenade_type", "zombie");
93
94         gametype = 0;
95
96         // hud_fields uses strunzone on the titles!
97         for(i = 0; i < MAX_HUD_FIELDS; ++i)
98                 hud_title[i] = strzone("(null)");
99
100         Cmd_HUD_SetFields(0);
101
102         postinit = false;
103
104         calledhooks = 0;
105
106         teams = Sort_Spawn();
107         players = Sort_Spawn();
108
109         GetTeam(NUM_SPECTATOR, true); // add specs first
110
111         // needs to be done so early because of the constants they create
112         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
113         CALL_ACCUMULATED_FUNCTION(RegisterTurrets);
114         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
115         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
116         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
117         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
118         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
119         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
120
121         WaypointSprite_Load();
122
123         // precaches
124         precache_model("null");
125         precache_sound("misc/hit.wav");
126         precache_sound("misc/typehit.wav");
127
128         Projectile_Precache();
129         Hook_Precache();
130         GibSplash_Precache();
131         Casings_Precache();
132         Vehicles_Precache();
133         Tuba_Precache();
134         CSQCPlayer_Precache();
135
136         if(autocvar_cl_reticle)
137         {
138                 precache_pic("gfx/reticle_normal");
139                 // weapon reticles are precached in weapon files
140         }
141
142         get_mi_min_max_texcoords(1); // try the CLEVER way first
143         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
144         shortmapname = mi_shortname;
145
146         if(precache_pic(minimapname) == "")
147         {
148                 // but maybe we have a non-clever minimap
149                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
150                 if(precache_pic(minimapname) == "")
151                         minimapname = ""; // FAIL
152                 else
153                         get_mi_min_max_texcoords(0); // load new texcoords
154         }
155
156         mi_center = (mi_min + mi_max) * 0.5;
157         mi_scale = mi_max - mi_min;
158         minimapname = strzone(minimapname);
159
160         WarpZone_Init();
161
162         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
163         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
164 }
165
166 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
167 void Shutdown(void)
168 {
169         WarpZone_Shutdown();
170
171         remove(teams);
172         remove(players);
173         db_close(binddb);
174         db_close(tempdb);
175         if(autocvar_cl_db_saveasdump)
176                 db_dump(ClientProgsDB, "client.db");
177         else
178                 db_save(ClientProgsDB, "client.db");
179         db_close(ClientProgsDB);
180
181         if(camera_active)
182                 cvar_set("chase_active",ftos(chase_active_backup));
183
184         // unset the event chasecam's chase_active
185         if(autocvar_chase_active < 0)
186                 cvar_set("chase_active", "0");
187
188         if (!isdemo())
189         {
190                 if (!(calledhooks & HOOK_START))
191                         localcmd("\n_cl_hook_gamestart nop\n");
192                 if (!(calledhooks & HOOK_END))
193                         localcmd("\ncl_hook_gameend\n");
194         }
195 }
196
197 .float has_team;
198 float SetTeam(entity o, int Team)
199 {
200         entity tm;
201         if(teamplay)
202         {
203                 switch(Team)
204                 {
205                         case -1:
206                         case NUM_TEAM_1:
207                         case NUM_TEAM_2:
208                         case NUM_TEAM_3:
209                         case NUM_TEAM_4:
210                                 break;
211                         default:
212                                 if(GetTeam(Team, false) == world)
213                                 {
214                                         dprintf("trying to switch to unsupported team %d\n", Team);
215                                         Team = NUM_SPECTATOR;
216                                 }
217                                 break;
218                 }
219         }
220         else
221         {
222                 switch(Team)
223                 {
224                         case -1:
225                         case 0:
226                                 break;
227                         default:
228                                 if(GetTeam(Team, false) == world)
229                                 {
230                                         dprintf("trying to switch to unsupported team %d\n", Team);
231                                         Team = NUM_SPECTATOR;
232                                 }
233                                 break;
234                 }
235         }
236         if(Team == -1) // leave
237         {
238                 if(o.has_team)
239                 {
240                         tm = GetTeam(o.team, false);
241                         tm.team_size -= 1;
242                         o.has_team = 0;
243                         return true;
244                 }
245         }
246         else
247         {
248                 if (!o.has_team)
249                 {
250                         o.team = Team;
251                         tm = GetTeam(Team, true);
252                         tm.team_size += 1;
253                         o.has_team = 1;
254                         return true;
255                 }
256                 else if(Team != o.team)
257                 {
258                         tm = GetTeam(o.team, false);
259                         tm.team_size -= 1;
260                         o.team = Team;
261                         tm = GetTeam(Team, true);
262                         tm.team_size += 1;
263                         return true;
264                 }
265         }
266         return false;
267 }
268
269 void Playerchecker_Think()
270 {
271     int i;
272         entity e;
273         for(i = 0; i < maxclients; ++i)
274         {
275                 e = playerslots[i];
276                 if(GetPlayerName(i) == "")
277                 {
278                         if(e.sort_prev)
279                         {
280                                 // player disconnected
281                                 SetTeam(e, -1);
282                                 RemovePlayer(e);
283                                 e.sort_prev = world;
284                                 //e.gotscores = 0;
285                         }
286                 }
287                 else
288                 {
289                         if (!e.sort_prev)
290                         {
291                                 // player connected
292                                 if (!e)
293                                         playerslots[i] = e = spawn();
294                                 e.sv_entnum = i;
295                                 e.ping = 0;
296                                 e.ping_packetloss = 0;
297                                 e.ping_movementloss = 0;
298                                 //e.gotscores = 0; // we might already have the scores...
299                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
300                                 RegisterPlayer(e);
301                                 HUD_UpdatePlayerPos(e);
302                         }
303                 }
304         }
305         self.nextthink = time + 0.2;
306 }
307
308 void Porto_Init();
309 void TrueAim_Init();
310 void PostInit(void)
311 {
312         entity playerchecker;
313         playerchecker = spawn();
314         playerchecker.think = Playerchecker_Think;
315         playerchecker.nextthink = time + 0.2;
316
317         Porto_Init();
318         TrueAim_Init();
319
320         postinit = true;
321 }
322
323 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
324 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
325 // All keys are in ascii.
326 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
327 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
328 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
329 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
330 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
331 {
332         float bSkipKey;
333         bSkipKey = false;
334
335         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
336                 return true;
337
338         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
339                 return true;
340
341         if(menu_visible && menu_action)
342                 if(menu_action(bInputType, nPrimary, nSecondary))
343                         return true;
344
345         return bSkipKey;
346 }
347
348 // END REQUIRED CSQC FUNCTIONS
349 // --------------------------------------------------------------------------
350
351 // --------------------------------------------------------------------------
352 // BEGIN OPTIONAL CSQC FUNCTIONS
353 void Ent_RemoveEntCS()
354 {
355         entcs_receiver[self.sv_entnum] = world;
356 }
357 void Ent_ReadEntCS()
358 {
359     int sf;
360         InterpolateOrigin_Undo();
361
362         self.classname = "entcs_receiver";
363         sf = ReadByte();
364
365         if(sf & 1)
366                 self.sv_entnum = ReadByte();
367         if(sf & 2)
368         {
369                 self.origin_x = ReadShort();
370                 self.origin_y = ReadShort();
371                 self.origin_z = ReadShort();
372                 setorigin(self, self.origin);
373         }
374         if(sf & 4)
375         {
376                 self.angles_y = ReadByte() * 360.0 / 256;
377                 self.angles_x = self.angles_z = 0;
378         }
379         if(sf & 8)
380                 self.healthvalue = ReadByte() * 10;
381         if(sf & 16)
382                 self.armorvalue = ReadByte() * 10;
383
384         entcs_receiver[self.sv_entnum] = self;
385         self.entremove = Ent_RemoveEntCS;
386         self.iflags |= IFLAG_ORIGIN;
387
388         InterpolateOrigin_Note();
389 }
390
391 void Ent_Remove();
392
393 void Ent_RemovePlayerScore()
394 {
395         if(self.owner) {
396                 SetTeam(self.owner, -1);
397                 self.owner.gotscores = 0;
398                 for(int i = 0; i < MAX_SCORE; ++i) {
399                         self.owner.(scores[i]) = 0; // clear all scores
400                 }
401         }
402 }
403
404 void Ent_ReadPlayerScore()
405 {
406         int i, n;
407         bool isNew;
408         entity o;
409
410         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
411         // (no I've never heard of M-x replace-string, sed, or anything like that)
412         isNew = !self.owner; // workaround for DP bug
413         n = ReadByte()-1;
414
415 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
416         if(!isNew && n != self.sv_entnum)
417         {
418                 //print("A CSQC entity changed its owner!\n");
419                 printf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
420                 isNew = true;
421                 Ent_Remove();
422                 self.enttype = ENT_CLIENT_SCORES;
423         }
424 #endif
425
426         self.sv_entnum = n;
427
428         if (!(playerslots[self.sv_entnum]))
429                 playerslots[self.sv_entnum] = spawn();
430         o = self.owner = playerslots[self.sv_entnum];
431         o.sv_entnum = self.sv_entnum;
432         o.gotscores = 1;
433
434         //if (!o.sort_prev)
435         //      RegisterPlayer(o);
436         //playerchecker will do this for us later, if it has not already done so
437
438     int sf, lf;
439 #if MAX_SCORE <= 8
440         sf = ReadByte();
441         lf = ReadByte();
442 #else
443         sf = ReadShort();
444         lf = ReadShort();
445 #endif
446     int p;
447         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
448                 if(sf & p)
449                 {
450                         if(lf & p)
451                                 o.(scores[i]) = ReadInt24_t();
452                         else
453                                 o.(scores[i]) = ReadChar();
454                 }
455
456         if(o.sort_prev)
457                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
458
459         self.entremove = Ent_RemovePlayerScore;
460 }
461
462 void Ent_ReadTeamScore()
463 {
464         int i;
465         entity o;
466
467         self.team = ReadByte();
468         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
469
470     int sf, lf;
471 #if MAX_TEAMSCORE <= 8
472         sf = ReadByte();
473         lf = ReadByte();
474 #else
475         sf = ReadShort();
476         lf = ReadShort();
477 #endif
478         int p;
479         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
480                 if(sf & p)
481                 {
482                         if(lf & p)
483                                 o.(teamscores[i]) = ReadInt24_t();
484                         else
485                                 o.(teamscores[i]) = ReadChar();
486                 }
487
488         HUD_UpdateTeamPos(o);
489 }
490
491 void Ent_ClientData()
492 {
493         float newspectatee_status;
494
495     int f = ReadByte();
496
497         scoreboard_showscores_force = (f & 1);
498
499         if(f & 2)
500         {
501                 newspectatee_status = ReadByte();
502                 if(newspectatee_status == player_localnum + 1)
503                         newspectatee_status = -1; // observing
504         }
505         else
506                 newspectatee_status = 0;
507
508         spectatorbutton_zoom = (f & 4);
509
510         if(f & 8)
511         {
512                 angles_held_status = 1;
513                 angles_held.x = ReadAngle();
514                 angles_held.y = ReadAngle();
515                 angles_held.z = 0;
516         }
517         else
518                 angles_held_status = 0;
519
520         if(newspectatee_status != spectatee_status)
521         {
522                 // clear race stuff
523                 race_laptime = 0;
524                 race_checkpointtime = 0;
525         }
526         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
527         {
528                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
529                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
530                 )
531                         prev_p_health = -1;
532                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
533                         prev_health = -1;
534         }
535         spectatee_status = newspectatee_status;
536
537         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
538 }
539
540 void Ent_Nagger()
541 {
542     int i, j, b, f;
543
544     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
545
546         if(!(nags & 4))
547         {
548                 if(vote_called_vote)
549                         strunzone(vote_called_vote);
550                 vote_called_vote = string_null;
551                 vote_active = 0;
552         }
553         else
554         {
555                 vote_active = 1;
556         }
557
558         if(nags & 64)
559         {
560                 vote_yescount = ReadByte();
561                 vote_nocount = ReadByte();
562                 vote_needed = ReadByte();
563                 vote_highlighted = ReadChar();
564         }
565
566         if(nags & 128)
567         {
568                 if(vote_called_vote)
569                         strunzone(vote_called_vote);
570                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
571         }
572
573         if(nags & 1)
574         {
575                 for(j = 0; j < maxclients; ++j)
576                         if(playerslots[j])
577                                 playerslots[j].ready = 1;
578                 for(i = 1; i <= maxclients; i += 8)
579                 {
580                         f = ReadByte();
581                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
582                                 if (!(f & b))
583                                         if(playerslots[j])
584                                                 playerslots[j].ready = 0;
585                 }
586         }
587
588         ready_waiting = (nags & 1);
589         ready_waiting_for_me = (nags & 2);
590         vote_waiting = (nags & 4);
591         vote_waiting_for_me = (nags & 8);
592         warmup_stage = (nags & 16);
593 }
594
595 void Ent_EliminatedPlayers()
596 {
597     int i, j, b, f;
598
599     int sf = ReadByte();
600         if(sf & 1)
601         {
602                 for(j = 0; j < maxclients; ++j)
603                         if(playerslots[j])
604                                 playerslots[j].eliminated = 1;
605                 for(i = 1; i <= maxclients; i += 8)
606                 {
607                         f = ReadByte();
608                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
609                                 if (!(f & b))
610                                         if(playerslots[j])
611                                                 playerslots[j].eliminated = 0;
612                 }
613         }
614 }
615
616 void Ent_RandomSeed()
617 {
618         float s;
619         prandom_debug();
620         s = ReadShort();
621         psrandom(s);
622 }
623
624 void Ent_ReadAccuracy(void)
625 {
626     int f, w;
627     int sf = ReadInt24_t();
628         if(sf == 0)
629         {
630                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
631                         weapon_accuracy[w] = -1;
632                 return;
633         }
634
635         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
636         {
637                 if(sf & f)
638                 {
639             int b = ReadByte();
640                         if(b == 0)
641                                 weapon_accuracy[w] = -1;
642                         else if(b == 255)
643                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
644                         else
645                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
646                 }
647                 if(f == 0x800000)
648                         f = 1;
649                 else
650                         f *= 2;
651         }
652 }
653
654 void Spawn_Draw(void)
655 {
656         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
657 }
658
659 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
660 {
661         float teamnum = (ReadByte() - 1);
662         vector spn_origin;
663         spn_origin.x = ReadShort();
664         spn_origin.y = ReadShort();
665         spn_origin.z = ReadShort();
666
667         if(is_new)
668         {
669                 self.origin = spn_origin;
670                 setsize(self, PL_MIN, PL_MAX);
671                 droptofloor();
672
673                 /*if(autocvar_cl_spawn_point_model) // needs a model first
674                 {
675                         self.mdl = "models/spawnpoint.md3";
676                         self.colormod = Team_ColorRGB(teamnum);
677                         precache_model(self.mdl);
678                         setmodel(self, self.mdl);
679                         self.drawmask = MASK_NORMAL;
680                         //self.movetype = MOVETYPE_NOCLIP;
681                         //self.draw = Spawn_Draw;
682                 }*/
683                 if(autocvar_cl_spawn_point_particles)
684                 {
685                         if((serverflags & SERVERFLAG_TEAMPLAY))
686                         {
687                                 switch(teamnum)
688                                 {
689                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
690                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
691                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
692                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
693                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
694                                 }
695                         }
696                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
697
698                         self.draw = Spawn_Draw;
699                 }
700         }
701
702         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
703 }
704
705 void Ent_ReadSpawnEvent(float is_new)
706 {
707         // If entnum is 0, ONLY do the local spawn actions
708         // this way the server can disable the sending of
709         // spawn origin or such to clients if wanted.
710         float entnum = ReadByte();
711
712         if(entnum)
713         {
714                 self.origin_x = ReadShort();
715                 self.origin_y = ReadShort();
716                 self.origin_z = ReadShort();
717
718                 if(is_new)
719                 {
720                         float teamnum = GetPlayerColor(entnum - 1);
721
722                         if(autocvar_cl_spawn_event_particles)
723                         {
724                                 switch(teamnum)
725                                 {
726                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
727                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
728                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
729                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
730                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
731                                 }
732                         }
733                         if(autocvar_cl_spawn_event_sound)
734                         {
735                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
736                         }
737                 }
738         }
739
740         // local spawn actions
741         if(is_new && (!entnum || (entnum == player_localentnum)))
742         {
743                 zoomin_effect = 1;
744                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
745
746                 if(autocvar_cl_unpress_zoom_on_spawn)
747                 {
748                         localcmd("-zoom\n");
749                         button_zoom = false;
750                 }
751         }
752
753         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
754 }
755
756 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
757 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
758 void Ent_RadarLink();
759 void Ent_Init();
760 void Ent_ScoresInfo();
761 void CSQC_Ent_Update(float bIsNewEntity)
762 {
763         float t;
764         float savetime;
765         t = ReadByte();
766
767         if(autocvar_developer_csqcentities)
768                 printf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
769
770         // set up the "time" global for received entities to be correct for interpolation purposes
771         savetime = time;
772         if(servertime)
773         {
774                 time = servertime;
775         }
776         else
777         {
778                 serverprevtime = time;
779                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
780                 time = serverprevtime + serverdeltatime;
781         }
782
783 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
784         if(self.enttype)
785         {
786                 if(t != self.enttype || bIsNewEntity)
787                 {
788                         //print("A CSQC entity changed its type!\n");
789                         printf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
790                         Ent_Remove();
791                         clearentity(self);
792                         bIsNewEntity = 1;
793                 }
794         }
795         else
796         {
797                 if(!bIsNewEntity)
798                 {
799                         printf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
800                         bIsNewEntity = 1;
801                 }
802         }
803 #endif
804         self.enttype = t;
805         switch(t)
806         {
807                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
808                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
809                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
810                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
811                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
812                 case ENT_CLIENT_LASER: Ent_Laser(); break;
813                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
814                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
815                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
816                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
817                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
818                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
819                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
820                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
821                 case ENT_CLIENT_INIT: Ent_Init(); break;
822                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
823                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
824                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
825                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
826                 case ENT_CLIENT_WALL: Ent_Wall(); break;
827                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
828                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
829                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
830                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
831                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
832                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
833                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
834                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
835                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
836                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
837                 case ENT_CLIENT_TURRET: ent_turret(); break;
838                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
839                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
840                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
841                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
842                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
843                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
844                 case ENT_CLIENT_HEALING_ORB: ent_healer(); break;
845
846                 default:
847                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
848                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
849                         break;
850         }
851
852         time = savetime;
853 }
854 // Destructor, but does NOT deallocate the entity by calling remove(). Also
855 // used when an entity changes its type. For an entity that someone interacts
856 // with others, make sure it can no longer do so.
857 void Ent_Remove()
858 {
859         if(self.entremove)
860                 self.entremove();
861
862         if(self.skeletonindex)
863         {
864                 skel_delete(self.skeletonindex);
865                 self.skeletonindex = 0;
866         }
867
868         if(self.snd_looping > 0)
869         {
870                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
871                 self.snd_looping = 0;
872         }
873
874         self.enttype = 0;
875         self.classname = "";
876         self.draw = menu_sub_null;
877         self.entremove = menu_sub_null;
878         // TODO possibly set more stuff to defaults
879 }
880 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
881 void CSQC_Ent_Remove()
882 {
883         if(autocvar_developer_csqcentities)
884                 printf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
885
886         if(wasfreed(self))
887         {
888                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
889                 return;
890         }
891         if(self.enttype)
892                 Ent_Remove();
893         remove(self);
894 }
895
896 void Gamemode_Init()
897 {
898         if (!isdemo())
899         {
900                 if(!(calledhooks & HOOK_START))
901                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
902                 calledhooks |= HOOK_START;
903         }
904 }
905 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
906 void CSQC_Parse_StuffCmd(string strMessage)
907 {
908         if(autocvar_developer_csqcentities)
909                 printf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
910
911         localcmd(strMessage);
912 }
913 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
914 void CSQC_Parse_Print(string strMessage)
915 {
916         if(autocvar_developer_csqcentities)
917                 printf("CSQC_Parse_Print(\"%s\")\n", strMessage);
918
919         print(ColorTranslateRGB(strMessage));
920 }
921
922 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
923 void CSQC_Parse_CenterPrint(string strMessage)
924 {
925         if(autocvar_developer_csqcentities)
926                 printf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
927
928         centerprint_hud(strMessage);
929 }
930
931 string notranslate_fogcmd1 = "\nfog ";
932 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
933 void Fog_Force()
934 {
935         // TODO somehow thwart prvm_globalset client ...
936
937         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
938                 { localcmd("\nr_drawfog 0\n"); }
939         else if(forcefog != "")
940                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
941 }
942
943 void Gamemode_Init();
944 void Ent_ScoresInfo()
945 {
946     int i;
947         self.classname = "ent_client_scores_info";
948         gametype = ReadInt24_t();
949         HUD_ModIcons_SetFunc();
950         for(i = 0; i < MAX_SCORE; ++i)
951         {
952                 if(scores_label[i])
953                         strunzone(scores_label[i]);
954                 scores_label[i] = strzone(ReadString());
955                 scores_flags[i] = ReadByte();
956         }
957         for(i = 0; i < MAX_TEAMSCORE; ++i)
958         {
959                 if(teamscores_label[i])
960                         strunzone(teamscores_label[i]);
961                 teamscores_label[i] = strzone(ReadString());
962                 teamscores_flags[i] = ReadByte();
963         }
964         HUD_InitScores();
965         Gamemode_Init();
966 }
967
968 void Ent_Init()
969 {
970         self.classname = "ent_client_init";
971
972         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
973
974         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
975         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
976         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
977         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
978         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
979         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
980         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
981         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
982
983         if(forcefog)
984                 strunzone(forcefog);
985         forcefog = strzone(ReadString());
986
987         armorblockpercent = ReadByte() / 255.0;
988
989         g_balance_mortar_bouncefactor = ReadCoord();
990         g_balance_mortar_bouncestop = ReadCoord();
991         g_balance_electro_secondary_bouncefactor = ReadCoord();
992         g_balance_electro_secondary_bouncestop = ReadCoord();
993
994         vortex_scope = !ReadByte();
995         rifle_scope = !ReadByte();
996
997         serverflags = ReadByte();
998
999         minelayer_maxmines = ReadByte();
1000
1001         hagar_maxrockets = ReadByte();
1002
1003         g_trueaim_minrange = ReadCoord();
1004         g_balance_porto_secondary = ReadByte();
1005
1006         if(!postinit)
1007                 PostInit();
1008 }
1009
1010 void Net_ReadRace()
1011 {
1012         float b;
1013
1014         b = ReadByte();
1015
1016         switch(b)
1017         {
1018                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1019                         race_checkpoint = ReadByte();
1020                         race_time = ReadInt24_t();
1021                         race_previousbesttime = ReadInt24_t();
1022                         if(race_previousbestname)
1023                                 strunzone(race_previousbestname);
1024                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1025
1026                         race_checkpointtime = time;
1027
1028                         if(race_checkpoint == 0 || race_checkpoint == 254)
1029                         {
1030                                 race_penaltyaccumulator = 0;
1031                                 race_laptime = time; // valid
1032                         }
1033
1034                         break;
1035
1036                 case RACE_NET_CHECKPOINT_CLEAR:
1037                         race_laptime = 0;
1038                         race_checkpointtime = 0;
1039                         break;
1040
1041                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1042                         race_laptime = ReadCoord();
1043                         race_checkpointtime = -99999;
1044                         // fall through
1045                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1046                         race_nextcheckpoint = ReadByte();
1047
1048                         race_nextbesttime = ReadInt24_t();
1049                         if(race_nextbestname)
1050                                 strunzone(race_nextbestname);
1051                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1052                         break;
1053
1054                 case RACE_NET_CHECKPOINT_HIT_RACE:
1055                         race_mycheckpoint = ReadByte();
1056                         race_mycheckpointtime = time;
1057                         race_mycheckpointdelta = ReadInt24_t();
1058                         race_mycheckpointlapsdelta = ReadByte();
1059                         if(race_mycheckpointlapsdelta >= 128)
1060                                 race_mycheckpointlapsdelta -= 256;
1061                         if(race_mycheckpointenemy)
1062                                 strunzone(race_mycheckpointenemy);
1063                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1064                         break;
1065
1066                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1067                         race_othercheckpoint = ReadByte();
1068                         race_othercheckpointtime = time;
1069                         race_othercheckpointdelta = ReadInt24_t();
1070                         race_othercheckpointlapsdelta = ReadByte();
1071                         if(race_othercheckpointlapsdelta >= 128)
1072                                 race_othercheckpointlapsdelta -= 256;
1073                         if(race_othercheckpointenemy)
1074                                 strunzone(race_othercheckpointenemy);
1075                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1076                         break;
1077
1078                 case RACE_NET_PENALTY_RACE:
1079                         race_penaltyeventtime = time;
1080                         race_penaltytime = ReadShort();
1081                         //race_penaltyaccumulator += race_penaltytime;
1082                         if(race_penaltyreason)
1083                                 strunzone(race_penaltyreason);
1084                         race_penaltyreason = strzone(ReadString());
1085                         break;
1086
1087                 case RACE_NET_PENALTY_QUALIFYING:
1088                         race_penaltyeventtime = time;
1089                         race_penaltytime = ReadShort();
1090                         race_penaltyaccumulator += race_penaltytime;
1091                         if(race_penaltyreason)
1092                                 strunzone(race_penaltyreason);
1093                         race_penaltyreason = strzone(ReadString());
1094                         break;
1095
1096                 case RACE_NET_SERVER_RECORD:
1097                         race_server_record = ReadInt24_t();
1098                         break;
1099                 case RACE_NET_SPEED_AWARD:
1100                         race_speedaward = ReadInt24_t();
1101                         if(race_speedaward_holder)
1102                                 strunzone(race_speedaward_holder);
1103                         race_speedaward_holder = strzone(ReadString());
1104                         break;
1105                 case RACE_NET_SPEED_AWARD_BEST:
1106                         race_speedaward_alltimebest = ReadInt24_t();
1107                         if(race_speedaward_alltimebest_holder)
1108                                 strunzone(race_speedaward_alltimebest_holder);
1109                         race_speedaward_alltimebest_holder = strzone(ReadString());
1110                         break;
1111                 case RACE_NET_SERVER_RANKINGS:
1112                         float prevpos, del;
1113             int pos = ReadShort();
1114                         prevpos = ReadShort();
1115                         del = ReadShort();
1116
1117                         // move other rankings out of the way
1118             int i;
1119                         if (prevpos) {
1120                                 for (i=prevpos-1;i>pos-1;--i) {
1121                                         grecordtime[i] = grecordtime[i-1];
1122                                         if(grecordholder[i])
1123                                                 strunzone(grecordholder[i]);
1124                                         grecordholder[i] = strzone(grecordholder[i-1]);
1125                                 }
1126                         } else if (del) { // a record has been deleted by the admin
1127                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1128                                         if (i == RANKINGS_CNT-1) { // clear out last record
1129                                                 grecordtime[i] = 0;
1130                                                 if (grecordholder[i])
1131                                                         strunzone(grecordholder[i]);
1132                                                 grecordholder[i] = string_null;
1133                                         }
1134                                         else {
1135                                                 grecordtime[i] = grecordtime[i+1];
1136                                                 if (grecordholder[i])
1137                                                         strunzone(grecordholder[i]);
1138                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1139                                         }
1140                                 }
1141                         } else { // player has no ranked record yet
1142                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1143                                         grecordtime[i] = grecordtime[i-1];
1144                                         if(grecordholder[i])
1145                                                 strunzone(grecordholder[i]);
1146                                         grecordholder[i] = strzone(grecordholder[i-1]);
1147                                 }
1148                         }
1149
1150                         // store new ranking
1151                         if(grecordholder[pos-1] != "")
1152                                 strunzone(grecordholder[pos-1]);
1153                         grecordholder[pos-1] = strzone(ReadString());
1154                         grecordtime[pos-1] = ReadInt24_t();
1155                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1156                                 race_myrank = pos;
1157                         break;
1158                 case RACE_NET_SERVER_STATUS:
1159                         race_status = ReadShort();
1160                         if(race_status_name)
1161                                 strunzone(race_status_name);
1162                         race_status_name = strzone(ReadString());
1163         }
1164 }
1165
1166 void Net_TeamNagger()
1167 {
1168         teamnagger = 1;
1169 }
1170
1171 void Net_ReadPingPLReport()
1172 {
1173         int e, pi, pl, ml;
1174         e = ReadByte();
1175         pi = ReadShort();
1176         pl = ReadByte();
1177         ml = ReadByte();
1178         if (!(playerslots[e]))
1179                 return;
1180         playerslots[e].ping = pi;
1181         playerslots[e].ping_packetloss = pl / 255.0;
1182         playerslots[e].ping_movementloss = ml / 255.0;
1183 }
1184
1185 void Net_WeaponComplain()
1186 {
1187         complain_weapon = ReadByte();
1188
1189         if(complain_weapon_name)
1190                 strunzone(complain_weapon_name);
1191         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1192
1193         complain_weapon_type = ReadByte();
1194
1195         complain_weapon_time = time;
1196         weapontime = time; // ping the weapon panel
1197
1198         switch(complain_weapon_type)
1199         {
1200                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1201                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1202                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1203         }
1204 }
1205
1206 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1207 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1208 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1209 float CSQC_Parse_TempEntity()
1210 {
1211         float bHandled;
1212                 bHandled  = true;
1213         // Acquire TE ID
1214         float nTEID;
1215                 nTEID = ReadByte();
1216
1217         if(autocvar_developer_csqcentities)
1218                 printf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1219
1220                 // NOTE: Could just do return instead of break...
1221         switch(nTEID)
1222         {
1223                 case TE_CSQC_TARGET_MUSIC:
1224                         Net_TargetMusic();
1225                         bHandled = true;
1226                         break;
1227                 case TE_CSQC_PICTURE:
1228                         Net_MapVote_Picture();
1229                         bHandled = true;
1230                         break;
1231                 case TE_CSQC_RACE:
1232                         Net_ReadRace();
1233                         bHandled = true;
1234                         break;
1235                 case TE_CSQC_VORTEXBEAMPARTICLE:
1236                         Net_ReadVortexBeamParticle();
1237                         bHandled = true;
1238                         break;
1239                 case TE_CSQC_TEAMNAGGER:
1240                         Net_TeamNagger();
1241                         bHandled = true;
1242                         break;
1243                 case TE_CSQC_ARC:
1244                         Net_ReadArc();
1245                         bHandled = true;
1246                         break;
1247                 case TE_CSQC_PINGPLREPORT:
1248                         Net_ReadPingPLReport();
1249                         bHandled = true;
1250                         break;
1251                 case TE_CSQC_WEAPONCOMPLAIN:
1252                         Net_WeaponComplain();
1253                         bHandled = true;
1254                         break;
1255                 case TE_CSQC_VEHICLESETUP:
1256                         Net_VehicleSetup();
1257                         bHandled = true;
1258                         break;
1259                 case TE_CSQC_SVNOTICE:
1260                         cl_notice_read();
1261                         bHandled = true;
1262                         break;
1263                 case TE_CSQC_SHOCKWAVEPARTICLE:
1264                         Net_ReadShockwaveParticle();
1265                         bHandled = true;
1266                         break;
1267                 default:
1268                         // No special logic for this temporary entity; return 0 so the engine can handle it
1269                         bHandled = false;
1270                         break;
1271         }
1272
1273         return bHandled;
1274 }
1275
1276 string getcommandkey(string text, string command)
1277 {
1278         string keys;
1279         float n, j, k, l = 0;
1280
1281         if (!autocvar_hud_showbinds)
1282                 return text;
1283
1284         keys = db_get(binddb, command);
1285         if (keys == "")
1286         {
1287                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1288                 for(j = 0; j < n; ++j)
1289                 {
1290                         k = stof(argv(j));
1291                         if(k != -1)
1292                         {
1293                                 if ("" == keys)
1294                                         keys = keynumtostring(k);
1295                                 else
1296                                         keys = strcat(keys, ", ", keynumtostring(k));
1297
1298                                 ++l;
1299                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1300                                         break;
1301                         }
1302
1303                 }
1304                 if (keys == "")
1305                         keys = "NO_KEY";
1306                 db_put(binddb, command, keys);
1307         }
1308
1309         if (keys == "NO_KEY") {
1310                 if (autocvar_hud_showbinds > 1)
1311                         return sprintf(_("%s (not bound)"), text);
1312                 else
1313                         return text;
1314         }
1315         else if (autocvar_hud_showbinds > 1)
1316                 return sprintf("%s (%s)", text, keys);
1317         else
1318                 return keys;
1319 }