qcsrc/client/main.qc

   1 #include "main.qh"
   2 #include "_all.qh"
   3
   4 #include "casings.qh"
   5 #include "csqcmodel_hooks.qh"
   6 #include "damage.qh"
   7 #include "effects.qh"
   8 #include "gibs.qh"
   9 #include "hook.qh"
  10 #include "hud.qh"
  11 #include "hud_config.qh"
  12 #include "laser.qh"
  13 #include "mapvoting.qh"
  14 #include "modeleffects.qh"
  15 #include "particles.qh"
  16 #include "prandom.qh"
  17 #include "scoreboard.qh"
  18 #include "shownames.qh"
  19 #include "sortlist.qh"
  20 #include "target_music.qh"
  21 #include "tturrets.qh"
  22 #include "tuba.qh"
  23 #include "t_items.qh"
  24 #include "wall.qh"
  25 #include "waypointsprites.qh"
  26
  27 #include "../common/vehicles/unit/bumblebee.qh"
  28 #include "../common/vehicles/cl_vehicles.qh"
  29 #include "../common/vehicles/vehicles.qh"
  30
  31 #include "weapons/projectile.qh"
  32
  33 #include "../common/buffs.qh"
  34 #include "../common/deathtypes.qh"
  35 #include "../common/mapinfo.qh"
  36 #include "../common/monsters/all.qh"
  37 #include "../common/nades.qh"
  38 #include "../common/net_notice.qh"
  39 #include "../common/notifications.qh"
  40 #include "../common/stats.qh"
  41 #include "../common/teams.qh"
  42
  43 #include "../common/items/all.qh"
  44
  45 #include "../common/weapons/all.qh"
  46
  47 #include "../csqcmodellib/cl_model.qh"
  48 #include "../csqcmodellib/interpolate.qh"
  49
  50 #include "../warpzonelib/client.qh"
  51
  52 // --------------------------------------------------------------------------
  53 // BEGIN REQUIRED CSQC FUNCTIONS
  54 //include "main.qh"
  55
  56 entity clearentity_ent;
  57 void clearentity(entity e)
  58 {
  59         if (!clearentity_ent)
  60         {
  61                 clearentity_ent = spawn();
  62                 clearentity_ent.classname = "clearentity";
  63         }
  64         int n = e.entnum;
  65         copyentity(clearentity_ent, e);
  66         e.entnum = n;
  67 }
  68
  69 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  70 void menu_show_error()
  71 {
  72         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  73 }
  74
  75 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  76 // Useful for precaching things
  77
  78 void menu_sub_null()
  79 {
  80 }
  81
  82 string forcefog;
  83 void WaypointSprite_Load();
  84 void ConsoleCommand_macro_init();
  85 void CSQC_Init(void)
  86 {
  87         prvm_language = cvar_string("prvm_language");
  88
  89 #ifdef WATERMARK
  90         dprintf("^4CSQC Build information: ^1%s\n", WATERMARK);
  91 #endif
  92
  93         int i;
  94
  95         binddb = db_create();
  96         tempdb = db_create();
  97         ClientProgsDB = db_load("client.db");
  98         compressShortVector_init();
  99
 100         draw_endBoldFont();
 101         menu_visible = false;
 102         menu_show = menu_show_error;
 103         menu_action = func_null;
 104
 105         for(i = 0; i < 255; ++i)
 106                 if(getplayerkeyvalue(i, "viewentity") == "")
 107                         break;
 108         maxclients = i;
 109
 110         //registercommand("hud_configure");
 111         //registercommand("hud_save");
 112         //registercommand("menu_action");
 113
 114         ConsoleCommand_macro_init();
 115
 116         registercvar("hud_usecsqc", "1");
 117         registercvar("scoreboard_columns", "default");
 118
 119         registercvar("cl_nade_type", "3");
 120         registercvar("cl_pokenade_type", "zombie");
 121
 122         gametype = 0;
 123
 124         // hud_fields uses strunzone on the titles!
 125         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 126                 hud_title[i] = strzone("(null)");
 127
 128         Cmd_HUD_SetFields(0);
 129
 130         postinit = false;
 131
 132         calledhooks = 0;
 133
 134         teams = Sort_Spawn();
 135         players = Sort_Spawn();
 136
 137         GetTeam(NUM_SPECTATOR, true); // add specs first
 138
 139         // needs to be done so early because of the constants they create
 140         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 141         CALL_ACCUMULATED_FUNCTION(RegisterVehicles);
 142         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 143         CALL_ACCUMULATED_FUNCTION(RegisterItems);
 144         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 145         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 146         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 147         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
 148         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 149
 150         WaypointSprite_Load();
 151
 152         // precaches
 153         precache_model("null");
 154         precache_sound("misc/hit.wav");
 155         precache_sound("misc/typehit.wav");
 156
 157         Projectile_Precache();
 158         Hook_Precache();
 159         GibSplash_Precache();
 160         Casings_Precache();
 161         turrets_precache();
 162         Tuba_Precache();
 163         CSQCPlayer_Precache();
 164
 165         if(autocvar_cl_reticle)
 166         {
 167                 precache_pic("gfx/reticle_normal");
 168                 // weapon reticles are precached in weapon files
 169         }
 170
 171         get_mi_min_max_texcoords(1); // try the CLEVER way first
 172         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 173         shortmapname = mi_shortname;
 174
 175         if(precache_pic(minimapname) == "")
 176         {
 177                 // but maybe we have a non-clever minimap
 178                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 179                 if(precache_pic(minimapname) == "")
 180                         minimapname = ""; // FAIL
 181                 else
 182                         get_mi_min_max_texcoords(0); // load new texcoords
 183         }
 184
 185         mi_center = (mi_min + mi_max) * 0.5;
 186         mi_scale = mi_max - mi_min;
 187         minimapname = strzone(minimapname);
 188
 189         WarpZone_Init();
 190
 191         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 192         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 193 }
 194
 195 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 196 void Shutdown(void)
 197 {
 198         WarpZone_Shutdown();
 199
 200         remove(teams);
 201         remove(players);
 202         db_close(binddb);
 203         db_close(tempdb);
 204         if(autocvar_cl_db_saveasdump)
 205                 db_dump(ClientProgsDB, "client.db");
 206         else
 207                 db_save(ClientProgsDB, "client.db");
 208         db_close(ClientProgsDB);
 209
 210         if(camera_active)
 211                 cvar_set("chase_active",ftos(chase_active_backup));
 212
 213         // unset the event chasecam's chase_active
 214         if(autocvar_chase_active < 0)
 215                 cvar_set("chase_active", "0");
 216
 217         if (!isdemo())
 218         {
 219                 if (!(calledhooks & HOOK_START))
 220                         localcmd("\n_cl_hook_gamestart nop\n");
 221                 if (!(calledhooks & HOOK_END))
 222                         localcmd("\ncl_hook_gameend\n");
 223         }
 224 }
 225
 226 .float has_team;
 227 float SetTeam(entity o, int Team)
 228 {
 229         entity tm;
 230         if(teamplay)
 231         {
 232                 switch(Team)
 233                 {
 234                         case -1:
 235                         case NUM_TEAM_1:
 236                         case NUM_TEAM_2:
 237                         case NUM_TEAM_3:
 238                         case NUM_TEAM_4:
 239                                 break;
 240                         default:
 241                                 if(GetTeam(Team, false) == world)
 242                                 {
 243                                         dprintf("trying to switch to unsupported team %d\n", Team);
 244                                         Team = NUM_SPECTATOR;
 245                                 }
 246                                 break;
 247                 }
 248         }
 249         else
 250         {
 251                 switch(Team)
 252                 {
 253                         case -1:
 254                         case 0:
 255                                 break;
 256                         default:
 257                                 if(GetTeam(Team, false) == world)
 258                                 {
 259                                         dprintf("trying to switch to unsupported team %d\n", Team);
 260                                         Team = NUM_SPECTATOR;
 261                                 }
 262                                 break;
 263                 }
 264         }
 265         if(Team == -1) // leave
 266         {
 267                 if(o.has_team)
 268                 {
 269                         tm = GetTeam(o.team, false);
 270                         tm.team_size -= 1;
 271                         o.has_team = 0;
 272                         return true;
 273                 }
 274         }
 275         else
 276         {
 277                 if (!o.has_team)
 278                 {
 279                         o.team = Team;
 280                         tm = GetTeam(Team, true);
 281                         tm.team_size += 1;
 282                         o.has_team = 1;
 283                         return true;
 284                 }
 285                 else if(Team != o.team)
 286                 {
 287                         tm = GetTeam(o.team, false);
 288                         tm.team_size -= 1;
 289                         o.team = Team;
 290                         tm = GetTeam(Team, true);
 291                         tm.team_size += 1;
 292                         return true;
 293                 }
 294         }
 295         return false;
 296 }
 297
 298 void Playerchecker_Think()
 299 {
 300     int i;
 301         entity e;
 302         for(i = 0; i < maxclients; ++i)
 303         {
 304                 e = playerslots[i];
 305                 if(GetPlayerName(i) == "")
 306                 {
 307                         if(e.sort_prev)
 308                         {
 309                                 // player disconnected
 310                                 SetTeam(e, -1);
 311                                 RemovePlayer(e);
 312                                 e.sort_prev = world;
 313                                 //e.gotscores = 0;
 314                         }
 315                 }
 316                 else
 317                 {
 318                         if (!e.sort_prev)
 319                         {
 320                                 // player connected
 321                                 if (!e)
 322                                         playerslots[i] = e = spawn();
 323                                 e.sv_entnum = i;
 324                                 e.ping = 0;
 325                                 e.ping_packetloss = 0;
 326                                 e.ping_movementloss = 0;
 327                                 //e.gotscores = 0; // we might already have the scores...
 328                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 329                                 RegisterPlayer(e);
 330                                 HUD_UpdatePlayerPos(e);
 331                         }
 332                 }
 333         }
 334         self.nextthink = time + 0.2;
 335 }
 336
 337 void Porto_Init();
 338 void TrueAim_Init();
 339 void PostInit(void)
 340 {
 341         entity playerchecker;
 342         playerchecker = spawn();
 343         playerchecker.think = Playerchecker_Think;
 344         playerchecker.nextthink = time + 0.2;
 345
 346         Porto_Init();
 347         TrueAim_Init();
 348
 349         postinit = true;
 350 }
 351
 352 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 353 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 354 // All keys are in ascii.
 355 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 356 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 357 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 358 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 359 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 360 {
 361         float bSkipKey;
 362         bSkipKey = false;
 363
 364         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 365                 return true;
 366
 367         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 368                 return true;
 369
 370         if(menu_visible && menu_action)
 371                 if(menu_action(bInputType, nPrimary, nSecondary))
 372                         return true;
 373
 374         return bSkipKey;
 375 }
 376
 377 // END REQUIRED CSQC FUNCTIONS
 378 // --------------------------------------------------------------------------
 379
 380 // --------------------------------------------------------------------------
 381 // BEGIN OPTIONAL CSQC FUNCTIONS
 382 void Ent_RemoveEntCS()
 383 {
 384         entcs_receiver[self.sv_entnum] = world;
 385 }
 386 void Ent_ReadEntCS()
 387 {
 388     int sf;
 389         InterpolateOrigin_Undo();
 390
 391         self.classname = "entcs_receiver";
 392         sf = ReadByte();
 393
 394         if(sf & 1)
 395                 self.sv_entnum = ReadByte();
 396         if(sf & 2)
 397         {
 398                 self.origin_x = ReadShort();
 399                 self.origin_y = ReadShort();
 400                 self.origin_z = ReadShort();
 401                 setorigin(self, self.origin);
 402         }
 403         if(sf & 4)
 404         {
 405                 self.angles_y = ReadByte() * 360.0 / 256;
 406                 self.angles_x = self.angles_z = 0;
 407         }
 408         if(sf & 8)
 409                 self.healthvalue = ReadByte() * 10;
 410         if(sf & 16)
 411                 self.armorvalue = ReadByte() * 10;
 412
 413         entcs_receiver[self.sv_entnum] = self;
 414         self.entremove = Ent_RemoveEntCS;
 415         self.iflags |= IFLAG_ORIGIN;
 416
 417         InterpolateOrigin_Note();
 418 }
 419
 420 void Ent_Remove();
 421
 422 void Ent_RemovePlayerScore()
 423 {
 424         if(self.owner) {
 425                 SetTeam(self.owner, -1);
 426                 self.owner.gotscores = 0;
 427                 for(int i = 0; i < MAX_SCORE; ++i) {
 428                         self.owner.(scores[i]) = 0; // clear all scores
 429                 }
 430         }
 431 }
 432
 433 void Ent_ReadPlayerScore()
 434 {
 435         int i, n;
 436         bool isNew;
 437         entity o;
 438
 439         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 440         // (no I've never heard of M-x replace-string, sed, or anything like that)
 441         isNew = !self.owner; // workaround for DP bug
 442         n = ReadByte()-1;
 443
 444 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 445         if(!isNew && n != self.sv_entnum)
 446         {
 447                 //print("A CSQC entity changed its owner!\n");
 448                 printf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 449                 isNew = true;
 450                 Ent_Remove();
 451                 self.enttype = ENT_CLIENT_SCORES;
 452         }
 453 #endif
 454
 455         self.sv_entnum = n;
 456
 457         if (!(playerslots[self.sv_entnum]))
 458                 playerslots[self.sv_entnum] = spawn();
 459         o = self.owner = playerslots[self.sv_entnum];
 460         o.sv_entnum = self.sv_entnum;
 461         o.gotscores = 1;
 462
 463         //if (!o.sort_prev)
 464         //      RegisterPlayer(o);
 465         //playerchecker will do this for us later, if it has not already done so
 466
 467     int sf, lf;
 468 #if MAX_SCORE <= 8
 469         sf = ReadByte();
 470         lf = ReadByte();
 471 #else
 472         sf = ReadShort();
 473         lf = ReadShort();
 474 #endif
 475     int p;
 476         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 477                 if(sf & p)
 478                 {
 479                         if(lf & p)
 480                                 o.(scores[i]) = ReadInt24_t();
 481                         else
 482                                 o.(scores[i]) = ReadChar();
 483                 }
 484
 485         if(o.sort_prev)
 486                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 487
 488         self.entremove = Ent_RemovePlayerScore;
 489 }
 490
 491 void Ent_ReadTeamScore()
 492 {
 493         int i;
 494         entity o;
 495
 496         self.team = ReadByte();
 497         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 498
 499     int sf, lf;
 500 #if MAX_TEAMSCORE <= 8
 501         sf = ReadByte();
 502         lf = ReadByte();
 503 #else
 504         sf = ReadShort();
 505         lf = ReadShort();
 506 #endif
 507         int p;
 508         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 509                 if(sf & p)
 510                 {
 511                         if(lf & p)
 512                                 o.(teamscores[i]) = ReadInt24_t();
 513                         else
 514                                 o.(teamscores[i]) = ReadChar();
 515                 }
 516
 517         HUD_UpdateTeamPos(o);
 518 }
 519
 520 void Ent_ClientData()
 521 {
 522         float newspectatee_status;
 523
 524     int f = ReadByte();
 525
 526         scoreboard_showscores_force = (f & 1);
 527
 528         if(f & 2)
 529         {
 530                 newspectatee_status = ReadByte();
 531                 if(newspectatee_status == player_localnum + 1)
 532                         newspectatee_status = -1; // observing
 533         }
 534         else
 535                 newspectatee_status = 0;
 536
 537         spectatorbutton_zoom = (f & 4);
 538
 539         if(f & 8)
 540         {
 541                 angles_held_status = 1;
 542                 angles_held.x = ReadAngle();
 543                 angles_held.y = ReadAngle();
 544                 angles_held.z = 0;
 545         }
 546         else
 547                 angles_held_status = 0;
 548
 549         if(newspectatee_status != spectatee_status)
 550         {
 551                 // clear race stuff
 552                 race_laptime = 0;
 553                 race_checkpointtime = 0;
 554         }
 555         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 556         {
 557                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 558                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 559                 )
 560                         prev_p_health = -1;
 561                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 562                         prev_health = -1;
 563         }
 564         spectatee_status = newspectatee_status;
 565
 566         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 567 }
 568
 569 void Ent_Nagger()
 570 {
 571     int i, j, b, f;
 572
 573     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 574
 575         if(!(nags & 4))
 576         {
 577                 if(vote_called_vote)
 578                         strunzone(vote_called_vote);
 579                 vote_called_vote = string_null;
 580                 vote_active = 0;
 581         }
 582         else
 583         {
 584                 vote_active = 1;
 585         }
 586
 587         if(nags & 64)
 588         {
 589                 vote_yescount = ReadByte();
 590                 vote_nocount = ReadByte();
 591                 vote_needed = ReadByte();
 592                 vote_highlighted = ReadChar();
 593         }
 594
 595         if(nags & 128)
 596         {
 597                 if(vote_called_vote)
 598                         strunzone(vote_called_vote);
 599                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 600         }
 601
 602         if(nags & 1)
 603         {
 604                 for(j = 0; j < maxclients; ++j)
 605                         if(playerslots[j])
 606                                 playerslots[j].ready = 1;
 607                 for(i = 1; i <= maxclients; i += 8)
 608                 {
 609                         f = ReadByte();
 610                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 611                                 if (!(f & b))
 612                                         if(playerslots[j])
 613                                                 playerslots[j].ready = 0;
 614                 }
 615         }
 616
 617         ready_waiting = (nags & 1);
 618         ready_waiting_for_me = (nags & 2);
 619         vote_waiting = (nags & 4);
 620         vote_waiting_for_me = (nags & 8);
 621         warmup_stage = (nags & 16);
 622 }
 623
 624 void Ent_EliminatedPlayers()
 625 {
 626     int i, j, b, f;
 627
 628     int sf = ReadByte();
 629         if(sf & 1)
 630         {
 631                 for(j = 0; j < maxclients; ++j)
 632                         if(playerslots[j])
 633                                 playerslots[j].eliminated = 1;
 634                 for(i = 1; i <= maxclients; i += 8)
 635                 {
 636                         f = ReadByte();
 637                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 638                                 if (!(f & b))
 639                                         if(playerslots[j])
 640                                                 playerslots[j].eliminated = 0;
 641                 }
 642         }
 643 }
 644
 645 void Ent_RandomSeed()
 646 {
 647         float s;
 648         prandom_debug();
 649         s = ReadShort();
 650         psrandom(s);
 651 }
 652
 653 void Ent_ReadAccuracy(void)
 654 {
 655     int f, w;
 656     int sf = ReadInt24_t();
 657         if(sf == 0)
 658         {
 659                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 660                         weapon_accuracy[w] = -1;
 661                 return;
 662         }
 663
 664         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 665         {
 666                 if(sf & f)
 667                 {
 668             int b = ReadByte();
 669                         if(b == 0)
 670                                 weapon_accuracy[w] = -1;
 671                         else if(b == 255)
 672                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 673                         else
 674                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 675                 }
 676                 if(f == 0x800000)
 677                         f = 1;
 678                 else
 679                         f *= 2;
 680         }
 681 }
 682
 683 void Spawn_Draw(void)
 684 {
 685         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 686 }
 687
 688 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 689 {
 690         float teamnum = (ReadByte() - 1);
 691         vector spn_origin;
 692         spn_origin.x = ReadShort();
 693         spn_origin.y = ReadShort();
 694         spn_origin.z = ReadShort();
 695
 696         if(is_new)
 697         {
 698                 self.origin = spn_origin;
 699                 setsize(self, PL_MIN, PL_MAX);
 700                 droptofloor();
 701
 702                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 703                 {
 704                         self.mdl = "models/spawnpoint.md3";
 705                         self.colormod = Team_ColorRGB(teamnum);
 706                         precache_model(self.mdl);
 707                         setmodel(self, self.mdl);
 708                         self.drawmask = MASK_NORMAL;
 709                         //self.movetype = MOVETYPE_NOCLIP;
 710                         //self.draw = Spawn_Draw;
 711                 }*/
 712                 if(autocvar_cl_spawn_point_particles)
 713                 {
 714                         if((serverflags & SERVERFLAG_TEAMPLAY))
 715                         {
 716                                 switch(teamnum)
 717                                 {
 718                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
 719                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
 720                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
 721                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
 722                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
 723                                 }
 724                         }
 725                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
 726
 727                         self.draw = Spawn_Draw;
 728                 }
 729         }
 730
 731         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 732 }
 733
 734 void Ent_ReadSpawnEvent(float is_new)
 735 {
 736         // If entnum is 0, ONLY do the local spawn actions
 737         // this way the server can disable the sending of
 738         // spawn origin or such to clients if wanted.
 739         float entnum = ReadByte();
 740
 741         if(entnum)
 742         {
 743                 self.origin_x = ReadShort();
 744                 self.origin_y = ReadShort();
 745                 self.origin_z = ReadShort();
 746
 747                 if(is_new)
 748                 {
 749                         float teamnum = GetPlayerColor(entnum - 1);
 750
 751                         if(autocvar_cl_spawn_event_particles)
 752                         {
 753                                 switch(teamnum)
 754                                 {
 755                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
 756                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
 757                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
 758                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
 759                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
 760                                 }
 761                         }
 762                         if(autocvar_cl_spawn_event_sound)
 763                         {
 764                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
 765                         }
 766                 }
 767         }
 768
 769         // local spawn actions
 770         if(is_new && (!entnum || (entnum == player_localentnum)))
 771         {
 772                 zoomin_effect = 1;
 773                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 774
 775                 if(autocvar_cl_unpress_zoom_on_spawn)
 776                 {
 777                         localcmd("-zoom\n");
 778                         button_zoom = false;
 779                 }
 780         }
 781
 782         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 783 }
 784
 785 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 786 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 787 void Ent_RadarLink();
 788 void Ent_Init();
 789 void Ent_ScoresInfo();
 790 void CSQC_Ent_Update(float bIsNewEntity)
 791 {
 792         float t;
 793         float savetime;
 794         t = ReadByte();
 795
 796         if(autocvar_developer_csqcentities)
 797                 printf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 798
 799         // set up the "time" global for received entities to be correct for interpolation purposes
 800         savetime = time;
 801         if(servertime)
 802         {
 803                 time = servertime;
 804         }
 805         else
 806         {
 807                 serverprevtime = time;
 808                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 809                 time = serverprevtime + serverdeltatime;
 810         }
 811
 812 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 813         if(self.enttype)
 814         {
 815                 if(t != self.enttype || bIsNewEntity)
 816                 {
 817                         //print("A CSQC entity changed its type!\n");
 818                         printf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 819                         Ent_Remove();
 820                         clearentity(self);
 821                         bIsNewEntity = 1;
 822                 }
 823         }
 824         else
 825         {
 826                 if(!bIsNewEntity)
 827                 {
 828                         printf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 829                         bIsNewEntity = 1;
 830                 }
 831         }
 832 #endif
 833         self.enttype = t;
 834         switch(t)
 835         {
 836                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 837                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 838                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 839                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 840                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 841                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 842                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 843                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
 844                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 845                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 846                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 847                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 848                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 849                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 850                 case ENT_CLIENT_INIT: Ent_Init(); break;
 851                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 852                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 853                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 854                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 855                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 856                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 857                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 858                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 859                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 860                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 861                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 862                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 863                 case ENT_CLIENT_INVENTORY: Inventory_Read(self); break;
 864                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
 865                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 866                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 867                 case ENT_CLIENT_TURRET: ent_turret(); break;
 868                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 869                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 870                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 871                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 872                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 873                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 874                 case ENT_CLIENT_HEALING_ORB: ent_healer(); break;
 875
 876                 default:
 877                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 878                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
 879                         break;
 880         }
 881
 882         time = savetime;
 883 }
 884 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 885 // used when an entity changes its type. For an entity that someone interacts
 886 // with others, make sure it can no longer do so.
 887 void Ent_Remove()
 888 {
 889         if(self.entremove)
 890                 self.entremove();
 891
 892         if(self.skeletonindex)
 893         {
 894                 skel_delete(self.skeletonindex);
 895                 self.skeletonindex = 0;
 896         }
 897
 898         if(self.snd_looping > 0)
 899         {
 900                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 901                 self.snd_looping = 0;
 902         }
 903
 904         self.enttype = 0;
 905         self.classname = "";
 906         self.draw = menu_sub_null;
 907         self.entremove = menu_sub_null;
 908         // TODO possibly set more stuff to defaults
 909 }
 910 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 911 void CSQC_Ent_Remove()
 912 {
 913         if(autocvar_developer_csqcentities)
 914                 printf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 915
 916         if(wasfreed(self))
 917         {
 918                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 919                 return;
 920         }
 921         if(self.enttype)
 922                 Ent_Remove();
 923         remove(self);
 924 }
 925
 926 void Gamemode_Init()
 927 {
 928         if (!isdemo())
 929         {
 930                 if(!(calledhooks & HOOK_START))
 931                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 932                 calledhooks |= HOOK_START;
 933         }
 934 }
 935 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 936 void CSQC_Parse_StuffCmd(string strMessage)
 937 {
 938         if(autocvar_developer_csqcentities)
 939                 printf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 940
 941         localcmd(strMessage);
 942 }
 943 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 944 void CSQC_Parse_Print(string strMessage)
 945 {
 946         if(autocvar_developer_csqcentities)
 947                 printf("CSQC_Parse_Print(\"%s\")\n", strMessage);
 948
 949         print(ColorTranslateRGB(strMessage));
 950 }
 951
 952 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 953 void CSQC_Parse_CenterPrint(string strMessage)
 954 {
 955         if(autocvar_developer_csqcentities)
 956                 printf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 957
 958         centerprint_hud(strMessage);
 959 }
 960
 961 string notranslate_fogcmd1 = "\nfog ";
 962 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 963 void Fog_Force()
 964 {
 965         // TODO somehow thwart prvm_globalset client ...
 966
 967         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 968                 { localcmd("\nr_drawfog 0\n"); }
 969         else if(forcefog != "")
 970                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
 971 }
 972
 973 void Gamemode_Init();
 974 void Ent_ScoresInfo()
 975 {
 976     int i;
 977         self.classname = "ent_client_scores_info";
 978         gametype = ReadInt24_t();
 979         HUD_ModIcons_SetFunc();
 980         for(i = 0; i < MAX_SCORE; ++i)
 981         {
 982                 if(scores_label[i])
 983                         strunzone(scores_label[i]);
 984                 scores_label[i] = strzone(ReadString());
 985                 scores_flags[i] = ReadByte();
 986         }
 987         for(i = 0; i < MAX_TEAMSCORE; ++i)
 988         {
 989                 if(teamscores_label[i])
 990                         strunzone(teamscores_label[i]);
 991                 teamscores_label[i] = strzone(ReadString());
 992                 teamscores_flags[i] = ReadByte();
 993         }
 994         HUD_InitScores();
 995         Gamemode_Init();
 996 }
 997
 998 void Ent_Init()
 999 {
1000         self.classname = "ent_client_init";
1001
1002         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1003
1004         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1005         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1006         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1007         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1008         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1009         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1010         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1011         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1012
1013         if(forcefog)
1014                 strunzone(forcefog);
1015         forcefog = strzone(ReadString());
1016
1017         armorblockpercent = ReadByte() / 255.0;
1018
1019         g_balance_mortar_bouncefactor = ReadCoord();
1020         g_balance_mortar_bouncestop = ReadCoord();
1021         g_balance_electro_secondary_bouncefactor = ReadCoord();
1022         g_balance_electro_secondary_bouncestop = ReadCoord();
1023
1024         vortex_scope = !ReadByte();
1025         rifle_scope = !ReadByte();
1026
1027         serverflags = ReadByte();
1028
1029         minelayer_maxmines = ReadByte();
1030
1031         hagar_maxrockets = ReadByte();
1032
1033         g_trueaim_minrange = ReadCoord();
1034         g_balance_porto_secondary = ReadByte();
1035
1036         if(!postinit)
1037                 PostInit();
1038 }
1039
1040 void Net_ReadRace()
1041 {
1042         float b;
1043
1044         b = ReadByte();
1045
1046         switch(b)
1047         {
1048                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1049                         race_checkpoint = ReadByte();
1050                         race_time = ReadInt24_t();
1051                         race_previousbesttime = ReadInt24_t();
1052                         if(race_previousbestname)
1053                                 strunzone(race_previousbestname);
1054                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1055
1056                         race_checkpointtime = time;
1057
1058                         if(race_checkpoint == 0 || race_checkpoint == 254)
1059                         {
1060                                 race_penaltyaccumulator = 0;
1061                                 race_laptime = time; // valid
1062                         }
1063
1064                         break;
1065
1066                 case RACE_NET_CHECKPOINT_CLEAR:
1067                         race_laptime = 0;
1068                         race_checkpointtime = 0;
1069                         break;
1070
1071                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1072                         race_laptime = ReadCoord();
1073                         race_checkpointtime = -99999;
1074                         // fall through
1075                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1076                         race_nextcheckpoint = ReadByte();
1077
1078                         race_nextbesttime = ReadInt24_t();
1079                         if(race_nextbestname)
1080                                 strunzone(race_nextbestname);
1081                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1082                         break;
1083
1084                 case RACE_NET_CHECKPOINT_HIT_RACE:
1085                         race_mycheckpoint = ReadByte();
1086                         race_mycheckpointtime = time;
1087                         race_mycheckpointdelta = ReadInt24_t();
1088                         race_mycheckpointlapsdelta = ReadByte();
1089                         if(race_mycheckpointlapsdelta >= 128)
1090                                 race_mycheckpointlapsdelta -= 256;
1091                         if(race_mycheckpointenemy)
1092                                 strunzone(race_mycheckpointenemy);
1093                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1094                         break;
1095
1096                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1097                         race_othercheckpoint = ReadByte();
1098                         race_othercheckpointtime = time;
1099                         race_othercheckpointdelta = ReadInt24_t();
1100                         race_othercheckpointlapsdelta = ReadByte();
1101                         if(race_othercheckpointlapsdelta >= 128)
1102                                 race_othercheckpointlapsdelta -= 256;
1103                         if(race_othercheckpointenemy)
1104                                 strunzone(race_othercheckpointenemy);
1105                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1106                         break;
1107
1108                 case RACE_NET_PENALTY_RACE:
1109                         race_penaltyeventtime = time;
1110                         race_penaltytime = ReadShort();
1111                         //race_penaltyaccumulator += race_penaltytime;
1112                         if(race_penaltyreason)
1113                                 strunzone(race_penaltyreason);
1114                         race_penaltyreason = strzone(ReadString());
1115                         break;
1116
1117                 case RACE_NET_PENALTY_QUALIFYING:
1118                         race_penaltyeventtime = time;
1119                         race_penaltytime = ReadShort();
1120                         race_penaltyaccumulator += race_penaltytime;
1121                         if(race_penaltyreason)
1122                                 strunzone(race_penaltyreason);
1123                         race_penaltyreason = strzone(ReadString());
1124                         break;
1125
1126                 case RACE_NET_SERVER_RECORD:
1127                         race_server_record = ReadInt24_t();
1128                         break;
1129                 case RACE_NET_SPEED_AWARD:
1130                         race_speedaward = ReadInt24_t();
1131                         if(race_speedaward_holder)
1132                                 strunzone(race_speedaward_holder);
1133                         race_speedaward_holder = strzone(ReadString());
1134                         break;
1135                 case RACE_NET_SPEED_AWARD_BEST:
1136                         race_speedaward_alltimebest = ReadInt24_t();
1137                         if(race_speedaward_alltimebest_holder)
1138                                 strunzone(race_speedaward_alltimebest_holder);
1139                         race_speedaward_alltimebest_holder = strzone(ReadString());
1140                         break;
1141                 case RACE_NET_SERVER_RANKINGS:
1142                         float prevpos, del;
1143             int pos = ReadShort();
1144                         prevpos = ReadShort();
1145                         del = ReadShort();
1146
1147                         // move other rankings out of the way
1148             int i;
1149                         if (prevpos) {
1150                                 for (i=prevpos-1;i>pos-1;--i) {
1151                                         grecordtime[i] = grecordtime[i-1];
1152                                         if(grecordholder[i])
1153                                                 strunzone(grecordholder[i]);
1154                                         grecordholder[i] = strzone(grecordholder[i-1]);
1155                                 }
1156                         } else if (del) { // a record has been deleted by the admin
1157                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1158                                         if (i == RANKINGS_CNT-1) { // clear out last record
1159                                                 grecordtime[i] = 0;
1160                                                 if (grecordholder[i])
1161                                                         strunzone(grecordholder[i]);
1162                                                 grecordholder[i] = string_null;
1163                                         }
1164                                         else {
1165                                                 grecordtime[i] = grecordtime[i+1];
1166                                                 if (grecordholder[i])
1167                                                         strunzone(grecordholder[i]);
1168                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1169                                         }
1170                                 }
1171                         } else { // player has no ranked record yet
1172                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1173                                         grecordtime[i] = grecordtime[i-1];
1174                                         if(grecordholder[i])
1175                                                 strunzone(grecordholder[i]);
1176                                         grecordholder[i] = strzone(grecordholder[i-1]);
1177                                 }
1178                         }
1179
1180                         // store new ranking
1181                         if(grecordholder[pos-1] != "")
1182                                 strunzone(grecordholder[pos-1]);
1183                         grecordholder[pos-1] = strzone(ReadString());
1184                         grecordtime[pos-1] = ReadInt24_t();
1185                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1186                                 race_myrank = pos;
1187                         break;
1188                 case RACE_NET_SERVER_STATUS:
1189                         race_status = ReadShort();
1190                         if(race_status_name)
1191                                 strunzone(race_status_name);
1192                         race_status_name = strzone(ReadString());
1193         }
1194 }
1195
1196 void Net_TeamNagger()
1197 {
1198         teamnagger = 1;
1199 }
1200
1201 void Net_ReadPingPLReport()
1202 {
1203         int e, pi, pl, ml;
1204         e = ReadByte();
1205         pi = ReadShort();
1206         pl = ReadByte();
1207         ml = ReadByte();
1208         if (!(playerslots[e]))
1209                 return;
1210         playerslots[e].ping = pi;
1211         playerslots[e].ping_packetloss = pl / 255.0;
1212         playerslots[e].ping_movementloss = ml / 255.0;
1213 }
1214
1215 void Net_WeaponComplain()
1216 {
1217         complain_weapon = ReadByte();
1218
1219         if(complain_weapon_name)
1220                 strunzone(complain_weapon_name);
1221         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1222
1223         complain_weapon_type = ReadByte();
1224
1225         complain_weapon_time = time;
1226         weapontime = time; // ping the weapon panel
1227
1228         switch(complain_weapon_type)
1229         {
1230                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1231                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1232                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1233         }
1234 }
1235
1236 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1237 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1238 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1239 float CSQC_Parse_TempEntity()
1240 {
1241         float bHandled;
1242                 bHandled  = true;
1243         // Acquire TE ID
1244         float nTEID;
1245                 nTEID = ReadByte();
1246
1247         if(autocvar_developer_csqcentities)
1248                 printf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1249
1250                 // NOTE: Could just do return instead of break...
1251         switch(nTEID)
1252         {
1253                 case TE_CSQC_TARGET_MUSIC:
1254                         Net_TargetMusic();
1255                         bHandled = true;
1256                         break;
1257                 case TE_CSQC_PICTURE:
1258                         Net_MapVote_Picture();
1259                         bHandled = true;
1260                         break;
1261                 case TE_CSQC_RACE:
1262                         Net_ReadRace();
1263                         bHandled = true;
1264                         break;
1265                 case TE_CSQC_VORTEXBEAMPARTICLE:
1266                         Net_ReadVortexBeamParticle();
1267                         bHandled = true;
1268                         break;
1269                 case TE_CSQC_TEAMNAGGER:
1270                         Net_TeamNagger();
1271                         bHandled = true;
1272                         break;
1273                 case TE_CSQC_ARC:
1274                         Net_ReadArc();
1275                         bHandled = true;
1276                         break;
1277                 case TE_CSQC_PINGPLREPORT:
1278                         Net_ReadPingPLReport();
1279                         bHandled = true;
1280                         break;
1281                 case TE_CSQC_WEAPONCOMPLAIN:
1282                         Net_WeaponComplain();
1283                         bHandled = true;
1284                         break;
1285                 case TE_CSQC_VEHICLESETUP:
1286                         Net_VehicleSetup();
1287                         bHandled = true;
1288                         break;
1289                 case TE_CSQC_SVNOTICE:
1290                         cl_notice_read();
1291                         bHandled = true;
1292                         break;
1293                 case TE_CSQC_SHOCKWAVEPARTICLE:
1294                         Net_ReadShockwaveParticle();
1295                         bHandled = true;
1296                         break;
1297                 default:
1298                         // No special logic for this temporary entity; return 0 so the engine can handle it
1299                         bHandled = false;
1300                         break;
1301         }
1302
1303         return bHandled;
1304 }
1305
1306 string getcommandkey(string text, string command)
1307 {
1308         string keys;
1309         float n, j, k, l = 0;
1310
1311         if (!autocvar_hud_showbinds)
1312                 return text;
1313
1314         keys = db_get(binddb, command);
1315         if (keys == "")
1316         {
1317                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1318                 for(j = 0; j < n; ++j)
1319                 {
1320                         k = stof(argv(j));
1321                         if(k != -1)
1322                         {
1323                                 if ("" == keys)
1324                                         keys = keynumtostring(k);
1325                                 else
1326                                         keys = strcat(keys, ", ", keynumtostring(k));
1327
1328                                 ++l;
1329                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1330                                         break;
1331                         }
1332
1333                 }
1334                 if (keys == "")
1335                         keys = "NO_KEY";
1336                 db_put(binddb, command, keys);
1337         }
1338
1339         if (keys == "NO_KEY") {
1340                 if (autocvar_hud_showbinds > 1)
1341                         return sprintf(_("%s (not bound)"), text);
1342                 else
1343                         return text;
1344         }
1345         else if (autocvar_hud_showbinds > 1)
1346                 return sprintf("%s (%s)", text, keys);
1347         else
1348                 return keys;
1349 }