qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include <common/effects/qc/all.qh>
   4 #include "hud/all.qh"
   5 #include "mapvoting.qh"
   6 #include "mutators/events.qh"
   7 #include "hud/panel/quickmenu.qh"
   8 #include "scoreboard.qh"
   9 #include "shownames.qh"
  10 #include <common/t_items.qh>
  11 #include "wall.qh"
  12 #include "weapons/projectile.qh"
  13 #include <common/deathtypes/all.qh>
  14 #include <common/items/all.qh>
  15 #include <common/mapinfo.qh>
  16 #include <common/minigames/cl_minigames.qh>
  17 #include <common/minigames/cl_minigames_hud.qh>
  18 #include <common/net_notice.qh>
  19 #include <common/triggers/include.qh>
  20 #include <common/vehicles/all.qh>
  21 #include <lib/csqcmodel/cl_model.qh>
  22 #include <lib/csqcmodel/interpolate.qh>
  23 #include <lib/warpzone/client.qh>
  24
  25 // --------------------------------------------------------------------------
  26 // BEGIN REQUIRED CSQC FUNCTIONS
  27 //include "main.qh"
  28
  29 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  30
  31 void draw_cursor(vector pos, vector ofs, string img, vector col, float a)
  32 {
  33         ofs = eX * (ofs.x * SIZE_CURSOR.x) + eY * (ofs.y * SIZE_CURSOR.y);
  34         drawpic(pos - ofs, strcat(draw_currentSkin, img), SIZE_CURSOR, col, a, DRAWFLAG_NORMAL);
  35 }
  36
  37 void draw_cursor_normal(vector pos, vector col, float a)
  38 {
  39         draw_cursor(pos, OFFSET_CURSOR, "/cursor", col, a);
  40 }
  41
  42 void LoadMenuSkinValues()
  43 {
  44         int fh = -1;
  45         if(cvar_string("menu_skin") != "")
  46         {
  47                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  48                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  49         }
  50         if(fh < 0 && cvar_defstring("menu_skin") != "")
  51         {
  52                 cvar_set("menu_skin", cvar_defstring("menu_skin"));
  53                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  54                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  55         }
  56         if(fh < 0)
  57         {
  58                 draw_currentSkin = "gfx/menu/default";
  59                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  60         }
  61
  62         draw_currentSkin = strzone(draw_currentSkin);
  63
  64         if(fh >= 0)
  65         {
  66                 string s;
  67                 while((s = fgets(fh)))
  68                 {
  69                         int n = tokenize_console(s);
  70                         if (n < 2)
  71                                 continue;
  72                         if(substring(argv(0), 0, 2) == "//")
  73                                 continue;
  74                         if(argv(0) == "SIZE_CURSOR")
  75                                 SIZE_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  76                         else if(argv(0) == "OFFSET_CURSOR")
  77                                 OFFSET_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  78                 }
  79                 fclose(fh);
  80         }
  81 }
  82
  83 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  84 // Useful for precaching things
  85
  86 void ConsoleCommand_macro_init();
  87 void CSQC_Init()
  88 {
  89         prvm_language = strzone(cvar_string("prvm_language"));
  90
  91 #ifdef WATERMARK
  92         LOG_INFOF("^4CSQC Build information: ^1%s\n", WATERMARK);
  93 #endif
  94
  95         {
  96                 int i = 0;
  97                 for ( ; i < 255; ++i)
  98                         if (getplayerkeyvalue(i, "viewentity") == "")
  99                                 break;
 100                 maxclients = i;
 101         }
 102
 103         // needs to be done so early because of the constants they create
 104         static_init();
 105         static_init_late();
 106         static_init_precache();
 107
 108         binddb = db_create();
 109         tempdb = db_create();
 110         ClientProgsDB = db_load("client.db");
 111         compressShortVector_init();
 112
 113         draw_endBoldFont();
 114
 115         //registercommand("hud_configure");
 116         //registercommand("hud_save");
 117         //registercommand("menu_action");
 118
 119         ConsoleCommand_macro_init();
 120
 121         registercvar("hud_usecsqc", "1");
 122         registercvar("scoreboard_columns", "default");
 123
 124         registercvar("cl_nade_type", "3");
 125         registercvar("cl_pokenade_type", "zombie");
 126
 127         registercvar("cl_jumpspeedcap_min", "");
 128         registercvar("cl_jumpspeedcap_max", "");
 129
 130         registercvar("cl_multijump", "1");
 131
 132         registercvar("cl_spawn_near_teammate", "1");
 133
 134         gametype = 0;
 135
 136         // hud_fields uses strunzone on the titles!
 137         for(int i = 0; i < MAX_HUD_FIELDS; ++i)
 138                 hud_title[i] = strzone("(null)");
 139
 140         Cmd_HUD_SetFields(0);
 141
 142         postinit = false;
 143
 144         calledhooks = 0;
 145
 146         teams = Sort_Spawn();
 147         players = Sort_Spawn();
 148
 149         GetTeam(NUM_SPECTATOR, true); // add specs first
 150
 151         // precaches
 152
 153         if(autocvar_cl_reticle)
 154         {
 155                 precache_pic("gfx/reticle_normal");
 156                 // weapon reticles are precached in weapon files
 157         }
 158
 159         {
 160                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 161                 minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 162                 shortmapname = mi_shortname;
 163
 164                 if (precache_pic(minimapname) == "")
 165                 {
 166                         // but maybe we have a non-clever minimap
 167                         minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 168                         if (precache_pic(minimapname) == "")
 169                                 minimapname = ""; // FAIL
 170                         else
 171                                 get_mi_min_max_texcoords(0); // load new texcoords
 172                 }
 173
 174                 mi_center = (mi_min + mi_max) * 0.5;
 175                 mi_scale = mi_max - mi_min;
 176                 minimapname = strzone(minimapname);
 177         }
 178
 179         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 180         LoadMenuSkinValues();
 181 }
 182
 183 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 184 void Shutdown()
 185 {
 186         WarpZone_Shutdown();
 187
 188         remove(teams);
 189         remove(players);
 190         db_close(binddb);
 191         db_close(tempdb);
 192         if(autocvar_cl_db_saveasdump)
 193                 db_dump(ClientProgsDB, "client.db");
 194         else
 195                 db_save(ClientProgsDB, "client.db");
 196         db_close(ClientProgsDB);
 197
 198         if(camera_active)
 199                 cvar_set("chase_active",ftos(chase_active_backup));
 200
 201         // unset the event chasecam's chase_active
 202         if(autocvar_chase_active < 0)
 203                 cvar_set("chase_active", "0");
 204
 205         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 206
 207         if (!isdemo())
 208         {
 209                 if (!(calledhooks & HOOK_START))
 210                         localcmd("\n_cl_hook_gamestart nop\n");
 211                 if (!(calledhooks & HOOK_END))
 212                         localcmd("\ncl_hook_gameend\n");
 213         }
 214
 215         deactivate_minigame();
 216         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 217 }
 218
 219 .float has_team;
 220 float SetTeam(entity o, int Team)
 221 {
 222     TC(int, Team);
 223         devassert_once(Team);
 224         entity tm;
 225         if(teamplay)
 226         {
 227                 switch(Team)
 228                 {
 229                         case -1:
 230                         case NUM_TEAM_1:
 231                         case NUM_TEAM_2:
 232                         case NUM_TEAM_3:
 233                         case NUM_TEAM_4:
 234                                 break;
 235                         default:
 236                                 if(GetTeam(Team, false) == NULL)
 237                                 {
 238                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 239                                         Team = NUM_SPECTATOR;
 240                                 }
 241                                 break;
 242                 }
 243         }
 244         else
 245         {
 246                 switch(Team)
 247                 {
 248                         case -1:
 249                         case 0:
 250                                 break;
 251                         default:
 252                                 if(GetTeam(Team, false) == NULL)
 253                                 {
 254                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 255                                         Team = NUM_SPECTATOR;
 256                                 }
 257                                 break;
 258                 }
 259         }
 260         if(Team == -1) // leave
 261         {
 262                 if(o.has_team)
 263                 {
 264                         tm = GetTeam(o.team, false);
 265                         tm.team_size -= 1;
 266                         o.has_team = 0;
 267                         return true;
 268                 }
 269         }
 270         else
 271         {
 272                 if (!o.has_team)
 273                 {
 274                         o.team = Team;
 275                         tm = GetTeam(Team, true);
 276                         tm.team_size += 1;
 277                         o.has_team = 1;
 278                         return true;
 279                 }
 280                 else if(Team != o.team)
 281                 {
 282                         tm = GetTeam(o.team, false);
 283                         tm.team_size -= 1;
 284                         o.team = Team;
 285                         tm = GetTeam(Team, true);
 286                         tm.team_size += 1;
 287                         return true;
 288                 }
 289         }
 290         return false;
 291 }
 292
 293 void Playerchecker_Think(entity this)
 294 {
 295     int i;
 296         entity e;
 297         for(i = 0; i < maxclients; ++i)
 298         {
 299                 e = playerslots[i];
 300                 if(entcs_GetName(i) == "")
 301                 {
 302                         if(e.sort_prev)
 303                         {
 304                                 // player disconnected
 305                                 SetTeam(e, -1);
 306                                 RemovePlayer(e);
 307                                 e.sort_prev = NULL;
 308                                 //e.gotscores = 0;
 309                         }
 310                 }
 311                 else
 312                 {
 313                         if (!e.sort_prev)
 314                         {
 315                                 // player connected
 316                                 if (!e)
 317                                 {
 318                                         playerslots[i] = e = new_pure(playerslot);
 319                                 }
 320                                 e.sv_entnum = i;
 321                                 e.ping = 0;
 322                                 e.ping_packetloss = 0;
 323                                 e.ping_movementloss = 0;
 324                                 //e.gotscores = 0; // we might already have the scores...
 325                                 int t = entcs_GetScoreTeam(i);
 326                                 if (t) SetTeam(e, t); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 327                                 RegisterPlayer(e);
 328                                 HUD_UpdatePlayerPos(e);
 329                         }
 330                 }
 331         }
 332         this.nextthink = time + 0.2;
 333 }
 334
 335 void TrueAim_Init();
 336 void PostInit()
 337 {
 338         entity playerchecker = new_pure(playerchecker);
 339         setthink(playerchecker, Playerchecker_Think);
 340         playerchecker.nextthink = time + 0.2;
 341
 342         TrueAim_Init();
 343
 344         postinit = true;
 345 }
 346
 347 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 348 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 349 // All keys are in ascii.
 350 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 351 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 352 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 353 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 354 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 355 {
 356     TC(int, bInputType);
 357         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 358                 return true;
 359
 360         if (QuickMenu_InputEvent(bInputType, nPrimary, nSecondary))
 361                 return true;
 362
 363         if (HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary))
 364                 return true;
 365
 366         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 367                 return true;
 368
 369         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
 370                 return true;
 371
 372         return false;
 373 }
 374
 375 // END REQUIRED CSQC FUNCTIONS
 376 // --------------------------------------------------------------------------
 377
 378 // --------------------------------------------------------------------------
 379 // BEGIN OPTIONAL CSQC FUNCTIONS
 380
 381 void Ent_Remove(entity this);
 382
 383 void Ent_RemovePlayerScore(entity this)
 384 {
 385         if(this.owner) {
 386                 SetTeam(this.owner, -1);
 387                 this.owner.gotscores = 0;
 388                 for(int i = 0; i < MAX_SCORE; ++i) {
 389                         this.owner.(scores[i]) = 0; // clear all scores
 390                 }
 391         }
 392 }
 393
 394 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 395 {
 396         make_pure(this);
 397         int i, n;
 398         bool isNew;
 399         entity o;
 400
 401         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 402         // (no I've never heard of M-x replace-string, sed, or anything like that)
 403         isNew = !this.owner; // workaround for DP bug
 404         n = ReadByte()-1;
 405
 406 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 407         if(!isNew && n != this.sv_entnum)
 408         {
 409                 //print("A CSQC entity changed its owner!\n");
 410                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", etof(this), this.classname);
 411                 isNew = true;
 412                 Ent_Remove(this);
 413         }
 414 #endif
 415
 416         this.sv_entnum = n;
 417
 418         o = playerslots[this.sv_entnum];
 419         if (!o)
 420         {
 421                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 422         }
 423         this.owner = o;
 424         o.sv_entnum = this.sv_entnum;
 425         o.gotscores = 1;
 426
 427         //if (!o.sort_prev)
 428         //      RegisterPlayer(o);
 429         //playerchecker will do this for us later, if it has not already done so
 430
 431     int sf, lf;
 432 #if MAX_SCORE <= 8
 433         sf = ReadByte();
 434         lf = ReadByte();
 435 #else
 436         sf = ReadShort();
 437         lf = ReadShort();
 438 #endif
 439     int p;
 440         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 441                 if(sf & p)
 442                 {
 443                         if(lf & p)
 444                                 o.(scores[i]) = ReadInt24_t();
 445                         else
 446                                 o.(scores[i]) = ReadChar();
 447                 }
 448
 449         return = true;
 450
 451         if(o.sort_prev)
 452                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 453
 454         this.entremove = Ent_RemovePlayerScore;
 455 }
 456
 457 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 458 {
 459         make_pure(this);
 460         int i;
 461         entity o;
 462
 463         this.team = ReadByte();
 464         o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 465
 466     int sf, lf;
 467 #if MAX_TEAMSCORE <= 8
 468         sf = ReadByte();
 469         lf = ReadByte();
 470 #else
 471         sf = ReadShort();
 472         lf = ReadShort();
 473 #endif
 474         int p;
 475         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 476                 if(sf & p)
 477                 {
 478                         if(lf & p)
 479                                 o.(teamscores[i]) = ReadInt24_t();
 480                         else
 481                                 o.(teamscores[i]) = ReadChar();
 482                 }
 483
 484         return = true;
 485
 486         HUD_UpdateTeamPos(o);
 487 }
 488
 489 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 490 {
 491         make_pure(this);
 492         float newspectatee_status;
 493
 494     int f = ReadByte();
 495
 496         scoreboard_showscores_force = (f & 1);
 497
 498         if(f & 2)
 499         {
 500                 newspectatee_status = ReadByte();
 501                 if(newspectatee_status == player_localnum + 1)
 502                         newspectatee_status = -1; // observing
 503         }
 504         else
 505                 newspectatee_status = 0;
 506
 507         spectatorbutton_zoom = (f & 4);
 508
 509         if(f & 8)
 510         {
 511                 angles_held_status = 1;
 512                 angles_held.x = ReadAngle();
 513                 angles_held.y = ReadAngle();
 514                 angles_held.z = 0;
 515         }
 516         else
 517                 angles_held_status = 0;
 518
 519         return = true;
 520
 521         if(newspectatee_status != spectatee_status)
 522         {
 523                 // clear race stuff
 524                 race_laptime = 0;
 525                 race_checkpointtime = 0;
 526                 hud_dynamic_shake_factor = -1;
 527         }
 528         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 529         {
 530                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 531                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 532                 )
 533                         prev_p_health = -1;
 534                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 535                         prev_health = -1;
 536         }
 537         spectatee_status = newspectatee_status;
 538
 539         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 540 }
 541
 542 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 543 {
 544         make_pure(this);
 545     int i, j, b, f;
 546
 547     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 548
 549         if(!(nags & BIT(2)))
 550         {
 551                 if(vote_called_vote)
 552                         strunzone(vote_called_vote);
 553                 vote_called_vote = string_null;
 554                 vote_active = 0;
 555         }
 556         else
 557         {
 558                 vote_active = 1;
 559         }
 560
 561         if(nags & BIT(6))
 562         {
 563                 vote_yescount = ReadByte();
 564                 vote_nocount = ReadByte();
 565                 vote_needed = ReadByte();
 566                 vote_highlighted = ReadChar();
 567         }
 568
 569         if(nags & BIT(7))
 570         {
 571                 if(vote_called_vote)
 572                         strunzone(vote_called_vote);
 573                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 574         }
 575
 576         if(nags & 1)
 577         {
 578                 for(j = 0; j < maxclients; ++j)
 579                         if(playerslots[j])
 580                                 playerslots[j].ready = 1;
 581                 for(i = 1; i <= maxclients; i += 8)
 582                 {
 583                         f = ReadByte();
 584                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 585                                 if (!(f & b))
 586                                         if(playerslots[j])
 587                                                 playerslots[j].ready = 0;
 588                 }
 589         }
 590
 591         return = true;
 592
 593         ready_waiting = (nags & BIT(0));
 594         ready_waiting_for_me = (nags & BIT(1));
 595         vote_waiting = (nags & BIT(2));
 596         vote_waiting_for_me = (nags & BIT(3));
 597         warmup_stage = (nags & BIT(4));
 598 }
 599
 600 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 601 {
 602         make_pure(this);
 603     int i, j, b, f;
 604
 605     int sf = ReadByte();
 606         if(sf & 1)
 607         {
 608                 for(j = 0; j < maxclients; ++j)
 609                         if(playerslots[j])
 610                                 playerslots[j].eliminated = 1;
 611                 for(i = 1; i <= maxclients; i += 8)
 612                 {
 613                         f = ReadByte();
 614                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 615                                 if (!(f & b))
 616                                         if(playerslots[j])
 617                                                 playerslots[j].eliminated = 0;
 618                 }
 619         }
 620         return true;
 621 }
 622
 623 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 624 {
 625         make_pure(this);
 626         prandom_debug();
 627         float s = ReadShort();
 628         psrandom(s);
 629         return true;
 630 }
 631
 632 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 633 {
 634         make_pure(this);
 635     int sf = ReadInt24_t();
 636         if (sf == 0) {
 637                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 638                         weapon_accuracy[w] = -1;
 639                 return true;
 640         }
 641
 642         int f = 1;
 643         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 644                 if (sf & f) {
 645             int b = ReadByte();
 646                         if (b == 0)
 647                                 weapon_accuracy[w] = -1;
 648                         else if (b == 255)
 649                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 650                         else
 651                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 652                 }
 653                 f = (f == 0x800000) ? 1 : f * 2;
 654         }
 655         return true;
 656 }
 657
 658 void Spawn_Draw(entity this)
 659 {
 660         __pointparticles(this.cnt, this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 661 }
 662
 663 void Spawn_PreDraw(entity this)
 664 {
 665         float alph;
 666         vector org = getpropertyvec(VF_ORIGIN);
 667         if(this.fade_start)
 668                 alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 669         else
 670                 alph = 1;
 671         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 672         this.alpha = alph;
 673         if(alph <= 0)
 674                 this.drawmask = 0;
 675         else
 676                 this.drawmask = MASK_NORMAL;
 677 }
 678
 679 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 680 {
 681         float teamnum = (ReadByte() - 1);
 682         vector spn_origin;
 683         spn_origin.x = ReadCoord();
 684         spn_origin.y = ReadCoord();
 685         spn_origin.z = ReadCoord();
 686
 687         this.team = (teamnum + 1);
 688
 689         //if(is_new)
 690         //{
 691                 this.origin = spn_origin;
 692                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 693                 //droptofloor();
 694
 695                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 696                 {
 697                         this.mdl = "models/spawnpoint.md3";
 698                         this.colormod = Team_ColorRGB(teamnum);
 699                         precache_model(this.mdl);
 700                         setmodel(this, this.mdl);
 701                         this.drawmask = MASK_NORMAL;
 702                         //this.movetype = MOVETYPE_NOCLIP;
 703                         //this.draw = Spawn_Draw;
 704                 }*/
 705                 if(autocvar_cl_spawn_point_particles)
 706                 {
 707                         if((serverflags & SERVERFLAG_TEAMPLAY))
 708                         {
 709                                 switch(teamnum)
 710                                 {
 711                                         case NUM_TEAM_1: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
 712                                         case NUM_TEAM_2: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
 713                                         case NUM_TEAM_3: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
 714                                         case NUM_TEAM_4: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
 715                                         default: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
 716                                 }
 717                         }
 718                         else { this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
 719
 720                         this.draw = Spawn_Draw;
 721                         setpredraw(this, Spawn_PreDraw);
 722                         this.fade_start = autocvar_cl_spawn_point_dist_min;
 723                         this.fade_end = autocvar_cl_spawn_point_dist_max;
 724                 }
 725         //}
 726
 727         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 728         return true;
 729 }
 730
 731 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 732 {
 733         // If entnum is 0, ONLY do the local spawn actions
 734         // this way the server can disable the sending of
 735         // spawn origin or such to clients if wanted.
 736         float entnum = ReadByte();
 737
 738         if(entnum)
 739         {
 740                 this.origin_x = ReadCoord();
 741                 this.origin_y = ReadCoord();
 742                 this.origin_z = ReadCoord();
 743
 744                 if(is_new)
 745                 {
 746                         float teamnum = entcs_GetTeam(entnum - 1);
 747
 748                         if(autocvar_cl_spawn_event_particles)
 749                         {
 750                                 switch(teamnum)
 751                                 {
 752                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 753                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 754                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 755                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 756                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 757                                 }
 758                         }
 759                         if(autocvar_cl_spawn_event_sound)
 760                         {
 761                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 762                         }
 763                 }
 764         }
 765         return = true;
 766
 767         // local spawn actions
 768         if(is_new && (!entnum || (entnum == player_localentnum)))
 769         {
 770                 zoomin_effect = 1;
 771                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 772
 773                 if(autocvar_cl_unpress_zoom_on_spawn)
 774                 {
 775                         localcmd("-zoom\n");
 776                         button_zoom = false;
 777                 }
 778         }
 779         HUD_Radar_Hide_Maximized();
 780         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 781 }
 782
 783 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 784 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 785 void CSQC_Ent_Update(entity this, bool isnew)
 786 {
 787         this.sourceLoc = __FILE__ ":" STR(__LINE__);
 788         int t = ReadByte();
 789
 790         // set up the "time" global for received entities to be correct for interpolation purposes
 791         float savetime = time;
 792         if(servertime)
 793         {
 794                 time = servertime;
 795         }
 796         else
 797         {
 798                 serverprevtime = time;
 799                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 800                 time = serverprevtime + serverdeltatime;
 801         }
 802
 803 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 804         if (this.enttype)
 805         {
 806                 if (t != this.enttype || isnew)
 807                 {
 808                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", etof(this), this.entnum, this.enttype, t);
 809                         Ent_Remove(this);
 810                         clearentity(this);
 811                         isnew = true;
 812                 }
 813         }
 814         else
 815         {
 816                 if (!isnew)
 817                 {
 818                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", etof(this), this.entnum, t);
 819                         isnew = true;
 820                 }
 821         }
 822 #endif
 823         this.enttype = t;
 824         bool done = false;
 825         FOREACH(LinkedEntities, it.m_id == t, {
 826                 if (isnew) this.classname = it.netname;
 827                 if (autocvar_developer_csqcentities)
 828             LOG_INFOF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)\n", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 829                 done = it.m_read(this, NULL, isnew);
 830                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 831                 break;
 832         });
 833         time = savetime;
 834         if (!done)
 835         {
 836                 LOG_FATALF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)\n", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 837         }
 838 }
 839
 840 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 841 // used when an entity changes its type. For an entity that someone interacts
 842 // with others, make sure it can no longer do so.
 843 void Ent_Remove(entity this)
 844 {
 845         if(this.entremove) this.entremove(this);
 846
 847         if(this.skeletonindex)
 848         {
 849                 skel_delete(this.skeletonindex);
 850                 this.skeletonindex = 0;
 851         }
 852
 853         if(this.snd_looping > 0)
 854         {
 855                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_g_jetpack_attenuation);
 856                 this.snd_looping = 0;
 857         }
 858
 859         this.enttype = 0;
 860         this.classname = "";
 861         this.draw = func_null;
 862         this.entremove = func_null;
 863         // TODO possibly set more stuff to defaults
 864 }
 865 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 866 void CSQC_Ent_Remove(entity this)
 867 {
 868         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}\n", this, this.entnum, this.enttype);
 869         if (wasfreed(this))
 870         {
 871                 LOG_WARNING("CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 872                 return;
 873         }
 874         if (this.enttype) Ent_Remove(this);
 875         remove(this);
 876 }
 877
 878 void Gamemode_Init()
 879 {
 880         if (!isdemo())
 881         {
 882                 if(!(calledhooks & HOOK_START))
 883                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 884                 calledhooks |= HOOK_START;
 885         }
 886 }
 887 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 888 void CSQC_Parse_StuffCmd(string strMessage)
 889 {
 890         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 891         localcmd(strMessage);
 892 }
 893 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 894 void CSQC_Parse_Print(string strMessage)
 895 {
 896         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")\n", strMessage);
 897         print(ColorTranslateRGB(strMessage));
 898 }
 899
 900 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 901 void CSQC_Parse_CenterPrint(string strMessage)
 902 {
 903         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 904         centerprint_hud(strMessage);
 905 }
 906
 907 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
 908 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
 909 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
 910 bool CSQC_Parse_TempEntity()
 911 {
 912         // Acquire TE ID
 913         int nTEID = ReadByte();
 914
 915         FOREACH(TempEntities, it.m_id == nTEID, {
 916                 if (autocvar_developer_csqcentities)
 917                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)\n", it.netname, nTEID);
 918                 return it.m_read(NULL, NULL, true);
 919         });
 920
 921         if (autocvar_developer_csqcentities)
 922                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
 923
 924         // No special logic for this temporary entity; return 0 so the engine can handle it
 925         return false;
 926 }
 927
 928 string forcefog;
 929 void Fog_Force()
 930 {
 931         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 932                 localcmd("\nr_drawfog 0\n");
 933         else if (forcefog != "")
 934                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
 935 }
 936
 937 void Gamemode_Init();
 938 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
 939 {
 940         make_pure(this);
 941         gametype = ReadInt24_t();
 942         HUD_ModIcons_SetFunc();
 943         for (int i = 0; i < MAX_SCORE; ++i)
 944         {
 945                 if (scores_label[i]) strunzone(scores_label[i]);
 946                 scores_label[i] = strzone(ReadString());
 947                 scores_flags[i] = ReadByte();
 948         }
 949         for (int i = 0; i < MAX_TEAMSCORE; ++i)
 950         {
 951                 if (teamscores_label[i]) strunzone(teamscores_label[i]);
 952                 teamscores_label[i] = strzone(ReadString());
 953                 teamscores_flags[i] = ReadByte();
 954         }
 955         return = true;
 956         HUD_InitScores();
 957         Gamemode_Init();
 958 }
 959
 960 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
 961 {
 962         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 963
 964         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 965         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 966         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 967         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 968         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 969         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 970         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 971         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 972
 973         if (forcefog) strunzone(forcefog);
 974         forcefog = strzone(ReadString());
 975
 976         armorblockpercent = ReadByte() / 255.0;
 977
 978         serverflags = ReadByte();
 979
 980         g_trueaim_minrange = ReadCoord();
 981
 982         return = true;
 983
 984         MUTATOR_CALLHOOK(Ent_Init);
 985
 986         if (!postinit) PostInit();
 987 }
 988
 989 float GetSpeedUnitFactor(int speed_unit)
 990 {
 991         switch(speed_unit)
 992         {
 993                 default:
 994                 case 1:
 995                         return 1.0;
 996                 case 2:
 997                         return 0.0254;
 998                 case 3:
 999                         return 0.0254 * 3.6;
1000                 case 4:
1001                         return 0.0254 * 3.6 * 0.6213711922;
1002                 case 5:
1003                         return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1004         }
1005 }
1006
1007 string GetSpeedUnit(int speed_unit)
1008 {
1009         switch(speed_unit)
1010         {
1011                 default:
1012                 case 1:
1013                         return _(" qu/s");
1014                 case 2:
1015                         return _(" m/s");
1016                 case 3:
1017                         return _(" km/h");
1018                 case 4:
1019                         return _(" mph");
1020                 case 5:
1021                         return _(" knots");
1022         }
1023 }
1024
1025 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1026 {
1027         int b = ReadByte();
1028
1029         switch (b)
1030         {
1031                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1032                         race_checkpoint = ReadByte();
1033                         race_time = ReadInt24_t();
1034                         race_previousbesttime = ReadInt24_t();
1035                         if(race_previousbestname)
1036                                 strunzone(race_previousbestname);
1037                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1038
1039                         race_checkpointtime = time;
1040
1041                         if(race_checkpoint == 0 || race_checkpoint == 254)
1042                         {
1043                                 race_penaltyaccumulator = 0;
1044                                 race_laptime = time; // valid
1045                         }
1046
1047                         break;
1048
1049                 case RACE_NET_CHECKPOINT_CLEAR:
1050                         race_laptime = 0;
1051                         race_checkpointtime = 0;
1052                         break;
1053
1054                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1055                         race_laptime = ReadCoord();
1056                         race_checkpointtime = -99999;
1057                         // fall through
1058                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1059                         race_nextcheckpoint = ReadByte();
1060
1061                         race_nextbesttime = ReadInt24_t();
1062                         if(race_nextbestname)
1063                                 strunzone(race_nextbestname);
1064                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1065                         break;
1066
1067                 case RACE_NET_CHECKPOINT_HIT_RACE:
1068                         race_mycheckpoint = ReadByte();
1069                         race_mycheckpointtime = time;
1070                         race_mycheckpointdelta = ReadInt24_t();
1071                         race_mycheckpointlapsdelta = ReadByte();
1072                         if(race_mycheckpointlapsdelta >= 128)
1073                                 race_mycheckpointlapsdelta -= 256;
1074                         if(race_mycheckpointenemy)
1075                                 strunzone(race_mycheckpointenemy);
1076                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1077                         break;
1078
1079                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1080                         race_othercheckpoint = ReadByte();
1081                         race_othercheckpointtime = time;
1082                         race_othercheckpointdelta = ReadInt24_t();
1083                         race_othercheckpointlapsdelta = ReadByte();
1084                         if(race_othercheckpointlapsdelta >= 128)
1085                                 race_othercheckpointlapsdelta -= 256;
1086                         if(race_othercheckpointenemy)
1087                                 strunzone(race_othercheckpointenemy);
1088                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1089                         break;
1090
1091                 case RACE_NET_PENALTY_RACE:
1092                         race_penaltyeventtime = time;
1093                         race_penaltytime = ReadShort();
1094                         //race_penaltyaccumulator += race_penaltytime;
1095                         if(race_penaltyreason)
1096                                 strunzone(race_penaltyreason);
1097                         race_penaltyreason = strzone(ReadString());
1098                         break;
1099
1100                 case RACE_NET_PENALTY_QUALIFYING:
1101                         race_penaltyeventtime = time;
1102                         race_penaltytime = ReadShort();
1103                         race_penaltyaccumulator += race_penaltytime;
1104                         if(race_penaltyreason)
1105                                 strunzone(race_penaltyreason);
1106                         race_penaltyreason = strzone(ReadString());
1107                         break;
1108
1109                 case RACE_NET_SERVER_RECORD:
1110                         race_server_record = ReadInt24_t();
1111                         break;
1112                 case RACE_NET_SPEED_AWARD:
1113                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1114                         if(race_speedaward_holder)
1115                                 strunzone(race_speedaward_holder);
1116                         race_speedaward_holder = strzone(ReadString());
1117                         if(race_speedaward_unit)
1118                                 strunzone(race_speedaward_unit);
1119                         race_speedaward_unit = strzone(GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1120                         break;
1121                 case RACE_NET_SPEED_AWARD_BEST:
1122                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1123                         if(race_speedaward_alltimebest_holder)
1124                                 strunzone(race_speedaward_alltimebest_holder);
1125                         race_speedaward_alltimebest_holder = strzone(ReadString());
1126                         if(race_speedaward_alltimebest_unit)
1127                                 strunzone(race_speedaward_alltimebest_unit);
1128                         race_speedaward_alltimebest_unit = strzone(GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1129                         break;
1130                 case RACE_NET_SERVER_RANKINGS:
1131                         float prevpos, del;
1132             int pos = ReadShort();
1133                         prevpos = ReadShort();
1134                         del = ReadShort();
1135
1136                         // move other rankings out of the way
1137             int i;
1138                         if (prevpos) {
1139                                 for (i=prevpos-1;i>pos-1;--i) {
1140                                         grecordtime[i] = grecordtime[i-1];
1141                                         if(grecordholder[i])
1142                                                 strunzone(grecordholder[i]);
1143                                         grecordholder[i] = strzone(grecordholder[i-1]);
1144                                 }
1145                         } else if (del) { // a record has been deleted by the admin
1146                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1147                                         if (i == RANKINGS_CNT-1) { // clear out last record
1148                                                 grecordtime[i] = 0;
1149                                                 if (grecordholder[i])
1150                                                         strunzone(grecordholder[i]);
1151                                                 grecordholder[i] = string_null;
1152                                         }
1153                                         else {
1154                                                 grecordtime[i] = grecordtime[i+1];
1155                                                 if (grecordholder[i])
1156                                                         strunzone(grecordholder[i]);
1157                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1158                                         }
1159                                 }
1160                         } else { // player has no ranked record yet
1161                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1162                                         grecordtime[i] = grecordtime[i-1];
1163                                         if(grecordholder[i])
1164                                                 strunzone(grecordholder[i]);
1165                                         grecordholder[i] = strzone(grecordholder[i-1]);
1166                                 }
1167                         }
1168
1169                         // store new ranking
1170                         if(grecordholder[pos-1] != "")
1171                                 strunzone(grecordholder[pos-1]);
1172                         grecordholder[pos-1] = strzone(ReadString());
1173                         grecordtime[pos-1] = ReadInt24_t();
1174                         if(grecordholder[pos-1] == entcs_GetName(player_localnum))
1175                                 race_myrank = pos;
1176                         break;
1177                 case RACE_NET_SERVER_STATUS:
1178                         race_status = ReadShort();
1179                         if(race_status_name)
1180                                 strunzone(race_status_name);
1181                         race_status_name = strzone(ReadString());
1182         }
1183         return true;
1184 }
1185
1186 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1187 {
1188         teamnagger = 1;
1189         return true;
1190 }
1191
1192 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1193 {
1194         int i = ReadByte();
1195         int pi = ReadShort();
1196         int pl = ReadByte();
1197         int ml = ReadByte();
1198         return = true;
1199         entity e = playerslots[i];
1200         if (!e) return;
1201         e.ping = pi;
1202         e.ping_packetloss = pl / 255.0;
1203         e.ping_movementloss = ml / 255.0;
1204 }
1205
1206 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1207 {
1208         complain_weapon = ReadByte();
1209         complain_weapon_type = ReadByte();
1210         return = true;
1211
1212         complain_weapon_time = time;
1213         weapontime = time; // ping the weapon panel
1214
1215         switch(complain_weapon_type)
1216         {
1217                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1218                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1219                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1220         }
1221 }
1222
1223 string getcommandkey(string text, string command)
1224 {
1225         string keys;
1226         float n, j, k, l = 0;
1227
1228         if (!autocvar_hud_showbinds)
1229                 return text;
1230
1231         keys = db_get(binddb, command);
1232         if (keys == "")
1233         {
1234                 bool joy_detected = cvar("joy_detected");
1235                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1236                 for(j = 0; j < n; ++j)
1237                 {
1238                         k = stof(argv(j));
1239                         if(k != -1)
1240                         {
1241                                 string key = keynumtostring(k);
1242                                 if(!joy_detected && substring(key, 0, 3) == "JOY")
1243                                         continue;
1244
1245                                 if (keys == "")
1246                                         keys = key;
1247                                 else
1248                                         keys = strcat(keys, ", ", key);
1249
1250                                 ++l;
1251                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1252                                         break;
1253                         }
1254
1255                 }
1256                 if (keys == "")
1257                         keys = "NO_KEY";
1258                 db_put(binddb, command, keys);
1259         }
1260
1261         if (keys == "NO_KEY") {
1262                 if (autocvar_hud_showbinds > 1)
1263                         return sprintf(_("%s (not bound)"), text);
1264                 else
1265                         return text;
1266         }
1267         else if (autocvar_hud_showbinds > 1)
1268                 return sprintf("%s (%s)", text, keys);
1269         else
1270                 return keys;
1271 }