c8274fe62641070f01f4448acce41d07080b0e9a
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / main.qc
1 #include "main.qh"
2
3 #include "defs.qh"
4 #include <common/ent_cs.qh>
5 #include "miscfunctions.qh"
6 #include <common/effects/effect.qh>
7 #include <common/effects/qc/_mod.qh>
8 #include <common/effects/all.qh>
9 #include <common/effects/all.inc>
10 #include "hud/_mod.qh"
11 #include "commands/cl_cmd.qh"
12 #include "mapvoting.qh"
13 #include <client/mutators/_mod.qh>
14 #include "hud/panel/scoreboard.qh"
15 #include "hud/panel/quickmenu.qh"
16 #include "shownames.qh"
17 #include "view.qh"
18 #include <common/t_items.qh>
19 #include "weapons/projectile.qh"
20 #include <common/deathtypes/all.qh>
21 #include <common/items/_mod.qh>
22 #include <common/mapinfo.qh>
23 #include <common/minigames/cl_minigames.qh>
24 #include <common/minigames/cl_minigames_hud.qh>
25 #include <common/net_linked.qh>
26 #include <common/net_notice.qh>
27 #include <common/scores.qh>
28 #include <common/mapobjects/_mod.qh>
29 #include <common/vehicles/all.qh>
30 #include <lib/csqcmodel/cl_model.qh>
31 #include <lib/csqcmodel/interpolate.qh>
32 #include <lib/warpzone/client.qh>
33
34 // --------------------------------------------------------------------------
35 // BEGIN REQUIRED CSQC FUNCTIONS
36 //include "main.qh"
37
38 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
39
40 void draw_cursor(vector pos, vector ofs, string img, vector col, float a)
41 {
42         ofs = vec2(ofs.x * SIZE_CURSOR.x, ofs.y * SIZE_CURSOR.y);
43         drawpic(pos - ofs, strcat(draw_currentSkin, img), SIZE_CURSOR, col, a, DRAWFLAG_NORMAL);
44 }
45
46 void draw_cursor_normal(vector pos, vector col, float a)
47 {
48         draw_cursor(pos, OFFSET_CURSOR, "/cursor", col, a);
49 }
50
51 void LoadMenuSkinValues()
52 {
53         int fh = -1;
54         if(cvar_string("menu_skin") != "")
55         {
56                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
57                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
58         }
59         if(fh < 0 && cvar_defstring("menu_skin") != "")
60         {
61                 cvar_set("menu_skin", cvar_defstring("menu_skin"));
62                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
63                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
64         }
65         if(fh < 0)
66         {
67                 draw_currentSkin = "gfx/menu/default";
68                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
69         }
70
71         draw_currentSkin = strzone(draw_currentSkin);
72
73         if(fh >= 0)
74         {
75                 string s;
76                 while((s = fgets(fh)))
77                 {
78                         int n = tokenize_console(s);
79                         if (n < 2)
80                                 continue;
81                         if(substring(argv(0), 0, 2) == "//")
82                                 continue;
83                         if(argv(0) == "SIZE_CURSOR")
84                                 SIZE_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
85                         else if(argv(0) == "OFFSET_CURSOR")
86                                 OFFSET_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
87                 }
88                 fclose(fh);
89         }
90 }
91
92 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
93 // Useful for precaching things
94
95 void CSQC_Init()
96 {
97         prvm_language = strzone(cvar_string("prvm_language"));
98
99 #ifdef WATERMARK
100         LOG_INFOF("^4CSQC Build information: ^1%s", WATERMARK);
101 #endif
102
103         {
104                 int i = 0;
105                 for ( ; i < 255; ++i)
106                         if (getplayerkeyvalue(i, "viewentity") == "")
107                                 break;
108                 maxclients = i;
109         }
110
111         // needs to be done so early because of the constants they create
112         static_init();
113         static_init_late();
114         static_init_precache();
115
116         binddb = db_create();
117         tempdb = db_create();
118         ClientProgsDB = db_load("client.db");
119
120         draw_endBoldFont();
121
122         //registercommand("hud_configure");
123         //registercommand("hud_save");
124         //registercommand("menu_action");
125
126         ConsoleCommand_macro_init();
127
128         registercvar("hud_usecsqc", "1");
129         registercvar("scoreboard_columns", "default");
130
131         registercvar("cl_nade_type", "3");
132         registercvar("cl_pokenade_type", "zombie");
133
134         registercvar("cl_jumpspeedcap_min", "");
135         registercvar("cl_jumpspeedcap_max", "");
136
137         registercvar("cl_shootfromfixedorigin", "");
138
139         registercvar("cl_multijump", "1");
140
141         registercvar("cl_spawn_near_teammate", "1");
142
143         registercvar("cl_weapon_switch_reload", "1");
144         registercvar("cl_weapon_switch_fallback_to_impulse", "1");
145
146         if(autocvar_cl_lockview)
147                 cvar_set("cl_lockview", "0");
148
149         gametype = NULL;
150
151         postinit = false;
152
153         calledhooks = 0;
154
155         teams = Sort_Spawn();
156         players = Sort_Spawn();
157
158         GetTeam(NUM_SPECTATOR, true); // add specs first
159
160         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
161                 weapon_accuracy[w] = -1;
162
163         // precaches
164
165         if(autocvar_cl_reticle)
166         {
167                 precache_pic("gfx/reticle_normal");
168                 // weapon reticles are precached in weapon files
169         }
170
171         {
172                 get_mi_min_max_texcoords(1); // try the CLEVER way first
173                 minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
174                 shortmapname = mi_shortname;
175
176                 if (precache_pic(minimapname) == "")
177                 {
178                         // but maybe we have a non-clever minimap
179                         minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
180                         if (precache_pic(minimapname) == "")
181                                 minimapname = ""; // FAIL
182                         else
183                                 get_mi_min_max_texcoords(0); // load new texcoords
184                 }
185
186                 mi_center = (mi_min + mi_max) * 0.5;
187                 mi_scale = mi_max - mi_min;
188                 minimapname = strzone(minimapname);
189         }
190
191         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
192         LoadMenuSkinValues();
193 }
194
195 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
196 void Shutdown()
197 {
198         WarpZone_Shutdown();
199
200         delete(teams);
201         delete(players);
202         db_close(binddb);
203         db_close(tempdb);
204         if(autocvar_cl_db_saveasdump)
205                 db_dump(ClientProgsDB, "client.db");
206         else
207                 db_save(ClientProgsDB, "client.db");
208         db_close(ClientProgsDB);
209
210         if(camera_active)
211                 cvar_set("chase_active",ftos(chase_active_backup));
212
213         // unset the event chasecam's chase_active
214         if(autocvar_chase_active < 0)
215                 cvar_set("chase_active", "0");
216
217         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
218
219         if (!isdemo())
220         {
221                 if (!(calledhooks & HOOK_START))
222                         localcmd("\n_cl_hook_gamestart nop\n");
223                 if (!(calledhooks & HOOK_END))
224                         localcmd("\ncl_hook_gameend\n");
225         }
226
227         localcmd("\ncl_hook_shutdown\n");
228
229         localcmd("\n-button12\n");
230
231         deactivate_minigame();
232         HUD_MinigameMenu_Close(NULL, NULL, NULL);
233
234         ReplicateVars(true); // destroy
235 }
236
237 .float has_team;
238 bool SetTeam(entity o, int Team)
239 {
240         TC(int, Team);
241         devassert_once(Team);
242         entity tm;
243         if(teamplay)
244         {
245                 switch(Team)
246                 {
247                         case -1:
248                         case NUM_TEAM_1:
249                         case NUM_TEAM_2:
250                         case NUM_TEAM_3:
251                         case NUM_TEAM_4:
252                                 break;
253                         default:
254                                 if(GetTeam(Team, false) == NULL)
255                                 {
256                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
257                                         Team = NUM_SPECTATOR;
258                                 }
259                                 break;
260                 }
261         }
262         else
263         {
264                 switch(Team)
265                 {
266                         case -1:
267                         case 0:
268                                 break;
269                         default:
270                                 if(GetTeam(Team, false) == NULL)
271                                 {
272                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
273                                         Team = NUM_SPECTATOR;
274                                 }
275                                 break;
276                 }
277         }
278         if(Team == -1) // leave
279         {
280                 if(o.has_team)
281                 {
282                         tm = GetTeam(o.team, false);
283                         tm.team_size -= 1;
284                         o.has_team = 0;
285                         return true;
286                 }
287         }
288         else
289         {
290                 if (!o.has_team)
291                 {
292                         o.team = Team;
293                         tm = GetTeam(Team, true);
294                         tm.team_size += 1;
295                         o.has_team = 1;
296                         return true;
297                 }
298                 else if(Team != o.team)
299                 {
300                         tm = GetTeam(o.team, false);
301                         tm.team_size -= 1;
302                         o.team = Team;
303                         tm = GetTeam(Team, true);
304                         tm.team_size += 1;
305                         return true;
306                 }
307         }
308         return false;
309 }
310
311 void Playerchecker_Think(entity this)
312 {
313         int i;
314         entity e;
315         for(i = 0; i < maxclients; ++i)
316         {
317                 e = playerslots[i];
318                 if(entcs_GetName(i) == "")
319                 {
320                         if(e.sort_prev)
321                         {
322                                 // player disconnected
323                                 SetTeam(e, -1);
324                                 RemovePlayer(e);
325                                 e.sort_prev = NULL;
326                                 //e.gotscores = 0;
327                         }
328                 }
329                 else
330                 {
331                         if (!e.sort_prev)
332                         {
333                                 // player connected
334                                 if (!e)
335                                 {
336                                         playerslots[i] = e = new_pure(playerslot);
337                                 }
338                                 e.sv_entnum = i;
339                                 e.ping = 0;
340                                 e.ping_packetloss = 0;
341                                 e.ping_movementloss = 0;
342                                 //e.gotscores = 0; // we might already have the scores...
343                                 int t = entcs_GetScoreTeam(i);
344                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
345                                 RegisterPlayer(e);
346                                 Scoreboard_UpdatePlayerPos(e);
347                         }
348                 }
349         }
350         this.nextthink = time + 0.2;
351 }
352
353 void PostInit()
354 {
355         entity playerchecker = new_pure(playerchecker);
356         setthink(playerchecker, Playerchecker_Think);
357         playerchecker.nextthink = time + 0.2;
358
359         TrueAim_Init();
360
361         postinit = true;
362 }
363
364 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
365 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
366 // All keys are in ascii.
367 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
368 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
369 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
370 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
371 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
372 {
373         TC(int, bInputType);
374         bool override = false;
375         override |= HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary);
376         if (override)
377                 return true;
378
379         override |= QuickMenu_InputEvent(bInputType, nPrimary, nSecondary);
380
381         override |= HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary);
382
383         override |= MapVote_InputEvent(bInputType, nPrimary, nSecondary);
384
385         override |= HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary);
386
387         if(override)
388                 return true;
389
390         return false;
391 }
392
393 // END REQUIRED CSQC FUNCTIONS
394 // --------------------------------------------------------------------------
395
396 // --------------------------------------------------------------------------
397 // BEGIN OPTIONAL CSQC FUNCTIONS
398
399 void Ent_RemovePlayerScore(entity this)
400 {
401         if(this.owner) {
402                 SetTeam(this.owner, -1);
403                 this.owner.gotscores = 0;
404                 FOREACH(Scores, true, {
405                         this.owner.(scores(it)) = 0; // clear all scores
406                 });
407         }
408 }
409
410 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
411 {
412         make_pure(this);
413         entity o;
414
415         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
416         // (no I've never heard of M-x replace-string, sed, or anything like that)
417         bool isNew = !this.owner; // workaround for DP bug
418         int n = ReadByte()-1;
419
420 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
421         if(!isNew && n != this.sv_entnum)
422         {
423                 //print("A CSQC entity changed its owner!\n");
424                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
425                 isNew = true;
426                 Ent_Remove(this);
427         }
428 #endif
429
430         this.sv_entnum = n;
431
432         o = playerslots[this.sv_entnum];
433         if (!o)
434         {
435                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
436         }
437         this.owner = o;
438         o.sv_entnum = this.sv_entnum;
439         o.gotscores = 1;
440
441         //if (!o.sort_prev)
442         //      RegisterPlayer(o);
443         //playerchecker will do this for us later, if it has not already done so
444
445         int sf = ReadShort();
446         int lf = ReadShort();
447         FOREACH(Scores, true, {
448                 int p = 1 << (i % 16);
449                 if (sf & p)
450                 {
451                         if (lf & p)
452                                 o.(scores(it)) = ReadInt24_t();
453                         else
454                                 o.(scores(it)) = ReadChar();
455                 }
456         });
457
458         return = true;
459
460         if(o.sort_prev)
461                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
462
463         this.entremove = Ent_RemovePlayerScore;
464 }
465
466 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
467 {
468         make_pure(this);
469         int i;
470
471         this.team = ReadByte();
472         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
473
474 #if MAX_TEAMSCORE <= 8
475         int sf = ReadByte();
476         int lf = ReadByte();
477 #else
478         int sf = ReadShort();
479         int lf = ReadShort();
480 #endif
481         for(i = 0; i < MAX_TEAMSCORE; ++i)
482                 if(sf & BIT(i))
483                 {
484                         if(lf & BIT(i))
485                                 o.(teamscores(i)) = ReadInt24_t();
486                         else
487                                 o.(teamscores(i)) = ReadChar();
488                 }
489
490         return = true;
491
492         Scoreboard_UpdateTeamPos(o);
493 }
494
495 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
496 {
497         make_pure(this);
498         float newspectatee_status;
499
500         int f = ReadByte();
501
502         scoreboard_showscores_force = (f & BIT(0));
503
504         if(f & BIT(1))
505         {
506                 newspectatee_status = ReadByte();
507                 if(newspectatee_status == player_localnum + 1)
508                         newspectatee_status = -1; // observing
509         }
510         else
511                 newspectatee_status = 0;
512
513         spectatorbutton_zoom = (f & BIT(2));
514
515         if(f & BIT(4))
516         {
517                 num_spectators = ReadByte();
518
519                 float i, slot;
520
521                 for(i = 0; i < MAX_SPECTATORS; ++i)
522                         spectatorlist[i] = 0; // reset list first
523
524                 for(i = 0; i < num_spectators; ++i)
525                 {
526                         slot = ReadByte();
527                         spectatorlist[i] = slot - 1;
528                 }
529         }
530
531         return = true;
532
533         if(newspectatee_status != spectatee_status)
534         {
535                 // clear race stuff
536                 race_laptime = 0;
537                 race_checkpointtime = 0;
538                 hud_dynamic_shake_factor = -1;
539                 spectatee_status_changed_time = time;
540         }
541         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
542         {
543                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
544                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
545                 )
546                         prev_p_health = -1;
547                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
548                         prev_health = -1;
549         }
550         spectatee_status = newspectatee_status;
551
552         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
553 }
554
555 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
556 {
557         make_pure(this);
558         int i, j, b, f;
559
560         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
561
562         if(!(nags & BIT(2)))
563         {
564                 strfree(vote_called_vote);
565                 vote_active = 0;
566         }
567         else
568         {
569                 vote_active = 1;
570         }
571
572         if(nags & BIT(6))
573         {
574                 vote_yescount = ReadByte();
575                 vote_nocount = ReadByte();
576                 vote_needed = ReadByte();
577                 vote_highlighted = ReadChar();
578         }
579
580         if(nags & BIT(7))
581         {
582                 strcpy(vote_called_vote, ReadString());
583         }
584
585         if(nags & 1)
586         {
587                 for(j = 0; j < maxclients; ++j)
588                         if(playerslots[j])
589                                 playerslots[j].ready = true;
590                 for(i = 1; i <= maxclients; i += 8)
591                 {
592                         f = ReadByte();
593                         for(j = i-1, b = BIT(0); b < BIT(8); b <<= 1, ++j)
594                                 if (!(f & b))
595                                         if(playerslots[j])
596                                                 playerslots[j].ready = false;
597                 }
598         }
599
600         return = true;
601
602         ready_waiting = (nags & BIT(0));
603         ready_waiting_for_me = (nags & BIT(1));
604         vote_waiting = (nags & BIT(2));
605         vote_waiting_for_me = (nags & BIT(3));
606         warmup_stage = (nags & BIT(4));
607 }
608
609 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
610 {
611         make_pure(this);
612         int sf = 0;
613         serialize(byte, 0, sf);
614         if (sf & 1) {
615                 for (int j = 0; j < maxclients; ++j) {
616                         if (playerslots[j]) {
617                                 playerslots[j].eliminated = true;
618                         }
619                 }
620                 for (int i = 1; i <= maxclients; i += 8) {
621                         int f = 0;
622                         serialize(byte, 0, f);
623                         for (int b = 0; b < 8; ++b) {
624                                 if (f & BIT(b)) continue;
625                                 int j = i - 1 + b;
626                                 if (playerslots[j]) {
627                                         playerslots[j].eliminated = false;
628                                 }
629                         }
630                 }
631         }
632         return true;
633 }
634
635 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
636 {
637         make_pure(this);
638         prandom_debug();
639         float s = ReadShort();
640         psrandom(s);
641         return true;
642 }
643
644 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
645 {
646         make_pure(this);
647         int sf = ReadInt24_t();
648         if (sf == 0) {
649                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
650                         weapon_accuracy[w] = -1;
651                 return true;
652         }
653
654         int f = 1;
655         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
656                 if (sf & f) {
657                         int b = ReadByte();
658                         if (b == 0)
659                                 weapon_accuracy[w] = -1;
660                         else if (b == 255)
661                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
662                         else
663                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
664                 }
665                 f = (f == 0x800000) ? 1 : f * 2;
666         }
667         return true;
668 }
669
670 void Spawn_Draw(entity this)
671 {
672         if(this.alpha <= 0)
673                 return;
674
675         __pointparticles(this.cnt, this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
676 }
677
678 void Spawn_PreDraw(entity this)
679 {
680         float alph;
681         vector org = getpropertyvec(VF_ORIGIN);
682         if(this.fade_start)
683         {
684                 if(vdist(org - this.origin, >, this.fade_end))
685                         alph = 0; // save on some processing
686                 else if(vdist(org - this.origin, <, this.fade_start))
687                         alph = 1; // more processing saved
688                 else
689                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
690         }
691         else
692                 alph = 1;
693         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
694         this.alpha = alph;
695         if(alph <= 0)
696                 this.drawmask = 0;
697         else
698                 this.drawmask = MASK_NORMAL;
699 }
700
701 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
702 {
703         float teamnum = (ReadByte() - 1);
704         vector spn_origin = ReadVector();
705
706         this.team = (teamnum + 1);
707
708         //if(is_new)
709         //{
710                 this.origin = spn_origin;
711                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
712                 //droptofloor();
713
714                 /*if(autocvar_cl_spawn_point_model) // needs a model first
715                 {
716                         this.mdl = "models/spawnpoint.md3";
717                         this.colormod = Team_ColorRGB(teamnum);
718                         precache_model(this.mdl);
719                         setmodel(this, this.mdl);
720                         this.drawmask = MASK_NORMAL;
721                         //this.move_movetype = MOVETYPE_NOCLIP;
722                         //this.draw = Spawn_Draw;
723                         IL_PUSH(g_drawables, this);
724                 }*/
725                 if(autocvar_cl_spawn_point_particles)
726                 {
727                         if(teamplay)
728                         {
729                                 switch(teamnum)
730                                 {
731                                         case NUM_TEAM_1: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
732                                         case NUM_TEAM_2: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
733                                         case NUM_TEAM_3: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
734                                         case NUM_TEAM_4: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
735                                         default: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
736                                 }
737                         }
738                         else { this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
739
740                         this.draw = Spawn_Draw;
741                         if (is_new) IL_PUSH(g_drawables, this);
742                         setpredraw(this, Spawn_PreDraw);
743                         this.fade_start = autocvar_cl_spawn_point_dist_min;
744                         this.fade_end = autocvar_cl_spawn_point_dist_max;
745                 }
746         //}
747
748         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
749         return true;
750 }
751
752 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
753 {
754         // If entnum is 0, ONLY do the local spawn actions
755         // this way the server can disable the sending of
756         // spawn origin or such to clients if wanted.
757         float entnum = ReadByte();
758
759         if(entnum)
760         {
761                 this.origin = ReadVector();
762
763                 if(is_new)
764                 {
765                         float teamnum = entcs_GetTeam(entnum - 1);
766
767                         if(autocvar_cl_spawn_event_particles)
768                         {
769                                 switch(teamnum)
770                                 {
771                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
772                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
773                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
774                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
775                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
776                                 }
777                         }
778                         if(autocvar_cl_spawn_event_sound)
779                         {
780                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
781                         }
782                 }
783         }
784         return = true;
785
786         // local spawn actions
787         if(is_new && (!entnum || (entnum == player_localentnum)))
788         {
789                 zoomin_effect = 1;
790                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
791
792                 if(autocvar_cl_unpress_zoom_on_spawn)
793                 {
794                         localcmd("-zoom\n");
795                         button_zoom = false;
796                 }
797                 HUD_Radar_Hide_Maximized();
798         }
799         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
800 }
801
802 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
803 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
804 void CSQC_Ent_Update(entity this, bool isnew)
805 {
806         this.sourceLoc = __FILE__":"STR(__LINE__);
807         int t = ReadByte();
808
809         // set up the "time" global for received entities to be correct for interpolation purposes
810         float savetime = time;
811         if(servertime)
812         {
813                 time = servertime;
814         }
815         else
816         {
817                 serverprevtime = time;
818                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
819                 time = serverprevtime + serverdeltatime;
820         }
821
822 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
823         if (this.enttype)
824         {
825                 if (t != this.enttype || isnew)
826                 {
827                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
828                         Ent_Remove(this);
829                         clearentity(this);
830                         isnew = true;
831                 }
832         }
833         else
834         {
835                 if (!isnew)
836                 {
837                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
838                         isnew = true;
839                 }
840         }
841 #endif
842         this.enttype = t;
843         bool done = false;
844         FOREACH(LinkedEntities, it.m_id == t, {
845                 if (isnew) this.classname = it.netname;
846                 if (autocvar_developer_csqcentities)
847             LOG_INFOF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
848                 done = it.m_read(this, NULL, isnew);
849                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
850                 break;
851         });
852         time = savetime;
853         if (!done)
854         {
855                 LOG_FATALF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
856         }
857 }
858
859 // Destructor, but does NOT deallocate the entity by calling remove(). Also
860 // used when an entity changes its type. For an entity that someone interacts
861 // with others, make sure it can no longer do so.
862 void Ent_Remove(entity this)
863 {
864         if(this.entremove) this.entremove(this);
865
866         if(this.skeletonindex)
867         {
868                 skel_delete(this.skeletonindex);
869                 this.skeletonindex = 0;
870         }
871
872         if(this.snd_looping > 0)
873         {
874                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
875                 this.snd_looping = 0;
876         }
877
878         this.enttype = 0;
879         this.classname = "";
880         this.draw = func_null;
881         this.entremove = func_null;
882         // TODO possibly set more stuff to defaults
883 }
884 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
885 void CSQC_Ent_Remove(entity this)
886 {
887         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
888         if (wasfreed(this))
889         {
890                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
891                 return;
892         }
893         if (this.enttype) Ent_Remove(this);
894         delete(this);
895 }
896
897 void Gamemode_Init()
898 {
899         if (!isdemo())
900         {
901                 if(!(calledhooks & HOOK_START))
902                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
903                 calledhooks |= HOOK_START;
904         }
905 }
906 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
907 void CSQC_Parse_StuffCmd(string strMessage)
908 {
909         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
910         localcmd(strMessage);
911 }
912 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
913 void CSQC_Parse_Print(string strMessage)
914 {
915         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
916         print(ColorTranslateRGB(strMessage));
917 }
918
919 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
920 void CSQC_Parse_CenterPrint(string strMessage)
921 {
922         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
923         centerprint_hud(strMessage);
924 }
925
926 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
927 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
928 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
929 bool CSQC_Parse_TempEntity()
930 {
931         // Acquire TE ID
932         int nTEID = ReadByte();
933
934         FOREACH(TempEntities, it.m_id == nTEID, {
935                 if (autocvar_developer_csqcentities)
936                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
937                 return it.m_read(NULL, NULL, true);
938         });
939
940         if (autocvar_developer_csqcentities)
941                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
942
943         // No special logic for this temporary entity; return 0 so the engine can handle it
944         return false;
945 }
946
947 string forcefog;
948 void Fog_Force()
949 {
950         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
951                 localcmd("\nr_drawfog 0\n");
952         else if (forcefog != "")
953                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
954 }
955
956 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
957 {
958         make_pure(this);
959         gametype = ReadRegistered(Gametypes);
960         teamplay = _MapInfo_GetTeamPlayBool(gametype);
961         HUD_ModIcons_SetFunc();
962         FOREACH(Scores, true, {
963                 strcpy(scores_label(it), ReadString());
964                 scores_flags(it) = ReadByte();
965         });
966         for (int i = 0; i < MAX_TEAMSCORE; ++i)
967         {
968                 strcpy(teamscores_label(i), ReadString());
969                 teamscores_flags(i) = ReadByte();
970         }
971         return = true;
972         Scoreboard_InitScores();
973         Gamemode_Init();
974 }
975
976 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
977 {
978         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
979
980         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
981         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
982         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
983         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
984         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
985         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
986         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
987         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
988
989         strcpy(forcefog, ReadString());
990
991         armorblockpercent = ReadByte() / 255.0;
992         damagepush_speedfactor = ReadByte() / 255.0;
993
994         serverflags = ReadByte();
995
996         g_trueaim_minrange = ReadCoord();
997
998         return = true;
999
1000         MUTATOR_CALLHOOK(Ent_Init);
1001
1002         if (!postinit) PostInit();
1003 }
1004
1005 float GetSpeedUnitFactor(int speed_unit)
1006 {
1007         switch(speed_unit)
1008         {
1009                 default:
1010                 case 1:
1011                         return 1.0;
1012                 case 2:
1013                         return 0.0254;
1014                 case 3:
1015                         return 0.0254 * 3.6;
1016                 case 4:
1017                         return 0.0254 * 3.6 * 0.6213711922;
1018                 case 5:
1019                         return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1020         }
1021 }
1022
1023 string GetSpeedUnit(int speed_unit)
1024 {
1025         switch(speed_unit)
1026         {
1027                 default:
1028                 case 1:
1029                         return _(" qu/s");
1030                 case 2:
1031                         return _(" m/s");
1032                 case 3:
1033                         return _(" km/h");
1034                 case 4:
1035                         return _(" mph");
1036                 case 5:
1037                         return _(" knots");
1038         }
1039 }
1040
1041 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1042 {
1043         int b = ReadByte();
1044
1045         switch (b)
1046         {
1047                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1048                         race_checkpoint = ReadByte();
1049                         race_time = ReadInt24_t();
1050                         race_previousbesttime = ReadInt24_t();
1051                         race_mypreviousbesttime = ReadInt24_t();
1052                         string pbestname = ReadString();
1053                         if(autocvar_cl_race_cptimes_onlyself)
1054                         {
1055                                 race_previousbesttime = race_mypreviousbesttime;
1056                                 race_mypreviousbesttime = 0;
1057                                 strcpy(race_previousbestname, "");
1058                         }
1059                         else
1060                                 strcpy(race_previousbestname, pbestname);
1061
1062                         race_checkpointtime = time;
1063
1064                         if(race_checkpoint == 0 || race_checkpoint == 254)
1065                         {
1066                                 race_penaltyaccumulator = 0;
1067                                 race_laptime = time; // valid
1068                         }
1069                         break;
1070
1071                 case RACE_NET_CHECKPOINT_CLEAR:
1072                         race_laptime = 0;
1073                         race_checkpointtime = 0;
1074                         break;
1075
1076                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1077                         race_laptime = ReadCoord();
1078                         race_checkpointtime = -99999;
1079                         // fall through
1080                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1081                         race_nextcheckpoint = ReadByte();
1082
1083                         race_nextbesttime = ReadInt24_t();
1084                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1085                                 race_mybesttime = ReadInt24_t();
1086                         string newname = ReadString();
1087                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1088                         {
1089                                 race_nextbesttime = race_mybesttime;
1090                                 race_mybesttime = 0;
1091                                 strcpy(race_nextbestname, "");
1092                         }
1093                         else
1094                                 strcpy(race_nextbestname, newname);
1095                         break;
1096
1097                 case RACE_NET_CHECKPOINT_HIT_RACE:
1098                         race_mycheckpoint = ReadByte();
1099                         race_mycheckpointtime = time;
1100                         race_mycheckpointdelta = ReadInt24_t();
1101                         race_mycheckpointlapsdelta = ReadByte();
1102                         if(race_mycheckpointlapsdelta >= 128)
1103                                 race_mycheckpointlapsdelta -= 256;
1104                         int who = ReadByte();
1105                         if(who)
1106                                 strcpy(race_mycheckpointenemy, entcs_GetName(who - 1));
1107                         else
1108                                 strcpy(race_mycheckpointenemy, ""); // TODO: maybe string_null works fine here?
1109                         break;
1110
1111                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1112                         race_othercheckpoint = ReadByte();
1113                         race_othercheckpointtime = time;
1114                         race_othercheckpointdelta = ReadInt24_t();
1115                         race_othercheckpointlapsdelta = ReadByte();
1116                         if(race_othercheckpointlapsdelta >= 128)
1117                                 race_othercheckpointlapsdelta -= 256;
1118                         int what = ReadByte();
1119                         if(what)
1120                                 strcpy(race_othercheckpointenemy, entcs_GetName(what - 1));
1121                         else
1122                                 strcpy(race_othercheckpointenemy, ""); // TODO: maybe string_null works fine here?
1123                         break;
1124
1125                 case RACE_NET_PENALTY_RACE:
1126                 case RACE_NET_PENALTY_QUALIFYING:
1127                         race_penaltyeventtime = time;
1128                         race_penaltytime = ReadShort();
1129                         string reason = ReadString();
1130                         if (reason == "missing a checkpoint")
1131                                 reason = _("missing a checkpoint");
1132                         strcpy(race_penaltyreason, reason);
1133                         if (b == RACE_NET_PENALTY_QUALIFYING)
1134                                 race_penaltyaccumulator += race_penaltytime;
1135                         break;
1136
1137                 case RACE_NET_SERVER_RECORD:
1138                         race_server_record = ReadInt24_t();
1139                         break;
1140                 case RACE_NET_SPEED_AWARD:
1141                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1142                         strcpy(race_speedaward_holder, ReadString());
1143                         strcpy(race_speedaward_unit, GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1144                         break;
1145                 case RACE_NET_SPEED_AWARD_BEST:
1146                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1147                         strcpy(race_speedaward_alltimebest_holder, ReadString());
1148                         strcpy(race_speedaward_alltimebest_unit, GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1149                         break;
1150                 case RACE_NET_RANKINGS_CNT:
1151                         RANKINGS_DISPLAY_CNT = ReadByte();
1152                         break;
1153                 case RACE_NET_SERVER_RANKINGS:
1154                         float prevpos, del;
1155                         int pos = ReadShort();
1156                         prevpos = ReadShort();
1157                         del = ReadShort();
1158
1159                         // move other rankings out of the way
1160                         int i;
1161                         if (prevpos) {
1162                                 int m = min(prevpos, RANKINGS_DISPLAY_CNT);
1163                                 for (i=m-1; i>pos-1; --i) {
1164                                         grecordtime[i] = grecordtime[i-1];
1165                                         strcpy(grecordholder[i], grecordholder[i-1]);
1166                                 }
1167                         } else if (del) { // a record has been deleted by the admin
1168                                 for (i=pos-1; i<= RANKINGS_DISPLAY_CNT-1; ++i) {
1169                                         if (i == RANKINGS_DISPLAY_CNT-1) { // clear out last record
1170                                                 grecordtime[i] = 0;
1171                                                 strfree(grecordholder[i]);
1172                                         }
1173                                         else {
1174                                                 grecordtime[i] = grecordtime[i+1];
1175                                                 strcpy(grecordholder[i], grecordholder[i+1]);
1176                                         }
1177                                 }
1178                         } else { // player has no ranked record yet
1179                                 for (i=RANKINGS_DISPLAY_CNT-1;i>pos-1;--i) {
1180                                         grecordtime[i] = grecordtime[i-1];
1181                                         strcpy(grecordholder[i], grecordholder[i-1]);
1182                                 }
1183                         }
1184
1185                         if (grecordtime[RANKINGS_DISPLAY_CNT]) {
1186                                 // kick off the player who fell from the last displayed position
1187                                 grecordtime[RANKINGS_DISPLAY_CNT] = 0;
1188                                 strfree(grecordholder[RANKINGS_DISPLAY_CNT]);
1189                         }
1190
1191                         // store new ranking
1192                         strcpy(grecordholder[pos-1], ReadString());
1193                         grecordtime[pos-1] = ReadInt24_t();
1194                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1195                                 race_myrank = pos;
1196                         break;
1197                 case RACE_NET_SERVER_STATUS:
1198                         race_status = ReadShort();
1199                         strcpy(race_status_name, ReadString());
1200         }
1201         return true;
1202 }
1203
1204 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1205 {
1206         teamnagger = 1;
1207         return true;
1208 }
1209
1210 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1211 {
1212         int i = ReadByte();
1213         int pi = ReadShort();
1214         int pl = ReadByte();
1215         int ml = ReadByte();
1216         return = true;
1217         entity e = playerslots[i];
1218         if (!e) return;
1219         e.ping = pi;
1220         e.ping_packetloss = pl / 255.0;
1221         e.ping_movementloss = ml / 255.0;
1222 }
1223
1224 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1225 {
1226         int weapon_id = ReadByte();
1227         complain_weapon = Weapons_from(weapon_id);
1228         complain_weapon_type = ReadByte();
1229         return = true;
1230
1231         complain_weapon_time = time;
1232         weapontime = time; // ping the weapon panel
1233
1234         switch(complain_weapon_type)
1235         {
1236                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, weapon_id); break;
1237                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, weapon_id); break;
1238                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, weapon_id); break;
1239         }
1240 }
1241
1242 string _getcommandkey(string cmd_name, string command, bool forcename)
1243 {
1244         string keys;
1245         float n, j, k, l = 0;
1246
1247         if (!autocvar_hud_showbinds)
1248                 return cmd_name;
1249
1250         keys = db_get(binddb, command);
1251         if (keys == "")
1252         {
1253                 bool joy_active = cvar("joy_active");
1254                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1255                 for(j = 0; j < n; ++j)
1256                 {
1257                         k = stof(argv(j));
1258                         if(k != -1)
1259                         {
1260                                 string key = keynumtostring(k);
1261                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1262                                         continue;
1263
1264                                 key = translate_key(key);
1265
1266                                 if (keys == "")
1267                                         keys = key;
1268                                 else
1269                                         keys = strcat(keys, ", ", key);
1270
1271                                 ++l;
1272                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1273                                         break;
1274                         }
1275
1276                 }
1277                 if (keys == "")
1278                         keys = "NO_KEY";
1279                 db_put(binddb, command, keys);
1280         }
1281
1282         if (keys == "NO_KEY") {
1283                 if (autocvar_hud_showbinds > 1)
1284                         return sprintf(_("%s (not bound)"), cmd_name);
1285                 else
1286                         return cmd_name;
1287         }
1288         else if (autocvar_hud_showbinds > 1 || forcename)
1289                 return sprintf("%s (%s)", cmd_name, keys);
1290         else
1291                 return keys;
1292 }