qcsrc/client/main.qc

   1 #include "main.qh"
   2 #include "_all.qh"
   3
   4 #include "casings.qh"
   5 #include "csqcmodel_hooks.qh"
   6 #include "damage.qh"
   7 #include "effects.qh"
   8 #include "gibs.qh"
   9 #include "hook.qh"
  10 #include "hud.qh"
  11 #include "hud_config.qh"
  12 #include "laser.qh"
  13 #include "mapvoting.qh"
  14 #include "modeleffects.qh"
  15 #include "particles.qh"
  16 #include "prandom.qh"
  17 #include "scoreboard.qh"
  18 #include "shownames.qh"
  19 #include "sortlist.qh"
  20 #include "tturrets.qh"
  21 #include "tuba.qh"
  22 #include "t_items.qh"
  23 #include "wall.qh"
  24 #include "waypointsprites.qh"
  25
  26 #include "vehicles/bumblebee.qh"
  27 #include "vehicles/all.qh"
  28
  29 #include "weapons/projectile.qh"
  30
  31 #include "../common/buffs.qh"
  32 #include "../common/deathtypes.qh"
  33 #include "../common/mapinfo.qh"
  34 #include "../common/monsters/all.qh"
  35 #include "../common/nades.qh"
  36 #include "../common/net_notice.qh"
  37 #include "../common/notifications.qh"
  38 #include "../common/stats.qh"
  39 #include "../common/teams.qh"
  40
  41 #include "../common/items/all.qh"
  42
  43 #include "../common/weapons/all.qh"
  44
  45 #include "../csqcmodellib/cl_model.qh"
  46 #include "../csqcmodellib/interpolate.qh"
  47
  48 #include "../common/triggers/include.qh"
  49
  50 #include "../warpzonelib/client.qh"
  51
  52 // --------------------------------------------------------------------------
  53 // BEGIN REQUIRED CSQC FUNCTIONS
  54 //include "main.qh"
  55
  56 entity clearentity_ent;
  57 void clearentity(entity e)
  58 {
  59         if (!clearentity_ent)
  60         {
  61                 clearentity_ent = spawn();
  62                 clearentity_ent.classname = "clearentity";
  63         }
  64         int n = e.entnum;
  65         copyentity(clearentity_ent, e);
  66         e.entnum = n;
  67 }
  68
  69 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  70 void menu_show_error()
  71 {
  72         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  73 }
  74
  75 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  76 // Useful for precaching things
  77
  78 void menu_sub_null()
  79 {
  80 }
  81
  82 string forcefog;
  83 void WaypointSprite_Load();
  84 void ConsoleCommand_macro_init();
  85 void CSQC_Init(void)
  86 {
  87         prvm_language = cvar_string("prvm_language");
  88
  89 #ifdef WATERMARK
  90         dprintf("^4CSQC Build information: ^1%s\n", WATERMARK);
  91 #endif
  92
  93         int i;
  94
  95         binddb = db_create();
  96         tempdb = db_create();
  97         ClientProgsDB = db_load("client.db");
  98         compressShortVector_init();
  99
 100         draw_endBoldFont();
 101         menu_visible = false;
 102         menu_show = menu_show_error;
 103         menu_action = func_null;
 104
 105         for(i = 0; i < 255; ++i)
 106                 if(getplayerkeyvalue(i, "viewentity") == "")
 107                         break;
 108         maxclients = i;
 109
 110         //registercommand("hud_configure");
 111         //registercommand("hud_save");
 112         //registercommand("menu_action");
 113
 114         ConsoleCommand_macro_init();
 115
 116         registercvar("hud_usecsqc", "1");
 117         registercvar("scoreboard_columns", "default");
 118
 119         registercvar("cl_nade_type", "3");
 120         registercvar("cl_pokenade_type", "zombie");
 121
 122         registercvar("cl_jumpspeedcap_min", "");
 123         registercvar("cl_jumpspeedcap_max", "");
 124
 125         gametype = 0;
 126
 127         // hud_fields uses strunzone on the titles!
 128         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 129                 hud_title[i] = strzone("(null)");
 130
 131         Cmd_HUD_SetFields(0);
 132
 133         postinit = false;
 134
 135         calledhooks = 0;
 136
 137         teams = Sort_Spawn();
 138         players = Sort_Spawn();
 139
 140         GetTeam(NUM_SPECTATOR, true); // add specs first
 141
 142         // needs to be done so early because of the constants they create
 143         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 144         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 145         CALL_ACCUMULATED_FUNCTION(RegisterItems);
 146         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 147         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 148         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 149         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
 150         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 151
 152         WaypointSprite_Load();
 153
 154         // precaches
 155         precache_model("null");
 156         precache_sound("misc/hit.wav");
 157         precache_sound("misc/typehit.wav");
 158
 159         Projectile_Precache();
 160         Hook_Precache();
 161         GibSplash_Precache();
 162         Casings_Precache();
 163         Vehicles_Precache();
 164         turrets_precache();
 165         Tuba_Precache();
 166         CSQCPlayer_Precache();
 167
 168         if(autocvar_cl_reticle)
 169         {
 170                 precache_pic("gfx/reticle_normal");
 171                 // weapon reticles are precached in weapon files
 172         }
 173
 174         get_mi_min_max_texcoords(1); // try the CLEVER way first
 175         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 176         shortmapname = mi_shortname;
 177
 178         if(precache_pic(minimapname) == "")
 179         {
 180                 // but maybe we have a non-clever minimap
 181                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 182                 if(precache_pic(minimapname) == "")
 183                         minimapname = ""; // FAIL
 184                 else
 185                         get_mi_min_max_texcoords(0); // load new texcoords
 186         }
 187
 188         mi_center = (mi_min + mi_max) * 0.5;
 189         mi_scale = mi_max - mi_min;
 190         minimapname = strzone(minimapname);
 191
 192         WarpZone_Init();
 193
 194         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 195         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 196 }
 197
 198 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 199 void Shutdown(void)
 200 {
 201         WarpZone_Shutdown();
 202
 203         remove(teams);
 204         remove(players);
 205         db_close(binddb);
 206         db_close(tempdb);
 207         if(autocvar_cl_db_saveasdump)
 208                 db_dump(ClientProgsDB, "client.db");
 209         else
 210                 db_save(ClientProgsDB, "client.db");
 211         db_close(ClientProgsDB);
 212
 213         if(camera_active)
 214                 cvar_set("chase_active",ftos(chase_active_backup));
 215
 216         // unset the event chasecam's chase_active
 217         if(autocvar_chase_active < 0)
 218                 cvar_set("chase_active", "0");
 219
 220         if (!isdemo())
 221         {
 222                 if (!(calledhooks & HOOK_START))
 223                         localcmd("\n_cl_hook_gamestart nop\n");
 224                 if (!(calledhooks & HOOK_END))
 225                         localcmd("\ncl_hook_gameend\n");
 226         }
 227 }
 228
 229 .float has_team;
 230 float SetTeam(entity o, int Team)
 231 {
 232         entity tm;
 233         if(teamplay)
 234         {
 235                 switch(Team)
 236                 {
 237                         case -1:
 238                         case NUM_TEAM_1:
 239                         case NUM_TEAM_2:
 240                         case NUM_TEAM_3:
 241                         case NUM_TEAM_4:
 242                                 break;
 243                         default:
 244                                 if(GetTeam(Team, false) == world)
 245                                 {
 246                                         dprintf("trying to switch to unsupported team %d\n", Team);
 247                                         Team = NUM_SPECTATOR;
 248                                 }
 249                                 break;
 250                 }
 251         }
 252         else
 253         {
 254                 switch(Team)
 255                 {
 256                         case -1:
 257                         case 0:
 258                                 break;
 259                         default:
 260                                 if(GetTeam(Team, false) == world)
 261                                 {
 262                                         dprintf("trying to switch to unsupported team %d\n", Team);
 263                                         Team = NUM_SPECTATOR;
 264                                 }
 265                                 break;
 266                 }
 267         }
 268         if(Team == -1) // leave
 269         {
 270                 if(o.has_team)
 271                 {
 272                         tm = GetTeam(o.team, false);
 273                         tm.team_size -= 1;
 274                         o.has_team = 0;
 275                         return true;
 276                 }
 277         }
 278         else
 279         {
 280                 if (!o.has_team)
 281                 {
 282                         o.team = Team;
 283                         tm = GetTeam(Team, true);
 284                         tm.team_size += 1;
 285                         o.has_team = 1;
 286                         return true;
 287                 }
 288                 else if(Team != o.team)
 289                 {
 290                         tm = GetTeam(o.team, false);
 291                         tm.team_size -= 1;
 292                         o.team = Team;
 293                         tm = GetTeam(Team, true);
 294                         tm.team_size += 1;
 295                         return true;
 296                 }
 297         }
 298         return false;
 299 }
 300
 301 void Playerchecker_Think()
 302 {
 303     int i;
 304         entity e;
 305         for(i = 0; i < maxclients; ++i)
 306         {
 307                 e = playerslots[i];
 308                 if(GetPlayerName(i) == "")
 309                 {
 310                         if(e.sort_prev)
 311                         {
 312                                 // player disconnected
 313                                 SetTeam(e, -1);
 314                                 RemovePlayer(e);
 315                                 e.sort_prev = world;
 316                                 //e.gotscores = 0;
 317                         }
 318                 }
 319                 else
 320                 {
 321                         if (!e.sort_prev)
 322                         {
 323                                 // player connected
 324                                 if (!e)
 325                                         playerslots[i] = e = spawn();
 326                                 e.sv_entnum = i;
 327                                 e.ping = 0;
 328                                 e.ping_packetloss = 0;
 329                                 e.ping_movementloss = 0;
 330                                 //e.gotscores = 0; // we might already have the scores...
 331                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 332                                 RegisterPlayer(e);
 333                                 HUD_UpdatePlayerPos(e);
 334                         }
 335                 }
 336         }
 337         self.nextthink = time + 0.2;
 338 }
 339
 340 void Porto_Init();
 341 void TrueAim_Init();
 342 void PostInit(void)
 343 {
 344         entity playerchecker;
 345         playerchecker = spawn();
 346         playerchecker.think = Playerchecker_Think;
 347         playerchecker.nextthink = time + 0.2;
 348
 349         Porto_Init();
 350         TrueAim_Init();
 351
 352         postinit = true;
 353 }
 354
 355 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 356 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 357 // All keys are in ascii.
 358 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 359 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 360 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 361 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 362 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 363 {
 364         float bSkipKey;
 365         bSkipKey = false;
 366
 367         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 368                 return true;
 369
 370         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 371                 return true;
 372
 373         if(menu_visible && menu_action)
 374                 if(menu_action(bInputType, nPrimary, nSecondary))
 375                         return true;
 376
 377         return bSkipKey;
 378 }
 379
 380 // END REQUIRED CSQC FUNCTIONS
 381 // --------------------------------------------------------------------------
 382
 383 // --------------------------------------------------------------------------
 384 // BEGIN OPTIONAL CSQC FUNCTIONS
 385
 386 void Ent_RemoveEntCS()
 387 {
 388         entcs_receiver[self.sv_entnum] = world;
 389 }
 390 void Ent_ReadEntCS()
 391 {
 392     int sf;
 393         InterpolateOrigin_Undo();
 394
 395         self.classname = "entcs_receiver";
 396         sf = ReadByte();
 397
 398         if(sf & 1)
 399                 self.sv_entnum = ReadByte();
 400         if(sf & 2)
 401         {
 402                 self.origin_x = ReadShort();
 403                 self.origin_y = ReadShort();
 404                 self.origin_z = ReadShort();
 405                 setorigin(self, self.origin);
 406         }
 407         if(sf & 4)
 408         {
 409                 self.angles_y = ReadByte() * 360.0 / 256;
 410                 self.angles_x = self.angles_z = 0;
 411         }
 412         if(sf & 8)
 413                 self.healthvalue = ReadByte() * 10;
 414         if(sf & 16)
 415                 self.armorvalue = ReadByte() * 10;
 416
 417         entcs_receiver[self.sv_entnum] = self;
 418         self.entremove = Ent_RemoveEntCS;
 419         self.iflags |= IFLAG_ORIGIN;
 420
 421         InterpolateOrigin_Note();
 422 }
 423
 424 void Ent_Remove();
 425
 426 void Ent_RemovePlayerScore()
 427 {
 428         if(self.owner) {
 429                 SetTeam(self.owner, -1);
 430                 self.owner.gotscores = 0;
 431                 for(int i = 0; i < MAX_SCORE; ++i) {
 432                         self.owner.(scores[i]) = 0; // clear all scores
 433                 }
 434         }
 435 }
 436
 437 void Ent_ReadPlayerScore()
 438 {
 439         int i, n;
 440         bool isNew;
 441         entity o;
 442
 443         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 444         // (no I've never heard of M-x replace-string, sed, or anything like that)
 445         isNew = !self.owner; // workaround for DP bug
 446         n = ReadByte()-1;
 447
 448 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 449         if(!isNew && n != self.sv_entnum)
 450         {
 451                 //print("A CSQC entity changed its owner!\n");
 452                 printf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 453                 isNew = true;
 454                 Ent_Remove();
 455                 self.enttype = ENT_CLIENT_SCORES;
 456         }
 457 #endif
 458
 459         self.sv_entnum = n;
 460
 461         if (!(playerslots[self.sv_entnum]))
 462                 playerslots[self.sv_entnum] = spawn();
 463         o = self.owner = playerslots[self.sv_entnum];
 464         o.sv_entnum = self.sv_entnum;
 465         o.gotscores = 1;
 466
 467         //if (!o.sort_prev)
 468         //      RegisterPlayer(o);
 469         //playerchecker will do this for us later, if it has not already done so
 470
 471     int sf, lf;
 472 #if MAX_SCORE <= 8
 473         sf = ReadByte();
 474         lf = ReadByte();
 475 #else
 476         sf = ReadShort();
 477         lf = ReadShort();
 478 #endif
 479     int p;
 480         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 481                 if(sf & p)
 482                 {
 483                         if(lf & p)
 484                                 o.(scores[i]) = ReadInt24_t();
 485                         else
 486                                 o.(scores[i]) = ReadChar();
 487                 }
 488
 489         if(o.sort_prev)
 490                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 491
 492         self.entremove = Ent_RemovePlayerScore;
 493 }
 494
 495 void Ent_ReadTeamScore()
 496 {
 497         int i;
 498         entity o;
 499
 500         self.team = ReadByte();
 501         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 502
 503     int sf, lf;
 504 #if MAX_TEAMSCORE <= 8
 505         sf = ReadByte();
 506         lf = ReadByte();
 507 #else
 508         sf = ReadShort();
 509         lf = ReadShort();
 510 #endif
 511         int p;
 512         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 513                 if(sf & p)
 514                 {
 515                         if(lf & p)
 516                                 o.(teamscores[i]) = ReadInt24_t();
 517                         else
 518                                 o.(teamscores[i]) = ReadChar();
 519                 }
 520
 521         HUD_UpdateTeamPos(o);
 522 }
 523
 524 void Ent_ClientData()
 525 {
 526         float newspectatee_status;
 527
 528     int f = ReadByte();
 529
 530         scoreboard_showscores_force = (f & 1);
 531
 532         if(f & 2)
 533         {
 534                 newspectatee_status = ReadByte();
 535                 if(newspectatee_status == player_localnum + 1)
 536                         newspectatee_status = -1; // observing
 537         }
 538         else
 539                 newspectatee_status = 0;
 540
 541         spectatorbutton_zoom = (f & 4);
 542
 543         if(f & 8)
 544         {
 545                 angles_held_status = 1;
 546                 angles_held.x = ReadAngle();
 547                 angles_held.y = ReadAngle();
 548                 angles_held.z = 0;
 549         }
 550         else
 551                 angles_held_status = 0;
 552
 553         if(newspectatee_status != spectatee_status)
 554         {
 555                 // clear race stuff
 556                 race_laptime = 0;
 557                 race_checkpointtime = 0;
 558         }
 559         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 560         {
 561                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 562                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 563                 )
 564                         prev_p_health = -1;
 565                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 566                         prev_health = -1;
 567         }
 568         spectatee_status = newspectatee_status;
 569
 570         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 571 }
 572
 573 void Ent_Nagger()
 574 {
 575     int i, j, b, f;
 576
 577     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 578
 579         if(!(nags & 4))
 580         {
 581                 if(vote_called_vote)
 582                         strunzone(vote_called_vote);
 583                 vote_called_vote = string_null;
 584                 vote_active = 0;
 585         }
 586         else
 587         {
 588                 vote_active = 1;
 589         }
 590
 591         if(nags & 64)
 592         {
 593                 vote_yescount = ReadByte();
 594                 vote_nocount = ReadByte();
 595                 vote_needed = ReadByte();
 596                 vote_highlighted = ReadChar();
 597         }
 598
 599         if(nags & 128)
 600         {
 601                 if(vote_called_vote)
 602                         strunzone(vote_called_vote);
 603                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 604         }
 605
 606         if(nags & 1)
 607         {
 608                 for(j = 0; j < maxclients; ++j)
 609                         if(playerslots[j])
 610                                 playerslots[j].ready = 1;
 611                 for(i = 1; i <= maxclients; i += 8)
 612                 {
 613                         f = ReadByte();
 614                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 615                                 if (!(f & b))
 616                                         if(playerslots[j])
 617                                                 playerslots[j].ready = 0;
 618                 }
 619         }
 620
 621         ready_waiting = (nags & 1);
 622         ready_waiting_for_me = (nags & 2);
 623         vote_waiting = (nags & 4);
 624         vote_waiting_for_me = (nags & 8);
 625         warmup_stage = (nags & 16);
 626 }
 627
 628 void Ent_EliminatedPlayers()
 629 {
 630     int i, j, b, f;
 631
 632     int sf = ReadByte();
 633         if(sf & 1)
 634         {
 635                 for(j = 0; j < maxclients; ++j)
 636                         if(playerslots[j])
 637                                 playerslots[j].eliminated = 1;
 638                 for(i = 1; i <= maxclients; i += 8)
 639                 {
 640                         f = ReadByte();
 641                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 642                                 if (!(f & b))
 643                                         if(playerslots[j])
 644                                                 playerslots[j].eliminated = 0;
 645                 }
 646         }
 647 }
 648
 649 void Ent_RandomSeed()
 650 {
 651         float s;
 652         prandom_debug();
 653         s = ReadShort();
 654         psrandom(s);
 655 }
 656
 657 void Ent_ReadAccuracy(void)
 658 {
 659     int f, w;
 660     int sf = ReadInt24_t();
 661         if(sf == 0)
 662         {
 663                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 664                         weapon_accuracy[w] = -1;
 665                 return;
 666         }
 667
 668         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 669         {
 670                 if(sf & f)
 671                 {
 672             int b = ReadByte();
 673                         if(b == 0)
 674                                 weapon_accuracy[w] = -1;
 675                         else if(b == 255)
 676                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 677                         else
 678                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 679                 }
 680                 if(f == 0x800000)
 681                         f = 1;
 682                 else
 683                         f *= 2;
 684         }
 685 }
 686
 687 void Spawn_Draw(void)
 688 {
 689         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 690 }
 691
 692 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 693 {
 694         float teamnum = (ReadByte() - 1);
 695         vector spn_origin;
 696         spn_origin.x = ReadShort();
 697         spn_origin.y = ReadShort();
 698         spn_origin.z = ReadShort();
 699
 700         if(is_new)
 701         {
 702                 self.origin = spn_origin;
 703                 setsize(self, PL_MIN_CONST, PL_MAX_CONST);
 704                 droptofloor();
 705
 706                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 707                 {
 708                         self.mdl = "models/spawnpoint.md3";
 709                         self.colormod = Team_ColorRGB(teamnum);
 710                         precache_model(self.mdl);
 711                         setmodel(self, self.mdl);
 712                         self.drawmask = MASK_NORMAL;
 713                         //self.movetype = MOVETYPE_NOCLIP;
 714                         //self.draw = Spawn_Draw;
 715                 }*/
 716                 if(autocvar_cl_spawn_point_particles)
 717                 {
 718                         if((serverflags & SERVERFLAG_TEAMPLAY))
 719                         {
 720                                 switch(teamnum)
 721                                 {
 722                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
 723                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
 724                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
 725                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
 726                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
 727                                 }
 728                         }
 729                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
 730
 731                         self.draw = Spawn_Draw;
 732                 }
 733         }
 734
 735         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 736 }
 737
 738 void Ent_ReadSpawnEvent(float is_new)
 739 {
 740         // If entnum is 0, ONLY do the local spawn actions
 741         // this way the server can disable the sending of
 742         // spawn origin or such to clients if wanted.
 743         float entnum = ReadByte();
 744
 745         if(entnum)
 746         {
 747                 self.origin_x = ReadShort();
 748                 self.origin_y = ReadShort();
 749                 self.origin_z = ReadShort();
 750
 751                 if(is_new)
 752                 {
 753                         float teamnum = GetPlayerColor(entnum - 1);
 754
 755                         if(autocvar_cl_spawn_event_particles)
 756                         {
 757                                 switch(teamnum)
 758                                 {
 759                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
 760                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
 761                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
 762                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
 763                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
 764                                 }
 765                         }
 766                         if(autocvar_cl_spawn_event_sound)
 767                         {
 768                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
 769                         }
 770                 }
 771         }
 772
 773         // local spawn actions
 774         if(is_new && (!entnum || (entnum == player_localentnum)))
 775         {
 776                 zoomin_effect = 1;
 777                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 778
 779                 if(autocvar_cl_unpress_zoom_on_spawn)
 780                 {
 781                         localcmd("-zoom\n");
 782                         button_zoom = false;
 783                 }
 784         }
 785
 786         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 787 }
 788
 789 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 790 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 791 void Ent_RadarLink();
 792 void Ent_Init();
 793 void Ent_ScoresInfo();
 794 void CSQC_Ent_Update(float bIsNewEntity)
 795 {
 796         float t;
 797         float savetime;
 798         t = ReadByte();
 799
 800         if(autocvar_developer_csqcentities)
 801                 printf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 802
 803         // set up the "time" global for received entities to be correct for interpolation purposes
 804         savetime = time;
 805         if(servertime)
 806         {
 807                 time = servertime;
 808         }
 809         else
 810         {
 811                 serverprevtime = time;
 812                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 813                 time = serverprevtime + serverdeltatime;
 814         }
 815
 816 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 817         if(self.enttype)
 818         {
 819                 if(t != self.enttype || bIsNewEntity)
 820                 {
 821                         //print("A CSQC entity changed its type!\n");
 822                         printf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 823                         Ent_Remove();
 824                         clearentity(self);
 825                         bIsNewEntity = 1;
 826                 }
 827         }
 828         else
 829         {
 830                 if(!bIsNewEntity)
 831                 {
 832                         printf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 833                         bIsNewEntity = 1;
 834                 }
 835         }
 836 #endif
 837         self.enttype = t;
 838         switch(t)
 839         {
 840                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 841                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 842                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 843                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 844                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 845                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 846                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 847                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
 848                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 849                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 850                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 851                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 852                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 853                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 854                 case ENT_CLIENT_INIT: Ent_Init(); break;
 855                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 856                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 857                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 858                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 859                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 860                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 861                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 862                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 863                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 864                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 865                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 866                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 867                 case ENT_CLIENT_INVENTORY: Inventory_Read(self); break;
 868                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
 869                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 870                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 871                 case ENT_CLIENT_TURRET: ent_turret(); break;
 872                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 873                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 874                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 875                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 876                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 877                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 878                 case ENT_CLIENT_HEALING_ORB: ent_healer(); break;
 879                 case ENT_CLIENT_VIEWLOC: ent_viewloc(); break;
 880                 case ENT_CLIENT_VIEWLOC_TRIGGER: ent_viewloc_trigger(); break;
 881                 case ENT_CLIENT_LADDER: ent_func_ladder(); break;
 882                 case ENT_CLIENT_TRIGGER_PUSH: ent_trigger_push(); break;
 883                 case ENT_CLIENT_TARGET_PUSH: ent_target_push(); break;
 884                 case ENT_CLIENT_CONVEYOR: ent_conveyor(); break;
 885                 case ENT_CLIENT_DOOR: ent_door(); break;
 886                 case ENT_CLIENT_PLAT: ent_plat(); break;
 887                 case ENT_CLIENT_SWAMP: ent_swamp(); break;
 888                 case ENT_CLIENT_CORNER: ent_corner(); break;
 889                 case ENT_CLIENT_KEYLOCK: ent_keylock(); break;
 890                 case ENT_CLIENT_TRAIN: ent_train(); break;
 891                 case ENT_CLIENT_TRIGGER_IMPULSE: ent_trigger_impulse(); break;
 892
 893                 default:
 894                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 895                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
 896                         break;
 897         }
 898
 899         time = savetime;
 900 }
 901 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 902 // used when an entity changes its type. For an entity that someone interacts
 903 // with others, make sure it can no longer do so.
 904 void Ent_Remove()
 905 {
 906         if(self.entremove)
 907                 self.entremove();
 908
 909         if(self.skeletonindex)
 910         {
 911                 skel_delete(self.skeletonindex);
 912                 self.skeletonindex = 0;
 913         }
 914
 915         if(self.snd_looping > 0)
 916         {
 917                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 918                 self.snd_looping = 0;
 919         }
 920
 921         self.enttype = 0;
 922         self.classname = "";
 923         self.draw = menu_sub_null;
 924         self.entremove = menu_sub_null;
 925         // TODO possibly set more stuff to defaults
 926 }
 927 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 928 void CSQC_Ent_Remove()
 929 {
 930         if(autocvar_developer_csqcentities)
 931                 printf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 932
 933         if(wasfreed(self))
 934         {
 935                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 936                 return;
 937         }
 938         if(self.enttype)
 939                 Ent_Remove();
 940         remove(self);
 941 }
 942
 943 void Gamemode_Init()
 944 {
 945         if (!isdemo())
 946         {
 947                 if(!(calledhooks & HOOK_START))
 948                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 949                 calledhooks |= HOOK_START;
 950         }
 951 }
 952 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 953 void CSQC_Parse_StuffCmd(string strMessage)
 954 {
 955         if(autocvar_developer_csqcentities)
 956                 printf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 957
 958         localcmd(strMessage);
 959 }
 960 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 961 void CSQC_Parse_Print(string strMessage)
 962 {
 963         if(autocvar_developer_csqcentities)
 964                 printf("CSQC_Parse_Print(\"%s\")\n", strMessage);
 965
 966         print(ColorTranslateRGB(strMessage));
 967 }
 968
 969 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 970 void CSQC_Parse_CenterPrint(string strMessage)
 971 {
 972         if(autocvar_developer_csqcentities)
 973                 printf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 974
 975         centerprint_hud(strMessage);
 976 }
 977
 978 string notranslate_fogcmd1 = "\nfog ";
 979 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 980 void Fog_Force()
 981 {
 982         // TODO somehow thwart prvm_globalset client ...
 983
 984         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 985                 { localcmd("\nr_drawfog 0\n"); }
 986         else if(forcefog != "")
 987                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
 988 }
 989
 990 void Gamemode_Init();
 991 void Ent_ScoresInfo()
 992 {
 993     int i;
 994         self.classname = "ent_client_scores_info";
 995         gametype = ReadInt24_t();
 996         HUD_ModIcons_SetFunc();
 997         for(i = 0; i < MAX_SCORE; ++i)
 998         {
 999                 if(scores_label[i])
1000                         strunzone(scores_label[i]);
1001                 scores_label[i] = strzone(ReadString());
1002                 scores_flags[i] = ReadByte();
1003         }
1004         for(i = 0; i < MAX_TEAMSCORE; ++i)
1005         {
1006                 if(teamscores_label[i])
1007                         strunzone(teamscores_label[i]);
1008                 teamscores_label[i] = strzone(ReadString());
1009                 teamscores_flags[i] = ReadByte();
1010         }
1011         HUD_InitScores();
1012         Gamemode_Init();
1013 }
1014
1015 void Ent_Init()
1016 {
1017         self.classname = "ent_client_init";
1018
1019         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1020
1021         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1022         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1023         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1024         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1025         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1026         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1027         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1028         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1029
1030         if(forcefog)
1031                 strunzone(forcefog);
1032         forcefog = strzone(ReadString());
1033
1034         armorblockpercent = ReadByte() / 255.0;
1035
1036         g_balance_mortar_bouncefactor = ReadCoord();
1037         g_balance_mortar_bouncestop = ReadCoord();
1038         g_balance_electro_secondary_bouncefactor = ReadCoord();
1039         g_balance_electro_secondary_bouncestop = ReadCoord();
1040
1041         vortex_scope = !ReadByte();
1042         rifle_scope = !ReadByte();
1043
1044         serverflags = ReadByte();
1045
1046         minelayer_maxmines = ReadByte();
1047
1048         hagar_maxrockets = ReadByte();
1049
1050         g_trueaim_minrange = ReadCoord();
1051         g_balance_porto_secondary = ReadByte();
1052
1053         if(!postinit)
1054                 PostInit();
1055 }
1056
1057 void Net_ReadRace()
1058 {
1059         float b;
1060
1061         b = ReadByte();
1062
1063         switch(b)
1064         {
1065                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1066                         race_checkpoint = ReadByte();
1067                         race_time = ReadInt24_t();
1068                         race_previousbesttime = ReadInt24_t();
1069                         if(race_previousbestname)
1070                                 strunzone(race_previousbestname);
1071                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1072
1073                         race_checkpointtime = time;
1074
1075                         if(race_checkpoint == 0 || race_checkpoint == 254)
1076                         {
1077                                 race_penaltyaccumulator = 0;
1078                                 race_laptime = time; // valid
1079                         }
1080
1081                         break;
1082
1083                 case RACE_NET_CHECKPOINT_CLEAR:
1084                         race_laptime = 0;
1085                         race_checkpointtime = 0;
1086                         break;
1087
1088                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1089                         race_laptime = ReadCoord();
1090                         race_checkpointtime = -99999;
1091                         // fall through
1092                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1093                         race_nextcheckpoint = ReadByte();
1094
1095                         race_nextbesttime = ReadInt24_t();
1096                         if(race_nextbestname)
1097                                 strunzone(race_nextbestname);
1098                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1099                         break;
1100
1101                 case RACE_NET_CHECKPOINT_HIT_RACE:
1102                         race_mycheckpoint = ReadByte();
1103                         race_mycheckpointtime = time;
1104                         race_mycheckpointdelta = ReadInt24_t();
1105                         race_mycheckpointlapsdelta = ReadByte();
1106                         if(race_mycheckpointlapsdelta >= 128)
1107                                 race_mycheckpointlapsdelta -= 256;
1108                         if(race_mycheckpointenemy)
1109                                 strunzone(race_mycheckpointenemy);
1110                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1111                         break;
1112
1113                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1114                         race_othercheckpoint = ReadByte();
1115                         race_othercheckpointtime = time;
1116                         race_othercheckpointdelta = ReadInt24_t();
1117                         race_othercheckpointlapsdelta = ReadByte();
1118                         if(race_othercheckpointlapsdelta >= 128)
1119                                 race_othercheckpointlapsdelta -= 256;
1120                         if(race_othercheckpointenemy)
1121                                 strunzone(race_othercheckpointenemy);
1122                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1123                         break;
1124
1125                 case RACE_NET_PENALTY_RACE:
1126                         race_penaltyeventtime = time;
1127                         race_penaltytime = ReadShort();
1128                         //race_penaltyaccumulator += race_penaltytime;
1129                         if(race_penaltyreason)
1130                                 strunzone(race_penaltyreason);
1131                         race_penaltyreason = strzone(ReadString());
1132                         break;
1133
1134                 case RACE_NET_PENALTY_QUALIFYING:
1135                         race_penaltyeventtime = time;
1136                         race_penaltytime = ReadShort();
1137                         race_penaltyaccumulator += race_penaltytime;
1138                         if(race_penaltyreason)
1139                                 strunzone(race_penaltyreason);
1140                         race_penaltyreason = strzone(ReadString());
1141                         break;
1142
1143                 case RACE_NET_SERVER_RECORD:
1144                         race_server_record = ReadInt24_t();
1145                         break;
1146                 case RACE_NET_SPEED_AWARD:
1147                         race_speedaward = ReadInt24_t();
1148                         if(race_speedaward_holder)
1149                                 strunzone(race_speedaward_holder);
1150                         race_speedaward_holder = strzone(ReadString());
1151                         break;
1152                 case RACE_NET_SPEED_AWARD_BEST:
1153                         race_speedaward_alltimebest = ReadInt24_t();
1154                         if(race_speedaward_alltimebest_holder)
1155                                 strunzone(race_speedaward_alltimebest_holder);
1156                         race_speedaward_alltimebest_holder = strzone(ReadString());
1157                         break;
1158                 case RACE_NET_SERVER_RANKINGS:
1159                         float prevpos, del;
1160             int pos = ReadShort();
1161                         prevpos = ReadShort();
1162                         del = ReadShort();
1163
1164                         // move other rankings out of the way
1165             int i;
1166                         if (prevpos) {
1167                                 for (i=prevpos-1;i>pos-1;--i) {
1168                                         grecordtime[i] = grecordtime[i-1];
1169                                         if(grecordholder[i])
1170                                                 strunzone(grecordholder[i]);
1171                                         grecordholder[i] = strzone(grecordholder[i-1]);
1172                                 }
1173                         } else if (del) { // a record has been deleted by the admin
1174                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1175                                         if (i == RANKINGS_CNT-1) { // clear out last record
1176                                                 grecordtime[i] = 0;
1177                                                 if (grecordholder[i])
1178                                                         strunzone(grecordholder[i]);
1179                                                 grecordholder[i] = string_null;
1180                                         }
1181                                         else {
1182                                                 grecordtime[i] = grecordtime[i+1];
1183                                                 if (grecordholder[i])
1184                                                         strunzone(grecordholder[i]);
1185                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1186                                         }
1187                                 }
1188                         } else { // player has no ranked record yet
1189                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1190                                         grecordtime[i] = grecordtime[i-1];
1191                                         if(grecordholder[i])
1192                                                 strunzone(grecordholder[i]);
1193                                         grecordholder[i] = strzone(grecordholder[i-1]);
1194                                 }
1195                         }
1196
1197                         // store new ranking
1198                         if(grecordholder[pos-1] != "")
1199                                 strunzone(grecordholder[pos-1]);
1200                         grecordholder[pos-1] = strzone(ReadString());
1201                         grecordtime[pos-1] = ReadInt24_t();
1202                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1203                                 race_myrank = pos;
1204                         break;
1205                 case RACE_NET_SERVER_STATUS:
1206                         race_status = ReadShort();
1207                         if(race_status_name)
1208                                 strunzone(race_status_name);
1209                         race_status_name = strzone(ReadString());
1210         }
1211 }
1212
1213 void Net_TeamNagger()
1214 {
1215         teamnagger = 1;
1216 }
1217
1218 void Net_ReadPingPLReport()
1219 {
1220         int e, pi, pl, ml;
1221         e = ReadByte();
1222         pi = ReadShort();
1223         pl = ReadByte();
1224         ml = ReadByte();
1225         if (!(playerslots[e]))
1226                 return;
1227         playerslots[e].ping = pi;
1228         playerslots[e].ping_packetloss = pl / 255.0;
1229         playerslots[e].ping_movementloss = ml / 255.0;
1230 }
1231
1232 void Net_WeaponComplain()
1233 {
1234         complain_weapon = ReadByte();
1235
1236         if(complain_weapon_name)
1237                 strunzone(complain_weapon_name);
1238         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1239
1240         complain_weapon_type = ReadByte();
1241
1242         complain_weapon_time = time;
1243         weapontime = time; // ping the weapon panel
1244
1245         switch(complain_weapon_type)
1246         {
1247                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1248                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1249                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1250         }
1251 }
1252
1253 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1254 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1255 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1256 float CSQC_Parse_TempEntity()
1257 {
1258         float bHandled;
1259                 bHandled  = true;
1260         // Acquire TE ID
1261         float nTEID;
1262                 nTEID = ReadByte();
1263
1264         if(autocvar_developer_csqcentities)
1265                 printf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1266
1267                 // NOTE: Could just do return instead of break...
1268         switch(nTEID)
1269         {
1270                 case TE_CSQC_TARGET_MUSIC:
1271                         Net_TargetMusic();
1272                         bHandled = true;
1273                         break;
1274                 case TE_CSQC_PICTURE:
1275                         Net_MapVote_Picture();
1276                         bHandled = true;
1277                         break;
1278                 case TE_CSQC_RACE:
1279                         Net_ReadRace();
1280                         bHandled = true;
1281                         break;
1282                 case TE_CSQC_VORTEXBEAMPARTICLE:
1283                         Net_ReadVortexBeamParticle();
1284                         bHandled = true;
1285                         break;
1286                 case TE_CSQC_TEAMNAGGER:
1287                         Net_TeamNagger();
1288                         bHandled = true;
1289                         break;
1290                 case TE_CSQC_ARC:
1291                         Net_ReadArc();
1292                         bHandled = true;
1293                         break;
1294                 case TE_CSQC_PINGPLREPORT:
1295                         Net_ReadPingPLReport();
1296                         bHandled = true;
1297                         break;
1298                 case TE_CSQC_WEAPONCOMPLAIN:
1299                         Net_WeaponComplain();
1300                         bHandled = true;
1301                         break;
1302                 case TE_CSQC_VEHICLESETUP:
1303                         Net_VehicleSetup();
1304                         bHandled = true;
1305                         break;
1306                 case TE_CSQC_SVNOTICE:
1307                         cl_notice_read();
1308                         bHandled = true;
1309                         break;
1310                 case TE_CSQC_SHOCKWAVEPARTICLE:
1311                         Net_ReadShockwaveParticle();
1312                         bHandled = true;
1313                         break;
1314                 default:
1315                         // No special logic for this temporary entity; return 0 so the engine can handle it
1316                         bHandled = false;
1317                         break;
1318         }
1319
1320         return bHandled;
1321 }
1322
1323 string getcommandkey(string text, string command)
1324 {
1325         string keys;
1326         float n, j, k, l = 0;
1327
1328         if (!autocvar_hud_showbinds)
1329                 return text;
1330
1331         keys = db_get(binddb, command);
1332         if (keys == "")
1333         {
1334                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1335                 for(j = 0; j < n; ++j)
1336                 {
1337                         k = stof(argv(j));
1338                         if(k != -1)
1339                         {
1340                                 if ("" == keys)
1341                                         keys = keynumtostring(k);
1342                                 else
1343                                         keys = strcat(keys, ", ", keynumtostring(k));
1344
1345                                 ++l;
1346                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1347                                         break;
1348                         }
1349
1350                 }
1351                 if (keys == "")
1352                         keys = "NO_KEY";
1353                 db_put(binddb, command, keys);
1354         }
1355
1356         if (keys == "NO_KEY") {
1357                 if (autocvar_hud_showbinds > 1)
1358                         return sprintf(_("%s (not bound)"), text);
1359                 else
1360                         return text;
1361         }
1362         else if (autocvar_hud_showbinds > 1)
1363                 return sprintf("%s (%s)", text, keys);
1364         else
1365                 return keys;
1366 }