qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include "defs.qh"
   4 #include <common/ent_cs.qh>
   5 #include "miscfunctions.qh"
   6 #include <common/effects/effect.qh>
   7 #include <common/effects/qc/_mod.qh>
   8 #include <common/effects/all.qh>
   9 #include <common/effects/all.inc>
  10 #include "hud/_mod.qh"
  11 #include "mapvoting.qh"
  12 #include "mutators/events.qh"
  13 #include "hud/panel/scoreboard.qh"
  14 #include "hud/panel/quickmenu.qh"
  15 #include "shownames.qh"
  16 #include <common/t_items.qh>
  17 #include "wall.qh"
  18 #include "weapons/projectile.qh"
  19 #include <common/deathtypes/all.qh>
  20 #include <common/items/_mod.qh>
  21 #include <common/mapinfo.qh>
  22 #include <common/minigames/cl_minigames.qh>
  23 #include <common/minigames/cl_minigames_hud.qh>
  24 #include <common/net_linked.qh>
  25 #include <common/net_notice.qh>
  26 #include <common/scores.qh>
  27 #include <common/triggers/include.qh>
  28 #include <common/vehicles/all.qh>
  29 #include <lib/csqcmodel/cl_model.qh>
  30 #include <lib/csqcmodel/interpolate.qh>
  31 #include <lib/warpzone/client.qh>
  32
  33 // --------------------------------------------------------------------------
  34 // BEGIN REQUIRED CSQC FUNCTIONS
  35 //include "main.qh"
  36
  37 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  38
  39 void draw_cursor(vector pos, vector ofs, string img, vector col, float a)
  40 {
  41         ofs = vec2(ofs.x * SIZE_CURSOR.x, ofs.y * SIZE_CURSOR.y);
  42         drawpic(pos - ofs, strcat(draw_currentSkin, img), SIZE_CURSOR, col, a, DRAWFLAG_NORMAL);
  43 }
  44
  45 void draw_cursor_normal(vector pos, vector col, float a)
  46 {
  47         draw_cursor(pos, OFFSET_CURSOR, "/cursor", col, a);
  48 }
  49
  50 void LoadMenuSkinValues()
  51 {
  52         int fh = -1;
  53         if(cvar_string("menu_skin") != "")
  54         {
  55                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  56                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  57         }
  58         if(fh < 0 && cvar_defstring("menu_skin") != "")
  59         {
  60                 cvar_set("menu_skin", cvar_defstring("menu_skin"));
  61                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  62                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  63         }
  64         if(fh < 0)
  65         {
  66                 draw_currentSkin = "gfx/menu/default";
  67                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  68         }
  69
  70         draw_currentSkin = strzone(draw_currentSkin);
  71
  72         if(fh >= 0)
  73         {
  74                 string s;
  75                 while((s = fgets(fh)))
  76                 {
  77                         int n = tokenize_console(s);
  78                         if (n < 2)
  79                                 continue;
  80                         if(substring(argv(0), 0, 2) == "//")
  81                                 continue;
  82                         if(argv(0) == "SIZE_CURSOR")
  83                                 SIZE_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  84                         else if(argv(0) == "OFFSET_CURSOR")
  85                                 OFFSET_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  86                 }
  87                 fclose(fh);
  88         }
  89 }
  90
  91 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  92 // Useful for precaching things
  93
  94 void ConsoleCommand_macro_init();
  95 void CSQC_Init()
  96 {
  97         prvm_language = strzone(cvar_string("prvm_language"));
  98
  99 #ifdef WATERMARK
 100         LOG_INFOF("^4CSQC Build information: ^1%s", WATERMARK);
 101 #endif
 102
 103         {
 104                 int i = 0;
 105                 for ( ; i < 255; ++i)
 106                         if (getplayerkeyvalue(i, "viewentity") == "")
 107                                 break;
 108                 maxclients = i;
 109         }
 110
 111         // needs to be done so early because of the constants they create
 112         static_init();
 113         static_init_late();
 114         static_init_precache();
 115
 116         binddb = db_create();
 117         tempdb = db_create();
 118         ClientProgsDB = db_load("client.db");
 119
 120         draw_endBoldFont();
 121
 122         //registercommand("hud_configure");
 123         //registercommand("hud_save");
 124         //registercommand("menu_action");
 125
 126         ConsoleCommand_macro_init();
 127
 128         registercvar("hud_usecsqc", "1");
 129         registercvar("scoreboard_columns", "default");
 130
 131         registercvar("cl_nade_type", "3");
 132         registercvar("cl_pokenade_type", "zombie");
 133
 134         registercvar("cl_jumpspeedcap_min", "");
 135         registercvar("cl_jumpspeedcap_max", "");
 136
 137         registercvar("cl_multijump", "1");
 138
 139         registercvar("cl_spawn_near_teammate", "1");
 140
 141         if(autocvar_cl_lockview)
 142                 cvar_set("cl_lockview", "0");
 143
 144         gametype = NULL;
 145
 146         postinit = false;
 147
 148         calledhooks = 0;
 149
 150         teams = Sort_Spawn();
 151         players = Sort_Spawn();
 152
 153         GetTeam(NUM_SPECTATOR, true); // add specs first
 154
 155         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 156                 weapon_accuracy[w] = -1;
 157
 158         // precaches
 159
 160         if(autocvar_cl_reticle)
 161         {
 162                 precache_pic("gfx/reticle_normal");
 163                 // weapon reticles are precached in weapon files
 164         }
 165
 166         {
 167                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 168                 minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 169                 shortmapname = mi_shortname;
 170
 171                 if (precache_pic(minimapname) == "")
 172                 {
 173                         // but maybe we have a non-clever minimap
 174                         minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 175                         if (precache_pic(minimapname) == "")
 176                                 minimapname = ""; // FAIL
 177                         else
 178                                 get_mi_min_max_texcoords(0); // load new texcoords
 179                 }
 180
 181                 mi_center = (mi_min + mi_max) * 0.5;
 182                 mi_scale = mi_max - mi_min;
 183                 minimapname = strzone(minimapname);
 184         }
 185
 186         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 187         LoadMenuSkinValues();
 188 }
 189
 190 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 191 void Shutdown()
 192 {
 193         WarpZone_Shutdown();
 194
 195         delete(teams);
 196         delete(players);
 197         db_close(binddb);
 198         db_close(tempdb);
 199         if(autocvar_cl_db_saveasdump)
 200                 db_dump(ClientProgsDB, "client.db");
 201         else
 202                 db_save(ClientProgsDB, "client.db");
 203         db_close(ClientProgsDB);
 204
 205         if(camera_active)
 206                 cvar_set("chase_active",ftos(chase_active_backup));
 207
 208         // unset the event chasecam's chase_active
 209         if(autocvar_chase_active < 0)
 210                 cvar_set("chase_active", "0");
 211
 212         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 213
 214         if (!isdemo())
 215         {
 216                 if (!(calledhooks & HOOK_START))
 217                         localcmd("\n_cl_hook_gamestart nop\n");
 218                 if (!(calledhooks & HOOK_END))
 219                         localcmd("\ncl_hook_gameend\n");
 220         }
 221
 222         localcmd("\ncl_hook_shutdown\n");
 223
 224         deactivate_minigame();
 225         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 226 }
 227
 228 .float has_team;
 229 float SetTeam(entity o, int Team)
 230 {
 231     TC(int, Team);
 232         devassert_once(Team);
 233         entity tm;
 234         if(teamplay)
 235         {
 236                 switch(Team)
 237                 {
 238                         case -1:
 239                         case NUM_TEAM_1:
 240                         case NUM_TEAM_2:
 241                         case NUM_TEAM_3:
 242                         case NUM_TEAM_4:
 243                                 break;
 244                         default:
 245                                 if(GetTeam(Team, false) == NULL)
 246                                 {
 247                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 248                                         Team = NUM_SPECTATOR;
 249                                 }
 250                                 break;
 251                 }
 252         }
 253         else
 254         {
 255                 switch(Team)
 256                 {
 257                         case -1:
 258                         case 0:
 259                                 break;
 260                         default:
 261                                 if(GetTeam(Team, false) == NULL)
 262                                 {
 263                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 264                                         Team = NUM_SPECTATOR;
 265                                 }
 266                                 break;
 267                 }
 268         }
 269         if(Team == -1) // leave
 270         {
 271                 if(o.has_team)
 272                 {
 273                         tm = GetTeam(o.team, false);
 274                         tm.team_size -= 1;
 275                         o.has_team = 0;
 276                         return true;
 277                 }
 278         }
 279         else
 280         {
 281                 if (!o.has_team)
 282                 {
 283                         o.team = Team;
 284                         tm = GetTeam(Team, true);
 285                         tm.team_size += 1;
 286                         o.has_team = 1;
 287                         return true;
 288                 }
 289                 else if(Team != o.team)
 290                 {
 291                         tm = GetTeam(o.team, false);
 292                         tm.team_size -= 1;
 293                         o.team = Team;
 294                         tm = GetTeam(Team, true);
 295                         tm.team_size += 1;
 296                         return true;
 297                 }
 298         }
 299         return false;
 300 }
 301
 302 void Playerchecker_Think(entity this)
 303 {
 304     int i;
 305         entity e;
 306         for(i = 0; i < maxclients; ++i)
 307         {
 308                 e = playerslots[i];
 309                 if(entcs_GetName(i) == "")
 310                 {
 311                         if(e.sort_prev)
 312                         {
 313                                 // player disconnected
 314                                 SetTeam(e, -1);
 315                                 RemovePlayer(e);
 316                                 e.sort_prev = NULL;
 317                                 //e.gotscores = 0;
 318                         }
 319                 }
 320                 else
 321                 {
 322                         if (!e.sort_prev)
 323                         {
 324                                 // player connected
 325                                 if (!e)
 326                                 {
 327                                         playerslots[i] = e = new_pure(playerslot);
 328                                 }
 329                                 e.sv_entnum = i;
 330                                 e.ping = 0;
 331                                 e.ping_packetloss = 0;
 332                                 e.ping_movementloss = 0;
 333                                 //e.gotscores = 0; // we might already have the scores...
 334                                 int t = entcs_GetScoreTeam(i);
 335                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 336                                 RegisterPlayer(e);
 337                                 Scoreboard_UpdatePlayerPos(e);
 338                         }
 339                 }
 340         }
 341         this.nextthink = time + 0.2;
 342 }
 343
 344 void TrueAim_Init();
 345 void PostInit()
 346 {
 347         entity playerchecker = new_pure(playerchecker);
 348         setthink(playerchecker, Playerchecker_Think);
 349         playerchecker.nextthink = time + 0.2;
 350
 351         TrueAim_Init();
 352
 353         postinit = true;
 354 }
 355
 356 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 357 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 358 // All keys are in ascii.
 359 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 360 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 361 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 362 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 363 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 364 {
 365     TC(int, bInputType);
 366         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 367                 return true;
 368
 369         if (QuickMenu_InputEvent(bInputType, nPrimary, nSecondary))
 370                 return true;
 371
 372         if (HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary))
 373                 return true;
 374
 375         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 376                 return true;
 377
 378         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
 379                 return true;
 380
 381         return false;
 382 }
 383
 384 // END REQUIRED CSQC FUNCTIONS
 385 // --------------------------------------------------------------------------
 386
 387 // --------------------------------------------------------------------------
 388 // BEGIN OPTIONAL CSQC FUNCTIONS
 389
 390 void Ent_Remove(entity this);
 391
 392 void Ent_RemovePlayerScore(entity this)
 393 {
 394         if(this.owner) {
 395                 SetTeam(this.owner, -1);
 396                 this.owner.gotscores = 0;
 397                 FOREACH(Scores, true, {
 398                         this.owner.(scores(it)) = 0; // clear all scores
 399                 });
 400         }
 401 }
 402
 403 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 404 {
 405         make_pure(this);
 406         entity o;
 407
 408         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 409         // (no I've never heard of M-x replace-string, sed, or anything like that)
 410         bool isNew = !this.owner; // workaround for DP bug
 411         int n = ReadByte()-1;
 412
 413 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 414         if(!isNew && n != this.sv_entnum)
 415         {
 416                 //print("A CSQC entity changed its owner!\n");
 417                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
 418                 isNew = true;
 419                 Ent_Remove(this);
 420         }
 421 #endif
 422
 423         this.sv_entnum = n;
 424
 425         o = playerslots[this.sv_entnum];
 426         if (!o)
 427         {
 428                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 429         }
 430         this.owner = o;
 431         o.sv_entnum = this.sv_entnum;
 432         o.gotscores = 1;
 433
 434         //if (!o.sort_prev)
 435         //      RegisterPlayer(o);
 436         //playerchecker will do this for us later, if it has not already done so
 437
 438         int sf = ReadShort();
 439         int lf = ReadShort();
 440         FOREACH(Scores, true, {
 441                 int p = 1 << (i % 16);
 442                 if (sf & p)
 443                 {
 444                         if (lf & p)
 445                                 o.(scores(it)) = ReadInt24_t();
 446                         else
 447                                 o.(scores(it)) = ReadChar();
 448                 }
 449         });
 450
 451         return = true;
 452
 453         if(o.sort_prev)
 454                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 455
 456         this.entremove = Ent_RemovePlayerScore;
 457 }
 458
 459 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 460 {
 461         make_pure(this);
 462         int i;
 463
 464         this.team = ReadByte();
 465         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 466
 467 #if MAX_TEAMSCORE <= 8
 468         int sf = ReadByte();
 469         int lf = ReadByte();
 470 #else
 471         int sf = ReadShort();
 472         int lf = ReadShort();
 473 #endif
 474         for(i = 0; i < MAX_TEAMSCORE; ++i)
 475                 if(sf & BIT(i))
 476                 {
 477                         if(lf & BIT(i))
 478                                 o.(teamscores(i)) = ReadInt24_t();
 479                         else
 480                                 o.(teamscores(i)) = ReadChar();
 481                 }
 482
 483         return = true;
 484
 485         Scoreboard_UpdateTeamPos(o);
 486 }
 487
 488 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 489 {
 490         make_pure(this);
 491         float newspectatee_status;
 492
 493         int f = ReadByte();
 494
 495         scoreboard_showscores_force = (f & BIT(0));
 496
 497         if(f & BIT(1))
 498         {
 499                 newspectatee_status = ReadByte();
 500                 if(newspectatee_status == player_localnum + 1)
 501                         newspectatee_status = -1; // observing
 502         }
 503         else
 504                 newspectatee_status = 0;
 505
 506         spectatorbutton_zoom = (f & BIT(2));
 507
 508         if(f & BIT(4))
 509         {
 510                 num_spectators = ReadByte();
 511
 512                 float i, slot;
 513
 514                 for(i = 0; i < MAX_SPECTATORS; ++i)
 515                         spectatorlist[i] = 0; // reset list first
 516
 517                 for(i = 0; i < num_spectators; ++i)
 518                 {
 519                         slot = ReadByte();
 520                         spectatorlist[i] = slot - 1;
 521                 }
 522         }
 523
 524         return = true;
 525
 526         if(newspectatee_status != spectatee_status)
 527         {
 528                 // clear race stuff
 529                 race_laptime = 0;
 530                 race_checkpointtime = 0;
 531                 hud_dynamic_shake_factor = -1;
 532         }
 533         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 534         {
 535                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 536                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 537                 )
 538                         prev_p_health = -1;
 539                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 540                         prev_health = -1;
 541         }
 542         spectatee_status = newspectatee_status;
 543
 544         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 545 }
 546
 547 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 548 {
 549         make_pure(this);
 550         int i, j, b, f;
 551
 552         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 553
 554         if(!(nags & BIT(2)))
 555         {
 556                 if(vote_called_vote)
 557                         strunzone(vote_called_vote);
 558                 vote_called_vote = string_null;
 559                 vote_active = 0;
 560         }
 561         else
 562         {
 563                 vote_active = 1;
 564         }
 565
 566         if(nags & BIT(6))
 567         {
 568                 vote_yescount = ReadByte();
 569                 vote_nocount = ReadByte();
 570                 vote_needed = ReadByte();
 571                 vote_highlighted = ReadChar();
 572         }
 573
 574         if(nags & BIT(7))
 575         {
 576                 if(vote_called_vote)
 577                         strunzone(vote_called_vote);
 578                 vote_called_vote = strzone(ReadString());
 579         }
 580
 581         if(nags & 1)
 582         {
 583                 for(j = 0; j < maxclients; ++j)
 584                         if(playerslots[j])
 585                                 playerslots[j].ready = 1;
 586                 for(i = 1; i <= maxclients; i += 8)
 587                 {
 588                         f = ReadByte();
 589                         for(j = i-1, b = BIT(0); b < BIT(8); b <<= 1, ++j)
 590                                 if (!(f & b))
 591                                         if(playerslots[j])
 592                                                 playerslots[j].ready = 0;
 593                 }
 594         }
 595
 596         return = true;
 597
 598         ready_waiting = (nags & BIT(0));
 599         ready_waiting_for_me = (nags & BIT(1));
 600         vote_waiting = (nags & BIT(2));
 601         vote_waiting_for_me = (nags & BIT(3));
 602         warmup_stage = (nags & BIT(4));
 603 }
 604
 605 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 606 {
 607         make_pure(this);
 608         int sf = 0;
 609         serialize(byte, 0, sf);
 610         if (sf & 1) {
 611                 for (int j = 0; j < maxclients; ++j) {
 612                         if (playerslots[j]) {
 613                                 playerslots[j].eliminated = 1;
 614                         }
 615                 }
 616                 for (int i = 1; i <= maxclients; i += 8) {
 617                         int f = 0;
 618                         serialize(byte, 0, f);
 619                         for (int b = 0; b < 8; ++b) {
 620                                 if (f & BIT(b)) continue;
 621                                 int j = i - 1 + b;
 622                                 if (playerslots[j]) {
 623                                         playerslots[j].eliminated = 0;
 624                                 }
 625                         }
 626                 }
 627         }
 628         return true;
 629 }
 630
 631 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 632 {
 633         make_pure(this);
 634         prandom_debug();
 635         float s = ReadShort();
 636         psrandom(s);
 637         return true;
 638 }
 639
 640 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 641 {
 642         make_pure(this);
 643         int sf = ReadInt24_t();
 644         if (sf == 0) {
 645                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 646                         weapon_accuracy[w] = -1;
 647                 return true;
 648         }
 649
 650         int f = 1;
 651         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 652                 if (sf & f) {
 653                         int b = ReadByte();
 654                         if (b == 0)
 655                                 weapon_accuracy[w] = -1;
 656                         else if (b == 255)
 657                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 658                         else
 659                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 660                 }
 661                 f = (f == 0x800000) ? 1 : f * 2;
 662         }
 663         return true;
 664 }
 665
 666 void Spawn_Draw(entity this)
 667 {
 668         if(this.alpha <= 0)
 669                 return;
 670
 671         __pointparticles(this.cnt, this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 672 }
 673
 674 void Spawn_PreDraw(entity this)
 675 {
 676         float alph;
 677         vector org = getpropertyvec(VF_ORIGIN);
 678         if(this.fade_start)
 679         {
 680                 if(vdist(org - this.origin, >, this.fade_end))
 681                         alph = 0; // save on some processing
 682                 else if(vdist(org - this.origin, <, this.fade_start))
 683                         alph = 1; // more processing saved
 684                 else
 685                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 686         }
 687         else
 688                 alph = 1;
 689         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 690         this.alpha = alph;
 691         if(alph <= 0)
 692                 this.drawmask = 0;
 693         else
 694                 this.drawmask = MASK_NORMAL;
 695 }
 696
 697 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 698 {
 699         float teamnum = (ReadByte() - 1);
 700         vector spn_origin = ReadVector();
 701
 702         this.team = (teamnum + 1);
 703
 704         //if(is_new)
 705         //{
 706                 this.origin = spn_origin;
 707                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 708                 //droptofloor();
 709
 710                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 711                 {
 712                         this.mdl = "models/spawnpoint.md3";
 713                         this.colormod = Team_ColorRGB(teamnum);
 714                         precache_model(this.mdl);
 715                         setmodel(this, this.mdl);
 716                         this.drawmask = MASK_NORMAL;
 717                         //this.move_movetype = MOVETYPE_NOCLIP;
 718                         //this.draw = Spawn_Draw;
 719                         IL_PUSH(g_drawables, this);
 720                 }*/
 721                 if(autocvar_cl_spawn_point_particles)
 722                 {
 723                         if(teamplay)
 724                         {
 725                                 switch(teamnum)
 726                                 {
 727                                         case NUM_TEAM_1: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
 728                                         case NUM_TEAM_2: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
 729                                         case NUM_TEAM_3: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
 730                                         case NUM_TEAM_4: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
 731                                         default: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
 732                                 }
 733                         }
 734                         else { this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
 735
 736                         this.draw = Spawn_Draw;
 737                         if (is_new) IL_PUSH(g_drawables, this);
 738                         setpredraw(this, Spawn_PreDraw);
 739                         this.fade_start = autocvar_cl_spawn_point_dist_min;
 740                         this.fade_end = autocvar_cl_spawn_point_dist_max;
 741                 }
 742         //}
 743
 744         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 745         return true;
 746 }
 747
 748 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 749 {
 750         // If entnum is 0, ONLY do the local spawn actions
 751         // this way the server can disable the sending of
 752         // spawn origin or such to clients if wanted.
 753         float entnum = ReadByte();
 754
 755         if(entnum)
 756         {
 757                 this.origin = ReadVector();
 758
 759                 if(is_new)
 760                 {
 761                         float teamnum = entcs_GetTeam(entnum - 1);
 762
 763                         if(autocvar_cl_spawn_event_particles)
 764                         {
 765                                 switch(teamnum)
 766                                 {
 767                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 768                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 769                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 770                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 771                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 772                                 }
 773                         }
 774                         if(autocvar_cl_spawn_event_sound)
 775                         {
 776                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 777                         }
 778                 }
 779         }
 780         return = true;
 781
 782         // local spawn actions
 783         if(is_new && (!entnum || (entnum == player_localentnum)))
 784         {
 785                 zoomin_effect = 1;
 786                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 787
 788                 if(autocvar_cl_unpress_zoom_on_spawn)
 789                 {
 790                         localcmd("-zoom\n");
 791                         button_zoom = false;
 792                 }
 793                 HUD_Radar_Hide_Maximized();
 794         }
 795         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 796 }
 797
 798 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 799 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 800 void CSQC_Ent_Update(entity this, bool isnew)
 801 {
 802         this.sourceLoc = __FILE__ ":" STR(__LINE__);
 803         int t = ReadByte();
 804
 805         // set up the "time" global for received entities to be correct for interpolation purposes
 806         float savetime = time;
 807         if(servertime)
 808         {
 809                 time = servertime;
 810         }
 811         else
 812         {
 813                 serverprevtime = time;
 814                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 815                 time = serverprevtime + serverdeltatime;
 816         }
 817
 818 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 819         if (this.enttype)
 820         {
 821                 if (t != this.enttype || isnew)
 822                 {
 823                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
 824                         Ent_Remove(this);
 825                         clearentity(this);
 826                         isnew = true;
 827                 }
 828         }
 829         else
 830         {
 831                 if (!isnew)
 832                 {
 833                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
 834                         isnew = true;
 835                 }
 836         }
 837 #endif
 838         this.enttype = t;
 839         bool done = false;
 840         FOREACH(LinkedEntities, it.m_id == t, {
 841                 if (isnew) this.classname = it.netname;
 842                 if (autocvar_developer_csqcentities)
 843             LOG_INFOF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 844                 done = it.m_read(this, NULL, isnew);
 845                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 846                 break;
 847         });
 848         time = savetime;
 849         if (!done)
 850         {
 851                 LOG_FATALF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 852         }
 853 }
 854
 855 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 856 // used when an entity changes its type. For an entity that someone interacts
 857 // with others, make sure it can no longer do so.
 858 void Ent_Remove(entity this)
 859 {
 860         if(this.entremove) this.entremove(this);
 861
 862         if(this.skeletonindex)
 863         {
 864                 skel_delete(this.skeletonindex);
 865                 this.skeletonindex = 0;
 866         }
 867
 868         if(this.snd_looping > 0)
 869         {
 870                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 871                 this.snd_looping = 0;
 872         }
 873
 874         this.enttype = 0;
 875         this.classname = "";
 876         this.draw = func_null;
 877         this.entremove = func_null;
 878         // TODO possibly set more stuff to defaults
 879 }
 880 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 881 void CSQC_Ent_Remove(entity this)
 882 {
 883         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
 884         if (wasfreed(this))
 885         {
 886                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
 887                 return;
 888         }
 889         if (this.enttype) Ent_Remove(this);
 890         delete(this);
 891 }
 892
 893 void Gamemode_Init()
 894 {
 895         if (!isdemo())
 896         {
 897                 if(!(calledhooks & HOOK_START))
 898                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 899                 calledhooks |= HOOK_START;
 900         }
 901 }
 902 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 903 void CSQC_Parse_StuffCmd(string strMessage)
 904 {
 905         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
 906         localcmd(strMessage);
 907 }
 908 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 909 void CSQC_Parse_Print(string strMessage)
 910 {
 911         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
 912         print(ColorTranslateRGB(strMessage));
 913 }
 914
 915 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 916 void CSQC_Parse_CenterPrint(string strMessage)
 917 {
 918         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
 919         centerprint_hud(strMessage);
 920 }
 921
 922 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
 923 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
 924 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
 925 bool CSQC_Parse_TempEntity()
 926 {
 927         // Acquire TE ID
 928         int nTEID = ReadByte();
 929
 930         FOREACH(TempEntities, it.m_id == nTEID, {
 931                 if (autocvar_developer_csqcentities)
 932                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
 933                 return it.m_read(NULL, NULL, true);
 934         });
 935
 936         if (autocvar_developer_csqcentities)
 937                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
 938
 939         // No special logic for this temporary entity; return 0 so the engine can handle it
 940         return false;
 941 }
 942
 943 string forcefog;
 944 void Fog_Force()
 945 {
 946         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 947                 localcmd("\nr_drawfog 0\n");
 948         else if (forcefog != "")
 949                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
 950 }
 951
 952 void Gamemode_Init();
 953 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
 954 {
 955         make_pure(this);
 956         gametype = ReadRegistered(Gametypes);
 957         teamplay = _MapInfo_GetTeamPlayBool(gametype);
 958         HUD_ModIcons_SetFunc();
 959         FOREACH(Scores, true, {
 960                 if (scores_label(it)) strunzone(scores_label(it));
 961                 scores_label(it) = strzone(ReadString());
 962                 scores_flags(it) = ReadByte();
 963         });
 964         for (int i = 0; i < MAX_TEAMSCORE; ++i)
 965         {
 966                 if (teamscores_label(i)) strunzone(teamscores_label(i));
 967                 teamscores_label(i) = strzone(ReadString());
 968                 teamscores_flags(i) = ReadByte();
 969         }
 970         return = true;
 971         Scoreboard_InitScores();
 972         Gamemode_Init();
 973 }
 974
 975 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
 976 {
 977         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 978
 979         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 980         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 981         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 982         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 983         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 984         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 985         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 986         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 987
 988         if (forcefog) strunzone(forcefog);
 989         forcefog = strzone(ReadString());
 990
 991         armorblockpercent = ReadByte() / 255.0;
 992         damagepush_speedfactor = ReadByte() / 255.0;
 993
 994         serverflags = ReadByte();
 995
 996         g_trueaim_minrange = ReadCoord();
 997
 998         return = true;
 999
1000         MUTATOR_CALLHOOK(Ent_Init);
1001
1002         if (!postinit) PostInit();
1003 }
1004
1005 float GetSpeedUnitFactor(int speed_unit)
1006 {
1007         switch(speed_unit)
1008         {
1009                 default:
1010                 case 1:
1011                         return 1.0;
1012                 case 2:
1013                         return 0.0254;
1014                 case 3:
1015                         return 0.0254 * 3.6;
1016                 case 4:
1017                         return 0.0254 * 3.6 * 0.6213711922;
1018                 case 5:
1019                         return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1020         }
1021 }
1022
1023 string GetSpeedUnit(int speed_unit)
1024 {
1025         switch(speed_unit)
1026         {
1027                 default:
1028                 case 1:
1029                         return _(" qu/s");
1030                 case 2:
1031                         return _(" m/s");
1032                 case 3:
1033                         return _(" km/h");
1034                 case 4:
1035                         return _(" mph");
1036                 case 5:
1037                         return _(" knots");
1038         }
1039 }
1040
1041 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1042 {
1043         int b = ReadByte();
1044
1045         switch (b)
1046         {
1047                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1048                         race_checkpoint = ReadByte();
1049                         race_time = ReadInt24_t();
1050                         race_previousbesttime = ReadInt24_t();
1051                         race_mypreviousbesttime = ReadInt24_t();
1052                         if(race_previousbestname)
1053                                 strunzone(race_previousbestname);
1054                         string pbestname = ReadString();
1055                         if(autocvar_cl_race_cptimes_onlyself)
1056                         {
1057                                 race_previousbesttime = race_mypreviousbesttime;
1058                                 race_mypreviousbesttime = 0;
1059                                 race_previousbestname = strzone("");
1060                         }
1061                         else
1062                                 race_previousbestname = strzone(pbestname);
1063
1064                         race_checkpointtime = time;
1065
1066                         if(race_checkpoint == 0 || race_checkpoint == 254)
1067                         {
1068                                 race_penaltyaccumulator = 0;
1069                                 race_laptime = time; // valid
1070                         }
1071                         break;
1072
1073                 case RACE_NET_CHECKPOINT_CLEAR:
1074                         race_laptime = 0;
1075                         race_checkpointtime = 0;
1076                         break;
1077
1078                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1079                         race_laptime = ReadCoord();
1080                         race_checkpointtime = -99999;
1081                         // fall through
1082                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1083                         race_nextcheckpoint = ReadByte();
1084
1085                         race_nextbesttime = ReadInt24_t();
1086                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1087                                 race_mybesttime = ReadInt24_t();
1088                         if(race_nextbestname)
1089                                 strunzone(race_nextbestname);
1090                         string newname = ReadString();
1091                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1092                         {
1093                                 race_nextbesttime = race_mybesttime;
1094                                 race_mybesttime = 0;
1095                                 race_nextbestname = strzone("");
1096                         }
1097                         else
1098                                 race_nextbestname = strzone(newname);
1099                         break;
1100
1101                 case RACE_NET_CHECKPOINT_HIT_RACE:
1102                         race_mycheckpoint = ReadByte();
1103                         race_mycheckpointtime = time;
1104                         race_mycheckpointdelta = ReadInt24_t();
1105                         race_mycheckpointlapsdelta = ReadByte();
1106                         if(race_mycheckpointlapsdelta >= 128)
1107                                 race_mycheckpointlapsdelta -= 256;
1108                         if(race_mycheckpointenemy)
1109                                 strunzone(race_mycheckpointenemy);
1110                         int who = ReadByte();
1111                         if(who)
1112                                 race_mycheckpointenemy = strzone(entcs_GetName(who - 1));
1113                         else
1114                                 race_mycheckpointenemy = strzone(""); // TODO: maybe string_null works fine here?
1115                         break;
1116
1117                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1118                         race_othercheckpoint = ReadByte();
1119                         race_othercheckpointtime = time;
1120                         race_othercheckpointdelta = ReadInt24_t();
1121                         race_othercheckpointlapsdelta = ReadByte();
1122                         if(race_othercheckpointlapsdelta >= 128)
1123                                 race_othercheckpointlapsdelta -= 256;
1124                         if(race_othercheckpointenemy)
1125                                 strunzone(race_othercheckpointenemy);
1126                         int what = ReadByte();
1127                         if(what)
1128                                 race_othercheckpointenemy = strzone(entcs_GetName(what - 1));
1129                         else
1130                                 race_othercheckpointenemy = strzone(""); // TODO: maybe string_null works fine here?
1131                         break;
1132
1133                 case RACE_NET_PENALTY_RACE:
1134                         race_penaltyeventtime = time;
1135                         race_penaltytime = ReadShort();
1136                         //race_penaltyaccumulator += race_penaltytime;
1137                         if(race_penaltyreason)
1138                                 strunzone(race_penaltyreason);
1139                         race_penaltyreason = strzone(ReadString());
1140                         break;
1141
1142                 case RACE_NET_PENALTY_QUALIFYING:
1143                         race_penaltyeventtime = time;
1144                         race_penaltytime = ReadShort();
1145                         race_penaltyaccumulator += race_penaltytime;
1146                         if(race_penaltyreason)
1147                                 strunzone(race_penaltyreason);
1148                         race_penaltyreason = strzone(ReadString());
1149                         break;
1150
1151                 case RACE_NET_SERVER_RECORD:
1152                         race_server_record = ReadInt24_t();
1153                         break;
1154                 case RACE_NET_SPEED_AWARD:
1155                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1156                         if(race_speedaward_holder)
1157                                 strunzone(race_speedaward_holder);
1158                         race_speedaward_holder = strzone(ReadString());
1159                         if(race_speedaward_unit)
1160                                 strunzone(race_speedaward_unit);
1161                         race_speedaward_unit = strzone(GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1162                         break;
1163                 case RACE_NET_SPEED_AWARD_BEST:
1164                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1165                         if(race_speedaward_alltimebest_holder)
1166                                 strunzone(race_speedaward_alltimebest_holder);
1167                         race_speedaward_alltimebest_holder = strzone(ReadString());
1168                         if(race_speedaward_alltimebest_unit)
1169                                 strunzone(race_speedaward_alltimebest_unit);
1170                         race_speedaward_alltimebest_unit = strzone(GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1171                         break;
1172                 case RACE_NET_SERVER_RANKINGS:
1173                         float prevpos, del;
1174             int pos = ReadShort();
1175                         prevpos = ReadShort();
1176                         del = ReadShort();
1177
1178                         // move other rankings out of the way
1179             int i;
1180                         if (prevpos) {
1181                                 for (i=prevpos-1;i>pos-1;--i) {
1182                                         grecordtime[i] = grecordtime[i-1];
1183                                         if(grecordholder[i])
1184                                                 strunzone(grecordholder[i]);
1185                                         grecordholder[i] = strzone(grecordholder[i-1]);
1186                                 }
1187                         } else if (del) { // a record has been deleted by the admin
1188                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1189                                         if (i == RANKINGS_CNT-1) { // clear out last record
1190                                                 grecordtime[i] = 0;
1191                                                 if (grecordholder[i])
1192                                                         strunzone(grecordholder[i]);
1193                                                 grecordholder[i] = string_null;
1194                                         }
1195                                         else {
1196                                                 grecordtime[i] = grecordtime[i+1];
1197                                                 if (grecordholder[i])
1198                                                         strunzone(grecordholder[i]);
1199                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1200                                         }
1201                                 }
1202                         } else { // player has no ranked record yet
1203                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1204                                         grecordtime[i] = grecordtime[i-1];
1205                                         if(grecordholder[i])
1206                                                 strunzone(grecordholder[i]);
1207                                         grecordholder[i] = strzone(grecordholder[i-1]);
1208                                 }
1209                         }
1210
1211                         // store new ranking
1212                         if(grecordholder[pos-1] != "")
1213                                 strunzone(grecordholder[pos-1]);
1214                         grecordholder[pos-1] = strzone(ReadString());
1215                         grecordtime[pos-1] = ReadInt24_t();
1216                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1217                                 race_myrank = pos;
1218                         break;
1219                 case RACE_NET_SERVER_STATUS:
1220                         race_status = ReadShort();
1221                         if(race_status_name)
1222                                 strunzone(race_status_name);
1223                         race_status_name = strzone(ReadString());
1224         }
1225         return true;
1226 }
1227
1228 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1229 {
1230         teamnagger = 1;
1231         return true;
1232 }
1233
1234 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1235 {
1236         int i = ReadByte();
1237         int pi = ReadShort();
1238         int pl = ReadByte();
1239         int ml = ReadByte();
1240         return = true;
1241         entity e = playerslots[i];
1242         if (!e) return;
1243         e.ping = pi;
1244         e.ping_packetloss = pl / 255.0;
1245         e.ping_movementloss = ml / 255.0;
1246 }
1247
1248 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1249 {
1250         complain_weapon = ReadByte();
1251         complain_weapon_type = ReadByte();
1252         return = true;
1253
1254         complain_weapon_time = time;
1255         weapontime = time; // ping the weapon panel
1256
1257         switch(complain_weapon_type)
1258         {
1259                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1260                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1261                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1262         }
1263 }
1264
1265 string _getcommandkey(string cmd_name, string command, bool forcename)
1266 {
1267         string keys;
1268         float n, j, k, l = 0;
1269
1270         if (!autocvar_hud_showbinds)
1271                 return cmd_name;
1272
1273         keys = db_get(binddb, command);
1274         if (keys == "")
1275         {
1276                 bool joy_active = cvar("joy_active");
1277                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1278                 for(j = 0; j < n; ++j)
1279                 {
1280                         k = stof(argv(j));
1281                         if(k != -1)
1282                         {
1283                                 string key = keynumtostring(k);
1284                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1285                                         continue;
1286
1287                                 if (keys == "")
1288                                         keys = key;
1289                                 else
1290                                         keys = strcat(keys, ", ", key);
1291
1292                                 ++l;
1293                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1294                                         break;
1295                         }
1296
1297                 }
1298                 if (keys == "")
1299                         keys = "NO_KEY";
1300                 db_put(binddb, command, keys);
1301         }
1302
1303         if (keys == "NO_KEY") {
1304                 if (autocvar_hud_showbinds > 1)
1305                         return sprintf(_("%s (not bound)"), cmd_name);
1306                 else
1307                         return cmd_name;
1308         }
1309         else if (autocvar_hud_showbinds > 1 || forcename)
1310                 return sprintf("%s (%s)", cmd_name, keys);
1311         else
1312                 return keys;
1313 }