qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include <common/effects/qc/all.qh>
   4 #include "hud/_mod.qh"
   5 #include "mapvoting.qh"
   6 #include "mutators/events.qh"
   7 #include "hud/panel/scoreboard.qh"
   8 #include "hud/panel/quickmenu.qh"
   9 #include "shownames.qh"
  10 #include <common/t_items.qh>
  11 #include "wall.qh"
  12 #include "weapons/projectile.qh"
  13 #include <common/deathtypes/all.qh>
  14 #include <common/items/_mod.qh>
  15 #include <common/mapinfo.qh>
  16 #include <common/minigames/cl_minigames.qh>
  17 #include <common/minigames/cl_minigames_hud.qh>
  18 #include <common/net_linked.qh>
  19 #include <common/net_notice.qh>
  20 #include <common/triggers/include.qh>
  21 #include <common/vehicles/all.qh>
  22 #include <lib/csqcmodel/cl_model.qh>
  23 #include <lib/csqcmodel/interpolate.qh>
  24 #include <lib/warpzone/client.qh>
  25
  26 // --------------------------------------------------------------------------
  27 // BEGIN REQUIRED CSQC FUNCTIONS
  28 //include "main.qh"
  29
  30 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  31
  32 void draw_cursor(vector pos, vector ofs, string img, vector col, float a)
  33 {
  34         ofs = vec2(ofs.x * SIZE_CURSOR.x, ofs.y * SIZE_CURSOR.y);
  35         drawpic(pos - ofs, strcat(draw_currentSkin, img), SIZE_CURSOR, col, a, DRAWFLAG_NORMAL);
  36 }
  37
  38 void draw_cursor_normal(vector pos, vector col, float a)
  39 {
  40         draw_cursor(pos, OFFSET_CURSOR, "/cursor", col, a);
  41 }
  42
  43 void LoadMenuSkinValues()
  44 {
  45         int fh = -1;
  46         if(cvar_string("menu_skin") != "")
  47         {
  48                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  49                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  50         }
  51         if(fh < 0 && cvar_defstring("menu_skin") != "")
  52         {
  53                 cvar_set("menu_skin", cvar_defstring("menu_skin"));
  54                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  55                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  56         }
  57         if(fh < 0)
  58         {
  59                 draw_currentSkin = "gfx/menu/default";
  60                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  61         }
  62
  63         draw_currentSkin = strzone(draw_currentSkin);
  64
  65         if(fh >= 0)
  66         {
  67                 string s;
  68                 while((s = fgets(fh)))
  69                 {
  70                         int n = tokenize_console(s);
  71                         if (n < 2)
  72                                 continue;
  73                         if(substring(argv(0), 0, 2) == "//")
  74                                 continue;
  75                         if(argv(0) == "SIZE_CURSOR")
  76                                 SIZE_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  77                         else if(argv(0) == "OFFSET_CURSOR")
  78                                 OFFSET_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  79                 }
  80                 fclose(fh);
  81         }
  82 }
  83
  84 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  85 // Useful for precaching things
  86
  87 void ConsoleCommand_macro_init();
  88 void CSQC_Init()
  89 {
  90         prvm_language = strzone(cvar_string("prvm_language"));
  91
  92 #ifdef WATERMARK
  93         LOG_INFOF("^4CSQC Build information: ^1%s\n", WATERMARK);
  94 #endif
  95
  96         {
  97                 int i = 0;
  98                 for ( ; i < 255; ++i)
  99                         if (getplayerkeyvalue(i, "viewentity") == "")
 100                                 break;
 101                 maxclients = i;
 102         }
 103
 104         // needs to be done so early because of the constants they create
 105         static_init();
 106         static_init_late();
 107         static_init_precache();
 108
 109         binddb = db_create();
 110         tempdb = db_create();
 111         ClientProgsDB = db_load("client.db");
 112
 113         draw_endBoldFont();
 114
 115         //registercommand("hud_configure");
 116         //registercommand("hud_save");
 117         //registercommand("menu_action");
 118
 119         ConsoleCommand_macro_init();
 120
 121         registercvar("hud_usecsqc", "1");
 122         registercvar("scoreboard_columns", "default");
 123
 124         registercvar("cl_nade_type", "3");
 125         registercvar("cl_pokenade_type", "zombie");
 126
 127         registercvar("cl_jumpspeedcap_min", "");
 128         registercvar("cl_jumpspeedcap_max", "");
 129
 130         registercvar("cl_multijump", "1");
 131
 132         registercvar("cl_spawn_near_teammate", "1");
 133
 134         if(autocvar_cl_lockview)
 135                 cvar_set("cl_lockview", "0");
 136
 137         gametype = NULL;
 138
 139         postinit = false;
 140
 141         calledhooks = 0;
 142
 143         teams = Sort_Spawn();
 144         players = Sort_Spawn();
 145
 146         GetTeam(NUM_SPECTATOR, true); // add specs first
 147
 148         // precaches
 149
 150         if(autocvar_cl_reticle)
 151         {
 152                 precache_pic("gfx/reticle_normal");
 153                 // weapon reticles are precached in weapon files
 154         }
 155
 156         {
 157                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 158                 minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 159                 shortmapname = mi_shortname;
 160
 161                 if (precache_pic(minimapname) == "")
 162                 {
 163                         // but maybe we have a non-clever minimap
 164                         minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 165                         if (precache_pic(minimapname) == "")
 166                                 minimapname = ""; // FAIL
 167                         else
 168                                 get_mi_min_max_texcoords(0); // load new texcoords
 169                 }
 170
 171                 mi_center = (mi_min + mi_max) * 0.5;
 172                 mi_scale = mi_max - mi_min;
 173                 minimapname = strzone(minimapname);
 174         }
 175
 176         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 177         LoadMenuSkinValues();
 178 }
 179
 180 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 181 void Shutdown()
 182 {
 183         WarpZone_Shutdown();
 184
 185         delete(teams);
 186         delete(players);
 187         db_close(binddb);
 188         db_close(tempdb);
 189         if(autocvar_cl_db_saveasdump)
 190                 db_dump(ClientProgsDB, "client.db");
 191         else
 192                 db_save(ClientProgsDB, "client.db");
 193         db_close(ClientProgsDB);
 194
 195         if(camera_active)
 196                 cvar_set("chase_active",ftos(chase_active_backup));
 197
 198         // unset the event chasecam's chase_active
 199         if(autocvar_chase_active < 0)
 200                 cvar_set("chase_active", "0");
 201
 202         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 203
 204         if (!isdemo())
 205         {
 206                 if (!(calledhooks & HOOK_START))
 207                         localcmd("\n_cl_hook_gamestart nop\n");
 208                 if (!(calledhooks & HOOK_END))
 209                         localcmd("\ncl_hook_gameend\n");
 210         }
 211
 212         localcmd("\ncl_hook_shutdown\n");
 213
 214         deactivate_minigame();
 215         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 216 }
 217
 218 .float has_team;
 219 float SetTeam(entity o, int Team)
 220 {
 221     TC(int, Team);
 222         devassert_once(Team);
 223         entity tm;
 224         if(teamplay)
 225         {
 226                 switch(Team)
 227                 {
 228                         case -1:
 229                         case NUM_TEAM_1:
 230                         case NUM_TEAM_2:
 231                         case NUM_TEAM_3:
 232                         case NUM_TEAM_4:
 233                                 break;
 234                         default:
 235                                 if(GetTeam(Team, false) == NULL)
 236                                 {
 237                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 238                                         Team = NUM_SPECTATOR;
 239                                 }
 240                                 break;
 241                 }
 242         }
 243         else
 244         {
 245                 switch(Team)
 246                 {
 247                         case -1:
 248                         case 0:
 249                                 break;
 250                         default:
 251                                 if(GetTeam(Team, false) == NULL)
 252                                 {
 253                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 254                                         Team = NUM_SPECTATOR;
 255                                 }
 256                                 break;
 257                 }
 258         }
 259         if(Team == -1) // leave
 260         {
 261                 if(o.has_team)
 262                 {
 263                         tm = GetTeam(o.team, false);
 264                         tm.team_size -= 1;
 265                         o.has_team = 0;
 266                         return true;
 267                 }
 268         }
 269         else
 270         {
 271                 if (!o.has_team)
 272                 {
 273                         o.team = Team;
 274                         tm = GetTeam(Team, true);
 275                         tm.team_size += 1;
 276                         o.has_team = 1;
 277                         return true;
 278                 }
 279                 else if(Team != o.team)
 280                 {
 281                         tm = GetTeam(o.team, false);
 282                         tm.team_size -= 1;
 283                         o.team = Team;
 284                         tm = GetTeam(Team, true);
 285                         tm.team_size += 1;
 286                         return true;
 287                 }
 288         }
 289         return false;
 290 }
 291
 292 void Playerchecker_Think(entity this)
 293 {
 294     int i;
 295         entity e;
 296         for(i = 0; i < maxclients; ++i)
 297         {
 298                 e = playerslots[i];
 299                 if(entcs_GetName(i) == "")
 300                 {
 301                         if(e.sort_prev)
 302                         {
 303                                 // player disconnected
 304                                 SetTeam(e, -1);
 305                                 RemovePlayer(e);
 306                                 e.sort_prev = NULL;
 307                                 //e.gotscores = 0;
 308                         }
 309                 }
 310                 else
 311                 {
 312                         if (!e.sort_prev)
 313                         {
 314                                 // player connected
 315                                 if (!e)
 316                                 {
 317                                         playerslots[i] = e = new_pure(playerslot);
 318                                 }
 319                                 e.sv_entnum = i;
 320                                 e.ping = 0;
 321                                 e.ping_packetloss = 0;
 322                                 e.ping_movementloss = 0;
 323                                 //e.gotscores = 0; // we might already have the scores...
 324                                 int t = entcs_GetScoreTeam(i);
 325                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 326                                 RegisterPlayer(e);
 327                                 Scoreboard_UpdatePlayerPos(e);
 328                         }
 329                 }
 330         }
 331         this.nextthink = time + 0.2;
 332 }
 333
 334 void TrueAim_Init();
 335 void PostInit()
 336 {
 337         entity playerchecker = new_pure(playerchecker);
 338         setthink(playerchecker, Playerchecker_Think);
 339         playerchecker.nextthink = time + 0.2;
 340
 341         TrueAim_Init();
 342
 343         postinit = true;
 344 }
 345
 346 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 347 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 348 // All keys are in ascii.
 349 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 350 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 351 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 352 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 353 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 354 {
 355     TC(int, bInputType);
 356         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 357                 return true;
 358
 359         if (QuickMenu_InputEvent(bInputType, nPrimary, nSecondary))
 360                 return true;
 361
 362         if (HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary))
 363                 return true;
 364
 365         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 366                 return true;
 367
 368         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
 369                 return true;
 370
 371         return false;
 372 }
 373
 374 // END REQUIRED CSQC FUNCTIONS
 375 // --------------------------------------------------------------------------
 376
 377 // --------------------------------------------------------------------------
 378 // BEGIN OPTIONAL CSQC FUNCTIONS
 379
 380 void Ent_Remove(entity this);
 381
 382 void Ent_RemovePlayerScore(entity this)
 383 {
 384         if(this.owner) {
 385                 SetTeam(this.owner, -1);
 386                 this.owner.gotscores = 0;
 387                 FOREACH(Scores, true, {
 388                         this.owner.(scores(it)) = 0; // clear all scores
 389                 });
 390         }
 391 }
 392
 393 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 394 {
 395         make_pure(this);
 396         entity o;
 397
 398         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 399         // (no I've never heard of M-x replace-string, sed, or anything like that)
 400         bool isNew = !this.owner; // workaround for DP bug
 401         int n = ReadByte()-1;
 402
 403 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 404         if(!isNew && n != this.sv_entnum)
 405         {
 406                 //print("A CSQC entity changed its owner!\n");
 407                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", etof(this), this.classname);
 408                 isNew = true;
 409                 Ent_Remove(this);
 410         }
 411 #endif
 412
 413         this.sv_entnum = n;
 414
 415         o = playerslots[this.sv_entnum];
 416         if (!o)
 417         {
 418                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 419         }
 420         this.owner = o;
 421         o.sv_entnum = this.sv_entnum;
 422         o.gotscores = 1;
 423
 424         //if (!o.sort_prev)
 425         //      RegisterPlayer(o);
 426         //playerchecker will do this for us later, if it has not already done so
 427
 428     int sf, lf;
 429         sf = ReadShort();
 430         lf = ReadShort();
 431         FOREACH(Scores, true, {
 432         int p = 1 << (i % 16);
 433                 if (sf & p)
 434                 {
 435                         if (lf & p)
 436                                 o.(scores(it)) = ReadInt24_t();
 437                         else
 438                                 o.(scores(it)) = ReadChar();
 439                 }
 440     });
 441
 442         return = true;
 443
 444         if(o.sort_prev)
 445                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 446
 447         this.entremove = Ent_RemovePlayerScore;
 448 }
 449
 450 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 451 {
 452         make_pure(this);
 453         int i;
 454         entity o;
 455
 456         this.team = ReadByte();
 457         o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 458
 459     int sf, lf;
 460 #if MAX_TEAMSCORE <= 8
 461         sf = ReadByte();
 462         lf = ReadByte();
 463 #else
 464         sf = ReadShort();
 465         lf = ReadShort();
 466 #endif
 467         int p;
 468         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 469                 if(sf & p)
 470                 {
 471                         if(lf & p)
 472                                 o.(teamscores(i)) = ReadInt24_t();
 473                         else
 474                                 o.(teamscores(i)) = ReadChar();
 475                 }
 476
 477         return = true;
 478
 479         Scoreboard_UpdateTeamPos(o);
 480 }
 481
 482 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 483 {
 484         make_pure(this);
 485         float newspectatee_status;
 486
 487     int f = ReadByte();
 488
 489         scoreboard_showscores_force = (f & 1);
 490
 491         if(f & 2)
 492         {
 493                 newspectatee_status = ReadByte();
 494                 if(newspectatee_status == player_localnum + 1)
 495                         newspectatee_status = -1; // observing
 496         }
 497         else
 498                 newspectatee_status = 0;
 499
 500         spectatorbutton_zoom = (f & 4);
 501
 502         if(f & 16)
 503         {
 504                 num_spectators = ReadByte();
 505
 506                 float i, slot;
 507
 508                 for(i = 0; i < MAX_SPECTATORS; ++i)
 509                         spectatorlist[i] = 0; // reset list first
 510
 511                 for(i = 0; i < num_spectators; ++i)
 512                 {
 513                         slot = ReadByte();
 514                         spectatorlist[i] = slot - 1;
 515                 }
 516         }
 517
 518         return = true;
 519
 520         if(newspectatee_status != spectatee_status)
 521         {
 522                 // clear race stuff
 523                 race_laptime = 0;
 524                 race_checkpointtime = 0;
 525                 hud_dynamic_shake_factor = -1;
 526         }
 527         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 528         {
 529                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 530                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 531                 )
 532                         prev_p_health = -1;
 533                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 534                         prev_health = -1;
 535         }
 536         spectatee_status = newspectatee_status;
 537
 538         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 539 }
 540
 541 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 542 {
 543         make_pure(this);
 544     int i, j, b, f;
 545
 546     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 547
 548         if(!(nags & BIT(2)))
 549         {
 550                 if(vote_called_vote)
 551                         strunzone(vote_called_vote);
 552                 vote_called_vote = string_null;
 553                 vote_active = 0;
 554         }
 555         else
 556         {
 557                 vote_active = 1;
 558         }
 559
 560         if(nags & BIT(6))
 561         {
 562                 vote_yescount = ReadByte();
 563                 vote_nocount = ReadByte();
 564                 vote_needed = ReadByte();
 565                 vote_highlighted = ReadChar();
 566         }
 567
 568         if(nags & BIT(7))
 569         {
 570                 if(vote_called_vote)
 571                         strunzone(vote_called_vote);
 572                 vote_called_vote = strzone(ReadString());
 573         }
 574
 575         if(nags & 1)
 576         {
 577                 for(j = 0; j < maxclients; ++j)
 578                         if(playerslots[j])
 579                                 playerslots[j].ready = 1;
 580                 for(i = 1; i <= maxclients; i += 8)
 581                 {
 582                         f = ReadByte();
 583                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 584                                 if (!(f & b))
 585                                         if(playerslots[j])
 586                                                 playerslots[j].ready = 0;
 587                 }
 588         }
 589
 590         return = true;
 591
 592         ready_waiting = (nags & BIT(0));
 593         ready_waiting_for_me = (nags & BIT(1));
 594         vote_waiting = (nags & BIT(2));
 595         vote_waiting_for_me = (nags & BIT(3));
 596         warmup_stage = (nags & BIT(4));
 597 }
 598
 599 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 600 {
 601         make_pure(this);
 602     int i, j, b, f;
 603
 604     int sf = ReadByte();
 605         if(sf & 1)
 606         {
 607                 for(j = 0; j < maxclients; ++j)
 608                         if(playerslots[j])
 609                                 playerslots[j].eliminated = 1;
 610                 for(i = 1; i <= maxclients; i += 8)
 611                 {
 612                         f = ReadByte();
 613                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 614                                 if (!(f & b))
 615                                         if(playerslots[j])
 616                                                 playerslots[j].eliminated = 0;
 617                 }
 618         }
 619         return true;
 620 }
 621
 622 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 623 {
 624         make_pure(this);
 625         prandom_debug();
 626         float s = ReadShort();
 627         psrandom(s);
 628         return true;
 629 }
 630
 631 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 632 {
 633         make_pure(this);
 634     int sf = ReadInt24_t();
 635         if (sf == 0) {
 636                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 637                         weapon_accuracy[w] = -1;
 638                 return true;
 639         }
 640
 641         int f = 1;
 642         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 643                 if (sf & f) {
 644             int b = ReadByte();
 645                         if (b == 0)
 646                                 weapon_accuracy[w] = -1;
 647                         else if (b == 255)
 648                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 649                         else
 650                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 651                 }
 652                 f = (f == 0x800000) ? 1 : f * 2;
 653         }
 654         return true;
 655 }
 656
 657 void Spawn_Draw(entity this)
 658 {
 659         __pointparticles(this.cnt, this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 660 }
 661
 662 void Spawn_PreDraw(entity this)
 663 {
 664         float alph;
 665         vector org = getpropertyvec(VF_ORIGIN);
 666         if(this.fade_start)
 667                 alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 668         else
 669                 alph = 1;
 670         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 671         this.alpha = alph;
 672         if(alph <= 0)
 673                 this.drawmask = 0;
 674         else
 675                 this.drawmask = MASK_NORMAL;
 676 }
 677
 678 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 679 {
 680         float teamnum = (ReadByte() - 1);
 681         vector spn_origin;
 682         spn_origin.x = ReadCoord();
 683         spn_origin.y = ReadCoord();
 684         spn_origin.z = ReadCoord();
 685
 686         this.team = (teamnum + 1);
 687
 688         //if(is_new)
 689         //{
 690                 this.origin = spn_origin;
 691                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 692                 //droptofloor();
 693
 694                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 695                 {
 696                         this.mdl = "models/spawnpoint.md3";
 697                         this.colormod = Team_ColorRGB(teamnum);
 698                         precache_model(this.mdl);
 699                         setmodel(this, this.mdl);
 700                         this.drawmask = MASK_NORMAL;
 701                         //this.move_movetype = MOVETYPE_NOCLIP;
 702                         //this.draw = Spawn_Draw;
 703                         IL_PUSH(g_drawables, this);
 704                 }*/
 705                 if(autocvar_cl_spawn_point_particles)
 706                 {
 707                         if(teamplay)
 708                         {
 709                                 switch(teamnum)
 710                                 {
 711                                         case NUM_TEAM_1: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
 712                                         case NUM_TEAM_2: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
 713                                         case NUM_TEAM_3: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
 714                                         case NUM_TEAM_4: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
 715                                         default: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
 716                                 }
 717                         }
 718                         else { this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
 719
 720                         this.draw = Spawn_Draw;
 721                         if (is_new) IL_PUSH(g_drawables, this);
 722                         setpredraw(this, Spawn_PreDraw);
 723                         this.fade_start = autocvar_cl_spawn_point_dist_min;
 724                         this.fade_end = autocvar_cl_spawn_point_dist_max;
 725                 }
 726         //}
 727
 728         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 729         return true;
 730 }
 731
 732 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 733 {
 734         // If entnum is 0, ONLY do the local spawn actions
 735         // this way the server can disable the sending of
 736         // spawn origin or such to clients if wanted.
 737         float entnum = ReadByte();
 738
 739         if(entnum)
 740         {
 741                 this.origin_x = ReadCoord();
 742                 this.origin_y = ReadCoord();
 743                 this.origin_z = ReadCoord();
 744
 745                 if(is_new)
 746                 {
 747                         float teamnum = entcs_GetTeam(entnum - 1);
 748
 749                         if(autocvar_cl_spawn_event_particles)
 750                         {
 751                                 switch(teamnum)
 752                                 {
 753                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 754                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 755                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 756                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 757                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 758                                 }
 759                         }
 760                         if(autocvar_cl_spawn_event_sound)
 761                         {
 762                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 763                         }
 764                 }
 765         }
 766         return = true;
 767
 768         // local spawn actions
 769         if(is_new && (!entnum || (entnum == player_localentnum)))
 770         {
 771                 zoomin_effect = 1;
 772                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 773
 774                 if(autocvar_cl_unpress_zoom_on_spawn)
 775                 {
 776                         localcmd("-zoom\n");
 777                         button_zoom = false;
 778                 }
 779                 HUD_Radar_Hide_Maximized();
 780         }
 781         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 782 }
 783
 784 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 785 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 786 void CSQC_Ent_Update(entity this, bool isnew)
 787 {
 788         this.sourceLoc = __FILE__ ":" STR(__LINE__);
 789         int t = ReadByte();
 790
 791         // set up the "time" global for received entities to be correct for interpolation purposes
 792         float savetime = time;
 793         if(servertime)
 794         {
 795                 time = servertime;
 796         }
 797         else
 798         {
 799                 serverprevtime = time;
 800                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 801                 time = serverprevtime + serverdeltatime;
 802         }
 803
 804 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 805         if (this.enttype)
 806         {
 807                 if (t != this.enttype || isnew)
 808                 {
 809                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", etof(this), this.entnum, this.enttype, t);
 810                         Ent_Remove(this);
 811                         clearentity(this);
 812                         isnew = true;
 813                 }
 814         }
 815         else
 816         {
 817                 if (!isnew)
 818                 {
 819                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", etof(this), this.entnum, t);
 820                         isnew = true;
 821                 }
 822         }
 823 #endif
 824         this.enttype = t;
 825         bool done = false;
 826         FOREACH(LinkedEntities, it.m_id == t, {
 827                 if (isnew) this.classname = it.netname;
 828                 if (autocvar_developer_csqcentities)
 829             LOG_INFOF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)\n", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 830                 done = it.m_read(this, NULL, isnew);
 831                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 832                 break;
 833         });
 834         time = savetime;
 835         if (!done)
 836         {
 837                 LOG_FATALF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 838         }
 839 }
 840
 841 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 842 // used when an entity changes its type. For an entity that someone interacts
 843 // with others, make sure it can no longer do so.
 844 void Ent_Remove(entity this)
 845 {
 846         if(this.entremove) this.entremove(this);
 847
 848         if(this.skeletonindex)
 849         {
 850                 skel_delete(this.skeletonindex);
 851                 this.skeletonindex = 0;
 852         }
 853
 854         if(this.snd_looping > 0)
 855         {
 856                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_g_jetpack_attenuation);
 857                 this.snd_looping = 0;
 858         }
 859
 860         this.enttype = 0;
 861         this.classname = "";
 862         this.draw = func_null;
 863         this.entremove = func_null;
 864         // TODO possibly set more stuff to defaults
 865 }
 866 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 867 void CSQC_Ent_Remove(entity this)
 868 {
 869         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}\n", this, this.entnum, this.enttype);
 870         if (wasfreed(this))
 871         {
 872                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
 873                 return;
 874         }
 875         if (this.enttype) Ent_Remove(this);
 876         delete(this);
 877 }
 878
 879 void Gamemode_Init()
 880 {
 881         if (!isdemo())
 882         {
 883                 if(!(calledhooks & HOOK_START))
 884                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 885                 calledhooks |= HOOK_START;
 886         }
 887 }
 888 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 889 void CSQC_Parse_StuffCmd(string strMessage)
 890 {
 891         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 892         localcmd(strMessage);
 893 }
 894 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 895 void CSQC_Parse_Print(string strMessage)
 896 {
 897         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")\n", strMessage);
 898         print(ColorTranslateRGB(strMessage));
 899 }
 900
 901 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 902 void CSQC_Parse_CenterPrint(string strMessage)
 903 {
 904         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 905         centerprint_hud(strMessage);
 906 }
 907
 908 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
 909 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
 910 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
 911 bool CSQC_Parse_TempEntity()
 912 {
 913         // Acquire TE ID
 914         int nTEID = ReadByte();
 915
 916         FOREACH(TempEntities, it.m_id == nTEID, {
 917                 if (autocvar_developer_csqcentities)
 918                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)\n", it.netname, nTEID);
 919                 return it.m_read(NULL, NULL, true);
 920         });
 921
 922         if (autocvar_developer_csqcentities)
 923                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
 924
 925         // No special logic for this temporary entity; return 0 so the engine can handle it
 926         return false;
 927 }
 928
 929 string forcefog;
 930 void Fog_Force()
 931 {
 932         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 933                 localcmd("\nr_drawfog 0\n");
 934         else if (forcefog != "")
 935                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
 936 }
 937
 938 void Gamemode_Init();
 939 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
 940 {
 941         make_pure(this);
 942         gametype = ReadRegistered(Gametypes);
 943         teamplay = _MapInfo_GetTeamPlayBool(gametype);
 944         HUD_ModIcons_SetFunc();
 945         FOREACH(Scores, true, {
 946                 if (scores_label(it)) strunzone(scores_label(it));
 947                 scores_label(it) = strzone(ReadString());
 948                 scores_flags(it) = ReadByte();
 949         });
 950         for (int i = 0; i < MAX_TEAMSCORE; ++i)
 951         {
 952                 if (teamscores_label(i)) strunzone(teamscores_label(i));
 953                 teamscores_label(i) = strzone(ReadString());
 954                 teamscores_flags(i) = ReadByte();
 955         }
 956         return = true;
 957         Scoreboard_InitScores();
 958         Gamemode_Init();
 959 }
 960
 961 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
 962 {
 963         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 964
 965         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 966         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 967         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 968         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 969         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 970         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 971         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 972         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 973
 974         if (forcefog) strunzone(forcefog);
 975         forcefog = strzone(ReadString());
 976
 977         armorblockpercent = ReadByte() / 255.0;
 978
 979         serverflags = ReadByte();
 980
 981         g_trueaim_minrange = ReadCoord();
 982
 983         return = true;
 984
 985         MUTATOR_CALLHOOK(Ent_Init);
 986
 987         if (!postinit) PostInit();
 988 }
 989
 990 float GetSpeedUnitFactor(int speed_unit)
 991 {
 992         switch(speed_unit)
 993         {
 994                 default:
 995                 case 1:
 996                         return 1.0;
 997                 case 2:
 998                         return 0.0254;
 999                 case 3:
1000                         return 0.0254 * 3.6;
1001                 case 4:
1002                         return 0.0254 * 3.6 * 0.6213711922;
1003                 case 5:
1004                         return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1005         }
1006 }
1007
1008 string GetSpeedUnit(int speed_unit)
1009 {
1010         switch(speed_unit)
1011         {
1012                 default:
1013                 case 1:
1014                         return _(" qu/s");
1015                 case 2:
1016                         return _(" m/s");
1017                 case 3:
1018                         return _(" km/h");
1019                 case 4:
1020                         return _(" mph");
1021                 case 5:
1022                         return _(" knots");
1023         }
1024 }
1025
1026 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1027 {
1028         int b = ReadByte();
1029
1030         switch (b)
1031         {
1032                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1033                         race_checkpoint = ReadByte();
1034                         race_time = ReadInt24_t();
1035                         race_previousbesttime = ReadInt24_t();
1036                         if(race_previousbestname)
1037                                 strunzone(race_previousbestname);
1038                         race_previousbestname = strzone(ReadString());
1039
1040                         race_checkpointtime = time;
1041
1042                         if(race_checkpoint == 0 || race_checkpoint == 254)
1043                         {
1044                                 race_penaltyaccumulator = 0;
1045                                 race_laptime = time; // valid
1046                         }
1047
1048                         break;
1049
1050                 case RACE_NET_CHECKPOINT_CLEAR:
1051                         race_laptime = 0;
1052                         race_checkpointtime = 0;
1053                         break;
1054
1055                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1056                         race_laptime = ReadCoord();
1057                         race_checkpointtime = -99999;
1058                         // fall through
1059                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1060                         race_nextcheckpoint = ReadByte();
1061
1062                         race_nextbesttime = ReadInt24_t();
1063                         if(race_nextbestname)
1064                                 strunzone(race_nextbestname);
1065                         race_nextbestname = strzone(ReadString());
1066                         break;
1067
1068                 case RACE_NET_CHECKPOINT_HIT_RACE:
1069                         race_mycheckpoint = ReadByte();
1070                         race_mycheckpointtime = time;
1071                         race_mycheckpointdelta = ReadInt24_t();
1072                         race_mycheckpointlapsdelta = ReadByte();
1073                         if(race_mycheckpointlapsdelta >= 128)
1074                                 race_mycheckpointlapsdelta -= 256;
1075                         if(race_mycheckpointenemy)
1076                                 strunzone(race_mycheckpointenemy);
1077                         race_mycheckpointenemy = strzone(ReadString());
1078                         break;
1079
1080                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1081                         race_othercheckpoint = ReadByte();
1082                         race_othercheckpointtime = time;
1083                         race_othercheckpointdelta = ReadInt24_t();
1084                         race_othercheckpointlapsdelta = ReadByte();
1085                         if(race_othercheckpointlapsdelta >= 128)
1086                                 race_othercheckpointlapsdelta -= 256;
1087                         if(race_othercheckpointenemy)
1088                                 strunzone(race_othercheckpointenemy);
1089                         race_othercheckpointenemy = strzone(ReadString());
1090                         break;
1091
1092                 case RACE_NET_PENALTY_RACE:
1093                         race_penaltyeventtime = time;
1094                         race_penaltytime = ReadShort();
1095                         //race_penaltyaccumulator += race_penaltytime;
1096                         if(race_penaltyreason)
1097                                 strunzone(race_penaltyreason);
1098                         race_penaltyreason = strzone(ReadString());
1099                         break;
1100
1101                 case RACE_NET_PENALTY_QUALIFYING:
1102                         race_penaltyeventtime = time;
1103                         race_penaltytime = ReadShort();
1104                         race_penaltyaccumulator += race_penaltytime;
1105                         if(race_penaltyreason)
1106                                 strunzone(race_penaltyreason);
1107                         race_penaltyreason = strzone(ReadString());
1108                         break;
1109
1110                 case RACE_NET_SERVER_RECORD:
1111                         race_server_record = ReadInt24_t();
1112                         break;
1113                 case RACE_NET_SPEED_AWARD:
1114                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1115                         if(race_speedaward_holder)
1116                                 strunzone(race_speedaward_holder);
1117                         race_speedaward_holder = strzone(ReadString());
1118                         if(race_speedaward_unit)
1119                                 strunzone(race_speedaward_unit);
1120                         race_speedaward_unit = strzone(GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1121                         break;
1122                 case RACE_NET_SPEED_AWARD_BEST:
1123                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1124                         if(race_speedaward_alltimebest_holder)
1125                                 strunzone(race_speedaward_alltimebest_holder);
1126                         race_speedaward_alltimebest_holder = strzone(ReadString());
1127                         if(race_speedaward_alltimebest_unit)
1128                                 strunzone(race_speedaward_alltimebest_unit);
1129                         race_speedaward_alltimebest_unit = strzone(GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1130                         break;
1131                 case RACE_NET_SERVER_RANKINGS:
1132                         float prevpos, del;
1133             int pos = ReadShort();
1134                         prevpos = ReadShort();
1135                         del = ReadShort();
1136
1137                         // move other rankings out of the way
1138             int i;
1139                         if (prevpos) {
1140                                 for (i=prevpos-1;i>pos-1;--i) {
1141                                         grecordtime[i] = grecordtime[i-1];
1142                                         if(grecordholder[i])
1143                                                 strunzone(grecordholder[i]);
1144                                         grecordholder[i] = strzone(grecordholder[i-1]);
1145                                 }
1146                         } else if (del) { // a record has been deleted by the admin
1147                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1148                                         if (i == RANKINGS_CNT-1) { // clear out last record
1149                                                 grecordtime[i] = 0;
1150                                                 if (grecordholder[i])
1151                                                         strunzone(grecordholder[i]);
1152                                                 grecordholder[i] = string_null;
1153                                         }
1154                                         else {
1155                                                 grecordtime[i] = grecordtime[i+1];
1156                                                 if (grecordholder[i])
1157                                                         strunzone(grecordholder[i]);
1158                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1159                                         }
1160                                 }
1161                         } else { // player has no ranked record yet
1162                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1163                                         grecordtime[i] = grecordtime[i-1];
1164                                         if(grecordholder[i])
1165                                                 strunzone(grecordholder[i]);
1166                                         grecordholder[i] = strzone(grecordholder[i-1]);
1167                                 }
1168                         }
1169
1170                         // store new ranking
1171                         if(grecordholder[pos-1] != "")
1172                                 strunzone(grecordholder[pos-1]);
1173                         grecordholder[pos-1] = strzone(ReadString());
1174                         grecordtime[pos-1] = ReadInt24_t();
1175                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1176                                 race_myrank = pos;
1177                         break;
1178                 case RACE_NET_SERVER_STATUS:
1179                         race_status = ReadShort();
1180                         if(race_status_name)
1181                                 strunzone(race_status_name);
1182                         race_status_name = strzone(ReadString());
1183         }
1184         return true;
1185 }
1186
1187 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1188 {
1189         teamnagger = 1;
1190         return true;
1191 }
1192
1193 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1194 {
1195         int i = ReadByte();
1196         int pi = ReadShort();
1197         int pl = ReadByte();
1198         int ml = ReadByte();
1199         return = true;
1200         entity e = playerslots[i];
1201         if (!e) return;
1202         e.ping = pi;
1203         e.ping_packetloss = pl / 255.0;
1204         e.ping_movementloss = ml / 255.0;
1205 }
1206
1207 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1208 {
1209         complain_weapon = ReadByte();
1210         complain_weapon_type = ReadByte();
1211         return = true;
1212
1213         complain_weapon_time = time;
1214         weapontime = time; // ping the weapon panel
1215
1216         switch(complain_weapon_type)
1217         {
1218                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1219                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1220                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1221         }
1222 }
1223
1224 string _getcommandkey(string cmd_name, string command, bool forcename)
1225 {
1226         string keys;
1227         float n, j, k, l = 0;
1228
1229         if (!autocvar_hud_showbinds)
1230                 return cmd_name;
1231
1232         keys = db_get(binddb, command);
1233         if (keys == "")
1234         {
1235                 bool joy_active = cvar("joy_active");
1236                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1237                 for(j = 0; j < n; ++j)
1238                 {
1239                         k = stof(argv(j));
1240                         if(k != -1)
1241                         {
1242                                 string key = keynumtostring(k);
1243                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1244                                         continue;
1245
1246                                 if (keys == "")
1247                                         keys = key;
1248                                 else
1249                                         keys = strcat(keys, ", ", key);
1250
1251                                 ++l;
1252                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1253                                         break;
1254                         }
1255
1256                 }
1257                 if (keys == "")
1258                         keys = "NO_KEY";
1259                 db_put(binddb, command, keys);
1260         }
1261
1262         if (keys == "NO_KEY") {
1263                 if (autocvar_hud_showbinds > 1)
1264                         return sprintf(_("%s (not bound)"), cmd_name);
1265                 else
1266                         return cmd_name;
1267         }
1268         else if (autocvar_hud_showbinds > 1 || forcename)
1269                 return sprintf("%s (%s)", cmd_name, keys);
1270         else
1271                 return keys;
1272 }