qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include "defs.qh"
   4 #include <common/ent_cs.qh>
   5 #include "miscfunctions.qh"
   6 #include <common/effects/effect.qh>
   7 #include <common/effects/qc/_mod.qh>
   8 #include <common/effects/all.qh>
   9 #include <common/effects/all.inc>
  10 #include "hud/_mod.qh"
  11 #include "mapvoting.qh"
  12 #include "mutators/events.qh"
  13 #include "hud/panel/scoreboard.qh"
  14 #include "hud/panel/quickmenu.qh"
  15 #include "shownames.qh"
  16 #include <common/t_items.qh>
  17 #include "wall.qh"
  18 #include "weapons/projectile.qh"
  19 #include <common/deathtypes/all.qh>
  20 #include <common/items/_mod.qh>
  21 #include <common/mapinfo.qh>
  22 #include <common/minigames/cl_minigames.qh>
  23 #include <common/minigames/cl_minigames_hud.qh>
  24 #include <common/net_linked.qh>
  25 #include <common/net_notice.qh>
  26 #include <common/scores.qh>
  27 #include <common/triggers/include.qh>
  28 #include <common/vehicles/all.qh>
  29 #include <lib/csqcmodel/cl_model.qh>
  30 #include <lib/csqcmodel/interpolate.qh>
  31 #include <lib/warpzone/client.qh>
  32
  33 // --------------------------------------------------------------------------
  34 // BEGIN REQUIRED CSQC FUNCTIONS
  35 //include "main.qh"
  36
  37 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  38
  39 void draw_cursor(vector pos, vector ofs, string img, vector col, float a)
  40 {
  41         ofs = vec2(ofs.x * SIZE_CURSOR.x, ofs.y * SIZE_CURSOR.y);
  42         drawpic(pos - ofs, strcat(draw_currentSkin, img), SIZE_CURSOR, col, a, DRAWFLAG_NORMAL);
  43 }
  44
  45 void draw_cursor_normal(vector pos, vector col, float a)
  46 {
  47         draw_cursor(pos, OFFSET_CURSOR, "/cursor", col, a);
  48 }
  49
  50 void LoadMenuSkinValues()
  51 {
  52         int fh = -1;
  53         if(cvar_string("menu_skin") != "")
  54         {
  55                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  56                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  57         }
  58         if(fh < 0 && cvar_defstring("menu_skin") != "")
  59         {
  60                 cvar_set("menu_skin", cvar_defstring("menu_skin"));
  61                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  62                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  63         }
  64         if(fh < 0)
  65         {
  66                 draw_currentSkin = "gfx/menu/default";
  67                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  68         }
  69
  70         draw_currentSkin = strzone(draw_currentSkin);
  71
  72         if(fh >= 0)
  73         {
  74                 string s;
  75                 while((s = fgets(fh)))
  76                 {
  77                         int n = tokenize_console(s);
  78                         if (n < 2)
  79                                 continue;
  80                         if(substring(argv(0), 0, 2) == "//")
  81                                 continue;
  82                         if(argv(0) == "SIZE_CURSOR")
  83                                 SIZE_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  84                         else if(argv(0) == "OFFSET_CURSOR")
  85                                 OFFSET_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  86                 }
  87                 fclose(fh);
  88         }
  89 }
  90
  91 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  92 // Useful for precaching things
  93
  94 void ConsoleCommand_macro_init();
  95 void CSQC_Init()
  96 {
  97         prvm_language = strzone(cvar_string("prvm_language"));
  98
  99 #ifdef WATERMARK
 100         LOG_INFOF("^4CSQC Build information: ^1%s", WATERMARK);
 101 #endif
 102
 103         {
 104                 int i = 0;
 105                 for ( ; i < 255; ++i)
 106                         if (getplayerkeyvalue(i, "viewentity") == "")
 107                                 break;
 108                 maxclients = i;
 109         }
 110
 111         // needs to be done so early because of the constants they create
 112         static_init();
 113         static_init_late();
 114         static_init_precache();
 115
 116         binddb = db_create();
 117         tempdb = db_create();
 118         ClientProgsDB = db_load("client.db");
 119
 120         draw_endBoldFont();
 121
 122         //registercommand("hud_configure");
 123         //registercommand("hud_save");
 124         //registercommand("menu_action");
 125
 126         ConsoleCommand_macro_init();
 127
 128         registercvar("hud_usecsqc", "1");
 129         registercvar("scoreboard_columns", "default");
 130
 131         registercvar("cl_nade_type", "3");
 132         registercvar("cl_pokenade_type", "zombie");
 133
 134         registercvar("cl_jumpspeedcap_min", "");
 135         registercvar("cl_jumpspeedcap_max", "");
 136
 137         registercvar("cl_multijump", "1");
 138
 139         registercvar("cl_spawn_near_teammate", "1");
 140
 141         if(autocvar_cl_lockview)
 142                 cvar_set("cl_lockview", "0");
 143
 144         gametype = NULL;
 145
 146         postinit = false;
 147
 148         calledhooks = 0;
 149
 150         teams = Sort_Spawn();
 151         players = Sort_Spawn();
 152
 153         GetTeam(NUM_SPECTATOR, true); // add specs first
 154
 155         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 156                 weapon_accuracy[w] = -1;
 157
 158         // precaches
 159
 160         if(autocvar_cl_reticle)
 161         {
 162                 precache_pic("gfx/reticle_normal");
 163                 // weapon reticles are precached in weapon files
 164         }
 165
 166         {
 167                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 168                 minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 169                 shortmapname = mi_shortname;
 170
 171                 if (precache_pic(minimapname) == "")
 172                 {
 173                         // but maybe we have a non-clever minimap
 174                         minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 175                         if (precache_pic(minimapname) == "")
 176                                 minimapname = ""; // FAIL
 177                         else
 178                                 get_mi_min_max_texcoords(0); // load new texcoords
 179                 }
 180
 181                 mi_center = (mi_min + mi_max) * 0.5;
 182                 mi_scale = mi_max - mi_min;
 183                 minimapname = strzone(minimapname);
 184         }
 185
 186         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 187         LoadMenuSkinValues();
 188 }
 189
 190 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 191 void Shutdown()
 192 {
 193         WarpZone_Shutdown();
 194
 195         delete(teams);
 196         delete(players);
 197         db_close(binddb);
 198         db_close(tempdb);
 199         if(autocvar_cl_db_saveasdump)
 200                 db_dump(ClientProgsDB, "client.db");
 201         else
 202                 db_save(ClientProgsDB, "client.db");
 203         db_close(ClientProgsDB);
 204
 205         if(camera_active)
 206                 cvar_set("chase_active",ftos(chase_active_backup));
 207
 208         // unset the event chasecam's chase_active
 209         if(autocvar_chase_active < 0)
 210                 cvar_set("chase_active", "0");
 211
 212         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 213
 214         if (!isdemo())
 215         {
 216                 if (!(calledhooks & HOOK_START))
 217                         localcmd("\n_cl_hook_gamestart nop\n");
 218                 if (!(calledhooks & HOOK_END))
 219                         localcmd("\ncl_hook_gameend\n");
 220         }
 221
 222         localcmd("\ncl_hook_shutdown\n");
 223
 224         deactivate_minigame();
 225         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 226 }
 227
 228 .float has_team;
 229 float SetTeam(entity o, int Team)
 230 {
 231     TC(int, Team);
 232         devassert_once(Team);
 233         entity tm;
 234         if(teamplay)
 235         {
 236                 switch(Team)
 237                 {
 238                         case -1:
 239                         case NUM_TEAM_1:
 240                         case NUM_TEAM_2:
 241                         case NUM_TEAM_3:
 242                         case NUM_TEAM_4:
 243                                 break;
 244                         default:
 245                                 if(GetTeam(Team, false) == NULL)
 246                                 {
 247                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 248                                         Team = NUM_SPECTATOR;
 249                                 }
 250                                 break;
 251                 }
 252         }
 253         else
 254         {
 255                 switch(Team)
 256                 {
 257                         case -1:
 258                         case 0:
 259                                 break;
 260                         default:
 261                                 if(GetTeam(Team, false) == NULL)
 262                                 {
 263                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 264                                         Team = NUM_SPECTATOR;
 265                                 }
 266                                 break;
 267                 }
 268         }
 269         if(Team == -1) // leave
 270         {
 271                 if(o.has_team)
 272                 {
 273                         tm = GetTeam(o.team, false);
 274                         tm.team_size -= 1;
 275                         o.has_team = 0;
 276                         return true;
 277                 }
 278         }
 279         else
 280         {
 281                 if (!o.has_team)
 282                 {
 283                         o.team = Team;
 284                         tm = GetTeam(Team, true);
 285                         tm.team_size += 1;
 286                         o.has_team = 1;
 287                         return true;
 288                 }
 289                 else if(Team != o.team)
 290                 {
 291                         tm = GetTeam(o.team, false);
 292                         tm.team_size -= 1;
 293                         o.team = Team;
 294                         tm = GetTeam(Team, true);
 295                         tm.team_size += 1;
 296                         return true;
 297                 }
 298         }
 299         return false;
 300 }
 301
 302 void Playerchecker_Think(entity this)
 303 {
 304     int i;
 305         entity e;
 306         for(i = 0; i < maxclients; ++i)
 307         {
 308                 e = playerslots[i];
 309                 if(entcs_GetName(i) == "")
 310                 {
 311                         if(e.sort_prev)
 312                         {
 313                                 // player disconnected
 314                                 SetTeam(e, -1);
 315                                 RemovePlayer(e);
 316                                 e.sort_prev = NULL;
 317                                 //e.gotscores = 0;
 318                         }
 319                 }
 320                 else
 321                 {
 322                         if (!e.sort_prev)
 323                         {
 324                                 // player connected
 325                                 if (!e)
 326                                 {
 327                                         playerslots[i] = e = new_pure(playerslot);
 328                                 }
 329                                 e.sv_entnum = i;
 330                                 e.ping = 0;
 331                                 e.ping_packetloss = 0;
 332                                 e.ping_movementloss = 0;
 333                                 //e.gotscores = 0; // we might already have the scores...
 334                                 int t = entcs_GetScoreTeam(i);
 335                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 336                                 RegisterPlayer(e);
 337                                 Scoreboard_UpdatePlayerPos(e);
 338                         }
 339                 }
 340         }
 341         this.nextthink = time + 0.2;
 342 }
 343
 344 void TrueAim_Init();
 345 void PostInit()
 346 {
 347         entity playerchecker = new_pure(playerchecker);
 348         setthink(playerchecker, Playerchecker_Think);
 349         playerchecker.nextthink = time + 0.2;
 350
 351         TrueAim_Init();
 352
 353         postinit = true;
 354 }
 355
 356 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 357 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 358 // All keys are in ascii.
 359 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 360 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 361 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 362 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 363 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 364 {
 365     TC(int, bInputType);
 366         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 367                 return true;
 368
 369         if (QuickMenu_InputEvent(bInputType, nPrimary, nSecondary))
 370                 return true;
 371
 372         if (HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary))
 373                 return true;
 374
 375         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 376                 return true;
 377
 378         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
 379                 return true;
 380
 381         return false;
 382 }
 383
 384 // END REQUIRED CSQC FUNCTIONS
 385 // --------------------------------------------------------------------------
 386
 387 // --------------------------------------------------------------------------
 388 // BEGIN OPTIONAL CSQC FUNCTIONS
 389
 390 void Ent_Remove(entity this);
 391
 392 void Ent_RemovePlayerScore(entity this)
 393 {
 394         if(this.owner) {
 395                 SetTeam(this.owner, -1);
 396                 this.owner.gotscores = 0;
 397                 FOREACH(Scores, true, {
 398                         this.owner.(scores(it)) = 0; // clear all scores
 399                 });
 400         }
 401 }
 402
 403 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 404 {
 405         make_pure(this);
 406         entity o;
 407
 408         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 409         // (no I've never heard of M-x replace-string, sed, or anything like that)
 410         bool isNew = !this.owner; // workaround for DP bug
 411         int n = ReadByte()-1;
 412
 413 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 414         if(!isNew && n != this.sv_entnum)
 415         {
 416                 //print("A CSQC entity changed its owner!\n");
 417                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
 418                 isNew = true;
 419                 Ent_Remove(this);
 420         }
 421 #endif
 422
 423         this.sv_entnum = n;
 424
 425         o = playerslots[this.sv_entnum];
 426         if (!o)
 427         {
 428                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 429         }
 430         this.owner = o;
 431         o.sv_entnum = this.sv_entnum;
 432         o.gotscores = 1;
 433
 434         //if (!o.sort_prev)
 435         //      RegisterPlayer(o);
 436         //playerchecker will do this for us later, if it has not already done so
 437
 438     int sf, lf;
 439         sf = ReadShort();
 440         lf = ReadShort();
 441         FOREACH(Scores, true, {
 442         int p = 1 << (i % 16);
 443                 if (sf & p)
 444                 {
 445                         if (lf & p)
 446                                 o.(scores(it)) = ReadInt24_t();
 447                         else
 448                                 o.(scores(it)) = ReadChar();
 449                 }
 450     });
 451
 452         return = true;
 453
 454         if(o.sort_prev)
 455                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 456
 457         this.entremove = Ent_RemovePlayerScore;
 458 }
 459
 460 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 461 {
 462         make_pure(this);
 463         int i;
 464         entity o;
 465
 466         this.team = ReadByte();
 467         o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 468
 469     int sf, lf;
 470 #if MAX_TEAMSCORE <= 8
 471         sf = ReadByte();
 472         lf = ReadByte();
 473 #else
 474         sf = ReadShort();
 475         lf = ReadShort();
 476 #endif
 477         int p;
 478         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 479                 if(sf & p)
 480                 {
 481                         if(lf & p)
 482                                 o.(teamscores(i)) = ReadInt24_t();
 483                         else
 484                                 o.(teamscores(i)) = ReadChar();
 485                 }
 486
 487         return = true;
 488
 489         Scoreboard_UpdateTeamPos(o);
 490 }
 491
 492 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 493 {
 494         make_pure(this);
 495         float newspectatee_status;
 496
 497     int f = ReadByte();
 498
 499         scoreboard_showscores_force = (f & BIT(0));
 500
 501         if(f & BIT(1))
 502         {
 503                 newspectatee_status = ReadByte();
 504                 if(newspectatee_status == player_localnum + 1)
 505                         newspectatee_status = -1; // observing
 506         }
 507         else
 508                 newspectatee_status = 0;
 509
 510         spectatorbutton_zoom = (f & BIT(2));
 511
 512         if(f & BIT(4))
 513         {
 514                 num_spectators = ReadByte();
 515
 516                 float i, slot;
 517
 518                 for(i = 0; i < MAX_SPECTATORS; ++i)
 519                         spectatorlist[i] = 0; // reset list first
 520
 521                 for(i = 0; i < num_spectators; ++i)
 522                 {
 523                         slot = ReadByte();
 524                         spectatorlist[i] = slot - 1;
 525                 }
 526         }
 527
 528         return = true;
 529
 530         if(newspectatee_status != spectatee_status)
 531         {
 532                 // clear race stuff
 533                 race_laptime = 0;
 534                 race_checkpointtime = 0;
 535                 hud_dynamic_shake_factor = -1;
 536         }
 537         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 538         {
 539                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 540                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 541                 )
 542                         prev_p_health = -1;
 543                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 544                         prev_health = -1;
 545         }
 546         spectatee_status = newspectatee_status;
 547
 548         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 549 }
 550
 551 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 552 {
 553         make_pure(this);
 554     int i, j, b, f;
 555
 556     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 557
 558         if(!(nags & BIT(2)))
 559         {
 560                 if(vote_called_vote)
 561                         strunzone(vote_called_vote);
 562                 vote_called_vote = string_null;
 563                 vote_active = 0;
 564         }
 565         else
 566         {
 567                 vote_active = 1;
 568         }
 569
 570         if(nags & BIT(6))
 571         {
 572                 vote_yescount = ReadByte();
 573                 vote_nocount = ReadByte();
 574                 vote_needed = ReadByte();
 575                 vote_highlighted = ReadChar();
 576         }
 577
 578         if(nags & BIT(7))
 579         {
 580                 if(vote_called_vote)
 581                         strunzone(vote_called_vote);
 582                 vote_called_vote = strzone(ReadString());
 583         }
 584
 585         if(nags & 1)
 586         {
 587                 for(j = 0; j < maxclients; ++j)
 588                         if(playerslots[j])
 589                                 playerslots[j].ready = 1;
 590                 for(i = 1; i <= maxclients; i += 8)
 591                 {
 592                         f = ReadByte();
 593                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 594                                 if (!(f & b))
 595                                         if(playerslots[j])
 596                                                 playerslots[j].ready = 0;
 597                 }
 598         }
 599
 600         return = true;
 601
 602         ready_waiting = (nags & BIT(0));
 603         ready_waiting_for_me = (nags & BIT(1));
 604         vote_waiting = (nags & BIT(2));
 605         vote_waiting_for_me = (nags & BIT(3));
 606         warmup_stage = (nags & BIT(4));
 607 }
 608
 609 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 610 {
 611         make_pure(this);
 612     int i, j, b, f;
 613
 614     int sf = ReadByte();
 615         if(sf & 1)
 616         {
 617                 for(j = 0; j < maxclients; ++j)
 618                         if(playerslots[j])
 619                                 playerslots[j].eliminated = 1;
 620                 for(i = 1; i <= maxclients; i += 8)
 621                 {
 622                         f = ReadByte();
 623                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 624                                 if (!(f & b))
 625                                         if(playerslots[j])
 626                                                 playerslots[j].eliminated = 0;
 627                 }
 628         }
 629         return true;
 630 }
 631
 632 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 633 {
 634         make_pure(this);
 635         prandom_debug();
 636         float s = ReadShort();
 637         psrandom(s);
 638         return true;
 639 }
 640
 641 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 642 {
 643         make_pure(this);
 644     int sf = ReadInt24_t();
 645         if (sf == 0) {
 646                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 647                         weapon_accuracy[w] = -1;
 648                 return true;
 649         }
 650
 651         int f = 1;
 652         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 653                 if (sf & f) {
 654             int b = ReadByte();
 655                         if (b == 0)
 656                                 weapon_accuracy[w] = -1;
 657                         else if (b == 255)
 658                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 659                         else
 660                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 661                 }
 662                 f = (f == 0x800000) ? 1 : f * 2;
 663         }
 664         return true;
 665 }
 666
 667 void Spawn_Draw(entity this)
 668 {
 669         if(this.alpha <= 0)
 670                 return;
 671
 672         __pointparticles(this.cnt, this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 673 }
 674
 675 void Spawn_PreDraw(entity this)
 676 {
 677         float alph;
 678         vector org = getpropertyvec(VF_ORIGIN);
 679         if(this.fade_start)
 680         {
 681                 if(vdist(org - this.origin, >, this.fade_end))
 682                         alph = 0; // save on some processing
 683                 else if(vdist(org - this.origin, <, this.fade_start))
 684                         alph = 1; // more processing saved
 685                 else
 686                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 687         }
 688         else
 689                 alph = 1;
 690         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 691         this.alpha = alph;
 692         if(alph <= 0)
 693                 this.drawmask = 0;
 694         else
 695                 this.drawmask = MASK_NORMAL;
 696 }
 697
 698 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 699 {
 700         float teamnum = (ReadByte() - 1);
 701         vector spn_origin;
 702         spn_origin.x = ReadCoord();
 703         spn_origin.y = ReadCoord();
 704         spn_origin.z = ReadCoord();
 705
 706         this.team = (teamnum + 1);
 707
 708         //if(is_new)
 709         //{
 710                 this.origin = spn_origin;
 711                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 712                 //droptofloor();
 713
 714                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 715                 {
 716                         this.mdl = "models/spawnpoint.md3";
 717                         this.colormod = Team_ColorRGB(teamnum);
 718                         precache_model(this.mdl);
 719                         setmodel(this, this.mdl);
 720                         this.drawmask = MASK_NORMAL;
 721                         //this.move_movetype = MOVETYPE_NOCLIP;
 722                         //this.draw = Spawn_Draw;
 723                         IL_PUSH(g_drawables, this);
 724                 }*/
 725                 if(autocvar_cl_spawn_point_particles)
 726                 {
 727                         if(teamplay)
 728                         {
 729                                 switch(teamnum)
 730                                 {
 731                                         case NUM_TEAM_1: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
 732                                         case NUM_TEAM_2: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
 733                                         case NUM_TEAM_3: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
 734                                         case NUM_TEAM_4: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
 735                                         default: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
 736                                 }
 737                         }
 738                         else { this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
 739
 740                         this.draw = Spawn_Draw;
 741                         if (is_new) IL_PUSH(g_drawables, this);
 742                         setpredraw(this, Spawn_PreDraw);
 743                         this.fade_start = autocvar_cl_spawn_point_dist_min;
 744                         this.fade_end = autocvar_cl_spawn_point_dist_max;
 745                 }
 746         //}
 747
 748         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 749         return true;
 750 }
 751
 752 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 753 {
 754         // If entnum is 0, ONLY do the local spawn actions
 755         // this way the server can disable the sending of
 756         // spawn origin or such to clients if wanted.
 757         float entnum = ReadByte();
 758
 759         if(entnum)
 760         {
 761                 this.origin_x = ReadCoord();
 762                 this.origin_y = ReadCoord();
 763                 this.origin_z = ReadCoord();
 764
 765                 if(is_new)
 766                 {
 767                         float teamnum = entcs_GetTeam(entnum - 1);
 768
 769                         if(autocvar_cl_spawn_event_particles)
 770                         {
 771                                 switch(teamnum)
 772                                 {
 773                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 774                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 775                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 776                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 777                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 778                                 }
 779                         }
 780                         if(autocvar_cl_spawn_event_sound)
 781                         {
 782                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 783                         }
 784                 }
 785         }
 786         return = true;
 787
 788         // local spawn actions
 789         if(is_new && (!entnum || (entnum == player_localentnum)))
 790         {
 791                 zoomin_effect = 1;
 792                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 793
 794                 if(autocvar_cl_unpress_zoom_on_spawn)
 795                 {
 796                         localcmd("-zoom\n");
 797                         button_zoom = false;
 798                 }
 799                 HUD_Radar_Hide_Maximized();
 800         }
 801         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 802 }
 803
 804 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 805 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 806 void CSQC_Ent_Update(entity this, bool isnew)
 807 {
 808         this.sourceLoc = __FILE__ ":" STR(__LINE__);
 809         int t = ReadByte();
 810
 811         // set up the "time" global for received entities to be correct for interpolation purposes
 812         float savetime = time;
 813         if(servertime)
 814         {
 815                 time = servertime;
 816         }
 817         else
 818         {
 819                 serverprevtime = time;
 820                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 821                 time = serverprevtime + serverdeltatime;
 822         }
 823
 824 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 825         if (this.enttype)
 826         {
 827                 if (t != this.enttype || isnew)
 828                 {
 829                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
 830                         Ent_Remove(this);
 831                         clearentity(this);
 832                         isnew = true;
 833                 }
 834         }
 835         else
 836         {
 837                 if (!isnew)
 838                 {
 839                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
 840                         isnew = true;
 841                 }
 842         }
 843 #endif
 844         this.enttype = t;
 845         bool done = false;
 846         FOREACH(LinkedEntities, it.m_id == t, {
 847                 if (isnew) this.classname = it.netname;
 848                 if (autocvar_developer_csqcentities)
 849             LOG_INFOF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 850                 done = it.m_read(this, NULL, isnew);
 851                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 852                 break;
 853         });
 854         time = savetime;
 855         if (!done)
 856         {
 857                 LOG_FATALF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 858         }
 859 }
 860
 861 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 862 // used when an entity changes its type. For an entity that someone interacts
 863 // with others, make sure it can no longer do so.
 864 void Ent_Remove(entity this)
 865 {
 866         if(this.entremove) this.entremove(this);
 867
 868         if(this.skeletonindex)
 869         {
 870                 skel_delete(this.skeletonindex);
 871                 this.skeletonindex = 0;
 872         }
 873
 874         if(this.snd_looping > 0)
 875         {
 876                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 877                 this.snd_looping = 0;
 878         }
 879
 880         this.enttype = 0;
 881         this.classname = "";
 882         this.draw = func_null;
 883         this.entremove = func_null;
 884         // TODO possibly set more stuff to defaults
 885 }
 886 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 887 void CSQC_Ent_Remove(entity this)
 888 {
 889         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
 890         if (wasfreed(this))
 891         {
 892                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
 893                 return;
 894         }
 895         if (this.enttype) Ent_Remove(this);
 896         delete(this);
 897 }
 898
 899 void Gamemode_Init()
 900 {
 901         if (!isdemo())
 902         {
 903                 if(!(calledhooks & HOOK_START))
 904                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 905                 calledhooks |= HOOK_START;
 906         }
 907 }
 908 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 909 void CSQC_Parse_StuffCmd(string strMessage)
 910 {
 911         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
 912         localcmd(strMessage);
 913 }
 914 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 915 void CSQC_Parse_Print(string strMessage)
 916 {
 917         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
 918         print(ColorTranslateRGB(strMessage));
 919 }
 920
 921 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 922 void CSQC_Parse_CenterPrint(string strMessage)
 923 {
 924         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
 925         centerprint_hud(strMessage);
 926 }
 927
 928 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
 929 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
 930 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
 931 bool CSQC_Parse_TempEntity()
 932 {
 933         // Acquire TE ID
 934         int nTEID = ReadByte();
 935
 936         FOREACH(TempEntities, it.m_id == nTEID, {
 937                 if (autocvar_developer_csqcentities)
 938                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
 939                 return it.m_read(NULL, NULL, true);
 940         });
 941
 942         if (autocvar_developer_csqcentities)
 943                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
 944
 945         // No special logic for this temporary entity; return 0 so the engine can handle it
 946         return false;
 947 }
 948
 949 string forcefog;
 950 void Fog_Force()
 951 {
 952         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 953                 localcmd("\nr_drawfog 0\n");
 954         else if (forcefog != "")
 955                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
 956 }
 957
 958 void Gamemode_Init();
 959 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
 960 {
 961         make_pure(this);
 962         gametype = ReadRegistered(Gametypes);
 963         teamplay = _MapInfo_GetTeamPlayBool(gametype);
 964         HUD_ModIcons_SetFunc();
 965         FOREACH(Scores, true, {
 966                 if (scores_label(it)) strunzone(scores_label(it));
 967                 scores_label(it) = strzone(ReadString());
 968                 scores_flags(it) = ReadByte();
 969         });
 970         for (int i = 0; i < MAX_TEAMSCORE; ++i)
 971         {
 972                 if (teamscores_label(i)) strunzone(teamscores_label(i));
 973                 teamscores_label(i) = strzone(ReadString());
 974                 teamscores_flags(i) = ReadByte();
 975         }
 976         return = true;
 977         Scoreboard_InitScores();
 978         Gamemode_Init();
 979 }
 980
 981 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
 982 {
 983         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 984
 985         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 986         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 987         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 988         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 989         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 990         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 991         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 992         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 993
 994         if (forcefog) strunzone(forcefog);
 995         forcefog = strzone(ReadString());
 996
 997         armorblockpercent = ReadByte() / 255.0;
 998         damagepush_speedfactor = ReadByte() / 255.0;
 999
1000         serverflags = ReadByte();
1001
1002         g_trueaim_minrange = ReadCoord();
1003
1004         return = true;
1005
1006         MUTATOR_CALLHOOK(Ent_Init);
1007
1008         if (!postinit) PostInit();
1009 }
1010
1011 float GetSpeedUnitFactor(int speed_unit)
1012 {
1013         switch(speed_unit)
1014         {
1015                 default:
1016                 case 1:
1017                         return 1.0;
1018                 case 2:
1019                         return 0.0254;
1020                 case 3:
1021                         return 0.0254 * 3.6;
1022                 case 4:
1023                         return 0.0254 * 3.6 * 0.6213711922;
1024                 case 5:
1025                         return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1026         }
1027 }
1028
1029 string GetSpeedUnit(int speed_unit)
1030 {
1031         switch(speed_unit)
1032         {
1033                 default:
1034                 case 1:
1035                         return _(" qu/s");
1036                 case 2:
1037                         return _(" m/s");
1038                 case 3:
1039                         return _(" km/h");
1040                 case 4:
1041                         return _(" mph");
1042                 case 5:
1043                         return _(" knots");
1044         }
1045 }
1046
1047 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1048 {
1049         int b = ReadByte();
1050
1051         switch (b)
1052         {
1053                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1054                         race_checkpoint = ReadByte();
1055                         race_time = ReadInt24_t();
1056                         race_previousbesttime = ReadInt24_t();
1057                         race_mypreviousbesttime = ReadInt24_t();
1058                         if(race_previousbestname)
1059                                 strunzone(race_previousbestname);
1060                         string pbestname = ReadString();
1061                         if(autocvar_cl_race_cptimes_onlyself)
1062                         {
1063                                 race_previousbesttime = race_mypreviousbesttime;
1064                                 race_mypreviousbesttime = 0;
1065                                 race_previousbestname = strzone("");
1066                         }
1067                         else
1068                                 race_previousbestname = strzone(pbestname);
1069
1070                         race_checkpointtime = time;
1071
1072                         if(race_checkpoint == 0 || race_checkpoint == 254)
1073                         {
1074                                 race_penaltyaccumulator = 0;
1075                                 race_laptime = time; // valid
1076                         }
1077                         break;
1078
1079                 case RACE_NET_CHECKPOINT_CLEAR:
1080                         race_laptime = 0;
1081                         race_checkpointtime = 0;
1082                         break;
1083
1084                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1085                         race_laptime = ReadCoord();
1086                         race_checkpointtime = -99999;
1087                         // fall through
1088                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1089                         race_nextcheckpoint = ReadByte();
1090
1091                         race_nextbesttime = ReadInt24_t();
1092                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1093                                 race_mybesttime = ReadInt24_t();
1094                         if(race_nextbestname)
1095                                 strunzone(race_nextbestname);
1096                         string newname = ReadString();
1097                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1098                         {
1099                                 race_nextbesttime = race_mybesttime;
1100                                 race_mybesttime = 0;
1101                                 race_nextbestname = strzone("");
1102                         }
1103                         else
1104                                 race_nextbestname = strzone(newname);
1105                         break;
1106
1107                 case RACE_NET_CHECKPOINT_HIT_RACE:
1108                         race_mycheckpoint = ReadByte();
1109                         race_mycheckpointtime = time;
1110                         race_mycheckpointdelta = ReadInt24_t();
1111                         race_mycheckpointlapsdelta = ReadByte();
1112                         if(race_mycheckpointlapsdelta >= 128)
1113                                 race_mycheckpointlapsdelta -= 256;
1114                         if(race_mycheckpointenemy)
1115                                 strunzone(race_mycheckpointenemy);
1116                         int who = ReadByte();
1117                         if(who)
1118                                 race_mycheckpointenemy = strzone(entcs_GetName(who - 1));
1119                         else
1120                                 race_mycheckpointenemy = strzone(""); // TODO: maybe string_null works fine here?
1121                         break;
1122
1123                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1124                         race_othercheckpoint = ReadByte();
1125                         race_othercheckpointtime = time;
1126                         race_othercheckpointdelta = ReadInt24_t();
1127                         race_othercheckpointlapsdelta = ReadByte();
1128                         if(race_othercheckpointlapsdelta >= 128)
1129                                 race_othercheckpointlapsdelta -= 256;
1130                         if(race_othercheckpointenemy)
1131                                 strunzone(race_othercheckpointenemy);
1132                         int what = ReadByte();
1133                         if(what)
1134                                 race_othercheckpointenemy = strzone(entcs_GetName(what - 1));
1135                         else
1136                                 race_othercheckpointenemy = strzone(""); // TODO: maybe string_null works fine here?
1137                         break;
1138
1139                 case RACE_NET_PENALTY_RACE:
1140                         race_penaltyeventtime = time;
1141                         race_penaltytime = ReadShort();
1142                         //race_penaltyaccumulator += race_penaltytime;
1143                         if(race_penaltyreason)
1144                                 strunzone(race_penaltyreason);
1145                         race_penaltyreason = strzone(ReadString());
1146                         break;
1147
1148                 case RACE_NET_PENALTY_QUALIFYING:
1149                         race_penaltyeventtime = time;
1150                         race_penaltytime = ReadShort();
1151                         race_penaltyaccumulator += race_penaltytime;
1152                         if(race_penaltyreason)
1153                                 strunzone(race_penaltyreason);
1154                         race_penaltyreason = strzone(ReadString());
1155                         break;
1156
1157                 case RACE_NET_SERVER_RECORD:
1158                         race_server_record = ReadInt24_t();
1159                         break;
1160                 case RACE_NET_SPEED_AWARD:
1161                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1162                         if(race_speedaward_holder)
1163                                 strunzone(race_speedaward_holder);
1164                         race_speedaward_holder = strzone(ReadString());
1165                         if(race_speedaward_unit)
1166                                 strunzone(race_speedaward_unit);
1167                         race_speedaward_unit = strzone(GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1168                         break;
1169                 case RACE_NET_SPEED_AWARD_BEST:
1170                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1171                         if(race_speedaward_alltimebest_holder)
1172                                 strunzone(race_speedaward_alltimebest_holder);
1173                         race_speedaward_alltimebest_holder = strzone(ReadString());
1174                         if(race_speedaward_alltimebest_unit)
1175                                 strunzone(race_speedaward_alltimebest_unit);
1176                         race_speedaward_alltimebest_unit = strzone(GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1177                         break;
1178                 case RACE_NET_SERVER_RANKINGS:
1179                         float prevpos, del;
1180             int pos = ReadShort();
1181                         prevpos = ReadShort();
1182                         del = ReadShort();
1183
1184                         // move other rankings out of the way
1185             int i;
1186                         if (prevpos) {
1187                                 for (i=prevpos-1;i>pos-1;--i) {
1188                                         grecordtime[i] = grecordtime[i-1];
1189                                         if(grecordholder[i])
1190                                                 strunzone(grecordholder[i]);
1191                                         grecordholder[i] = strzone(grecordholder[i-1]);
1192                                 }
1193                         } else if (del) { // a record has been deleted by the admin
1194                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1195                                         if (i == RANKINGS_CNT-1) { // clear out last record
1196                                                 grecordtime[i] = 0;
1197                                                 if (grecordholder[i])
1198                                                         strunzone(grecordholder[i]);
1199                                                 grecordholder[i] = string_null;
1200                                         }
1201                                         else {
1202                                                 grecordtime[i] = grecordtime[i+1];
1203                                                 if (grecordholder[i])
1204                                                         strunzone(grecordholder[i]);
1205                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1206                                         }
1207                                 }
1208                         } else { // player has no ranked record yet
1209                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1210                                         grecordtime[i] = grecordtime[i-1];
1211                                         if(grecordholder[i])
1212                                                 strunzone(grecordholder[i]);
1213                                         grecordholder[i] = strzone(grecordholder[i-1]);
1214                                 }
1215                         }
1216
1217                         // store new ranking
1218                         if(grecordholder[pos-1] != "")
1219                                 strunzone(grecordholder[pos-1]);
1220                         grecordholder[pos-1] = strzone(ReadString());
1221                         grecordtime[pos-1] = ReadInt24_t();
1222                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1223                                 race_myrank = pos;
1224                         break;
1225                 case RACE_NET_SERVER_STATUS:
1226                         race_status = ReadShort();
1227                         if(race_status_name)
1228                                 strunzone(race_status_name);
1229                         race_status_name = strzone(ReadString());
1230         }
1231         return true;
1232 }
1233
1234 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1235 {
1236         teamnagger = 1;
1237         return true;
1238 }
1239
1240 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1241 {
1242         int i = ReadByte();
1243         int pi = ReadShort();
1244         int pl = ReadByte();
1245         int ml = ReadByte();
1246         return = true;
1247         entity e = playerslots[i];
1248         if (!e) return;
1249         e.ping = pi;
1250         e.ping_packetloss = pl / 255.0;
1251         e.ping_movementloss = ml / 255.0;
1252 }
1253
1254 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1255 {
1256         complain_weapon = ReadByte();
1257         complain_weapon_type = ReadByte();
1258         return = true;
1259
1260         complain_weapon_time = time;
1261         weapontime = time; // ping the weapon panel
1262
1263         switch(complain_weapon_type)
1264         {
1265                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1266                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1267                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1268         }
1269 }
1270
1271 string _getcommandkey(string cmd_name, string command, bool forcename)
1272 {
1273         string keys;
1274         float n, j, k, l = 0;
1275
1276         if (!autocvar_hud_showbinds)
1277                 return cmd_name;
1278
1279         keys = db_get(binddb, command);
1280         if (keys == "")
1281         {
1282                 bool joy_active = cvar("joy_active");
1283                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1284                 for(j = 0; j < n; ++j)
1285                 {
1286                         k = stof(argv(j));
1287                         if(k != -1)
1288                         {
1289                                 string key = keynumtostring(k);
1290                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1291                                         continue;
1292
1293                                 if (keys == "")
1294                                         keys = key;
1295                                 else
1296                                         keys = strcat(keys, ", ", key);
1297
1298                                 ++l;
1299                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1300                                         break;
1301                         }
1302
1303                 }
1304                 if (keys == "")
1305                         keys = "NO_KEY";
1306                 db_put(binddb, command, keys);
1307         }
1308
1309         if (keys == "NO_KEY") {
1310                 if (autocvar_hud_showbinds > 1)
1311                         return sprintf(_("%s (not bound)"), cmd_name);
1312                 else
1313                         return cmd_name;
1314         }
1315         else if (autocvar_hud_showbinds > 1 || forcename)
1316                 return sprintf("%s (%s)", cmd_name, keys);
1317         else
1318                 return keys;
1319 }