qcsrc/client/main.qc

   1 #include "mapvoting.qh"
   2 #include "modeleffects.qh"
   3 #include "particles.qh"
   4 #include "scoreboard.qh"
   5 #include "shownames.qh"
   6 #include "target_music.qh"
   7 #include "tturrets.qh"
   8 #include "tuba.qh"
   9 #include "wall.qh"
  10 #include "waypointsprites.qh"
  11
  12 #include "vehicles/vehicles.qh"
  13
  14 #include "../server/vehicles/bumblebee.qh"
  15
  16 #include "../common/net_notice.qh"
  17
  18 #include "../common/monsters/monsters.qh"
  19
  20 #include "../common/triggers/include.qh"
  21
  22 #include "../warpzonelib/client.qh"
  23
  24 // --------------------------------------------------------------------------
  25 // BEGIN REQUIRED CSQC FUNCTIONS
  26 //include "main.qh"
  27
  28 entity clearentity_ent;
  29 void clearentity(entity e)
  30 {
  31         if (!clearentity_ent)
  32         {
  33                 clearentity_ent = spawn();
  34                 clearentity_ent.classname = "clearentity";
  35         }
  36         int n = e.entnum;
  37         copyentity(clearentity_ent, e);
  38         e.entnum = n;
  39 }
  40
  41 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  42 void menu_show_error()
  43 {
  44         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  45 }
  46
  47 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  48 // Useful for precaching things
  49
  50 void menu_sub_null()
  51 {
  52 }
  53
  54 string forcefog;
  55 void WaypointSprite_Load();
  56 void ConsoleCommand_macro_init();
  57 void CSQC_Init(void)
  58 {
  59         prvm_language = cvar_string("prvm_language");
  60
  61 #ifdef WATERMARK
  62         dprintf("^4CSQC Build information: ^1%s\n", WATERMARK);
  63 #endif
  64
  65         int i;
  66
  67         binddb = db_create();
  68         tempdb = db_create();
  69         ClientProgsDB = db_load("client.db");
  70         compressShortVector_init();
  71
  72         draw_endBoldFont();
  73         menu_visible = false;
  74         menu_show = menu_show_error;
  75         menu_action = func_null;
  76
  77         for(i = 0; i < 255; ++i)
  78                 if(getplayerkeyvalue(i, "viewentity") == "")
  79                         break;
  80         maxclients = i;
  81
  82         //registercommand("hud_configure");
  83         //registercommand("hud_save");
  84         //registercommand("menu_action");
  85
  86         ConsoleCommand_macro_init();
  87
  88         registercvar("hud_usecsqc", "1");
  89         registercvar("scoreboard_columns", "default");
  90
  91         registercvar("cl_nade_type", "3");
  92         registercvar("cl_pokenade_type", "zombie");
  93
  94         gametype = 0;
  95
  96         // hud_fields uses strunzone on the titles!
  97         for(i = 0; i < MAX_HUD_FIELDS; ++i)
  98                 hud_title[i] = strzone("(null)");
  99
 100         Cmd_HUD_SetFields(0);
 101
 102         postinit = false;
 103
 104         calledhooks = 0;
 105
 106         teams = Sort_Spawn();
 107         players = Sort_Spawn();
 108
 109         GetTeam(NUM_SPECTATOR, true); // add specs first
 110
 111         // needs to be done so early because of the constants they create
 112         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 113         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 114         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 115         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 116         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 117         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
 118         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 119
 120         WaypointSprite_Load();
 121
 122         // precaches
 123         precache_model("null");
 124         precache_sound("misc/hit.wav");
 125         precache_sound("misc/typehit.wav");
 126
 127         Projectile_Precache();
 128         Hook_Precache();
 129         GibSplash_Precache();
 130         Casings_Precache();
 131         Vehicles_Precache();
 132         turrets_precache();
 133         Tuba_Precache();
 134         CSQCPlayer_Precache();
 135
 136         if(autocvar_cl_reticle)
 137         {
 138                 precache_pic("gfx/reticle_normal");
 139                 // weapon reticles are precached in weapon files
 140         }
 141
 142         get_mi_min_max_texcoords(1); // try the CLEVER way first
 143         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 144         shortmapname = mi_shortname;
 145
 146         if(precache_pic(minimapname) == "")
 147         {
 148                 // but maybe we have a non-clever minimap
 149                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 150                 if(precache_pic(minimapname) == "")
 151                         minimapname = ""; // FAIL
 152                 else
 153                         get_mi_min_max_texcoords(0); // load new texcoords
 154         }
 155
 156         mi_center = (mi_min + mi_max) * 0.5;
 157         mi_scale = mi_max - mi_min;
 158         minimapname = strzone(minimapname);
 159
 160         WarpZone_Init();
 161
 162         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 163         hud_configure_prev = -1;
 164
 165         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 166 }
 167
 168 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 169 void Shutdown(void)
 170 {
 171         WarpZone_Shutdown();
 172
 173         remove(teams);
 174         remove(players);
 175         db_close(binddb);
 176         db_close(tempdb);
 177         if(autocvar_cl_db_saveasdump)
 178                 db_dump(ClientProgsDB, "client.db");
 179         else
 180                 db_save(ClientProgsDB, "client.db");
 181         db_close(ClientProgsDB);
 182
 183         if(camera_active)
 184                 cvar_set("chase_active",ftos(chase_active_backup));
 185
 186         // unset the event chasecam's chase_active
 187         if(autocvar_chase_active < 0)
 188                 cvar_set("chase_active", "0");
 189
 190         if (!isdemo())
 191         {
 192                 if (!(calledhooks & HOOK_START))
 193                         localcmd("\n_cl_hook_gamestart nop\n");
 194                 if (!(calledhooks & HOOK_END))
 195                         localcmd("\ncl_hook_gameend\n");
 196         }
 197 }
 198
 199 .float has_team;
 200 float SetTeam(entity o, int Team)
 201 {
 202         entity tm;
 203         if(teamplay)
 204         {
 205                 switch(Team)
 206                 {
 207                         case -1:
 208                         case NUM_TEAM_1:
 209                         case NUM_TEAM_2:
 210                         case NUM_TEAM_3:
 211                         case NUM_TEAM_4:
 212                                 break;
 213                         default:
 214                                 if(GetTeam(Team, false) == world)
 215                                 {
 216                                         dprintf("trying to switch to unsupported team %d\n", Team);
 217                                         Team = NUM_SPECTATOR;
 218                                 }
 219                                 break;
 220                 }
 221         }
 222         else
 223         {
 224                 switch(Team)
 225                 {
 226                         case -1:
 227                         case 0:
 228                                 break;
 229                         default:
 230                                 if(GetTeam(Team, false) == world)
 231                                 {
 232                                         dprintf("trying to switch to unsupported team %d\n", Team);
 233                                         Team = NUM_SPECTATOR;
 234                                 }
 235                                 break;
 236                 }
 237         }
 238         if(Team == -1) // leave
 239         {
 240                 if(o.has_team)
 241                 {
 242                         tm = GetTeam(o.team, false);
 243                         tm.team_size -= 1;
 244                         o.has_team = 0;
 245                         return true;
 246                 }
 247         }
 248         else
 249         {
 250                 if (!o.has_team)
 251                 {
 252                         o.team = Team;
 253                         tm = GetTeam(Team, true);
 254                         tm.team_size += 1;
 255                         o.has_team = 1;
 256                         return true;
 257                 }
 258                 else if(Team != o.team)
 259                 {
 260                         tm = GetTeam(o.team, false);
 261                         tm.team_size -= 1;
 262                         o.team = Team;
 263                         tm = GetTeam(Team, true);
 264                         tm.team_size += 1;
 265                         return true;
 266                 }
 267         }
 268         return false;
 269 }
 270
 271 void Playerchecker_Think()
 272 {
 273     int i;
 274         entity e;
 275         for(i = 0; i < maxclients; ++i)
 276         {
 277                 e = playerslots[i];
 278                 if(GetPlayerName(i) == "")
 279                 {
 280                         if(e.sort_prev)
 281                         {
 282                                 // player disconnected
 283                                 SetTeam(e, -1);
 284                                 RemovePlayer(e);
 285                                 e.sort_prev = world;
 286                                 //e.gotscores = 0;
 287                         }
 288                 }
 289                 else
 290                 {
 291                         if (!e.sort_prev)
 292                         {
 293                                 // player connected
 294                                 if (!e)
 295                                         playerslots[i] = e = spawn();
 296                                 e.sv_entnum = i;
 297                                 e.ping = 0;
 298                                 e.ping_packetloss = 0;
 299                                 e.ping_movementloss = 0;
 300                                 //e.gotscores = 0; // we might already have the scores...
 301                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 302                                 RegisterPlayer(e);
 303                                 HUD_UpdatePlayerPos(e);
 304                         }
 305                 }
 306         }
 307         self.nextthink = time + 0.2;
 308 }
 309
 310 void Porto_Init();
 311 void TrueAim_Init();
 312 void PostInit(void)
 313 {
 314         entity playerchecker;
 315         playerchecker = spawn();
 316         playerchecker.think = Playerchecker_Think;
 317         playerchecker.nextthink = time + 0.2;
 318
 319         Porto_Init();
 320         TrueAim_Init();
 321
 322         postinit = true;
 323 }
 324
 325 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 326 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 327 // All keys are in ascii.
 328 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 329 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 330 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 331 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 332 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 333 {
 334         float bSkipKey;
 335         bSkipKey = false;
 336
 337         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 338                 return true;
 339
 340         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 341                 return true;
 342
 343         if(menu_visible && menu_action)
 344                 if(menu_action(bInputType, nPrimary, nSecondary))
 345                         return true;
 346
 347         return bSkipKey;
 348 }
 349
 350 // END REQUIRED CSQC FUNCTIONS
 351 // --------------------------------------------------------------------------
 352
 353 // --------------------------------------------------------------------------
 354 // BEGIN OPTIONAL CSQC FUNCTIONS
 355
 356 void Ent_RemoveEntCS()
 357 {
 358         entcs_receiver[self.sv_entnum] = world;
 359 }
 360 void Ent_ReadEntCS()
 361 {
 362     int sf;
 363         InterpolateOrigin_Undo();
 364
 365         self.classname = "entcs_receiver";
 366         sf = ReadByte();
 367
 368         if(sf & 1)
 369                 self.sv_entnum = ReadByte();
 370         if(sf & 2)
 371         {
 372                 self.origin_x = ReadShort();
 373                 self.origin_y = ReadShort();
 374                 self.origin_z = ReadShort();
 375                 setorigin(self, self.origin);
 376         }
 377         if(sf & 4)
 378         {
 379                 self.angles_y = ReadByte() * 360.0 / 256;
 380                 self.angles_x = self.angles_z = 0;
 381         }
 382         if(sf & 8)
 383                 self.healthvalue = ReadByte() * 10;
 384         if(sf & 16)
 385                 self.armorvalue = ReadByte() * 10;
 386
 387         entcs_receiver[self.sv_entnum] = self;
 388         self.entremove = Ent_RemoveEntCS;
 389         self.iflags |= IFLAG_ORIGIN;
 390
 391         InterpolateOrigin_Note();
 392 }
 393
 394 void Ent_Remove();
 395
 396 void Ent_RemovePlayerScore()
 397 {
 398         if(self.owner) {
 399                 SetTeam(self.owner, -1);
 400                 self.owner.gotscores = 0;
 401                 for(int i = 0; i < MAX_SCORE; ++i) {
 402                         self.owner.(scores[i]) = 0; // clear all scores
 403                 }
 404         }
 405 }
 406
 407 void Ent_ReadPlayerScore()
 408 {
 409         int i, n;
 410         bool isNew;
 411         entity o;
 412
 413         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 414         // (no I've never heard of M-x replace-string, sed, or anything like that)
 415         isNew = !self.owner; // workaround for DP bug
 416         n = ReadByte()-1;
 417
 418 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 419         if(!isNew && n != self.sv_entnum)
 420         {
 421                 //print("A CSQC entity changed its owner!\n");
 422                 printf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 423                 isNew = true;
 424                 Ent_Remove();
 425                 self.enttype = ENT_CLIENT_SCORES;
 426         }
 427 #endif
 428
 429         self.sv_entnum = n;
 430
 431         if (!(playerslots[self.sv_entnum]))
 432                 playerslots[self.sv_entnum] = spawn();
 433         o = self.owner = playerslots[self.sv_entnum];
 434         o.sv_entnum = self.sv_entnum;
 435         o.gotscores = 1;
 436
 437         //if (!o.sort_prev)
 438         //      RegisterPlayer(o);
 439         //playerchecker will do this for us later, if it has not already done so
 440
 441     int sf, lf;
 442 #if MAX_SCORE <= 8
 443         sf = ReadByte();
 444         lf = ReadByte();
 445 #else
 446         sf = ReadShort();
 447         lf = ReadShort();
 448 #endif
 449     int p;
 450         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 451                 if(sf & p)
 452                 {
 453                         if(lf & p)
 454                                 o.(scores[i]) = ReadInt24_t();
 455                         else
 456                                 o.(scores[i]) = ReadChar();
 457                 }
 458
 459         if(o.sort_prev)
 460                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 461
 462         self.entremove = Ent_RemovePlayerScore;
 463 }
 464
 465 void Ent_ReadTeamScore()
 466 {
 467         int i;
 468         entity o;
 469
 470         self.team = ReadByte();
 471         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 472
 473     int sf, lf;
 474 #if MAX_TEAMSCORE <= 8
 475         sf = ReadByte();
 476         lf = ReadByte();
 477 #else
 478         sf = ReadShort();
 479         lf = ReadShort();
 480 #endif
 481         int p;
 482         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 483                 if(sf & p)
 484                 {
 485                         if(lf & p)
 486                                 o.(teamscores[i]) = ReadInt24_t();
 487                         else
 488                                 o.(teamscores[i]) = ReadChar();
 489                 }
 490
 491         HUD_UpdateTeamPos(o);
 492 }
 493
 494 void Ent_ClientData()
 495 {
 496         float newspectatee_status;
 497
 498     int f = ReadByte();
 499
 500         scoreboard_showscores_force = (f & 1);
 501
 502         if(f & 2)
 503         {
 504                 newspectatee_status = ReadByte();
 505                 if(newspectatee_status == player_localnum + 1)
 506                         newspectatee_status = -1; // observing
 507         }
 508         else
 509                 newspectatee_status = 0;
 510
 511         spectatorbutton_zoom = (f & 4);
 512
 513         if(f & 8)
 514         {
 515                 angles_held_status = 1;
 516                 angles_held.x = ReadAngle();
 517                 angles_held.y = ReadAngle();
 518                 angles_held.z = 0;
 519         }
 520         else
 521                 angles_held_status = 0;
 522
 523         if(newspectatee_status != spectatee_status)
 524         {
 525                 // clear race stuff
 526                 race_laptime = 0;
 527                 race_checkpointtime = 0;
 528         }
 529         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 530         {
 531                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 532                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 533                 )
 534                         prev_p_health = -1;
 535                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 536                         prev_health = -1;
 537         }
 538         spectatee_status = newspectatee_status;
 539
 540         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 541 }
 542
 543 void Ent_Nagger()
 544 {
 545     int i, j, b, f;
 546
 547     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 548
 549         if(!(nags & 4))
 550         {
 551                 if(vote_called_vote)
 552                         strunzone(vote_called_vote);
 553                 vote_called_vote = string_null;
 554                 vote_active = 0;
 555         }
 556         else
 557         {
 558                 vote_active = 1;
 559         }
 560
 561         if(nags & 64)
 562         {
 563                 vote_yescount = ReadByte();
 564                 vote_nocount = ReadByte();
 565                 vote_needed = ReadByte();
 566                 vote_highlighted = ReadChar();
 567         }
 568
 569         if(nags & 128)
 570         {
 571                 if(vote_called_vote)
 572                         strunzone(vote_called_vote);
 573                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 574         }
 575
 576         if(nags & 1)
 577         {
 578                 for(j = 0; j < maxclients; ++j)
 579                         if(playerslots[j])
 580                                 playerslots[j].ready = 1;
 581                 for(i = 1; i <= maxclients; i += 8)
 582                 {
 583                         f = ReadByte();
 584                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 585                                 if (!(f & b))
 586                                         if(playerslots[j])
 587                                                 playerslots[j].ready = 0;
 588                 }
 589         }
 590
 591         ready_waiting = (nags & 1);
 592         ready_waiting_for_me = (nags & 2);
 593         vote_waiting = (nags & 4);
 594         vote_waiting_for_me = (nags & 8);
 595         warmup_stage = (nags & 16);
 596 }
 597
 598 void Ent_EliminatedPlayers()
 599 {
 600     int i, j, b, f;
 601
 602     int sf = ReadByte();
 603         if(sf & 1)
 604         {
 605                 for(j = 0; j < maxclients; ++j)
 606                         if(playerslots[j])
 607                                 playerslots[j].eliminated = 1;
 608                 for(i = 1; i <= maxclients; i += 8)
 609                 {
 610                         f = ReadByte();
 611                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 612                                 if (!(f & b))
 613                                         if(playerslots[j])
 614                                                 playerslots[j].eliminated = 0;
 615                 }
 616         }
 617 }
 618
 619 void Ent_RandomSeed()
 620 {
 621         float s;
 622         prandom_debug();
 623         s = ReadShort();
 624         psrandom(s);
 625 }
 626
 627 void Ent_ReadAccuracy(void)
 628 {
 629     int f, w;
 630     int sf = ReadInt24_t();
 631         if(sf == 0)
 632         {
 633                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 634                         weapon_accuracy[w] = -1;
 635                 return;
 636         }
 637
 638         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 639         {
 640                 if(sf & f)
 641                 {
 642             int b = ReadByte();
 643                         if(b == 0)
 644                                 weapon_accuracy[w] = -1;
 645                         else if(b == 255)
 646                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 647                         else
 648                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 649                 }
 650                 if(f == 0x800000)
 651                         f = 1;
 652                 else
 653                         f *= 2;
 654         }
 655 }
 656
 657 void Spawn_Draw(void)
 658 {
 659         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 660 }
 661
 662 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 663 {
 664         float teamnum = (ReadByte() - 1);
 665         vector spn_origin;
 666         spn_origin.x = ReadShort();
 667         spn_origin.y = ReadShort();
 668         spn_origin.z = ReadShort();
 669
 670         if(is_new)
 671         {
 672                 self.origin = spn_origin;
 673                 setsize(self, PL_MIN, PL_MAX);
 674                 droptofloor();
 675
 676                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 677                 {
 678                         self.mdl = "models/spawnpoint.md3";
 679                         self.colormod = Team_ColorRGB(teamnum);
 680                         precache_model(self.mdl);
 681                         setmodel(self, self.mdl);
 682                         self.drawmask = MASK_NORMAL;
 683                         //self.movetype = MOVETYPE_NOCLIP;
 684                         //self.draw = Spawn_Draw;
 685                 }*/
 686                 if(autocvar_cl_spawn_point_particles)
 687                 {
 688                         if((serverflags & SERVERFLAG_TEAMPLAY))
 689                         {
 690                                 switch(teamnum)
 691                                 {
 692                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
 693                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
 694                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
 695                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
 696                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
 697                                 }
 698                         }
 699                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
 700
 701                         self.draw = Spawn_Draw;
 702                 }
 703         }
 704
 705         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 706 }
 707
 708 void Ent_ReadSpawnEvent(float is_new)
 709 {
 710         // If entnum is 0, ONLY do the local spawn actions
 711         // this way the server can disable the sending of
 712         // spawn origin or such to clients if wanted.
 713         float entnum = ReadByte();
 714
 715         if(entnum)
 716         {
 717                 self.origin_x = ReadShort();
 718                 self.origin_y = ReadShort();
 719                 self.origin_z = ReadShort();
 720
 721                 if(is_new)
 722                 {
 723                         float teamnum = GetPlayerColor(entnum - 1);
 724
 725                         if(autocvar_cl_spawn_event_particles)
 726                         {
 727                                 switch(teamnum)
 728                                 {
 729                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
 730                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
 731                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
 732                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
 733                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
 734                                 }
 735                         }
 736                         if(autocvar_cl_spawn_event_sound)
 737                         {
 738                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
 739                         }
 740                 }
 741         }
 742
 743         // local spawn actions
 744         if(is_new && (!entnum || (entnum == player_localentnum)))
 745         {
 746                 zoomin_effect = 1;
 747                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 748
 749                 if(autocvar_cl_unpress_zoom_on_spawn)
 750                 {
 751                         localcmd("-zoom\n");
 752                         button_zoom = false;
 753                 }
 754         }
 755
 756         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 757 }
 758
 759 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 760 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 761 void Ent_RadarLink();
 762 void Ent_Init();
 763 void Ent_ScoresInfo();
 764 void CSQC_Ent_Update(float bIsNewEntity)
 765 {
 766         float t;
 767         float savetime;
 768         t = ReadByte();
 769
 770         if(autocvar_developer_csqcentities)
 771                 printf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 772
 773         // set up the "time" global for received entities to be correct for interpolation purposes
 774         savetime = time;
 775         if(servertime)
 776         {
 777                 time = servertime;
 778         }
 779         else
 780         {
 781                 serverprevtime = time;
 782                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 783                 time = serverprevtime + serverdeltatime;
 784         }
 785
 786 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 787         if(self.enttype)
 788         {
 789                 if(t != self.enttype || bIsNewEntity)
 790                 {
 791                         //print("A CSQC entity changed its type!\n");
 792                         printf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 793                         Ent_Remove();
 794                         clearentity(self);
 795                         bIsNewEntity = 1;
 796                 }
 797         }
 798         else
 799         {
 800                 if(!bIsNewEntity)
 801                 {
 802                         printf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 803                         bIsNewEntity = 1;
 804                 }
 805         }
 806 #endif
 807         self.enttype = t;
 808         switch(t)
 809         {
 810                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 811                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 812                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 813                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 814                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 815                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 816                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 817                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
 818                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 819                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 820                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 821                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 822                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 823                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 824                 case ENT_CLIENT_INIT: Ent_Init(); break;
 825                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 826                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 827                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 828                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 829                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 830                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 831                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 832                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 833                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 834                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 835                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 836                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 837                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
 838                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 839                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 840                 case ENT_CLIENT_TURRET: ent_turret(); break;
 841                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 842                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 843                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 844                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 845                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 846                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 847                 case ENT_CLIENT_HEALING_ORB: ent_healer(); break;
 848                 case ENT_CLIENT_LADDER: ent_func_ladder(); break;
 849                 case ENT_CLIENT_TRIGGER_PUSH: ent_trigger_push(); break;
 850                 case ENT_CLIENT_TARGET_PUSH: ent_target_push(); break;
 851                 case ENT_CLIENT_CONVEYOR: ent_conveyor(); break;
 852                 case ENT_CLIENT_DOOR: ent_door(); break;
 853                 case ENT_CLIENT_DOOR_TRIGGER: ent_door_trigger(); break;
 854                 case ENT_CLIENT_PLAT: ent_plat(); break;
 855                 case ENT_CLIENT_PLAT_TRIGGER: ent_plat_trigger(); break;
 856                 case ENT_CLIENT_SWAMP: ent_swamp(); break;
 857
 858                 default:
 859                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 860                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
 861                         break;
 862         }
 863
 864         time = savetime;
 865 }
 866 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 867 // used when an entity changes its type. For an entity that someone interacts
 868 // with others, make sure it can no longer do so.
 869 void Ent_Remove()
 870 {
 871         if(self.entremove)
 872                 self.entremove();
 873
 874         if(self.skeletonindex)
 875         {
 876                 skel_delete(self.skeletonindex);
 877                 self.skeletonindex = 0;
 878         }
 879
 880         if(self.snd_looping > 0)
 881         {
 882                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 883                 self.snd_looping = 0;
 884         }
 885
 886         self.enttype = 0;
 887         self.classname = "";
 888         self.draw = menu_sub_null;
 889         self.entremove = menu_sub_null;
 890         // TODO possibly set more stuff to defaults
 891 }
 892 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 893 void CSQC_Ent_Remove()
 894 {
 895         if(autocvar_developer_csqcentities)
 896                 printf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 897
 898         if(wasfreed(self))
 899         {
 900                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 901                 return;
 902         }
 903         if(self.enttype)
 904                 Ent_Remove();
 905         remove(self);
 906 }
 907
 908 void Gamemode_Init()
 909 {
 910         if (!isdemo())
 911         {
 912                 if(!(calledhooks & HOOK_START))
 913                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 914                 calledhooks |= HOOK_START;
 915         }
 916 }
 917 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 918 void CSQC_Parse_StuffCmd(string strMessage)
 919 {
 920         if(autocvar_developer_csqcentities)
 921                 printf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 922
 923         localcmd(strMessage);
 924 }
 925 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 926 void CSQC_Parse_Print(string strMessage)
 927 {
 928         if(autocvar_developer_csqcentities)
 929                 printf("CSQC_Parse_Print(\"%s\")\n", strMessage);
 930
 931         print(ColorTranslateRGB(strMessage));
 932 }
 933
 934 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 935 void CSQC_Parse_CenterPrint(string strMessage)
 936 {
 937         if(autocvar_developer_csqcentities)
 938                 printf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 939
 940         centerprint_hud(strMessage);
 941 }
 942
 943 string notranslate_fogcmd1 = "\nfog ";
 944 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 945 void Fog_Force()
 946 {
 947         // TODO somehow thwart prvm_globalset client ...
 948
 949         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 950                 { localcmd("\nr_drawfog 0\n"); }
 951         else if(forcefog != "")
 952                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
 953 }
 954
 955 void Gamemode_Init();
 956 void Ent_ScoresInfo()
 957 {
 958     int i;
 959         self.classname = "ent_client_scores_info";
 960         gametype = ReadInt24_t();
 961         HUD_ModIcons_SetFunc();
 962         for(i = 0; i < MAX_SCORE; ++i)
 963         {
 964                 if(scores_label[i])
 965                         strunzone(scores_label[i]);
 966                 scores_label[i] = strzone(ReadString());
 967                 scores_flags[i] = ReadByte();
 968         }
 969         for(i = 0; i < MAX_TEAMSCORE; ++i)
 970         {
 971                 if(teamscores_label[i])
 972                         strunzone(teamscores_label[i]);
 973                 teamscores_label[i] = strzone(ReadString());
 974                 teamscores_flags[i] = ReadByte();
 975         }
 976         HUD_InitScores();
 977         Gamemode_Init();
 978 }
 979
 980 void Ent_Init()
 981 {
 982         self.classname = "ent_client_init";
 983
 984         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 985
 986         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 987         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 988         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 989         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 990         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 991         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 992         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 993         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 994
 995         if(forcefog)
 996                 strunzone(forcefog);
 997         forcefog = strzone(ReadString());
 998
 999         armorblockpercent = ReadByte() / 255.0;
1000
1001         g_balance_mortar_bouncefactor = ReadCoord();
1002         g_balance_mortar_bouncestop = ReadCoord();
1003         g_balance_electro_secondary_bouncefactor = ReadCoord();
1004         g_balance_electro_secondary_bouncestop = ReadCoord();
1005
1006         vortex_scope = !ReadByte();
1007         rifle_scope = !ReadByte();
1008
1009         serverflags = ReadByte();
1010
1011         minelayer_maxmines = ReadByte();
1012
1013         hagar_maxrockets = ReadByte();
1014
1015         g_trueaim_minrange = ReadCoord();
1016         g_balance_porto_secondary = ReadByte();
1017
1018         if(!postinit)
1019                 PostInit();
1020 }
1021
1022 void Net_ReadRace()
1023 {
1024         float b;
1025
1026         b = ReadByte();
1027
1028         switch(b)
1029         {
1030                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1031                         race_checkpoint = ReadByte();
1032                         race_time = ReadInt24_t();
1033                         race_previousbesttime = ReadInt24_t();
1034                         if(race_previousbestname)
1035                                 strunzone(race_previousbestname);
1036                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1037
1038                         race_checkpointtime = time;
1039
1040                         if(race_checkpoint == 0 || race_checkpoint == 254)
1041                         {
1042                                 race_penaltyaccumulator = 0;
1043                                 race_laptime = time; // valid
1044                         }
1045
1046                         break;
1047
1048                 case RACE_NET_CHECKPOINT_CLEAR:
1049                         race_laptime = 0;
1050                         race_checkpointtime = 0;
1051                         break;
1052
1053                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1054                         race_laptime = ReadCoord();
1055                         race_checkpointtime = -99999;
1056                         // fall through
1057                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1058                         race_nextcheckpoint = ReadByte();
1059
1060                         race_nextbesttime = ReadInt24_t();
1061                         if(race_nextbestname)
1062                                 strunzone(race_nextbestname);
1063                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1064                         break;
1065
1066                 case RACE_NET_CHECKPOINT_HIT_RACE:
1067                         race_mycheckpoint = ReadByte();
1068                         race_mycheckpointtime = time;
1069                         race_mycheckpointdelta = ReadInt24_t();
1070                         race_mycheckpointlapsdelta = ReadByte();
1071                         if(race_mycheckpointlapsdelta >= 128)
1072                                 race_mycheckpointlapsdelta -= 256;
1073                         if(race_mycheckpointenemy)
1074                                 strunzone(race_mycheckpointenemy);
1075                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1076                         break;
1077
1078                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1079                         race_othercheckpoint = ReadByte();
1080                         race_othercheckpointtime = time;
1081                         race_othercheckpointdelta = ReadInt24_t();
1082                         race_othercheckpointlapsdelta = ReadByte();
1083                         if(race_othercheckpointlapsdelta >= 128)
1084                                 race_othercheckpointlapsdelta -= 256;
1085                         if(race_othercheckpointenemy)
1086                                 strunzone(race_othercheckpointenemy);
1087                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1088                         break;
1089
1090                 case RACE_NET_PENALTY_RACE:
1091                         race_penaltyeventtime = time;
1092                         race_penaltytime = ReadShort();
1093                         //race_penaltyaccumulator += race_penaltytime;
1094                         if(race_penaltyreason)
1095                                 strunzone(race_penaltyreason);
1096                         race_penaltyreason = strzone(ReadString());
1097                         break;
1098
1099                 case RACE_NET_PENALTY_QUALIFYING:
1100                         race_penaltyeventtime = time;
1101                         race_penaltytime = ReadShort();
1102                         race_penaltyaccumulator += race_penaltytime;
1103                         if(race_penaltyreason)
1104                                 strunzone(race_penaltyreason);
1105                         race_penaltyreason = strzone(ReadString());
1106                         break;
1107
1108                 case RACE_NET_SERVER_RECORD:
1109                         race_server_record = ReadInt24_t();
1110                         break;
1111                 case RACE_NET_SPEED_AWARD:
1112                         race_speedaward = ReadInt24_t();
1113                         if(race_speedaward_holder)
1114                                 strunzone(race_speedaward_holder);
1115                         race_speedaward_holder = strzone(ReadString());
1116                         break;
1117                 case RACE_NET_SPEED_AWARD_BEST:
1118                         race_speedaward_alltimebest = ReadInt24_t();
1119                         if(race_speedaward_alltimebest_holder)
1120                                 strunzone(race_speedaward_alltimebest_holder);
1121                         race_speedaward_alltimebest_holder = strzone(ReadString());
1122                         break;
1123                 case RACE_NET_SERVER_RANKINGS:
1124                         float prevpos, del;
1125             int pos = ReadShort();
1126                         prevpos = ReadShort();
1127                         del = ReadShort();
1128
1129                         // move other rankings out of the way
1130             int i;
1131                         if (prevpos) {
1132                                 for (i=prevpos-1;i>pos-1;--i) {
1133                                         grecordtime[i] = grecordtime[i-1];
1134                                         if(grecordholder[i])
1135                                                 strunzone(grecordholder[i]);
1136                                         grecordholder[i] = strzone(grecordholder[i-1]);
1137                                 }
1138                         } else if (del) { // a record has been deleted by the admin
1139                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1140                                         if (i == RANKINGS_CNT-1) { // clear out last record
1141                                                 grecordtime[i] = 0;
1142                                                 if (grecordholder[i])
1143                                                         strunzone(grecordholder[i]);
1144                                                 grecordholder[i] = string_null;
1145                                         }
1146                                         else {
1147                                                 grecordtime[i] = grecordtime[i+1];
1148                                                 if (grecordholder[i])
1149                                                         strunzone(grecordholder[i]);
1150                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1151                                         }
1152                                 }
1153                         } else { // player has no ranked record yet
1154                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1155                                         grecordtime[i] = grecordtime[i-1];
1156                                         if(grecordholder[i])
1157                                                 strunzone(grecordholder[i]);
1158                                         grecordholder[i] = strzone(grecordholder[i-1]);
1159                                 }
1160                         }
1161
1162                         // store new ranking
1163                         if(grecordholder[pos-1] != "")
1164                                 strunzone(grecordholder[pos-1]);
1165                         grecordholder[pos-1] = strzone(ReadString());
1166                         grecordtime[pos-1] = ReadInt24_t();
1167                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1168                                 race_myrank = pos;
1169                         break;
1170                 case RACE_NET_SERVER_STATUS:
1171                         race_status = ReadShort();
1172                         if(race_status_name)
1173                                 strunzone(race_status_name);
1174                         race_status_name = strzone(ReadString());
1175         }
1176 }
1177
1178 void Net_TeamNagger()
1179 {
1180         teamnagger = 1;
1181 }
1182
1183 void Net_ReadPingPLReport()
1184 {
1185         int e, pi, pl, ml;
1186         e = ReadByte();
1187         pi = ReadShort();
1188         pl = ReadByte();
1189         ml = ReadByte();
1190         if (!(playerslots[e]))
1191                 return;
1192         playerslots[e].ping = pi;
1193         playerslots[e].ping_packetloss = pl / 255.0;
1194         playerslots[e].ping_movementloss = ml / 255.0;
1195 }
1196
1197 void Net_WeaponComplain()
1198 {
1199         complain_weapon = ReadByte();
1200
1201         if(complain_weapon_name)
1202                 strunzone(complain_weapon_name);
1203         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1204
1205         complain_weapon_type = ReadByte();
1206
1207         complain_weapon_time = time;
1208         weapontime = time; // ping the weapon panel
1209
1210         switch(complain_weapon_type)
1211         {
1212                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1213                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1214                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1215         }
1216 }
1217
1218 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1219 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1220 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1221 float CSQC_Parse_TempEntity()
1222 {
1223         float bHandled;
1224                 bHandled  = true;
1225         // Acquire TE ID
1226         float nTEID;
1227                 nTEID = ReadByte();
1228
1229         if(autocvar_developer_csqcentities)
1230                 printf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1231
1232                 // NOTE: Could just do return instead of break...
1233         switch(nTEID)
1234         {
1235                 case TE_CSQC_TARGET_MUSIC:
1236                         Net_TargetMusic();
1237                         bHandled = true;
1238                         break;
1239                 case TE_CSQC_PICTURE:
1240                         Net_MapVote_Picture();
1241                         bHandled = true;
1242                         break;
1243                 case TE_CSQC_RACE:
1244                         Net_ReadRace();
1245                         bHandled = true;
1246                         break;
1247                 case TE_CSQC_VORTEXBEAMPARTICLE:
1248                         Net_ReadVortexBeamParticle();
1249                         bHandled = true;
1250                         break;
1251                 case TE_CSQC_TEAMNAGGER:
1252                         Net_TeamNagger();
1253                         bHandled = true;
1254                         break;
1255                 case TE_CSQC_ARC:
1256                         Net_ReadArc();
1257                         bHandled = true;
1258                         break;
1259                 case TE_CSQC_PINGPLREPORT:
1260                         Net_ReadPingPLReport();
1261                         bHandled = true;
1262                         break;
1263                 case TE_CSQC_WEAPONCOMPLAIN:
1264                         Net_WeaponComplain();
1265                         bHandled = true;
1266                         break;
1267                 case TE_CSQC_VEHICLESETUP:
1268                         Net_VehicleSetup();
1269                         bHandled = true;
1270                         break;
1271                 case TE_CSQC_SVNOTICE:
1272                         cl_notice_read();
1273                         bHandled = true;
1274                         break;
1275                 case TE_CSQC_SHOCKWAVEPARTICLE:
1276                         Net_ReadShockwaveParticle();
1277                         bHandled = true;
1278                         break;
1279                 default:
1280                         // No special logic for this temporary entity; return 0 so the engine can handle it
1281                         bHandled = false;
1282                         break;
1283         }
1284
1285         return bHandled;
1286 }
1287
1288 string getcommandkey(string text, string command)
1289 {
1290         string keys;
1291         float n, j, k, l = 0;
1292
1293         if (!autocvar_hud_showbinds)
1294                 return text;
1295
1296         keys = db_get(binddb, command);
1297         if (keys == "")
1298         {
1299                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1300                 for(j = 0; j < n; ++j)
1301                 {
1302                         k = stof(argv(j));
1303                         if(k != -1)
1304                         {
1305                                 if ("" == keys)
1306                                         keys = keynumtostring(k);
1307                                 else
1308                                         keys = strcat(keys, ", ", keynumtostring(k));
1309
1310                                 ++l;
1311                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1312                                         break;
1313                         }
1314
1315                 }
1316                 if (keys == "")
1317                         keys = "NO_KEY";
1318                 db_put(binddb, command, keys);
1319         }
1320
1321         if (keys == "NO_KEY") {
1322                 if (autocvar_hud_showbinds > 1)
1323                         return sprintf(_("%s (not bound)"), text);
1324                 else
1325                         return text;
1326         }
1327         else if (autocvar_hud_showbinds > 1)
1328                 return sprintf("%s (%s)", text, keys);
1329         else
1330                 return keys;
1331 }