qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include "defs.qh"
   4 #include <common/ent_cs.qh>
   5 #include "miscfunctions.qh"
   6 #include <common/effects/effect.qh>
   7 #include <common/effects/qc/_mod.qh>
   8 #include <common/effects/all.qh>
   9 #include <common/effects/all.inc>
  10 #include "hud/_mod.qh"
  11 #include "commands/cl_cmd.qh"
  12 #include "mapvoting.qh"
  13 #include <client/mutators/_mod.qh>
  14 #include "hud/panel/scoreboard.qh"
  15 #include "hud/panel/quickmenu.qh"
  16 #include "shownames.qh"
  17 #include "view.qh"
  18 #include <common/t_items.qh>
  19 #include "weapons/projectile.qh"
  20 #include <common/deathtypes/all.qh>
  21 #include <common/items/_mod.qh>
  22 #include <common/mapinfo.qh>
  23 #include <common/minigames/cl_minigames.qh>
  24 #include <common/minigames/cl_minigames_hud.qh>
  25 #include <common/net_linked.qh>
  26 #include <common/net_notice.qh>
  27 #include <common/scores.qh>
  28 #include <common/mapobjects/_mod.qh>
  29 #include <common/vehicles/all.qh>
  30 #include <lib/csqcmodel/cl_model.qh>
  31 #include <lib/csqcmodel/interpolate.qh>
  32 #include <lib/warpzone/client.qh>
  33
  34 // --------------------------------------------------------------------------
  35 // BEGIN REQUIRED CSQC FUNCTIONS
  36 //include "main.qh"
  37
  38 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  39
  40 void draw_cursor(vector pos, vector ofs, string img, vector col, float a)
  41 {
  42         ofs = vec2(ofs.x * SIZE_CURSOR.x, ofs.y * SIZE_CURSOR.y);
  43         drawpic(pos - ofs, strcat(draw_currentSkin, img), SIZE_CURSOR, col, a, DRAWFLAG_NORMAL);
  44 }
  45
  46 void draw_cursor_normal(vector pos, vector col, float a)
  47 {
  48         draw_cursor(pos, OFFSET_CURSOR, "/cursor", col, a);
  49 }
  50
  51 void LoadMenuSkinValues()
  52 {
  53         int fh = -1;
  54         if(cvar_string("menu_skin") != "")
  55         {
  56                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  57                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  58         }
  59         if(fh < 0 && cvar_defstring("menu_skin") != "")
  60         {
  61                 cvar_set("menu_skin", cvar_defstring("menu_skin"));
  62                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  63                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  64         }
  65         if(fh < 0)
  66         {
  67                 draw_currentSkin = "gfx/menu/default";
  68                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  69         }
  70
  71         draw_currentSkin = strzone(draw_currentSkin);
  72
  73         if(fh >= 0)
  74         {
  75                 string s;
  76                 while((s = fgets(fh)))
  77                 {
  78                         int n = tokenize_console(s);
  79                         if (n < 2)
  80                                 continue;
  81                         if(substring(argv(0), 0, 2) == "//")
  82                                 continue;
  83                         if(argv(0) == "SIZE_CURSOR")
  84                                 SIZE_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  85                         else if(argv(0) == "OFFSET_CURSOR")
  86                                 OFFSET_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  87                 }
  88                 fclose(fh);
  89         }
  90 }
  91
  92 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  93 // Useful for precaching things
  94
  95 void CSQC_Init()
  96 {
  97         prvm_language = strzone(cvar_string("prvm_language"));
  98
  99 #ifdef WATERMARK
 100         LOG_INFOF("^4CSQC Build information: ^1%s", WATERMARK);
 101 #endif
 102
 103         {
 104                 int i = 0;
 105                 for ( ; i < 255; ++i)
 106                         if (getplayerkeyvalue(i, "viewentity") == "")
 107                                 break;
 108                 maxclients = i;
 109         }
 110
 111         // needs to be done so early because of the constants they create
 112         static_init();
 113         static_init_late();
 114         static_init_precache();
 115
 116         binddb = db_create();
 117         tempdb = db_create();
 118         ClientProgsDB = db_load("client.db");
 119
 120         draw_endBoldFont();
 121
 122         //registercommand("hud_configure");
 123         //registercommand("hud_save");
 124         //registercommand("menu_action");
 125
 126         ConsoleCommand_macro_init();
 127
 128         registercvar("hud_usecsqc", "1");
 129         registercvar("scoreboard_columns", "default");
 130
 131         registercvar("cl_nade_type", "3");
 132         registercvar("cl_pokenade_type", "zombie");
 133
 134         registercvar("cl_jumpspeedcap_min", "");
 135         registercvar("cl_jumpspeedcap_max", "");
 136
 137         registercvar("cl_shootfromfixedorigin", "");
 138
 139         registercvar("cl_multijump", "1");
 140
 141         registercvar("cl_spawn_near_teammate", "1");
 142
 143         if(autocvar_cl_lockview)
 144                 cvar_set("cl_lockview", "0");
 145
 146         gametype = NULL;
 147
 148         postinit = false;
 149
 150         calledhooks = 0;
 151
 152         teams = Sort_Spawn();
 153         players = Sort_Spawn();
 154
 155         GetTeam(NUM_SPECTATOR, true); // add specs first
 156
 157         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 158                 weapon_accuracy[w] = -1;
 159
 160         // precaches
 161
 162         if(autocvar_cl_reticle)
 163         {
 164                 precache_pic("gfx/reticle_normal");
 165                 // weapon reticles are precached in weapon files
 166         }
 167
 168         {
 169                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 170                 minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 171                 shortmapname = mi_shortname;
 172
 173                 if (precache_pic(minimapname) == "")
 174                 {
 175                         // but maybe we have a non-clever minimap
 176                         minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 177                         if (precache_pic(minimapname) == "")
 178                                 minimapname = ""; // FAIL
 179                         else
 180                                 get_mi_min_max_texcoords(0); // load new texcoords
 181                 }
 182
 183                 mi_center = (mi_min + mi_max) * 0.5;
 184                 mi_scale = mi_max - mi_min;
 185                 minimapname = strzone(minimapname);
 186         }
 187
 188         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 189         LoadMenuSkinValues();
 190 }
 191
 192 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 193 void Shutdown()
 194 {
 195         WarpZone_Shutdown();
 196
 197         delete(teams);
 198         delete(players);
 199         db_close(binddb);
 200         db_close(tempdb);
 201         if(autocvar_cl_db_saveasdump)
 202                 db_dump(ClientProgsDB, "client.db");
 203         else
 204                 db_save(ClientProgsDB, "client.db");
 205         db_close(ClientProgsDB);
 206
 207         if(camera_active)
 208                 cvar_set("chase_active",ftos(chase_active_backup));
 209
 210         // unset the event chasecam's chase_active
 211         if(autocvar_chase_active < 0)
 212                 cvar_set("chase_active", "0");
 213
 214         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 215
 216         if (!isdemo())
 217         {
 218                 if (!(calledhooks & HOOK_START))
 219                         localcmd("\n_cl_hook_gamestart nop\n");
 220                 if (!(calledhooks & HOOK_END))
 221                         localcmd("\ncl_hook_gameend\n");
 222         }
 223
 224         localcmd("\ncl_hook_shutdown\n");
 225
 226         deactivate_minigame();
 227         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 228 }
 229
 230 .float has_team;
 231 bool SetTeam(entity o, int Team)
 232 {
 233         TC(int, Team);
 234         devassert_once(Team);
 235         entity tm;
 236         if(teamplay)
 237         {
 238                 switch(Team)
 239                 {
 240                         case -1:
 241                         case NUM_TEAM_1:
 242                         case NUM_TEAM_2:
 243                         case NUM_TEAM_3:
 244                         case NUM_TEAM_4:
 245                                 break;
 246                         default:
 247                                 if(GetTeam(Team, false) == NULL)
 248                                 {
 249                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 250                                         Team = NUM_SPECTATOR;
 251                                 }
 252                                 break;
 253                 }
 254         }
 255         else
 256         {
 257                 switch(Team)
 258                 {
 259                         case -1:
 260                         case 0:
 261                                 break;
 262                         default:
 263                                 if(GetTeam(Team, false) == NULL)
 264                                 {
 265                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 266                                         Team = NUM_SPECTATOR;
 267                                 }
 268                                 break;
 269                 }
 270         }
 271         if(Team == -1) // leave
 272         {
 273                 if(o.has_team)
 274                 {
 275                         tm = GetTeam(o.team, false);
 276                         tm.team_size -= 1;
 277                         o.has_team = 0;
 278                         return true;
 279                 }
 280         }
 281         else
 282         {
 283                 if (!o.has_team)
 284                 {
 285                         o.team = Team;
 286                         tm = GetTeam(Team, true);
 287                         tm.team_size += 1;
 288                         o.has_team = 1;
 289                         return true;
 290                 }
 291                 else if(Team != o.team)
 292                 {
 293                         tm = GetTeam(o.team, false);
 294                         tm.team_size -= 1;
 295                         o.team = Team;
 296                         tm = GetTeam(Team, true);
 297                         tm.team_size += 1;
 298                         return true;
 299                 }
 300         }
 301         return false;
 302 }
 303
 304 void Playerchecker_Think(entity this)
 305 {
 306     int i;
 307         entity e;
 308         for(i = 0; i < maxclients; ++i)
 309         {
 310                 e = playerslots[i];
 311                 if(entcs_GetName(i) == "")
 312                 {
 313                         if(e.sort_prev)
 314                         {
 315                                 // player disconnected
 316                                 SetTeam(e, -1);
 317                                 RemovePlayer(e);
 318                                 e.sort_prev = NULL;
 319                                 //e.gotscores = 0;
 320                         }
 321                 }
 322                 else
 323                 {
 324                         if (!e.sort_prev)
 325                         {
 326                                 // player connected
 327                                 if (!e)
 328                                 {
 329                                         playerslots[i] = e = new_pure(playerslot);
 330                                 }
 331                                 e.sv_entnum = i;
 332                                 e.ping = 0;
 333                                 e.ping_packetloss = 0;
 334                                 e.ping_movementloss = 0;
 335                                 //e.gotscores = 0; // we might already have the scores...
 336                                 int t = entcs_GetScoreTeam(i);
 337                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 338                                 RegisterPlayer(e);
 339                                 Scoreboard_UpdatePlayerPos(e);
 340                         }
 341                 }
 342         }
 343         this.nextthink = time + 0.2;
 344 }
 345
 346 void PostInit()
 347 {
 348         entity playerchecker = new_pure(playerchecker);
 349         setthink(playerchecker, Playerchecker_Think);
 350         playerchecker.nextthink = time + 0.2;
 351
 352         TrueAim_Init();
 353
 354         postinit = true;
 355 }
 356
 357 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 358 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 359 // All keys are in ascii.
 360 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 361 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 362 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 363 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 364 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 365 {
 366         TC(int, bInputType);
 367         bool override = false;
 368         override |= HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary);
 369         if (override)
 370                 return true;
 371
 372         override |= QuickMenu_InputEvent(bInputType, nPrimary, nSecondary);
 373
 374         override |= HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary);
 375
 376         override |= MapVote_InputEvent(bInputType, nPrimary, nSecondary);
 377
 378         override |= HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary);
 379
 380         if(override)
 381                 return true;
 382
 383         return false;
 384 }
 385
 386 // END REQUIRED CSQC FUNCTIONS
 387 // --------------------------------------------------------------------------
 388
 389 // --------------------------------------------------------------------------
 390 // BEGIN OPTIONAL CSQC FUNCTIONS
 391
 392 void Ent_RemovePlayerScore(entity this)
 393 {
 394         if(this.owner) {
 395                 SetTeam(this.owner, -1);
 396                 this.owner.gotscores = 0;
 397                 FOREACH(Scores, true, {
 398                         this.owner.(scores(it)) = 0; // clear all scores
 399                 });
 400         }
 401 }
 402
 403 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 404 {
 405         make_pure(this);
 406         entity o;
 407
 408         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 409         // (no I've never heard of M-x replace-string, sed, or anything like that)
 410         bool isNew = !this.owner; // workaround for DP bug
 411         int n = ReadByte()-1;
 412
 413 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 414         if(!isNew && n != this.sv_entnum)
 415         {
 416                 //print("A CSQC entity changed its owner!\n");
 417                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
 418                 isNew = true;
 419                 Ent_Remove(this);
 420         }
 421 #endif
 422
 423         this.sv_entnum = n;
 424
 425         o = playerslots[this.sv_entnum];
 426         if (!o)
 427         {
 428                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 429         }
 430         this.owner = o;
 431         o.sv_entnum = this.sv_entnum;
 432         o.gotscores = 1;
 433
 434         //if (!o.sort_prev)
 435         //      RegisterPlayer(o);
 436         //playerchecker will do this for us later, if it has not already done so
 437
 438         int sf = ReadShort();
 439         int lf = ReadShort();
 440         FOREACH(Scores, true, {
 441                 int p = 1 << (i % 16);
 442                 if (sf & p)
 443                 {
 444                         if (lf & p)
 445                                 o.(scores(it)) = ReadInt24_t();
 446                         else
 447                                 o.(scores(it)) = ReadChar();
 448                 }
 449         });
 450
 451         return = true;
 452
 453         if(o.sort_prev)
 454                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 455
 456         this.entremove = Ent_RemovePlayerScore;
 457 }
 458
 459 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 460 {
 461         make_pure(this);
 462         int i;
 463
 464         this.team = ReadByte();
 465         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 466
 467 #if MAX_TEAMSCORE <= 8
 468         int sf = ReadByte();
 469         int lf = ReadByte();
 470 #else
 471         int sf = ReadShort();
 472         int lf = ReadShort();
 473 #endif
 474         for(i = 0; i < MAX_TEAMSCORE; ++i)
 475                 if(sf & BIT(i))
 476                 {
 477                         if(lf & BIT(i))
 478                                 o.(teamscores(i)) = ReadInt24_t();
 479                         else
 480                                 o.(teamscores(i)) = ReadChar();
 481                 }
 482
 483         return = true;
 484
 485         Scoreboard_UpdateTeamPos(o);
 486 }
 487
 488 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 489 {
 490         make_pure(this);
 491         float newspectatee_status;
 492
 493         int f = ReadByte();
 494
 495         scoreboard_showscores_force = (f & BIT(0));
 496
 497         if(f & BIT(1))
 498         {
 499                 newspectatee_status = ReadByte();
 500                 if(newspectatee_status == player_localnum + 1)
 501                         newspectatee_status = -1; // observing
 502         }
 503         else
 504                 newspectatee_status = 0;
 505
 506         spectatorbutton_zoom = (f & BIT(2));
 507
 508         if(f & BIT(4))
 509         {
 510                 num_spectators = ReadByte();
 511
 512                 float i, slot;
 513
 514                 for(i = 0; i < MAX_SPECTATORS; ++i)
 515                         spectatorlist[i] = 0; // reset list first
 516
 517                 for(i = 0; i < num_spectators; ++i)
 518                 {
 519                         slot = ReadByte();
 520                         spectatorlist[i] = slot - 1;
 521                 }
 522         }
 523
 524         return = true;
 525
 526         if(newspectatee_status != spectatee_status)
 527         {
 528                 // clear race stuff
 529                 race_laptime = 0;
 530                 race_checkpointtime = 0;
 531                 hud_dynamic_shake_factor = -1;
 532                 spectatee_status_changed_time = time;
 533         }
 534         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 535         {
 536                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 537                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 538                 )
 539                         prev_p_health = -1;
 540                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 541                         prev_health = -1;
 542         }
 543         spectatee_status = newspectatee_status;
 544
 545         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 546 }
 547
 548 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 549 {
 550         make_pure(this);
 551         int i, j, b, f;
 552
 553         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 554
 555         if(!(nags & BIT(2)))
 556         {
 557                 strfree(vote_called_vote);
 558                 vote_active = 0;
 559         }
 560         else
 561         {
 562                 vote_active = 1;
 563         }
 564
 565         if(nags & BIT(6))
 566         {
 567                 vote_yescount = ReadByte();
 568                 vote_nocount = ReadByte();
 569                 vote_needed = ReadByte();
 570                 vote_highlighted = ReadChar();
 571         }
 572
 573         if(nags & BIT(7))
 574         {
 575                 strcpy(vote_called_vote, ReadString());
 576         }
 577
 578         if(nags & 1)
 579         {
 580                 for(j = 0; j < maxclients; ++j)
 581                         if(playerslots[j])
 582                                 playerslots[j].ready = true;
 583                 for(i = 1; i <= maxclients; i += 8)
 584                 {
 585                         f = ReadByte();
 586                         for(j = i-1, b = BIT(0); b < BIT(8); b <<= 1, ++j)
 587                                 if (!(f & b))
 588                                         if(playerslots[j])
 589                                                 playerslots[j].ready = false;
 590                 }
 591         }
 592
 593         return = true;
 594
 595         ready_waiting = (nags & BIT(0));
 596         ready_waiting_for_me = (nags & BIT(1));
 597         vote_waiting = (nags & BIT(2));
 598         vote_waiting_for_me = (nags & BIT(3));
 599         warmup_stage = (nags & BIT(4));
 600 }
 601
 602 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 603 {
 604         make_pure(this);
 605         int sf = 0;
 606         serialize(byte, 0, sf);
 607         if (sf & 1) {
 608                 for (int j = 0; j < maxclients; ++j) {
 609                         if (playerslots[j]) {
 610                                 playerslots[j].eliminated = true;
 611                         }
 612                 }
 613                 for (int i = 1; i <= maxclients; i += 8) {
 614                         int f = 0;
 615                         serialize(byte, 0, f);
 616                         for (int b = 0; b < 8; ++b) {
 617                                 if (f & BIT(b)) continue;
 618                                 int j = i - 1 + b;
 619                                 if (playerslots[j]) {
 620                                         playerslots[j].eliminated = false;
 621                                 }
 622                         }
 623                 }
 624         }
 625         return true;
 626 }
 627
 628 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 629 {
 630         make_pure(this);
 631         prandom_debug();
 632         float s = ReadShort();
 633         psrandom(s);
 634         return true;
 635 }
 636
 637 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 638 {
 639         make_pure(this);
 640         int sf = ReadInt24_t();
 641         if (sf == 0) {
 642                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 643                         weapon_accuracy[w] = -1;
 644                 return true;
 645         }
 646
 647         int f = 1;
 648         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 649                 if (sf & f) {
 650                         int b = ReadByte();
 651                         if (b == 0)
 652                                 weapon_accuracy[w] = -1;
 653                         else if (b == 255)
 654                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 655                         else
 656                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 657                 }
 658                 f = (f == 0x800000) ? 1 : f * 2;
 659         }
 660         return true;
 661 }
 662
 663 void Spawn_Draw(entity this)
 664 {
 665         if(this.alpha <= 0)
 666                 return;
 667
 668         __pointparticles(this.cnt, this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 669 }
 670
 671 void Spawn_PreDraw(entity this)
 672 {
 673         float alph;
 674         vector org = getpropertyvec(VF_ORIGIN);
 675         if(this.fade_start)
 676         {
 677                 if(vdist(org - this.origin, >, this.fade_end))
 678                         alph = 0; // save on some processing
 679                 else if(vdist(org - this.origin, <, this.fade_start))
 680                         alph = 1; // more processing saved
 681                 else
 682                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 683         }
 684         else
 685                 alph = 1;
 686         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 687         this.alpha = alph;
 688         if(alph <= 0)
 689                 this.drawmask = 0;
 690         else
 691                 this.drawmask = MASK_NORMAL;
 692 }
 693
 694 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 695 {
 696         float teamnum = (ReadByte() - 1);
 697         vector spn_origin = ReadVector();
 698
 699         this.team = (teamnum + 1);
 700
 701         //if(is_new)
 702         //{
 703                 this.origin = spn_origin;
 704                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 705                 //droptofloor();
 706
 707                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 708                 {
 709                         this.mdl = "models/spawnpoint.md3";
 710                         this.colormod = Team_ColorRGB(teamnum);
 711                         precache_model(this.mdl);
 712                         setmodel(this, this.mdl);
 713                         this.drawmask = MASK_NORMAL;
 714                         //this.move_movetype = MOVETYPE_NOCLIP;
 715                         //this.draw = Spawn_Draw;
 716                         IL_PUSH(g_drawables, this);
 717                 }*/
 718                 if(autocvar_cl_spawn_point_particles)
 719                 {
 720                         if(teamplay)
 721                         {
 722                                 switch(teamnum)
 723                                 {
 724                                         case NUM_TEAM_1: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
 725                                         case NUM_TEAM_2: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
 726                                         case NUM_TEAM_3: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
 727                                         case NUM_TEAM_4: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
 728                                         default: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
 729                                 }
 730                         }
 731                         else { this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
 732
 733                         this.draw = Spawn_Draw;
 734                         if (is_new) IL_PUSH(g_drawables, this);
 735                         setpredraw(this, Spawn_PreDraw);
 736                         this.fade_start = autocvar_cl_spawn_point_dist_min;
 737                         this.fade_end = autocvar_cl_spawn_point_dist_max;
 738                 }
 739         //}
 740
 741         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 742         return true;
 743 }
 744
 745 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 746 {
 747         // If entnum is 0, ONLY do the local spawn actions
 748         // this way the server can disable the sending of
 749         // spawn origin or such to clients if wanted.
 750         float entnum = ReadByte();
 751
 752         if(entnum)
 753         {
 754                 this.origin = ReadVector();
 755
 756                 if(is_new)
 757                 {
 758                         float teamnum = entcs_GetTeam(entnum - 1);
 759
 760                         if(autocvar_cl_spawn_event_particles)
 761                         {
 762                                 switch(teamnum)
 763                                 {
 764                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 765                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 766                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 767                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 768                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 769                                 }
 770                         }
 771                         if(autocvar_cl_spawn_event_sound)
 772                         {
 773                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 774                         }
 775                 }
 776         }
 777         return = true;
 778
 779         // local spawn actions
 780         if(is_new && (!entnum || (entnum == player_localentnum)))
 781         {
 782                 zoomin_effect = 1;
 783                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 784
 785                 if(autocvar_cl_unpress_zoom_on_spawn)
 786                 {
 787                         localcmd("-zoom\n");
 788                         button_zoom = false;
 789                 }
 790                 HUD_Radar_Hide_Maximized();
 791         }
 792         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 793 }
 794
 795 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 796 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 797 void CSQC_Ent_Update(entity this, bool isnew)
 798 {
 799         this.sourceLoc = __FILE__ ":" STR(__LINE__);
 800         int t = ReadByte();
 801
 802         // set up the "time" global for received entities to be correct for interpolation purposes
 803         float savetime = time;
 804         if(servertime)
 805         {
 806                 time = servertime;
 807         }
 808         else
 809         {
 810                 serverprevtime = time;
 811                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 812                 time = serverprevtime + serverdeltatime;
 813         }
 814
 815 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 816         if (this.enttype)
 817         {
 818                 if (t != this.enttype || isnew)
 819                 {
 820                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
 821                         Ent_Remove(this);
 822                         clearentity(this);
 823                         isnew = true;
 824                 }
 825         }
 826         else
 827         {
 828                 if (!isnew)
 829                 {
 830                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
 831                         isnew = true;
 832                 }
 833         }
 834 #endif
 835         this.enttype = t;
 836         bool done = false;
 837         FOREACH(LinkedEntities, it.m_id == t, {
 838                 if (isnew) this.classname = it.netname;
 839                 if (autocvar_developer_csqcentities)
 840             LOG_INFOF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 841                 done = it.m_read(this, NULL, isnew);
 842                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 843                 break;
 844         });
 845         time = savetime;
 846         if (!done)
 847         {
 848                 LOG_FATALF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 849         }
 850 }
 851
 852 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 853 // used when an entity changes its type. For an entity that someone interacts
 854 // with others, make sure it can no longer do so.
 855 void Ent_Remove(entity this)
 856 {
 857         if(this.entremove) this.entremove(this);
 858
 859         if(this.skeletonindex)
 860         {
 861                 skel_delete(this.skeletonindex);
 862                 this.skeletonindex = 0;
 863         }
 864
 865         if(this.snd_looping > 0)
 866         {
 867                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 868                 this.snd_looping = 0;
 869         }
 870
 871         this.enttype = 0;
 872         this.classname = "";
 873         this.draw = func_null;
 874         this.entremove = func_null;
 875         // TODO possibly set more stuff to defaults
 876 }
 877 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 878 void CSQC_Ent_Remove(entity this)
 879 {
 880         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
 881         if (wasfreed(this))
 882         {
 883                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
 884                 return;
 885         }
 886         if (this.enttype) Ent_Remove(this);
 887         delete(this);
 888 }
 889
 890 void Gamemode_Init()
 891 {
 892         if (!isdemo())
 893         {
 894                 if(!(calledhooks & HOOK_START))
 895                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 896                 calledhooks |= HOOK_START;
 897         }
 898 }
 899 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 900 void CSQC_Parse_StuffCmd(string strMessage)
 901 {
 902         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
 903         localcmd(strMessage);
 904 }
 905 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 906 void CSQC_Parse_Print(string strMessage)
 907 {
 908         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
 909         print(ColorTranslateRGB(strMessage));
 910 }
 911
 912 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 913 void CSQC_Parse_CenterPrint(string strMessage)
 914 {
 915         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
 916         centerprint_hud(strMessage);
 917 }
 918
 919 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
 920 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
 921 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
 922 bool CSQC_Parse_TempEntity()
 923 {
 924         // Acquire TE ID
 925         int nTEID = ReadByte();
 926
 927         FOREACH(TempEntities, it.m_id == nTEID, {
 928                 if (autocvar_developer_csqcentities)
 929                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
 930                 return it.m_read(NULL, NULL, true);
 931         });
 932
 933         if (autocvar_developer_csqcentities)
 934                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
 935
 936         // No special logic for this temporary entity; return 0 so the engine can handle it
 937         return false;
 938 }
 939
 940 string forcefog;
 941 void Fog_Force()
 942 {
 943         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 944                 localcmd("\nr_drawfog 0\n");
 945         else if (forcefog != "")
 946                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
 947 }
 948
 949 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
 950 {
 951         make_pure(this);
 952         gametype = ReadRegistered(Gametypes);
 953         teamplay = _MapInfo_GetTeamPlayBool(gametype);
 954         HUD_ModIcons_SetFunc();
 955         FOREACH(Scores, true, {
 956                 strcpy(scores_label(it), ReadString());
 957                 scores_flags(it) = ReadByte();
 958         });
 959         for (int i = 0; i < MAX_TEAMSCORE; ++i)
 960         {
 961                 strcpy(teamscores_label(i), ReadString());
 962                 teamscores_flags(i) = ReadByte();
 963         }
 964         return = true;
 965         Scoreboard_InitScores();
 966         Gamemode_Init();
 967 }
 968
 969 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
 970 {
 971         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 972
 973         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 974         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 975         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 976         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 977         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 978         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 979         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 980         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 981
 982         strcpy(forcefog, ReadString());
 983
 984         armorblockpercent = ReadByte() / 255.0;
 985         damagepush_speedfactor = ReadByte() / 255.0;
 986
 987         serverflags = ReadByte();
 988
 989         g_trueaim_minrange = ReadCoord();
 990
 991         return = true;
 992
 993         MUTATOR_CALLHOOK(Ent_Init);
 994
 995         if (!postinit) PostInit();
 996 }
 997
 998 float GetSpeedUnitFactor(int speed_unit)
 999 {
1000         switch(speed_unit)
1001         {
1002                 default:
1003                 case 1:
1004                         return 1.0;
1005                 case 2:
1006                         return 0.0254;
1007                 case 3:
1008                         return 0.0254 * 3.6;
1009                 case 4:
1010                         return 0.0254 * 3.6 * 0.6213711922;
1011                 case 5:
1012                         return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1013         }
1014 }
1015
1016 string GetSpeedUnit(int speed_unit)
1017 {
1018         switch(speed_unit)
1019         {
1020                 default:
1021                 case 1:
1022                         return _(" qu/s");
1023                 case 2:
1024                         return _(" m/s");
1025                 case 3:
1026                         return _(" km/h");
1027                 case 4:
1028                         return _(" mph");
1029                 case 5:
1030                         return _(" knots");
1031         }
1032 }
1033
1034 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1035 {
1036         int b = ReadByte();
1037
1038         switch (b)
1039         {
1040                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1041                         race_checkpoint = ReadByte();
1042                         race_time = ReadInt24_t();
1043                         race_previousbesttime = ReadInt24_t();
1044                         race_mypreviousbesttime = ReadInt24_t();
1045                         string pbestname = ReadString();
1046                         if(autocvar_cl_race_cptimes_onlyself)
1047                         {
1048                                 race_previousbesttime = race_mypreviousbesttime;
1049                                 race_mypreviousbesttime = 0;
1050                                 strcpy(race_previousbestname, "");
1051                         }
1052                         else
1053                                 strcpy(race_previousbestname, pbestname);
1054
1055                         race_checkpointtime = time;
1056
1057                         if(race_checkpoint == 0 || race_checkpoint == 254)
1058                         {
1059                                 race_penaltyaccumulator = 0;
1060                                 race_laptime = time; // valid
1061                         }
1062                         break;
1063
1064                 case RACE_NET_CHECKPOINT_CLEAR:
1065                         race_laptime = 0;
1066                         race_checkpointtime = 0;
1067                         break;
1068
1069                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1070                         race_laptime = ReadCoord();
1071                         race_checkpointtime = -99999;
1072                         // fall through
1073                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1074                         race_nextcheckpoint = ReadByte();
1075
1076                         race_nextbesttime = ReadInt24_t();
1077                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1078                                 race_mybesttime = ReadInt24_t();
1079                         string newname = ReadString();
1080                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1081                         {
1082                                 race_nextbesttime = race_mybesttime;
1083                                 race_mybesttime = 0;
1084                                 strcpy(race_nextbestname, "");
1085                         }
1086                         else
1087                                 strcpy(race_nextbestname, newname);
1088                         break;
1089
1090                 case RACE_NET_CHECKPOINT_HIT_RACE:
1091                         race_mycheckpoint = ReadByte();
1092                         race_mycheckpointtime = time;
1093                         race_mycheckpointdelta = ReadInt24_t();
1094                         race_mycheckpointlapsdelta = ReadByte();
1095                         if(race_mycheckpointlapsdelta >= 128)
1096                                 race_mycheckpointlapsdelta -= 256;
1097                         int who = ReadByte();
1098                         if(who)
1099                                 strcpy(race_mycheckpointenemy, entcs_GetName(who - 1));
1100                         else
1101                                 strcpy(race_mycheckpointenemy, ""); // TODO: maybe string_null works fine here?
1102                         break;
1103
1104                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1105                         race_othercheckpoint = ReadByte();
1106                         race_othercheckpointtime = time;
1107                         race_othercheckpointdelta = ReadInt24_t();
1108                         race_othercheckpointlapsdelta = ReadByte();
1109                         if(race_othercheckpointlapsdelta >= 128)
1110                                 race_othercheckpointlapsdelta -= 256;
1111                         int what = ReadByte();
1112                         if(what)
1113                                 strcpy(race_othercheckpointenemy, entcs_GetName(what - 1));
1114                         else
1115                                 strcpy(race_othercheckpointenemy, ""); // TODO: maybe string_null works fine here?
1116                         break;
1117
1118                 case RACE_NET_PENALTY_RACE:
1119                         race_penaltyeventtime = time;
1120                         race_penaltytime = ReadShort();
1121                         //race_penaltyaccumulator += race_penaltytime;
1122                         strcpy(race_penaltyreason, ReadString());
1123                         break;
1124
1125                 case RACE_NET_PENALTY_QUALIFYING:
1126                         race_penaltyeventtime = time;
1127                         race_penaltytime = ReadShort();
1128                         race_penaltyaccumulator += race_penaltytime;
1129                         strcpy(race_penaltyreason, ReadString());
1130                         break;
1131
1132                 case RACE_NET_SERVER_RECORD:
1133                         race_server_record = ReadInt24_t();
1134                         break;
1135                 case RACE_NET_SPEED_AWARD:
1136                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1137                         strcpy(race_speedaward_holder, ReadString());
1138                         strcpy(race_speedaward_unit, GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1139                         break;
1140                 case RACE_NET_SPEED_AWARD_BEST:
1141                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1142                         strcpy(race_speedaward_alltimebest_holder, ReadString());
1143                         strcpy(race_speedaward_alltimebest_unit, GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1144                         break;
1145                 case RACE_NET_RANKINGS_CNT:
1146                         RANKINGS_DISPLAY_CNT = ReadByte();
1147                         break;
1148                 case RACE_NET_SERVER_RANKINGS:
1149                         float prevpos, del;
1150             int pos = ReadShort();
1151                         prevpos = ReadShort();
1152                         del = ReadShort();
1153
1154                         // move other rankings out of the way
1155             int i;
1156                         if (prevpos) {
1157                                 int m = min(prevpos, RANKINGS_DISPLAY_CNT);
1158                                 for (i=m-1; i>pos-1; --i) {
1159                                         grecordtime[i] = grecordtime[i-1];
1160                                         strcpy(grecordholder[i], grecordholder[i-1]);
1161                                 }
1162                         } else if (del) { // a record has been deleted by the admin
1163                                 for (i=pos-1; i<= RANKINGS_DISPLAY_CNT-1; ++i) {
1164                                         if (i == RANKINGS_DISPLAY_CNT-1) { // clear out last record
1165                                                 grecordtime[i] = 0;
1166                                                 strfree(grecordholder[i]);
1167                                         }
1168                                         else {
1169                                                 grecordtime[i] = grecordtime[i+1];
1170                                                 strcpy(grecordholder[i], grecordholder[i+1]);
1171                                         }
1172                                 }
1173                         } else { // player has no ranked record yet
1174                                 for (i=RANKINGS_DISPLAY_CNT-1;i>pos-1;--i) {
1175                                         grecordtime[i] = grecordtime[i-1];
1176                                         strcpy(grecordholder[i], grecordholder[i-1]);
1177                                 }
1178                         }
1179
1180                         if (grecordtime[RANKINGS_DISPLAY_CNT]) {
1181                                 // kick off the player who fell from the last displayed position
1182                                 grecordtime[RANKINGS_DISPLAY_CNT] = 0;
1183                                 strfree(grecordholder[RANKINGS_DISPLAY_CNT]);
1184                         }
1185
1186                         // store new ranking
1187                         strcpy(grecordholder[pos-1], ReadString());
1188                         grecordtime[pos-1] = ReadInt24_t();
1189                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1190                                 race_myrank = pos;
1191                         break;
1192                 case RACE_NET_SERVER_STATUS:
1193                         race_status = ReadShort();
1194                         strcpy(race_status_name, ReadString());
1195         }
1196         return true;
1197 }
1198
1199 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1200 {
1201         teamnagger = 1;
1202         return true;
1203 }
1204
1205 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1206 {
1207         int i = ReadByte();
1208         int pi = ReadShort();
1209         int pl = ReadByte();
1210         int ml = ReadByte();
1211         return = true;
1212         entity e = playerslots[i];
1213         if (!e) return;
1214         e.ping = pi;
1215         e.ping_packetloss = pl / 255.0;
1216         e.ping_movementloss = ml / 255.0;
1217 }
1218
1219 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1220 {
1221         int weapon_id = ReadByte();
1222         complain_weapon = Weapons_from(weapon_id);
1223         complain_weapon_type = ReadByte();
1224         return = true;
1225
1226         complain_weapon_time = time;
1227         weapontime = time; // ping the weapon panel
1228
1229         switch(complain_weapon_type)
1230         {
1231                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, weapon_id); break;
1232                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, weapon_id); break;
1233                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, weapon_id); break;
1234         }
1235 }
1236
1237 string _getcommandkey(string cmd_name, string command, bool forcename)
1238 {
1239         string keys;
1240         float n, j, k, l = 0;
1241
1242         if (!autocvar_hud_showbinds)
1243                 return cmd_name;
1244
1245         keys = db_get(binddb, command);
1246         if (keys == "")
1247         {
1248                 bool joy_active = cvar("joy_active");
1249                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1250                 for(j = 0; j < n; ++j)
1251                 {
1252                         k = stof(argv(j));
1253                         if(k != -1)
1254                         {
1255                                 string key = keynumtostring(k);
1256                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1257                                         continue;
1258
1259                                 if (keys == "")
1260                                         keys = key;
1261                                 else
1262                                         keys = strcat(keys, ", ", key);
1263
1264                                 ++l;
1265                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1266                                         break;
1267                         }
1268
1269                 }
1270                 if (keys == "")
1271                         keys = "NO_KEY";
1272                 db_put(binddb, command, keys);
1273         }
1274
1275         if (keys == "NO_KEY") {
1276                 if (autocvar_hud_showbinds > 1)
1277                         return sprintf(_("%s (not bound)"), cmd_name);
1278                 else
1279                         return cmd_name;
1280         }
1281         else if (autocvar_hud_showbinds > 1 || forcename)
1282                 return sprintf("%s (%s)", cmd_name, keys);
1283         else
1284                 return keys;
1285 }