qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include <common/effects/qc/all.qh>
   4 #include "hud/_mod.qh"
   5 #include "mapvoting.qh"
   6 #include "mutators/events.qh"
   7 #include "hud/panel/scoreboard.qh"
   8 #include "hud/panel/quickmenu.qh"
   9 #include "shownames.qh"
  10 #include <common/t_items.qh>
  11 #include "wall.qh"
  12 #include "weapons/projectile.qh"
  13 #include <common/deathtypes/all.qh>
  14 #include <common/items/_mod.qh>
  15 #include <common/mapinfo.qh>
  16 #include <common/minigames/cl_minigames.qh>
  17 #include <common/minigames/cl_minigames_hud.qh>
  18 #include <common/net_linked.qh>
  19 #include <common/net_notice.qh>
  20 #include <common/scores.qh>
  21 #include <common/triggers/include.qh>
  22 #include <common/vehicles/all.qh>
  23 #include <lib/csqcmodel/cl_model.qh>
  24 #include <lib/csqcmodel/interpolate.qh>
  25 #include <lib/warpzone/client.qh>
  26
  27 // --------------------------------------------------------------------------
  28 // BEGIN REQUIRED CSQC FUNCTIONS
  29 //include "main.qh"
  30
  31 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  32
  33 void draw_cursor(vector pos, vector ofs, string img, vector col, float a)
  34 {
  35         ofs = vec2(ofs.x * SIZE_CURSOR.x, ofs.y * SIZE_CURSOR.y);
  36         drawpic(pos - ofs, strcat(draw_currentSkin, img), SIZE_CURSOR, col, a, DRAWFLAG_NORMAL);
  37 }
  38
  39 void draw_cursor_normal(vector pos, vector col, float a)
  40 {
  41         draw_cursor(pos, OFFSET_CURSOR, "/cursor", col, a);
  42 }
  43
  44 void LoadMenuSkinValues()
  45 {
  46         int fh = -1;
  47         if(cvar_string("menu_skin") != "")
  48         {
  49                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  50                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  51         }
  52         if(fh < 0 && cvar_defstring("menu_skin") != "")
  53         {
  54                 cvar_set("menu_skin", cvar_defstring("menu_skin"));
  55                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  56                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  57         }
  58         if(fh < 0)
  59         {
  60                 draw_currentSkin = "gfx/menu/default";
  61                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  62         }
  63
  64         draw_currentSkin = strzone(draw_currentSkin);
  65
  66         if(fh >= 0)
  67         {
  68                 string s;
  69                 while((s = fgets(fh)))
  70                 {
  71                         int n = tokenize_console(s);
  72                         if (n < 2)
  73                                 continue;
  74                         if(substring(argv(0), 0, 2) == "//")
  75                                 continue;
  76                         if(argv(0) == "SIZE_CURSOR")
  77                                 SIZE_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  78                         else if(argv(0) == "OFFSET_CURSOR")
  79                                 OFFSET_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  80                 }
  81                 fclose(fh);
  82         }
  83 }
  84
  85 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  86 // Useful for precaching things
  87
  88 void ConsoleCommand_macro_init();
  89 void CSQC_Init()
  90 {
  91         prvm_language = strzone(cvar_string("prvm_language"));
  92
  93 #ifdef WATERMARK
  94         LOG_INFOF("^4CSQC Build information: ^1%s\n", WATERMARK);
  95 #endif
  96
  97         {
  98                 int i = 0;
  99                 for ( ; i < 255; ++i)
 100                         if (getplayerkeyvalue(i, "viewentity") == "")
 101                                 break;
 102                 maxclients = i;
 103         }
 104
 105         // needs to be done so early because of the constants they create
 106         static_init();
 107         static_init_late();
 108         static_init_precache();
 109
 110         binddb = db_create();
 111         tempdb = db_create();
 112         ClientProgsDB = db_load("client.db");
 113
 114         draw_endBoldFont();
 115
 116         //registercommand("hud_configure");
 117         //registercommand("hud_save");
 118         //registercommand("menu_action");
 119
 120         ConsoleCommand_macro_init();
 121
 122         registercvar("hud_usecsqc", "1");
 123         registercvar("scoreboard_columns", "default");
 124
 125         registercvar("cl_nade_type", "3");
 126         registercvar("cl_pokenade_type", "zombie");
 127
 128         registercvar("cl_jumpspeedcap_min", "");
 129         registercvar("cl_jumpspeedcap_max", "");
 130
 131         registercvar("cl_multijump", "1");
 132
 133         registercvar("cl_spawn_near_teammate", "1");
 134
 135         if(autocvar_cl_lockview)
 136                 cvar_set("cl_lockview", "0");
 137
 138         gametype = NULL;
 139
 140         postinit = false;
 141
 142         calledhooks = 0;
 143
 144         teams = Sort_Spawn();
 145         players = Sort_Spawn();
 146
 147         GetTeam(NUM_SPECTATOR, true); // add specs first
 148
 149         // precaches
 150
 151         if(autocvar_cl_reticle)
 152         {
 153                 precache_pic("gfx/reticle_normal");
 154                 // weapon reticles are precached in weapon files
 155         }
 156
 157         {
 158                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 159                 minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 160                 shortmapname = mi_shortname;
 161
 162                 if (precache_pic(minimapname) == "")
 163                 {
 164                         // but maybe we have a non-clever minimap
 165                         minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 166                         if (precache_pic(minimapname) == "")
 167                                 minimapname = ""; // FAIL
 168                         else
 169                                 get_mi_min_max_texcoords(0); // load new texcoords
 170                 }
 171
 172                 mi_center = (mi_min + mi_max) * 0.5;
 173                 mi_scale = mi_max - mi_min;
 174                 minimapname = strzone(minimapname);
 175         }
 176
 177         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 178         LoadMenuSkinValues();
 179 }
 180
 181 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 182 void Shutdown()
 183 {
 184         WarpZone_Shutdown();
 185
 186         delete(teams);
 187         delete(players);
 188         db_close(binddb);
 189         db_close(tempdb);
 190         if(autocvar_cl_db_saveasdump)
 191                 db_dump(ClientProgsDB, "client.db");
 192         else
 193                 db_save(ClientProgsDB, "client.db");
 194         db_close(ClientProgsDB);
 195
 196         if(camera_active)
 197                 cvar_set("chase_active",ftos(chase_active_backup));
 198
 199         // unset the event chasecam's chase_active
 200         if(autocvar_chase_active < 0)
 201                 cvar_set("chase_active", "0");
 202
 203         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 204
 205         if (!isdemo())
 206         {
 207                 if (!(calledhooks & HOOK_START))
 208                         localcmd("\n_cl_hook_gamestart nop\n");
 209                 if (!(calledhooks & HOOK_END))
 210                         localcmd("\ncl_hook_gameend\n");
 211         }
 212
 213         localcmd("\ncl_hook_shutdown\n");
 214
 215         deactivate_minigame();
 216         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 217 }
 218
 219 .float has_team;
 220 float SetTeam(entity o, int Team)
 221 {
 222     TC(int, Team);
 223         devassert_once(Team);
 224         entity tm;
 225         if(teamplay)
 226         {
 227                 switch(Team)
 228                 {
 229                         case -1:
 230                         case NUM_TEAM_1:
 231                         case NUM_TEAM_2:
 232                         case NUM_TEAM_3:
 233                         case NUM_TEAM_4:
 234                                 break;
 235                         default:
 236                                 if(GetTeam(Team, false) == NULL)
 237                                 {
 238                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 239                                         Team = NUM_SPECTATOR;
 240                                 }
 241                                 break;
 242                 }
 243         }
 244         else
 245         {
 246                 switch(Team)
 247                 {
 248                         case -1:
 249                         case 0:
 250                                 break;
 251                         default:
 252                                 if(GetTeam(Team, false) == NULL)
 253                                 {
 254                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 255                                         Team = NUM_SPECTATOR;
 256                                 }
 257                                 break;
 258                 }
 259         }
 260         if(Team == -1) // leave
 261         {
 262                 if(o.has_team)
 263                 {
 264                         tm = GetTeam(o.team, false);
 265                         tm.team_size -= 1;
 266                         o.has_team = 0;
 267                         return true;
 268                 }
 269         }
 270         else
 271         {
 272                 if (!o.has_team)
 273                 {
 274                         o.team = Team;
 275                         tm = GetTeam(Team, true);
 276                         tm.team_size += 1;
 277                         o.has_team = 1;
 278                         return true;
 279                 }
 280                 else if(Team != o.team)
 281                 {
 282                         tm = GetTeam(o.team, false);
 283                         tm.team_size -= 1;
 284                         o.team = Team;
 285                         tm = GetTeam(Team, true);
 286                         tm.team_size += 1;
 287                         return true;
 288                 }
 289         }
 290         return false;
 291 }
 292
 293 void Playerchecker_Think(entity this)
 294 {
 295     int i;
 296         entity e;
 297         for(i = 0; i < maxclients; ++i)
 298         {
 299                 e = playerslots[i];
 300                 if(entcs_GetName(i) == "")
 301                 {
 302                         if(e.sort_prev)
 303                         {
 304                                 // player disconnected
 305                                 SetTeam(e, -1);
 306                                 RemovePlayer(e);
 307                                 e.sort_prev = NULL;
 308                                 //e.gotscores = 0;
 309                         }
 310                 }
 311                 else
 312                 {
 313                         if (!e.sort_prev)
 314                         {
 315                                 // player connected
 316                                 if (!e)
 317                                 {
 318                                         playerslots[i] = e = new_pure(playerslot);
 319                                 }
 320                                 e.sv_entnum = i;
 321                                 e.ping = 0;
 322                                 e.ping_packetloss = 0;
 323                                 e.ping_movementloss = 0;
 324                                 //e.gotscores = 0; // we might already have the scores...
 325                                 int t = entcs_GetScoreTeam(i);
 326                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 327                                 RegisterPlayer(e);
 328                                 Scoreboard_UpdatePlayerPos(e);
 329                         }
 330                 }
 331         }
 332         this.nextthink = time + 0.2;
 333 }
 334
 335 void TrueAim_Init();
 336 void PostInit()
 337 {
 338         entity playerchecker = new_pure(playerchecker);
 339         setthink(playerchecker, Playerchecker_Think);
 340         playerchecker.nextthink = time + 0.2;
 341
 342         TrueAim_Init();
 343
 344         postinit = true;
 345 }
 346
 347 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 348 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 349 // All keys are in ascii.
 350 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 351 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 352 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 353 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 354 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 355 {
 356     TC(int, bInputType);
 357         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 358                 return true;
 359
 360         if (QuickMenu_InputEvent(bInputType, nPrimary, nSecondary))
 361                 return true;
 362
 363         if (HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary))
 364                 return true;
 365
 366         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 367                 return true;
 368
 369         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
 370                 return true;
 371
 372         return false;
 373 }
 374
 375 // END REQUIRED CSQC FUNCTIONS
 376 // --------------------------------------------------------------------------
 377
 378 // --------------------------------------------------------------------------
 379 // BEGIN OPTIONAL CSQC FUNCTIONS
 380
 381 void Ent_Remove(entity this);
 382
 383 void Ent_RemovePlayerScore(entity this)
 384 {
 385         if(this.owner) {
 386                 SetTeam(this.owner, -1);
 387                 this.owner.gotscores = 0;
 388                 FOREACH(Scores, true, {
 389                         this.owner.(scores(it)) = 0; // clear all scores
 390                 });
 391         }
 392 }
 393
 394 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 395 {
 396         make_pure(this);
 397         entity o;
 398
 399         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 400         // (no I've never heard of M-x replace-string, sed, or anything like that)
 401         bool isNew = !this.owner; // workaround for DP bug
 402         int n = ReadByte()-1;
 403
 404 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 405         if(!isNew && n != this.sv_entnum)
 406         {
 407                 //print("A CSQC entity changed its owner!\n");
 408                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", etof(this), this.classname);
 409                 isNew = true;
 410                 Ent_Remove(this);
 411         }
 412 #endif
 413
 414         this.sv_entnum = n;
 415
 416         o = playerslots[this.sv_entnum];
 417         if (!o)
 418         {
 419                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 420         }
 421         this.owner = o;
 422         o.sv_entnum = this.sv_entnum;
 423         o.gotscores = 1;
 424
 425         //if (!o.sort_prev)
 426         //      RegisterPlayer(o);
 427         //playerchecker will do this for us later, if it has not already done so
 428
 429     int sf, lf;
 430         sf = ReadShort();
 431         lf = ReadShort();
 432         FOREACH(Scores, true, {
 433         int p = 1 << (i % 16);
 434                 if (sf & p)
 435                 {
 436                         if (lf & p)
 437                                 o.(scores(it)) = ReadInt24_t();
 438                         else
 439                                 o.(scores(it)) = ReadChar();
 440                 }
 441     });
 442
 443         return = true;
 444
 445         if(o.sort_prev)
 446                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 447
 448         this.entremove = Ent_RemovePlayerScore;
 449 }
 450
 451 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 452 {
 453         make_pure(this);
 454         int i;
 455         entity o;
 456
 457         this.team = ReadByte();
 458         o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 459
 460     int sf, lf;
 461 #if MAX_TEAMSCORE <= 8
 462         sf = ReadByte();
 463         lf = ReadByte();
 464 #else
 465         sf = ReadShort();
 466         lf = ReadShort();
 467 #endif
 468         int p;
 469         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 470                 if(sf & p)
 471                 {
 472                         if(lf & p)
 473                                 o.(teamscores(i)) = ReadInt24_t();
 474                         else
 475                                 o.(teamscores(i)) = ReadChar();
 476                 }
 477
 478         return = true;
 479
 480         Scoreboard_UpdateTeamPos(o);
 481 }
 482
 483 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 484 {
 485         make_pure(this);
 486         float newspectatee_status;
 487
 488     int f = ReadByte();
 489
 490         scoreboard_showscores_force = (f & 1);
 491
 492         if(f & 2)
 493         {
 494                 newspectatee_status = ReadByte();
 495                 if(newspectatee_status == player_localnum + 1)
 496                         newspectatee_status = -1; // observing
 497         }
 498         else
 499                 newspectatee_status = 0;
 500
 501         spectatorbutton_zoom = (f & 4);
 502
 503         if(f & 16)
 504         {
 505                 num_spectators = ReadByte();
 506
 507                 float i, slot;
 508
 509                 for(i = 0; i < MAX_SPECTATORS; ++i)
 510                         spectatorlist[i] = 0; // reset list first
 511
 512                 for(i = 0; i < num_spectators; ++i)
 513                 {
 514                         slot = ReadByte();
 515                         spectatorlist[i] = slot - 1;
 516                 }
 517         }
 518
 519         return = true;
 520
 521         if(newspectatee_status != spectatee_status)
 522         {
 523                 // clear race stuff
 524                 race_laptime = 0;
 525                 race_checkpointtime = 0;
 526                 hud_dynamic_shake_factor = -1;
 527         }
 528         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 529         {
 530                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 531                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 532                 )
 533                         prev_p_health = -1;
 534                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 535                         prev_health = -1;
 536         }
 537         spectatee_status = newspectatee_status;
 538
 539         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 540 }
 541
 542 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 543 {
 544         make_pure(this);
 545     int i, j, b, f;
 546
 547     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 548
 549         if(!(nags & BIT(2)))
 550         {
 551                 if(vote_called_vote)
 552                         strunzone(vote_called_vote);
 553                 vote_called_vote = string_null;
 554                 vote_active = 0;
 555         }
 556         else
 557         {
 558                 vote_active = 1;
 559         }
 560
 561         if(nags & BIT(6))
 562         {
 563                 vote_yescount = ReadByte();
 564                 vote_nocount = ReadByte();
 565                 vote_needed = ReadByte();
 566                 vote_highlighted = ReadChar();
 567         }
 568
 569         if(nags & BIT(7))
 570         {
 571                 if(vote_called_vote)
 572                         strunzone(vote_called_vote);
 573                 vote_called_vote = strzone(ReadString());
 574         }
 575
 576         if(nags & 1)
 577         {
 578                 for(j = 0; j < maxclients; ++j)
 579                         if(playerslots[j])
 580                                 playerslots[j].ready = 1;
 581                 for(i = 1; i <= maxclients; i += 8)
 582                 {
 583                         f = ReadByte();
 584                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 585                                 if (!(f & b))
 586                                         if(playerslots[j])
 587                                                 playerslots[j].ready = 0;
 588                 }
 589         }
 590
 591         return = true;
 592
 593         ready_waiting = (nags & BIT(0));
 594         ready_waiting_for_me = (nags & BIT(1));
 595         vote_waiting = (nags & BIT(2));
 596         vote_waiting_for_me = (nags & BIT(3));
 597         warmup_stage = (nags & BIT(4));
 598 }
 599
 600 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 601 {
 602         make_pure(this);
 603     int i, j, b, f;
 604
 605     int sf = ReadByte();
 606         if(sf & 1)
 607         {
 608                 for(j = 0; j < maxclients; ++j)
 609                         if(playerslots[j])
 610                                 playerslots[j].eliminated = 1;
 611                 for(i = 1; i <= maxclients; i += 8)
 612                 {
 613                         f = ReadByte();
 614                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 615                                 if (!(f & b))
 616                                         if(playerslots[j])
 617                                                 playerslots[j].eliminated = 0;
 618                 }
 619         }
 620         return true;
 621 }
 622
 623 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 624 {
 625         make_pure(this);
 626         prandom_debug();
 627         float s = ReadShort();
 628         psrandom(s);
 629         return true;
 630 }
 631
 632 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 633 {
 634         make_pure(this);
 635     int sf = ReadInt24_t();
 636         if (sf == 0) {
 637                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 638                         weapon_accuracy[w] = -1;
 639                 return true;
 640         }
 641
 642         int f = 1;
 643         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 644                 if (sf & f) {
 645             int b = ReadByte();
 646                         if (b == 0)
 647                                 weapon_accuracy[w] = -1;
 648                         else if (b == 255)
 649                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 650                         else
 651                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 652                 }
 653                 f = (f == 0x800000) ? 1 : f * 2;
 654         }
 655         return true;
 656 }
 657
 658 void Spawn_Draw(entity this)
 659 {
 660         __pointparticles(this.cnt, this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 661 }
 662
 663 void Spawn_PreDraw(entity this)
 664 {
 665         float alph;
 666         vector org = getpropertyvec(VF_ORIGIN);
 667         if(this.fade_start)
 668                 alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 669         else
 670                 alph = 1;
 671         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 672         this.alpha = alph;
 673         if(alph <= 0)
 674                 this.drawmask = 0;
 675         else
 676                 this.drawmask = MASK_NORMAL;
 677 }
 678
 679 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 680 {
 681         float teamnum = (ReadByte() - 1);
 682         vector spn_origin;
 683         spn_origin.x = ReadCoord();
 684         spn_origin.y = ReadCoord();
 685         spn_origin.z = ReadCoord();
 686
 687         this.team = (teamnum + 1);
 688
 689         //if(is_new)
 690         //{
 691                 this.origin = spn_origin;
 692                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 693                 //droptofloor();
 694
 695                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 696                 {
 697                         this.mdl = "models/spawnpoint.md3";
 698                         this.colormod = Team_ColorRGB(teamnum);
 699                         precache_model(this.mdl);
 700                         setmodel(this, this.mdl);
 701                         this.drawmask = MASK_NORMAL;
 702                         //this.move_movetype = MOVETYPE_NOCLIP;
 703                         //this.draw = Spawn_Draw;
 704                         IL_PUSH(g_drawables, this);
 705                 }*/
 706                 if(autocvar_cl_spawn_point_particles)
 707                 {
 708                         if(teamplay)
 709                         {
 710                                 switch(teamnum)
 711                                 {
 712                                         case NUM_TEAM_1: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
 713                                         case NUM_TEAM_2: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
 714                                         case NUM_TEAM_3: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
 715                                         case NUM_TEAM_4: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
 716                                         default: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
 717                                 }
 718                         }
 719                         else { this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
 720
 721                         this.draw = Spawn_Draw;
 722                         if (is_new) IL_PUSH(g_drawables, this);
 723                         setpredraw(this, Spawn_PreDraw);
 724                         this.fade_start = autocvar_cl_spawn_point_dist_min;
 725                         this.fade_end = autocvar_cl_spawn_point_dist_max;
 726                 }
 727         //}
 728
 729         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 730         return true;
 731 }
 732
 733 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 734 {
 735         // If entnum is 0, ONLY do the local spawn actions
 736         // this way the server can disable the sending of
 737         // spawn origin or such to clients if wanted.
 738         float entnum = ReadByte();
 739
 740         if(entnum)
 741         {
 742                 this.origin_x = ReadCoord();
 743                 this.origin_y = ReadCoord();
 744                 this.origin_z = ReadCoord();
 745
 746                 if(is_new)
 747                 {
 748                         float teamnum = entcs_GetTeam(entnum - 1);
 749
 750                         if(autocvar_cl_spawn_event_particles)
 751                         {
 752                                 switch(teamnum)
 753                                 {
 754                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 755                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 756                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 757                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 758                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 759                                 }
 760                         }
 761                         if(autocvar_cl_spawn_event_sound)
 762                         {
 763                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 764                         }
 765                 }
 766         }
 767         return = true;
 768
 769         // local spawn actions
 770         if(is_new && (!entnum || (entnum == player_localentnum)))
 771         {
 772                 zoomin_effect = 1;
 773                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 774
 775                 if(autocvar_cl_unpress_zoom_on_spawn)
 776                 {
 777                         localcmd("-zoom\n");
 778                         button_zoom = false;
 779                 }
 780                 HUD_Radar_Hide_Maximized();
 781         }
 782         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 783 }
 784
 785 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 786 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 787 void CSQC_Ent_Update(entity this, bool isnew)
 788 {
 789         this.sourceLoc = __FILE__ ":" STR(__LINE__);
 790         int t = ReadByte();
 791
 792         // set up the "time" global for received entities to be correct for interpolation purposes
 793         float savetime = time;
 794         if(servertime)
 795         {
 796                 time = servertime;
 797         }
 798         else
 799         {
 800                 serverprevtime = time;
 801                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 802                 time = serverprevtime + serverdeltatime;
 803         }
 804
 805 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 806         if (this.enttype)
 807         {
 808                 if (t != this.enttype || isnew)
 809                 {
 810                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", etof(this), this.entnum, this.enttype, t);
 811                         Ent_Remove(this);
 812                         clearentity(this);
 813                         isnew = true;
 814                 }
 815         }
 816         else
 817         {
 818                 if (!isnew)
 819                 {
 820                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", etof(this), this.entnum, t);
 821                         isnew = true;
 822                 }
 823         }
 824 #endif
 825         this.enttype = t;
 826         bool done = false;
 827         FOREACH(LinkedEntities, it.m_id == t, {
 828                 if (isnew) this.classname = it.netname;
 829                 if (autocvar_developer_csqcentities)
 830             LOG_INFOF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)\n", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 831                 done = it.m_read(this, NULL, isnew);
 832                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 833                 break;
 834         });
 835         time = savetime;
 836         if (!done)
 837         {
 838                 LOG_FATALF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 839         }
 840 }
 841
 842 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 843 // used when an entity changes its type. For an entity that someone interacts
 844 // with others, make sure it can no longer do so.
 845 void Ent_Remove(entity this)
 846 {
 847         if(this.entremove) this.entremove(this);
 848
 849         if(this.skeletonindex)
 850         {
 851                 skel_delete(this.skeletonindex);
 852                 this.skeletonindex = 0;
 853         }
 854
 855         if(this.snd_looping > 0)
 856         {
 857                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 858                 this.snd_looping = 0;
 859         }
 860
 861         this.enttype = 0;
 862         this.classname = "";
 863         this.draw = func_null;
 864         this.entremove = func_null;
 865         // TODO possibly set more stuff to defaults
 866 }
 867 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 868 void CSQC_Ent_Remove(entity this)
 869 {
 870         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}\n", this, this.entnum, this.enttype);
 871         if (wasfreed(this))
 872         {
 873                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
 874                 return;
 875         }
 876         if (this.enttype) Ent_Remove(this);
 877         delete(this);
 878 }
 879
 880 void Gamemode_Init()
 881 {
 882         if (!isdemo())
 883         {
 884                 if(!(calledhooks & HOOK_START))
 885                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 886                 calledhooks |= HOOK_START;
 887         }
 888 }
 889 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 890 void CSQC_Parse_StuffCmd(string strMessage)
 891 {
 892         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 893         localcmd(strMessage);
 894 }
 895 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 896 void CSQC_Parse_Print(string strMessage)
 897 {
 898         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")\n", strMessage);
 899         print(ColorTranslateRGB(strMessage));
 900 }
 901
 902 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 903 void CSQC_Parse_CenterPrint(string strMessage)
 904 {
 905         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 906         centerprint_hud(strMessage);
 907 }
 908
 909 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
 910 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
 911 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
 912 bool CSQC_Parse_TempEntity()
 913 {
 914         // Acquire TE ID
 915         int nTEID = ReadByte();
 916
 917         FOREACH(TempEntities, it.m_id == nTEID, {
 918                 if (autocvar_developer_csqcentities)
 919                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)\n", it.netname, nTEID);
 920                 return it.m_read(NULL, NULL, true);
 921         });
 922
 923         if (autocvar_developer_csqcentities)
 924                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
 925
 926         // No special logic for this temporary entity; return 0 so the engine can handle it
 927         return false;
 928 }
 929
 930 string forcefog;
 931 void Fog_Force()
 932 {
 933         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 934                 localcmd("\nr_drawfog 0\n");
 935         else if (forcefog != "")
 936                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
 937 }
 938
 939 void Gamemode_Init();
 940 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
 941 {
 942         make_pure(this);
 943         gametype = ReadRegistered(Gametypes);
 944         teamplay = _MapInfo_GetTeamPlayBool(gametype);
 945         HUD_ModIcons_SetFunc();
 946         FOREACH(Scores, true, {
 947                 if (scores_label(it)) strunzone(scores_label(it));
 948                 scores_label(it) = strzone(ReadString());
 949                 scores_flags(it) = ReadByte();
 950         });
 951         for (int i = 0; i < MAX_TEAMSCORE; ++i)
 952         {
 953                 if (teamscores_label(i)) strunzone(teamscores_label(i));
 954                 teamscores_label(i) = strzone(ReadString());
 955                 teamscores_flags(i) = ReadByte();
 956         }
 957         return = true;
 958         Scoreboard_InitScores();
 959         Gamemode_Init();
 960 }
 961
 962 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
 963 {
 964         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 965
 966         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 967         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 968         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 969         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 970         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 971         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 972         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 973         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 974
 975         if (forcefog) strunzone(forcefog);
 976         forcefog = strzone(ReadString());
 977
 978         armorblockpercent = ReadByte() / 255.0;
 979         damagepush_speedfactor = ReadByte() / 255.0;
 980
 981         serverflags = ReadByte();
 982
 983         g_trueaim_minrange = ReadCoord();
 984
 985         return = true;
 986
 987         MUTATOR_CALLHOOK(Ent_Init);
 988
 989         if (!postinit) PostInit();
 990 }
 991
 992 float GetSpeedUnitFactor(int speed_unit)
 993 {
 994         switch(speed_unit)
 995         {
 996                 default:
 997                 case 1:
 998                         return 1.0;
 999                 case 2:
1000                         return 0.0254;
1001                 case 3:
1002                         return 0.0254 * 3.6;
1003                 case 4:
1004                         return 0.0254 * 3.6 * 0.6213711922;
1005                 case 5:
1006                         return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1007         }
1008 }
1009
1010 string GetSpeedUnit(int speed_unit)
1011 {
1012         switch(speed_unit)
1013         {
1014                 default:
1015                 case 1:
1016                         return _(" qu/s");
1017                 case 2:
1018                         return _(" m/s");
1019                 case 3:
1020                         return _(" km/h");
1021                 case 4:
1022                         return _(" mph");
1023                 case 5:
1024                         return _(" knots");
1025         }
1026 }
1027
1028 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1029 {
1030         int b = ReadByte();
1031
1032         switch (b)
1033         {
1034                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1035                         race_checkpoint = ReadByte();
1036                         race_time = ReadInt24_t();
1037                         race_previousbesttime = ReadInt24_t();
1038                         race_mypreviousbesttime = ReadInt24_t();
1039                         if(race_previousbestname)
1040                                 strunzone(race_previousbestname);
1041                         string pbestname = ReadString();
1042                         if(autocvar_cl_race_cptimes_onlyself)
1043                         {
1044                                 race_previousbesttime = race_mypreviousbesttime;
1045                                 race_mypreviousbesttime = 0;
1046                                 race_previousbestname = strzone("");
1047                         }
1048                         else
1049                                 race_previousbestname = strzone(pbestname);
1050
1051                         race_checkpointtime = time;
1052
1053                         if(race_checkpoint == 0 || race_checkpoint == 254)
1054                         {
1055                                 race_penaltyaccumulator = 0;
1056                                 race_laptime = time; // valid
1057                         }
1058                         break;
1059
1060                 case RACE_NET_CHECKPOINT_CLEAR:
1061                         race_laptime = 0;
1062                         race_checkpointtime = 0;
1063                         break;
1064
1065                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1066                         race_laptime = ReadCoord();
1067                         race_checkpointtime = -99999;
1068                         // fall through
1069                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1070                         race_nextcheckpoint = ReadByte();
1071
1072                         race_nextbesttime = ReadInt24_t();
1073                         race_mybesttime = ReadInt24_t();
1074                         if(race_nextbestname)
1075                                 strunzone(race_nextbestname);
1076                         string newname = ReadString();
1077                         if(autocvar_cl_race_cptimes_onlyself)
1078                         {
1079                                 race_nextbesttime = race_mybesttime;
1080                                 race_mybesttime = 0;
1081                                 race_nextbestname = strzone("");
1082                         }
1083                         else
1084                                 race_nextbestname = strzone(newname);
1085                         break;
1086
1087                 case RACE_NET_CHECKPOINT_HIT_RACE:
1088                         race_mycheckpoint = ReadByte();
1089                         race_mycheckpointtime = time;
1090                         race_mycheckpointdelta = ReadInt24_t();
1091                         race_mycheckpointlapsdelta = ReadByte();
1092                         if(race_mycheckpointlapsdelta >= 128)
1093                                 race_mycheckpointlapsdelta -= 256;
1094                         if(race_mycheckpointenemy)
1095                                 strunzone(race_mycheckpointenemy);
1096                         int who = ReadByte();
1097                         if(who)
1098                                 race_mycheckpointenemy = strzone(entcs_GetName(who - 1));
1099                         else
1100                                 race_mycheckpointenemy = strzone(""); // TODO: maybe string_null works fine here?
1101                         break;
1102
1103                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1104                         race_othercheckpoint = ReadByte();
1105                         race_othercheckpointtime = time;
1106                         race_othercheckpointdelta = ReadInt24_t();
1107                         race_othercheckpointlapsdelta = ReadByte();
1108                         if(race_othercheckpointlapsdelta >= 128)
1109                                 race_othercheckpointlapsdelta -= 256;
1110                         if(race_othercheckpointenemy)
1111                                 strunzone(race_othercheckpointenemy);
1112                         int what = ReadByte();
1113                         if(what)
1114                                 race_othercheckpointenemy = strzone(entcs_GetName(what - 1));
1115                         else
1116                                 race_othercheckpointenemy = strzone(""); // TODO: maybe string_null works fine here?
1117                         break;
1118
1119                 case RACE_NET_PENALTY_RACE:
1120                         race_penaltyeventtime = time;
1121                         race_penaltytime = ReadShort();
1122                         //race_penaltyaccumulator += race_penaltytime;
1123                         if(race_penaltyreason)
1124                                 strunzone(race_penaltyreason);
1125                         race_penaltyreason = strzone(ReadString());
1126                         break;
1127
1128                 case RACE_NET_PENALTY_QUALIFYING:
1129                         race_penaltyeventtime = time;
1130                         race_penaltytime = ReadShort();
1131                         race_penaltyaccumulator += race_penaltytime;
1132                         if(race_penaltyreason)
1133                                 strunzone(race_penaltyreason);
1134                         race_penaltyreason = strzone(ReadString());
1135                         break;
1136
1137                 case RACE_NET_SERVER_RECORD:
1138                         race_server_record = ReadInt24_t();
1139                         break;
1140                 case RACE_NET_SPEED_AWARD:
1141                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1142                         if(race_speedaward_holder)
1143                                 strunzone(race_speedaward_holder);
1144                         race_speedaward_holder = strzone(ReadString());
1145                         if(race_speedaward_unit)
1146                                 strunzone(race_speedaward_unit);
1147                         race_speedaward_unit = strzone(GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1148                         break;
1149                 case RACE_NET_SPEED_AWARD_BEST:
1150                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1151                         if(race_speedaward_alltimebest_holder)
1152                                 strunzone(race_speedaward_alltimebest_holder);
1153                         race_speedaward_alltimebest_holder = strzone(ReadString());
1154                         if(race_speedaward_alltimebest_unit)
1155                                 strunzone(race_speedaward_alltimebest_unit);
1156                         race_speedaward_alltimebest_unit = strzone(GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1157                         break;
1158                 case RACE_NET_SERVER_RANKINGS:
1159                         float prevpos, del;
1160             int pos = ReadShort();
1161                         prevpos = ReadShort();
1162                         del = ReadShort();
1163
1164                         // move other rankings out of the way
1165             int i;
1166                         if (prevpos) {
1167                                 for (i=prevpos-1;i>pos-1;--i) {
1168                                         grecordtime[i] = grecordtime[i-1];
1169                                         if(grecordholder[i])
1170                                                 strunzone(grecordholder[i]);
1171                                         grecordholder[i] = strzone(grecordholder[i-1]);
1172                                 }
1173                         } else if (del) { // a record has been deleted by the admin
1174                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1175                                         if (i == RANKINGS_CNT-1) { // clear out last record
1176                                                 grecordtime[i] = 0;
1177                                                 if (grecordholder[i])
1178                                                         strunzone(grecordholder[i]);
1179                                                 grecordholder[i] = string_null;
1180                                         }
1181                                         else {
1182                                                 grecordtime[i] = grecordtime[i+1];
1183                                                 if (grecordholder[i])
1184                                                         strunzone(grecordholder[i]);
1185                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1186                                         }
1187                                 }
1188                         } else { // player has no ranked record yet
1189                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1190                                         grecordtime[i] = grecordtime[i-1];
1191                                         if(grecordholder[i])
1192                                                 strunzone(grecordholder[i]);
1193                                         grecordholder[i] = strzone(grecordholder[i-1]);
1194                                 }
1195                         }
1196
1197                         // store new ranking
1198                         if(grecordholder[pos-1] != "")
1199                                 strunzone(grecordholder[pos-1]);
1200                         grecordholder[pos-1] = strzone(ReadString());
1201                         grecordtime[pos-1] = ReadInt24_t();
1202                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1203                                 race_myrank = pos;
1204                         break;
1205                 case RACE_NET_SERVER_STATUS:
1206                         race_status = ReadShort();
1207                         if(race_status_name)
1208                                 strunzone(race_status_name);
1209                         race_status_name = strzone(ReadString());
1210         }
1211         return true;
1212 }
1213
1214 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1215 {
1216         teamnagger = 1;
1217         return true;
1218 }
1219
1220 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1221 {
1222         int i = ReadByte();
1223         int pi = ReadShort();
1224         int pl = ReadByte();
1225         int ml = ReadByte();
1226         return = true;
1227         entity e = playerslots[i];
1228         if (!e) return;
1229         e.ping = pi;
1230         e.ping_packetloss = pl / 255.0;
1231         e.ping_movementloss = ml / 255.0;
1232 }
1233
1234 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1235 {
1236         complain_weapon = ReadByte();
1237         complain_weapon_type = ReadByte();
1238         return = true;
1239
1240         complain_weapon_time = time;
1241         weapontime = time; // ping the weapon panel
1242
1243         switch(complain_weapon_type)
1244         {
1245                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1246                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1247                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1248         }
1249 }
1250
1251 string _getcommandkey(string cmd_name, string command, bool forcename)
1252 {
1253         string keys;
1254         float n, j, k, l = 0;
1255
1256         if (!autocvar_hud_showbinds)
1257                 return cmd_name;
1258
1259         keys = db_get(binddb, command);
1260         if (keys == "")
1261         {
1262                 bool joy_active = cvar("joy_active");
1263                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1264                 for(j = 0; j < n; ++j)
1265                 {
1266                         k = stof(argv(j));
1267                         if(k != -1)
1268                         {
1269                                 string key = keynumtostring(k);
1270                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1271                                         continue;
1272
1273                                 if (keys == "")
1274                                         keys = key;
1275                                 else
1276                                         keys = strcat(keys, ", ", key);
1277
1278                                 ++l;
1279                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1280                                         break;
1281                         }
1282
1283                 }
1284                 if (keys == "")
1285                         keys = "NO_KEY";
1286                 db_put(binddb, command, keys);
1287         }
1288
1289         if (keys == "NO_KEY") {
1290                 if (autocvar_hud_showbinds > 1)
1291                         return sprintf(_("%s (not bound)"), cmd_name);
1292                 else
1293                         return cmd_name;
1294         }
1295         else if (autocvar_hud_showbinds > 1 || forcename)
1296                 return sprintf("%s (%s)", cmd_name, keys);
1297         else
1298                 return keys;
1299 }