qcsrc/client/main.qc

   1 #include "controlpoint.qh"
   2 #include "generator.qh"
   3 #include "mapvoting.qh"
   4 #include "modeleffects.qh"
   5 #include "particles.qh"
   6 #include "scoreboard.qh"
   7 #include "shownames.qh"
   8 #include "target_music.qh"
   9 #include "tturrets.qh"
  10 #include "tuba.qh"
  11 #include "wall.qh"
  12 #include "waypointsprites.qh"
  13
  14 #include "vehicles/vehicles.qh"
  15
  16 #include "../server/vehicles/bumblebee.qh"
  17
  18 #include "../common/net_notice.qh"
  19
  20 #include "../common/monsters/monsters.qh"
  21
  22 #include "../warpzonelib/client.qh"
  23
  24 // --------------------------------------------------------------------------
  25 // BEGIN REQUIRED CSQC FUNCTIONS
  26 //include "main.qh"
  27
  28 entity clearentity_ent;
  29 void clearentity(entity e)
  30 {
  31         if (!clearentity_ent)
  32         {
  33                 clearentity_ent = spawn();
  34                 clearentity_ent.classname = "clearentity";
  35         }
  36         int n = e.entnum;
  37         copyentity(clearentity_ent, e);
  38         e.entnum = n;
  39 }
  40
  41 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  42 void menu_show_error()
  43 {
  44         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  45 }
  46
  47 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  48 // Useful for precaching things
  49
  50 void menu_sub_null()
  51 {
  52 }
  53
  54 string forcefog;
  55 void WaypointSprite_Load();
  56 void ConsoleCommand_macro_init();
  57 void CSQC_Init(void)
  58 {
  59         prvm_language = cvar_string("prvm_language");
  60
  61 #ifdef WATERMARK
  62         dprintf("^4CSQC Build information: ^1%s\n", WATERMARK);
  63 #endif
  64
  65         int i;
  66
  67         binddb = db_create();
  68         tempdb = db_create();
  69         ClientProgsDB = db_load("client.db");
  70         compressShortVector_init();
  71
  72         draw_endBoldFont();
  73         menu_visible = false;
  74         menu_show = menu_show_error;
  75         menu_action = func_null;
  76
  77         for(i = 0; i < 255; ++i)
  78                 if(getplayerkeyvalue(i, "viewentity") == "")
  79                         break;
  80         maxclients = i;
  81
  82         //registercommand("hud_configure");
  83         //registercommand("hud_save");
  84         //registercommand("menu_action");
  85
  86         ConsoleCommand_macro_init();
  87
  88         registercvar("hud_usecsqc", "1");
  89         registercvar("scoreboard_columns", "default");
  90
  91         registercvar("cl_nade_type", "3");
  92         registercvar("cl_pokenade_type", "zombie");
  93
  94         gametype = 0;
  95
  96         // hud_fields uses strunzone on the titles!
  97         for(i = 0; i < MAX_HUD_FIELDS; ++i)
  98                 hud_title[i] = strzone("(null)");
  99
 100         Cmd_HUD_SetFields(0);
 101
 102         postinit = false;
 103
 104         calledhooks = 0;
 105
 106         teams = Sort_Spawn();
 107         players = Sort_Spawn();
 108
 109         GetTeam(NUM_SPECTATOR, true); // add specs first
 110
 111         // needs to be done so early because of the constants they create
 112         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 113         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 114         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 115         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 116         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 117         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
 118         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 119
 120         WaypointSprite_Load();
 121
 122         // precaches
 123         precache_model("null");
 124         precache_sound("misc/hit.wav");
 125         precache_sound("misc/typehit.wav");
 126
 127         generator_precache();
 128         Projectile_Precache();
 129         Hook_Precache();
 130         GibSplash_Precache();
 131         Casings_Precache();
 132         Vehicles_Precache();
 133         turrets_precache();
 134         Tuba_Precache();
 135         CSQCPlayer_Precache();
 136
 137         if(autocvar_cl_reticle)
 138         {
 139                 precache_pic("gfx/reticle_normal");
 140                 // weapon reticles are precached in weapon files
 141         }
 142
 143         get_mi_min_max_texcoords(1); // try the CLEVER way first
 144         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 145         shortmapname = mi_shortname;
 146
 147         if(precache_pic(minimapname) == "")
 148         {
 149                 // but maybe we have a non-clever minimap
 150                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 151                 if(precache_pic(minimapname) == "")
 152                         minimapname = ""; // FAIL
 153                 else
 154                         get_mi_min_max_texcoords(0); // load new texcoords
 155         }
 156
 157         mi_center = (mi_min + mi_max) * 0.5;
 158         mi_scale = mi_max - mi_min;
 159         minimapname = strzone(minimapname);
 160
 161         WarpZone_Init();
 162
 163         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 164         hud_configure_prev = -1;
 165
 166         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 167 }
 168
 169 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 170 void Shutdown(void)
 171 {
 172         WarpZone_Shutdown();
 173
 174         remove(teams);
 175         remove(players);
 176         db_close(binddb);
 177         db_close(tempdb);
 178         if(autocvar_cl_db_saveasdump)
 179                 db_dump(ClientProgsDB, "client.db");
 180         else
 181                 db_save(ClientProgsDB, "client.db");
 182         db_close(ClientProgsDB);
 183
 184         if(camera_active)
 185                 cvar_set("chase_active",ftos(chase_active_backup));
 186
 187         // unset the event chasecam's chase_active
 188         if(autocvar_chase_active < 0)
 189                 cvar_set("chase_active", "0");
 190
 191         if (!isdemo())
 192         {
 193                 if (!(calledhooks & HOOK_START))
 194                         localcmd("\n_cl_hook_gamestart nop\n");
 195                 if (!(calledhooks & HOOK_END))
 196                         localcmd("\ncl_hook_gameend\n");
 197         }
 198 }
 199
 200 .float has_team;
 201 float SetTeam(entity o, int Team)
 202 {
 203         entity tm;
 204         if(teamplay)
 205         {
 206                 switch(Team)
 207                 {
 208                         case -1:
 209                         case NUM_TEAM_1:
 210                         case NUM_TEAM_2:
 211                         case NUM_TEAM_3:
 212                         case NUM_TEAM_4:
 213                                 break;
 214                         default:
 215                                 if(GetTeam(Team, false) == world)
 216                                 {
 217                                         dprintf("trying to switch to unsupported team %d\n", Team);
 218                                         Team = NUM_SPECTATOR;
 219                                 }
 220                                 break;
 221                 }
 222         }
 223         else
 224         {
 225                 switch(Team)
 226                 {
 227                         case -1:
 228                         case 0:
 229                                 break;
 230                         default:
 231                                 if(GetTeam(Team, false) == world)
 232                                 {
 233                                         dprintf("trying to switch to unsupported team %d\n", Team);
 234                                         Team = NUM_SPECTATOR;
 235                                 }
 236                                 break;
 237                 }
 238         }
 239         if(Team == -1) // leave
 240         {
 241                 if(o.has_team)
 242                 {
 243                         tm = GetTeam(o.team, false);
 244                         tm.team_size -= 1;
 245                         o.has_team = 0;
 246                         return true;
 247                 }
 248         }
 249         else
 250         {
 251                 if (!o.has_team)
 252                 {
 253                         o.team = Team;
 254                         tm = GetTeam(Team, true);
 255                         tm.team_size += 1;
 256                         o.has_team = 1;
 257                         return true;
 258                 }
 259                 else if(Team != o.team)
 260                 {
 261                         tm = GetTeam(o.team, false);
 262                         tm.team_size -= 1;
 263                         o.team = Team;
 264                         tm = GetTeam(Team, true);
 265                         tm.team_size += 1;
 266                         return true;
 267                 }
 268         }
 269         return false;
 270 }
 271
 272 void Playerchecker_Think()
 273 {
 274     int i;
 275         entity e;
 276         for(i = 0; i < maxclients; ++i)
 277         {
 278                 e = playerslots[i];
 279                 if(GetPlayerName(i) == "")
 280                 {
 281                         if(e.sort_prev)
 282                         {
 283                                 // player disconnected
 284                                 SetTeam(e, -1);
 285                                 RemovePlayer(e);
 286                                 e.sort_prev = world;
 287                                 //e.gotscores = 0;
 288                         }
 289                 }
 290                 else
 291                 {
 292                         if (!e.sort_prev)
 293                         {
 294                                 // player connected
 295                                 if (!e)
 296                                         playerslots[i] = e = spawn();
 297                                 e.sv_entnum = i;
 298                                 e.ping = 0;
 299                                 e.ping_packetloss = 0;
 300                                 e.ping_movementloss = 0;
 301                                 //e.gotscores = 0; // we might already have the scores...
 302                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 303                                 RegisterPlayer(e);
 304                                 HUD_UpdatePlayerPos(e);
 305                         }
 306                 }
 307         }
 308         self.nextthink = time + 0.2;
 309 }
 310
 311 void Porto_Init();
 312 void TrueAim_Init();
 313 void PostInit(void)
 314 {
 315         entity playerchecker;
 316         playerchecker = spawn();
 317         playerchecker.think = Playerchecker_Think;
 318         playerchecker.nextthink = time + 0.2;
 319
 320         Porto_Init();
 321         TrueAim_Init();
 322
 323         postinit = true;
 324 }
 325
 326 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 327 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 328 // All keys are in ascii.
 329 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 330 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 331 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 332 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 333 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 334 {
 335         float bSkipKey;
 336         bSkipKey = false;
 337
 338         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 339                 return true;
 340
 341         if ( HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary) )
 342                 return true;
 343
 344         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 345                 return true;
 346
 347         if(menu_visible && menu_action)
 348                 if(menu_action(bInputType, nPrimary, nSecondary))
 349                         return true;
 350
 351         return bSkipKey;
 352 }
 353
 354 // END REQUIRED CSQC FUNCTIONS
 355 // --------------------------------------------------------------------------
 356
 357 // --------------------------------------------------------------------------
 358 // BEGIN OPTIONAL CSQC FUNCTIONS
 359 void Ent_RemoveEntCS()
 360 {
 361         entcs_receiver[self.sv_entnum] = world;
 362 }
 363 void Ent_ReadEntCS()
 364 {
 365     int sf;
 366         InterpolateOrigin_Undo();
 367
 368         self.classname = "entcs_receiver";
 369         sf = ReadByte();
 370
 371         if(sf & 1)
 372                 self.sv_entnum = ReadByte();
 373         if(sf & 2)
 374         {
 375                 self.origin_x = ReadShort();
 376                 self.origin_y = ReadShort();
 377                 self.origin_z = ReadShort();
 378                 setorigin(self, self.origin);
 379         }
 380         if(sf & 4)
 381         {
 382                 self.angles_y = ReadByte() * 360.0 / 256;
 383                 self.angles_x = self.angles_z = 0;
 384         }
 385         if(sf & 8)
 386                 self.healthvalue = ReadByte() * 10;
 387         if(sf & 16)
 388                 self.armorvalue = ReadByte() * 10;
 389
 390         entcs_receiver[self.sv_entnum] = self;
 391         self.entremove = Ent_RemoveEntCS;
 392         self.iflags |= IFLAG_ORIGIN;
 393
 394         InterpolateOrigin_Note();
 395 }
 396
 397 void Ent_Remove();
 398
 399 void Ent_RemovePlayerScore()
 400 {
 401         if(self.owner) {
 402                 SetTeam(self.owner, -1);
 403                 self.owner.gotscores = 0;
 404                 for(int i = 0; i < MAX_SCORE; ++i) {
 405                         self.owner.(scores[i]) = 0; // clear all scores
 406                 }
 407         }
 408 }
 409
 410 void Ent_ReadPlayerScore()
 411 {
 412         int i, n;
 413         bool isNew;
 414         entity o;
 415
 416         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 417         // (no I've never heard of M-x replace-string, sed, or anything like that)
 418         isNew = !self.owner; // workaround for DP bug
 419         n = ReadByte()-1;
 420
 421 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 422         if(!isNew && n != self.sv_entnum)
 423         {
 424                 //print("A CSQC entity changed its owner!\n");
 425                 printf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 426                 isNew = true;
 427                 Ent_Remove();
 428                 self.enttype = ENT_CLIENT_SCORES;
 429         }
 430 #endif
 431
 432         self.sv_entnum = n;
 433
 434         if (!(playerslots[self.sv_entnum]))
 435                 playerslots[self.sv_entnum] = spawn();
 436         o = self.owner = playerslots[self.sv_entnum];
 437         o.sv_entnum = self.sv_entnum;
 438         o.gotscores = 1;
 439
 440         //if (!o.sort_prev)
 441         //      RegisterPlayer(o);
 442         //playerchecker will do this for us later, if it has not already done so
 443
 444     int sf, lf;
 445 #if MAX_SCORE <= 8
 446         sf = ReadByte();
 447         lf = ReadByte();
 448 #else
 449         sf = ReadShort();
 450         lf = ReadShort();
 451 #endif
 452     int p;
 453         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 454                 if(sf & p)
 455                 {
 456                         if(lf & p)
 457                                 o.(scores[i]) = ReadInt24_t();
 458                         else
 459                                 o.(scores[i]) = ReadChar();
 460                 }
 461
 462         if(o.sort_prev)
 463                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 464
 465         self.entremove = Ent_RemovePlayerScore;
 466 }
 467
 468 void Ent_ReadTeamScore()
 469 {
 470         int i;
 471         entity o;
 472
 473         self.team = ReadByte();
 474         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 475
 476     int sf, lf;
 477 #if MAX_TEAMSCORE <= 8
 478         sf = ReadByte();
 479         lf = ReadByte();
 480 #else
 481         sf = ReadShort();
 482         lf = ReadShort();
 483 #endif
 484         int p;
 485         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 486                 if(sf & p)
 487                 {
 488                         if(lf & p)
 489                                 o.(teamscores[i]) = ReadInt24_t();
 490                         else
 491                                 o.(teamscores[i]) = ReadChar();
 492                 }
 493
 494         HUD_UpdateTeamPos(o);
 495 }
 496
 497 void Ent_ClientData()
 498 {
 499         float newspectatee_status;
 500
 501     int f = ReadByte();
 502
 503         scoreboard_showscores_force = (f & 1);
 504
 505         if(f & 2)
 506         {
 507                 newspectatee_status = ReadByte();
 508                 if(newspectatee_status == player_localnum + 1)
 509                         newspectatee_status = -1; // observing
 510         }
 511         else
 512                 newspectatee_status = 0;
 513
 514         spectatorbutton_zoom = (f & 4);
 515
 516         if(f & 8)
 517         {
 518                 angles_held_status = 1;
 519                 angles_held.x = ReadAngle();
 520                 angles_held.y = ReadAngle();
 521                 angles_held.z = 0;
 522         }
 523         else
 524                 angles_held_status = 0;
 525
 526         if(newspectatee_status != spectatee_status)
 527         {
 528                 // clear race stuff
 529                 race_laptime = 0;
 530                 race_checkpointtime = 0;
 531         }
 532         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 533         {
 534                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 535                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 536                 )
 537                         prev_p_health = -1;
 538                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 539                         prev_health = -1;
 540         }
 541         spectatee_status = newspectatee_status;
 542
 543         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 544 }
 545
 546 void Ent_Nagger()
 547 {
 548     int i, j, b, f;
 549
 550     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 551
 552         if(!(nags & 4))
 553         {
 554                 if(vote_called_vote)
 555                         strunzone(vote_called_vote);
 556                 vote_called_vote = string_null;
 557                 vote_active = 0;
 558         }
 559         else
 560         {
 561                 vote_active = 1;
 562         }
 563
 564         if(nags & 64)
 565         {
 566                 vote_yescount = ReadByte();
 567                 vote_nocount = ReadByte();
 568                 vote_needed = ReadByte();
 569                 vote_highlighted = ReadChar();
 570         }
 571
 572         if(nags & 128)
 573         {
 574                 if(vote_called_vote)
 575                         strunzone(vote_called_vote);
 576                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 577         }
 578
 579         if(nags & 1)
 580         {
 581                 for(j = 0; j < maxclients; ++j)
 582                         if(playerslots[j])
 583                                 playerslots[j].ready = 1;
 584                 for(i = 1; i <= maxclients; i += 8)
 585                 {
 586                         f = ReadByte();
 587                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 588                                 if (!(f & b))
 589                                         if(playerslots[j])
 590                                                 playerslots[j].ready = 0;
 591                 }
 592         }
 593
 594         ready_waiting = (nags & 1);
 595         ready_waiting_for_me = (nags & 2);
 596         vote_waiting = (nags & 4);
 597         vote_waiting_for_me = (nags & 8);
 598         warmup_stage = (nags & 16);
 599 }
 600
 601 void Ent_EliminatedPlayers()
 602 {
 603     int i, j, b, f;
 604
 605     int sf = ReadByte();
 606         if(sf & 1)
 607         {
 608                 for(j = 0; j < maxclients; ++j)
 609                         if(playerslots[j])
 610                                 playerslots[j].eliminated = 1;
 611                 for(i = 1; i <= maxclients; i += 8)
 612                 {
 613                         f = ReadByte();
 614                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 615                                 if (!(f & b))
 616                                         if(playerslots[j])
 617                                                 playerslots[j].eliminated = 0;
 618                 }
 619         }
 620 }
 621
 622 void Ent_RandomSeed()
 623 {
 624         float s;
 625         prandom_debug();
 626         s = ReadShort();
 627         psrandom(s);
 628 }
 629
 630 void Ent_ReadAccuracy(void)
 631 {
 632     int f, w;
 633     int sf = ReadInt24_t();
 634         if(sf == 0)
 635         {
 636                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 637                         weapon_accuracy[w] = -1;
 638                 return;
 639         }
 640
 641         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 642         {
 643                 if(sf & f)
 644                 {
 645             int b = ReadByte();
 646                         if(b == 0)
 647                                 weapon_accuracy[w] = -1;
 648                         else if(b == 255)
 649                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 650                         else
 651                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 652                 }
 653                 if(f == 0x800000)
 654                         f = 1;
 655                 else
 656                         f *= 2;
 657         }
 658 }
 659
 660 void Spawn_Draw(void)
 661 {
 662         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 663 }
 664
 665 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 666 {
 667         float teamnum = (ReadByte() - 1);
 668         vector spn_origin;
 669         spn_origin.x = ReadShort();
 670         spn_origin.y = ReadShort();
 671         spn_origin.z = ReadShort();
 672
 673         if(is_new)
 674         {
 675                 self.origin = spn_origin;
 676                 setsize(self, PL_MIN, PL_MAX);
 677                 droptofloor();
 678
 679                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 680                 {
 681                         self.mdl = "models/spawnpoint.md3";
 682                         self.colormod = Team_ColorRGB(teamnum);
 683                         precache_model(self.mdl);
 684                         setmodel(self, self.mdl);
 685                         self.drawmask = MASK_NORMAL;
 686                         //self.movetype = MOVETYPE_NOCLIP;
 687                         //self.draw = Spawn_Draw;
 688                 }*/
 689                 if(autocvar_cl_spawn_point_particles)
 690                 {
 691                         if((serverflags & SERVERFLAG_TEAMPLAY))
 692                         {
 693                                 switch(teamnum)
 694                                 {
 695                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
 696                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
 697                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
 698                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
 699                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
 700                                 }
 701                         }
 702                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
 703
 704                         self.draw = Spawn_Draw;
 705                 }
 706         }
 707
 708         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 709 }
 710
 711 void Ent_ReadSpawnEvent(float is_new)
 712 {
 713         // If entnum is 0, ONLY do the local spawn actions
 714         // this way the server can disable the sending of
 715         // spawn origin or such to clients if wanted.
 716         float entnum = ReadByte();
 717
 718         if(entnum)
 719         {
 720                 self.origin_x = ReadShort();
 721                 self.origin_y = ReadShort();
 722                 self.origin_z = ReadShort();
 723
 724                 if(is_new)
 725                 {
 726                         float teamnum = GetPlayerColor(entnum - 1);
 727
 728                         if(autocvar_cl_spawn_event_particles)
 729                         {
 730                                 switch(teamnum)
 731                                 {
 732                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
 733                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
 734                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
 735                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
 736                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
 737                                 }
 738                         }
 739                         if(autocvar_cl_spawn_event_sound)
 740                         {
 741                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
 742                         }
 743                 }
 744         }
 745
 746         // local spawn actions
 747         if(is_new && (!entnum || (entnum == player_localentnum)))
 748         {
 749                 zoomin_effect = 1;
 750                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 751
 752                 if(autocvar_cl_unpress_zoom_on_spawn)
 753                 {
 754                         localcmd("-zoom\n");
 755                         button_zoom = false;
 756                 }
 757         }
 758         HUD_Radar_Hide_Maximized();
 759         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 760 }
 761
 762 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 763 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 764 void Ent_RadarLink();
 765 void Ent_Init();
 766 void Ent_ScoresInfo();
 767 void CSQC_Ent_Update(float bIsNewEntity)
 768 {
 769         float t;
 770         float savetime;
 771         t = ReadByte();
 772
 773         if(autocvar_developer_csqcentities)
 774                 printf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 775
 776         // set up the "time" global for received entities to be correct for interpolation purposes
 777         savetime = time;
 778         if(servertime)
 779         {
 780                 time = servertime;
 781         }
 782         else
 783         {
 784                 serverprevtime = time;
 785                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 786                 time = serverprevtime + serverdeltatime;
 787         }
 788
 789 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 790         if(self.enttype)
 791         {
 792                 if(t != self.enttype || bIsNewEntity)
 793                 {
 794                         //print("A CSQC entity changed its type!\n");
 795                         printf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 796                         Ent_Remove();
 797                         clearentity(self);
 798                         bIsNewEntity = 1;
 799                 }
 800         }
 801         else
 802         {
 803                 if(!bIsNewEntity)
 804                 {
 805                         printf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 806                         bIsNewEntity = 1;
 807                 }
 808         }
 809 #endif
 810         self.enttype = t;
 811         switch(t)
 812         {
 813                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 814                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 815                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 816                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 817                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 818                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 819                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 820                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
 821                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 822                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 823                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 824                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 825                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 826                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 827                 case ENT_CLIENT_INIT: Ent_Init(); break;
 828                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 829                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 830                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 831                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 832                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 833                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 834                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 835                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 836                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 837                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 838                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 839                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 840                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
 841                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 842                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 843                 case ENT_CLIENT_TURRET: ent_turret(); break;
 844                 case ENT_CLIENT_GENERATOR: ent_generator(); break;
 845                 case ENT_CLIENT_CONTROLPOINT_ICON: ent_cpicon(); break;
 846                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 847                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 848                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 849                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 850                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 851                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 852                 case ENT_CLIENT_HEALING_ORB: ent_healer(); break;
 853
 854                 default:
 855                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 856                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
 857                         break;
 858         }
 859
 860         time = savetime;
 861 }
 862 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 863 // used when an entity changes its type. For an entity that someone interacts
 864 // with others, make sure it can no longer do so.
 865 void Ent_Remove()
 866 {
 867         if(self.entremove)
 868                 self.entremove();
 869
 870         if(self.skeletonindex)
 871         {
 872                 skel_delete(self.skeletonindex);
 873                 self.skeletonindex = 0;
 874         }
 875
 876         if(self.snd_looping > 0)
 877         {
 878                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 879                 self.snd_looping = 0;
 880         }
 881
 882         self.enttype = 0;
 883         self.classname = "";
 884         self.draw = menu_sub_null;
 885         self.entremove = menu_sub_null;
 886         // TODO possibly set more stuff to defaults
 887 }
 888 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 889 void CSQC_Ent_Remove()
 890 {
 891         if(autocvar_developer_csqcentities)
 892                 printf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 893
 894         if(wasfreed(self))
 895         {
 896                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 897                 return;
 898         }
 899         if(self.enttype)
 900                 Ent_Remove();
 901         remove(self);
 902 }
 903
 904 void Gamemode_Init()
 905 {
 906         if (!isdemo())
 907         {
 908                 if(!(calledhooks & HOOK_START))
 909                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 910                 calledhooks |= HOOK_START;
 911         }
 912 }
 913 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 914 void CSQC_Parse_StuffCmd(string strMessage)
 915 {
 916         if(autocvar_developer_csqcentities)
 917                 printf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 918
 919         localcmd(strMessage);
 920 }
 921 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 922 void CSQC_Parse_Print(string strMessage)
 923 {
 924         if(autocvar_developer_csqcentities)
 925                 printf("CSQC_Parse_Print(\"%s\")\n", strMessage);
 926
 927         print(ColorTranslateRGB(strMessage));
 928 }
 929
 930 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 931 void CSQC_Parse_CenterPrint(string strMessage)
 932 {
 933         if(autocvar_developer_csqcentities)
 934                 printf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 935
 936         centerprint_hud(strMessage);
 937 }
 938
 939 string notranslate_fogcmd1 = "\nfog ";
 940 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 941 void Fog_Force()
 942 {
 943         // TODO somehow thwart prvm_globalset client ...
 944
 945         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 946                 { localcmd("\nr_drawfog 0\n"); }
 947         else if(forcefog != "")
 948                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
 949 }
 950
 951 void Gamemode_Init();
 952 void Ent_ScoresInfo()
 953 {
 954     int i;
 955         self.classname = "ent_client_scores_info";
 956         gametype = ReadInt24_t();
 957         HUD_ModIcons_SetFunc();
 958         for(i = 0; i < MAX_SCORE; ++i)
 959         {
 960                 if(scores_label[i])
 961                         strunzone(scores_label[i]);
 962                 scores_label[i] = strzone(ReadString());
 963                 scores_flags[i] = ReadByte();
 964         }
 965         for(i = 0; i < MAX_TEAMSCORE; ++i)
 966         {
 967                 if(teamscores_label[i])
 968                         strunzone(teamscores_label[i]);
 969                 teamscores_label[i] = strzone(ReadString());
 970                 teamscores_flags[i] = ReadByte();
 971         }
 972         HUD_InitScores();
 973         Gamemode_Init();
 974 }
 975
 976 void Ent_Init()
 977 {
 978         self.classname = "ent_client_init";
 979
 980         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 981
 982         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 983         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 984         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 985         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 986         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 987         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 988         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 989         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 990
 991         if(forcefog)
 992                 strunzone(forcefog);
 993         forcefog = strzone(ReadString());
 994
 995         armorblockpercent = ReadByte() / 255.0;
 996
 997         g_balance_mortar_bouncefactor = ReadCoord();
 998         g_balance_mortar_bouncestop = ReadCoord();
 999         g_balance_electro_secondary_bouncefactor = ReadCoord();
1000         g_balance_electro_secondary_bouncestop = ReadCoord();
1001
1002         vortex_scope = !ReadByte();
1003         rifle_scope = !ReadByte();
1004
1005         serverflags = ReadByte();
1006
1007         minelayer_maxmines = ReadByte();
1008
1009         hagar_maxrockets = ReadByte();
1010
1011         g_trueaim_minrange = ReadCoord();
1012         g_balance_porto_secondary = ReadByte();
1013
1014         if(!postinit)
1015                 PostInit();
1016 }
1017
1018 void Net_ReadRace()
1019 {
1020         float b;
1021
1022         b = ReadByte();
1023
1024         switch(b)
1025         {
1026                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1027                         race_checkpoint = ReadByte();
1028                         race_time = ReadInt24_t();
1029                         race_previousbesttime = ReadInt24_t();
1030                         if(race_previousbestname)
1031                                 strunzone(race_previousbestname);
1032                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1033
1034                         race_checkpointtime = time;
1035
1036                         if(race_checkpoint == 0 || race_checkpoint == 254)
1037                         {
1038                                 race_penaltyaccumulator = 0;
1039                                 race_laptime = time; // valid
1040                         }
1041
1042                         break;
1043
1044                 case RACE_NET_CHECKPOINT_CLEAR:
1045                         race_laptime = 0;
1046                         race_checkpointtime = 0;
1047                         break;
1048
1049                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1050                         race_laptime = ReadCoord();
1051                         race_checkpointtime = -99999;
1052                         // fall through
1053                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1054                         race_nextcheckpoint = ReadByte();
1055
1056                         race_nextbesttime = ReadInt24_t();
1057                         if(race_nextbestname)
1058                                 strunzone(race_nextbestname);
1059                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1060                         break;
1061
1062                 case RACE_NET_CHECKPOINT_HIT_RACE:
1063                         race_mycheckpoint = ReadByte();
1064                         race_mycheckpointtime = time;
1065                         race_mycheckpointdelta = ReadInt24_t();
1066                         race_mycheckpointlapsdelta = ReadByte();
1067                         if(race_mycheckpointlapsdelta >= 128)
1068                                 race_mycheckpointlapsdelta -= 256;
1069                         if(race_mycheckpointenemy)
1070                                 strunzone(race_mycheckpointenemy);
1071                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1072                         break;
1073
1074                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1075                         race_othercheckpoint = ReadByte();
1076                         race_othercheckpointtime = time;
1077                         race_othercheckpointdelta = ReadInt24_t();
1078                         race_othercheckpointlapsdelta = ReadByte();
1079                         if(race_othercheckpointlapsdelta >= 128)
1080                                 race_othercheckpointlapsdelta -= 256;
1081                         if(race_othercheckpointenemy)
1082                                 strunzone(race_othercheckpointenemy);
1083                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1084                         break;
1085
1086                 case RACE_NET_PENALTY_RACE:
1087                         race_penaltyeventtime = time;
1088                         race_penaltytime = ReadShort();
1089                         //race_penaltyaccumulator += race_penaltytime;
1090                         if(race_penaltyreason)
1091                                 strunzone(race_penaltyreason);
1092                         race_penaltyreason = strzone(ReadString());
1093                         break;
1094
1095                 case RACE_NET_PENALTY_QUALIFYING:
1096                         race_penaltyeventtime = time;
1097                         race_penaltytime = ReadShort();
1098                         race_penaltyaccumulator += race_penaltytime;
1099                         if(race_penaltyreason)
1100                                 strunzone(race_penaltyreason);
1101                         race_penaltyreason = strzone(ReadString());
1102                         break;
1103
1104                 case RACE_NET_SERVER_RECORD:
1105                         race_server_record = ReadInt24_t();
1106                         break;
1107                 case RACE_NET_SPEED_AWARD:
1108                         race_speedaward = ReadInt24_t();
1109                         if(race_speedaward_holder)
1110                                 strunzone(race_speedaward_holder);
1111                         race_speedaward_holder = strzone(ReadString());
1112                         break;
1113                 case RACE_NET_SPEED_AWARD_BEST:
1114                         race_speedaward_alltimebest = ReadInt24_t();
1115                         if(race_speedaward_alltimebest_holder)
1116                                 strunzone(race_speedaward_alltimebest_holder);
1117                         race_speedaward_alltimebest_holder = strzone(ReadString());
1118                         break;
1119                 case RACE_NET_SERVER_RANKINGS:
1120                         float prevpos, del;
1121             int pos = ReadShort();
1122                         prevpos = ReadShort();
1123                         del = ReadShort();
1124
1125                         // move other rankings out of the way
1126             int i;
1127                         if (prevpos) {
1128                                 for (i=prevpos-1;i>pos-1;--i) {
1129                                         grecordtime[i] = grecordtime[i-1];
1130                                         if(grecordholder[i])
1131                                                 strunzone(grecordholder[i]);
1132                                         grecordholder[i] = strzone(grecordholder[i-1]);
1133                                 }
1134                         } else if (del) { // a record has been deleted by the admin
1135                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1136                                         if (i == RANKINGS_CNT-1) { // clear out last record
1137                                                 grecordtime[i] = 0;
1138                                                 if (grecordholder[i])
1139                                                         strunzone(grecordholder[i]);
1140                                                 grecordholder[i] = string_null;
1141                                         }
1142                                         else {
1143                                                 grecordtime[i] = grecordtime[i+1];
1144                                                 if (grecordholder[i])
1145                                                         strunzone(grecordholder[i]);
1146                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1147                                         }
1148                                 }
1149                         } else { // player has no ranked record yet
1150                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1151                                         grecordtime[i] = grecordtime[i-1];
1152                                         if(grecordholder[i])
1153                                                 strunzone(grecordholder[i]);
1154                                         grecordholder[i] = strzone(grecordholder[i-1]);
1155                                 }
1156                         }
1157
1158                         // store new ranking
1159                         if(grecordholder[pos-1] != "")
1160                                 strunzone(grecordholder[pos-1]);
1161                         grecordholder[pos-1] = strzone(ReadString());
1162                         grecordtime[pos-1] = ReadInt24_t();
1163                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1164                                 race_myrank = pos;
1165                         break;
1166                 case RACE_NET_SERVER_STATUS:
1167                         race_status = ReadShort();
1168                         if(race_status_name)
1169                                 strunzone(race_status_name);
1170                         race_status_name = strzone(ReadString());
1171         }
1172 }
1173
1174 void Net_TeamNagger()
1175 {
1176         teamnagger = 1;
1177 }
1178
1179 void Net_ReadPingPLReport()
1180 {
1181         int e, pi, pl, ml;
1182         e = ReadByte();
1183         pi = ReadShort();
1184         pl = ReadByte();
1185         ml = ReadByte();
1186         if (!(playerslots[e]))
1187                 return;
1188         playerslots[e].ping = pi;
1189         playerslots[e].ping_packetloss = pl / 255.0;
1190         playerslots[e].ping_movementloss = ml / 255.0;
1191 }
1192
1193 void Net_WeaponComplain()
1194 {
1195         complain_weapon = ReadByte();
1196
1197         if(complain_weapon_name)
1198                 strunzone(complain_weapon_name);
1199         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1200
1201         complain_weapon_type = ReadByte();
1202
1203         complain_weapon_time = time;
1204         weapontime = time; // ping the weapon panel
1205
1206         switch(complain_weapon_type)
1207         {
1208                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1209                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1210                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1211         }
1212 }
1213
1214 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1215 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1216 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1217 float CSQC_Parse_TempEntity()
1218 {
1219         float bHandled;
1220                 bHandled  = true;
1221         // Acquire TE ID
1222         float nTEID;
1223                 nTEID = ReadByte();
1224
1225         if(autocvar_developer_csqcentities)
1226                 printf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1227
1228                 // NOTE: Could just do return instead of break...
1229         switch(nTEID)
1230         {
1231                 case TE_CSQC_TARGET_MUSIC:
1232                         Net_TargetMusic();
1233                         bHandled = true;
1234                         break;
1235                 case TE_CSQC_PICTURE:
1236                         Net_MapVote_Picture();
1237                         bHandled = true;
1238                         break;
1239                 case TE_CSQC_RACE:
1240                         Net_ReadRace();
1241                         bHandled = true;
1242                         break;
1243                 case TE_CSQC_VORTEXBEAMPARTICLE:
1244                         Net_ReadVortexBeamParticle();
1245                         bHandled = true;
1246                         break;
1247                 case TE_CSQC_TEAMNAGGER:
1248                         Net_TeamNagger();
1249                         bHandled = true;
1250                         break;
1251                 case TE_CSQC_ARC:
1252                         Net_ReadArc();
1253                         bHandled = true;
1254                         break;
1255                 case TE_CSQC_PINGPLREPORT:
1256                         Net_ReadPingPLReport();
1257                         bHandled = true;
1258                         break;
1259                 case TE_CSQC_WEAPONCOMPLAIN:
1260                         Net_WeaponComplain();
1261                         bHandled = true;
1262                         break;
1263                 case TE_CSQC_VEHICLESETUP:
1264                         Net_VehicleSetup();
1265                         bHandled = true;
1266                         break;
1267                 case TE_CSQC_SVNOTICE:
1268                         cl_notice_read();
1269                         bHandled = true;
1270                         break;
1271                 case TE_CSQC_SHOCKWAVEPARTICLE:
1272                         Net_ReadShockwaveParticle();
1273                         bHandled = true;
1274                         break;
1275                 default:
1276                         // No special logic for this temporary entity; return 0 so the engine can handle it
1277                         bHandled = false;
1278                         break;
1279         }
1280
1281         return bHandled;
1282 }
1283
1284 string getcommandkey(string text, string command)
1285 {
1286         string keys;
1287         float n, j, k, l = 0;
1288
1289         if (!autocvar_hud_showbinds)
1290                 return text;
1291
1292         keys = db_get(binddb, command);
1293         if (keys == "")
1294         {
1295                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1296                 for(j = 0; j < n; ++j)
1297                 {
1298                         k = stof(argv(j));
1299                         if(k != -1)
1300                         {
1301                                 if ("" == keys)
1302                                         keys = keynumtostring(k);
1303                                 else
1304                                         keys = strcat(keys, ", ", keynumtostring(k));
1305
1306                                 ++l;
1307                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1308                                         break;
1309                         }
1310
1311                 }
1312                 if (keys == "")
1313                         keys = "NO_KEY";
1314                 db_put(binddb, command, keys);
1315         }
1316
1317         if (keys == "NO_KEY") {
1318                 if (autocvar_hud_showbinds > 1)
1319                         return sprintf(_("%s (not bound)"), text);
1320                 else
1321                         return text;
1322         }
1323         else if (autocvar_hud_showbinds > 1)
1324                 return sprintf("%s (%s)", text, keys);
1325         else
1326                 return keys;
1327 }