bc3fb43d6820af3bee49ddf3aa1b9c2e029b3874
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / main.qc
1 #include "main.qh"
2 #include "_all.qh"
3
4 #include "controlpoint.qh"
5 #include "damage.qh"
6 #include "effects.qh"
7 #include "generator.qh"
8 #include "gibs.qh"
9 #include "hook.qh"
10 #include "hud.qh"
11 #include "hud_config.qh"
12 #include "laser.qh"
13 #include "mapvoting.qh"
14 #include "modeleffects.qh"
15 #include "particles.qh"
16 #include "scoreboard.qh"
17 #include "shownames.qh"
18 #include "tuba.qh"
19 #include "t_items.qh"
20 #include "wall.qh"
21
22 #include "../common/vehicles/all.qh"
23
24 #include "mutators/events.qh"
25
26 #include "weapons/projectile.qh"
27
28 #include "../common/buffs/all.qh"
29 #include "../common/deathtypes.qh"
30 #include "../common/effects/effects.qh"
31 #include "../common/mapinfo.qh"
32 #include "../common/monsters/all.qh"
33 #include "../common/nades/all.qh"
34 #include "../common/net_notice.qh"
35 #include "../common/notifications.qh"
36 #include "../common/stats.qh"
37 #include "../common/teams.qh"
38
39 #include "../common/items/all.qh"
40
41 #include "../common/mutators/base.qh"
42
43 #include "../common/weapons/all.qh"
44
45 #include "../csqcmodellib/cl_model.qh"
46 #include "../csqcmodellib/interpolate.qh"
47
48 #include "../common/triggers/include.qh"
49
50 #include "../common/turrets/cl_turrets.qh"
51
52 #include "../warpzonelib/client.qh"
53
54 // --------------------------------------------------------------------------
55 // BEGIN REQUIRED CSQC FUNCTIONS
56 //include "main.qh"
57
58 entity clearentity_ent;
59 void clearentity(entity e)
60 {
61         if (!clearentity_ent)
62         {
63                 clearentity_ent = spawn();
64                 clearentity_ent.classname = "clearentity";
65         }
66         int n = e.entnum;
67         copyentity(clearentity_ent, e);
68         e.entnum = n;
69 }
70
71 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
72 void menu_show_error()
73 {
74         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
75 }
76
77 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
78 // Useful for precaching things
79
80 void menu_sub_null()
81 {
82 }
83
84 void draw_null(entity this) { }
85
86 string forcefog;
87 void ConsoleCommand_macro_init();
88 void CSQC_Init(void)
89 {
90         prvm_language = strzone(cvar_string("prvm_language"));
91
92 #ifdef WATERMARK
93         LOG_TRACEF("^4CSQC Build information: ^1%s\n", WATERMARK);
94 #endif
95
96         int i;
97
98         binddb = db_create();
99         tempdb = db_create();
100         ClientProgsDB = db_load("client.db");
101         compressShortVector_init();
102
103         draw_endBoldFont();
104         menu_visible = false;
105         menu_show = menu_show_error;
106         menu_action = func_null;
107
108         for(i = 0; i < 255; ++i)
109                 if(getplayerkeyvalue(i, "viewentity") == "")
110                         break;
111         maxclients = i;
112
113         //registercommand("hud_configure");
114         //registercommand("hud_save");
115         //registercommand("menu_action");
116
117         ConsoleCommand_macro_init();
118
119         registercvar("hud_usecsqc", "1");
120         registercvar("scoreboard_columns", "default");
121
122         registercvar("cl_nade_type", "3");
123         registercvar("cl_pokenade_type", "zombie");
124
125         registercvar("cl_jumpspeedcap_min", "");
126         registercvar("cl_jumpspeedcap_max", "");
127
128         registercvar("cl_multijump", "0");
129
130         registercvar("cl_spawn_near_teammate", "1");
131
132         gametype = 0;
133
134         // hud_fields uses strunzone on the titles!
135         for(i = 0; i < MAX_HUD_FIELDS; ++i)
136                 hud_title[i] = strzone("(null)");
137
138         Cmd_HUD_SetFields(0);
139
140         postinit = false;
141
142         calledhooks = 0;
143
144         teams = Sort_Spawn();
145         players = Sort_Spawn();
146
147         GetTeam(NUM_SPECTATOR, true); // add specs first
148
149         // needs to be done so early because of the constants they create
150         static_init();
151         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
152         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
153         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
154
155         // precaches
156
157         Projectile_Precache();
158         Tuba_Precache();
159
160         if(autocvar_cl_reticle)
161         {
162                 precache_pic("gfx/reticle_normal");
163                 // weapon reticles are precached in weapon files
164         }
165
166         get_mi_min_max_texcoords(1); // try the CLEVER way first
167         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
168         shortmapname = mi_shortname;
169
170         if(precache_pic(minimapname) == "")
171         {
172                 // but maybe we have a non-clever minimap
173                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
174                 if(precache_pic(minimapname) == "")
175                         minimapname = ""; // FAIL
176                 else
177                         get_mi_min_max_texcoords(0); // load new texcoords
178         }
179
180         mi_center = (mi_min + mi_max) * 0.5;
181         mi_scale = mi_max - mi_min;
182         minimapname = strzone(minimapname);
183
184         WarpZone_Init();
185
186         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
187         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
188 }
189
190 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
191 void Shutdown(void)
192 {
193         WarpZone_Shutdown();
194
195         remove(teams);
196         remove(players);
197         db_close(binddb);
198         db_close(tempdb);
199         if(autocvar_cl_db_saveasdump)
200                 db_dump(ClientProgsDB, "client.db");
201         else
202                 db_save(ClientProgsDB, "client.db");
203         db_close(ClientProgsDB);
204
205         if(camera_active)
206                 cvar_set("chase_active",ftos(chase_active_backup));
207
208         // unset the event chasecam's chase_active
209         if(autocvar_chase_active < 0)
210                 cvar_set("chase_active", "0");
211
212         if (!isdemo())
213         {
214                 if (!(calledhooks & HOOK_START))
215                         localcmd("\n_cl_hook_gamestart nop\n");
216                 if (!(calledhooks & HOOK_END))
217                         localcmd("\ncl_hook_gameend\n");
218         }
219
220         deactivate_minigame();
221         HUD_MinigameMenu_Close();
222 }
223
224 .float has_team;
225 float SetTeam(entity o, int Team)
226 {
227         entity tm;
228         if(teamplay)
229         {
230                 switch(Team)
231                 {
232                         case -1:
233                         case NUM_TEAM_1:
234                         case NUM_TEAM_2:
235                         case NUM_TEAM_3:
236                         case NUM_TEAM_4:
237                                 break;
238                         default:
239                                 if(GetTeam(Team, false) == world)
240                                 {
241                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
242                                         Team = NUM_SPECTATOR;
243                                 }
244                                 break;
245                 }
246         }
247         else
248         {
249                 switch(Team)
250                 {
251                         case -1:
252                         case 0:
253                                 break;
254                         default:
255                                 if(GetTeam(Team, false) == world)
256                                 {
257                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
258                                         Team = NUM_SPECTATOR;
259                                 }
260                                 break;
261                 }
262         }
263         if(Team == -1) // leave
264         {
265                 if(o.has_team)
266                 {
267                         tm = GetTeam(o.team, false);
268                         tm.team_size -= 1;
269                         o.has_team = 0;
270                         return true;
271                 }
272         }
273         else
274         {
275                 if (!o.has_team)
276                 {
277                         o.team = Team;
278                         tm = GetTeam(Team, true);
279                         tm.team_size += 1;
280                         o.has_team = 1;
281                         return true;
282                 }
283                 else if(Team != o.team)
284                 {
285                         tm = GetTeam(o.team, false);
286                         tm.team_size -= 1;
287                         o.team = Team;
288                         tm = GetTeam(Team, true);
289                         tm.team_size += 1;
290                         return true;
291                 }
292         }
293         return false;
294 }
295
296 void Playerchecker_Think()
297 {SELFPARAM();
298     int i;
299         entity e;
300         for(i = 0; i < maxclients; ++i)
301         {
302                 e = playerslots[i];
303                 if(GetPlayerName(i) == "")
304                 {
305                         if(e.sort_prev)
306                         {
307                                 // player disconnected
308                                 SetTeam(e, -1);
309                                 RemovePlayer(e);
310                                 e.sort_prev = world;
311                                 //e.gotscores = 0;
312                         }
313                 }
314                 else
315                 {
316                         if (!e.sort_prev)
317                         {
318                                 // player connected
319                                 if (!e)
320                                         playerslots[i] = e = spawn();
321                                 e.sv_entnum = i;
322                                 e.ping = 0;
323                                 e.ping_packetloss = 0;
324                                 e.ping_movementloss = 0;
325                                 //e.gotscores = 0; // we might already have the scores...
326                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
327                                 RegisterPlayer(e);
328                                 HUD_UpdatePlayerPos(e);
329                         }
330                 }
331         }
332         self.nextthink = time + 0.2;
333 }
334
335 void Porto_Init();
336 void TrueAim_Init();
337 void PostInit(void)
338 {
339         entity playerchecker;
340         playerchecker = spawn();
341         playerchecker.think = Playerchecker_Think;
342         playerchecker.nextthink = time + 0.2;
343
344         Porto_Init();
345         TrueAim_Init();
346
347         postinit = true;
348 }
349
350 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
351 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
352 // All keys are in ascii.
353 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
354 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
355 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
356 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
357 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
358 {
359         float bSkipKey;
360         bSkipKey = false;
361
362         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
363                 return true;
364
365         if (QuickMenu_InputEvent(bInputType, nPrimary, nSecondary))
366                 return true;
367
368         if ( HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary) )
369                 return true;
370
371         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
372                 return true;
373
374         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
375                 return true;
376
377         if(menu_visible && menu_action)
378                 if(menu_action(bInputType, nPrimary, nSecondary))
379                         return true;
380
381         return bSkipKey;
382 }
383
384 // END REQUIRED CSQC FUNCTIONS
385 // --------------------------------------------------------------------------
386
387 // --------------------------------------------------------------------------
388 // BEGIN OPTIONAL CSQC FUNCTIONS
389
390 void Ent_RemoveEntCS()
391 {SELFPARAM();
392         entcs_receiver[self.sv_entnum] = world;
393 }
394 void Ent_ReadEntCS()
395 {SELFPARAM();
396     int sf;
397         InterpolateOrigin_Undo();
398
399         self.classname = "entcs_receiver";
400         sf = ReadByte();
401
402         if(sf & 1)
403                 self.sv_entnum = ReadByte();
404         if(sf & 2)
405         {
406                 self.origin_x = ReadShort();
407                 self.origin_y = ReadShort();
408                 self.origin_z = ReadShort();
409                 setorigin(self, self.origin);
410         }
411         if(sf & 4)
412         {
413                 self.angles_y = ReadByte() * 360.0 / 256;
414                 self.angles_x = self.angles_z = 0;
415         }
416         if(sf & 8)
417                 self.healthvalue = ReadByte() * 10;
418         if(sf & 16)
419                 self.armorvalue = ReadByte() * 10;
420
421         entcs_receiver[self.sv_entnum] = self;
422         self.entremove = Ent_RemoveEntCS;
423         self.iflags |= IFLAG_ORIGIN;
424
425         InterpolateOrigin_Note();
426 }
427
428 void Ent_Remove();
429
430 void Ent_RemovePlayerScore()
431 {SELFPARAM();
432         if(self.owner) {
433                 SetTeam(self.owner, -1);
434                 self.owner.gotscores = 0;
435                 for(int i = 0; i < MAX_SCORE; ++i) {
436                         self.owner.(scores[i]) = 0; // clear all scores
437                 }
438         }
439 }
440
441 void Ent_ReadPlayerScore()
442 {SELFPARAM();
443         int i, n;
444         bool isNew;
445         entity o;
446
447         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
448         // (no I've never heard of M-x replace-string, sed, or anything like that)
449         isNew = !self.owner; // workaround for DP bug
450         n = ReadByte()-1;
451
452 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
453         if(!isNew && n != self.sv_entnum)
454         {
455                 //print("A CSQC entity changed its owner!\n");
456                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
457                 isNew = true;
458                 Ent_Remove();
459                 self.enttype = ENT_CLIENT_SCORES;
460         }
461 #endif
462
463         self.sv_entnum = n;
464
465         if (!(playerslots[self.sv_entnum]))
466                 playerslots[self.sv_entnum] = spawn();
467         o = self.owner = playerslots[self.sv_entnum];
468         o.sv_entnum = self.sv_entnum;
469         o.gotscores = 1;
470
471         //if (!o.sort_prev)
472         //      RegisterPlayer(o);
473         //playerchecker will do this for us later, if it has not already done so
474
475     int sf, lf;
476 #if MAX_SCORE <= 8
477         sf = ReadByte();
478         lf = ReadByte();
479 #else
480         sf = ReadShort();
481         lf = ReadShort();
482 #endif
483     int p;
484         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
485                 if(sf & p)
486                 {
487                         if(lf & p)
488                                 o.(scores[i]) = ReadInt24_t();
489                         else
490                                 o.(scores[i]) = ReadChar();
491                 }
492
493         if(o.sort_prev)
494                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
495
496         self.entremove = Ent_RemovePlayerScore;
497 }
498
499 void Ent_ReadTeamScore()
500 {SELFPARAM();
501         int i;
502         entity o;
503
504         self.team = ReadByte();
505         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
506
507     int sf, lf;
508 #if MAX_TEAMSCORE <= 8
509         sf = ReadByte();
510         lf = ReadByte();
511 #else
512         sf = ReadShort();
513         lf = ReadShort();
514 #endif
515         int p;
516         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
517                 if(sf & p)
518                 {
519                         if(lf & p)
520                                 o.(teamscores[i]) = ReadInt24_t();
521                         else
522                                 o.(teamscores[i]) = ReadChar();
523                 }
524
525         HUD_UpdateTeamPos(o);
526 }
527
528 void Ent_ClientData()
529 {
530         float newspectatee_status;
531
532     int f = ReadByte();
533
534         scoreboard_showscores_force = (f & 1);
535
536         if(f & 2)
537         {
538                 newspectatee_status = ReadByte();
539                 if(newspectatee_status == player_localnum + 1)
540                         newspectatee_status = -1; // observing
541         }
542         else
543                 newspectatee_status = 0;
544
545         spectatorbutton_zoom = (f & 4);
546
547         if(f & 8)
548         {
549                 angles_held_status = 1;
550                 angles_held.x = ReadAngle();
551                 angles_held.y = ReadAngle();
552                 angles_held.z = 0;
553         }
554         else
555                 angles_held_status = 0;
556
557         if(newspectatee_status != spectatee_status)
558         {
559                 // clear race stuff
560                 race_laptime = 0;
561                 race_checkpointtime = 0;
562         }
563         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
564         {
565                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
566                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
567                 )
568                         prev_p_health = -1;
569                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
570                         prev_health = -1;
571         }
572         spectatee_status = newspectatee_status;
573
574         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
575 }
576
577 void Ent_Nagger()
578 {
579     int i, j, b, f;
580
581     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
582
583         if(!(nags & 4))
584         {
585                 if(vote_called_vote)
586                         strunzone(vote_called_vote);
587                 vote_called_vote = string_null;
588                 vote_active = 0;
589         }
590         else
591         {
592                 vote_active = 1;
593         }
594
595         if(nags & 64)
596         {
597                 vote_yescount = ReadByte();
598                 vote_nocount = ReadByte();
599                 vote_needed = ReadByte();
600                 vote_highlighted = ReadChar();
601         }
602
603         if(nags & 128)
604         {
605                 if(vote_called_vote)
606                         strunzone(vote_called_vote);
607                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
608         }
609
610         if(nags & 1)
611         {
612                 for(j = 0; j < maxclients; ++j)
613                         if(playerslots[j])
614                                 playerslots[j].ready = 1;
615                 for(i = 1; i <= maxclients; i += 8)
616                 {
617                         f = ReadByte();
618                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
619                                 if (!(f & b))
620                                         if(playerslots[j])
621                                                 playerslots[j].ready = 0;
622                 }
623         }
624
625         ready_waiting = (nags & 1);
626         ready_waiting_for_me = (nags & 2);
627         vote_waiting = (nags & 4);
628         vote_waiting_for_me = (nags & 8);
629         warmup_stage = (nags & 16);
630 }
631
632 void Ent_EliminatedPlayers()
633 {
634     int i, j, b, f;
635
636     int sf = ReadByte();
637         if(sf & 1)
638         {
639                 for(j = 0; j < maxclients; ++j)
640                         if(playerslots[j])
641                                 playerslots[j].eliminated = 1;
642                 for(i = 1; i <= maxclients; i += 8)
643                 {
644                         f = ReadByte();
645                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
646                                 if (!(f & b))
647                                         if(playerslots[j])
648                                                 playerslots[j].eliminated = 0;
649                 }
650         }
651 }
652
653 void Ent_RandomSeed()
654 {
655         float s;
656         prandom_debug();
657         s = ReadShort();
658         psrandom(s);
659 }
660
661 void Ent_ReadAccuracy(void)
662 {
663     int f, w;
664     int sf = ReadInt24_t();
665         if(sf == 0)
666         {
667                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
668                         weapon_accuracy[w] = -1;
669                 return;
670         }
671
672         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
673         {
674                 if(sf & f)
675                 {
676             int b = ReadByte();
677                         if(b == 0)
678                                 weapon_accuracy[w] = -1;
679                         else if(b == 255)
680                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
681                         else
682                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
683                 }
684                 if(f == 0x800000)
685                         f = 1;
686                 else
687                         f *= 2;
688         }
689 }
690
691 void Spawn_Draw(entity this)
692 {
693         pointparticles(this.cnt, this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
694 }
695
696 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
697 {SELFPARAM();
698         float teamnum = (ReadByte() - 1);
699         vector spn_origin;
700         spn_origin.x = ReadShort();
701         spn_origin.y = ReadShort();
702         spn_origin.z = ReadShort();
703
704         if(is_new)
705         {
706                 self.origin = spn_origin;
707                 setsize(self, PL_MIN_CONST, PL_MAX_CONST);
708                 droptofloor();
709
710                 /*if(autocvar_cl_spawn_point_model) // needs a model first
711                 {
712                         self.mdl = "models/spawnpoint.md3";
713                         self.colormod = Team_ColorRGB(teamnum);
714                         precache_model(self.mdl);
715                         setmodel(self, self.mdl);
716                         self.drawmask = MASK_NORMAL;
717                         //self.movetype = MOVETYPE_NOCLIP;
718                         //self.draw = Spawn_Draw;
719                 }*/
720                 if(autocvar_cl_spawn_point_particles)
721                 {
722                         if((serverflags & SERVERFLAG_TEAMPLAY))
723                         {
724                                 switch(teamnum)
725                                 {
726                                         case NUM_TEAM_1: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
727                                         case NUM_TEAM_2: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
728                                         case NUM_TEAM_3: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
729                                         case NUM_TEAM_4: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
730                                         default: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
731                                 }
732                         }
733                         else { self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
734
735                         self.draw = Spawn_Draw;
736                 }
737         }
738
739         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
740 }
741
742 void Ent_ReadSpawnEvent(float is_new)
743 {SELFPARAM();
744         // If entnum is 0, ONLY do the local spawn actions
745         // this way the server can disable the sending of
746         // spawn origin or such to clients if wanted.
747         float entnum = ReadByte();
748
749         if(entnum)
750         {
751                 self.origin_x = ReadShort();
752                 self.origin_y = ReadShort();
753                 self.origin_z = ReadShort();
754
755                 if(is_new)
756                 {
757                         float teamnum = GetPlayerColor(entnum - 1);
758
759                         if(autocvar_cl_spawn_event_particles)
760                         {
761                                 switch(teamnum)
762                                 {
763                                         case NUM_TEAM_1: pointparticles(particleeffectnum(EFFECT_SPAWN_RED), self.origin, '0 0 0', 1); break;
764                                         case NUM_TEAM_2: pointparticles(particleeffectnum(EFFECT_SPAWN_BLUE), self.origin, '0 0 0', 1); break;
765                                         case NUM_TEAM_3: pointparticles(particleeffectnum(EFFECT_SPAWN_YELLOW), self.origin, '0 0 0', 1); break;
766                                         case NUM_TEAM_4: pointparticles(particleeffectnum(EFFECT_SPAWN_PINK), self.origin, '0 0 0', 1); break;
767                                         default: pointparticles(particleeffectnum(EFFECT_SPAWN_NEUTRAL), self.origin, '0 0 0', 1); break;
768                                 }
769                         }
770                         if(autocvar_cl_spawn_event_sound)
771                         {
772                                 sound(self, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
773                         }
774                 }
775         }
776
777         // local spawn actions
778         if(is_new && (!entnum || (entnum == player_localentnum)))
779         {
780                 zoomin_effect = 1;
781                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
782
783                 if(autocvar_cl_unpress_zoom_on_spawn)
784                 {
785                         localcmd("-zoom\n");
786                         button_zoom = false;
787                 }
788         }
789         HUD_Radar_Hide_Maximized();
790         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
791 }
792
793 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
794 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
795 void Ent_RadarLink();
796 void Ent_Init();
797 void Ent_ScoresInfo();
798 void CSQC_Ent_Update(float bIsNewEntity)
799 {SELFPARAM();
800         int t = ReadByte();
801
802         if(autocvar_developer_csqcentities)
803                 LOG_INFOF("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
804
805         // set up the "time" global for received entities to be correct for interpolation purposes
806         float savetime = time;
807         if(servertime)
808         {
809                 time = servertime;
810         }
811         else
812         {
813                 serverprevtime = time;
814                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
815                 time = serverprevtime + serverdeltatime;
816         }
817
818 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
819         if(self.enttype)
820         {
821                 if(t != self.enttype || bIsNewEntity)
822                 {
823                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
824                         Ent_Remove();
825                         clearentity(self);
826                         bIsNewEntity = 1;
827                 }
828         }
829         else
830         {
831                 if(!bIsNewEntity)
832                 {
833                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
834                         bIsNewEntity = 1;
835                 }
836         }
837 #endif
838         self.enttype = t;
839         bool done = false;
840         FOREACH(LinkedEntities, it.m_id == t, LAMBDA(
841                 it.m_read(self, bIsNewEntity);
842                 done = true;
843                 break;
844         ));
845         if (!done)
846         switch(t)
847         {
848                 case ENT_CLIENT_MUTATOR: {
849                         int mutID = ReadMutator();
850                         if (!MUTATOR_CALLHOOK(CSQC_Ent_Update, mutID, bIsNewEntity))
851                         error(sprintf("Unknown mutator type in CSQC_Ent_Update (mutID: %d, edict: %d, classname: %s)\n", mutID, num_for_edict(self), self.classname));
852                         break;
853                 }
854                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
855                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
856                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
857                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
858                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
859                 case ENT_CLIENT_LASER: Ent_Laser(); break;
860                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
861                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
862                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
863                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
864                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
865                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
866                 case ENT_CLIENT_INIT: Ent_Init(); break;
867                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
868                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
869                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
870                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
871                 case ENT_CLIENT_WALL: Ent_Wall(); break;
872                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
873                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
874                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
875                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
876                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
877                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
878                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
879                 case ENT_CLIENT_INVENTORY: Inventory_Read(self); break;
880                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
881                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
882                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
883                 case ENT_CLIENT_TURRET: ent_turret(); break;
884                 case ENT_CLIENT_GENERATOR: ent_generator(); break;
885                 case ENT_CLIENT_CONTROLPOINT_ICON: ent_cpicon(this); break;
886                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
887                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
888                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
889                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
890                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
891                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
892                 case ENT_CLIENT_MINIGAME: ent_read_minigame(); break;
893                 case ENT_CLIENT_VIEWLOC: ent_viewloc(); break;
894                 case ENT_CLIENT_VIEWLOC_TRIGGER: ent_viewloc_trigger(); break;
895                 case ENT_CLIENT_LADDER: ent_func_ladder(); break;
896                 case ENT_CLIENT_TRIGGER_PUSH: ent_trigger_push(); break;
897                 case ENT_CLIENT_TARGET_PUSH: ent_target_push(); break;
898                 case ENT_CLIENT_CONVEYOR: ent_conveyor(); break;
899                 case ENT_CLIENT_DOOR: ent_door(); break;
900                 case ENT_CLIENT_PLAT: ent_plat(); break;
901                 case ENT_CLIENT_SWAMP: ent_swamp(); break;
902                 case ENT_CLIENT_CORNER: ent_corner(); break;
903                 case ENT_CLIENT_KEYLOCK: ent_keylock(); break;
904                 case ENT_CLIENT_TRAIN: ent_train(); break;
905                 case ENT_CLIENT_TRIGGER_IMPULSE: ent_trigger_impulse(); break;
906                 case ENT_CLIENT_EFFECT: Read_Effect(bIsNewEntity); break;
907
908                 default:
909                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
910                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
911                         break;
912         }
913
914         time = savetime;
915 }
916 // Destructor, but does NOT deallocate the entity by calling remove(). Also
917 // used when an entity changes its type. For an entity that someone interacts
918 // with others, make sure it can no longer do so.
919 void Ent_Remove()
920 {SELFPARAM();
921         if(self.entremove)
922                 self.entremove();
923
924         if(self.skeletonindex)
925         {
926                 skel_delete(self.skeletonindex);
927                 self.skeletonindex = 0;
928         }
929
930         if(self.snd_looping > 0)
931         {
932                 sound(self, self.snd_looping, SND_Null, VOL_BASE, autocvar_g_jetpack_attenuation);
933                 self.snd_looping = 0;
934         }
935
936         self.enttype = 0;
937         self.classname = "";
938         self.draw = draw_null;
939         self.entremove = menu_sub_null;
940         // TODO possibly set more stuff to defaults
941 }
942 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
943 void CSQC_Ent_Remove()
944 {SELFPARAM();
945         if(autocvar_developer_csqcentities)
946                 LOG_INFOF("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
947
948         if(wasfreed(self))
949         {
950                 LOG_INFO("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
951                 return;
952         }
953         if(self.enttype)
954                 Ent_Remove();
955         remove(self);
956 }
957
958 void Gamemode_Init()
959 {
960         if (!isdemo())
961         {
962                 if(!(calledhooks & HOOK_START))
963                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
964                 calledhooks |= HOOK_START;
965         }
966 }
967 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
968 void CSQC_Parse_StuffCmd(string strMessage)
969 {
970         if(autocvar_developer_csqcentities)
971                 LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
972
973         localcmd(strMessage);
974 }
975 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
976 void CSQC_Parse_Print(string strMessage)
977 {
978         if(autocvar_developer_csqcentities)
979                 LOG_INFOF("CSQC_Parse_Print(\"%s\")\n", strMessage);
980
981         print(ColorTranslateRGB(strMessage));
982 }
983
984 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
985 void CSQC_Parse_CenterPrint(string strMessage)
986 {
987         if(autocvar_developer_csqcentities)
988                 LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
989
990         centerprint_hud(strMessage);
991 }
992
993 string notranslate_fogcmd1 = "\nfog ";
994 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
995 void Fog_Force()
996 {
997         // TODO somehow thwart prvm_globalset client ...
998
999         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
1000                 { localcmd("\nr_drawfog 0\n"); }
1001         else if(forcefog != "")
1002                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
1003 }
1004
1005 void Gamemode_Init();
1006 void Ent_ScoresInfo()
1007 {SELFPARAM();
1008     int i;
1009         self.classname = "ent_client_scores_info";
1010         gametype = ReadInt24_t();
1011         HUD_ModIcons_SetFunc();
1012         for(i = 0; i < MAX_SCORE; ++i)
1013         {
1014                 if(scores_label[i])
1015                         strunzone(scores_label[i]);
1016                 scores_label[i] = strzone(ReadString());
1017                 scores_flags[i] = ReadByte();
1018         }
1019         for(i = 0; i < MAX_TEAMSCORE; ++i)
1020         {
1021                 if(teamscores_label[i])
1022                         strunzone(teamscores_label[i]);
1023                 teamscores_label[i] = strzone(ReadString());
1024                 teamscores_flags[i] = ReadByte();
1025         }
1026         HUD_InitScores();
1027         Gamemode_Init();
1028 }
1029
1030 void Ent_Init()
1031 {SELFPARAM();
1032         self.classname = "ent_client_init";
1033
1034         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1035
1036         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1037         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1038         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1039         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1040         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1041         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1042         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1043         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1044
1045         if(forcefog)
1046                 strunzone(forcefog);
1047         forcefog = strzone(ReadString());
1048
1049         armorblockpercent = ReadByte() / 255.0;
1050
1051         g_balance_mortar_bouncefactor = ReadCoord();
1052         g_balance_mortar_bouncestop = ReadCoord();
1053         g_balance_electro_secondary_bouncefactor = ReadCoord();
1054         g_balance_electro_secondary_bouncestop = ReadCoord();
1055
1056         vortex_scope = !ReadByte();
1057         rifle_scope = !ReadByte();
1058
1059         serverflags = ReadByte();
1060
1061         minelayer_maxmines = ReadByte();
1062
1063         hagar_maxrockets = ReadByte();
1064
1065         g_trueaim_minrange = ReadCoord();
1066         g_balance_porto_secondary = ReadByte();
1067
1068         if(!postinit)
1069                 PostInit();
1070 }
1071
1072 void Net_ReadRace()
1073 {
1074         float b;
1075
1076         b = ReadByte();
1077
1078         switch(b)
1079         {
1080                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1081                         race_checkpoint = ReadByte();
1082                         race_time = ReadInt24_t();
1083                         race_previousbesttime = ReadInt24_t();
1084                         if(race_previousbestname)
1085                                 strunzone(race_previousbestname);
1086                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1087
1088                         race_checkpointtime = time;
1089
1090                         if(race_checkpoint == 0 || race_checkpoint == 254)
1091                         {
1092                                 race_penaltyaccumulator = 0;
1093                                 race_laptime = time; // valid
1094                         }
1095
1096                         break;
1097
1098                 case RACE_NET_CHECKPOINT_CLEAR:
1099                         race_laptime = 0;
1100                         race_checkpointtime = 0;
1101                         break;
1102
1103                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1104                         race_laptime = ReadCoord();
1105                         race_checkpointtime = -99999;
1106                         // fall through
1107                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1108                         race_nextcheckpoint = ReadByte();
1109
1110                         race_nextbesttime = ReadInt24_t();
1111                         if(race_nextbestname)
1112                                 strunzone(race_nextbestname);
1113                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1114                         break;
1115
1116                 case RACE_NET_CHECKPOINT_HIT_RACE:
1117                         race_mycheckpoint = ReadByte();
1118                         race_mycheckpointtime = time;
1119                         race_mycheckpointdelta = ReadInt24_t();
1120                         race_mycheckpointlapsdelta = ReadByte();
1121                         if(race_mycheckpointlapsdelta >= 128)
1122                                 race_mycheckpointlapsdelta -= 256;
1123                         if(race_mycheckpointenemy)
1124                                 strunzone(race_mycheckpointenemy);
1125                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1126                         break;
1127
1128                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1129                         race_othercheckpoint = ReadByte();
1130                         race_othercheckpointtime = time;
1131                         race_othercheckpointdelta = ReadInt24_t();
1132                         race_othercheckpointlapsdelta = ReadByte();
1133                         if(race_othercheckpointlapsdelta >= 128)
1134                                 race_othercheckpointlapsdelta -= 256;
1135                         if(race_othercheckpointenemy)
1136                                 strunzone(race_othercheckpointenemy);
1137                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1138                         break;
1139
1140                 case RACE_NET_PENALTY_RACE:
1141                         race_penaltyeventtime = time;
1142                         race_penaltytime = ReadShort();
1143                         //race_penaltyaccumulator += race_penaltytime;
1144                         if(race_penaltyreason)
1145                                 strunzone(race_penaltyreason);
1146                         race_penaltyreason = strzone(ReadString());
1147                         break;
1148
1149                 case RACE_NET_PENALTY_QUALIFYING:
1150                         race_penaltyeventtime = time;
1151                         race_penaltytime = ReadShort();
1152                         race_penaltyaccumulator += race_penaltytime;
1153                         if(race_penaltyreason)
1154                                 strunzone(race_penaltyreason);
1155                         race_penaltyreason = strzone(ReadString());
1156                         break;
1157
1158                 case RACE_NET_SERVER_RECORD:
1159                         race_server_record = ReadInt24_t();
1160                         break;
1161                 case RACE_NET_SPEED_AWARD:
1162                         race_speedaward = ReadInt24_t();
1163                         if(race_speedaward_holder)
1164                                 strunzone(race_speedaward_holder);
1165                         race_speedaward_holder = strzone(ReadString());
1166                         break;
1167                 case RACE_NET_SPEED_AWARD_BEST:
1168                         race_speedaward_alltimebest = ReadInt24_t();
1169                         if(race_speedaward_alltimebest_holder)
1170                                 strunzone(race_speedaward_alltimebest_holder);
1171                         race_speedaward_alltimebest_holder = strzone(ReadString());
1172                         break;
1173                 case RACE_NET_SERVER_RANKINGS:
1174                         float prevpos, del;
1175             int pos = ReadShort();
1176                         prevpos = ReadShort();
1177                         del = ReadShort();
1178
1179                         // move other rankings out of the way
1180             int i;
1181                         if (prevpos) {
1182                                 for (i=prevpos-1;i>pos-1;--i) {
1183                                         grecordtime[i] = grecordtime[i-1];
1184                                         if(grecordholder[i])
1185                                                 strunzone(grecordholder[i]);
1186                                         grecordholder[i] = strzone(grecordholder[i-1]);
1187                                 }
1188                         } else if (del) { // a record has been deleted by the admin
1189                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1190                                         if (i == RANKINGS_CNT-1) { // clear out last record
1191                                                 grecordtime[i] = 0;
1192                                                 if (grecordholder[i])
1193                                                         strunzone(grecordholder[i]);
1194                                                 grecordholder[i] = string_null;
1195                                         }
1196                                         else {
1197                                                 grecordtime[i] = grecordtime[i+1];
1198                                                 if (grecordholder[i])
1199                                                         strunzone(grecordholder[i]);
1200                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1201                                         }
1202                                 }
1203                         } else { // player has no ranked record yet
1204                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1205                                         grecordtime[i] = grecordtime[i-1];
1206                                         if(grecordholder[i])
1207                                                 strunzone(grecordholder[i]);
1208                                         grecordholder[i] = strzone(grecordholder[i-1]);
1209                                 }
1210                         }
1211
1212                         // store new ranking
1213                         if(grecordholder[pos-1] != "")
1214                                 strunzone(grecordholder[pos-1]);
1215                         grecordholder[pos-1] = strzone(ReadString());
1216                         grecordtime[pos-1] = ReadInt24_t();
1217                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1218                                 race_myrank = pos;
1219                         break;
1220                 case RACE_NET_SERVER_STATUS:
1221                         race_status = ReadShort();
1222                         if(race_status_name)
1223                                 strunzone(race_status_name);
1224                         race_status_name = strzone(ReadString());
1225         }
1226 }
1227
1228 void Net_TeamNagger()
1229 {
1230         teamnagger = 1;
1231 }
1232
1233 void Net_ReadPingPLReport()
1234 {
1235         int e, pi, pl, ml;
1236         e = ReadByte();
1237         pi = ReadShort();
1238         pl = ReadByte();
1239         ml = ReadByte();
1240         if (!(playerslots[e]))
1241                 return;
1242         playerslots[e].ping = pi;
1243         playerslots[e].ping_packetloss = pl / 255.0;
1244         playerslots[e].ping_movementloss = ml / 255.0;
1245 }
1246
1247 void Net_WeaponComplain()
1248 {
1249         complain_weapon = ReadByte();
1250
1251         if(complain_weapon_name)
1252                 strunzone(complain_weapon_name);
1253         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1254
1255         complain_weapon_type = ReadByte();
1256
1257         complain_weapon_time = time;
1258         weapontime = time; // ping the weapon panel
1259
1260         switch(complain_weapon_type)
1261         {
1262                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1263                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1264                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1265         }
1266 }
1267
1268 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1269 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1270 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1271 bool CSQC_Parse_TempEntity()
1272 {
1273         // Acquire TE ID
1274         int nTEID = ReadByte();
1275
1276         if (autocvar_developer_csqcentities)
1277                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1278
1279         FOREACH(TempEntities, it.m_id == nTEID, LAMBDA(
1280                 it.m_read(NULL, true);
1281                 return true;
1282         ));
1283         switch (nTEID)
1284         {
1285                 case TE_CSQC_MUTATOR:
1286                         int mutID = ReadMutator();
1287                         if (MUTATOR_CALLHOOK(CSQC_Parse_TempEntity, mutID))
1288                         return true;
1289                 case TE_CSQC_TARGET_MUSIC:
1290                         Net_TargetMusic();
1291                         return true;
1292                 case TE_CSQC_PICTURE:
1293                         Net_MapVote_Picture();
1294                         return true;
1295                 case TE_CSQC_RACE:
1296                         Net_ReadRace();
1297                         return true;
1298                 case TE_CSQC_VORTEXBEAMPARTICLE:
1299                         Net_ReadVortexBeamParticle();
1300                         return true;
1301                 case TE_CSQC_TEAMNAGGER:
1302                         Net_TeamNagger();
1303                         return true;
1304                 case TE_CSQC_ARC:
1305                         Net_ReadArc();
1306                         return true;
1307                 case TE_CSQC_PINGPLREPORT:
1308                         Net_ReadPingPLReport();
1309                         return true;
1310                 case TE_CSQC_WEAPONCOMPLAIN:
1311                         Net_WeaponComplain();
1312                         return true;
1313                 case TE_CSQC_VEHICLESETUP:
1314                         Net_VehicleSetup();
1315                         return true;
1316                 case TE_CSQC_SVNOTICE:
1317                         cl_notice_read();
1318                         return true;
1319                 case TE_CSQC_SHOCKWAVEPARTICLE:
1320                         Net_ReadShockwaveParticle();
1321                         return true;
1322                 default:
1323                         // No special logic for this temporary entity; return 0 so the engine can handle it
1324                         return false;
1325         }
1326 }
1327
1328 string getcommandkey(string text, string command)
1329 {
1330         string keys;
1331         float n, j, k, l = 0;
1332
1333         if (!autocvar_hud_showbinds)
1334                 return text;
1335
1336         keys = db_get(binddb, command);
1337         if (keys == "")
1338         {
1339                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1340                 for(j = 0; j < n; ++j)
1341                 {
1342                         k = stof(argv(j));
1343                         if(k != -1)
1344                         {
1345                                 if ("" == keys)
1346                                         keys = keynumtostring(k);
1347                                 else
1348                                         keys = strcat(keys, ", ", keynumtostring(k));
1349
1350                                 ++l;
1351                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1352                                         break;
1353                         }
1354
1355                 }
1356                 if (keys == "")
1357                         keys = "NO_KEY";
1358                 db_put(binddb, command, keys);
1359         }
1360
1361         if (keys == "NO_KEY") {
1362                 if (autocvar_hud_showbinds > 1)
1363                         return sprintf(_("%s (not bound)"), text);
1364                 else
1365                         return text;
1366         }
1367         else if (autocvar_hud_showbinds > 1)
1368                 return sprintf("%s (%s)", text, keys);
1369         else
1370                 return keys;
1371 }