qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include "defs.qh"
   4 #include <common/ent_cs.qh>
   5 #include "miscfunctions.qh"
   6 #include <common/effects/effect.qh>
   7 #include <common/effects/qc/_mod.qh>
   8 #include <common/effects/all.qh>
   9 #include <common/effects/all.inc>
  10 #include "hud/_mod.qh"
  11 #include "commands/cl_cmd.qh"
  12 #include "mapvoting.qh"
  13 #include <client/mutators/_mod.qh>
  14 #include "hud/panel/scoreboard.qh"
  15 #include "hud/panel/quickmenu.qh"
  16 #include "shownames.qh"
  17 #include "view.qh"
  18 #include <common/t_items.qh>
  19 #include "weapons/projectile.qh"
  20 #include <common/deathtypes/all.qh>
  21 #include <common/items/_mod.qh>
  22 #include <common/mapinfo.qh>
  23 #include <common/minigames/cl_minigames.qh>
  24 #include <common/minigames/cl_minigames_hud.qh>
  25 #include <common/net_linked.qh>
  26 #include <common/net_notice.qh>
  27 #include <common/scores.qh>
  28 #include <common/mapobjects/_mod.qh>
  29 #include <common/vehicles/all.qh>
  30 #include <lib/csqcmodel/cl_model.qh>
  31 #include <lib/csqcmodel/interpolate.qh>
  32 #include <lib/warpzone/client.qh>
  33
  34 // --------------------------------------------------------------------------
  35 // BEGIN REQUIRED CSQC FUNCTIONS
  36 //include "main.qh"
  37
  38 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  39
  40 void draw_cursor(vector pos, vector ofs, string img, vector col, float a)
  41 {
  42         ofs = vec2(ofs.x * SIZE_CURSOR.x, ofs.y * SIZE_CURSOR.y);
  43         drawpic(pos - ofs, strcat(draw_currentSkin, img), SIZE_CURSOR, col, a, DRAWFLAG_NORMAL);
  44 }
  45
  46 void draw_cursor_normal(vector pos, vector col, float a)
  47 {
  48         draw_cursor(pos, OFFSET_CURSOR, "/cursor", col, a);
  49 }
  50
  51 void LoadMenuSkinValues()
  52 {
  53         int fh = -1;
  54         if(cvar_string("menu_skin") != "")
  55         {
  56                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  57                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  58         }
  59         if(fh < 0 && cvar_defstring("menu_skin") != "")
  60         {
  61                 cvar_set("menu_skin", cvar_defstring("menu_skin"));
  62                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  63                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  64         }
  65         if(fh < 0)
  66         {
  67                 draw_currentSkin = "gfx/menu/default";
  68                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  69         }
  70
  71         draw_currentSkin = strzone(draw_currentSkin);
  72
  73         if(fh >= 0)
  74         {
  75                 string s;
  76                 while((s = fgets(fh)))
  77                 {
  78                         int n = tokenize_console(s);
  79                         if (n < 2)
  80                                 continue;
  81                         if(substring(argv(0), 0, 2) == "//")
  82                                 continue;
  83                         if(argv(0) == "SIZE_CURSOR")
  84                                 SIZE_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  85                         else if(argv(0) == "OFFSET_CURSOR")
  86                                 OFFSET_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  87                 }
  88                 fclose(fh);
  89         }
  90 }
  91
  92 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  93 // Useful for precaching things
  94
  95 void CSQC_Init()
  96 {
  97         prvm_language = strzone(cvar_string("prvm_language"));
  98
  99 #ifdef WATERMARK
 100         LOG_INFOF("^4CSQC Build information: ^1%s", WATERMARK);
 101 #endif
 102
 103         {
 104                 int i = 0;
 105                 for ( ; i < 255; ++i)
 106                         if (getplayerkeyvalue(i, "viewentity") == "")
 107                                 break;
 108                 maxclients = i;
 109         }
 110
 111         // needs to be done so early because of the constants they create
 112         static_init();
 113         static_init_late();
 114         static_init_precache();
 115
 116         binddb = db_create();
 117         tempdb = db_create();
 118         ClientProgsDB = db_load("client.db");
 119
 120         draw_endBoldFont();
 121
 122         //registercommand("hud_configure");
 123         //registercommand("hud_save");
 124         //registercommand("menu_action");
 125
 126         ConsoleCommand_macro_init();
 127
 128         registercvar("hud_usecsqc", "1");
 129         registercvar("scoreboard_columns", "default");
 130
 131         registercvar("cl_nade_type", "3");
 132         registercvar("cl_pokenade_type", "zombie");
 133
 134         registercvar("cl_jumpspeedcap_min", "");
 135         registercvar("cl_jumpspeedcap_max", "");
 136
 137         registercvar("cl_shootfromfixedorigin", "");
 138
 139         registercvar("cl_multijump", "1");
 140
 141         registercvar("cl_spawn_near_teammate", "1");
 142
 143         registercvar("cl_weapon_switch_reload", "1");
 144         registercvar("cl_weapon_switch_fallback_to_impulse", "1");
 145
 146         if(autocvar_cl_lockview)
 147                 cvar_set("cl_lockview", "0");
 148
 149         gametype = NULL;
 150
 151         postinit = false;
 152
 153         calledhooks = 0;
 154
 155         teams = Sort_Spawn();
 156         players = Sort_Spawn();
 157
 158         GetTeam(NUM_SPECTATOR, true); // add specs first
 159
 160         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 161                 weapon_accuracy[w] = -1;
 162
 163         // precaches
 164
 165         if(autocvar_cl_reticle)
 166         {
 167                 precache_pic("gfx/reticle_normal");
 168                 // weapon reticles are precached in weapon files
 169         }
 170
 171         {
 172                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 173                 minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 174                 shortmapname = mi_shortname;
 175
 176                 if (precache_pic(minimapname) == "")
 177                 {
 178                         // but maybe we have a non-clever minimap
 179                         minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 180                         if (precache_pic(minimapname) == "")
 181                                 minimapname = ""; // FAIL
 182                         else
 183                                 get_mi_min_max_texcoords(0); // load new texcoords
 184                 }
 185
 186                 mi_center = (mi_min + mi_max) * 0.5;
 187                 mi_scale = mi_max - mi_min;
 188                 minimapname = strzone(minimapname);
 189         }
 190
 191         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 192         LoadMenuSkinValues();
 193 }
 194
 195 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 196 void Shutdown()
 197 {
 198         WarpZone_Shutdown();
 199
 200         delete(teams);
 201         delete(players);
 202         db_close(binddb);
 203         db_close(tempdb);
 204         if(autocvar_cl_db_saveasdump)
 205                 db_dump(ClientProgsDB, "client.db");
 206         else
 207                 db_save(ClientProgsDB, "client.db");
 208         db_close(ClientProgsDB);
 209
 210         if(camera_active)
 211                 cvar_set("chase_active",ftos(chase_active_backup));
 212
 213         // unset the event chasecam's chase_active
 214         if(autocvar_chase_active < 0)
 215                 cvar_set("chase_active", "0");
 216
 217         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 218
 219         if (!isdemo())
 220         {
 221                 if (!(calledhooks & HOOK_START))
 222                         localcmd("\n_cl_hook_gamestart nop\n");
 223                 if (!(calledhooks & HOOK_END))
 224                         localcmd("\ncl_hook_gameend\n");
 225         }
 226
 227         localcmd("\ncl_hook_shutdown\n");
 228
 229         localcmd("\n-button12\n");
 230
 231         deactivate_minigame();
 232         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 233 }
 234
 235 .float has_team;
 236 bool SetTeam(entity o, int Team)
 237 {
 238         TC(int, Team);
 239         devassert_once(Team);
 240         entity tm;
 241         if(teamplay)
 242         {
 243                 switch(Team)
 244                 {
 245                         case -1:
 246                         case NUM_TEAM_1:
 247                         case NUM_TEAM_2:
 248                         case NUM_TEAM_3:
 249                         case NUM_TEAM_4:
 250                                 break;
 251                         default:
 252                                 if(GetTeam(Team, false) == NULL)
 253                                 {
 254                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 255                                         Team = NUM_SPECTATOR;
 256                                 }
 257                                 break;
 258                 }
 259         }
 260         else
 261         {
 262                 switch(Team)
 263                 {
 264                         case -1:
 265                         case 0:
 266                                 break;
 267                         default:
 268                                 if(GetTeam(Team, false) == NULL)
 269                                 {
 270                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 271                                         Team = NUM_SPECTATOR;
 272                                 }
 273                                 break;
 274                 }
 275         }
 276         if(Team == -1) // leave
 277         {
 278                 if(o.has_team)
 279                 {
 280                         tm = GetTeam(o.team, false);
 281                         tm.team_size -= 1;
 282                         o.has_team = 0;
 283                         return true;
 284                 }
 285         }
 286         else
 287         {
 288                 if (!o.has_team)
 289                 {
 290                         o.team = Team;
 291                         tm = GetTeam(Team, true);
 292                         tm.team_size += 1;
 293                         o.has_team = 1;
 294                         return true;
 295                 }
 296                 else if(Team != o.team)
 297                 {
 298                         tm = GetTeam(o.team, false);
 299                         tm.team_size -= 1;
 300                         o.team = Team;
 301                         tm = GetTeam(Team, true);
 302                         tm.team_size += 1;
 303                         return true;
 304                 }
 305         }
 306         return false;
 307 }
 308
 309 void Playerchecker_Think(entity this)
 310 {
 311     int i;
 312         entity e;
 313         for(i = 0; i < maxclients; ++i)
 314         {
 315                 e = playerslots[i];
 316                 if(entcs_GetName(i) == "")
 317                 {
 318                         if(e.sort_prev)
 319                         {
 320                                 // player disconnected
 321                                 SetTeam(e, -1);
 322                                 RemovePlayer(e);
 323                                 e.sort_prev = NULL;
 324                                 //e.gotscores = 0;
 325                         }
 326                 }
 327                 else
 328                 {
 329                         if (!e.sort_prev)
 330                         {
 331                                 // player connected
 332                                 if (!e)
 333                                 {
 334                                         playerslots[i] = e = new_pure(playerslot);
 335                                 }
 336                                 e.sv_entnum = i;
 337                                 e.ping = 0;
 338                                 e.ping_packetloss = 0;
 339                                 e.ping_movementloss = 0;
 340                                 //e.gotscores = 0; // we might already have the scores...
 341                                 int t = entcs_GetScoreTeam(i);
 342                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 343                                 RegisterPlayer(e);
 344                                 Scoreboard_UpdatePlayerPos(e);
 345                         }
 346                 }
 347         }
 348         this.nextthink = time + 0.2;
 349 }
 350
 351 void PostInit()
 352 {
 353         entity playerchecker = new_pure(playerchecker);
 354         setthink(playerchecker, Playerchecker_Think);
 355         playerchecker.nextthink = time + 0.2;
 356
 357         TrueAim_Init();
 358
 359         postinit = true;
 360 }
 361
 362 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 363 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 364 // All keys are in ascii.
 365 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 366 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 367 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 368 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 369 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 370 {
 371         TC(int, bInputType);
 372         bool override = false;
 373         override |= HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary);
 374         if (override)
 375                 return true;
 376
 377         override |= QuickMenu_InputEvent(bInputType, nPrimary, nSecondary);
 378
 379         override |= HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary);
 380
 381         override |= MapVote_InputEvent(bInputType, nPrimary, nSecondary);
 382
 383         override |= HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary);
 384
 385         if(override)
 386                 return true;
 387
 388         return false;
 389 }
 390
 391 // END REQUIRED CSQC FUNCTIONS
 392 // --------------------------------------------------------------------------
 393
 394 // --------------------------------------------------------------------------
 395 // BEGIN OPTIONAL CSQC FUNCTIONS
 396
 397 void Ent_RemovePlayerScore(entity this)
 398 {
 399         if(this.owner) {
 400                 SetTeam(this.owner, -1);
 401                 this.owner.gotscores = 0;
 402                 FOREACH(Scores, true, {
 403                         this.owner.(scores(it)) = 0; // clear all scores
 404                 });
 405         }
 406 }
 407
 408 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 409 {
 410         make_pure(this);
 411         entity o;
 412
 413         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 414         // (no I've never heard of M-x replace-string, sed, or anything like that)
 415         bool isNew = !this.owner; // workaround for DP bug
 416         int n = ReadByte()-1;
 417
 418 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 419         if(!isNew && n != this.sv_entnum)
 420         {
 421                 //print("A CSQC entity changed its owner!\n");
 422                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
 423                 isNew = true;
 424                 Ent_Remove(this);
 425         }
 426 #endif
 427
 428         this.sv_entnum = n;
 429
 430         o = playerslots[this.sv_entnum];
 431         if (!o)
 432         {
 433                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 434         }
 435         this.owner = o;
 436         o.sv_entnum = this.sv_entnum;
 437         o.gotscores = 1;
 438
 439         //if (!o.sort_prev)
 440         //      RegisterPlayer(o);
 441         //playerchecker will do this for us later, if it has not already done so
 442
 443         int sf = ReadShort();
 444         int lf = ReadShort();
 445         FOREACH(Scores, true, {
 446                 int p = 1 << (i % 16);
 447                 if (sf & p)
 448                 {
 449                         if (lf & p)
 450                                 o.(scores(it)) = ReadInt24_t();
 451                         else
 452                                 o.(scores(it)) = ReadChar();
 453                 }
 454         });
 455
 456         return = true;
 457
 458         if(o.sort_prev)
 459                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 460
 461         this.entremove = Ent_RemovePlayerScore;
 462 }
 463
 464 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 465 {
 466         make_pure(this);
 467         int i;
 468
 469         this.team = ReadByte();
 470         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 471
 472 #if MAX_TEAMSCORE <= 8
 473         int sf = ReadByte();
 474         int lf = ReadByte();
 475 #else
 476         int sf = ReadShort();
 477         int lf = ReadShort();
 478 #endif
 479         for(i = 0; i < MAX_TEAMSCORE; ++i)
 480                 if(sf & BIT(i))
 481                 {
 482                         if(lf & BIT(i))
 483                                 o.(teamscores(i)) = ReadInt24_t();
 484                         else
 485                                 o.(teamscores(i)) = ReadChar();
 486                 }
 487
 488         return = true;
 489
 490         Scoreboard_UpdateTeamPos(o);
 491 }
 492
 493 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 494 {
 495         make_pure(this);
 496         float newspectatee_status;
 497
 498         int f = ReadByte();
 499
 500         scoreboard_showscores_force = (f & BIT(0));
 501
 502         if(f & BIT(1))
 503         {
 504                 newspectatee_status = ReadByte();
 505                 if(newspectatee_status == player_localnum + 1)
 506                         newspectatee_status = -1; // observing
 507         }
 508         else
 509                 newspectatee_status = 0;
 510
 511         spectatorbutton_zoom = (f & BIT(2));
 512
 513         if(f & BIT(4))
 514         {
 515                 num_spectators = ReadByte();
 516
 517                 float i, slot;
 518
 519                 for(i = 0; i < MAX_SPECTATORS; ++i)
 520                         spectatorlist[i] = 0; // reset list first
 521
 522                 for(i = 0; i < num_spectators; ++i)
 523                 {
 524                         slot = ReadByte();
 525                         spectatorlist[i] = slot - 1;
 526                 }
 527         }
 528
 529         return = true;
 530
 531         if(newspectatee_status != spectatee_status)
 532         {
 533                 // clear race stuff
 534                 race_laptime = 0;
 535                 race_checkpointtime = 0;
 536                 hud_dynamic_shake_factor = -1;
 537                 spectatee_status_changed_time = time;
 538         }
 539         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 540         {
 541                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 542                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 543                 )
 544                         prev_p_health = -1;
 545                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 546                         prev_health = -1;
 547         }
 548         spectatee_status = newspectatee_status;
 549
 550         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 551 }
 552
 553 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 554 {
 555         make_pure(this);
 556         int i, j, b, f;
 557
 558         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 559
 560         if(!(nags & BIT(2)))
 561         {
 562                 strfree(vote_called_vote);
 563                 vote_active = 0;
 564         }
 565         else
 566         {
 567                 vote_active = 1;
 568         }
 569
 570         if(nags & BIT(6))
 571         {
 572                 vote_yescount = ReadByte();
 573                 vote_nocount = ReadByte();
 574                 vote_needed = ReadByte();
 575                 vote_highlighted = ReadChar();
 576         }
 577
 578         if(nags & BIT(7))
 579         {
 580                 strcpy(vote_called_vote, ReadString());
 581         }
 582
 583         if(nags & 1)
 584         {
 585                 for(j = 0; j < maxclients; ++j)
 586                         if(playerslots[j])
 587                                 playerslots[j].ready = true;
 588                 for(i = 1; i <= maxclients; i += 8)
 589                 {
 590                         f = ReadByte();
 591                         for(j = i-1, b = BIT(0); b < BIT(8); b <<= 1, ++j)
 592                                 if (!(f & b))
 593                                         if(playerslots[j])
 594                                                 playerslots[j].ready = false;
 595                 }
 596         }
 597
 598         return = true;
 599
 600         ready_waiting = (nags & BIT(0));
 601         ready_waiting_for_me = (nags & BIT(1));
 602         vote_waiting = (nags & BIT(2));
 603         vote_waiting_for_me = (nags & BIT(3));
 604         warmup_stage = (nags & BIT(4));
 605 }
 606
 607 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 608 {
 609         make_pure(this);
 610         int sf = 0;
 611         serialize(byte, 0, sf);
 612         if (sf & 1) {
 613                 for (int j = 0; j < maxclients; ++j) {
 614                         if (playerslots[j]) {
 615                                 playerslots[j].eliminated = true;
 616                         }
 617                 }
 618                 for (int i = 1; i <= maxclients; i += 8) {
 619                         int f = 0;
 620                         serialize(byte, 0, f);
 621                         for (int b = 0; b < 8; ++b) {
 622                                 if (f & BIT(b)) continue;
 623                                 int j = i - 1 + b;
 624                                 if (playerslots[j]) {
 625                                         playerslots[j].eliminated = false;
 626                                 }
 627                         }
 628                 }
 629         }
 630         return true;
 631 }
 632
 633 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 634 {
 635         make_pure(this);
 636         prandom_debug();
 637         float s = ReadShort();
 638         psrandom(s);
 639         return true;
 640 }
 641
 642 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 643 {
 644         make_pure(this);
 645         int sf = ReadInt24_t();
 646         if (sf == 0) {
 647                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 648                         weapon_accuracy[w] = -1;
 649                 return true;
 650         }
 651
 652         int f = 1;
 653         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 654                 if (sf & f) {
 655                         int b = ReadByte();
 656                         if (b == 0)
 657                                 weapon_accuracy[w] = -1;
 658                         else if (b == 255)
 659                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 660                         else
 661                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 662                 }
 663                 f = (f == 0x800000) ? 1 : f * 2;
 664         }
 665         return true;
 666 }
 667
 668 void Spawn_Draw(entity this)
 669 {
 670         if(this.alpha <= 0)
 671                 return;
 672
 673         __pointparticles(this.cnt, this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 674 }
 675
 676 void Spawn_PreDraw(entity this)
 677 {
 678         float alph;
 679         vector org = getpropertyvec(VF_ORIGIN);
 680         if(this.fade_start)
 681         {
 682                 if(vdist(org - this.origin, >, this.fade_end))
 683                         alph = 0; // save on some processing
 684                 else if(vdist(org - this.origin, <, this.fade_start))
 685                         alph = 1; // more processing saved
 686                 else
 687                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 688         }
 689         else
 690                 alph = 1;
 691         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 692         this.alpha = alph;
 693         if(alph <= 0)
 694                 this.drawmask = 0;
 695         else
 696                 this.drawmask = MASK_NORMAL;
 697 }
 698
 699 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 700 {
 701         float teamnum = (ReadByte() - 1);
 702         vector spn_origin = ReadVector();
 703
 704         this.team = (teamnum + 1);
 705
 706         //if(is_new)
 707         //{
 708                 this.origin = spn_origin;
 709                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 710                 //droptofloor();
 711
 712                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 713                 {
 714                         this.mdl = "models/spawnpoint.md3";
 715                         this.colormod = Team_ColorRGB(teamnum);
 716                         precache_model(this.mdl);
 717                         setmodel(this, this.mdl);
 718                         this.drawmask = MASK_NORMAL;
 719                         //this.move_movetype = MOVETYPE_NOCLIP;
 720                         //this.draw = Spawn_Draw;
 721                         IL_PUSH(g_drawables, this);
 722                 }*/
 723                 if(autocvar_cl_spawn_point_particles)
 724                 {
 725                         if(teamplay)
 726                         {
 727                                 switch(teamnum)
 728                                 {
 729                                         case NUM_TEAM_1: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
 730                                         case NUM_TEAM_2: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
 731                                         case NUM_TEAM_3: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
 732                                         case NUM_TEAM_4: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
 733                                         default: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
 734                                 }
 735                         }
 736                         else { this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
 737
 738                         this.draw = Spawn_Draw;
 739                         if (is_new) IL_PUSH(g_drawables, this);
 740                         setpredraw(this, Spawn_PreDraw);
 741                         this.fade_start = autocvar_cl_spawn_point_dist_min;
 742                         this.fade_end = autocvar_cl_spawn_point_dist_max;
 743                 }
 744         //}
 745
 746         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 747         return true;
 748 }
 749
 750 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 751 {
 752         // If entnum is 0, ONLY do the local spawn actions
 753         // this way the server can disable the sending of
 754         // spawn origin or such to clients if wanted.
 755         float entnum = ReadByte();
 756
 757         if(entnum)
 758         {
 759                 this.origin = ReadVector();
 760
 761                 if(is_new)
 762                 {
 763                         float teamnum = entcs_GetTeam(entnum - 1);
 764
 765                         if(autocvar_cl_spawn_event_particles)
 766                         {
 767                                 switch(teamnum)
 768                                 {
 769                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 770                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 771                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 772                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 773                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 774                                 }
 775                         }
 776                         if(autocvar_cl_spawn_event_sound)
 777                         {
 778                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 779                         }
 780                 }
 781         }
 782         return = true;
 783
 784         // local spawn actions
 785         if(is_new && (!entnum || (entnum == player_localentnum)))
 786         {
 787                 zoomin_effect = 1;
 788                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 789
 790                 if(autocvar_cl_unpress_zoom_on_spawn)
 791                 {
 792                         localcmd("-zoom\n");
 793                         button_zoom = false;
 794                 }
 795                 HUD_Radar_Hide_Maximized();
 796         }
 797         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 798 }
 799
 800 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 801 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 802 void CSQC_Ent_Update(entity this, bool isnew)
 803 {
 804         this.sourceLoc = __FILE__":"STR(__LINE__);
 805         int t = ReadByte();
 806
 807         // set up the "time" global for received entities to be correct for interpolation purposes
 808         float savetime = time;
 809         if(servertime)
 810         {
 811                 time = servertime;
 812         }
 813         else
 814         {
 815                 serverprevtime = time;
 816                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 817                 time = serverprevtime + serverdeltatime;
 818         }
 819
 820 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 821         if (this.enttype)
 822         {
 823                 if (t != this.enttype || isnew)
 824                 {
 825                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
 826                         Ent_Remove(this);
 827                         clearentity(this);
 828                         isnew = true;
 829                 }
 830         }
 831         else
 832         {
 833                 if (!isnew)
 834                 {
 835                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
 836                         isnew = true;
 837                 }
 838         }
 839 #endif
 840         this.enttype = t;
 841         bool done = false;
 842         FOREACH(LinkedEntities, it.m_id == t, {
 843                 if (isnew) this.classname = it.netname;
 844                 if (autocvar_developer_csqcentities)
 845             LOG_INFOF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 846                 done = it.m_read(this, NULL, isnew);
 847                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 848                 break;
 849         });
 850         time = savetime;
 851         if (!done)
 852         {
 853                 LOG_FATALF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 854         }
 855 }
 856
 857 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 858 // used when an entity changes its type. For an entity that someone interacts
 859 // with others, make sure it can no longer do so.
 860 void Ent_Remove(entity this)
 861 {
 862         if(this.entremove) this.entremove(this);
 863
 864         if(this.skeletonindex)
 865         {
 866                 skel_delete(this.skeletonindex);
 867                 this.skeletonindex = 0;
 868         }
 869
 870         if(this.snd_looping > 0)
 871         {
 872                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 873                 this.snd_looping = 0;
 874         }
 875
 876         this.enttype = 0;
 877         this.classname = "";
 878         this.draw = func_null;
 879         this.entremove = func_null;
 880         // TODO possibly set more stuff to defaults
 881 }
 882 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 883 void CSQC_Ent_Remove(entity this)
 884 {
 885         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
 886         if (wasfreed(this))
 887         {
 888                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
 889                 return;
 890         }
 891         if (this.enttype) Ent_Remove(this);
 892         delete(this);
 893 }
 894
 895 void Gamemode_Init()
 896 {
 897         if (!isdemo())
 898         {
 899                 if(!(calledhooks & HOOK_START))
 900                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 901                 calledhooks |= HOOK_START;
 902         }
 903 }
 904 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 905 void CSQC_Parse_StuffCmd(string strMessage)
 906 {
 907         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
 908         localcmd(strMessage);
 909 }
 910 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 911 void CSQC_Parse_Print(string strMessage)
 912 {
 913         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
 914         print(ColorTranslateRGB(strMessage));
 915 }
 916
 917 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 918 void CSQC_Parse_CenterPrint(string strMessage)
 919 {
 920         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
 921         centerprint_hud(strMessage);
 922 }
 923
 924 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
 925 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
 926 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
 927 bool CSQC_Parse_TempEntity()
 928 {
 929         // Acquire TE ID
 930         int nTEID = ReadByte();
 931
 932         FOREACH(TempEntities, it.m_id == nTEID, {
 933                 if (autocvar_developer_csqcentities)
 934                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
 935                 return it.m_read(NULL, NULL, true);
 936         });
 937
 938         if (autocvar_developer_csqcentities)
 939                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
 940
 941         // No special logic for this temporary entity; return 0 so the engine can handle it
 942         return false;
 943 }
 944
 945 string forcefog;
 946 void Fog_Force()
 947 {
 948         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 949                 localcmd("\nr_drawfog 0\n");
 950         else if (forcefog != "")
 951                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
 952 }
 953
 954 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
 955 {
 956         make_pure(this);
 957         gametype = ReadRegistered(Gametypes);
 958         teamplay = _MapInfo_GetTeamPlayBool(gametype);
 959         HUD_ModIcons_SetFunc();
 960         FOREACH(Scores, true, {
 961                 strcpy(scores_label(it), ReadString());
 962                 scores_flags(it) = ReadByte();
 963         });
 964         for (int i = 0; i < MAX_TEAMSCORE; ++i)
 965         {
 966                 strcpy(teamscores_label(i), ReadString());
 967                 teamscores_flags(i) = ReadByte();
 968         }
 969         return = true;
 970         Scoreboard_InitScores();
 971         Gamemode_Init();
 972 }
 973
 974 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
 975 {
 976         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 977
 978         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 979         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 980         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 981         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 982         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 983         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 984         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 985         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 986
 987         strcpy(forcefog, ReadString());
 988
 989         armorblockpercent = ReadByte() / 255.0;
 990         damagepush_speedfactor = ReadByte() / 255.0;
 991
 992         serverflags = ReadByte();
 993
 994         g_trueaim_minrange = ReadCoord();
 995
 996         return = true;
 997
 998         MUTATOR_CALLHOOK(Ent_Init);
 999
1000         if (!postinit) PostInit();
1001 }
1002
1003 float GetSpeedUnitFactor(int speed_unit)
1004 {
1005         switch(speed_unit)
1006         {
1007                 default:
1008                 case 1:
1009                         return 1.0;
1010                 case 2:
1011                         return 0.0254;
1012                 case 3:
1013                         return 0.0254 * 3.6;
1014                 case 4:
1015                         return 0.0254 * 3.6 * 0.6213711922;
1016                 case 5:
1017                         return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1018         }
1019 }
1020
1021 string GetSpeedUnit(int speed_unit)
1022 {
1023         switch(speed_unit)
1024         {
1025                 default:
1026                 case 1:
1027                         return _(" qu/s");
1028                 case 2:
1029                         return _(" m/s");
1030                 case 3:
1031                         return _(" km/h");
1032                 case 4:
1033                         return _(" mph");
1034                 case 5:
1035                         return _(" knots");
1036         }
1037 }
1038
1039 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1040 {
1041         int b = ReadByte();
1042
1043         switch (b)
1044         {
1045                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1046                         race_checkpoint = ReadByte();
1047                         race_time = ReadInt24_t();
1048                         race_previousbesttime = ReadInt24_t();
1049                         race_mypreviousbesttime = ReadInt24_t();
1050                         string pbestname = ReadString();
1051                         if(autocvar_cl_race_cptimes_onlyself)
1052                         {
1053                                 race_previousbesttime = race_mypreviousbesttime;
1054                                 race_mypreviousbesttime = 0;
1055                                 strcpy(race_previousbestname, "");
1056                         }
1057                         else
1058                                 strcpy(race_previousbestname, pbestname);
1059
1060                         race_checkpointtime = time;
1061
1062                         if(race_checkpoint == 0 || race_checkpoint == 254)
1063                         {
1064                                 race_penaltyaccumulator = 0;
1065                                 race_laptime = time; // valid
1066                         }
1067                         break;
1068
1069                 case RACE_NET_CHECKPOINT_CLEAR:
1070                         race_laptime = 0;
1071                         race_checkpointtime = 0;
1072                         break;
1073
1074                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1075                         race_laptime = ReadCoord();
1076                         race_checkpointtime = -99999;
1077                         // fall through
1078                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1079                         race_nextcheckpoint = ReadByte();
1080
1081                         race_nextbesttime = ReadInt24_t();
1082                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1083                                 race_mybesttime = ReadInt24_t();
1084                         string newname = ReadString();
1085                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1086                         {
1087                                 race_nextbesttime = race_mybesttime;
1088                                 race_mybesttime = 0;
1089                                 strcpy(race_nextbestname, "");
1090                         }
1091                         else
1092                                 strcpy(race_nextbestname, newname);
1093                         break;
1094
1095                 case RACE_NET_CHECKPOINT_HIT_RACE:
1096                         race_mycheckpoint = ReadByte();
1097                         race_mycheckpointtime = time;
1098                         race_mycheckpointdelta = ReadInt24_t();
1099                         race_mycheckpointlapsdelta = ReadByte();
1100                         if(race_mycheckpointlapsdelta >= 128)
1101                                 race_mycheckpointlapsdelta -= 256;
1102                         int who = ReadByte();
1103                         if(who)
1104                                 strcpy(race_mycheckpointenemy, entcs_GetName(who - 1));
1105                         else
1106                                 strcpy(race_mycheckpointenemy, ""); // TODO: maybe string_null works fine here?
1107                         break;
1108
1109                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1110                         race_othercheckpoint = ReadByte();
1111                         race_othercheckpointtime = time;
1112                         race_othercheckpointdelta = ReadInt24_t();
1113                         race_othercheckpointlapsdelta = ReadByte();
1114                         if(race_othercheckpointlapsdelta >= 128)
1115                                 race_othercheckpointlapsdelta -= 256;
1116                         int what = ReadByte();
1117                         if(what)
1118                                 strcpy(race_othercheckpointenemy, entcs_GetName(what - 1));
1119                         else
1120                                 strcpy(race_othercheckpointenemy, ""); // TODO: maybe string_null works fine here?
1121                         break;
1122
1123                 case RACE_NET_PENALTY_RACE:
1124                         race_penaltyeventtime = time;
1125                         race_penaltytime = ReadShort();
1126                         //race_penaltyaccumulator += race_penaltytime;
1127                         strcpy(race_penaltyreason, ReadString());
1128                         break;
1129
1130                 case RACE_NET_PENALTY_QUALIFYING:
1131                         race_penaltyeventtime = time;
1132                         race_penaltytime = ReadShort();
1133                         race_penaltyaccumulator += race_penaltytime;
1134                         strcpy(race_penaltyreason, ReadString());
1135                         break;
1136
1137                 case RACE_NET_SERVER_RECORD:
1138                         race_server_record = ReadInt24_t();
1139                         break;
1140                 case RACE_NET_SPEED_AWARD:
1141                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1142                         strcpy(race_speedaward_holder, ReadString());
1143                         strcpy(race_speedaward_unit, GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1144                         break;
1145                 case RACE_NET_SPEED_AWARD_BEST:
1146                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1147                         strcpy(race_speedaward_alltimebest_holder, ReadString());
1148                         strcpy(race_speedaward_alltimebest_unit, GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1149                         break;
1150                 case RACE_NET_RANKINGS_CNT:
1151                         RANKINGS_DISPLAY_CNT = ReadByte();
1152                         break;
1153                 case RACE_NET_SERVER_RANKINGS:
1154                         float prevpos, del;
1155             int pos = ReadShort();
1156                         prevpos = ReadShort();
1157                         del = ReadShort();
1158
1159                         // move other rankings out of the way
1160             int i;
1161                         if (prevpos) {
1162                                 int m = min(prevpos, RANKINGS_DISPLAY_CNT);
1163                                 for (i=m-1; i>pos-1; --i) {
1164                                         grecordtime[i] = grecordtime[i-1];
1165                                         strcpy(grecordholder[i], grecordholder[i-1]);
1166                                 }
1167                         } else if (del) { // a record has been deleted by the admin
1168                                 for (i=pos-1; i<= RANKINGS_DISPLAY_CNT-1; ++i) {
1169                                         if (i == RANKINGS_DISPLAY_CNT-1) { // clear out last record
1170                                                 grecordtime[i] = 0;
1171                                                 strfree(grecordholder[i]);
1172                                         }
1173                                         else {
1174                                                 grecordtime[i] = grecordtime[i+1];
1175                                                 strcpy(grecordholder[i], grecordholder[i+1]);
1176                                         }
1177                                 }
1178                         } else { // player has no ranked record yet
1179                                 for (i=RANKINGS_DISPLAY_CNT-1;i>pos-1;--i) {
1180                                         grecordtime[i] = grecordtime[i-1];
1181                                         strcpy(grecordholder[i], grecordholder[i-1]);
1182                                 }
1183                         }
1184
1185                         if (grecordtime[RANKINGS_DISPLAY_CNT]) {
1186                                 // kick off the player who fell from the last displayed position
1187                                 grecordtime[RANKINGS_DISPLAY_CNT] = 0;
1188                                 strfree(grecordholder[RANKINGS_DISPLAY_CNT]);
1189                         }
1190
1191                         // store new ranking
1192                         strcpy(grecordholder[pos-1], ReadString());
1193                         grecordtime[pos-1] = ReadInt24_t();
1194                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1195                                 race_myrank = pos;
1196                         break;
1197                 case RACE_NET_SERVER_STATUS:
1198                         race_status = ReadShort();
1199                         strcpy(race_status_name, ReadString());
1200         }
1201         return true;
1202 }
1203
1204 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1205 {
1206         teamnagger = 1;
1207         return true;
1208 }
1209
1210 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1211 {
1212         int i = ReadByte();
1213         int pi = ReadShort();
1214         int pl = ReadByte();
1215         int ml = ReadByte();
1216         return = true;
1217         entity e = playerslots[i];
1218         if (!e) return;
1219         e.ping = pi;
1220         e.ping_packetloss = pl / 255.0;
1221         e.ping_movementloss = ml / 255.0;
1222 }
1223
1224 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1225 {
1226         int weapon_id = ReadByte();
1227         complain_weapon = Weapons_from(weapon_id);
1228         complain_weapon_type = ReadByte();
1229         return = true;
1230
1231         complain_weapon_time = time;
1232         weapontime = time; // ping the weapon panel
1233
1234         switch(complain_weapon_type)
1235         {
1236                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, weapon_id); break;
1237                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, weapon_id); break;
1238                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, weapon_id); break;
1239         }
1240 }
1241
1242 string _getcommandkey(string cmd_name, string command, bool forcename)
1243 {
1244         string keys;
1245         float n, j, k, l = 0;
1246
1247         if (!autocvar_hud_showbinds)
1248                 return cmd_name;
1249
1250         keys = db_get(binddb, command);
1251         if (keys == "")
1252         {
1253                 bool joy_active = cvar("joy_active");
1254                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1255                 for(j = 0; j < n; ++j)
1256                 {
1257                         k = stof(argv(j));
1258                         if(k != -1)
1259                         {
1260                                 string key = keynumtostring(k);
1261                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1262                                         continue;
1263
1264                                 if (keys == "")
1265                                         keys = key;
1266                                 else
1267                                         keys = strcat(keys, ", ", key);
1268
1269                                 ++l;
1270                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1271                                         break;
1272                         }
1273
1274                 }
1275                 if (keys == "")
1276                         keys = "NO_KEY";
1277                 db_put(binddb, command, keys);
1278         }
1279
1280         if (keys == "NO_KEY") {
1281                 if (autocvar_hud_showbinds > 1)
1282                         return sprintf(_("%s (not bound)"), cmd_name);
1283                 else
1284                         return cmd_name;
1285         }
1286         else if (autocvar_hud_showbinds > 1 || forcename)
1287                 return sprintf("%s (%s)", cmd_name, keys);
1288         else
1289                 return keys;
1290 }