qcsrc/client/main.qc

   1 #include "mapvoting.qh"
   2 #include "modeleffects.qh"
   3 #include "particles.qh"
   4 #include "scoreboard.qh"
   5 #include "shownames.qh"
   6 #include "tturrets.qh"
   7 #include "tuba.qh"
   8 #include "wall.qh"
   9 #include "waypointsprites.qh"
  10
  11 #include "vehicles/vehicles.qh"
  12
  13 #include "../server/vehicles/bumblebee.qh"
  14
  15 #include "../common/net_notice.qh"
  16
  17 #include "../common/monsters/monsters.qh"
  18
  19 #include "../common/triggers/include.qh"
  20
  21 #include "../warpzonelib/client.qh"
  22
  23 // --------------------------------------------------------------------------
  24 // BEGIN REQUIRED CSQC FUNCTIONS
  25 //include "main.qh"
  26
  27 entity clearentity_ent;
  28 void clearentity(entity e)
  29 {
  30         if (!clearentity_ent)
  31         {
  32                 clearentity_ent = spawn();
  33                 clearentity_ent.classname = "clearentity";
  34         }
  35         int n = e.entnum;
  36         copyentity(clearentity_ent, e);
  37         e.entnum = n;
  38 }
  39
  40 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  41 void menu_show_error()
  42 {
  43         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  44 }
  45
  46 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  47 // Useful for precaching things
  48
  49 void menu_sub_null()
  50 {
  51 }
  52
  53 string forcefog;
  54 void WaypointSprite_Load();
  55 void ConsoleCommand_macro_init();
  56 void CSQC_Init(void)
  57 {
  58         prvm_language = cvar_string("prvm_language");
  59
  60 #ifdef WATERMARK
  61         dprintf("^4CSQC Build information: ^1%s\n", WATERMARK);
  62 #endif
  63
  64         int i;
  65
  66         binddb = db_create();
  67         tempdb = db_create();
  68         ClientProgsDB = db_load("client.db");
  69         compressShortVector_init();
  70
  71         draw_endBoldFont();
  72         menu_visible = false;
  73         menu_show = menu_show_error;
  74         menu_action = func_null;
  75
  76         for(i = 0; i < 255; ++i)
  77                 if(getplayerkeyvalue(i, "viewentity") == "")
  78                         break;
  79         maxclients = i;
  80
  81         //registercommand("hud_configure");
  82         //registercommand("hud_save");
  83         //registercommand("menu_action");
  84
  85         ConsoleCommand_macro_init();
  86
  87         registercvar("hud_usecsqc", "1");
  88         registercvar("scoreboard_columns", "default");
  89
  90         registercvar("cl_nade_type", "3");
  91         registercvar("cl_pokenade_type", "zombie");
  92
  93         gametype = 0;
  94
  95         // hud_fields uses strunzone on the titles!
  96         for(i = 0; i < MAX_HUD_FIELDS; ++i)
  97                 hud_title[i] = strzone("(null)");
  98
  99         Cmd_HUD_SetFields(0);
 100
 101         postinit = false;
 102
 103         calledhooks = 0;
 104
 105         teams = Sort_Spawn();
 106         players = Sort_Spawn();
 107
 108         GetTeam(NUM_SPECTATOR, true); // add specs first
 109
 110         // needs to be done so early because of the constants they create
 111         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 112         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 113         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 114         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 115         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 116         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
 117         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 118
 119         WaypointSprite_Load();
 120
 121         // precaches
 122         precache_model("null");
 123         precache_sound("misc/hit.wav");
 124         precache_sound("misc/typehit.wav");
 125
 126         Projectile_Precache();
 127         Hook_Precache();
 128         GibSplash_Precache();
 129         Casings_Precache();
 130         Vehicles_Precache();
 131         turrets_precache();
 132         Tuba_Precache();
 133         CSQCPlayer_Precache();
 134
 135         if(autocvar_cl_reticle)
 136         {
 137                 precache_pic("gfx/reticle_normal");
 138                 // weapon reticles are precached in weapon files
 139         }
 140
 141         get_mi_min_max_texcoords(1); // try the CLEVER way first
 142         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 143         shortmapname = mi_shortname;
 144
 145         if(precache_pic(minimapname) == "")
 146         {
 147                 // but maybe we have a non-clever minimap
 148                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 149                 if(precache_pic(minimapname) == "")
 150                         minimapname = ""; // FAIL
 151                 else
 152                         get_mi_min_max_texcoords(0); // load new texcoords
 153         }
 154
 155         mi_center = (mi_min + mi_max) * 0.5;
 156         mi_scale = mi_max - mi_min;
 157         minimapname = strzone(minimapname);
 158
 159         WarpZone_Init();
 160
 161         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 162         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 163 }
 164
 165 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 166 void Shutdown(void)
 167 {
 168         WarpZone_Shutdown();
 169
 170         remove(teams);
 171         remove(players);
 172         db_close(binddb);
 173         db_close(tempdb);
 174         if(autocvar_cl_db_saveasdump)
 175                 db_dump(ClientProgsDB, "client.db");
 176         else
 177                 db_save(ClientProgsDB, "client.db");
 178         db_close(ClientProgsDB);
 179
 180         if(camera_active)
 181                 cvar_set("chase_active",ftos(chase_active_backup));
 182
 183         // unset the event chasecam's chase_active
 184         if(autocvar_chase_active < 0)
 185                 cvar_set("chase_active", "0");
 186
 187         if (!isdemo())
 188         {
 189                 if (!(calledhooks & HOOK_START))
 190                         localcmd("\n_cl_hook_gamestart nop\n");
 191                 if (!(calledhooks & HOOK_END))
 192                         localcmd("\ncl_hook_gameend\n");
 193         }
 194 }
 195
 196 .float has_team;
 197 float SetTeam(entity o, int Team)
 198 {
 199         entity tm;
 200         if(teamplay)
 201         {
 202                 switch(Team)
 203                 {
 204                         case -1:
 205                         case NUM_TEAM_1:
 206                         case NUM_TEAM_2:
 207                         case NUM_TEAM_3:
 208                         case NUM_TEAM_4:
 209                                 break;
 210                         default:
 211                                 if(GetTeam(Team, false) == world)
 212                                 {
 213                                         dprintf("trying to switch to unsupported team %d\n", Team);
 214                                         Team = NUM_SPECTATOR;
 215                                 }
 216                                 break;
 217                 }
 218         }
 219         else
 220         {
 221                 switch(Team)
 222                 {
 223                         case -1:
 224                         case 0:
 225                                 break;
 226                         default:
 227                                 if(GetTeam(Team, false) == world)
 228                                 {
 229                                         dprintf("trying to switch to unsupported team %d\n", Team);
 230                                         Team = NUM_SPECTATOR;
 231                                 }
 232                                 break;
 233                 }
 234         }
 235         if(Team == -1) // leave
 236         {
 237                 if(o.has_team)
 238                 {
 239                         tm = GetTeam(o.team, false);
 240                         tm.team_size -= 1;
 241                         o.has_team = 0;
 242                         return true;
 243                 }
 244         }
 245         else
 246         {
 247                 if (!o.has_team)
 248                 {
 249                         o.team = Team;
 250                         tm = GetTeam(Team, true);
 251                         tm.team_size += 1;
 252                         o.has_team = 1;
 253                         return true;
 254                 }
 255                 else if(Team != o.team)
 256                 {
 257                         tm = GetTeam(o.team, false);
 258                         tm.team_size -= 1;
 259                         o.team = Team;
 260                         tm = GetTeam(Team, true);
 261                         tm.team_size += 1;
 262                         return true;
 263                 }
 264         }
 265         return false;
 266 }
 267
 268 void Playerchecker_Think()
 269 {
 270     int i;
 271         entity e;
 272         for(i = 0; i < maxclients; ++i)
 273         {
 274                 e = playerslots[i];
 275                 if(GetPlayerName(i) == "")
 276                 {
 277                         if(e.sort_prev)
 278                         {
 279                                 // player disconnected
 280                                 SetTeam(e, -1);
 281                                 RemovePlayer(e);
 282                                 e.sort_prev = world;
 283                                 //e.gotscores = 0;
 284                         }
 285                 }
 286                 else
 287                 {
 288                         if (!e.sort_prev)
 289                         {
 290                                 // player connected
 291                                 if (!e)
 292                                         playerslots[i] = e = spawn();
 293                                 e.sv_entnum = i;
 294                                 e.ping = 0;
 295                                 e.ping_packetloss = 0;
 296                                 e.ping_movementloss = 0;
 297                                 //e.gotscores = 0; // we might already have the scores...
 298                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 299                                 RegisterPlayer(e);
 300                                 HUD_UpdatePlayerPos(e);
 301                         }
 302                 }
 303         }
 304         self.nextthink = time + 0.2;
 305 }
 306
 307 void Porto_Init();
 308 void TrueAim_Init();
 309 void PostInit(void)
 310 {
 311         entity playerchecker;
 312         playerchecker = spawn();
 313         playerchecker.think = Playerchecker_Think;
 314         playerchecker.nextthink = time + 0.2;
 315
 316         Porto_Init();
 317         TrueAim_Init();
 318
 319         postinit = true;
 320 }
 321
 322 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 323 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 324 // All keys are in ascii.
 325 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 326 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 327 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 328 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 329 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 330 {
 331         float bSkipKey;
 332         bSkipKey = false;
 333
 334         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 335                 return true;
 336
 337         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 338                 return true;
 339
 340         if(menu_visible && menu_action)
 341                 if(menu_action(bInputType, nPrimary, nSecondary))
 342                         return true;
 343
 344         return bSkipKey;
 345 }
 346
 347 // END REQUIRED CSQC FUNCTIONS
 348 // --------------------------------------------------------------------------
 349
 350 // --------------------------------------------------------------------------
 351 // BEGIN OPTIONAL CSQC FUNCTIONS
 352
 353 void Ent_RemoveEntCS()
 354 {
 355         entcs_receiver[self.sv_entnum] = world;
 356 }
 357 void Ent_ReadEntCS()
 358 {
 359     int sf;
 360         InterpolateOrigin_Undo();
 361
 362         self.classname = "entcs_receiver";
 363         sf = ReadByte();
 364
 365         if(sf & 1)
 366                 self.sv_entnum = ReadByte();
 367         if(sf & 2)
 368         {
 369                 self.origin_x = ReadShort();
 370                 self.origin_y = ReadShort();
 371                 self.origin_z = ReadShort();
 372                 setorigin(self, self.origin);
 373         }
 374         if(sf & 4)
 375         {
 376                 self.angles_y = ReadByte() * 360.0 / 256;
 377                 self.angles_x = self.angles_z = 0;
 378         }
 379         if(sf & 8)
 380                 self.healthvalue = ReadByte() * 10;
 381         if(sf & 16)
 382                 self.armorvalue = ReadByte() * 10;
 383
 384         entcs_receiver[self.sv_entnum] = self;
 385         self.entremove = Ent_RemoveEntCS;
 386         self.iflags |= IFLAG_ORIGIN;
 387
 388         InterpolateOrigin_Note();
 389 }
 390
 391 void Ent_Remove();
 392
 393 void Ent_RemovePlayerScore()
 394 {
 395         if(self.owner) {
 396                 SetTeam(self.owner, -1);
 397                 self.owner.gotscores = 0;
 398                 for(int i = 0; i < MAX_SCORE; ++i) {
 399                         self.owner.(scores[i]) = 0; // clear all scores
 400                 }
 401         }
 402 }
 403
 404 void Ent_ReadPlayerScore()
 405 {
 406         int i, n;
 407         bool isNew;
 408         entity o;
 409
 410         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 411         // (no I've never heard of M-x replace-string, sed, or anything like that)
 412         isNew = !self.owner; // workaround for DP bug
 413         n = ReadByte()-1;
 414
 415 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 416         if(!isNew && n != self.sv_entnum)
 417         {
 418                 //print("A CSQC entity changed its owner!\n");
 419                 printf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 420                 isNew = true;
 421                 Ent_Remove();
 422                 self.enttype = ENT_CLIENT_SCORES;
 423         }
 424 #endif
 425
 426         self.sv_entnum = n;
 427
 428         if (!(playerslots[self.sv_entnum]))
 429                 playerslots[self.sv_entnum] = spawn();
 430         o = self.owner = playerslots[self.sv_entnum];
 431         o.sv_entnum = self.sv_entnum;
 432         o.gotscores = 1;
 433
 434         //if (!o.sort_prev)
 435         //      RegisterPlayer(o);
 436         //playerchecker will do this for us later, if it has not already done so
 437
 438     int sf, lf;
 439 #if MAX_SCORE <= 8
 440         sf = ReadByte();
 441         lf = ReadByte();
 442 #else
 443         sf = ReadShort();
 444         lf = ReadShort();
 445 #endif
 446     int p;
 447         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 448                 if(sf & p)
 449                 {
 450                         if(lf & p)
 451                                 o.(scores[i]) = ReadInt24_t();
 452                         else
 453                                 o.(scores[i]) = ReadChar();
 454                 }
 455
 456         if(o.sort_prev)
 457                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 458
 459         self.entremove = Ent_RemovePlayerScore;
 460 }
 461
 462 void Ent_ReadTeamScore()
 463 {
 464         int i;
 465         entity o;
 466
 467         self.team = ReadByte();
 468         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 469
 470     int sf, lf;
 471 #if MAX_TEAMSCORE <= 8
 472         sf = ReadByte();
 473         lf = ReadByte();
 474 #else
 475         sf = ReadShort();
 476         lf = ReadShort();
 477 #endif
 478         int p;
 479         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 480                 if(sf & p)
 481                 {
 482                         if(lf & p)
 483                                 o.(teamscores[i]) = ReadInt24_t();
 484                         else
 485                                 o.(teamscores[i]) = ReadChar();
 486                 }
 487
 488         HUD_UpdateTeamPos(o);
 489 }
 490
 491 void Ent_ClientData()
 492 {
 493         float newspectatee_status;
 494
 495     int f = ReadByte();
 496
 497         scoreboard_showscores_force = (f & 1);
 498
 499         if(f & 2)
 500         {
 501                 newspectatee_status = ReadByte();
 502                 if(newspectatee_status == player_localnum + 1)
 503                         newspectatee_status = -1; // observing
 504         }
 505         else
 506                 newspectatee_status = 0;
 507
 508         spectatorbutton_zoom = (f & 4);
 509
 510         if(f & 8)
 511         {
 512                 angles_held_status = 1;
 513                 angles_held.x = ReadAngle();
 514                 angles_held.y = ReadAngle();
 515                 angles_held.z = 0;
 516         }
 517         else
 518                 angles_held_status = 0;
 519
 520         if(newspectatee_status != spectatee_status)
 521         {
 522                 // clear race stuff
 523                 race_laptime = 0;
 524                 race_checkpointtime = 0;
 525         }
 526         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 527         {
 528                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 529                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 530                 )
 531                         prev_p_health = -1;
 532                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 533                         prev_health = -1;
 534         }
 535         spectatee_status = newspectatee_status;
 536
 537         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 538 }
 539
 540 void Ent_Nagger()
 541 {
 542     int i, j, b, f;
 543
 544     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 545
 546         if(!(nags & 4))
 547         {
 548                 if(vote_called_vote)
 549                         strunzone(vote_called_vote);
 550                 vote_called_vote = string_null;
 551                 vote_active = 0;
 552         }
 553         else
 554         {
 555                 vote_active = 1;
 556         }
 557
 558         if(nags & 64)
 559         {
 560                 vote_yescount = ReadByte();
 561                 vote_nocount = ReadByte();
 562                 vote_needed = ReadByte();
 563                 vote_highlighted = ReadChar();
 564         }
 565
 566         if(nags & 128)
 567         {
 568                 if(vote_called_vote)
 569                         strunzone(vote_called_vote);
 570                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 571         }
 572
 573         if(nags & 1)
 574         {
 575                 for(j = 0; j < maxclients; ++j)
 576                         if(playerslots[j])
 577                                 playerslots[j].ready = 1;
 578                 for(i = 1; i <= maxclients; i += 8)
 579                 {
 580                         f = ReadByte();
 581                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 582                                 if (!(f & b))
 583                                         if(playerslots[j])
 584                                                 playerslots[j].ready = 0;
 585                 }
 586         }
 587
 588         ready_waiting = (nags & 1);
 589         ready_waiting_for_me = (nags & 2);
 590         vote_waiting = (nags & 4);
 591         vote_waiting_for_me = (nags & 8);
 592         warmup_stage = (nags & 16);
 593 }
 594
 595 void Ent_EliminatedPlayers()
 596 {
 597     int i, j, b, f;
 598
 599     int sf = ReadByte();
 600         if(sf & 1)
 601         {
 602                 for(j = 0; j < maxclients; ++j)
 603                         if(playerslots[j])
 604                                 playerslots[j].eliminated = 1;
 605                 for(i = 1; i <= maxclients; i += 8)
 606                 {
 607                         f = ReadByte();
 608                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 609                                 if (!(f & b))
 610                                         if(playerslots[j])
 611                                                 playerslots[j].eliminated = 0;
 612                 }
 613         }
 614 }
 615
 616 void Ent_RandomSeed()
 617 {
 618         float s;
 619         prandom_debug();
 620         s = ReadShort();
 621         psrandom(s);
 622 }
 623
 624 void Ent_ReadAccuracy(void)
 625 {
 626     int f, w;
 627     int sf = ReadInt24_t();
 628         if(sf == 0)
 629         {
 630                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 631                         weapon_accuracy[w] = -1;
 632                 return;
 633         }
 634
 635         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 636         {
 637                 if(sf & f)
 638                 {
 639             int b = ReadByte();
 640                         if(b == 0)
 641                                 weapon_accuracy[w] = -1;
 642                         else if(b == 255)
 643                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 644                         else
 645                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 646                 }
 647                 if(f == 0x800000)
 648                         f = 1;
 649                 else
 650                         f *= 2;
 651         }
 652 }
 653
 654 void Spawn_Draw(void)
 655 {
 656         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 657 }
 658
 659 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 660 {
 661         float teamnum = (ReadByte() - 1);
 662         vector spn_origin;
 663         spn_origin.x = ReadShort();
 664         spn_origin.y = ReadShort();
 665         spn_origin.z = ReadShort();
 666
 667         if(is_new)
 668         {
 669                 self.origin = spn_origin;
 670                 setsize(self, '-16 -16 -24', '16 16 45');
 671                 droptofloor();
 672
 673                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 674                 {
 675                         self.mdl = "models/spawnpoint.md3";
 676                         self.colormod = Team_ColorRGB(teamnum);
 677                         precache_model(self.mdl);
 678                         setmodel(self, self.mdl);
 679                         self.drawmask = MASK_NORMAL;
 680                         //self.movetype = MOVETYPE_NOCLIP;
 681                         //self.draw = Spawn_Draw;
 682                 }*/
 683                 if(autocvar_cl_spawn_point_particles)
 684                 {
 685                         if((serverflags & SERVERFLAG_TEAMPLAY))
 686                         {
 687                                 switch(teamnum)
 688                                 {
 689                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
 690                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
 691                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
 692                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
 693                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
 694                                 }
 695                         }
 696                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
 697
 698                         self.draw = Spawn_Draw;
 699                 }
 700         }
 701
 702         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 703 }
 704
 705 void Ent_ReadSpawnEvent(float is_new)
 706 {
 707         // If entnum is 0, ONLY do the local spawn actions
 708         // this way the server can disable the sending of
 709         // spawn origin or such to clients if wanted.
 710         float entnum = ReadByte();
 711
 712         if(entnum)
 713         {
 714                 self.origin_x = ReadShort();
 715                 self.origin_y = ReadShort();
 716                 self.origin_z = ReadShort();
 717
 718                 if(is_new)
 719                 {
 720                         float teamnum = GetPlayerColor(entnum - 1);
 721
 722                         if(autocvar_cl_spawn_event_particles)
 723                         {
 724                                 switch(teamnum)
 725                                 {
 726                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
 727                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
 728                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
 729                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
 730                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
 731                                 }
 732                         }
 733                         if(autocvar_cl_spawn_event_sound)
 734                         {
 735                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
 736                         }
 737                 }
 738         }
 739
 740         // local spawn actions
 741         if(is_new && (!entnum || (entnum == player_localentnum)))
 742         {
 743                 zoomin_effect = 1;
 744                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 745
 746                 if(autocvar_cl_unpress_zoom_on_spawn)
 747                 {
 748                         localcmd("-zoom\n");
 749                         button_zoom = false;
 750                 }
 751         }
 752
 753         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 754 }
 755
 756 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 757 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 758 void Ent_RadarLink();
 759 void Ent_Init();
 760 void Ent_ScoresInfo();
 761 void CSQC_Ent_Update(float bIsNewEntity)
 762 {
 763         float t;
 764         float savetime;
 765         t = ReadByte();
 766
 767         if(autocvar_developer_csqcentities)
 768                 printf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 769
 770         // set up the "time" global for received entities to be correct for interpolation purposes
 771         savetime = time;
 772         if(servertime)
 773         {
 774                 time = servertime;
 775         }
 776         else
 777         {
 778                 serverprevtime = time;
 779                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 780                 time = serverprevtime + serverdeltatime;
 781         }
 782
 783 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 784         if(self.enttype)
 785         {
 786                 if(t != self.enttype || bIsNewEntity)
 787                 {
 788                         //print("A CSQC entity changed its type!\n");
 789                         printf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 790                         Ent_Remove();
 791                         clearentity(self);
 792                         bIsNewEntity = 1;
 793                 }
 794         }
 795         else
 796         {
 797                 if(!bIsNewEntity)
 798                 {
 799                         printf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 800                         bIsNewEntity = 1;
 801                 }
 802         }
 803 #endif
 804         self.enttype = t;
 805         switch(t)
 806         {
 807                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 808                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 809                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 810                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 811                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 812                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 813                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 814                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
 815                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 816                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 817                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 818                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 819                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 820                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 821                 case ENT_CLIENT_INIT: Ent_Init(); break;
 822                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 823                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 824                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 825                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 826                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 827                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 828                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 829                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 830                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 831                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 832                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 833                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 834                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
 835                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 836                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 837                 case ENT_CLIENT_TURRET: ent_turret(); break;
 838                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 839                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 840                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 841                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 842                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 843                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 844                 case ENT_CLIENT_HEALING_ORB: ent_healer(); break;
 845                 case ENT_CLIENT_LADDER: ent_func_ladder(); break;
 846                 case ENT_CLIENT_TRIGGER_PUSH: ent_trigger_push(); break;
 847                 case ENT_CLIENT_TARGET_PUSH: ent_target_push(); break;
 848                 case ENT_CLIENT_CONVEYOR: ent_conveyor(); break;
 849                 case ENT_CLIENT_DOOR: ent_door(); break;
 850                 case ENT_CLIENT_PLAT: ent_plat(); break;
 851                 case ENT_CLIENT_SWAMP: ent_swamp(); break;
 852                 case ENT_CLIENT_CORNER: ent_corner(); break;
 853                 case ENT_CLIENT_KEYLOCK: ent_keylock(); break;
 854                 case ENT_CLIENT_TRAIN: ent_train(); break;
 855                 case ENT_CLIENT_TRIGGER_IMPULSE: ent_trigger_impulse(); break;
 856
 857                 default:
 858                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 859                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
 860                         break;
 861         }
 862
 863         time = savetime;
 864 }
 865 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 866 // used when an entity changes its type. For an entity that someone interacts
 867 // with others, make sure it can no longer do so.
 868 void Ent_Remove()
 869 {
 870         if(self.entremove)
 871                 self.entremove();
 872
 873         if(self.skeletonindex)
 874         {
 875                 skel_delete(self.skeletonindex);
 876                 self.skeletonindex = 0;
 877         }
 878
 879         if(self.snd_looping > 0)
 880         {
 881                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 882                 self.snd_looping = 0;
 883         }
 884
 885         self.enttype = 0;
 886         self.classname = "";
 887         self.draw = menu_sub_null;
 888         self.entremove = menu_sub_null;
 889         // TODO possibly set more stuff to defaults
 890 }
 891 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 892 void CSQC_Ent_Remove()
 893 {
 894         if(autocvar_developer_csqcentities)
 895                 printf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 896
 897         if(wasfreed(self))
 898         {
 899                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 900                 return;
 901         }
 902         if(self.enttype)
 903                 Ent_Remove();
 904         remove(self);
 905 }
 906
 907 void Gamemode_Init()
 908 {
 909         if (!isdemo())
 910         {
 911                 if(!(calledhooks & HOOK_START))
 912                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 913                 calledhooks |= HOOK_START;
 914         }
 915 }
 916 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 917 void CSQC_Parse_StuffCmd(string strMessage)
 918 {
 919         if(autocvar_developer_csqcentities)
 920                 printf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 921
 922         localcmd(strMessage);
 923 }
 924 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 925 void CSQC_Parse_Print(string strMessage)
 926 {
 927         if(autocvar_developer_csqcentities)
 928                 printf("CSQC_Parse_Print(\"%s\")\n", strMessage);
 929
 930         print(ColorTranslateRGB(strMessage));
 931 }
 932
 933 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 934 void CSQC_Parse_CenterPrint(string strMessage)
 935 {
 936         if(autocvar_developer_csqcentities)
 937                 printf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 938
 939         centerprint_hud(strMessage);
 940 }
 941
 942 string notranslate_fogcmd1 = "\nfog ";
 943 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 944 void Fog_Force()
 945 {
 946         // TODO somehow thwart prvm_globalset client ...
 947
 948         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 949                 { localcmd("\nr_drawfog 0\n"); }
 950         else if(forcefog != "")
 951                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
 952 }
 953
 954 void Gamemode_Init();
 955 void Ent_ScoresInfo()
 956 {
 957     int i;
 958         self.classname = "ent_client_scores_info";
 959         gametype = ReadInt24_t();
 960         HUD_ModIcons_SetFunc();
 961         for(i = 0; i < MAX_SCORE; ++i)
 962         {
 963                 if(scores_label[i])
 964                         strunzone(scores_label[i]);
 965                 scores_label[i] = strzone(ReadString());
 966                 scores_flags[i] = ReadByte();
 967         }
 968         for(i = 0; i < MAX_TEAMSCORE; ++i)
 969         {
 970                 if(teamscores_label[i])
 971                         strunzone(teamscores_label[i]);
 972                 teamscores_label[i] = strzone(ReadString());
 973                 teamscores_flags[i] = ReadByte();
 974         }
 975         HUD_InitScores();
 976         Gamemode_Init();
 977 }
 978
 979 void Ent_Init()
 980 {
 981         self.classname = "ent_client_init";
 982
 983         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 984
 985         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 986         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 987         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 988         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 989         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 990         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 991         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 992         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 993
 994         if(forcefog)
 995                 strunzone(forcefog);
 996         forcefog = strzone(ReadString());
 997
 998         armorblockpercent = ReadByte() / 255.0;
 999
1000         g_balance_mortar_bouncefactor = ReadCoord();
1001         g_balance_mortar_bouncestop = ReadCoord();
1002         g_balance_electro_secondary_bouncefactor = ReadCoord();
1003         g_balance_electro_secondary_bouncestop = ReadCoord();
1004
1005         vortex_scope = !ReadByte();
1006         rifle_scope = !ReadByte();
1007
1008         serverflags = ReadByte();
1009
1010         minelayer_maxmines = ReadByte();
1011
1012         hagar_maxrockets = ReadByte();
1013
1014         g_trueaim_minrange = ReadCoord();
1015         g_balance_porto_secondary = ReadByte();
1016
1017         if(!postinit)
1018                 PostInit();
1019 }
1020
1021 void Net_ReadRace()
1022 {
1023         float b;
1024
1025         b = ReadByte();
1026
1027         switch(b)
1028         {
1029                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1030                         race_checkpoint = ReadByte();
1031                         race_time = ReadInt24_t();
1032                         race_previousbesttime = ReadInt24_t();
1033                         if(race_previousbestname)
1034                                 strunzone(race_previousbestname);
1035                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1036
1037                         race_checkpointtime = time;
1038
1039                         if(race_checkpoint == 0 || race_checkpoint == 254)
1040                         {
1041                                 race_penaltyaccumulator = 0;
1042                                 race_laptime = time; // valid
1043                         }
1044
1045                         break;
1046
1047                 case RACE_NET_CHECKPOINT_CLEAR:
1048                         race_laptime = 0;
1049                         race_checkpointtime = 0;
1050                         break;
1051
1052                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1053                         race_laptime = ReadCoord();
1054                         race_checkpointtime = -99999;
1055                         // fall through
1056                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1057                         race_nextcheckpoint = ReadByte();
1058
1059                         race_nextbesttime = ReadInt24_t();
1060                         if(race_nextbestname)
1061                                 strunzone(race_nextbestname);
1062                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1063                         break;
1064
1065                 case RACE_NET_CHECKPOINT_HIT_RACE:
1066                         race_mycheckpoint = ReadByte();
1067                         race_mycheckpointtime = time;
1068                         race_mycheckpointdelta = ReadInt24_t();
1069                         race_mycheckpointlapsdelta = ReadByte();
1070                         if(race_mycheckpointlapsdelta >= 128)
1071                                 race_mycheckpointlapsdelta -= 256;
1072                         if(race_mycheckpointenemy)
1073                                 strunzone(race_mycheckpointenemy);
1074                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1075                         break;
1076
1077                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1078                         race_othercheckpoint = ReadByte();
1079                         race_othercheckpointtime = time;
1080                         race_othercheckpointdelta = ReadInt24_t();
1081                         race_othercheckpointlapsdelta = ReadByte();
1082                         if(race_othercheckpointlapsdelta >= 128)
1083                                 race_othercheckpointlapsdelta -= 256;
1084                         if(race_othercheckpointenemy)
1085                                 strunzone(race_othercheckpointenemy);
1086                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1087                         break;
1088
1089                 case RACE_NET_PENALTY_RACE:
1090                         race_penaltyeventtime = time;
1091                         race_penaltytime = ReadShort();
1092                         //race_penaltyaccumulator += race_penaltytime;
1093                         if(race_penaltyreason)
1094                                 strunzone(race_penaltyreason);
1095                         race_penaltyreason = strzone(ReadString());
1096                         break;
1097
1098                 case RACE_NET_PENALTY_QUALIFYING:
1099                         race_penaltyeventtime = time;
1100                         race_penaltytime = ReadShort();
1101                         race_penaltyaccumulator += race_penaltytime;
1102                         if(race_penaltyreason)
1103                                 strunzone(race_penaltyreason);
1104                         race_penaltyreason = strzone(ReadString());
1105                         break;
1106
1107                 case RACE_NET_SERVER_RECORD:
1108                         race_server_record = ReadInt24_t();
1109                         break;
1110                 case RACE_NET_SPEED_AWARD:
1111                         race_speedaward = ReadInt24_t();
1112                         if(race_speedaward_holder)
1113                                 strunzone(race_speedaward_holder);
1114                         race_speedaward_holder = strzone(ReadString());
1115                         break;
1116                 case RACE_NET_SPEED_AWARD_BEST:
1117                         race_speedaward_alltimebest = ReadInt24_t();
1118                         if(race_speedaward_alltimebest_holder)
1119                                 strunzone(race_speedaward_alltimebest_holder);
1120                         race_speedaward_alltimebest_holder = strzone(ReadString());
1121                         break;
1122                 case RACE_NET_SERVER_RANKINGS:
1123                         float prevpos, del;
1124             int pos = ReadShort();
1125                         prevpos = ReadShort();
1126                         del = ReadShort();
1127
1128                         // move other rankings out of the way
1129             int i;
1130                         if (prevpos) {
1131                                 for (i=prevpos-1;i>pos-1;--i) {
1132                                         grecordtime[i] = grecordtime[i-1];
1133                                         if(grecordholder[i])
1134                                                 strunzone(grecordholder[i]);
1135                                         grecordholder[i] = strzone(grecordholder[i-1]);
1136                                 }
1137                         } else if (del) { // a record has been deleted by the admin
1138                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1139                                         if (i == RANKINGS_CNT-1) { // clear out last record
1140                                                 grecordtime[i] = 0;
1141                                                 if (grecordholder[i])
1142                                                         strunzone(grecordholder[i]);
1143                                                 grecordholder[i] = string_null;
1144                                         }
1145                                         else {
1146                                                 grecordtime[i] = grecordtime[i+1];
1147                                                 if (grecordholder[i])
1148                                                         strunzone(grecordholder[i]);
1149                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1150                                         }
1151                                 }
1152                         } else { // player has no ranked record yet
1153                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1154                                         grecordtime[i] = grecordtime[i-1];
1155                                         if(grecordholder[i])
1156                                                 strunzone(grecordholder[i]);
1157                                         grecordholder[i] = strzone(grecordholder[i-1]);
1158                                 }
1159                         }
1160
1161                         // store new ranking
1162                         if(grecordholder[pos-1] != "")
1163                                 strunzone(grecordholder[pos-1]);
1164                         grecordholder[pos-1] = strzone(ReadString());
1165                         grecordtime[pos-1] = ReadInt24_t();
1166                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1167                                 race_myrank = pos;
1168                         break;
1169                 case RACE_NET_SERVER_STATUS:
1170                         race_status = ReadShort();
1171                         if(race_status_name)
1172                                 strunzone(race_status_name);
1173                         race_status_name = strzone(ReadString());
1174         }
1175 }
1176
1177 void Net_TeamNagger()
1178 {
1179         teamnagger = 1;
1180 }
1181
1182 void Net_ReadPingPLReport()
1183 {
1184         int e, pi, pl, ml;
1185         e = ReadByte();
1186         pi = ReadShort();
1187         pl = ReadByte();
1188         ml = ReadByte();
1189         if (!(playerslots[e]))
1190                 return;
1191         playerslots[e].ping = pi;
1192         playerslots[e].ping_packetloss = pl / 255.0;
1193         playerslots[e].ping_movementloss = ml / 255.0;
1194 }
1195
1196 void Net_WeaponComplain()
1197 {
1198         complain_weapon = ReadByte();
1199
1200         if(complain_weapon_name)
1201                 strunzone(complain_weapon_name);
1202         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1203
1204         complain_weapon_type = ReadByte();
1205
1206         complain_weapon_time = time;
1207         weapontime = time; // ping the weapon panel
1208
1209         switch(complain_weapon_type)
1210         {
1211                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1212                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1213                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1214         }
1215 }
1216
1217 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1218 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1219 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1220 float CSQC_Parse_TempEntity()
1221 {
1222         float bHandled;
1223                 bHandled  = true;
1224         // Acquire TE ID
1225         float nTEID;
1226                 nTEID = ReadByte();
1227
1228         if(autocvar_developer_csqcentities)
1229                 printf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1230
1231                 // NOTE: Could just do return instead of break...
1232         switch(nTEID)
1233         {
1234                 case TE_CSQC_TARGET_MUSIC:
1235                         Net_TargetMusic();
1236                         bHandled = true;
1237                         break;
1238                 case TE_CSQC_PICTURE:
1239                         Net_MapVote_Picture();
1240                         bHandled = true;
1241                         break;
1242                 case TE_CSQC_RACE:
1243                         Net_ReadRace();
1244                         bHandled = true;
1245                         break;
1246                 case TE_CSQC_VORTEXBEAMPARTICLE:
1247                         Net_ReadVortexBeamParticle();
1248                         bHandled = true;
1249                         break;
1250                 case TE_CSQC_TEAMNAGGER:
1251                         Net_TeamNagger();
1252                         bHandled = true;
1253                         break;
1254                 case TE_CSQC_ARC:
1255                         Net_ReadArc();
1256                         bHandled = true;
1257                         break;
1258                 case TE_CSQC_PINGPLREPORT:
1259                         Net_ReadPingPLReport();
1260                         bHandled = true;
1261                         break;
1262                 case TE_CSQC_WEAPONCOMPLAIN:
1263                         Net_WeaponComplain();
1264                         bHandled = true;
1265                         break;
1266                 case TE_CSQC_VEHICLESETUP:
1267                         Net_VehicleSetup();
1268                         bHandled = true;
1269                         break;
1270                 case TE_CSQC_SVNOTICE:
1271                         cl_notice_read();
1272                         bHandled = true;
1273                         break;
1274                 case TE_CSQC_SHOCKWAVEPARTICLE:
1275                         Net_ReadShockwaveParticle();
1276                         bHandled = true;
1277                         break;
1278                 default:
1279                         // No special logic for this temporary entity; return 0 so the engine can handle it
1280                         bHandled = false;
1281                         break;
1282         }
1283
1284         return bHandled;
1285 }
1286
1287 string getcommandkey(string text, string command)
1288 {
1289         string keys;
1290         float n, j, k, l = 0;
1291
1292         if (!autocvar_hud_showbinds)
1293                 return text;
1294
1295         keys = db_get(binddb, command);
1296         if (keys == "")
1297         {
1298                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1299                 for(j = 0; j < n; ++j)
1300                 {
1301                         k = stof(argv(j));
1302                         if(k != -1)
1303                         {
1304                                 if ("" == keys)
1305                                         keys = keynumtostring(k);
1306                                 else
1307                                         keys = strcat(keys, ", ", keynumtostring(k));
1308
1309                                 ++l;
1310                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1311                                         break;
1312                         }
1313
1314                 }
1315                 if (keys == "")
1316                         keys = "NO_KEY";
1317                 db_put(binddb, command, keys);
1318         }
1319
1320         if (keys == "NO_KEY") {
1321                 if (autocvar_hud_showbinds > 1)
1322                         return sprintf(_("%s (not bound)"), text);
1323                 else
1324                         return text;
1325         }
1326         else if (autocvar_hud_showbinds > 1)
1327                 return sprintf("%s (%s)", text, keys);
1328         else
1329                 return keys;
1330 }