qcsrc/client/main.qc

   1 #include "main.qh"
   2 #include "_all.qh"
   3
   4 #include "controlpoint.qh"
   5 #include "csqcmodel_hooks.qh"
   6 #include "damage.qh"
   7 #include "effects.qh"
   8 #include "generator.qh"
   9 #include "gibs.qh"
  10 #include "hook.qh"
  11 #include "hud.qh"
  12 #include "hud_config.qh"
  13 #include "laser.qh"
  14 #include "mapvoting.qh"
  15 #include "modeleffects.qh"
  16 #include "particles.qh"
  17 #include "scoreboard.qh"
  18 #include "shownames.qh"
  19 #include "tuba.qh"
  20 #include "t_items.qh"
  21 #include "wall.qh"
  22
  23 #include "../common/vehicles/all.qh"
  24
  25 #include "mutators/events.qh"
  26
  27 #include "weapons/projectile.qh"
  28
  29 #include "../common/buffs.qh"
  30 #include "../common/deathtypes.qh"
  31 #include "../common/effects/effects.qh"
  32 #include "../common/mapinfo.qh"
  33 #include "../common/monsters/all.qh"
  34 #include "../common/nades.qh"
  35 #include "../common/net_notice.qh"
  36 #include "../common/notifications.qh"
  37 #include "../common/stats.qh"
  38 #include "../common/teams.qh"
  39
  40 #include "../common/items/all.qh"
  41
  42 #include "../common/mutators/base.qh"
  43
  44 #include "../common/weapons/all.qh"
  45
  46 #include "../csqcmodellib/cl_model.qh"
  47 #include "../csqcmodellib/interpolate.qh"
  48
  49 #include "../common/triggers/include.qh"
  50
  51 #include "../common/turrets/cl_turrets.qh"
  52 #include "../common/turrets/turrets.qh"
  53
  54 #include "../warpzonelib/client.qh"
  55
  56 // --------------------------------------------------------------------------
  57 // BEGIN REQUIRED CSQC FUNCTIONS
  58 //include "main.qh"
  59
  60 entity clearentity_ent;
  61 void clearentity(entity e)
  62 {
  63         if (!clearentity_ent)
  64         {
  65                 clearentity_ent = spawn();
  66                 clearentity_ent.classname = "clearentity";
  67         }
  68         int n = e.entnum;
  69         copyentity(clearentity_ent, e);
  70         e.entnum = n;
  71 }
  72
  73 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  74 void menu_show_error()
  75 {
  76         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  77 }
  78
  79 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  80 // Useful for precaching things
  81
  82 void menu_sub_null()
  83 {
  84 }
  85
  86 string forcefog;
  87 void ConsoleCommand_macro_init();
  88 void CSQC_Init(void)
  89 {
  90         prvm_language = strzone(cvar_string("prvm_language"));
  91
  92 #ifdef WATERMARK
  93         LOG_TRACEF("^4CSQC Build information: ^1%s\n", WATERMARK);
  94 #endif
  95
  96         int i;
  97
  98         binddb = db_create();
  99         tempdb = db_create();
 100         ClientProgsDB = db_load("client.db");
 101         compressShortVector_init();
 102
 103         draw_endBoldFont();
 104         menu_visible = false;
 105         menu_show = menu_show_error;
 106         menu_action = func_null;
 107
 108         for(i = 0; i < 255; ++i)
 109                 if(getplayerkeyvalue(i, "viewentity") == "")
 110                         break;
 111         maxclients = i;
 112
 113         //registercommand("hud_configure");
 114         //registercommand("hud_save");
 115         //registercommand("menu_action");
 116
 117         ConsoleCommand_macro_init();
 118
 119         registercvar("hud_usecsqc", "1");
 120         registercvar("scoreboard_columns", "default");
 121
 122         registercvar("cl_nade_type", "3");
 123         registercvar("cl_pokenade_type", "zombie");
 124
 125         registercvar("cl_jumpspeedcap_min", "");
 126         registercvar("cl_jumpspeedcap_max", "");
 127
 128         registercvar("cl_multijump", "0");
 129
 130         registercvar("cl_spawn_near_teammate", "1");
 131
 132         gametype = 0;
 133
 134         // hud_fields uses strunzone on the titles!
 135         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 136                 hud_title[i] = strzone("(null)");
 137
 138         Cmd_HUD_SetFields(0);
 139
 140         postinit = false;
 141
 142         calledhooks = 0;
 143
 144         teams = Sort_Spawn();
 145         players = Sort_Spawn();
 146
 147         GetTeam(NUM_SPECTATOR, true); // add specs first
 148
 149         // needs to be done so early because of the constants they create
 150         static_init();
 151         CALL_ACCUMULATED_FUNCTION(RegisterTurrets);
 152         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 153         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 154         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
 155
 156         initialize_minigames();
 157
 158         // precaches
 159         precache_sound("misc/hit.wav");
 160         precache_sound("misc/typehit.wav");
 161
 162         generator_precache();
 163         Projectile_Precache();
 164         Hook_Precache();
 165         GibSplash_Precache();
 166         Tuba_Precache();
 167         CSQCPlayer_Precache();
 168
 169         if(autocvar_cl_reticle)
 170         {
 171                 precache_pic("gfx/reticle_normal");
 172                 // weapon reticles are precached in weapon files
 173         }
 174
 175         get_mi_min_max_texcoords(1); // try the CLEVER way first
 176         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 177         shortmapname = mi_shortname;
 178
 179         if(precache_pic(minimapname) == "")
 180         {
 181                 // but maybe we have a non-clever minimap
 182                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 183                 if(precache_pic(minimapname) == "")
 184                         minimapname = ""; // FAIL
 185                 else
 186                         get_mi_min_max_texcoords(0); // load new texcoords
 187         }
 188
 189         mi_center = (mi_min + mi_max) * 0.5;
 190         mi_scale = mi_max - mi_min;
 191         minimapname = strzone(minimapname);
 192
 193         WarpZone_Init();
 194
 195         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 196         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 197 }
 198
 199 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 200 void Shutdown(void)
 201 {
 202         WarpZone_Shutdown();
 203
 204         remove(teams);
 205         remove(players);
 206         db_close(binddb);
 207         db_close(tempdb);
 208         if(autocvar_cl_db_saveasdump)
 209                 db_dump(ClientProgsDB, "client.db");
 210         else
 211                 db_save(ClientProgsDB, "client.db");
 212         db_close(ClientProgsDB);
 213
 214         if(camera_active)
 215                 cvar_set("chase_active",ftos(chase_active_backup));
 216
 217         // unset the event chasecam's chase_active
 218         if(autocvar_chase_active < 0)
 219                 cvar_set("chase_active", "0");
 220
 221         if (!isdemo())
 222         {
 223                 if (!(calledhooks & HOOK_START))
 224                         localcmd("\n_cl_hook_gamestart nop\n");
 225                 if (!(calledhooks & HOOK_END))
 226                         localcmd("\ncl_hook_gameend\n");
 227         }
 228
 229         deactivate_minigame();
 230         HUD_MinigameMenu_Close();
 231 }
 232
 233 .float has_team;
 234 float SetTeam(entity o, int Team)
 235 {
 236         entity tm;
 237         if(teamplay)
 238         {
 239                 switch(Team)
 240                 {
 241                         case -1:
 242                         case NUM_TEAM_1:
 243                         case NUM_TEAM_2:
 244                         case NUM_TEAM_3:
 245                         case NUM_TEAM_4:
 246                                 break;
 247                         default:
 248                                 if(GetTeam(Team, false) == world)
 249                                 {
 250                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 251                                         Team = NUM_SPECTATOR;
 252                                 }
 253                                 break;
 254                 }
 255         }
 256         else
 257         {
 258                 switch(Team)
 259                 {
 260                         case -1:
 261                         case 0:
 262                                 break;
 263                         default:
 264                                 if(GetTeam(Team, false) == world)
 265                                 {
 266                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 267                                         Team = NUM_SPECTATOR;
 268                                 }
 269                                 break;
 270                 }
 271         }
 272         if(Team == -1) // leave
 273         {
 274                 if(o.has_team)
 275                 {
 276                         tm = GetTeam(o.team, false);
 277                         tm.team_size -= 1;
 278                         o.has_team = 0;
 279                         return true;
 280                 }
 281         }
 282         else
 283         {
 284                 if (!o.has_team)
 285                 {
 286                         o.team = Team;
 287                         tm = GetTeam(Team, true);
 288                         tm.team_size += 1;
 289                         o.has_team = 1;
 290                         return true;
 291                 }
 292                 else if(Team != o.team)
 293                 {
 294                         tm = GetTeam(o.team, false);
 295                         tm.team_size -= 1;
 296                         o.team = Team;
 297                         tm = GetTeam(Team, true);
 298                         tm.team_size += 1;
 299                         return true;
 300                 }
 301         }
 302         return false;
 303 }
 304
 305 void Playerchecker_Think()
 306 {SELFPARAM();
 307     int i;
 308         entity e;
 309         for(i = 0; i < maxclients; ++i)
 310         {
 311                 e = playerslots[i];
 312                 if(GetPlayerName(i) == "")
 313                 {
 314                         if(e.sort_prev)
 315                         {
 316                                 // player disconnected
 317                                 SetTeam(e, -1);
 318                                 RemovePlayer(e);
 319                                 e.sort_prev = world;
 320                                 //e.gotscores = 0;
 321                         }
 322                 }
 323                 else
 324                 {
 325                         if (!e.sort_prev)
 326                         {
 327                                 // player connected
 328                                 if (!e)
 329                                         playerslots[i] = e = spawn();
 330                                 e.sv_entnum = i;
 331                                 e.ping = 0;
 332                                 e.ping_packetloss = 0;
 333                                 e.ping_movementloss = 0;
 334                                 //e.gotscores = 0; // we might already have the scores...
 335                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 336                                 RegisterPlayer(e);
 337                                 HUD_UpdatePlayerPos(e);
 338                         }
 339                 }
 340         }
 341         self.nextthink = time + 0.2;
 342 }
 343
 344 void Porto_Init();
 345 void TrueAim_Init();
 346 void PostInit(void)
 347 {
 348         entity playerchecker;
 349         playerchecker = spawn();
 350         playerchecker.think = Playerchecker_Think;
 351         playerchecker.nextthink = time + 0.2;
 352
 353         Porto_Init();
 354         TrueAim_Init();
 355
 356         postinit = true;
 357 }
 358
 359 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 360 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 361 // All keys are in ascii.
 362 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 363 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 364 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 365 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 366 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 367 {
 368         float bSkipKey;
 369         bSkipKey = false;
 370
 371         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 372                 return true;
 373
 374         if (QuickMenu_InputEvent(bInputType, nPrimary, nSecondary))
 375                 return true;
 376
 377         if ( HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary) )
 378                 return true;
 379
 380         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 381                 return true;
 382
 383         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
 384                 return true;
 385
 386         if(menu_visible && menu_action)
 387                 if(menu_action(bInputType, nPrimary, nSecondary))
 388                         return true;
 389
 390         return bSkipKey;
 391 }
 392
 393 // END REQUIRED CSQC FUNCTIONS
 394 // --------------------------------------------------------------------------
 395
 396 // --------------------------------------------------------------------------
 397 // BEGIN OPTIONAL CSQC FUNCTIONS
 398
 399 void Ent_RemoveEntCS()
 400 {SELFPARAM();
 401         entcs_receiver[self.sv_entnum] = world;
 402 }
 403 void Ent_ReadEntCS()
 404 {SELFPARAM();
 405     int sf;
 406         InterpolateOrigin_Undo();
 407
 408         self.classname = "entcs_receiver";
 409         sf = ReadByte();
 410
 411         if(sf & 1)
 412                 self.sv_entnum = ReadByte();
 413         if(sf & 2)
 414         {
 415                 self.origin_x = ReadShort();
 416                 self.origin_y = ReadShort();
 417                 self.origin_z = ReadShort();
 418                 setorigin(self, self.origin);
 419         }
 420         if(sf & 4)
 421         {
 422                 self.angles_y = ReadByte() * 360.0 / 256;
 423                 self.angles_x = self.angles_z = 0;
 424         }
 425         if(sf & 8)
 426                 self.healthvalue = ReadByte() * 10;
 427         if(sf & 16)
 428                 self.armorvalue = ReadByte() * 10;
 429
 430         entcs_receiver[self.sv_entnum] = self;
 431         self.entremove = Ent_RemoveEntCS;
 432         self.iflags |= IFLAG_ORIGIN;
 433
 434         InterpolateOrigin_Note();
 435 }
 436
 437 void Ent_Remove();
 438
 439 void Ent_RemovePlayerScore()
 440 {SELFPARAM();
 441         if(self.owner) {
 442                 SetTeam(self.owner, -1);
 443                 self.owner.gotscores = 0;
 444                 for(int i = 0; i < MAX_SCORE; ++i) {
 445                         self.owner.(scores[i]) = 0; // clear all scores
 446                 }
 447         }
 448 }
 449
 450 void Ent_ReadPlayerScore()
 451 {SELFPARAM();
 452         int i, n;
 453         bool isNew;
 454         entity o;
 455
 456         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 457         // (no I've never heard of M-x replace-string, sed, or anything like that)
 458         isNew = !self.owner; // workaround for DP bug
 459         n = ReadByte()-1;
 460
 461 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 462         if(!isNew && n != self.sv_entnum)
 463         {
 464                 //print("A CSQC entity changed its owner!\n");
 465                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 466                 isNew = true;
 467                 Ent_Remove();
 468                 self.enttype = ENT_CLIENT_SCORES;
 469         }
 470 #endif
 471
 472         self.sv_entnum = n;
 473
 474         if (!(playerslots[self.sv_entnum]))
 475                 playerslots[self.sv_entnum] = spawn();
 476         o = self.owner = playerslots[self.sv_entnum];
 477         o.sv_entnum = self.sv_entnum;
 478         o.gotscores = 1;
 479
 480         //if (!o.sort_prev)
 481         //      RegisterPlayer(o);
 482         //playerchecker will do this for us later, if it has not already done so
 483
 484     int sf, lf;
 485 #if MAX_SCORE <= 8
 486         sf = ReadByte();
 487         lf = ReadByte();
 488 #else
 489         sf = ReadShort();
 490         lf = ReadShort();
 491 #endif
 492     int p;
 493         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 494                 if(sf & p)
 495                 {
 496                         if(lf & p)
 497                                 o.(scores[i]) = ReadInt24_t();
 498                         else
 499                                 o.(scores[i]) = ReadChar();
 500                 }
 501
 502         if(o.sort_prev)
 503                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 504
 505         self.entremove = Ent_RemovePlayerScore;
 506 }
 507
 508 void Ent_ReadTeamScore()
 509 {SELFPARAM();
 510         int i;
 511         entity o;
 512
 513         self.team = ReadByte();
 514         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 515
 516     int sf, lf;
 517 #if MAX_TEAMSCORE <= 8
 518         sf = ReadByte();
 519         lf = ReadByte();
 520 #else
 521         sf = ReadShort();
 522         lf = ReadShort();
 523 #endif
 524         int p;
 525         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 526                 if(sf & p)
 527                 {
 528                         if(lf & p)
 529                                 o.(teamscores[i]) = ReadInt24_t();
 530                         else
 531                                 o.(teamscores[i]) = ReadChar();
 532                 }
 533
 534         HUD_UpdateTeamPos(o);
 535 }
 536
 537 void Ent_ClientData()
 538 {
 539         float newspectatee_status;
 540
 541     int f = ReadByte();
 542
 543         scoreboard_showscores_force = (f & 1);
 544
 545         if(f & 2)
 546         {
 547                 newspectatee_status = ReadByte();
 548                 if(newspectatee_status == player_localnum + 1)
 549                         newspectatee_status = -1; // observing
 550         }
 551         else
 552                 newspectatee_status = 0;
 553
 554         spectatorbutton_zoom = (f & 4);
 555
 556         if(f & 8)
 557         {
 558                 angles_held_status = 1;
 559                 angles_held.x = ReadAngle();
 560                 angles_held.y = ReadAngle();
 561                 angles_held.z = 0;
 562         }
 563         else
 564                 angles_held_status = 0;
 565
 566         if(newspectatee_status != spectatee_status)
 567         {
 568                 // clear race stuff
 569                 race_laptime = 0;
 570                 race_checkpointtime = 0;
 571         }
 572         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 573         {
 574                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 575                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 576                 )
 577                         prev_p_health = -1;
 578                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 579                         prev_health = -1;
 580         }
 581         spectatee_status = newspectatee_status;
 582
 583         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 584 }
 585
 586 void Ent_Nagger()
 587 {
 588     int i, j, b, f;
 589
 590     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 591
 592         if(!(nags & 4))
 593         {
 594                 if(vote_called_vote)
 595                         strunzone(vote_called_vote);
 596                 vote_called_vote = string_null;
 597                 vote_active = 0;
 598         }
 599         else
 600         {
 601                 vote_active = 1;
 602         }
 603
 604         if(nags & 64)
 605         {
 606                 vote_yescount = ReadByte();
 607                 vote_nocount = ReadByte();
 608                 vote_needed = ReadByte();
 609                 vote_highlighted = ReadChar();
 610         }
 611
 612         if(nags & 128)
 613         {
 614                 if(vote_called_vote)
 615                         strunzone(vote_called_vote);
 616                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 617         }
 618
 619         if(nags & 1)
 620         {
 621                 for(j = 0; j < maxclients; ++j)
 622                         if(playerslots[j])
 623                                 playerslots[j].ready = 1;
 624                 for(i = 1; i <= maxclients; i += 8)
 625                 {
 626                         f = ReadByte();
 627                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 628                                 if (!(f & b))
 629                                         if(playerslots[j])
 630                                                 playerslots[j].ready = 0;
 631                 }
 632         }
 633
 634         ready_waiting = (nags & 1);
 635         ready_waiting_for_me = (nags & 2);
 636         vote_waiting = (nags & 4);
 637         vote_waiting_for_me = (nags & 8);
 638         warmup_stage = (nags & 16);
 639 }
 640
 641 void Ent_EliminatedPlayers()
 642 {
 643     int i, j, b, f;
 644
 645     int sf = ReadByte();
 646         if(sf & 1)
 647         {
 648                 for(j = 0; j < maxclients; ++j)
 649                         if(playerslots[j])
 650                                 playerslots[j].eliminated = 1;
 651                 for(i = 1; i <= maxclients; i += 8)
 652                 {
 653                         f = ReadByte();
 654                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 655                                 if (!(f & b))
 656                                         if(playerslots[j])
 657                                                 playerslots[j].eliminated = 0;
 658                 }
 659         }
 660 }
 661
 662 void Ent_RandomSeed()
 663 {
 664         float s;
 665         prandom_debug();
 666         s = ReadShort();
 667         psrandom(s);
 668 }
 669
 670 void Ent_ReadAccuracy(void)
 671 {
 672     int f, w;
 673     int sf = ReadInt24_t();
 674         if(sf == 0)
 675         {
 676                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 677                         weapon_accuracy[w] = -1;
 678                 return;
 679         }
 680
 681         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 682         {
 683                 if(sf & f)
 684                 {
 685             int b = ReadByte();
 686                         if(b == 0)
 687                                 weapon_accuracy[w] = -1;
 688                         else if(b == 255)
 689                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 690                         else
 691                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 692                 }
 693                 if(f == 0x800000)
 694                         f = 1;
 695                 else
 696                         f *= 2;
 697         }
 698 }
 699
 700 void Spawn_Draw(void)
 701 {SELFPARAM();
 702         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 703 }
 704
 705 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 706 {SELFPARAM();
 707         float teamnum = (ReadByte() - 1);
 708         vector spn_origin;
 709         spn_origin.x = ReadShort();
 710         spn_origin.y = ReadShort();
 711         spn_origin.z = ReadShort();
 712
 713         if(is_new)
 714         {
 715                 self.origin = spn_origin;
 716                 setsize(self, PL_MIN_CONST, PL_MAX_CONST);
 717                 droptofloor();
 718
 719                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 720                 {
 721                         self.mdl = "models/spawnpoint.md3";
 722                         self.colormod = Team_ColorRGB(teamnum);
 723                         precache_model(self.mdl);
 724                         setmodel(self, self.mdl);
 725                         self.drawmask = MASK_NORMAL;
 726                         //self.movetype = MOVETYPE_NOCLIP;
 727                         //self.draw = Spawn_Draw;
 728                 }*/
 729                 if(autocvar_cl_spawn_point_particles)
 730                 {
 731                         if((serverflags & SERVERFLAG_TEAMPLAY))
 732                         {
 733                                 switch(teamnum)
 734                                 {
 735                                         case NUM_TEAM_1: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
 736                                         case NUM_TEAM_2: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
 737                                         case NUM_TEAM_3: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
 738                                         case NUM_TEAM_4: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
 739                                         default: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
 740                                 }
 741                         }
 742                         else { self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
 743
 744                         self.draw = Spawn_Draw;
 745                 }
 746         }
 747
 748         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 749 }
 750
 751 void Ent_ReadSpawnEvent(float is_new)
 752 {SELFPARAM();
 753         // If entnum is 0, ONLY do the local spawn actions
 754         // this way the server can disable the sending of
 755         // spawn origin or such to clients if wanted.
 756         float entnum = ReadByte();
 757
 758         if(entnum)
 759         {
 760                 self.origin_x = ReadShort();
 761                 self.origin_y = ReadShort();
 762                 self.origin_z = ReadShort();
 763
 764                 if(is_new)
 765                 {
 766                         float teamnum = GetPlayerColor(entnum - 1);
 767
 768                         if(autocvar_cl_spawn_event_particles)
 769                         {
 770                                 switch(teamnum)
 771                                 {
 772                                         case NUM_TEAM_1: pointparticles(particleeffectnum(EFFECT_SPAWN_RED), self.origin, '0 0 0', 1); break;
 773                                         case NUM_TEAM_2: pointparticles(particleeffectnum(EFFECT_SPAWN_BLUE), self.origin, '0 0 0', 1); break;
 774                                         case NUM_TEAM_3: pointparticles(particleeffectnum(EFFECT_SPAWN_YELLOW), self.origin, '0 0 0', 1); break;
 775                                         case NUM_TEAM_4: pointparticles(particleeffectnum(EFFECT_SPAWN_PINK), self.origin, '0 0 0', 1); break;
 776                                         default: pointparticles(particleeffectnum(EFFECT_SPAWN_NEUTRAL), self.origin, '0 0 0', 1); break;
 777                                 }
 778                         }
 779                         if(autocvar_cl_spawn_event_sound)
 780                         {
 781                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
 782                         }
 783                 }
 784         }
 785
 786         // local spawn actions
 787         if(is_new && (!entnum || (entnum == player_localentnum)))
 788         {
 789                 zoomin_effect = 1;
 790                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 791
 792                 if(autocvar_cl_unpress_zoom_on_spawn)
 793                 {
 794                         localcmd("-zoom\n");
 795                         button_zoom = false;
 796                 }
 797         }
 798         HUD_Radar_Hide_Maximized();
 799         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 800 }
 801
 802 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 803 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 804 void Ent_RadarLink();
 805 void Ent_Init();
 806 void Ent_ScoresInfo();
 807 void CSQC_Ent_Update(float bIsNewEntity)
 808 {SELFPARAM();
 809         float t;
 810         float savetime;
 811         t = ReadByte();
 812
 813         if(autocvar_developer_csqcentities)
 814                 LOG_INFOF("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 815
 816         // set up the "time" global for received entities to be correct for interpolation purposes
 817         savetime = time;
 818         if(servertime)
 819         {
 820                 time = servertime;
 821         }
 822         else
 823         {
 824                 serverprevtime = time;
 825                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 826                 time = serverprevtime + serverdeltatime;
 827         }
 828
 829 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 830         if(self.enttype)
 831         {
 832                 if(t != self.enttype || bIsNewEntity)
 833                 {
 834                         //print("A CSQC entity changed its type!\n");
 835                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 836                         Ent_Remove();
 837                         clearentity(self);
 838                         bIsNewEntity = 1;
 839                 }
 840         }
 841         else
 842         {
 843                 if(!bIsNewEntity)
 844                 {
 845                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 846                         bIsNewEntity = 1;
 847                 }
 848         }
 849 #endif
 850         self.enttype = t;
 851         switch(t)
 852         {
 853                 case ENT_CLIENT_MUTATOR: {
 854                         int mutID = ReadMutator();
 855                         if (!MUTATOR_CALLHOOK(CSQC_Ent_Update, mutID, bIsNewEntity))
 856                         error(sprintf("Unknown mutator type in CSQC_Ent_Update (mutID: %d, edict: %d, classname: %s)\n", mutID, num_for_edict(self), self.classname));
 857                         break;
 858                 }
 859                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 860                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 861                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 862                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 863                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 864                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 865                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 866                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
 867                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 868                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 869                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 870                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 871                 case ENT_CLIENT_INIT: Ent_Init(); break;
 872                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 873                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 874                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 875                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 876                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 877                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 878                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 879                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 880                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 881                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 882                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 883                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 884                 case ENT_CLIENT_INVENTORY: Inventory_Read(self); break;
 885                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
 886                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 887                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 888                 case ENT_CLIENT_TURRET: ent_turret(); break;
 889                 case ENT_CLIENT_GENERATOR: ent_generator(); break;
 890                 case ENT_CLIENT_CONTROLPOINT_ICON: ent_cpicon(); break;
 891                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 892                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 893                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 894                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 895                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 896                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 897                 case ENT_CLIENT_HEALING_ORB: ent_healer(); break;
 898                 case ENT_CLIENT_MINIGAME: ent_read_minigame(); break;
 899                 case ENT_CLIENT_VIEWLOC: ent_viewloc(); break;
 900                 case ENT_CLIENT_VIEWLOC_TRIGGER: ent_viewloc_trigger(); break;
 901                 case ENT_CLIENT_LADDER: ent_func_ladder(); break;
 902                 case ENT_CLIENT_TRIGGER_PUSH: ent_trigger_push(); break;
 903                 case ENT_CLIENT_TARGET_PUSH: ent_target_push(); break;
 904                 case ENT_CLIENT_CONVEYOR: ent_conveyor(); break;
 905                 case ENT_CLIENT_DOOR: ent_door(); break;
 906                 case ENT_CLIENT_PLAT: ent_plat(); break;
 907                 case ENT_CLIENT_SWAMP: ent_swamp(); break;
 908                 case ENT_CLIENT_CORNER: ent_corner(); break;
 909                 case ENT_CLIENT_KEYLOCK: ent_keylock(); break;
 910                 case ENT_CLIENT_TRAIN: ent_train(); break;
 911                 case ENT_CLIENT_TRIGGER_IMPULSE: ent_trigger_impulse(); break;
 912                 case ENT_CLIENT_EFFECT: Read_Effect(bIsNewEntity); break;
 913
 914                 default:
 915                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 916                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
 917                         break;
 918         }
 919
 920         time = savetime;
 921 }
 922 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 923 // used when an entity changes its type. For an entity that someone interacts
 924 // with others, make sure it can no longer do so.
 925 void Ent_Remove()
 926 {SELFPARAM();
 927         if(self.entremove)
 928                 self.entremove();
 929
 930         if(self.skeletonindex)
 931         {
 932                 skel_delete(self.skeletonindex);
 933                 self.skeletonindex = 0;
 934         }
 935
 936         if(self.snd_looping > 0)
 937         {
 938                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 939                 self.snd_looping = 0;
 940         }
 941
 942         self.enttype = 0;
 943         self.classname = "";
 944         self.draw = menu_sub_null;
 945         self.entremove = menu_sub_null;
 946         // TODO possibly set more stuff to defaults
 947 }
 948 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 949 void CSQC_Ent_Remove()
 950 {SELFPARAM();
 951         if(autocvar_developer_csqcentities)
 952                 LOG_INFOF("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 953
 954         if(wasfreed(self))
 955         {
 956                 LOG_INFO("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 957                 return;
 958         }
 959         if(self.enttype)
 960                 Ent_Remove();
 961         remove(self);
 962 }
 963
 964 void Gamemode_Init()
 965 {
 966         if (!isdemo())
 967         {
 968                 if(!(calledhooks & HOOK_START))
 969                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 970                 calledhooks |= HOOK_START;
 971         }
 972 }
 973 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 974 void CSQC_Parse_StuffCmd(string strMessage)
 975 {
 976         if(autocvar_developer_csqcentities)
 977                 LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 978
 979         localcmd(strMessage);
 980 }
 981 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 982 void CSQC_Parse_Print(string strMessage)
 983 {
 984         if(autocvar_developer_csqcentities)
 985                 LOG_INFOF("CSQC_Parse_Print(\"%s\")\n", strMessage);
 986
 987         print(ColorTranslateRGB(strMessage));
 988 }
 989
 990 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 991 void CSQC_Parse_CenterPrint(string strMessage)
 992 {
 993         if(autocvar_developer_csqcentities)
 994                 LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 995
 996         centerprint_hud(strMessage);
 997 }
 998
 999 string notranslate_fogcmd1 = "\nfog ";
1000 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
1001 void Fog_Force()
1002 {
1003         // TODO somehow thwart prvm_globalset client ...
1004
1005         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
1006                 { localcmd("\nr_drawfog 0\n"); }
1007         else if(forcefog != "")
1008                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
1009 }
1010
1011 void Gamemode_Init();
1012 void Ent_ScoresInfo()
1013 {SELFPARAM();
1014     int i;
1015         self.classname = "ent_client_scores_info";
1016         gametype = ReadInt24_t();
1017         HUD_ModIcons_SetFunc();
1018         for(i = 0; i < MAX_SCORE; ++i)
1019         {
1020                 if(scores_label[i])
1021                         strunzone(scores_label[i]);
1022                 scores_label[i] = strzone(ReadString());
1023                 scores_flags[i] = ReadByte();
1024         }
1025         for(i = 0; i < MAX_TEAMSCORE; ++i)
1026         {
1027                 if(teamscores_label[i])
1028                         strunzone(teamscores_label[i]);
1029                 teamscores_label[i] = strzone(ReadString());
1030                 teamscores_flags[i] = ReadByte();
1031         }
1032         HUD_InitScores();
1033         Gamemode_Init();
1034 }
1035
1036 void Ent_Init()
1037 {SELFPARAM();
1038         self.classname = "ent_client_init";
1039
1040         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1041
1042         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1043         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1044         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1045         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1046         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1047         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1048         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1049         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1050
1051         if(forcefog)
1052                 strunzone(forcefog);
1053         forcefog = strzone(ReadString());
1054
1055         armorblockpercent = ReadByte() / 255.0;
1056
1057         g_balance_mortar_bouncefactor = ReadCoord();
1058         g_balance_mortar_bouncestop = ReadCoord();
1059         g_balance_electro_secondary_bouncefactor = ReadCoord();
1060         g_balance_electro_secondary_bouncestop = ReadCoord();
1061
1062         vortex_scope = !ReadByte();
1063         rifle_scope = !ReadByte();
1064
1065         serverflags = ReadByte();
1066
1067         minelayer_maxmines = ReadByte();
1068
1069         hagar_maxrockets = ReadByte();
1070
1071         g_trueaim_minrange = ReadCoord();
1072         g_balance_porto_secondary = ReadByte();
1073
1074         if(!postinit)
1075                 PostInit();
1076 }
1077
1078 void Net_ReadRace()
1079 {
1080         float b;
1081
1082         b = ReadByte();
1083
1084         switch(b)
1085         {
1086                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1087                         race_checkpoint = ReadByte();
1088                         race_time = ReadInt24_t();
1089                         race_previousbesttime = ReadInt24_t();
1090                         if(race_previousbestname)
1091                                 strunzone(race_previousbestname);
1092                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1093
1094                         race_checkpointtime = time;
1095
1096                         if(race_checkpoint == 0 || race_checkpoint == 254)
1097                         {
1098                                 race_penaltyaccumulator = 0;
1099                                 race_laptime = time; // valid
1100                         }
1101
1102                         break;
1103
1104                 case RACE_NET_CHECKPOINT_CLEAR:
1105                         race_laptime = 0;
1106                         race_checkpointtime = 0;
1107                         break;
1108
1109                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1110                         race_laptime = ReadCoord();
1111                         race_checkpointtime = -99999;
1112                         // fall through
1113                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1114                         race_nextcheckpoint = ReadByte();
1115
1116                         race_nextbesttime = ReadInt24_t();
1117                         if(race_nextbestname)
1118                                 strunzone(race_nextbestname);
1119                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1120                         break;
1121
1122                 case RACE_NET_CHECKPOINT_HIT_RACE:
1123                         race_mycheckpoint = ReadByte();
1124                         race_mycheckpointtime = time;
1125                         race_mycheckpointdelta = ReadInt24_t();
1126                         race_mycheckpointlapsdelta = ReadByte();
1127                         if(race_mycheckpointlapsdelta >= 128)
1128                                 race_mycheckpointlapsdelta -= 256;
1129                         if(race_mycheckpointenemy)
1130                                 strunzone(race_mycheckpointenemy);
1131                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1132                         break;
1133
1134                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1135                         race_othercheckpoint = ReadByte();
1136                         race_othercheckpointtime = time;
1137                         race_othercheckpointdelta = ReadInt24_t();
1138                         race_othercheckpointlapsdelta = ReadByte();
1139                         if(race_othercheckpointlapsdelta >= 128)
1140                                 race_othercheckpointlapsdelta -= 256;
1141                         if(race_othercheckpointenemy)
1142                                 strunzone(race_othercheckpointenemy);
1143                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1144                         break;
1145
1146                 case RACE_NET_PENALTY_RACE:
1147                         race_penaltyeventtime = time;
1148                         race_penaltytime = ReadShort();
1149                         //race_penaltyaccumulator += race_penaltytime;
1150                         if(race_penaltyreason)
1151                                 strunzone(race_penaltyreason);
1152                         race_penaltyreason = strzone(ReadString());
1153                         break;
1154
1155                 case RACE_NET_PENALTY_QUALIFYING:
1156                         race_penaltyeventtime = time;
1157                         race_penaltytime = ReadShort();
1158                         race_penaltyaccumulator += race_penaltytime;
1159                         if(race_penaltyreason)
1160                                 strunzone(race_penaltyreason);
1161                         race_penaltyreason = strzone(ReadString());
1162                         break;
1163
1164                 case RACE_NET_SERVER_RECORD:
1165                         race_server_record = ReadInt24_t();
1166                         break;
1167                 case RACE_NET_SPEED_AWARD:
1168                         race_speedaward = ReadInt24_t();
1169                         if(race_speedaward_holder)
1170                                 strunzone(race_speedaward_holder);
1171                         race_speedaward_holder = strzone(ReadString());
1172                         break;
1173                 case RACE_NET_SPEED_AWARD_BEST:
1174                         race_speedaward_alltimebest = ReadInt24_t();
1175                         if(race_speedaward_alltimebest_holder)
1176                                 strunzone(race_speedaward_alltimebest_holder);
1177                         race_speedaward_alltimebest_holder = strzone(ReadString());
1178                         break;
1179                 case RACE_NET_SERVER_RANKINGS:
1180                         float prevpos, del;
1181             int pos = ReadShort();
1182                         prevpos = ReadShort();
1183                         del = ReadShort();
1184
1185                         // move other rankings out of the way
1186             int i;
1187                         if (prevpos) {
1188                                 for (i=prevpos-1;i>pos-1;--i) {
1189                                         grecordtime[i] = grecordtime[i-1];
1190                                         if(grecordholder[i])
1191                                                 strunzone(grecordholder[i]);
1192                                         grecordholder[i] = strzone(grecordholder[i-1]);
1193                                 }
1194                         } else if (del) { // a record has been deleted by the admin
1195                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1196                                         if (i == RANKINGS_CNT-1) { // clear out last record
1197                                                 grecordtime[i] = 0;
1198                                                 if (grecordholder[i])
1199                                                         strunzone(grecordholder[i]);
1200                                                 grecordholder[i] = string_null;
1201                                         }
1202                                         else {
1203                                                 grecordtime[i] = grecordtime[i+1];
1204                                                 if (grecordholder[i])
1205                                                         strunzone(grecordholder[i]);
1206                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1207                                         }
1208                                 }
1209                         } else { // player has no ranked record yet
1210                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1211                                         grecordtime[i] = grecordtime[i-1];
1212                                         if(grecordholder[i])
1213                                                 strunzone(grecordholder[i]);
1214                                         grecordholder[i] = strzone(grecordholder[i-1]);
1215                                 }
1216                         }
1217
1218                         // store new ranking
1219                         if(grecordholder[pos-1] != "")
1220                                 strunzone(grecordholder[pos-1]);
1221                         grecordholder[pos-1] = strzone(ReadString());
1222                         grecordtime[pos-1] = ReadInt24_t();
1223                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1224                                 race_myrank = pos;
1225                         break;
1226                 case RACE_NET_SERVER_STATUS:
1227                         race_status = ReadShort();
1228                         if(race_status_name)
1229                                 strunzone(race_status_name);
1230                         race_status_name = strzone(ReadString());
1231         }
1232 }
1233
1234 void Net_TeamNagger()
1235 {
1236         teamnagger = 1;
1237 }
1238
1239 void Net_ReadPingPLReport()
1240 {
1241         int e, pi, pl, ml;
1242         e = ReadByte();
1243         pi = ReadShort();
1244         pl = ReadByte();
1245         ml = ReadByte();
1246         if (!(playerslots[e]))
1247                 return;
1248         playerslots[e].ping = pi;
1249         playerslots[e].ping_packetloss = pl / 255.0;
1250         playerslots[e].ping_movementloss = ml / 255.0;
1251 }
1252
1253 void Net_WeaponComplain()
1254 {
1255         complain_weapon = ReadByte();
1256
1257         if(complain_weapon_name)
1258                 strunzone(complain_weapon_name);
1259         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1260
1261         complain_weapon_type = ReadByte();
1262
1263         complain_weapon_time = time;
1264         weapontime = time; // ping the weapon panel
1265
1266         switch(complain_weapon_type)
1267         {
1268                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1269                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1270                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1271         }
1272 }
1273
1274 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1275 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1276 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1277 float CSQC_Parse_TempEntity()
1278 {
1279         // Acquire TE ID
1280         int nTEID = ReadByte();
1281
1282         if (autocvar_developer_csqcentities)
1283                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1284
1285         switch (nTEID)
1286         {
1287                 case TE_CSQC_MUTATOR:
1288                         int mutID = ReadMutator();
1289                         if (MUTATOR_CALLHOOK(CSQC_Parse_TempEntity, mutID))
1290                         return true;
1291                 case TE_CSQC_TARGET_MUSIC:
1292                         Net_TargetMusic();
1293                         return true;
1294                 case TE_CSQC_PICTURE:
1295                         Net_MapVote_Picture();
1296                         return true;
1297                 case TE_CSQC_RACE:
1298                         Net_ReadRace();
1299                         return true;
1300                 case TE_CSQC_VORTEXBEAMPARTICLE:
1301                         Net_ReadVortexBeamParticle();
1302                         return true;
1303                 case TE_CSQC_TEAMNAGGER:
1304                         Net_TeamNagger();
1305                         return true;
1306                 case TE_CSQC_ARC:
1307                         Net_ReadArc();
1308                         return true;
1309                 case TE_CSQC_PINGPLREPORT:
1310                         Net_ReadPingPLReport();
1311                         return true;
1312                 case TE_CSQC_WEAPONCOMPLAIN:
1313                         Net_WeaponComplain();
1314                         return true;
1315                 case TE_CSQC_VEHICLESETUP:
1316                         Net_VehicleSetup();
1317                         return true;
1318                 case TE_CSQC_SVNOTICE:
1319                         cl_notice_read();
1320                         return true;
1321                 case TE_CSQC_SHOCKWAVEPARTICLE:
1322                         Net_ReadShockwaveParticle();
1323                         return true;
1324                 default:
1325                         // No special logic for this temporary entity; return 0 so the engine can handle it
1326                         return false;
1327         }
1328 }
1329
1330 string getcommandkey(string text, string command)
1331 {
1332         string keys;
1333         float n, j, k, l = 0;
1334
1335         if (!autocvar_hud_showbinds)
1336                 return text;
1337
1338         keys = db_get(binddb, command);
1339         if (keys == "")
1340         {
1341                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1342                 for(j = 0; j < n; ++j)
1343                 {
1344                         k = stof(argv(j));
1345                         if(k != -1)
1346                         {
1347                                 if ("" == keys)
1348                                         keys = keynumtostring(k);
1349                                 else
1350                                         keys = strcat(keys, ", ", keynumtostring(k));
1351
1352                                 ++l;
1353                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1354                                         break;
1355                         }
1356
1357                 }
1358                 if (keys == "")
1359                         keys = "NO_KEY";
1360                 db_put(binddb, command, keys);
1361         }
1362
1363         if (keys == "NO_KEY") {
1364                 if (autocvar_hud_showbinds > 1)
1365                         return sprintf(_("%s (not bound)"), text);
1366                 else
1367                         return text;
1368         }
1369         else if (autocvar_hud_showbinds > 1)
1370                 return sprintf("%s (%s)", text, keys);
1371         else
1372                 return keys;
1373 }