qcsrc/client/main.qc

   1 #include "main.qh"
   2 #include "_all.qh"
   3
   4 #include "casings.qh"
   5 #include "controlpoint.qh"
   6 #include "csqcmodel_hooks.qh"
   7 #include "damage.qh"
   8 #include "effects.qh"
   9 #include "generator.qh"
  10 #include "gibs.qh"
  11 #include "hook.qh"
  12 #include "hud.qh"
  13 #include "hud_config.qh"
  14 #include "laser.qh"
  15 #include "mapvoting.qh"
  16 #include "modeleffects.qh"
  17 #include "particles.qh"
  18 #include "prandom.qh"
  19 #include "scoreboard.qh"
  20 #include "shownames.qh"
  21 #include "sortlist.qh"
  22 #include "tuba.qh"
  23 #include "t_items.qh"
  24 #include "wall.qh"
  25 #include "waypointsprites.qh"
  26
  27 #include "../common/vehicles/all.qh"
  28
  29 #include "mutators/events.qh"
  30
  31 #include "weapons/projectile.qh"
  32
  33 #include "../common/buffs.qh"
  34 #include "../common/deathtypes.qh"
  35 #include "../common/effects.qh"
  36 #include "../common/mapinfo.qh"
  37 #include "../common/monsters/all.qh"
  38 #include "../common/nades.qh"
  39 #include "../common/net_notice.qh"
  40 #include "../common/notifications.qh"
  41 #include "../common/stats.qh"
  42 #include "../common/teams.qh"
  43
  44 #include "../common/items/all.qh"
  45
  46 #include "../common/mutators/base.qh"
  47
  48 #include "../common/weapons/all.qh"
  49
  50 #include "../csqcmodellib/cl_model.qh"
  51 #include "../csqcmodellib/interpolate.qh"
  52
  53 #include "../common/triggers/include.qh"
  54
  55 #include "../common/turrets/cl_turrets.qh"
  56 #include "../common/turrets/turrets.qh"
  57
  58 #include "../warpzonelib/client.qh"
  59
  60 // --------------------------------------------------------------------------
  61 // BEGIN REQUIRED CSQC FUNCTIONS
  62 //include "main.qh"
  63
  64 entity clearentity_ent;
  65 void clearentity(entity e)
  66 {
  67         if (!clearentity_ent)
  68         {
  69                 clearentity_ent = spawn();
  70                 clearentity_ent.classname = "clearentity";
  71         }
  72         int n = e.entnum;
  73         copyentity(clearentity_ent, e);
  74         e.entnum = n;
  75 }
  76
  77 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  78 void menu_show_error()
  79 {
  80         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  81 }
  82
  83 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  84 // Useful for precaching things
  85
  86 void menu_sub_null()
  87 {
  88 }
  89
  90 string forcefog;
  91 void WaypointSprite_Load();
  92 void ConsoleCommand_macro_init();
  93 void CSQC_Init(void)
  94 {
  95         prvm_language = cvar_string("prvm_language");
  96
  97 #ifdef WATERMARK
  98         dprintf("^4CSQC Build information: ^1%s\n", WATERMARK);
  99 #endif
 100
 101         int i;
 102
 103         binddb = db_create();
 104         tempdb = db_create();
 105         ClientProgsDB = db_load("client.db");
 106         compressShortVector_init();
 107
 108         draw_endBoldFont();
 109         menu_visible = false;
 110         menu_show = menu_show_error;
 111         menu_action = func_null;
 112
 113         for(i = 0; i < 255; ++i)
 114                 if(getplayerkeyvalue(i, "viewentity") == "")
 115                         break;
 116         maxclients = i;
 117
 118         //registercommand("hud_configure");
 119         //registercommand("hud_save");
 120         //registercommand("menu_action");
 121
 122         ConsoleCommand_macro_init();
 123
 124         registercvar("hud_usecsqc", "1");
 125         registercvar("scoreboard_columns", "default");
 126
 127         registercvar("cl_nade_type", "3");
 128         registercvar("cl_pokenade_type", "zombie");
 129
 130         registercvar("cl_jumpspeedcap_min", "");
 131         registercvar("cl_jumpspeedcap_max", "");
 132
 133         gametype = 0;
 134
 135         // hud_fields uses strunzone on the titles!
 136         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 137                 hud_title[i] = strzone("(null)");
 138
 139         Cmd_HUD_SetFields(0);
 140
 141         postinit = false;
 142
 143         calledhooks = 0;
 144
 145         teams = Sort_Spawn();
 146         players = Sort_Spawn();
 147
 148         GetTeam(NUM_SPECTATOR, true); // add specs first
 149
 150         // needs to be done so early because of the constants they create
 151         static_init();
 152         CALL_ACCUMULATED_FUNCTION(RegisterTurrets);
 153         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 154         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 155         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
 156         CALL_ACCUMULATED_FUNCTION(RegisterEffects);
 157
 158         WaypointSprite_Load();
 159
 160         // precaches
 161         precache_model("null");
 162         precache_sound("misc/hit.wav");
 163         precache_sound("misc/typehit.wav");
 164
 165         generator_precache();
 166         Projectile_Precache();
 167         Hook_Precache();
 168         GibSplash_Precache();
 169         Casings_Precache();
 170         Tuba_Precache();
 171         CSQCPlayer_Precache();
 172
 173         if(autocvar_cl_reticle)
 174         {
 175                 precache_pic("gfx/reticle_normal");
 176                 // weapon reticles are precached in weapon files
 177         }
 178
 179         get_mi_min_max_texcoords(1); // try the CLEVER way first
 180         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 181         shortmapname = mi_shortname;
 182
 183         if(precache_pic(minimapname) == "")
 184         {
 185                 // but maybe we have a non-clever minimap
 186                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 187                 if(precache_pic(minimapname) == "")
 188                         minimapname = ""; // FAIL
 189                 else
 190                         get_mi_min_max_texcoords(0); // load new texcoords
 191         }
 192
 193         mi_center = (mi_min + mi_max) * 0.5;
 194         mi_scale = mi_max - mi_min;
 195         minimapname = strzone(minimapname);
 196
 197         WarpZone_Init();
 198
 199         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 200         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 201 }
 202
 203 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 204 void Shutdown(void)
 205 {
 206         WarpZone_Shutdown();
 207
 208         remove(teams);
 209         remove(players);
 210         db_close(binddb);
 211         db_close(tempdb);
 212         if(autocvar_cl_db_saveasdump)
 213                 db_dump(ClientProgsDB, "client.db");
 214         else
 215                 db_save(ClientProgsDB, "client.db");
 216         db_close(ClientProgsDB);
 217
 218         if(camera_active)
 219                 cvar_set("chase_active",ftos(chase_active_backup));
 220
 221         // unset the event chasecam's chase_active
 222         if(autocvar_chase_active < 0)
 223                 cvar_set("chase_active", "0");
 224
 225         if (!isdemo())
 226         {
 227                 if (!(calledhooks & HOOK_START))
 228                         localcmd("\n_cl_hook_gamestart nop\n");
 229                 if (!(calledhooks & HOOK_END))
 230                         localcmd("\ncl_hook_gameend\n");
 231         }
 232 }
 233
 234 .float has_team;
 235 float SetTeam(entity o, int Team)
 236 {
 237         entity tm;
 238         if(teamplay)
 239         {
 240                 switch(Team)
 241                 {
 242                         case -1:
 243                         case NUM_TEAM_1:
 244                         case NUM_TEAM_2:
 245                         case NUM_TEAM_3:
 246                         case NUM_TEAM_4:
 247                                 break;
 248                         default:
 249                                 if(GetTeam(Team, false) == world)
 250                                 {
 251                                         dprintf("trying to switch to unsupported team %d\n", Team);
 252                                         Team = NUM_SPECTATOR;
 253                                 }
 254                                 break;
 255                 }
 256         }
 257         else
 258         {
 259                 switch(Team)
 260                 {
 261                         case -1:
 262                         case 0:
 263                                 break;
 264                         default:
 265                                 if(GetTeam(Team, false) == world)
 266                                 {
 267                                         dprintf("trying to switch to unsupported team %d\n", Team);
 268                                         Team = NUM_SPECTATOR;
 269                                 }
 270                                 break;
 271                 }
 272         }
 273         if(Team == -1) // leave
 274         {
 275                 if(o.has_team)
 276                 {
 277                         tm = GetTeam(o.team, false);
 278                         tm.team_size -= 1;
 279                         o.has_team = 0;
 280                         return true;
 281                 }
 282         }
 283         else
 284         {
 285                 if (!o.has_team)
 286                 {
 287                         o.team = Team;
 288                         tm = GetTeam(Team, true);
 289                         tm.team_size += 1;
 290                         o.has_team = 1;
 291                         return true;
 292                 }
 293                 else if(Team != o.team)
 294                 {
 295                         tm = GetTeam(o.team, false);
 296                         tm.team_size -= 1;
 297                         o.team = Team;
 298                         tm = GetTeam(Team, true);
 299                         tm.team_size += 1;
 300                         return true;
 301                 }
 302         }
 303         return false;
 304 }
 305
 306 void Playerchecker_Think()
 307 {
 308     int i;
 309         entity e;
 310         for(i = 0; i < maxclients; ++i)
 311         {
 312                 e = playerslots[i];
 313                 if(GetPlayerName(i) == "")
 314                 {
 315                         if(e.sort_prev)
 316                         {
 317                                 // player disconnected
 318                                 SetTeam(e, -1);
 319                                 RemovePlayer(e);
 320                                 e.sort_prev = world;
 321                                 //e.gotscores = 0;
 322                         }
 323                 }
 324                 else
 325                 {
 326                         if (!e.sort_prev)
 327                         {
 328                                 // player connected
 329                                 if (!e)
 330                                         playerslots[i] = e = spawn();
 331                                 e.sv_entnum = i;
 332                                 e.ping = 0;
 333                                 e.ping_packetloss = 0;
 334                                 e.ping_movementloss = 0;
 335                                 //e.gotscores = 0; // we might already have the scores...
 336                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 337                                 RegisterPlayer(e);
 338                                 HUD_UpdatePlayerPos(e);
 339                         }
 340                 }
 341         }
 342         self.nextthink = time + 0.2;
 343 }
 344
 345 void Porto_Init();
 346 void TrueAim_Init();
 347 void PostInit(void)
 348 {
 349         entity playerchecker;
 350         playerchecker = spawn();
 351         playerchecker.think = Playerchecker_Think;
 352         playerchecker.nextthink = time + 0.2;
 353
 354         Porto_Init();
 355         TrueAim_Init();
 356
 357         postinit = true;
 358 }
 359
 360 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 361 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 362 // All keys are in ascii.
 363 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 364 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 365 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 366 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 367 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 368 {
 369         float bSkipKey;
 370         bSkipKey = false;
 371
 372         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 373                 return true;
 374
 375         if ( HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary) )
 376                 return true;
 377
 378         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 379                 return true;
 380
 381         if(menu_visible && menu_action)
 382                 if(menu_action(bInputType, nPrimary, nSecondary))
 383                         return true;
 384
 385         return bSkipKey;
 386 }
 387
 388 // END REQUIRED CSQC FUNCTIONS
 389 // --------------------------------------------------------------------------
 390
 391 // --------------------------------------------------------------------------
 392 // BEGIN OPTIONAL CSQC FUNCTIONS
 393
 394 void Ent_RemoveEntCS()
 395 {
 396         entcs_receiver[self.sv_entnum] = world;
 397 }
 398 void Ent_ReadEntCS()
 399 {
 400     int sf;
 401         InterpolateOrigin_Undo();
 402
 403         self.classname = "entcs_receiver";
 404         sf = ReadByte();
 405
 406         if(sf & 1)
 407                 self.sv_entnum = ReadByte();
 408         if(sf & 2)
 409         {
 410                 self.origin_x = ReadShort();
 411                 self.origin_y = ReadShort();
 412                 self.origin_z = ReadShort();
 413                 setorigin(self, self.origin);
 414         }
 415         if(sf & 4)
 416         {
 417                 self.angles_y = ReadByte() * 360.0 / 256;
 418                 self.angles_x = self.angles_z = 0;
 419         }
 420         if(sf & 8)
 421                 self.healthvalue = ReadByte() * 10;
 422         if(sf & 16)
 423                 self.armorvalue = ReadByte() * 10;
 424
 425         entcs_receiver[self.sv_entnum] = self;
 426         self.entremove = Ent_RemoveEntCS;
 427         self.iflags |= IFLAG_ORIGIN;
 428
 429         InterpolateOrigin_Note();
 430 }
 431
 432 void Ent_Remove();
 433
 434 void Ent_RemovePlayerScore()
 435 {
 436         if(self.owner) {
 437                 SetTeam(self.owner, -1);
 438                 self.owner.gotscores = 0;
 439                 for(int i = 0; i < MAX_SCORE; ++i) {
 440                         self.owner.(scores[i]) = 0; // clear all scores
 441                 }
 442         }
 443 }
 444
 445 void Ent_ReadPlayerScore()
 446 {
 447         int i, n;
 448         bool isNew;
 449         entity o;
 450
 451         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 452         // (no I've never heard of M-x replace-string, sed, or anything like that)
 453         isNew = !self.owner; // workaround for DP bug
 454         n = ReadByte()-1;
 455
 456 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 457         if(!isNew && n != self.sv_entnum)
 458         {
 459                 //print("A CSQC entity changed its owner!\n");
 460                 printf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 461                 isNew = true;
 462                 Ent_Remove();
 463                 self.enttype = ENT_CLIENT_SCORES;
 464         }
 465 #endif
 466
 467         self.sv_entnum = n;
 468
 469         if (!(playerslots[self.sv_entnum]))
 470                 playerslots[self.sv_entnum] = spawn();
 471         o = self.owner = playerslots[self.sv_entnum];
 472         o.sv_entnum = self.sv_entnum;
 473         o.gotscores = 1;
 474
 475         //if (!o.sort_prev)
 476         //      RegisterPlayer(o);
 477         //playerchecker will do this for us later, if it has not already done so
 478
 479     int sf, lf;
 480 #if MAX_SCORE <= 8
 481         sf = ReadByte();
 482         lf = ReadByte();
 483 #else
 484         sf = ReadShort();
 485         lf = ReadShort();
 486 #endif
 487     int p;
 488         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 489                 if(sf & p)
 490                 {
 491                         if(lf & p)
 492                                 o.(scores[i]) = ReadInt24_t();
 493                         else
 494                                 o.(scores[i]) = ReadChar();
 495                 }
 496
 497         if(o.sort_prev)
 498                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 499
 500         self.entremove = Ent_RemovePlayerScore;
 501 }
 502
 503 void Ent_ReadTeamScore()
 504 {
 505         int i;
 506         entity o;
 507
 508         self.team = ReadByte();
 509         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 510
 511     int sf, lf;
 512 #if MAX_TEAMSCORE <= 8
 513         sf = ReadByte();
 514         lf = ReadByte();
 515 #else
 516         sf = ReadShort();
 517         lf = ReadShort();
 518 #endif
 519         int p;
 520         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 521                 if(sf & p)
 522                 {
 523                         if(lf & p)
 524                                 o.(teamscores[i]) = ReadInt24_t();
 525                         else
 526                                 o.(teamscores[i]) = ReadChar();
 527                 }
 528
 529         HUD_UpdateTeamPos(o);
 530 }
 531
 532 void Ent_ClientData()
 533 {
 534         float newspectatee_status;
 535
 536     int f = ReadByte();
 537
 538         scoreboard_showscores_force = (f & 1);
 539
 540         if(f & 2)
 541         {
 542                 newspectatee_status = ReadByte();
 543                 if(newspectatee_status == player_localnum + 1)
 544                         newspectatee_status = -1; // observing
 545         }
 546         else
 547                 newspectatee_status = 0;
 548
 549         spectatorbutton_zoom = (f & 4);
 550
 551         if(f & 8)
 552         {
 553                 angles_held_status = 1;
 554                 angles_held.x = ReadAngle();
 555                 angles_held.y = ReadAngle();
 556                 angles_held.z = 0;
 557         }
 558         else
 559                 angles_held_status = 0;
 560
 561         if(newspectatee_status != spectatee_status)
 562         {
 563                 // clear race stuff
 564                 race_laptime = 0;
 565                 race_checkpointtime = 0;
 566         }
 567         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 568         {
 569                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 570                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 571                 )
 572                         prev_p_health = -1;
 573                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 574                         prev_health = -1;
 575         }
 576         spectatee_status = newspectatee_status;
 577
 578         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 579 }
 580
 581 void Ent_Nagger()
 582 {
 583     int i, j, b, f;
 584
 585     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 586
 587         if(!(nags & 4))
 588         {
 589                 if(vote_called_vote)
 590                         strunzone(vote_called_vote);
 591                 vote_called_vote = string_null;
 592                 vote_active = 0;
 593         }
 594         else
 595         {
 596                 vote_active = 1;
 597         }
 598
 599         if(nags & 64)
 600         {
 601                 vote_yescount = ReadByte();
 602                 vote_nocount = ReadByte();
 603                 vote_needed = ReadByte();
 604                 vote_highlighted = ReadChar();
 605         }
 606
 607         if(nags & 128)
 608         {
 609                 if(vote_called_vote)
 610                         strunzone(vote_called_vote);
 611                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 612         }
 613
 614         if(nags & 1)
 615         {
 616                 for(j = 0; j < maxclients; ++j)
 617                         if(playerslots[j])
 618                                 playerslots[j].ready = 1;
 619                 for(i = 1; i <= maxclients; i += 8)
 620                 {
 621                         f = ReadByte();
 622                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 623                                 if (!(f & b))
 624                                         if(playerslots[j])
 625                                                 playerslots[j].ready = 0;
 626                 }
 627         }
 628
 629         ready_waiting = (nags & 1);
 630         ready_waiting_for_me = (nags & 2);
 631         vote_waiting = (nags & 4);
 632         vote_waiting_for_me = (nags & 8);
 633         warmup_stage = (nags & 16);
 634 }
 635
 636 void Ent_EliminatedPlayers()
 637 {
 638     int i, j, b, f;
 639
 640     int sf = ReadByte();
 641         if(sf & 1)
 642         {
 643                 for(j = 0; j < maxclients; ++j)
 644                         if(playerslots[j])
 645                                 playerslots[j].eliminated = 1;
 646                 for(i = 1; i <= maxclients; i += 8)
 647                 {
 648                         f = ReadByte();
 649                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 650                                 if (!(f & b))
 651                                         if(playerslots[j])
 652                                                 playerslots[j].eliminated = 0;
 653                 }
 654         }
 655 }
 656
 657 void Ent_RandomSeed()
 658 {
 659         float s;
 660         prandom_debug();
 661         s = ReadShort();
 662         psrandom(s);
 663 }
 664
 665 void Ent_ReadAccuracy(void)
 666 {
 667     int f, w;
 668     int sf = ReadInt24_t();
 669         if(sf == 0)
 670         {
 671                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 672                         weapon_accuracy[w] = -1;
 673                 return;
 674         }
 675
 676         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 677         {
 678                 if(sf & f)
 679                 {
 680             int b = ReadByte();
 681                         if(b == 0)
 682                                 weapon_accuracy[w] = -1;
 683                         else if(b == 255)
 684                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 685                         else
 686                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 687                 }
 688                 if(f == 0x800000)
 689                         f = 1;
 690                 else
 691                         f *= 2;
 692         }
 693 }
 694
 695 void Spawn_Draw(void)
 696 {
 697         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 698 }
 699
 700 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 701 {
 702         float teamnum = (ReadByte() - 1);
 703         vector spn_origin;
 704         spn_origin.x = ReadShort();
 705         spn_origin.y = ReadShort();
 706         spn_origin.z = ReadShort();
 707
 708         if(is_new)
 709         {
 710                 self.origin = spn_origin;
 711                 setsize(self, PL_MIN_CONST, PL_MAX_CONST);
 712                 droptofloor();
 713
 714                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 715                 {
 716                         self.mdl = "models/spawnpoint.md3";
 717                         self.colormod = Team_ColorRGB(teamnum);
 718                         precache_model(self.mdl);
 719                         setmodel(self, self.mdl);
 720                         self.drawmask = MASK_NORMAL;
 721                         //self.movetype = MOVETYPE_NOCLIP;
 722                         //self.draw = Spawn_Draw;
 723                 }*/
 724                 if(autocvar_cl_spawn_point_particles)
 725                 {
 726                         if((serverflags & SERVERFLAG_TEAMPLAY))
 727                         {
 728                                 switch(teamnum)
 729                                 {
 730                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
 731                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
 732                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
 733                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
 734                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
 735                                 }
 736                         }
 737                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
 738
 739                         self.draw = Spawn_Draw;
 740                 }
 741         }
 742
 743         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 744 }
 745
 746 void Ent_ReadSpawnEvent(float is_new)
 747 {
 748         // If entnum is 0, ONLY do the local spawn actions
 749         // this way the server can disable the sending of
 750         // spawn origin or such to clients if wanted.
 751         float entnum = ReadByte();
 752
 753         if(entnum)
 754         {
 755                 self.origin_x = ReadShort();
 756                 self.origin_y = ReadShort();
 757                 self.origin_z = ReadShort();
 758
 759                 if(is_new)
 760                 {
 761                         float teamnum = GetPlayerColor(entnum - 1);
 762
 763                         if(autocvar_cl_spawn_event_particles)
 764                         {
 765                                 switch(teamnum)
 766                                 {
 767                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
 768                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
 769                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
 770                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
 771                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
 772                                 }
 773                         }
 774                         if(autocvar_cl_spawn_event_sound)
 775                         {
 776                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
 777                         }
 778                 }
 779         }
 780
 781         // local spawn actions
 782         if(is_new && (!entnum || (entnum == player_localentnum)))
 783         {
 784                 zoomin_effect = 1;
 785                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 786
 787                 if(autocvar_cl_unpress_zoom_on_spawn)
 788                 {
 789                         localcmd("-zoom\n");
 790                         button_zoom = false;
 791                 }
 792         }
 793         HUD_Radar_Hide_Maximized();
 794         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 795 }
 796
 797 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 798 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 799 void Ent_RadarLink();
 800 void Ent_Init();
 801 void Ent_ScoresInfo();
 802 void CSQC_Ent_Update(float bIsNewEntity)
 803 {
 804         float t;
 805         float savetime;
 806         t = ReadByte();
 807
 808         if(autocvar_developer_csqcentities)
 809                 printf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 810
 811         // set up the "time" global for received entities to be correct for interpolation purposes
 812         savetime = time;
 813         if(servertime)
 814         {
 815                 time = servertime;
 816         }
 817         else
 818         {
 819                 serverprevtime = time;
 820                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 821                 time = serverprevtime + serverdeltatime;
 822         }
 823
 824 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 825         if(self.enttype)
 826         {
 827                 if(t != self.enttype || bIsNewEntity)
 828                 {
 829                         //print("A CSQC entity changed its type!\n");
 830                         printf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 831                         Ent_Remove();
 832                         clearentity(self);
 833                         bIsNewEntity = 1;
 834                 }
 835         }
 836         else
 837         {
 838                 if(!bIsNewEntity)
 839                 {
 840                         printf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 841                         bIsNewEntity = 1;
 842                 }
 843         }
 844 #endif
 845         self.enttype = t;
 846         switch(t)
 847         {
 848                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 849                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 850                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 851                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 852                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 853                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 854                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 855                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
 856                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 857                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 858                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 859                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 860                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 861                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 862                 case ENT_CLIENT_INIT: Ent_Init(); break;
 863                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 864                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 865                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 866                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 867                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 868                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 869                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 870                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 871                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 872                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 873                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 874                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 875                 case ENT_CLIENT_INVENTORY: Inventory_Read(self); break;
 876                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
 877                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 878                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 879                 case ENT_CLIENT_TURRET: ent_turret(); break;
 880                 case ENT_CLIENT_GENERATOR: ent_generator(); break;
 881                 case ENT_CLIENT_CONTROLPOINT_ICON: ent_cpicon(); break;
 882                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 883                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 884                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 885                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 886                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 887                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 888                 case ENT_CLIENT_HEALING_ORB: ent_healer(); break;
 889                 case ENT_CLIENT_VIEWLOC: ent_viewloc(); break;
 890                 case ENT_CLIENT_VIEWLOC_TRIGGER: ent_viewloc_trigger(); break;
 891                 case ENT_CLIENT_LADDER: ent_func_ladder(); break;
 892                 case ENT_CLIENT_TRIGGER_PUSH: ent_trigger_push(); break;
 893                 case ENT_CLIENT_TARGET_PUSH: ent_target_push(); break;
 894                 case ENT_CLIENT_CONVEYOR: ent_conveyor(); break;
 895                 case ENT_CLIENT_DOOR: ent_door(); break;
 896                 case ENT_CLIENT_PLAT: ent_plat(); break;
 897                 case ENT_CLIENT_SWAMP: ent_swamp(); break;
 898                 case ENT_CLIENT_CORNER: ent_corner(); break;
 899                 case ENT_CLIENT_KEYLOCK: ent_keylock(); break;
 900                 case ENT_CLIENT_TRAIN: ent_train(); break;
 901                 case ENT_CLIENT_TRIGGER_IMPULSE: ent_trigger_impulse(); break;
 902                 case ENT_CLIENT_EFFECT: Read_Effect(bIsNewEntity); break;
 903
 904                 default:
 905                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 906                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
 907                         break;
 908         }
 909
 910         time = savetime;
 911 }
 912 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 913 // used when an entity changes its type. For an entity that someone interacts
 914 // with others, make sure it can no longer do so.
 915 void Ent_Remove()
 916 {
 917         if(self.entremove)
 918                 self.entremove();
 919
 920         if(self.skeletonindex)
 921         {
 922                 skel_delete(self.skeletonindex);
 923                 self.skeletonindex = 0;
 924         }
 925
 926         if(self.snd_looping > 0)
 927         {
 928                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 929                 self.snd_looping = 0;
 930         }
 931
 932         self.enttype = 0;
 933         self.classname = "";
 934         self.draw = menu_sub_null;
 935         self.entremove = menu_sub_null;
 936         // TODO possibly set more stuff to defaults
 937 }
 938 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 939 void CSQC_Ent_Remove()
 940 {
 941         if(autocvar_developer_csqcentities)
 942                 printf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 943
 944         if(wasfreed(self))
 945         {
 946                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 947                 return;
 948         }
 949         if(self.enttype)
 950                 Ent_Remove();
 951         remove(self);
 952 }
 953
 954 void Gamemode_Init()
 955 {
 956         if (!isdemo())
 957         {
 958                 if(!(calledhooks & HOOK_START))
 959                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 960                 calledhooks |= HOOK_START;
 961         }
 962 }
 963 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 964 void CSQC_Parse_StuffCmd(string strMessage)
 965 {
 966         if(autocvar_developer_csqcentities)
 967                 printf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 968
 969         localcmd(strMessage);
 970 }
 971 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 972 void CSQC_Parse_Print(string strMessage)
 973 {
 974         if(autocvar_developer_csqcentities)
 975                 printf("CSQC_Parse_Print(\"%s\")\n", strMessage);
 976
 977         print(ColorTranslateRGB(strMessage));
 978 }
 979
 980 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 981 void CSQC_Parse_CenterPrint(string strMessage)
 982 {
 983         if(autocvar_developer_csqcentities)
 984                 printf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 985
 986         centerprint_hud(strMessage);
 987 }
 988
 989 string notranslate_fogcmd1 = "\nfog ";
 990 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 991 void Fog_Force()
 992 {
 993         // TODO somehow thwart prvm_globalset client ...
 994
 995         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 996                 { localcmd("\nr_drawfog 0\n"); }
 997         else if(forcefog != "")
 998                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
 999 }
1000
1001 void Gamemode_Init();
1002 void Ent_ScoresInfo()
1003 {
1004     int i;
1005         self.classname = "ent_client_scores_info";
1006         gametype = ReadInt24_t();
1007         HUD_ModIcons_SetFunc();
1008         for(i = 0; i < MAX_SCORE; ++i)
1009         {
1010                 if(scores_label[i])
1011                         strunzone(scores_label[i]);
1012                 scores_label[i] = strzone(ReadString());
1013                 scores_flags[i] = ReadByte();
1014         }
1015         for(i = 0; i < MAX_TEAMSCORE; ++i)
1016         {
1017                 if(teamscores_label[i])
1018                         strunzone(teamscores_label[i]);
1019                 teamscores_label[i] = strzone(ReadString());
1020                 teamscores_flags[i] = ReadByte();
1021         }
1022         HUD_InitScores();
1023         Gamemode_Init();
1024 }
1025
1026 void Ent_Init()
1027 {
1028         self.classname = "ent_client_init";
1029
1030         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1031
1032         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1033         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1034         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1035         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1036         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1037         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1038         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1039         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1040
1041         if(forcefog)
1042                 strunzone(forcefog);
1043         forcefog = strzone(ReadString());
1044
1045         armorblockpercent = ReadByte() / 255.0;
1046
1047         g_balance_mortar_bouncefactor = ReadCoord();
1048         g_balance_mortar_bouncestop = ReadCoord();
1049         g_balance_electro_secondary_bouncefactor = ReadCoord();
1050         g_balance_electro_secondary_bouncestop = ReadCoord();
1051
1052         vortex_scope = !ReadByte();
1053         rifle_scope = !ReadByte();
1054
1055         serverflags = ReadByte();
1056
1057         minelayer_maxmines = ReadByte();
1058
1059         hagar_maxrockets = ReadByte();
1060
1061         g_trueaim_minrange = ReadCoord();
1062         g_balance_porto_secondary = ReadByte();
1063
1064         if(!postinit)
1065                 PostInit();
1066 }
1067
1068 void Net_ReadRace()
1069 {
1070         float b;
1071
1072         b = ReadByte();
1073
1074         switch(b)
1075         {
1076                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1077                         race_checkpoint = ReadByte();
1078                         race_time = ReadInt24_t();
1079                         race_previousbesttime = ReadInt24_t();
1080                         if(race_previousbestname)
1081                                 strunzone(race_previousbestname);
1082                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1083
1084                         race_checkpointtime = time;
1085
1086                         if(race_checkpoint == 0 || race_checkpoint == 254)
1087                         {
1088                                 race_penaltyaccumulator = 0;
1089                                 race_laptime = time; // valid
1090                         }
1091
1092                         break;
1093
1094                 case RACE_NET_CHECKPOINT_CLEAR:
1095                         race_laptime = 0;
1096                         race_checkpointtime = 0;
1097                         break;
1098
1099                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1100                         race_laptime = ReadCoord();
1101                         race_checkpointtime = -99999;
1102                         // fall through
1103                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1104                         race_nextcheckpoint = ReadByte();
1105
1106                         race_nextbesttime = ReadInt24_t();
1107                         if(race_nextbestname)
1108                                 strunzone(race_nextbestname);
1109                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1110                         break;
1111
1112                 case RACE_NET_CHECKPOINT_HIT_RACE:
1113                         race_mycheckpoint = ReadByte();
1114                         race_mycheckpointtime = time;
1115                         race_mycheckpointdelta = ReadInt24_t();
1116                         race_mycheckpointlapsdelta = ReadByte();
1117                         if(race_mycheckpointlapsdelta >= 128)
1118                                 race_mycheckpointlapsdelta -= 256;
1119                         if(race_mycheckpointenemy)
1120                                 strunzone(race_mycheckpointenemy);
1121                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1122                         break;
1123
1124                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1125                         race_othercheckpoint = ReadByte();
1126                         race_othercheckpointtime = time;
1127                         race_othercheckpointdelta = ReadInt24_t();
1128                         race_othercheckpointlapsdelta = ReadByte();
1129                         if(race_othercheckpointlapsdelta >= 128)
1130                                 race_othercheckpointlapsdelta -= 256;
1131                         if(race_othercheckpointenemy)
1132                                 strunzone(race_othercheckpointenemy);
1133                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1134                         break;
1135
1136                 case RACE_NET_PENALTY_RACE:
1137                         race_penaltyeventtime = time;
1138                         race_penaltytime = ReadShort();
1139                         //race_penaltyaccumulator += race_penaltytime;
1140                         if(race_penaltyreason)
1141                                 strunzone(race_penaltyreason);
1142                         race_penaltyreason = strzone(ReadString());
1143                         break;
1144
1145                 case RACE_NET_PENALTY_QUALIFYING:
1146                         race_penaltyeventtime = time;
1147                         race_penaltytime = ReadShort();
1148                         race_penaltyaccumulator += race_penaltytime;
1149                         if(race_penaltyreason)
1150                                 strunzone(race_penaltyreason);
1151                         race_penaltyreason = strzone(ReadString());
1152                         break;
1153
1154                 case RACE_NET_SERVER_RECORD:
1155                         race_server_record = ReadInt24_t();
1156                         break;
1157                 case RACE_NET_SPEED_AWARD:
1158                         race_speedaward = ReadInt24_t();
1159                         if(race_speedaward_holder)
1160                                 strunzone(race_speedaward_holder);
1161                         race_speedaward_holder = strzone(ReadString());
1162                         break;
1163                 case RACE_NET_SPEED_AWARD_BEST:
1164                         race_speedaward_alltimebest = ReadInt24_t();
1165                         if(race_speedaward_alltimebest_holder)
1166                                 strunzone(race_speedaward_alltimebest_holder);
1167                         race_speedaward_alltimebest_holder = strzone(ReadString());
1168                         break;
1169                 case RACE_NET_SERVER_RANKINGS:
1170                         float prevpos, del;
1171             int pos = ReadShort();
1172                         prevpos = ReadShort();
1173                         del = ReadShort();
1174
1175                         // move other rankings out of the way
1176             int i;
1177                         if (prevpos) {
1178                                 for (i=prevpos-1;i>pos-1;--i) {
1179                                         grecordtime[i] = grecordtime[i-1];
1180                                         if(grecordholder[i])
1181                                                 strunzone(grecordholder[i]);
1182                                         grecordholder[i] = strzone(grecordholder[i-1]);
1183                                 }
1184                         } else if (del) { // a record has been deleted by the admin
1185                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1186                                         if (i == RANKINGS_CNT-1) { // clear out last record
1187                                                 grecordtime[i] = 0;
1188                                                 if (grecordholder[i])
1189                                                         strunzone(grecordholder[i]);
1190                                                 grecordholder[i] = string_null;
1191                                         }
1192                                         else {
1193                                                 grecordtime[i] = grecordtime[i+1];
1194                                                 if (grecordholder[i])
1195                                                         strunzone(grecordholder[i]);
1196                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1197                                         }
1198                                 }
1199                         } else { // player has no ranked record yet
1200                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1201                                         grecordtime[i] = grecordtime[i-1];
1202                                         if(grecordholder[i])
1203                                                 strunzone(grecordholder[i]);
1204                                         grecordholder[i] = strzone(grecordholder[i-1]);
1205                                 }
1206                         }
1207
1208                         // store new ranking
1209                         if(grecordholder[pos-1] != "")
1210                                 strunzone(grecordholder[pos-1]);
1211                         grecordholder[pos-1] = strzone(ReadString());
1212                         grecordtime[pos-1] = ReadInt24_t();
1213                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1214                                 race_myrank = pos;
1215                         break;
1216                 case RACE_NET_SERVER_STATUS:
1217                         race_status = ReadShort();
1218                         if(race_status_name)
1219                                 strunzone(race_status_name);
1220                         race_status_name = strzone(ReadString());
1221         }
1222 }
1223
1224 void Net_TeamNagger()
1225 {
1226         teamnagger = 1;
1227 }
1228
1229 void Net_ReadPingPLReport()
1230 {
1231         int e, pi, pl, ml;
1232         e = ReadByte();
1233         pi = ReadShort();
1234         pl = ReadByte();
1235         ml = ReadByte();
1236         if (!(playerslots[e]))
1237                 return;
1238         playerslots[e].ping = pi;
1239         playerslots[e].ping_packetloss = pl / 255.0;
1240         playerslots[e].ping_movementloss = ml / 255.0;
1241 }
1242
1243 void Net_WeaponComplain()
1244 {
1245         complain_weapon = ReadByte();
1246
1247         if(complain_weapon_name)
1248                 strunzone(complain_weapon_name);
1249         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1250
1251         complain_weapon_type = ReadByte();
1252
1253         complain_weapon_time = time;
1254         weapontime = time; // ping the weapon panel
1255
1256         switch(complain_weapon_type)
1257         {
1258                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1259                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1260                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1261         }
1262 }
1263
1264 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1265 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1266 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1267 float CSQC_Parse_TempEntity()
1268 {
1269         // Acquire TE ID
1270         int nTEID = ReadByte();
1271
1272         if (autocvar_developer_csqcentities)
1273                 printf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1274
1275         switch (nTEID)
1276         {
1277                 case TE_CSQC_MUTATOR:
1278                         int mutID = ReadMutator();
1279                         if (MUTATOR_CALLHOOK(CSQC_Parse_TempEntity, mutID))
1280                         return true;
1281                 case TE_CSQC_TARGET_MUSIC:
1282                         Net_TargetMusic();
1283                         return true;
1284                 case TE_CSQC_PICTURE:
1285                         Net_MapVote_Picture();
1286                         return true;
1287                 case TE_CSQC_RACE:
1288                         Net_ReadRace();
1289                         return true;
1290                 case TE_CSQC_VORTEXBEAMPARTICLE:
1291                         Net_ReadVortexBeamParticle();
1292                         return true;
1293                 case TE_CSQC_TEAMNAGGER:
1294                         Net_TeamNagger();
1295                         return true;
1296                 case TE_CSQC_ARC:
1297                         Net_ReadArc();
1298                         return true;
1299                 case TE_CSQC_PINGPLREPORT:
1300                         Net_ReadPingPLReport();
1301                         return true;
1302                 case TE_CSQC_WEAPONCOMPLAIN:
1303                         Net_WeaponComplain();
1304                         return true;
1305                 case TE_CSQC_VEHICLESETUP:
1306                         Net_VehicleSetup();
1307                         return true;
1308                 case TE_CSQC_SVNOTICE:
1309                         cl_notice_read();
1310                         return true;
1311                 case TE_CSQC_SHOCKWAVEPARTICLE:
1312                         Net_ReadShockwaveParticle();
1313                         return true;
1314                 default:
1315                         // No special logic for this temporary entity; return 0 so the engine can handle it
1316                         return false;
1317         }
1318 }
1319
1320 string getcommandkey(string text, string command)
1321 {
1322         string keys;
1323         float n, j, k, l = 0;
1324
1325         if (!autocvar_hud_showbinds)
1326                 return text;
1327
1328         keys = db_get(binddb, command);
1329         if (keys == "")
1330         {
1331                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1332                 for(j = 0; j < n; ++j)
1333                 {
1334                         k = stof(argv(j));
1335                         if(k != -1)
1336                         {
1337                                 if ("" == keys)
1338                                         keys = keynumtostring(k);
1339                                 else
1340                                         keys = strcat(keys, ", ", keynumtostring(k));
1341
1342                                 ++l;
1343                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1344                                         break;
1345                         }
1346
1347                 }
1348                 if (keys == "")
1349                         keys = "NO_KEY";
1350                 db_put(binddb, command, keys);
1351         }
1352
1353         if (keys == "NO_KEY") {
1354                 if (autocvar_hud_showbinds > 1)
1355                         return sprintf(_("%s (not bound)"), text);
1356                 else
1357                         return text;
1358         }
1359         else if (autocvar_hud_showbinds > 1)
1360                 return sprintf("%s (%s)", text, keys);
1361         else
1362                 return keys;
1363 }